]> de.git.xonotic.org Git - xonotic/xonotic-data.pk3dir.git/blob - qcsrc/server/t_items.qc
Merge branch 'master' into Mario/monsters
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / t_items.qc
1 #define ISF_LOCATION 2
2 #define ISF_MODEL    4
3 #define ISF_STATUS   8
4     #define ITS_STAYWEP   1
5     #define ITS_ANIMATE1  2
6     #define ITS_ANIMATE2  4
7     #define ITS_AVAILABLE 8
8     #define ITS_ALLOWFB   16
9     #define ITS_ALLOWSI   32
10     #define ITS_POWERUP   64
11 #define ISF_COLORMAP 16
12 #define ISF_DROP 32
13 #define ISF_ANGLES 64
14
15 .float ItemStatus;
16
17 #ifdef CSQC
18
19 var float  autocvar_cl_animate_items = 1;
20 var float  autocvar_cl_ghost_items = 0.45;
21 var vector autocvar_cl_ghost_items_color = '-1 -1 -1';
22 var float  autocvar_cl_fullbright_items = 0;
23 var vector autocvar_cl_weapon_stay_color = '2 0.5 0.5';
24 var float  autocvar_cl_weapon_stay_alpha = 0.75;
25 var float  autocvar_cl_simple_items = 0;
26 var string autocvr_cl_simpleitems_postfix = "_simple";
27 .float  spawntime;
28 .float  gravity;
29 .vector colormod;
30 void ItemDraw()
31 {    
32     if(self.gravity)
33     {        
34         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
35         if(self.move_flags & FL_ONGROUND) 
36         { // For some reason move_avelocity gets set to '0 0 0' here ...
37             self.oldorigin = self.origin;
38             self.gravity = 0;
39
40             if(autocvar_cl_animate_items)   
41             { // ... so reset it if animations are requested. 
42                 if(self.ItemStatus & ITS_ANIMATE1)
43                     self.move_avelocity = '0 180 0';
44                 
45                 if(self.ItemStatus & ITS_ANIMATE2)
46                     self.move_avelocity = '0 -90 0';
47             }
48         }
49     }
50     else if (autocvar_cl_animate_items)
51     {        
52         if(self.ItemStatus & ITS_ANIMATE1)
53         {
54             self.angles += self.move_avelocity * frametime;
55             setorigin(self, '0 0 10' + self.oldorigin + '0 0 8' * sin(time * 2));        
56         }    
57         
58         if(self.ItemStatus & ITS_ANIMATE2)
59         {
60             self.angles += self.move_avelocity * frametime;
61             setorigin(self, '0 0 8' + self.oldorigin + '0 0 4' * sin(time * 3));        
62         }
63     }
64 }
65
66 void ItemDrawSimple()
67 {
68     if(self.gravity)
69     {        
70         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);    
71         
72         if(self.move_flags & FL_ONGROUND)
73             self.gravity = 0;
74     }
75 }
76
77 void ItemRead(float _IsNew)
78 {
79     float sf = ReadByte();
80
81     if(sf & ISF_LOCATION)
82     {
83         self.origin_x = ReadCoord();
84         self.origin_y = ReadCoord();
85         self.origin_z = ReadCoord();
86         setorigin(self, self.origin);
87         self.oldorigin = self.origin;
88     }
89     
90     if(sf & ISF_ANGLES) 
91     {
92         self.angles_x = ReadCoord();
93         self.angles_y = ReadCoord();
94         self.angles_z = ReadCoord();        
95         self.move_angles = self.angles;
96     }
97     
98     if(sf & ISF_STATUS) // need to read/write status frist so model can handle simple, fb etc.
99     {
100         self.ItemStatus = ReadByte();    
101         
102         if(self.ItemStatus & ITS_AVAILABLE)
103         {
104             self.alpha = 1;
105             self.colormod = self.glowmod = '1 1 1';
106         }
107         else
108         {
109             if (autocvar_cl_ghost_items_color)
110             {
111                 self.alpha = autocvar_cl_ghost_items;
112                 self.colormod = self.glowmod = autocvar_cl_ghost_items_color;
113             }
114             else
115                 self.alpha = -1;
116         }    
117         
118         if(autocvar_cl_fullbright_items)
119             if(self.ItemStatus & ITS_ALLOWFB)
120                 self.effects |= EF_FULLBRIGHT;
121             
122         if(self.ItemStatus & ITS_STAYWEP)
123         {
124             self.colormod = self.glowmod = autocvar_cl_weapon_stay_color;
125             self.alpha = autocvar_cl_weapon_stay_alpha;
126             
127         }
128         
129         if(self.ItemStatus & ITS_POWERUP)
130         {
131             if(self.ItemStatus & ITS_AVAILABLE)
132                 self.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
133             else
134                  self.effects &~= (EF_ADDITIVE | EF_FULLBRIGHT);
135         }
136     }
137     
138     if(sf & ISF_MODEL)
139     {
140         self.drawmask  = MASK_NORMAL;
141         self.movetype  = MOVETYPE_NOCLIP;
142         self.draw       = ItemDraw;
143         
144         if(self.mdl)
145             strunzone(self.mdl);
146         
147         self.mdl = "";
148         string _fn = ReadString();
149         
150         if(autocvar_cl_simple_items && (self.ItemStatus & ITS_ALLOWSI))
151         {
152             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
153             self.draw = ItemDrawSimple;
154                     
155             
156             
157             if(fexists(sprintf("%s%s.md3", _fn2, autocvr_cl_simpleitems_postfix)))
158                 self.mdl = strzone(sprintf("%s%s.md3", _fn2, autocvr_cl_simpleitems_postfix));
159             else if(fexists(sprintf("%s%s.dpm", _fn2, autocvr_cl_simpleitems_postfix)))
160                 self.mdl = strzone(sprintf("%s%s.dpm", _fn2, autocvr_cl_simpleitems_postfix));
161             else if(fexists(sprintf("%s%s.iqm", _fn2, autocvr_cl_simpleitems_postfix)))
162                 self.mdl = strzone(sprintf("%s%s.iqm", _fn2, autocvr_cl_simpleitems_postfix));
163             else if(fexists(sprintf("%s%s.obj", _fn2, autocvr_cl_simpleitems_postfix)))
164                 self.mdl = strzone(sprintf("%s%s.obj", _fn2, autocvr_cl_simpleitems_postfix));
165             else
166             {
167                 self.draw = ItemDraw;
168                 dprint("Simple item requested for ", _fn, " but no model exsist for it\n");
169             }
170         }
171         
172         if(self.draw != ItemDrawSimple)        
173             self.mdl = strzone(_fn);                
174         
175         
176         if(self.mdl == "")
177             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, " tell tZork aboute this!\n");
178         
179         precache_model(self.mdl);
180         setmodel(self, self.mdl);
181     }
182     
183     if(sf & ISF_COLORMAP)
184         self.colormap = ReadShort();
185     
186     if(sf & ISF_DROP)
187     {
188         self.gravity = 1;
189         self.move_angles = '0 0 0';
190         self.move_movetype = MOVETYPE_TOSS;
191         self.move_velocity_x = ReadCoord();
192         self.move_velocity_y = ReadCoord();
193         self.move_velocity_z = ReadCoord();
194         self.velocity = self.move_velocity;
195         self.move_origin = self.oldorigin;
196         
197         if(!self.move_time)
198         {
199             self.move_time = time;
200             self.spawntime = time;
201         }
202         else
203             self.move_time = max(self.move_time, time);
204     }
205         
206     if(autocvar_cl_animate_items)
207     {        
208         if(self.ItemStatus & ITS_ANIMATE1)
209             self.move_avelocity = '0 180 0';
210                 
211         if(self.ItemStatus & ITS_ANIMATE2)
212             self.move_avelocity = '0 -90 0';
213     }
214 }
215
216 #endif
217
218 #ifdef SVQC
219 float autocvar_sv_simple_items;
220 float ItemSend(entity to, float sf)
221 {
222     if(self.gravity)
223         sf |= ISF_DROP;
224     else
225         sf &~= ISF_DROP;
226         
227         WriteByte(MSG_ENTITY, ENT_CLIENT_ITEM); 
228         WriteByte(MSG_ENTITY, sf);
229
230         //WriteByte(MSG_ENTITY, self.cnt);
231     if(sf & ISF_LOCATION)
232     {
233         WriteCoord(MSG_ENTITY, self.origin_x);
234         WriteCoord(MSG_ENTITY, self.origin_y);
235         WriteCoord(MSG_ENTITY, self.origin_z);
236     }
237     
238     if(sf & ISF_ANGLES)
239     {
240         WriteCoord(MSG_ENTITY, self.angles_x);
241         WriteCoord(MSG_ENTITY, self.angles_y);
242         WriteCoord(MSG_ENTITY, self.angles_z);
243     }
244
245     if(sf & ISF_STATUS)
246         WriteByte(MSG_ENTITY, self.ItemStatus);
247
248     if(sf & ISF_MODEL)
249     {
250         
251         if(self.mdl == "")
252             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, "exspect a crash just aboute now\n");
253         
254         WriteString(MSG_ENTITY, self.mdl);
255     }
256         
257         
258     if(sf & ISF_COLORMAP)
259         WriteShort(MSG_ENTITY, self.colormap);
260
261     if(sf & ISF_DROP)
262     {
263         WriteCoord(MSG_ENTITY, self.velocity_x);
264         WriteCoord(MSG_ENTITY, self.velocity_y);
265         WriteCoord(MSG_ENTITY, self.velocity_z);
266     }
267         
268     return TRUE;
269 }
270
271
272 float have_pickup_item(void)
273 {
274         if(self.flags & FL_POWERUP)
275         {
276                 if(autocvar_g_powerups > 0)
277                         return TRUE;
278                 if(autocvar_g_powerups == 0)
279                         return FALSE;
280                 if(g_ca)
281                         return FALSE;
282                 if(g_arena)
283                         return FALSE;
284         }
285         else
286         {
287                 if(autocvar_g_pickup_items > 0)
288                         return TRUE;
289                 if(autocvar_g_pickup_items == 0)
290                         return FALSE;
291                 if(g_ca)
292                         return FALSE;
293                 if(g_weaponarena)
294                         if(!WEPSET_EMPTY_E(self) || (self.items & IT_AMMO))
295                                 return FALSE;
296         }
297         return TRUE;
298 }
299
300 #define ITEM_RESPAWN_TICKS 10
301
302 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
303         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
304 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
305         // range: 10 .. respawntime + respawntimejitter
306
307 floatfield Item_CounterField(float it)
308 {
309         switch(it)
310         {
311                 case IT_SHELLS:      return ammo_shells;
312                 case IT_NAILS:       return ammo_nails;
313                 case IT_ROCKETS:     return ammo_rockets;
314                 case IT_CELLS:       return ammo_cells;
315                 case IT_FUEL:        return ammo_fuel;
316                 case IT_5HP:         return health;
317                 case IT_25HP:        return health;
318                 case IT_HEALTH:      return health;
319                 case IT_ARMOR_SHARD: return armorvalue;
320                 case IT_ARMOR:       return armorvalue;
321                 // add more things here (health, armor)
322                 default:             error("requested item has no counter field");
323         }
324 #ifdef GMQCC
325         // should never happen
326         return health;
327 #endif
328 }
329
330 string Item_CounterFieldName(float it)
331 {
332         switch(it)
333         {
334                 case IT_SHELLS:      return "shells";
335                 case IT_NAILS:       return "nails";
336                 case IT_ROCKETS:     return "rockets";
337                 case IT_CELLS:       return "cells";
338                 case IT_FUEL:        return "fuel";
339
340                 // add more things here (health, armor)
341                 default:             error("requested item has no counter field name");
342         }
343 #ifdef GMQCC
344         // should never happen
345         return string_null;
346 #endif
347 }
348
349 .float max_armorvalue;
350 .float pickup_anyway;
351 /*
352 float Item_Customize()
353 {
354         if(self.spawnshieldtime)
355                 return TRUE;
356         if(!WEPSET_CONTAINS_ALL_EE(other, self))
357         {
358                 self.colormod = '0 0 0';
359                 self.glowmod = self.colormod;
360                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
361                 return TRUE;
362         }
363         else
364         {
365                 if(g_ghost_items)
366                 {
367                         self.colormod = stov(autocvar_g_ghost_items_color);
368                         self.glowmod = self.colormod;
369                         self.alpha = g_ghost_items;
370                         return TRUE;
371                 }
372                 else
373                         return FALSE;
374         }
375 }
376 */
377
378 void Item_Show (entity e, float mode)
379 {    
380         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
381         e.ItemStatus &~= ITS_STAYWEP;
382         if (mode > 0)
383         {
384                 // make the item look normal, and be touchable
385                 e.model = e.mdl;
386                 e.solid = SOLID_TRIGGER;
387                 e.spawnshieldtime = 1;
388                 e.ItemStatus |= ITS_AVAILABLE;
389         }
390         else if (mode < 0)
391         {
392                 // hide the item completely
393                 e.model = string_null;
394                 e.solid = SOLID_NOT;
395                 e.spawnshieldtime = 1;
396                 e.ItemStatus &~= ITS_AVAILABLE;
397         }
398         else if((e.flags & FL_WEAPON) && !(e.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
399         {
400                 // make the item translucent and not touchable
401                 e.model = e.mdl;
402                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
403                 e.effects |= EF_STARDUST;
404                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
405                 e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
406         }
407         else
408         {
409                 //setmodel(e, "null");
410                 e.solid = SOLID_NOT;
411                 e.colormod = '0 0 0';
412                 e.glowmod = e.colormod;
413                 e.spawnshieldtime = 1;
414                 e.ItemStatus &~= ITS_AVAILABLE;
415         }
416         
417         if (e.items & IT_STRENGTH || e.items & IT_INVINCIBLE)
418             e.ItemStatus |= ITS_POWERUP;                
419         
420         if (autocvar_g_nodepthtestitems)
421                 e.effects |= EF_NODEPTHTEST;
422                 
423     
424     if (autocvar_g_fullbrightitems)
425                 e.ItemStatus |= ITS_ALLOWFB;
426         
427         if (autocvar_sv_simple_items)
428         e.ItemStatus |= ITS_ALLOWSI;
429
430         // relink entity (because solid may have changed)
431         setorigin(e, e.origin);
432     e.SendFlags |= ISF_STATUS;
433 }
434
435 void Item_Respawn (void)
436 {
437         Item_Show(self, 1);
438         // this is ugly...
439         if(self.items == IT_STRENGTH)
440                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
441         else if(self.items == IT_INVINCIBLE)
442                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
443         else
444                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);  // play respawn sound
445         setorigin (self, self.origin);
446
447         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
448         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
449 }
450
451 void Item_RespawnCountdown (void)
452 {
453         if(self.count >= ITEM_RESPAWN_TICKS)
454         {
455                 if(self.waypointsprite_attached)
456                         WaypointSprite_Kill(self.waypointsprite_attached);
457                 Item_Respawn();
458         }
459         else
460         {
461                 self.nextthink = time + 1;
462                 self.count += 1;
463                 if(self.count == 1)
464                 {
465                         string name;
466                         vector rgb = '1 0 1';
467                         name = string_null;
468                         switch(self.items)
469                         {
470                                 case IT_FUEL_REGEN: name = "item-fuelregen"; rgb = '1 0.5 0'; break;
471                                 case IT_JETPACK:    name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
472                                 case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
473                                 case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
474                         }
475                         item_name = name;
476                         item_color = rgb;
477                         MUTATOR_CALLHOOK(Item_RespawnCountdown);
478                         name = item_name;
479                         rgb = item_color;
480                         if(self.flags & FL_WEAPON)
481                         {
482                                 entity wi = get_weaponinfo(self.weapon);
483                                 if(wi)
484                                 {
485                                         name = wi.model2;
486                                         rgb = '1 0 0';
487                                 }
488                         }
489                         if(name)
490                         {
491                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
492                                 if(self.waypointsprite_attached)
493                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
494                         }
495                         else
496                         {
497                                 print("Unknown powerup-marked item is wanting to respawn\n");
498                                 localcmd(sprintf("prvm_edict server %d\n", num_for_edict(self)));
499                         }
500                 }
501                 sound (self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM); // play respawn sound
502                 if(self.waypointsprite_attached)
503                 {
504                         WaypointSprite_Ping(self.waypointsprite_attached);
505                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
506                 }
507         }
508 }
509
510 void Item_ScheduleRespawnIn(entity e, float t)
511 {
512         if((e.flags & FL_POWERUP) || WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
513         {
514                 e.think = Item_RespawnCountdown;
515                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
516                 e.count = 0;
517         }
518         else
519         {
520                 e.think = Item_Respawn;
521                 e.nextthink = time + t;
522         }
523 }
524
525 void Item_ScheduleRespawn(entity e)
526 {
527         if(e.respawntime > 0)
528         {
529                 Item_Show(e, 0);
530                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
531         }
532         else // if respawntime is -1, this item does not respawn
533                 Item_Show(e, -1);
534 }
535
536 void Item_ScheduleInitialRespawn(entity e)
537 {
538         Item_Show(e, 0);
539         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
540 }
541
542 float ITEM_MODE_NONE = 0;
543 float ITEM_MODE_HEALTH = 1;
544 float ITEM_MODE_ARMOR = 2;
545 float ITEM_MODE_FUEL = 3;
546 float Item_GiveAmmoTo(entity item, entity player, .float ammofield, float ammomax, float mode)
547 {
548         if (!item.ammofield)
549                 return FALSE;
550
551         if (item.spawnshieldtime)
552         {
553                 if ((player.ammofield < ammomax) || item.pickup_anyway)
554                 {
555                         player.ammofield = bound(player.ammofield, ammomax, player.ammofield + item.ammofield);
556                         goto YEAH;
557                 }
558         }
559         else if(g_weapon_stay == 2)
560         {
561                 float mi = min(item.ammofield, ammomax);
562                 if (player.ammofield < mi)
563                 {
564                         player.ammofield = mi;
565                         goto YEAH;
566                 }
567         }
568
569         return FALSE;
570
571 :YEAH
572         switch(mode)
573         {
574                 case ITEM_MODE_FUEL:
575                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
576                         break;
577                 case ITEM_MODE_HEALTH:
578                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
579                         break;
580                 case ITEM_MODE_ARMOR:
581                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
582                         break;
583                 default:
584                         break;
585         }
586         return TRUE;
587 }
588
589 float Item_GiveTo(entity item, entity player)
590 {
591         float _switchweapon;
592         float pickedup;
593         float it;
594         float i;
595
596         // if nothing happens to player, just return without taking the item
597         pickedup = FALSE;
598         _switchweapon = FALSE;
599         // in case the player has autoswitch enabled do the following:
600         // if the player is using their best weapon before items are given, they
601         // probably want to switch to an even better weapon after items are given
602         if (player.autoswitch)
603         if (player.switchweapon == w_getbestweapon(player))
604                 _switchweapon = TRUE;
605
606         if not(WEPSET_CONTAINS_EW(player, player.switchweapon))
607                 _switchweapon = TRUE;
608
609         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
610         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
611         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
612         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
613         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
614         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
615         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
616
617         if (item.flags & FL_WEAPON)
618         {
619                 WEPSET_DECLARE_A(it);
620                 WEPSET_COPY_AE(it, item);
621                 WEPSET_ANDNOT_AE(it, player);
622
623                 if (!WEPSET_EMPTY_A(it) || (item.spawnshieldtime && item.pickup_anyway))
624                 {
625                         pickedup = TRUE;
626                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
627                         if(WEPSET_CONTAINS_AW(it, i))
628                                 W_GiveWeapon(player, i);
629                 }
630         }
631
632         if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
633         {
634                 pickedup = TRUE;
635                 player.items |= it;
636                 sprint (player, strcat("You got the ^2", item.netname, "\n"));
637         }
638
639         if (item.strength_finished)
640         {
641                 pickedup = TRUE;
642                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
643         }
644         if (item.invincible_finished)
645         {
646                 pickedup = TRUE;
647                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
648         }
649         if (item.superweapons_finished)
650         {
651                 pickedup = TRUE;
652                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
653         }
654         if (item.max_health)
655         {
656                 pickedup = TRUE;
657                 // extra life powerup handled by mutators
658         }
659
660 :skip
661         
662         // always eat teamed entities
663         if(item.team)
664                 pickedup = TRUE;
665
666         if (!pickedup)
667                 return 0;
668
669         if (_switchweapon)
670                 if (player.switchweapon != w_getbestweapon(player))
671                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
672
673         return 1;
674 }
675
676 void Item_Touch (void)
677 {
678         entity e, head;
679         
680         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
681         if(self.classname == "droppedweapon")
682         {
683                 if (ITEM_TOUCH_NEEDKILL())
684                 {
685                         remove(self);
686                         return;
687                 }
688         }
689
690         if not(IS_PLAYER(other))
691                 return;
692         if (other.frozen)
693                 return;
694         if (other.deadflag)
695                 return;
696         if (self.solid != SOLID_TRIGGER)
697                 return;
698         if (self.owner == other)
699                 return;
700         if(MUTATOR_CALLHOOK(ItemTouch))
701                 return;
702
703         if (self.classname == "droppedweapon")
704         {
705                 self.strength_finished = max(0, self.strength_finished - time);
706                 self.invincible_finished = max(0, self.invincible_finished - time);
707                 self.superweapons_finished = max(0, self.superweapons_finished - time);
708         }
709
710         if(!Item_GiveTo(self, other))
711         {
712                 if (self.classname == "droppedweapon")
713                 {
714                         // undo what we did above
715                         self.strength_finished += time;
716                         self.invincible_finished += time;
717                         self.superweapons_finished += time;
718                 }
719                 return;
720         }
721
722         other.last_pickup = time;
723
724         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
725         sound (other, CH_TRIGGER, self.item_pickupsound, VOL_BASE, ATTN_NORM);
726
727         if (self.classname == "droppedweapon")
728                 remove (self);
729         else if not(self.spawnshieldtime)
730                 return;
731         else
732         {
733                 if(self.team)
734                 {
735                         RandomSelection_Init();
736                         for(head = world; (head = findfloat(head, team, self.team)); )
737                         {
738                                 if(head.flags & FL_ITEM)
739                                 {
740                                         Item_Show(head, -1);
741                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
742                                 }
743                         }
744                         e = RandomSelection_chosen_ent;
745
746                 }
747                 else
748                         e = self;
749                 Item_ScheduleRespawn(e);
750         }
751 }
752
753 void Item_Reset()
754 {
755         Item_Show(self, !self.state);
756         setorigin (self, self.origin);
757
758         if(self.classname != "droppedweapon")
759         {
760                 self.think = func_null;
761                 self.nextthink = 0;
762
763                 if(self.waypointsprite_attached)
764                         WaypointSprite_Kill(self.waypointsprite_attached);
765
766                 if((self.flags & FL_POWERUP) | WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // do not spawn powerups initially!
767                         Item_ScheduleInitialRespawn(self);
768         }
769 }
770
771 void Item_FindTeam()
772 {
773         entity head, e;
774
775         if(self.effects & EF_NODRAW)
776         {
777                 // marker for item team search
778                 dprint("Initializing item team ", ftos(self.team), "\n");
779                 RandomSelection_Init();
780                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
781                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
782                 e = RandomSelection_chosen_ent;
783                 e.state = 0;
784                 Item_Show(e, 1);
785
786                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
787                 {
788                         if(head != e)
789                         {
790                                 // make it a non-spawned item
791                                 Item_Show(head, -1);
792                                 head.state = 1; // state 1 = initially hidden item
793                         }
794                         head.effects &~= EF_NODRAW;
795                 }
796
797                 Item_Reset();
798         }
799 }
800
801 // Savage: used for item garbage-collection
802 // TODO: perhaps nice special effect?
803 void RemoveItem(void)
804 {
805         remove(self);
806 }
807
808 // pickup evaluation functions
809 // these functions decide how desirable an item is to the bots
810
811 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
812
813 float weapon_pickupevalfunc(entity player, entity item)
814 {
815         float c, j, position;
816
817         // See if I have it already
818         if(!WEPSET_CONTAINS_ALL_EE(player, item))
819         {
820                 // If I can pick it up
821                 if(!item.spawnshieldtime)
822                         c = 0;
823                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
824                 {
825                         // Skilled bots will grab more
826                         c = bound(0, skill / 10, 1) * 0.5;
827                 }
828                 else
829                         c = 0;
830         }
831         else
832                 c = 1;
833
834         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
835         if( bot_custom_weapon && c )
836         {
837                 // Find the highest position on any range
838                 position = -1;
839                 for(j = 0; j < WEP_LAST ; ++j){
840                         if(
841                                         bot_weapons_far[j] == item.weapon ||
842                                         bot_weapons_mid[j] == item.weapon ||
843                                         bot_weapons_close[j] == item.weapon
844                           )
845                         {
846                                 position = j;
847                                 break;
848                         }
849                 }
850
851                 // Rate it
852                 if (position >= 0 )
853                 {
854                         position = WEP_LAST - position;
855                         // item.bot_pickupbasevalue is overwritten here
856                         return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
857                 }
858         }
859
860         return item.bot_pickupbasevalue * c;
861 }
862
863 float commodity_pickupevalfunc(entity player, entity item)
864 {
865         float c, i;
866         float need_shells = FALSE, need_nails = FALSE, need_rockets = FALSE, need_cells = FALSE, need_fuel = FALSE;
867         entity wi;
868         c = 0;
869
870         // Detect needed ammo
871         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
872         {
873                 wi = get_weaponinfo(i);
874
875                 if not(WEPSET_CONTAINS_EW(player, i))
876                         continue;
877
878                 if(wi.items & IT_SHELLS)
879                         need_shells = TRUE;
880                 else if(wi.items & IT_NAILS)
881                         need_nails = TRUE;
882                 else if(wi.items & IT_ROCKETS)
883                         need_rockets = TRUE;
884                 else if(wi.items & IT_CELLS)
885                         need_cells = TRUE;
886                 else if(wi.items & IT_FUEL)
887                         need_cells = TRUE;
888         }
889
890         // TODO: figure out if the player even has the weapon this ammo is for?
891         // may not affect strategy much though...
892         // find out how much more ammo/armor/health the player can hold
893         if (need_shells)
894         if (item.ammo_shells)
895         if (player.ammo_shells < g_pickup_shells_max)
896                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
897         if (need_nails)
898         if (item.ammo_nails)
899         if (player.ammo_nails < g_pickup_nails_max)
900                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
901         if (need_rockets)
902         if (item.ammo_rockets)
903         if (player.ammo_rockets < g_pickup_rockets_max)
904                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
905         if (need_cells)
906         if (item.ammo_cells)
907         if (player.ammo_cells < g_pickup_cells_max)
908                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
909         if (need_fuel)
910         if (item.ammo_fuel)
911         if (player.ammo_fuel < g_pickup_fuel_max)
912                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
913         if (item.armorvalue)
914         if (player.armorvalue < item.max_armorvalue)
915                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
916         if (item.health)
917         if (player.health < item.max_health)
918                 c = c + max(0, 1 - player.health / item.max_health);
919
920         return item.bot_pickupbasevalue * c;
921 }
922
923 void Item_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
924 {
925         if(ITEM_DAMAGE_NEEDKILL(deathtype))
926                 RemoveItem();
927 }
928
929 .float is_item;
930 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
931 {
932         startitem_failed = FALSE;
933
934         if(self.model == "")
935                 self.model = itemmodel;
936         
937         if(self.model == "")
938     {
939         error(strcat("^1Tried to spawn ", itemname, " with no model!\n"));
940         return;
941     }
942         
943         if(self.item_pickupsound == "")
944                 self.item_pickupsound = pickupsound;
945         
946         if(!self.respawntime) // both need to be set
947         {
948                 self.respawntime = defaultrespawntime;
949                 self.respawntimejitter = defaultrespawntimejitter;
950         }
951
952         self.items = itemid;
953         self.weapon = weaponid;
954
955         if(weaponid)
956                 WEPSET_COPY_EW(self, weaponid);
957         
958         self.flags = FL_ITEM | itemflags;
959
960         if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
961         {
962                 startitem_failed = TRUE;
963                 remove(self);
964                 return;
965         }
966
967         // is it a dropped weapon?
968         if (self.classname == "droppedweapon")
969         {
970                 self.reset = SUB_Remove;
971                 // it's a dropped weapon
972                 self.movetype = MOVETYPE_TOSS;
973
974                 // Savage: remove thrown items after a certain period of time ("garbage collection")
975                 self.think = RemoveItem;
976                 self.nextthink = time + 20;
977
978                 self.takedamage = DAMAGE_YES;
979                 self.event_damage = Item_Damage;
980
981                 if(self.strength_finished || self.invincible_finished || self.superweapons_finished)
982                 /*
983                 if(self.items == 0)
984                 if(WEPSET_CONTAINS_ALL_AE(WEPBIT_SUPERWEAPONS, self)) // only superweapons
985                 if(self.ammo_nails == 0)
986                 if(self.ammo_cells == 0)
987                 if(self.ammo_rockets == 0)
988                 if(self.ammo_shells == 0)
989                 if(self.ammo_fuel == 0)
990                 if(self.health == 0)
991                 if(self.armorvalue == 0)
992                 */
993                 {
994                         // if item is worthless after a timer, have it expire then
995                         self.nextthink = max(self.strength_finished, self.invincible_finished, self.superweapons_finished);
996                 }
997
998                 // don't drop if in a NODROP zone (such as lava)
999                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
1000                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1001                 {
1002                         startitem_failed = TRUE;
1003                         remove(self);
1004                         return;
1005                 }
1006         }
1007         else
1008         {
1009                 if(!have_pickup_item())
1010                 {
1011                         startitem_failed = TRUE;
1012                         remove (self);
1013                         return;
1014                 }
1015                 
1016                 if(self.angles != '0 0 0')
1017             self.SendFlags |= ISF_ANGLES;
1018
1019                 self.reset = Item_Reset;
1020                 // it's a level item
1021                 if(self.spawnflags & 1)
1022                         self.noalign = 1;
1023                 if (self.noalign)
1024                         self.movetype = MOVETYPE_NONE;
1025                 else
1026                         self.movetype = MOVETYPE_TOSS;
1027                 // do item filtering according to game mode and other things
1028                 if (!self.noalign)
1029                 {
1030                         // first nudge it off the floor a little bit to avoid math errors
1031                         setorigin(self, self.origin + '0 0 1');
1032                         // set item size before we spawn a spawnfunc_waypoint
1033                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1034                                 setsize (self, '-16 -16 0', '16 16 48');
1035                         else
1036                                 setsize (self, '-16 -16 0', '16 16 32');
1037                         // note droptofloor returns FALSE if stuck/or would fall too far
1038                         droptofloor();
1039                         waypoint_spawnforitem(self);
1040                 }
1041
1042                 /*
1043                  * can't do it that way, as it would break maps
1044                  * TODO make a target_give like entity another way, that perhaps has
1045                  * the weapon name in a key
1046                 if(self.targetname)
1047                 {
1048                         // target_give not yet supported; maybe later
1049                         print("removed targeted ", self.classname, "\n");
1050                         startitem_failed = TRUE;
1051                         remove (self);
1052                         return;
1053                 }
1054                 */
1055
1056                 if(autocvar_spawn_debug >= 2)
1057                 {
1058                         entity otheritem;
1059                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
1060                         {
1061                             // why not flags & fl_item?
1062                                 if(otheritem.is_item)
1063                                 {
1064                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
1065                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
1066                                         error("Mapper sucks.");
1067                                 }
1068                         }
1069                         self.is_item = TRUE;
1070                 }
1071
1072                 WEPSET_OR_AW(weaponsInMap, weaponid);
1073
1074                 precache_model (self.model);
1075                 precache_sound (self.item_pickupsound);
1076
1077                 precache_sound ("misc/itemrespawncountdown.wav");
1078                 if(itemid == IT_STRENGTH)
1079                         precache_sound ("misc/strength_respawn.wav");
1080                 else if(itemid == IT_INVINCIBLE)
1081                         precache_sound ("misc/shield_respawn.wav");
1082                 else
1083                         precache_sound ("misc/itemrespawn.wav");
1084
1085                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
1086                         self.target = "###item###"; // for finding the nearest item using find()
1087         }
1088
1089         self.bot_pickup = TRUE;
1090         self.bot_pickupevalfunc = pickupevalfunc;
1091         self.bot_pickupbasevalue = pickupbasevalue;
1092         self.mdl = self.model;
1093         self.netname = itemname;
1094         self.touch = Item_Touch;
1095         setmodel(self, "null"); // precision set below
1096         //self.effects |= EF_LOWPRECISION; 
1097         
1098         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1099     {
1100         self.pos1 = '-16 -16 0';
1101         self.pos2 = '16 16 48';
1102     }
1103         else
1104     {
1105         self.pos1 = '-16 -16 0';
1106         self.pos2 = '16 16 32';
1107     }
1108     setsize (self, self.pos1, self.pos2);
1109     
1110     if(itemflags & FL_POWERUP) 
1111         self.ItemStatus |= ITS_ANIMATE1;
1112         
1113         if(self.armorvalue || self.health)
1114         self.ItemStatus |= ITS_ANIMATE2;
1115         
1116         if(itemflags & FL_WEAPON)
1117         {
1118                 if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1119             self.colormap = 1024; // color shirt=0 pants=0 grey
1120         else
1121             self.gravity = 1;
1122             
1123                 self.ItemStatus |= ITS_ANIMATE1;
1124                 self.ItemStatus |= ISF_COLORMAP;
1125         }
1126
1127         self.state = 0;
1128         if(self.team) // broken, no idea why.
1129         {
1130                 if(!self.cnt)
1131                         self.cnt = 1; // item probability weight
1132                         
1133                 self.effects |= EF_NODRAW; // marker for item team search
1134                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
1135         }
1136         else
1137                 Item_Reset();
1138         
1139     Net_LinkEntity(self, FALSE, 0, ItemSend);
1140
1141         // call this hook after everything else has been done
1142         if(MUTATOR_CALLHOOK(Item_Spawn))
1143         {
1144                 startitem_failed = TRUE;
1145                 remove(self);
1146                 return;
1147         }
1148 }
1149
1150 float weaponswapping;
1151 float internalteam;
1152
1153 void weapon_defaultspawnfunc(float wpn)
1154 {
1155         entity e;
1156         float t;
1157         var .float ammofield;
1158         string s;
1159         entity oldself;
1160         float i, j;
1161         float f;
1162
1163         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
1164         {
1165                 e = get_weaponinfo(wpn);
1166
1167                 if(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
1168                 {
1169                         print("Attempted to spawn a mutator-blocked weapon; these guns will in the future require a mutator\n");
1170                         /*
1171                         objerror("Attempted to spawn a mutator-blocked weapon rejected");
1172                         startitem_failed = TRUE;
1173                         return;
1174                         */
1175                 }
1176
1177                 s = W_Apply_Weaponreplace(e.netname);
1178                 ret_string = s;
1179                 other = e;
1180                 MUTATOR_CALLHOOK(SetWeaponreplace);
1181                 s = ret_string;
1182                 if(s == "")
1183                 {
1184                         remove(self);
1185                         startitem_failed = TRUE;
1186                         return;
1187                 }
1188                 t = tokenize_console(s);
1189                 if(t >= 2)
1190                 {
1191                         self.team = --internalteam;
1192                         oldself = self;
1193                         for(i = 1; i < t; ++i)
1194                         {
1195                                 s = argv(i);
1196                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1197                                 {
1198                                         e = get_weaponinfo(j);
1199                                         if(e.netname == s)
1200                                         {
1201                                                 self = spawn();
1202                                                 copyentity(oldself, self);
1203                                                 self.classname = "replacedweapon";
1204                                                 weapon_defaultspawnfunc(j);
1205                                                 break;
1206                                         }
1207                                 }
1208                                 if(j > WEP_LAST)
1209                                 {
1210                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1211                                 }
1212                         }
1213                         self = oldself;
1214                 }
1215                 if(t >= 1) // always the case!
1216                 {
1217                         s = argv(0);
1218                         wpn = 0;
1219                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1220                         {
1221                                 e = get_weaponinfo(j);
1222                                 if(e.netname == s)
1223                                 {
1224                                         wpn = j;
1225                                         break;
1226                                 }
1227                         }
1228                         if(j > WEP_LAST)
1229                         {
1230                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1231                         }
1232                 }
1233                 if(wpn == 0)
1234                 {
1235                         remove(self);
1236                         startitem_failed = TRUE;
1237                         return;
1238                 }
1239         }
1240
1241         e = get_weaponinfo(wpn);
1242
1243         if(!self.respawntime)
1244         {
1245                 if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1246                 {
1247                         self.respawntime = g_pickup_respawntime_superweapon;
1248                         self.respawntimejitter = g_pickup_respawntimejitter_superweapon;
1249                 }
1250                 else
1251                 {
1252                         self.respawntime = g_pickup_respawntime_weapon;
1253                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
1254                 }
1255         }
1256
1257         if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1258                 if(!self.superweapons_finished)
1259                         self.superweapons_finished = autocvar_g_balance_superweapons_time;
1260
1261         if(e.items)
1262         {
1263                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1264                 {
1265                         if(e.items & j)
1266                         {
1267                                 ammofield = Item_CounterField(j);
1268                                 if(!self.ammofield)
1269                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j), "_weapon"));
1270                         }
1271                 }
1272         }
1273
1274         // pickup anyway
1275         if(g_pickup_weapons_anyway)
1276                 self.pickup_anyway = TRUE;
1277
1278         f = FL_WEAPON;
1279
1280         // no weapon-stay on superweapons
1281         if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1282                 f |= FL_NO_WEAPON_STAY;
1283
1284         // weapon stay isn't supported for teamed weapons
1285         if(self.team)
1286                 f |= FL_NO_WEAPON_STAY;
1287
1288         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapon, f, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1289         if (self.modelindex) // don't precache if self was removed
1290                 weapon_action(e.weapon, WR_PRECACHE);
1291 }
1292
1293 void spawnfunc_weapon_shotgun (void);
1294 void spawnfunc_weapon_uzi (void) {
1295         if(autocvar_sv_q3acompat_machineshotgunswap)
1296         if(self.classname != "droppedweapon")
1297         {
1298                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1299                 return;
1300         }
1301         weapon_defaultspawnfunc(WEP_UZI);
1302 }
1303
1304 void spawnfunc_weapon_shotgun (void) {
1305         if(autocvar_sv_q3acompat_machineshotgunswap)
1306         if(self.classname != "droppedweapon")
1307         {
1308                 weapon_defaultspawnfunc(WEP_UZI);
1309                 return;
1310         }
1311         weapon_defaultspawnfunc(WEP_SHOTGUN);
1312 }
1313
1314 void spawnfunc_weapon_nex (void)
1315 {
1316         weapon_defaultspawnfunc(WEP_NEX);
1317 }
1318
1319 void spawnfunc_weapon_minstanex (void)
1320 {
1321         weapon_defaultspawnfunc(WEP_MINSTANEX);
1322 }
1323
1324 void spawnfunc_weapon_rocketlauncher (void)
1325 {
1326         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1327 }
1328
1329 void spawnfunc_item_rockets (void) {
1330         if(!self.ammo_rockets)
1331                 self.ammo_rockets = g_pickup_rockets;
1332         if(!self.pickup_anyway)
1333                 self.pickup_anyway = g_pickup_ammo_anyway;
1334         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1335 }
1336
1337 void spawnfunc_item_shells (void);
1338 void spawnfunc_item_bullets (void) {
1339         if(!weaponswapping)
1340         if(autocvar_sv_q3acompat_machineshotgunswap)
1341         if(self.classname != "droppedweapon")
1342         {
1343                 weaponswapping = TRUE;
1344                 spawnfunc_item_shells();
1345                 weaponswapping = FALSE;
1346                 return;
1347         }
1348
1349         if(!self.ammo_nails)
1350                 self.ammo_nails = g_pickup_nails;
1351         if(!self.pickup_anyway)
1352                 self.pickup_anyway = g_pickup_ammo_anyway;
1353         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1354 }
1355
1356 void spawnfunc_item_cells (void) {
1357         if(!self.ammo_cells)
1358                 self.ammo_cells = g_pickup_cells;
1359         if(!self.pickup_anyway)
1360                 self.pickup_anyway = g_pickup_ammo_anyway;
1361         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1362 }
1363
1364 void spawnfunc_item_shells (void) {
1365         if(!weaponswapping)
1366         if(autocvar_sv_q3acompat_machineshotgunswap)
1367         if(self.classname != "droppedweapon")
1368         {
1369                 weaponswapping = TRUE;
1370                 spawnfunc_item_bullets();
1371                 weaponswapping = FALSE;
1372                 return;
1373         }
1374
1375         if(!self.ammo_shells)
1376                 self.ammo_shells = g_pickup_shells;
1377         if(!self.pickup_anyway)
1378                 self.pickup_anyway = g_pickup_ammo_anyway;
1379         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1380 }
1381
1382 void spawnfunc_item_armor_small (void) {
1383         if(!self.armorvalue)
1384                 self.armorvalue = g_pickup_armorsmall;
1385         if(!self.max_armorvalue)
1386                 self.max_armorvalue = g_pickup_armorsmall_max;
1387         if(!self.pickup_anyway)
1388                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1389         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1390 }
1391
1392 void spawnfunc_item_armor_medium (void) {
1393         if(!self.armorvalue)
1394                 self.armorvalue = g_pickup_armormedium;
1395         if(!self.max_armorvalue)
1396                 self.max_armorvalue = g_pickup_armormedium_max;
1397         if(!self.pickup_anyway)
1398                 self.pickup_anyway = g_pickup_armormedium_anyway;
1399         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1400 }
1401
1402 void spawnfunc_item_armor_big (void) {
1403         if(!self.armorvalue)
1404                 self.armorvalue = g_pickup_armorbig;
1405         if(!self.max_armorvalue)
1406                 self.max_armorvalue = g_pickup_armorbig_max;
1407         if(!self.pickup_anyway)
1408                 self.pickup_anyway = g_pickup_armorbig_anyway;
1409         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1410 }
1411
1412 void spawnfunc_item_armor_large (void) {
1413         if(!self.armorvalue)
1414                 self.armorvalue = g_pickup_armorlarge;
1415         if(!self.max_armorvalue)
1416                 self.max_armorvalue = g_pickup_armorlarge_max;
1417         if(!self.pickup_anyway)
1418                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1419         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1420 }
1421
1422 void spawnfunc_item_health_small (void) {
1423         if(!self.max_health)
1424                 self.max_health = g_pickup_healthsmall_max;
1425         if(!self.health)
1426                 self.health = g_pickup_healthsmall;
1427         if(!self.pickup_anyway)
1428                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1429         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1430 }
1431
1432 void spawnfunc_item_health_medium (void) {
1433         if(!self.max_health)
1434                 self.max_health = g_pickup_healthmedium_max;
1435         if(!self.health)
1436                 self.health = g_pickup_healthmedium;
1437         if(!self.pickup_anyway)
1438                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1439         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1440 }
1441
1442 void spawnfunc_item_health_large (void) {
1443         if(!self.max_health)
1444                 self.max_health = g_pickup_healthlarge_max;
1445         if(!self.health)
1446                 self.health = g_pickup_healthlarge;
1447         if(!self.pickup_anyway)
1448                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1449         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1450 }
1451
1452 void spawnfunc_item_health_mega (void) {
1453                 if(!self.max_health)
1454                         self.max_health = g_pickup_healthmega_max;
1455                 if(!self.health)
1456                         self.health = g_pickup_healthmega;
1457                 if(!self.pickup_anyway)
1458                         self.pickup_anyway = g_pickup_healthmega_anyway;
1459                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1460 }
1461
1462 // support old misnamed entities
1463 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1464 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1465 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1466 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1467 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1468
1469 void spawnfunc_item_strength (void) {
1470                 precache_sound("weapons/strength_fire.wav");
1471                 if(!self.strength_finished)
1472                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1473                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1474 }
1475
1476 void spawnfunc_item_invincible (void) {
1477                 if(!self.invincible_finished)
1478                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1479                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1480 }
1481
1482 // compatibility:
1483 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1484
1485 float GiveItems(entity e, float beginarg, float endarg);
1486 void target_items_use (void)
1487 {
1488         if(activator.classname == "droppedweapon")
1489         {
1490                 EXACTTRIGGER_TOUCH;
1491                 remove(activator);
1492                 return;
1493         }
1494
1495         if not(IS_PLAYER(activator))
1496                 return;
1497         if(activator.deadflag != DEAD_NO)
1498                 return;
1499         EXACTTRIGGER_TOUCH;
1500
1501         entity e;
1502         for(e = world; (e = find(e, classname, "droppedweapon")); )
1503                 if(e.enemy == activator)
1504                         remove(e);
1505
1506         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1507                 centerprint(activator, self.message);
1508 }
1509
1510 void spawnfunc_target_items (void)
1511 {
1512         float n, i, j;
1513         entity e;
1514
1515         self.use = target_items_use;
1516         if(!self.strength_finished)
1517                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1518         if(!self.invincible_finished)
1519                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1520         if(!self.superweapons_finished)
1521                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1522
1523         precache_sound("misc/itempickup.wav");
1524         precache_sound("misc/megahealth.wav");
1525         precache_sound("misc/armor25.wav");
1526         precache_sound("misc/powerup.wav");
1527         precache_sound("misc/poweroff.wav");
1528         precache_sound("weapons/weaponpickup.wav");
1529
1530         n = tokenize_console(self.netname);
1531         if(argv(0) == "give")
1532         {
1533                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1534         }
1535         else
1536         {
1537                 for(i = 0; i < n; ++i)
1538                 {
1539                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1540                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1541                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1542                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1543                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1544                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1545                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1546                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1547                         else
1548                         {
1549                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1550                                 {
1551                                         e = get_weaponinfo(j);
1552                                         if(argv(i) == e.netname)
1553                                         {
1554                                                 WEPSET_OR_EW(self, j);
1555                                                 if(self.spawnflags == 0 || self.spawnflags == 2)
1556                                                         weapon_action(e.weapon, WR_PRECACHE);
1557                                                 break;
1558                                         }
1559                                 }
1560                                 if(j > WEP_LAST)
1561                                         print("target_items: invalid item ", argv(i), "\n");
1562                         }
1563                 }
1564
1565                 string itemprefix, valueprefix;
1566                 if(self.spawnflags == 0)
1567                 {
1568                         itemprefix = "";
1569                         valueprefix = "";
1570                 }
1571                 else if(self.spawnflags == 1)
1572                 {
1573                         itemprefix = "max ";
1574                         valueprefix = "max ";
1575                 }
1576                 else if(self.spawnflags == 2)
1577                 {
1578                         itemprefix = "min ";
1579                         valueprefix = "min ";
1580                 }
1581                 else if(self.spawnflags == 4)
1582                 {
1583                         itemprefix = "minus ";
1584                         valueprefix = "max ";
1585                 }
1586                 else
1587                 {
1588                         error("invalid spawnflags");
1589 #ifdef GMQCC
1590                         itemprefix = string_null;
1591                         valueprefix = string_null;
1592 #endif
1593                 }
1594
1595                 self.netname = "";
1596                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1597                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1598                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1599                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1600                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * !!(self.items & IT_SUPERWEAPON), "superweapons");
1601                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1602                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1603                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1604                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1605                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1606                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1607                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1608                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1609                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1610                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1611                 {
1612                         e = get_weaponinfo(j);
1613                         if(e.weapon)
1614                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, WEPSET_CONTAINS_EW(self, j), e.netname);
1615                 }
1616         }
1617         self.netname = strzone(self.netname);
1618         //print(self.netname, "\n");
1619
1620         n = tokenize_console(self.netname);
1621         for(i = 0; i < n; ++i)
1622         {
1623                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1624                 {
1625                         e = get_weaponinfo(j);
1626                         if(argv(i) == e.netname)
1627                         {
1628                                 weapon_action(e.weapon, WR_PRECACHE);
1629                                 break;
1630                         }
1631                 }
1632         }
1633 }
1634
1635 void spawnfunc_item_fuel(void)
1636 {
1637         if(!self.ammo_fuel)
1638                 self.ammo_fuel = g_pickup_fuel;
1639         if(!self.pickup_anyway)
1640                 self.pickup_anyway = g_pickup_ammo_anyway;
1641         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1642 }
1643
1644 void spawnfunc_item_fuel_regen(void)
1645 {
1646         if(start_items & IT_FUEL_REGEN)
1647         {
1648                 spawnfunc_item_fuel();
1649                 return;
1650         }
1651         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1652 }
1653
1654 void spawnfunc_item_jetpack(void)
1655 {
1656         if(g_grappling_hook)
1657                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1658         if(!self.ammo_fuel)
1659                 self.ammo_fuel = g_pickup_fuel_jetpack;
1660         if(start_items & IT_JETPACK)
1661         {
1662                 spawnfunc_item_fuel();
1663                 return;
1664         }
1665         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1666 }
1667
1668
1669 #define OP_SET 0
1670 #define OP_MIN 1
1671 #define OP_MAX 2
1672 #define OP_PLUS 3
1673 #define OP_MINUS 4
1674
1675 float GiveWeapon(entity e, float wpn, float op, float val)
1676 {
1677         float v0, v1;
1678         v0 = WEPSET_CONTAINS_EW(e, wpn);
1679         switch(op)
1680         {
1681                 case OP_SET:
1682                         if(val > 0)
1683                                 WEPSET_OR_EW(e, wpn);
1684                         else
1685                                 WEPSET_ANDNOT_EW(e, wpn);
1686                         break;
1687                 case OP_MIN:
1688                 case OP_PLUS:
1689                         if(val > 0)
1690                                 WEPSET_OR_EW(e, wpn);
1691                         break;
1692                 case OP_MAX:
1693                         if(val <= 0)
1694                                 WEPSET_ANDNOT_EW(e, wpn);
1695                         break;
1696                 case OP_MINUS:
1697                         if(val > 0)
1698                                 WEPSET_ANDNOT_EW(e, wpn);
1699                         break;
1700         }
1701         v1 = WEPSET_CONTAINS_EW(e, wpn);
1702         return (v0 != v1);
1703 }
1704
1705 float GiveBit(entity e, .float fld, float bit, float op, float val)
1706 {
1707         float v0, v1;
1708         v0 = (e.fld & bit);
1709         switch(op)
1710         {
1711                 case OP_SET:
1712                         if(val > 0)
1713                                 e.fld |= bit;
1714                         else
1715                                 e.fld &~= bit;
1716                         break;
1717                 case OP_MIN:
1718                 case OP_PLUS:
1719                         if(val > 0)
1720                                 e.fld |= bit;
1721                         break;
1722                 case OP_MAX:
1723                         if(val <= 0)
1724                                 e.fld &~= bit;
1725                         break;
1726                 case OP_MINUS:
1727                         if(val > 0)
1728                                 e.fld &~= bit;
1729                         break;
1730         }
1731         v1 = (e.fld & bit);
1732         return (v0 != v1);
1733 }
1734
1735 float GiveValue(entity e, .float fld, float op, float val)
1736 {
1737         float v0, v1;
1738         v0 = e.fld;
1739         switch(op)
1740         {
1741                 case OP_SET:
1742                         e.fld = val;
1743                         break;
1744                 case OP_MIN:
1745                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1746                         break;
1747                 case OP_MAX:
1748                         e.fld = min(e.fld, val);
1749                         break;
1750                 case OP_PLUS:
1751                         e.fld += val;
1752                         break;
1753                 case OP_MINUS:
1754                         e.fld -= val;
1755                         break;
1756         }
1757         v1 = e.fld;
1758         return (v0 != v1);
1759 }
1760
1761 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1762 {
1763         if(v1 == v0)
1764                 return;
1765         if(v1 <= v0 - t)
1766         {
1767                 if(snd_decr != "")
1768                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTN_NORM);
1769         }
1770         else if(v0 >= v0 + t)
1771         {
1772                 if(snd_incr != "")
1773                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTN_NORM);
1774         }
1775 }
1776
1777 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1778 {
1779         if(v0 < v1)
1780                 e.rotfield = max(e.rotfield, time + rottime);
1781         else if(v0 > v1)
1782                 e.regenfield = max(e.regenfield, time + regentime);
1783 }
1784
1785 #define PREGIVE_WEAPONS(e) WEPSET_DECLARE_A(save_weapons); WEPSET_COPY_AE(save_weapons, e)
1786 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1787 #define POSTGIVE_WEAPON(e,b,snd_incr,snd_decr) GiveSound((e), WEPSET_CONTAINS_AW(save_weapons, b), WEPSET_CONTAINS_EW(e, b), 0, snd_incr, snd_decr)
1788 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1789 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1790 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1791
1792 float GiveItems(entity e, float beginarg, float endarg)
1793 {
1794         float got, i, j, val, op;
1795         float _switchweapon;
1796         entity wi;
1797         string cmd;
1798
1799         val = 999;
1800         op = OP_SET;
1801
1802         got = 0;
1803
1804         _switchweapon = FALSE;
1805         if (e.autoswitch)
1806                 if (e.switchweapon == w_getbestweapon(e))
1807                         _switchweapon = TRUE;
1808
1809         e.strength_finished = max(0, e.strength_finished - time);
1810         e.invincible_finished = max(0, e.invincible_finished - time);
1811         e.superweapons_finished = max(0, e.superweapons_finished - time);
1812         
1813         PREGIVE(e, items);
1814         PREGIVE_WEAPONS(e);
1815         PREGIVE(e, strength_finished);
1816         PREGIVE(e, invincible_finished);
1817         PREGIVE(e, superweapons_finished);
1818         PREGIVE(e, ammo_nails);
1819         PREGIVE(e, ammo_cells);
1820         PREGIVE(e, ammo_shells);
1821         PREGIVE(e, ammo_rockets);
1822         PREGIVE(e, ammo_fuel);
1823         PREGIVE(e, armorvalue);
1824         PREGIVE(e, health);
1825
1826         for(i = beginarg; i < endarg; ++i)
1827         {
1828                 cmd = argv(i);
1829
1830                 if(cmd == "0" || stof(cmd))
1831                 {
1832                         val = stof(cmd);
1833                         continue;
1834                 }
1835                 switch(cmd)
1836                 {
1837                         case "no":
1838                                 op = OP_MAX;
1839                                 val = 0;
1840                                 continue;
1841                         case "max":
1842                                 op = OP_MAX;
1843                                 continue;
1844                         case "min":
1845                                 op = OP_MIN;
1846                                 continue;
1847                         case "plus":
1848                                 op = OP_PLUS;
1849                                 continue;
1850                         case "minus":
1851                                 op = OP_MINUS;
1852                                 continue;
1853                         case "ALL":
1854                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1855                                 got += GiveValue(e, strength_finished, op, val);
1856                                 got += GiveValue(e, invincible_finished, op, val);
1857                                 got += GiveValue(e, superweapons_finished, op, val);
1858                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1859                         case "all":
1860                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1861                                 got += GiveValue(e, health, op, val);
1862                                 got += GiveValue(e, armorvalue, op, val);
1863                         case "allweapons":
1864                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1865                                 {
1866                                         wi = get_weaponinfo(j);
1867                                         if(wi.weapon)
1868                                                 if not(wi.spawnflags & WEP_FLAG_MUTATORBLOCKED)
1869                                                         got += GiveWeapon(e, j, op, val);
1870                                 }
1871                         case "allammo":
1872                                 got += GiveValue(e, ammo_cells, op, val);
1873                                 got += GiveValue(e, ammo_shells, op, val);
1874                                 got += GiveValue(e, ammo_nails, op, val);
1875                                 got += GiveValue(e, ammo_rockets, op, val);
1876                                 got += GiveValue(e, ammo_fuel, op, val);
1877                                 break;
1878                         case "unlimited_ammo":
1879                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1880                                 break;
1881                         case "unlimited_weapon_ammo":
1882                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1883                                 break;
1884                         case "unlimited_superweapons":
1885                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1886                                 break;
1887                         case "jetpack":
1888                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1889                                 break;
1890                         case "fuel_regen":
1891                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1892                                 break;
1893                         case "strength":
1894                                 got += GiveValue(e, strength_finished, op, val);
1895                                 break;
1896                         case "invincible":
1897                                 got += GiveValue(e, invincible_finished, op, val);
1898                                 break;
1899                         case "superweapons":
1900                                 got += GiveValue(e, superweapons_finished, op, val);
1901                                 break;
1902                         case "cells":
1903                                 got += GiveValue(e, ammo_cells, op, val);
1904                                 break;
1905                         case "shells":
1906                                 got += GiveValue(e, ammo_shells, op, val);
1907                                 break;
1908                         case "nails":
1909                         case "bullets":
1910                                 got += GiveValue(e, ammo_nails, op, val);
1911                                 break;
1912                         case "rockets":
1913                                 got += GiveValue(e, ammo_rockets, op, val);
1914                                 break;
1915                         case "health":
1916                                 got += GiveValue(e, health, op, val);
1917                                 break;
1918                         case "armor":
1919                                 got += GiveValue(e, armorvalue, op, val);
1920                                 break;
1921                         case "fuel":
1922                                 got += GiveValue(e, ammo_fuel, op, val);
1923                                 break;
1924                         default:
1925                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1926                                 {
1927                                         wi = get_weaponinfo(j);
1928                                         if(cmd == wi.netname)
1929                                         {
1930                                                 got += GiveWeapon(e, j, op, val);
1931                                                 break;
1932                                         }
1933                                 }
1934                                 if(j > WEP_LAST)
1935                                         print("give: invalid item ", cmd, "\n");
1936                                 break;
1937                 }
1938                 val = 999;
1939                 op = OP_SET;
1940         }
1941
1942         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1943         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1944         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1945         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1946         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1947         {
1948                 wi = get_weaponinfo(j);
1949                 if(wi.weapon)
1950                 {
1951                         POSTGIVE_WEAPON(e, j, "weapons/weaponpickup.wav", string_null);
1952                         if not(WEPSET_CONTAINS_AW(save_weapons, j))
1953                                 if(WEPSET_CONTAINS_EW(e, j))
1954                                         weapon_action(wi.weapon, WR_PRECACHE);
1955                 }
1956         }
1957         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1958         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1959         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1960         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1961         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1962         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1963         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
1964         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
1965         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
1966
1967         if(e.superweapons_finished <= 0)
1968                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1969                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1970
1971         if(e.strength_finished <= 0)
1972                 e.strength_finished = 0;
1973         else
1974                 e.strength_finished += time;
1975         if(e.invincible_finished <= 0)
1976                 e.invincible_finished = 0;
1977         else
1978                 e.invincible_finished += time;
1979         if(e.superweapons_finished <= 0)
1980                 e.superweapons_finished = 0;
1981         else
1982                 e.superweapons_finished += time;
1983
1984         if not(WEPSET_CONTAINS_EW(e, e.switchweapon))
1985                 _switchweapon = TRUE;
1986         if(_switchweapon)
1987                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1988
1989         return got;
1990 }
1991 #endif