qcsrc/server/t_items.qc

   1 #define ISF_LOCATION 2
   2 #define ISF_MODEL    4
   3 #define ISF_STATUS   8
   4     #define ITS_STAYWEP   1
   5     #define ITS_ANIMATE1  2
   6     #define ITS_ANIMATE2  4
   7     #define ITS_AVAILABLE 8
   8     #define ITS_ALLOWFB   16
   9     #define ITS_ALLOWSI   32
  10     #define ITS_POWERUP   64
  11 #define ISF_COLORMAP 16
  12 #define ISF_DROP 32
  13 #define ISF_ANGLES 64
  14
  15 .float ItemStatus;
  16
  17 #ifdef CSQC
  18
  19 var float  autocvar_cl_animate_items = 1;
  20 var float  autocvar_cl_ghost_items = 0.45;
  21 var vector autocvar_cl_ghost_items_color = '-1 -1 -1';
  22 var float  autocvar_cl_fullbright_items = 0;
  23 var vector autocvar_cl_weapon_stay_color = '2 0.5 0.5';
  24 var float  autocvar_cl_weapon_stay_alpha = 0.75;
  25 var float  autocvar_cl_simple_items = 0;
  26 var string autocvr_cl_simpleitems_postfix = "_simple";
  27 .float  spawntime;
  28 .float  gravity;
  29 .vector colormod;
  30 void ItemDraw()
  31 {
  32     if(self.gravity)
  33     {
  34         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  35         if(self.move_flags & FL_ONGROUND)
  36         { // For some reason move_avelocity gets set to '0 0 0' here ...
  37             self.oldorigin = self.origin;
  38             self.gravity = 0;
  39
  40             if(autocvar_cl_animate_items)
  41             { // ... so reset it if animations are requested.
  42                 if(self.ItemStatus & ITS_ANIMATE1)
  43                     self.move_avelocity = '0 180 0';
  44
  45                 if(self.ItemStatus & ITS_ANIMATE2)
  46                     self.move_avelocity = '0 -90 0';
  47             }
  48         }
  49     }
  50     else if (autocvar_cl_animate_items)
  51     {
  52         if(self.ItemStatus & ITS_ANIMATE1)
  53         {
  54             self.angles += self.move_avelocity * frametime;
  55             setorigin(self, '0 0 10' + self.oldorigin + '0 0 8' * sin(time * 2));
  56         }
  57
  58         if(self.ItemStatus & ITS_ANIMATE2)
  59         {
  60             self.angles += self.move_avelocity * frametime;
  61             setorigin(self, '0 0 8' + self.oldorigin + '0 0 4' * sin(time * 3));
  62         }
  63     }
  64 }
  65
  66 void ItemDrawSimple()
  67 {
  68     if(self.gravity)
  69     {
  70         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  71
  72         if(self.move_flags & FL_ONGROUND)
  73             self.gravity = 0;
  74     }
  75 }
  76
  77 void ItemRead(float _IsNew)
  78 {
  79     float sf = ReadByte();
  80
  81     if(sf & ISF_LOCATION)
  82     {
  83         self.origin_x = ReadCoord();
  84         self.origin_y = ReadCoord();
  85         self.origin_z = ReadCoord();
  86         setorigin(self, self.origin);
  87         self.oldorigin = self.origin;
  88     }
  89
  90     if(sf & ISF_ANGLES)
  91     {
  92         self.angles_x = ReadCoord();
  93         self.angles_y = ReadCoord();
  94         self.angles_z = ReadCoord();
  95         self.move_angles = self.angles;
  96     }
  97
  98     if(sf & ISF_STATUS) // need to read/write status frist so model can handle simple, fb etc.
  99     {
 100         self.ItemStatus = ReadByte();
 101
 102         if(self.ItemStatus & ITS_AVAILABLE)
 103         {
 104             self.alpha = 1;
 105             self.colormod = self.glowmod = '1 1 1';
 106         }
 107         else
 108         {
 109             if (autocvar_cl_ghost_items_color)
 110             {
 111                 self.alpha = autocvar_cl_ghost_items;
 112                 self.colormod = self.glowmod = autocvar_cl_ghost_items_color;
 113             }
 114             else
 115                 self.alpha = -1;
 116         }
 117
 118         if(autocvar_cl_fullbright_items)
 119             if(self.ItemStatus & ITS_ALLOWFB)
 120                 self.effects |= EF_FULLBRIGHT;
 121
 122         if(self.ItemStatus & ITS_STAYWEP)
 123         {
 124             self.colormod = self.glowmod = autocvar_cl_weapon_stay_color;
 125             self.alpha = autocvar_cl_weapon_stay_alpha;
 126
 127         }
 128
 129         if(self.ItemStatus & ITS_POWERUP)
 130         {
 131             if(self.ItemStatus & ITS_AVAILABLE)
 132                 self.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 133             else
 134                  self.effects &~= (EF_ADDITIVE | EF_FULLBRIGHT);
 135         }
 136     }
 137
 138     if(sf & ISF_MODEL)
 139     {
 140         self.drawmask  = MASK_NORMAL;
 141         self.movetype  = MOVETYPE_NOCLIP;
 142         self.draw       = ItemDraw;
 143
 144         if(self.mdl)
 145             strunzone(self.mdl);
 146
 147         self.mdl = "";
 148         string _fn = ReadString();
 149
 150         if(autocvar_cl_simple_items && (self.ItemStatus & ITS_ALLOWSI))
 151         {
 152             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 153             self.draw = ItemDrawSimple;
 154
 155
 156
 157             if(fexists(sprintf("%s%s.md3", _fn2, autocvr_cl_simpleitems_postfix)))
 158                 self.mdl = strzone(sprintf("%s%s.md3", _fn2, autocvr_cl_simpleitems_postfix));
 159             else if(fexists(sprintf("%s%s.dpm", _fn2, autocvr_cl_simpleitems_postfix)))
 160                 self.mdl = strzone(sprintf("%s%s.dpm", _fn2, autocvr_cl_simpleitems_postfix));
 161             else if(fexists(sprintf("%s%s.iqm", _fn2, autocvr_cl_simpleitems_postfix)))
 162                 self.mdl = strzone(sprintf("%s%s.iqm", _fn2, autocvr_cl_simpleitems_postfix));
 163             else if(fexists(sprintf("%s%s.obj", _fn2, autocvr_cl_simpleitems_postfix)))
 164                 self.mdl = strzone(sprintf("%s%s.obj", _fn2, autocvr_cl_simpleitems_postfix));
 165             else
 166             {
 167                 self.draw = ItemDraw;
 168                 dprint("Simple item requested for ", _fn, " but no model exsist for it\n");
 169             }
 170         }
 171
 172         if(self.draw != ItemDrawSimple)
 173             self.mdl = strzone(_fn);
 174
 175
 176         if(self.mdl == "")
 177             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, " tell tZork aboute this!\n");
 178
 179         precache_model(self.mdl);
 180         setmodel(self, self.mdl);
 181     }
 182
 183     if(sf & ISF_COLORMAP)
 184         self.colormap = ReadShort();
 185
 186     if(sf & ISF_DROP)
 187     {
 188         self.gravity = 1;
 189         self.move_angles = '0 0 0';
 190         self.move_movetype = MOVETYPE_TOSS;
 191         self.move_velocity_x = ReadCoord();
 192         self.move_velocity_y = ReadCoord();
 193         self.move_velocity_z = ReadCoord();
 194         self.velocity = self.move_velocity;
 195         self.move_origin = self.oldorigin;
 196
 197         if(!self.move_time)
 198         {
 199             self.move_time = time;
 200             self.spawntime = time;
 201         }
 202         else
 203             self.move_time = max(self.move_time, time);
 204     }
 205
 206     if(autocvar_cl_animate_items)
 207     {
 208         if(self.ItemStatus & ITS_ANIMATE1)
 209             self.move_avelocity = '0 180 0';
 210
 211         if(self.ItemStatus & ITS_ANIMATE2)
 212             self.move_avelocity = '0 -90 0';
 213     }
 214 }
 215
 216 #endif
 217
 218 #ifdef SVQC
 219 float autocvar_sv_simple_items;
 220 float ItemSend(entity to, float sf)
 221 {
 222     if(self.gravity)
 223         sf |= ISF_DROP;
 224     else
 225         sf &~= ISF_DROP;
 226
 227         WriteByte(MSG_ENTITY, ENT_CLIENT_ITEM);
 228         WriteByte(MSG_ENTITY, sf);
 229
 230         //WriteByte(MSG_ENTITY, self.cnt);
 231     if(sf & ISF_LOCATION)
 232     {
 233         WriteCoord(MSG_ENTITY, self.origin_x);
 234         WriteCoord(MSG_ENTITY, self.origin_y);
 235         WriteCoord(MSG_ENTITY, self.origin_z);
 236     }
 237
 238     if(sf & ISF_ANGLES)
 239     {
 240         WriteCoord(MSG_ENTITY, self.angles_x);
 241         WriteCoord(MSG_ENTITY, self.angles_y);
 242         WriteCoord(MSG_ENTITY, self.angles_z);
 243     }
 244
 245     if(sf & ISF_STATUS)
 246         WriteByte(MSG_ENTITY, self.ItemStatus);
 247
 248     if(sf & ISF_MODEL)
 249     {
 250
 251         if(self.mdl == "")
 252             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, "exspect a crash just aboute now\n");
 253
 254         WriteString(MSG_ENTITY, self.mdl);
 255     }
 256
 257
 258     if(sf & ISF_COLORMAP)
 259         WriteShort(MSG_ENTITY, self.colormap);
 260
 261     if(sf & ISF_DROP)
 262     {
 263         WriteCoord(MSG_ENTITY, self.velocity_x);
 264         WriteCoord(MSG_ENTITY, self.velocity_y);
 265         WriteCoord(MSG_ENTITY, self.velocity_z);
 266     }
 267
 268     return TRUE;
 269 }
 270
 271
 272 float have_pickup_item(void)
 273 {
 274         if(self.flags & FL_POWERUP)
 275         {
 276                 if(autocvar_g_powerups > 0)
 277                         return TRUE;
 278                 if(autocvar_g_powerups == 0)
 279                         return FALSE;
 280                 if(g_lms)
 281                         return FALSE;
 282                 if(g_ca)
 283                         return FALSE;
 284                 if(g_arena)
 285                         return FALSE;
 286         }
 287         else
 288         {
 289                 if(autocvar_g_pickup_items > 0)
 290                         return TRUE;
 291                 if(autocvar_g_pickup_items == 0)
 292                         return FALSE;
 293                 if(g_lms)
 294                         return FALSE;
 295                 if(g_ca)
 296                         return FALSE;
 297                 if(g_weaponarena)
 298                         if(!WEPSET_EMPTY_E(self) || (self.items & IT_AMMO))
 299                                 return FALSE;
 300         }
 301         return TRUE;
 302 }
 303
 304 #define ITEM_RESPAWN_TICKS 10
 305
 306 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
 307         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
 308 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
 309         // range: 10 .. respawntime + respawntimejitter
 310
 311 floatfield Item_CounterField(float it)
 312 {
 313         switch(it)
 314         {
 315                 case IT_SHELLS:      return ammo_shells;
 316                 case IT_NAILS:       return ammo_nails;
 317                 case IT_ROCKETS:     return ammo_rockets;
 318                 case IT_CELLS:       return ammo_cells;
 319                 case IT_FUEL:        return ammo_fuel;
 320                 case IT_5HP:         return health;
 321                 case IT_25HP:        return health;
 322                 case IT_HEALTH:      return health;
 323                 case IT_ARMOR_SHARD: return armorvalue;
 324                 case IT_ARMOR:       return armorvalue;
 325                 // add more things here (health, armor)
 326                 default:             error("requested item has no counter field");
 327         }
 328 #ifdef GMQCC
 329         // should never happen
 330         return health;
 331 #endif
 332 }
 333
 334 string Item_CounterFieldName(float it)
 335 {
 336         switch(it)
 337         {
 338                 case IT_SHELLS:      return "shells";
 339                 case IT_NAILS:       return "nails";
 340                 case IT_ROCKETS:     return "rockets";
 341                 case IT_CELLS:       return "cells";
 342                 case IT_FUEL:        return "fuel";
 343
 344                 // add more things here (health, armor)
 345                 default:             error("requested item has no counter field name");
 346         }
 347 #ifdef GMQCC
 348         // should never happen
 349         return string_null;
 350 #endif
 351 }
 352
 353 .float max_armorvalue;
 354 .float pickup_anyway;
 355 /*
 356 float Item_Customize()
 357 {
 358         if(self.spawnshieldtime)
 359                 return TRUE;
 360         if(!WEPSET_CONTAINS_ALL_EE(other, self))
 361         {
 362                 self.colormod = '0 0 0';
 363                 self.glowmod = self.colormod;
 364                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 365                 return TRUE;
 366         }
 367         else
 368         {
 369                 if(g_ghost_items)
 370                 {
 371                         self.colormod = stov(autocvar_g_ghost_items_color);
 372                         self.glowmod = self.colormod;
 373                         self.alpha = g_ghost_items;
 374                         return TRUE;
 375                 }
 376                 else
 377                         return FALSE;
 378         }
 379 }
 380 */
 381
 382 void Item_Show (entity e, float mode)
 383 {
 384         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
 385         e.ItemStatus &~= ITS_STAYWEP;
 386         if (mode > 0)
 387         {
 388                 // make the item look normal, and be touchable
 389                 e.model = e.mdl;
 390                 e.solid = SOLID_TRIGGER;
 391                 e.spawnshieldtime = 1;
 392                 e.ItemStatus |= ITS_AVAILABLE;
 393         }
 394         else if (mode < 0)
 395         {
 396                 // hide the item completely
 397                 e.model = string_null;
 398                 e.solid = SOLID_NOT;
 399                 e.spawnshieldtime = 1;
 400                 e.ItemStatus &~= ITS_AVAILABLE;
 401         }
 402         else if((e.flags & FL_WEAPON) && !(e.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 403         {
 404                 // make the item translucent and not touchable
 405                 e.model = e.mdl;
 406                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 407                 e.effects |= EF_STARDUST;
 408                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 409                 e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 410         }
 411         else
 412         {
 413                 //setmodel(e, "null");
 414                 e.solid = SOLID_NOT;
 415                 e.colormod = '0 0 0';
 416                 e.glowmod = e.colormod;
 417                 e.spawnshieldtime = 1;
 418                 e.ItemStatus &~= ITS_AVAILABLE;
 419         }
 420
 421         if (e.items & IT_STRENGTH || e.items & IT_INVINCIBLE)
 422             e.ItemStatus |= ITS_POWERUP;
 423
 424         if (autocvar_g_nodepthtestitems)
 425                 e.effects |= EF_NODEPTHTEST;
 426
 427
 428     if (autocvar_g_fullbrightitems)
 429                 e.ItemStatus |= ITS_ALLOWFB;
 430
 431         if (autocvar_sv_simple_items)
 432         e.ItemStatus |= ITS_ALLOWSI;
 433
 434         // relink entity (because solid may have changed)
 435         setorigin(e, e.origin);
 436     e.SendFlags |= ISF_STATUS;
 437 }
 438
 439 void Item_Respawn (void)
 440 {
 441         Item_Show(self, 1);
 442         // this is ugly...
 443         if(self.items == IT_STRENGTH)
 444                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
 445         else if(self.items == IT_INVINCIBLE)
 446                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 447         else
 448                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);  // play respawn sound
 449         setorigin (self, self.origin);
 450
 451         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 452         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 453 }
 454
 455 void Item_RespawnCountdown (void)
 456 {
 457         if(self.count >= ITEM_RESPAWN_TICKS)
 458         {
 459                 if(self.waypointsprite_attached)
 460                         WaypointSprite_Kill(self.waypointsprite_attached);
 461                 Item_Respawn();
 462         }
 463         else
 464         {
 465                 self.nextthink = time + 1;
 466                 self.count += 1;
 467                 if(self.count == 1)
 468                 {
 469                         string name;
 470                         vector rgb = '1 0 1';
 471                         name = string_null;
 472                         switch(self.items)
 473                         {
 474                                 case IT_FUEL_REGEN: name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 475                                 case IT_JETPACK:    name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 476                                 case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 477                                 case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 478                         }
 479                         item_name = name;
 480                         item_color = rgb;
 481                         MUTATOR_CALLHOOK(Item_RespawnCountdown);
 482                         name = item_name;
 483                         rgb = item_color;
 484                         if(self.flags & FL_WEAPON)
 485                         {
 486                                 entity wi = get_weaponinfo(self.weapon);
 487                                 if(wi)
 488                                 {
 489                                         name = wi.model2;
 490                                         rgb = '1 0 0';
 491                                 }
 492                         }
 493                         if(name)
 494                         {
 495                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
 496                                 if(self.waypointsprite_attached)
 497                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 498                         }
 499                         else
 500                         {
 501                                 print("Unknown powerup-marked item is wanting to respawn\n");
 502                                 localcmd(sprintf("prvm_edict server %d\n", num_for_edict(self)));
 503                         }
 504                 }
 505                 sound (self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM); // play respawn sound
 506                 if(self.waypointsprite_attached)
 507                 {
 508                         WaypointSprite_Ping(self.waypointsprite_attached);
 509                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 510                 }
 511         }
 512 }
 513
 514 void Item_ScheduleRespawnIn(entity e, float t)
 515 {
 516         if((e.flags & FL_POWERUP) || WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
 517         {
 518                 e.think = Item_RespawnCountdown;
 519                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 520                 e.count = 0;
 521         }
 522         else
 523         {
 524                 e.think = Item_Respawn;
 525                 e.nextthink = time + t;
 526         }
 527 }
 528
 529 void Item_ScheduleRespawn(entity e)
 530 {
 531         if(e.respawntime > 0)
 532         {
 533                 Item_Show(e, 0);
 534                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 535         }
 536         else // if respawntime is -1, this item does not respawn
 537                 Item_Show(e, -1);
 538 }
 539
 540 void Item_ScheduleInitialRespawn(entity e)
 541 {
 542         Item_Show(e, 0);
 543         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 544 }
 545
 546 float ITEM_MODE_NONE = 0;
 547 float ITEM_MODE_HEALTH = 1;
 548 float ITEM_MODE_ARMOR = 2;
 549 float ITEM_MODE_FUEL = 3;
 550 float Item_GiveAmmoTo(entity item, entity player, .float ammofield, float ammomax, float mode)
 551 {
 552         if (!item.ammofield)
 553                 return FALSE;
 554
 555         if (item.spawnshieldtime)
 556         {
 557                 if ((player.ammofield < ammomax) || item.pickup_anyway)
 558                 {
 559                         player.ammofield = bound(player.ammofield, ammomax, player.ammofield + item.ammofield);
 560                         goto YEAH;
 561                 }
 562         }
 563         else if(g_weapon_stay == 2)
 564         {
 565                 float mi = min(item.ammofield, ammomax);
 566                 if (player.ammofield < mi)
 567                 {
 568                         player.ammofield = mi;
 569                         goto YEAH;
 570                 }
 571         }
 572
 573         return FALSE;
 574
 575 :YEAH
 576         switch(mode)
 577         {
 578                 case ITEM_MODE_FUEL:
 579                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 580                         break;
 581                 case ITEM_MODE_HEALTH:
 582                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 583                         break;
 584                 case ITEM_MODE_ARMOR:
 585                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 586                         break;
 587                 default:
 588                         break;
 589         }
 590         return TRUE;
 591 }
 592
 593 float Item_GiveTo(entity item, entity player)
 594 {
 595         float _switchweapon;
 596         float pickedup;
 597         float it;
 598         float i;
 599
 600         // if nothing happens to player, just return without taking the item
 601         pickedup = FALSE;
 602         _switchweapon = FALSE;
 603         // in case the player has autoswitch enabled do the following:
 604         // if the player is using their best weapon before items are given, they
 605         // probably want to switch to an even better weapon after items are given
 606         if (player.autoswitch)
 607         if (player.switchweapon == w_getbestweapon(player))
 608                 _switchweapon = TRUE;
 609
 610         if not(WEPSET_CONTAINS_EW(player, player.switchweapon))
 611                 _switchweapon = TRUE;
 612
 613         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 614         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 615         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 616         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 617         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 618         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 619         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 620
 621         if (item.flags & FL_WEAPON)
 622         {
 623                 WEPSET_DECLARE_A(it);
 624                 WEPSET_COPY_AE(it, item);
 625                 WEPSET_ANDNOT_AE(it, player);
 626
 627                 if (!WEPSET_EMPTY_A(it) || (item.spawnshieldtime && self.pickup_anyway))
 628                 {
 629                 pickedup = TRUE;
 630                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 631                         if(WEPSET_CONTAINS_AW(it, i))
 632                         W_GiveWeapon(player, i);
 633                 }
 634         }
 635
 636         if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 637         {
 638                 pickedup = TRUE;
 639                 player.items |= it;
 640                 sprint (player, strcat("You got the ^2", item.netname, "\n"));
 641         }
 642
 643         if (item.strength_finished)
 644         {
 645                 pickedup = TRUE;
 646                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 647         }
 648         if (item.invincible_finished)
 649         {
 650                 pickedup = TRUE;
 651                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 652         }
 653         if (item.superweapons_finished)
 654         {
 655                 pickedup = TRUE;
 656                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 657         }
 658
 659 :skip
 660
 661         // always eat teamed entities
 662         if(item.team)
 663                 pickedup = TRUE;
 664
 665         if (!pickedup)
 666                 return 0;
 667
 668         if (_switchweapon)
 669                 if (player.switchweapon != w_getbestweapon(player))
 670                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 671
 672         return 1;
 673 }
 674
 675 void Item_Touch (void)
 676 {
 677         entity e, head;
 678
 679         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 680         if(self.classname == "droppedweapon")
 681         {
 682                 if (ITEM_TOUCH_NEEDKILL())
 683                 {
 684                         remove(self);
 685                         return;
 686                 }
 687         }
 688
 689         if (other.classname != "player")
 690                 return;
 691         if (other.deadflag)
 692                 return;
 693         if (self.solid != SOLID_TRIGGER)
 694                 return;
 695         if (self.owner == other)
 696                 return;
 697         if(MUTATOR_CALLHOOK(ItemTouch))
 698                 return;
 699
 700         if (self.classname == "droppedweapon")
 701         {
 702                 self.strength_finished = max(0, self.strength_finished - time);
 703                 self.invincible_finished = max(0, self.invincible_finished - time);
 704                 self.superweapons_finished = max(0, self.superweapons_finished - time);
 705         }
 706
 707         if(!Item_GiveTo(self, other))
 708         {
 709                 if (self.classname == "droppedweapon")
 710                 {
 711                         // undo what we did above
 712                         self.strength_finished += time;
 713                         self.invincible_finished += time;
 714                         self.superweapons_finished += time;
 715                 }
 716                 return;
 717         }
 718
 719         other.last_pickup = time;
 720
 721         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 722         sound (other, CH_TRIGGER, self.item_pickupsound, VOL_BASE, ATTN_NORM);
 723
 724         if (self.classname == "droppedweapon")
 725                 remove (self);
 726         else if not(self.spawnshieldtime)
 727                 return;
 728         else
 729         {
 730                 if(self.team)
 731                 {
 732                         RandomSelection_Init();
 733                         for(head = world; (head = findfloat(head, team, self.team)); )
 734                         {
 735                                 if(head.flags & FL_ITEM)
 736                                 {
 737                                         Item_Show(head, -1);
 738                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 739                                 }
 740                         }
 741                         e = RandomSelection_chosen_ent;
 742
 743                 }
 744                 else
 745                         e = self;
 746                 Item_ScheduleRespawn(e);
 747         }
 748 }
 749
 750 void Item_Reset()
 751 {
 752         Item_Show(self, !self.state);
 753         setorigin (self, self.origin);
 754
 755         if(self.classname != "droppedweapon")
 756         {
 757                 self.think = func_null;
 758                 self.nextthink = 0;
 759
 760                 if(self.waypointsprite_attached)
 761                         WaypointSprite_Kill(self.waypointsprite_attached);
 762
 763                 if((self.flags & FL_POWERUP) | WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // do not spawn powerups initially!
 764                         Item_ScheduleInitialRespawn(self);
 765         }
 766 }
 767
 768 void Item_FindTeam()
 769 {
 770         entity head, e;
 771
 772         if(self.effects & EF_NODRAW)
 773         {
 774                 // marker for item team search
 775                 dprint("Initializing item team ", ftos(self.team), "\n");
 776                 RandomSelection_Init();
 777                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 778                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 779                 e = RandomSelection_chosen_ent;
 780                 e.state = 0;
 781                 Item_Show(e, 1);
 782
 783                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 784                 {
 785                         if(head != e)
 786                         {
 787                                 // make it a non-spawned item
 788                                 Item_Show(head, -1);
 789                                 head.state = 1; // state 1 = initially hidden item
 790                         }
 791                         head.effects &~= EF_NODRAW;
 792                 }
 793
 794                 Item_Reset();
 795         }
 796 }
 797
 798 // Savage: used for item garbage-collection
 799 // TODO: perhaps nice special effect?
 800 void RemoveItem(void)
 801 {
 802         remove(self);
 803 }
 804
 805 // pickup evaluation functions
 806 // these functions decide how desirable an item is to the bots
 807
 808 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 809
 810 float weapon_pickupevalfunc(entity player, entity item)
 811 {
 812         float c, j, position;
 813
 814         // See if I have it already
 815         if(!WEPSET_CONTAINS_ALL_EE(player, item))
 816         {
 817                 // If I can pick it up
 818                 if(!item.spawnshieldtime)
 819                         c = 0;
 820                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 821                 {
 822                         // Skilled bots will grab more
 823                         c = bound(0, skill / 10, 1) * 0.5;
 824                 }
 825                 else
 826                         c = 0;
 827         }
 828         else
 829                 c = 1;
 830
 831         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 832         if( bot_custom_weapon && c )
 833         {
 834                 // Find the highest position on any range
 835                 position = -1;
 836                 for(j = 0; j < WEP_LAST ; ++j){
 837                         if(
 838                                         bot_weapons_far[j] == item.weapon ||
 839                                         bot_weapons_mid[j] == item.weapon ||
 840                                         bot_weapons_close[j] == item.weapon
 841                           )
 842                         {
 843                                 position = j;
 844                                 break;
 845                         }
 846                 }
 847
 848                 // Rate it
 849                 if (position >= 0 )
 850                 {
 851                         position = WEP_LAST - position;
 852                         // item.bot_pickupbasevalue is overwritten here
 853                         return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 854                 }
 855         }
 856
 857         return item.bot_pickupbasevalue * c;
 858 }
 859
 860 float commodity_pickupevalfunc(entity player, entity item)
 861 {
 862         float c, i;
 863         float need_shells = FALSE, need_nails = FALSE, need_rockets = FALSE, need_cells = FALSE, need_fuel = FALSE;
 864         entity wi;
 865         c = 0;
 866
 867         // Detect needed ammo
 868         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 869         {
 870                 wi = get_weaponinfo(i);
 871
 872                 if not(WEPSET_CONTAINS_EW(player, i))
 873                         continue;
 874
 875                 if(wi.items & IT_SHELLS)
 876                         need_shells = TRUE;
 877                 else if(wi.items & IT_NAILS)
 878                         need_nails = TRUE;
 879                 else if(wi.items & IT_ROCKETS)
 880                         need_rockets = TRUE;
 881                 else if(wi.items & IT_CELLS)
 882                         need_cells = TRUE;
 883                 else if(wi.items & IT_FUEL)
 884                         need_cells = TRUE;
 885         }
 886
 887         // TODO: figure out if the player even has the weapon this ammo is for?
 888         // may not affect strategy much though...
 889         // find out how much more ammo/armor/health the player can hold
 890         if (need_shells)
 891         if (item.ammo_shells)
 892         if (player.ammo_shells < g_pickup_shells_max)
 893                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 894         if (need_nails)
 895         if (item.ammo_nails)
 896         if (player.ammo_nails < g_pickup_nails_max)
 897                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 898         if (need_rockets)
 899         if (item.ammo_rockets)
 900         if (player.ammo_rockets < g_pickup_rockets_max)
 901                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 902         if (need_cells)
 903         if (item.ammo_cells)
 904         if (player.ammo_cells < g_pickup_cells_max)
 905                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 906         if (need_fuel)
 907         if (item.ammo_fuel)
 908         if (player.ammo_fuel < g_pickup_fuel_max)
 909                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
 910         if (item.armorvalue)
 911         if (player.armorvalue < item.max_armorvalue)
 912                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 913         if (item.health)
 914         if (player.health < item.max_health)
 915                 c = c + max(0, 1 - player.health / item.max_health);
 916
 917         return item.bot_pickupbasevalue * c;
 918 }
 919
 920 void Item_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 921 {
 922         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 923                 RemoveItem();
 924 }
 925
 926 .float is_item;
 927 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 928 {
 929         startitem_failed = FALSE;
 930
 931         if(self.model == "")
 932                 self.model = itemmodel;
 933
 934         if(self.model == "")
 935     {
 936         error(strcat("^1Tried to spawn ", itemname, " with no model!\n"));
 937         return;
 938     }
 939
 940         if(self.item_pickupsound == "")
 941                 self.item_pickupsound = pickupsound;
 942
 943         if(!self.respawntime) // both need to be set
 944         {
 945                 self.respawntime = defaultrespawntime;
 946                 self.respawntimejitter = defaultrespawntimejitter;
 947         }
 948
 949         self.items = itemid;
 950         self.weapon = weaponid;
 951
 952         if(weaponid)
 953                 WEPSET_COPY_EW(self, weaponid);
 954
 955         self.flags = FL_ITEM | itemflags;
 956
 957         if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
 958         {
 959                 startitem_failed = TRUE;
 960                 remove(self);
 961                 return;
 962         }
 963
 964         // is it a dropped weapon?
 965         if (self.classname == "droppedweapon")
 966         {
 967                 self.reset = SUB_Remove;
 968                 // it's a dropped weapon
 969                 self.movetype = MOVETYPE_TOSS;
 970
 971                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 972                 self.think = RemoveItem;
 973                 self.nextthink = time + 20;
 974
 975                 self.takedamage = DAMAGE_YES;
 976                 self.event_damage = Item_Damage;
 977
 978                 if(self.strength_finished || self.invincible_finished || self.superweapons_finished)
 979                 /*
 980                 if(self.items == 0)
 981                 if(WEPSET_CONTAINS_ALL_AE(WEPBIT_SUPERWEAPONS, self)) // only superweapons
 982                 if(self.ammo_nails == 0)
 983                 if(self.ammo_cells == 0)
 984                 if(self.ammo_rockets == 0)
 985                 if(self.ammo_shells == 0)
 986                 if(self.ammo_fuel == 0)
 987                 if(self.health == 0)
 988                 if(self.armorvalue == 0)
 989                 */
 990                 {
 991                         // if item is worthless after a timer, have it expire then
 992                         self.nextthink = max(self.strength_finished, self.invincible_finished, self.superweapons_finished);
 993                 }
 994
 995                 // don't drop if in a NODROP zone (such as lava)
 996                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 997                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 998                 {
 999                         startitem_failed = TRUE;
1000                         remove(self);
1001                         return;
1002                 }
1003         }
1004         else
1005         {
1006                 if(!have_pickup_item())
1007                 {
1008                         startitem_failed = TRUE;
1009                         remove (self);
1010                         return;
1011                 }
1012
1013                 if(self.angles != '0 0 0')
1014             self.SendFlags |= ISF_ANGLES;
1015
1016                 self.reset = Item_Reset;
1017                 // it's a level item
1018                 if(self.spawnflags & 1)
1019                         self.noalign = 1;
1020                 if (self.noalign)
1021                         self.movetype = MOVETYPE_NONE;
1022                 else
1023                         self.movetype = MOVETYPE_TOSS;
1024                 // do item filtering according to game mode and other things
1025                 if (!self.noalign)
1026                 {
1027                         // first nudge it off the floor a little bit to avoid math errors
1028                         setorigin(self, self.origin + '0 0 1');
1029                         // set item size before we spawn a spawnfunc_waypoint
1030                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1031                                 setsize (self, '-16 -16 0', '16 16 48');
1032                         else
1033                                 setsize (self, '-16 -16 0', '16 16 32');
1034                         // note droptofloor returns FALSE if stuck/or would fall too far
1035                         droptofloor();
1036                         waypoint_spawnforitem(self);
1037                 }
1038
1039                 /*
1040                  * can't do it that way, as it would break maps
1041                  * TODO make a target_give like entity another way, that perhaps has
1042                  * the weapon name in a key
1043                 if(self.targetname)
1044                 {
1045                         // target_give not yet supported; maybe later
1046                         print("removed targeted ", self.classname, "\n");
1047                         startitem_failed = TRUE;
1048                         remove (self);
1049                         return;
1050                 }
1051                 */
1052
1053                 if(autocvar_spawn_debug >= 2)
1054                 {
1055                         entity otheritem;
1056                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
1057                         {
1058                             // why not flags & fl_item?
1059                                 if(otheritem.is_item)
1060                                 {
1061                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
1062                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
1063                                         error("Mapper sucks.");
1064                                 }
1065                         }
1066                         self.is_item = TRUE;
1067                 }
1068
1069                 WEPSET_OR_AW(weaponsInMap, weaponid);
1070
1071                 precache_model (self.model);
1072                 precache_sound (self.item_pickupsound);
1073
1074                 precache_sound ("misc/itemrespawncountdown.wav");
1075                 if(itemid == IT_STRENGTH)
1076                         precache_sound ("misc/strength_respawn.wav");
1077                 else if(itemid == IT_INVINCIBLE)
1078                         precache_sound ("misc/shield_respawn.wav");
1079                 else
1080                         precache_sound ("misc/itemrespawn.wav");
1081
1082                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
1083                         self.target = "###item###"; // for finding the nearest item using find()
1084         }
1085
1086         self.bot_pickup = TRUE;
1087         self.bot_pickupevalfunc = pickupevalfunc;
1088         self.bot_pickupbasevalue = pickupbasevalue;
1089         self.mdl = self.model;
1090         self.netname = itemname;
1091         self.touch = Item_Touch;
1092         setmodel(self, "null"); // precision set below
1093         //self.effects |= EF_LOWPRECISION;
1094
1095         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1096     {
1097         self.pos1 = '-16 -16 0';
1098         self.pos2 = '16 16 48';
1099     }
1100         else
1101     {
1102         self.pos1 = '-16 -16 0';
1103         self.pos2 = '16 16 32';
1104     }
1105     setsize (self, self.pos1, self.pos2);
1106
1107     if(itemflags & FL_POWERUP)
1108         self.ItemStatus |= ITS_ANIMATE1;
1109
1110         if(self.armorvalue || self.health)
1111         self.ItemStatus |= ITS_ANIMATE2;
1112
1113         if(itemflags & FL_WEAPON)
1114         {
1115                 if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1116             self.colormap = 1024; // color shirt=0 pants=0 grey
1117         else
1118             self.gravity = 1;
1119
1120                 self.ItemStatus |= ITS_ANIMATE1;
1121                 self.ItemStatus |= ISF_COLORMAP;
1122         }
1123
1124         self.state = 0;
1125         if(self.team) // broken, no idea why.
1126         {
1127                 if(!self.cnt)
1128                         self.cnt = 1; // item probability weight
1129
1130                 self.effects |= EF_NODRAW; // marker for item team search
1131                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
1132         }
1133         else
1134                 Item_Reset();
1135
1136     Net_LinkEntity(self, FALSE, 0, ItemSend);
1137
1138         // call this hook after everything else has been done
1139         if(MUTATOR_CALLHOOK(Item_Spawn))
1140         {
1141                 startitem_failed = TRUE;
1142                 remove(self);
1143                 return;
1144         }
1145 }
1146
1147 float weaponswapping;
1148 float internalteam;
1149
1150 void weapon_defaultspawnfunc(float wpn)
1151 {
1152         entity e;
1153         float t;
1154         var .float ammofield;
1155         string s;
1156         entity oldself;
1157         float i, j;
1158         float f;
1159
1160         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
1161         {
1162                 e = get_weaponinfo(wpn);
1163
1164                 if(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
1165                 {
1166                         print("Attempted to spawn a mutator-blocked weapon; these guns will in the future require a mutator\n");
1167                         /*
1168                         objerror("Attempted to spawn a mutator-blocked weapon rejected");
1169                         startitem_failed = TRUE;
1170                         return;
1171                         */
1172                 }
1173
1174                 s = W_Apply_Weaponreplace(e.netname);
1175                 ret_string = s;
1176                 other = e;
1177                 MUTATOR_CALLHOOK(SetWeaponreplace);
1178                 s = ret_string;
1179                 if(s == "")
1180                 {
1181                         remove(self);
1182                         startitem_failed = TRUE;
1183                         return;
1184                 }
1185                 t = tokenize_console(s);
1186                 if(t >= 2)
1187                 {
1188                         self.team = --internalteam;
1189                         oldself = self;
1190                         for(i = 1; i < t; ++i)
1191                         {
1192                                 s = argv(i);
1193                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1194                                 {
1195                                         e = get_weaponinfo(j);
1196                                         if(e.netname == s)
1197                                         {
1198                                                 self = spawn();
1199                                                 copyentity(oldself, self);
1200                                                 self.classname = "replacedweapon";
1201                                                 weapon_defaultspawnfunc(j);
1202                                                 break;
1203                                         }
1204                                 }
1205                                 if(j > WEP_LAST)
1206                                 {
1207                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1208                                 }
1209                         }
1210                         self = oldself;
1211                 }
1212                 if(t >= 1) // always the case!
1213                 {
1214                         s = argv(0);
1215                         wpn = 0;
1216                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1217                         {
1218                                 e = get_weaponinfo(j);
1219                                 if(e.netname == s)
1220                                 {
1221                                         wpn = j;
1222                                         break;
1223                                 }
1224                         }
1225                         if(j > WEP_LAST)
1226                         {
1227                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1228                         }
1229                 }
1230                 if(wpn == 0)
1231                 {
1232                         remove(self);
1233                         startitem_failed = TRUE;
1234                         return;
1235                 }
1236         }
1237
1238         e = get_weaponinfo(wpn);
1239
1240         if(!self.respawntime)
1241         {
1242                 if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1243                 {
1244                         self.respawntime = g_pickup_respawntime_superweapon;
1245                         self.respawntimejitter = g_pickup_respawntimejitter_superweapon;
1246                 }
1247                 else
1248                 {
1249                         self.respawntime = g_pickup_respawntime_weapon;
1250                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
1251                 }
1252         }
1253
1254         if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1255                 if(!self.superweapons_finished)
1256                         self.superweapons_finished = autocvar_g_balance_superweapons_time;
1257
1258         if(e.items)
1259         {
1260                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1261                 {
1262                         if(e.items & j)
1263                         {
1264                                 ammofield = Item_CounterField(j);
1265                                 if(!self.ammofield)
1266                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j), "_weapon"));
1267                         }
1268                 }
1269         }
1270
1271         // pickup anyway
1272         if(g_pickup_weapons_anyway)
1273                 self.pickup_anyway = TRUE;
1274
1275         f = FL_WEAPON;
1276
1277         // no weapon-stay on superweapons
1278         if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1279                 f |= FL_NO_WEAPON_STAY;
1280
1281         // weapon stay isn't supported for teamed weapons
1282         if(self.team)
1283                 f |= FL_NO_WEAPON_STAY;
1284
1285         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapon, f, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1286         if (self.modelindex) // don't precache if self was removed
1287                 weapon_action(e.weapon, WR_PRECACHE);
1288 }
1289
1290 void spawnfunc_weapon_shotgun (void);
1291 void spawnfunc_weapon_uzi (void) {
1292         if(autocvar_sv_q3acompat_machineshotgunswap)
1293         if(self.classname != "droppedweapon")
1294         {
1295                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1296                 return;
1297         }
1298         weapon_defaultspawnfunc(WEP_UZI);
1299 }
1300
1301 void spawnfunc_weapon_shotgun (void) {
1302         if(autocvar_sv_q3acompat_machineshotgunswap)
1303         if(self.classname != "droppedweapon")
1304         {
1305                 weapon_defaultspawnfunc(WEP_UZI);
1306                 return;
1307         }
1308         weapon_defaultspawnfunc(WEP_SHOTGUN);
1309 }
1310
1311 void spawnfunc_weapon_nex (void)
1312 {
1313         weapon_defaultspawnfunc(WEP_NEX);
1314 }
1315
1316 void spawnfunc_weapon_minstanex (void)
1317 {
1318         weapon_defaultspawnfunc(WEP_MINSTANEX);
1319 }
1320
1321 void spawnfunc_weapon_rocketlauncher (void)
1322 {
1323         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1324 }
1325
1326 void spawnfunc_item_rockets (void) {
1327         if(!self.ammo_rockets)
1328                 self.ammo_rockets = g_pickup_rockets;
1329         if(!self.pickup_anyway)
1330                 self.pickup_anyway = g_pickup_ammo_anyway;
1331         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1332 }
1333
1334 void spawnfunc_item_shells (void);
1335 void spawnfunc_item_bullets (void) {
1336         if(!weaponswapping)
1337         if(autocvar_sv_q3acompat_machineshotgunswap)
1338         if(self.classname != "droppedweapon")
1339         {
1340                 weaponswapping = TRUE;
1341                 spawnfunc_item_shells();
1342                 weaponswapping = FALSE;
1343                 return;
1344         }
1345
1346         if(!self.ammo_nails)
1347                 self.ammo_nails = g_pickup_nails;
1348         if(!self.pickup_anyway)
1349                 self.pickup_anyway = g_pickup_ammo_anyway;
1350         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1351 }
1352
1353 void spawnfunc_item_cells (void) {
1354         if(!self.ammo_cells)
1355                 self.ammo_cells = g_pickup_cells;
1356         if(!self.pickup_anyway)
1357                 self.pickup_anyway = g_pickup_ammo_anyway;
1358         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1359 }
1360
1361 void spawnfunc_item_shells (void) {
1362         if(!weaponswapping)
1363         if(autocvar_sv_q3acompat_machineshotgunswap)
1364         if(self.classname != "droppedweapon")
1365         {
1366                 weaponswapping = TRUE;
1367                 spawnfunc_item_bullets();
1368                 weaponswapping = FALSE;
1369                 return;
1370         }
1371
1372         if(!self.ammo_shells)
1373                 self.ammo_shells = g_pickup_shells;
1374         if(!self.pickup_anyway)
1375                 self.pickup_anyway = g_pickup_ammo_anyway;
1376         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1377 }
1378
1379 void spawnfunc_item_armor_small (void) {
1380         if(!self.armorvalue)
1381                 self.armorvalue = g_pickup_armorsmall;
1382         if(!self.max_armorvalue)
1383                 self.max_armorvalue = g_pickup_armorsmall_max;
1384         if(!self.pickup_anyway)
1385                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1386         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1387 }
1388
1389 void spawnfunc_item_armor_medium (void) {
1390         if(!self.armorvalue)
1391                 self.armorvalue = g_pickup_armormedium;
1392         if(!self.max_armorvalue)
1393                 self.max_armorvalue = g_pickup_armormedium_max;
1394         if(!self.pickup_anyway)
1395                 self.pickup_anyway = g_pickup_armormedium_anyway;
1396         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1397 }
1398
1399 void spawnfunc_item_armor_big (void) {
1400         if(!self.armorvalue)
1401                 self.armorvalue = g_pickup_armorbig;
1402         if(!self.max_armorvalue)
1403                 self.max_armorvalue = g_pickup_armorbig_max;
1404         if(!self.pickup_anyway)
1405                 self.pickup_anyway = g_pickup_armorbig_anyway;
1406         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1407 }
1408
1409 void spawnfunc_item_armor_large (void) {
1410         if(!self.armorvalue)
1411                 self.armorvalue = g_pickup_armorlarge;
1412         if(!self.max_armorvalue)
1413                 self.max_armorvalue = g_pickup_armorlarge_max;
1414         if(!self.pickup_anyway)
1415                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1416         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1417 }
1418
1419 void spawnfunc_item_health_small (void) {
1420         if(!self.max_health)
1421                 self.max_health = g_pickup_healthsmall_max;
1422         if(!self.health)
1423                 self.health = g_pickup_healthsmall;
1424         if(!self.pickup_anyway)
1425                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1426         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1427 }
1428
1429 void spawnfunc_item_health_medium (void) {
1430         if(!self.max_health)
1431                 self.max_health = g_pickup_healthmedium_max;
1432         if(!self.health)
1433                 self.health = g_pickup_healthmedium;
1434         if(!self.pickup_anyway)
1435                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1436         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1437 }
1438
1439 void spawnfunc_item_health_large (void) {
1440         if(!self.max_health)
1441                 self.max_health = g_pickup_healthlarge_max;
1442         if(!self.health)
1443                 self.health = g_pickup_healthlarge;
1444         if(!self.pickup_anyway)
1445                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1446         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1447 }
1448
1449 void spawnfunc_item_health_mega (void) {
1450                 if(!self.max_health)
1451                         self.max_health = g_pickup_healthmega_max;
1452                 if(!self.health)
1453                         self.health = g_pickup_healthmega;
1454                 if(!self.pickup_anyway)
1455                         self.pickup_anyway = g_pickup_healthmega_anyway;
1456                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1457 }
1458
1459 // support old misnamed entities
1460 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1461 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1462 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1463 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1464 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1465
1466 void spawnfunc_item_strength (void) {
1467                 precache_sound("weapons/strength_fire.wav");
1468                 if(!self.strength_finished)
1469                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1470                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1471 }
1472
1473 void spawnfunc_item_invincible (void) {
1474                 if(!self.invincible_finished)
1475                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1476                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1477 }
1478
1479 // compatibility:
1480 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1481
1482 float GiveItems(entity e, float beginarg, float endarg);
1483 void target_items_use (void)
1484 {
1485         if(activator.classname == "droppedweapon")
1486         {
1487                 EXACTTRIGGER_TOUCH;
1488                 remove(activator);
1489                 return;
1490         }
1491
1492         if(activator.classname != "player")
1493                 return;
1494         if(activator.deadflag != DEAD_NO)
1495                 return;
1496         EXACTTRIGGER_TOUCH;
1497
1498         entity e;
1499         for(e = world; (e = find(e, classname, "droppedweapon")); )
1500                 if(e.enemy == activator)
1501                         remove(e);
1502
1503         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1504                 centerprint(activator, self.message);
1505 }
1506
1507 void spawnfunc_target_items (void)
1508 {
1509         float n, i, j;
1510         entity e;
1511
1512         self.use = target_items_use;
1513         if(!self.strength_finished)
1514                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1515         if(!self.invincible_finished)
1516                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1517         if(!self.superweapons_finished)
1518                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1519
1520         precache_sound("misc/itempickup.wav");
1521         precache_sound("misc/megahealth.wav");
1522         precache_sound("misc/armor25.wav");
1523         precache_sound("misc/powerup.wav");
1524         precache_sound("misc/poweroff.wav");
1525         precache_sound("weapons/weaponpickup.wav");
1526
1527         n = tokenize_console(self.netname);
1528         if(argv(0) == "give")
1529         {
1530                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1531         }
1532         else
1533         {
1534                 for(i = 0; i < n; ++i)
1535                 {
1536                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1537                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1538                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1539                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1540                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1541                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1542                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1543                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1544                         else
1545                         {
1546                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1547                                 {
1548                                         e = get_weaponinfo(j);
1549                                         if(argv(i) == e.netname)
1550                                         {
1551                                                 WEPSET_OR_EW(self, j);
1552                                                 if(self.spawnflags == 0 || self.spawnflags == 2)
1553                                                         weapon_action(e.weapon, WR_PRECACHE);
1554                                                 break;
1555                                         }
1556                                 }
1557                                 if(j > WEP_LAST)
1558                                         print("target_items: invalid item ", argv(i), "\n");
1559                         }
1560                 }
1561
1562                 string itemprefix, valueprefix;
1563                 if(self.spawnflags == 0)
1564                 {
1565                         itemprefix = "";
1566                         valueprefix = "";
1567                 }
1568                 else if(self.spawnflags == 1)
1569                 {
1570                         itemprefix = "max ";
1571                         valueprefix = "max ";
1572                 }
1573                 else if(self.spawnflags == 2)
1574                 {
1575                         itemprefix = "min ";
1576                         valueprefix = "min ";
1577                 }
1578                 else if(self.spawnflags == 4)
1579                 {
1580                         itemprefix = "minus ";
1581                         valueprefix = "max ";
1582                 }
1583                 else
1584                 {
1585                         error("invalid spawnflags");
1586 #ifdef GMQCC
1587                         itemprefix = string_null;
1588                         valueprefix = string_null;
1589 #endif
1590                 }
1591
1592                 self.netname = "";
1593                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1594                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1595                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1596                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1597                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * !!(self.items & IT_SUPERWEAPON), "superweapons");
1598                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1599                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1600                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1601                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1602                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1603                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1604                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1605                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1606                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1607                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1608                 {
1609                         e = get_weaponinfo(j);
1610                         if(e.weapon)
1611                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, WEPSET_CONTAINS_EW(self, j), e.netname);
1612                 }
1613         }
1614         self.netname = strzone(self.netname);
1615         //print(self.netname, "\n");
1616
1617         n = tokenize_console(self.netname);
1618         for(i = 0; i < n; ++i)
1619         {
1620                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1621                 {
1622                         e = get_weaponinfo(j);
1623                         if(argv(i) == e.netname)
1624                         {
1625                                 weapon_action(e.weapon, WR_PRECACHE);
1626                                 break;
1627                         }
1628                 }
1629         }
1630 }
1631
1632 void spawnfunc_item_fuel(void)
1633 {
1634         if(!self.ammo_fuel)
1635                 self.ammo_fuel = g_pickup_fuel;
1636         if(!self.pickup_anyway)
1637                 self.pickup_anyway = g_pickup_ammo_anyway;
1638         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1639 }
1640
1641 void spawnfunc_item_fuel_regen(void)
1642 {
1643         if(start_items & IT_FUEL_REGEN)
1644         {
1645                 spawnfunc_item_fuel();
1646                 return;
1647         }
1648         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1649 }
1650
1651 void spawnfunc_item_jetpack(void)
1652 {
1653         if(g_grappling_hook)
1654                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1655         if(!self.ammo_fuel)
1656                 self.ammo_fuel = g_pickup_fuel_jetpack;
1657         if(start_items & IT_JETPACK)
1658         {
1659                 spawnfunc_item_fuel();
1660                 return;
1661         }
1662         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1663 }
1664
1665
1666 #define OP_SET 0
1667 #define OP_MIN 1
1668 #define OP_MAX 2
1669 #define OP_PLUS 3
1670 #define OP_MINUS 4
1671
1672 float GiveWeapon(entity e, float wpn, float op, float val)
1673 {
1674         float v0, v1;
1675         v0 = WEPSET_CONTAINS_EW(e, wpn);
1676         switch(op)
1677         {
1678                 case OP_SET:
1679                         if(val > 0)
1680                                 WEPSET_OR_EW(e, wpn);
1681                         else
1682                                 WEPSET_ANDNOT_EW(e, wpn);
1683                         break;
1684                 case OP_MIN:
1685                 case OP_PLUS:
1686                         if(val > 0)
1687                                 WEPSET_OR_EW(e, wpn);
1688                         break;
1689                 case OP_MAX:
1690                         if(val <= 0)
1691                                 WEPSET_ANDNOT_EW(e, wpn);
1692                         break;
1693                 case OP_MINUS:
1694                         if(val > 0)
1695                                 WEPSET_ANDNOT_EW(e, wpn);
1696                         break;
1697         }
1698         v1 = WEPSET_CONTAINS_EW(e, wpn);
1699         return (v0 != v1);
1700 }
1701
1702 float GiveBit(entity e, .float fld, float bit, float op, float val)
1703 {
1704         float v0, v1;
1705         v0 = (e.fld & bit);
1706         switch(op)
1707         {
1708                 case OP_SET:
1709                         if(val > 0)
1710                                 e.fld |= bit;
1711                         else
1712                                 e.fld &~= bit;
1713                         break;
1714                 case OP_MIN:
1715                 case OP_PLUS:
1716                         if(val > 0)
1717                                 e.fld |= bit;
1718                         break;
1719                 case OP_MAX:
1720                         if(val <= 0)
1721                                 e.fld &~= bit;
1722                         break;
1723                 case OP_MINUS:
1724                         if(val > 0)
1725                                 e.fld &~= bit;
1726                         break;
1727         }
1728         v1 = (e.fld & bit);
1729         return (v0 != v1);
1730 }
1731
1732 float GiveValue(entity e, .float fld, float op, float val)
1733 {
1734         float v0, v1;
1735         v0 = e.fld;
1736         switch(op)
1737         {
1738                 case OP_SET:
1739                         e.fld = val;
1740                         break;
1741                 case OP_MIN:
1742                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1743                         break;
1744                 case OP_MAX:
1745                         e.fld = min(e.fld, val);
1746                         break;
1747                 case OP_PLUS:
1748                         e.fld += val;
1749                         break;
1750                 case OP_MINUS:
1751                         e.fld -= val;
1752                         break;
1753         }
1754         v1 = e.fld;
1755         return (v0 != v1);
1756 }
1757
1758 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1759 {
1760         if(v1 == v0)
1761                 return;
1762         if(v1 <= v0 - t)
1763         {
1764                 if(snd_decr != "")
1765                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTN_NORM);
1766         }
1767         else if(v0 >= v0 + t)
1768         {
1769                 if(snd_incr != "")
1770                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTN_NORM);
1771         }
1772 }
1773
1774 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1775 {
1776         if(v0 < v1)
1777                 e.rotfield = max(e.rotfield, time + rottime);
1778         else if(v0 > v1)
1779                 e.regenfield = max(e.regenfield, time + regentime);
1780 }
1781
1782 #define PREGIVE_WEAPONS(e) WEPSET_DECLARE_A(save_weapons); WEPSET_COPY_AE(save_weapons, e)
1783 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1784 #define POSTGIVE_WEAPON(e,b,snd_incr,snd_decr) GiveSound((e), WEPSET_CONTAINS_AW(save_weapons, b), WEPSET_CONTAINS_EW(e, b), 0, snd_incr, snd_decr)
1785 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1786 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1787 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1788
1789 float GiveItems(entity e, float beginarg, float endarg)
1790 {
1791         float got, i, j, val, op;
1792         float _switchweapon;
1793         entity wi;
1794         string cmd;
1795
1796         val = 999;
1797         op = OP_SET;
1798
1799         got = 0;
1800
1801         _switchweapon = FALSE;
1802         if (e.autoswitch)
1803                 if (e.switchweapon == w_getbestweapon(e))
1804                         _switchweapon = TRUE;
1805
1806         e.strength_finished = max(0, e.strength_finished - time);
1807         e.invincible_finished = max(0, e.invincible_finished - time);
1808         e.superweapons_finished = max(0, e.superweapons_finished - time);
1809
1810         PREGIVE(e, items);
1811         PREGIVE_WEAPONS(e);
1812         PREGIVE(e, strength_finished);
1813         PREGIVE(e, invincible_finished);
1814         PREGIVE(e, superweapons_finished);
1815         PREGIVE(e, ammo_nails);
1816         PREGIVE(e, ammo_cells);
1817         PREGIVE(e, ammo_shells);
1818         PREGIVE(e, ammo_rockets);
1819         PREGIVE(e, ammo_fuel);
1820         PREGIVE(e, armorvalue);
1821         PREGIVE(e, health);
1822
1823         for(i = beginarg; i < endarg; ++i)
1824         {
1825                 cmd = argv(i);
1826
1827                 if(cmd == "0" || stof(cmd))
1828                 {
1829                         val = stof(cmd);
1830                         continue;
1831                 }
1832                 switch(cmd)
1833                 {
1834                         case "no":
1835                                 op = OP_MAX;
1836                                 val = 0;
1837                                 continue;
1838                         case "max":
1839                                 op = OP_MAX;
1840                                 continue;
1841                         case "min":
1842                                 op = OP_MIN;
1843                                 continue;
1844                         case "plus":
1845                                 op = OP_PLUS;
1846                                 continue;
1847                         case "minus":
1848                                 op = OP_MINUS;
1849                                 continue;
1850                         case "ALL":
1851                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1852                                 got += GiveValue(e, strength_finished, op, val);
1853                                 got += GiveValue(e, invincible_finished, op, val);
1854                                 got += GiveValue(e, superweapons_finished, op, val);
1855                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1856                         case "all":
1857                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1858                                 got += GiveValue(e, health, op, val);
1859                                 got += GiveValue(e, armorvalue, op, val);
1860                         case "allweapons":
1861                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1862                                 {
1863                                         wi = get_weaponinfo(j);
1864                                         if(wi.weapon)
1865                                                 if not(wi.spawnflags & WEP_FLAG_MUTATORBLOCKED)
1866                                                         got += GiveWeapon(e, j, op, val);
1867                                 }
1868                         case "allammo":
1869                                 got += GiveValue(e, ammo_cells, op, val);
1870                                 got += GiveValue(e, ammo_shells, op, val);
1871                                 got += GiveValue(e, ammo_nails, op, val);
1872                                 got += GiveValue(e, ammo_rockets, op, val);
1873                                 got += GiveValue(e, ammo_fuel, op, val);
1874                                 break;
1875                         case "unlimited_ammo":
1876                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1877                                 break;
1878                         case "unlimited_weapon_ammo":
1879                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1880                                 break;
1881                         case "unlimited_superweapons":
1882                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1883                                 break;
1884                         case "jetpack":
1885                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1886                                 break;
1887                         case "fuel_regen":
1888                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1889                                 break;
1890                         case "strength":
1891                                 got += GiveValue(e, strength_finished, op, val);
1892                                 break;
1893                         case "invincible":
1894                                 got += GiveValue(e, invincible_finished, op, val);
1895                                 break;
1896                         case "superweapons":
1897                                 got += GiveValue(e, superweapons_finished, op, val);
1898                                 break;
1899                         case "cells":
1900                                 got += GiveValue(e, ammo_cells, op, val);
1901                                 break;
1902                         case "shells":
1903                                 got += GiveValue(e, ammo_shells, op, val);
1904                                 break;
1905                         case "nails":
1906                         case "bullets":
1907                                 got += GiveValue(e, ammo_nails, op, val);
1908                                 break;
1909                         case "rockets":
1910                                 got += GiveValue(e, ammo_rockets, op, val);
1911                                 break;
1912                         case "health":
1913                                 got += GiveValue(e, health, op, val);
1914                                 break;
1915                         case "armor":
1916                                 got += GiveValue(e, armorvalue, op, val);
1917                                 break;
1918                         case "fuel":
1919                                 got += GiveValue(e, ammo_fuel, op, val);
1920                                 break;
1921                         default:
1922                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1923                                 {
1924                                         wi = get_weaponinfo(j);
1925                                         if(cmd == wi.netname)
1926                                         {
1927                                                 got += GiveWeapon(e, j, op, val);
1928                                                 break;
1929                                         }
1930                                 }
1931                                 if(j > WEP_LAST)
1932                                         print("give: invalid item ", cmd, "\n");
1933                                 break;
1934                 }
1935                 val = 999;
1936                 op = OP_SET;
1937         }
1938
1939         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1940         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1941         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1942         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1943         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1944         {
1945                 wi = get_weaponinfo(j);
1946                 if(wi.weapon)
1947                 {
1948                         POSTGIVE_WEAPON(e, j, "weapons/weaponpickup.wav", string_null);
1949                         if not(WEPSET_CONTAINS_AW(save_weapons, j))
1950                                 if(WEPSET_CONTAINS_EW(e, j))
1951                                         weapon_action(wi.weapon, WR_PRECACHE);
1952                 }
1953         }
1954         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1955         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1956         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1957         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1958         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1959         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1960         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
1961         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
1962         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
1963
1964         if(e.superweapons_finished <= 0)
1965                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1966                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1967
1968         if(e.strength_finished <= 0)
1969                 e.strength_finished = 0;
1970         else
1971                 e.strength_finished += time;
1972         if(e.invincible_finished <= 0)
1973                 e.invincible_finished = 0;
1974         else
1975                 e.invincible_finished += time;
1976         if(e.superweapons_finished <= 0)
1977                 e.superweapons_finished = 0;
1978         else
1979                 e.superweapons_finished += time;
1980
1981         if not(WEPSET_CONTAINS_EW(e, e.switchweapon))
1982                 _switchweapon = TRUE;
1983         if(_switchweapon)
1984                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1985
1986         return got;
1987 }
1988 #endif