qcsrc/server/t_items.qc

   1 #define ISF_LOCATION 2
   2 #define ISF_MODEL    4
   3 #define ISF_STATUS   8
   4     #define ITS_STAYWEP   1
   5     #define ITS_ANIMATE1  2
   6     #define ITS_ANIMATE2  4
   7     #define ITS_AVAILABLE 8
   8     #define ITS_ALLOWFB   16
   9     #define ITS_ALLOWSI   32
  10     #define ITS_POWERUP   64
  11 #define ISF_COLORMAP 16
  12 #define ISF_DROP 32
  13 #define ISF_ANGLES 64
  14
  15 .float ItemStatus;
  16
  17 #ifdef CSQC
  18
  19 var float  autocvar_cl_animate_items = 1;
  20 var float  autocvar_cl_ghost_items = 0.45;
  21 var vector autocvar_cl_ghost_items_color = '-1 -1 -1';
  22 var float  autocvar_cl_fullbright_items = 0;
  23 var vector autocvar_cl_weapon_stay_color = '2 0.5 0.5';
  24 var float  autocvar_cl_weapon_stay_alpha = 0.75;
  25 var float  autocvar_cl_simple_items = 0;
  26 var string autocvr_cl_simpleitems_postfix = "_simple";
  27 .float  spawntime;
  28 .float  gravity;
  29 .vector colormod;
  30 void ItemDraw()
  31 {
  32     if(self.gravity)
  33     {
  34         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  35         if(self.move_flags & FL_ONGROUND)
  36         { // For some reason move_avelocity gets set to '0 0 0' here ...
  37             self.oldorigin = self.origin;
  38             self.gravity = 0;
  39
  40             if(autocvar_cl_animate_items)
  41             { // ... so reset it if animations are requested.
  42                 if(self.ItemStatus & ITS_ANIMATE1)
  43                     self.move_avelocity = '0 180 0';
  44
  45                 if(self.ItemStatus & ITS_ANIMATE2)
  46                     self.move_avelocity = '0 -90 0';
  47             }
  48         }
  49     }
  50     else if (autocvar_cl_animate_items)
  51     {
  52         if(self.ItemStatus & ITS_ANIMATE1)
  53         {
  54             self.angles += self.move_avelocity * frametime;
  55             setorigin(self, '0 0 10' + self.oldorigin + '0 0 8' * sin(time * 2));
  56         }
  57
  58         if(self.ItemStatus & ITS_ANIMATE2)
  59         {
  60             self.angles += self.move_avelocity * frametime;
  61             setorigin(self, '0 0 8' + self.oldorigin + '0 0 4' * sin(time * 3));
  62         }
  63     }
  64 }
  65
  66 void ItemDrawSimple()
  67 {
  68     if(self.gravity)
  69     {
  70         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  71
  72         if(self.move_flags & FL_ONGROUND)
  73             self.gravity = 0;
  74     }
  75 }
  76
  77 void ItemRead(float _IsNew)
  78 {
  79     float sf = ReadByte();
  80
  81     if(sf & ISF_LOCATION)
  82     {
  83         self.origin_x = ReadCoord();
  84         self.origin_y = ReadCoord();
  85         self.origin_z = ReadCoord();
  86         setorigin(self, self.origin);
  87         self.oldorigin = self.origin;
  88     }
  89
  90     if(sf & ISF_ANGLES)
  91     {
  92         self.angles_x = ReadCoord();
  93         self.angles_y = ReadCoord();
  94         self.angles_z = ReadCoord();
  95         self.move_angles = self.angles;
  96     }
  97
  98     if(sf & ISF_STATUS) // need to read/write status frist so model can handle simple, fb etc.
  99     {
 100         self.ItemStatus = ReadByte();
 101
 102         if(self.ItemStatus & ITS_AVAILABLE)
 103         {
 104             self.alpha = 1;
 105             self.colormod = self.glowmod = '1 1 1';
 106         }
 107         else
 108         {
 109             if (autocvar_cl_ghost_items_color)
 110             {
 111                 self.alpha = autocvar_cl_ghost_items;
 112                 self.colormod = self.glowmod = autocvar_cl_ghost_items_color;
 113             }
 114             else
 115                 self.alpha = -1;
 116         }
 117
 118         if(autocvar_cl_fullbright_items)
 119             if(self.ItemStatus & ITS_ALLOWFB)
 120                 self.effects |= EF_FULLBRIGHT;
 121
 122         if(self.ItemStatus & ITS_STAYWEP)
 123         {
 124             self.colormod = self.glowmod = autocvar_cl_weapon_stay_color;
 125             self.alpha = autocvar_cl_weapon_stay_alpha;
 126
 127         }
 128
 129         if(self.ItemStatus & ITS_POWERUP)
 130         {
 131             if(self.ItemStatus & ITS_AVAILABLE)
 132                 self.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 133             else
 134                  self.effects &~= (EF_ADDITIVE | EF_FULLBRIGHT);
 135         }
 136     }
 137
 138     if(sf & ISF_MODEL)
 139     {
 140         self.drawmask  = MASK_NORMAL;
 141         self.movetype  = MOVETYPE_NOCLIP;
 142         self.draw       = ItemDraw;
 143
 144         if(self.mdl)
 145             strunzone(self.mdl);
 146
 147         self.mdl = "";
 148         string _fn = ReadString();
 149
 150         if(autocvar_cl_simple_items && (self.ItemStatus & ITS_ALLOWSI))
 151         {
 152             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 153             self.draw = ItemDrawSimple;
 154
 155
 156
 157             if(fexists(sprintf("%s%s.md3", _fn2, autocvr_cl_simpleitems_postfix)))
 158                 self.mdl = strzone(sprintf("%s%s.md3", _fn2, autocvr_cl_simpleitems_postfix));
 159             else if(fexists(sprintf("%s%s.dpm", _fn2, autocvr_cl_simpleitems_postfix)))
 160                 self.mdl = strzone(sprintf("%s%s.dpm", _fn2, autocvr_cl_simpleitems_postfix));
 161             else if(fexists(sprintf("%s%s.iqm", _fn2, autocvr_cl_simpleitems_postfix)))
 162                 self.mdl = strzone(sprintf("%s%s.iqm", _fn2, autocvr_cl_simpleitems_postfix));
 163             else if(fexists(sprintf("%s%s.obj", _fn2, autocvr_cl_simpleitems_postfix)))
 164                 self.mdl = strzone(sprintf("%s%s.obj", _fn2, autocvr_cl_simpleitems_postfix));
 165             else
 166             {
 167                 self.draw = ItemDraw;
 168                 dprint("Simple item requested for ", _fn, " but no model exsist for it\n");
 169             }
 170         }
 171
 172         if(self.draw != ItemDrawSimple)
 173             self.mdl = strzone(_fn);
 174
 175
 176         if(self.mdl == "")
 177             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, " tell tZork aboute this!\n");
 178
 179         precache_model(self.mdl);
 180         setmodel(self, self.mdl);
 181     }
 182
 183     if(sf & ISF_COLORMAP)
 184         self.colormap = ReadShort();
 185
 186     if(sf & ISF_DROP)
 187     {
 188         self.gravity = 1;
 189         self.move_angles = '0 0 0';
 190         self.move_movetype = MOVETYPE_TOSS;
 191         self.move_velocity_x = ReadCoord();
 192         self.move_velocity_y = ReadCoord();
 193         self.move_velocity_z = ReadCoord();
 194         self.velocity = self.move_velocity;
 195         self.move_origin = self.oldorigin;
 196
 197         if(!self.move_time)
 198         {
 199             self.move_time = time;
 200             self.spawntime = time;
 201         }
 202         else
 203             self.move_time = max(self.move_time, time);
 204     }
 205
 206     if(autocvar_cl_animate_items)
 207     {
 208         if(self.ItemStatus & ITS_ANIMATE1)
 209             self.move_avelocity = '0 180 0';
 210
 211         if(self.ItemStatus & ITS_ANIMATE2)
 212             self.move_avelocity = '0 -90 0';
 213     }
 214 }
 215
 216 #endif
 217
 218 #ifdef SVQC
 219 float autocvar_sv_simple_items;
 220 float ItemSend(entity to, float sf)
 221 {
 222     if(self.gravity)
 223         sf |= ISF_DROP;
 224     else
 225         sf &~= ISF_DROP;
 226
 227         WriteByte(MSG_ENTITY, ENT_CLIENT_ITEM);
 228         WriteByte(MSG_ENTITY, sf);
 229
 230         //WriteByte(MSG_ENTITY, self.cnt);
 231     if(sf & ISF_LOCATION)
 232     {
 233         WriteCoord(MSG_ENTITY, self.origin_x);
 234         WriteCoord(MSG_ENTITY, self.origin_y);
 235         WriteCoord(MSG_ENTITY, self.origin_z);
 236     }
 237
 238     if(sf & ISF_ANGLES)
 239     {
 240         WriteCoord(MSG_ENTITY, self.angles_x);
 241         WriteCoord(MSG_ENTITY, self.angles_y);
 242         WriteCoord(MSG_ENTITY, self.angles_z);
 243     }
 244
 245     if(sf & ISF_STATUS)
 246         WriteByte(MSG_ENTITY, self.ItemStatus);
 247
 248     if(sf & ISF_MODEL)
 249     {
 250
 251         if(self.mdl == "")
 252             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, "exspect a crash just aboute now\n");
 253
 254         WriteString(MSG_ENTITY, self.mdl);
 255     }
 256
 257
 258     if(sf & ISF_COLORMAP)
 259         WriteShort(MSG_ENTITY, self.colormap);
 260
 261     if(sf & ISF_DROP)
 262     {
 263         WriteCoord(MSG_ENTITY, self.velocity_x);
 264         WriteCoord(MSG_ENTITY, self.velocity_y);
 265         WriteCoord(MSG_ENTITY, self.velocity_z);
 266     }
 267
 268     return TRUE;
 269 }
 270
 271
 272 float have_pickup_item(void)
 273 {
 274         if(self.flags & FL_POWERUP)
 275         {
 276                 if(autocvar_g_powerups > 0)
 277                         return TRUE;
 278                 if(autocvar_g_powerups == 0)
 279                         return FALSE;
 280                 if(g_ca)
 281                         return FALSE;
 282                 if(g_arena)
 283                         return FALSE;
 284         }
 285         else
 286         {
 287                 if(autocvar_g_pickup_items > 0)
 288                         return TRUE;
 289                 if(autocvar_g_pickup_items == 0)
 290                         return FALSE;
 291                 if(g_ca)
 292                         return FALSE;
 293                 if(g_weaponarena)
 294                         if(!WEPSET_EMPTY_E(self) || (self.items & IT_AMMO))
 295                                 return FALSE;
 296         }
 297         return TRUE;
 298 }
 299
 300 #define ITEM_RESPAWN_TICKS 10
 301
 302 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
 303         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
 304 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
 305         // range: 10 .. respawntime + respawntimejitter
 306
 307 floatfield Item_CounterField(float it)
 308 {
 309         switch(it)
 310         {
 311                 case IT_SHELLS:      return ammo_shells;
 312                 case IT_NAILS:       return ammo_nails;
 313                 case IT_ROCKETS:     return ammo_rockets;
 314                 case IT_CELLS:       return ammo_cells;
 315                 case IT_FUEL:        return ammo_fuel;
 316                 case IT_5HP:         return health;
 317                 case IT_25HP:        return health;
 318                 case IT_HEALTH:      return health;
 319                 case IT_ARMOR_SHARD: return armorvalue;
 320                 case IT_ARMOR:       return armorvalue;
 321                 // add more things here (health, armor)
 322                 default:             error("requested item has no counter field");
 323         }
 324 #ifdef GMQCC
 325         // should never happen
 326         return health;
 327 #endif
 328 }
 329
 330 string Item_CounterFieldName(float it)
 331 {
 332         switch(it)
 333         {
 334                 case IT_SHELLS:      return "shells";
 335                 case IT_NAILS:       return "nails";
 336                 case IT_ROCKETS:     return "rockets";
 337                 case IT_CELLS:       return "cells";
 338                 case IT_FUEL:        return "fuel";
 339
 340                 // add more things here (health, armor)
 341                 default:             error("requested item has no counter field name");
 342         }
 343 #ifdef GMQCC
 344         // should never happen
 345         return string_null;
 346 #endif
 347 }
 348
 349 .float max_armorvalue;
 350 .float pickup_anyway;
 351 /*
 352 float Item_Customize()
 353 {
 354         if(self.spawnshieldtime)
 355                 return TRUE;
 356         if(!WEPSET_CONTAINS_ALL_EE(other, self))
 357         {
 358                 self.colormod = '0 0 0';
 359                 self.glowmod = self.colormod;
 360                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 361                 return TRUE;
 362         }
 363         else
 364         {
 365                 if(g_ghost_items)
 366                 {
 367                         self.colormod = stov(autocvar_g_ghost_items_color);
 368                         self.glowmod = self.colormod;
 369                         self.alpha = g_ghost_items;
 370                         return TRUE;
 371                 }
 372                 else
 373                         return FALSE;
 374         }
 375 }
 376 */
 377
 378 void Item_Show (entity e, float mode)
 379 {
 380         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
 381         e.ItemStatus &~= ITS_STAYWEP;
 382         if (mode > 0)
 383         {
 384                 // make the item look normal, and be touchable
 385                 e.model = e.mdl;
 386                 e.solid = SOLID_TRIGGER;
 387                 e.spawnshieldtime = 1;
 388                 e.ItemStatus |= ITS_AVAILABLE;
 389         }
 390         else if (mode < 0)
 391         {
 392                 // hide the item completely
 393                 e.model = string_null;
 394                 e.solid = SOLID_NOT;
 395                 e.spawnshieldtime = 1;
 396                 e.ItemStatus &~= ITS_AVAILABLE;
 397         }
 398         else if((e.flags & FL_WEAPON) && !(e.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 399         {
 400                 // make the item translucent and not touchable
 401                 e.model = e.mdl;
 402                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 403                 e.effects |= EF_STARDUST;
 404                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 405                 e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 406         }
 407         else
 408         {
 409                 //setmodel(e, "null");
 410                 e.solid = SOLID_NOT;
 411                 e.colormod = '0 0 0';
 412                 e.glowmod = e.colormod;
 413                 e.spawnshieldtime = 1;
 414                 e.ItemStatus &~= ITS_AVAILABLE;
 415         }
 416
 417         if (e.items & IT_STRENGTH || e.items & IT_INVINCIBLE)
 418             e.ItemStatus |= ITS_POWERUP;
 419
 420         if (autocvar_g_nodepthtestitems)
 421                 e.effects |= EF_NODEPTHTEST;
 422
 423
 424     if (autocvar_g_fullbrightitems)
 425                 e.ItemStatus |= ITS_ALLOWFB;
 426
 427         if (autocvar_sv_simple_items)
 428         e.ItemStatus |= ITS_ALLOWSI;
 429
 430         // relink entity (because solid may have changed)
 431         setorigin(e, e.origin);
 432     e.SendFlags |= ISF_STATUS;
 433 }
 434
 435 void Item_Respawn (void)
 436 {
 437         Item_Show(self, 1);
 438         // this is ugly...
 439         if(self.items == IT_STRENGTH)
 440                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
 441         else if(self.items == IT_INVINCIBLE)
 442                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 443         else
 444                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);  // play respawn sound
 445         setorigin (self, self.origin);
 446
 447         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 448         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 449 }
 450
 451 void Item_RespawnCountdown (void)
 452 {
 453         if(self.count >= ITEM_RESPAWN_TICKS)
 454         {
 455                 if(self.waypointsprite_attached)
 456                         WaypointSprite_Kill(self.waypointsprite_attached);
 457                 Item_Respawn();
 458         }
 459         else
 460         {
 461                 self.nextthink = time + 1;
 462                 self.count += 1;
 463                 if(self.count == 1)
 464                 {
 465                         string name;
 466                         vector rgb = '1 0 1';
 467                         name = string_null;
 468                         switch(self.items)
 469                         {
 470                                 case IT_FUEL_REGEN: name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 471                                 case IT_JETPACK:    name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 472                                 case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 473                                 case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 474                         }
 475                         item_name = name;
 476                         item_color = rgb;
 477                         MUTATOR_CALLHOOK(Item_RespawnCountdown);
 478                         name = item_name;
 479                         rgb = item_color;
 480                         if(self.flags & FL_WEAPON)
 481                         {
 482                                 entity wi = get_weaponinfo(self.weapon);
 483                                 if(wi)
 484                                 {
 485                                         name = wi.model2;
 486                                         rgb = '1 0 0';
 487                                 }
 488                         }
 489                         if(name)
 490                         {
 491                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
 492                                 if(self.waypointsprite_attached)
 493                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 494                         }
 495                         else
 496                         {
 497                                 print("Unknown powerup-marked item is wanting to respawn\n");
 498                                 localcmd(sprintf("prvm_edict server %d\n", num_for_edict(self)));
 499                         }
 500                 }
 501                 sound (self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM); // play respawn sound
 502                 if(self.waypointsprite_attached)
 503                 {
 504                         WaypointSprite_Ping(self.waypointsprite_attached);
 505                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 506                 }
 507         }
 508 }
 509
 510 void Item_ScheduleRespawnIn(entity e, float t)
 511 {
 512         if((e.flags & FL_POWERUP) || WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
 513         {
 514                 e.think = Item_RespawnCountdown;
 515                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 516                 e.count = 0;
 517         }
 518         else
 519         {
 520                 e.think = Item_Respawn;
 521                 e.nextthink = time + t;
 522         }
 523 }
 524
 525 void Item_ScheduleRespawn(entity e)
 526 {
 527         if(e.respawntime > 0)
 528         {
 529                 Item_Show(e, 0);
 530                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 531         }
 532         else // if respawntime is -1, this item does not respawn
 533                 Item_Show(e, -1);
 534 }
 535
 536 void Item_ScheduleInitialRespawn(entity e)
 537 {
 538         Item_Show(e, 0);
 539         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 540 }
 541
 542 float ITEM_MODE_NONE = 0;
 543 float ITEM_MODE_HEALTH = 1;
 544 float ITEM_MODE_ARMOR = 2;
 545 float ITEM_MODE_FUEL = 3;
 546 float Item_GiveAmmoTo(entity item, entity player, .float ammofield, float ammomax, float mode)
 547 {
 548         if (!item.ammofield)
 549                 return FALSE;
 550
 551         if (item.spawnshieldtime)
 552         {
 553                 if ((player.ammofield < ammomax) || item.pickup_anyway)
 554                 {
 555                         player.ammofield = bound(player.ammofield, ammomax, player.ammofield + item.ammofield);
 556                         goto YEAH;
 557                 }
 558         }
 559         else if(g_weapon_stay == 2)
 560         {
 561                 float mi = min(item.ammofield, ammomax);
 562                 if (player.ammofield < mi)
 563                 {
 564                         player.ammofield = mi;
 565                         goto YEAH;
 566                 }
 567         }
 568
 569         return FALSE;
 570
 571 :YEAH
 572         switch(mode)
 573         {
 574                 case ITEM_MODE_FUEL:
 575                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 576                         break;
 577                 case ITEM_MODE_HEALTH:
 578                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 579                         break;
 580                 case ITEM_MODE_ARMOR:
 581                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 582                         break;
 583                 default:
 584                         break;
 585         }
 586         return TRUE;
 587 }
 588
 589 float Item_GiveTo(entity item, entity player)
 590 {
 591         float _switchweapon;
 592         float pickedup;
 593         float it;
 594         float i;
 595
 596         // if nothing happens to player, just return without taking the item
 597         pickedup = FALSE;
 598         _switchweapon = FALSE;
 599         // in case the player has autoswitch enabled do the following:
 600         // if the player is using their best weapon before items are given, they
 601         // probably want to switch to an even better weapon after items are given
 602         if (player.autoswitch)
 603         if (player.switchweapon == w_getbestweapon(player))
 604                 _switchweapon = TRUE;
 605
 606         if not(WEPSET_CONTAINS_EW(player, player.switchweapon))
 607                 _switchweapon = TRUE;
 608
 609         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 610         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 611         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 612         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 613         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 614         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 615         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 616
 617         if (item.flags & FL_WEAPON)
 618         {
 619                 WEPSET_DECLARE_A(it);
 620                 WEPSET_COPY_AE(it, item);
 621                 WEPSET_ANDNOT_AE(it, player);
 622
 623                 if (!WEPSET_EMPTY_A(it) || (item.spawnshieldtime && item.pickup_anyway))
 624                 {
 625                         pickedup = TRUE;
 626                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 627                         if(WEPSET_CONTAINS_AW(it, i))
 628                                 W_GiveWeapon(player, i);
 629                 }
 630         }
 631
 632         if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 633         {
 634                 pickedup = TRUE;
 635                 player.items |= it;
 636                 sprint (player, strcat("You got the ^2", item.netname, "\n"));
 637         }
 638
 639         if (item.strength_finished)
 640         {
 641                 pickedup = TRUE;
 642                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 643         }
 644         if (item.invincible_finished)
 645         {
 646                 pickedup = TRUE;
 647                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 648         }
 649         if (item.superweapons_finished)
 650         {
 651                 pickedup = TRUE;
 652                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 653         }
 654
 655 :skip
 656
 657         // always eat teamed entities
 658         if(item.team)
 659                 pickedup = TRUE;
 660
 661         if (!pickedup)
 662                 return 0;
 663
 664         if (_switchweapon)
 665                 if (player.switchweapon != w_getbestweapon(player))
 666                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 667
 668         return 1;
 669 }
 670
 671 void Item_Touch (void)
 672 {
 673         entity e, head;
 674
 675         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 676         if(self.classname == "droppedweapon")
 677         {
 678                 if (ITEM_TOUCH_NEEDKILL())
 679                 {
 680                         remove(self);
 681                         return;
 682                 }
 683         }
 684
 685         if not(IS_PLAYER(other))
 686                 return;
 687         if (other.frozen)
 688                 return;
 689         if (other.deadflag)
 690                 return;
 691         if (self.solid != SOLID_TRIGGER)
 692                 return;
 693         if (self.owner == other)
 694                 return;
 695
 696         switch(MUTATOR_CALLHOOK(ItemTouch))
 697         {
 698                 case MUT_ITEMTOUCH_RETURN: { return; }
 699                 case MUT_ITEMTOUCH_PICKUP: { goto pickup; }
 700         }
 701
 702         if (self.classname == "droppedweapon")
 703         {
 704                 self.strength_finished = max(0, self.strength_finished - time);
 705                 self.invincible_finished = max(0, self.invincible_finished - time);
 706                 self.superweapons_finished = max(0, self.superweapons_finished - time);
 707         }
 708
 709         if(!Item_GiveTo(self, other))
 710         {
 711                 if (self.classname == "droppedweapon")
 712                 {
 713                         // undo what we did above
 714                         self.strength_finished += time;
 715                         self.invincible_finished += time;
 716                         self.superweapons_finished += time;
 717                 }
 718                 return;
 719         }
 720
 721         :pickup
 722
 723         other.last_pickup = time;
 724
 725         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 726         sound (other, CH_TRIGGER, self.item_pickupsound, VOL_BASE, ATTN_NORM);
 727
 728         if (self.classname == "droppedweapon")
 729                 remove (self);
 730         else if not(self.spawnshieldtime)
 731                 return;
 732         else
 733         {
 734                 if(self.team)
 735                 {
 736                         RandomSelection_Init();
 737                         for(head = world; (head = findfloat(head, team, self.team)); )
 738                         {
 739                                 if(head.flags & FL_ITEM)
 740                                 {
 741                                         Item_Show(head, -1);
 742                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 743                                 }
 744                         }
 745                         e = RandomSelection_chosen_ent;
 746
 747                 }
 748                 else
 749                         e = self;
 750                 Item_ScheduleRespawn(e);
 751         }
 752 }
 753
 754 void Item_Reset()
 755 {
 756         Item_Show(self, !self.state);
 757         setorigin (self, self.origin);
 758
 759         if(self.classname != "droppedweapon")
 760         {
 761                 self.think = func_null;
 762                 self.nextthink = 0;
 763
 764                 if(self.waypointsprite_attached)
 765                         WaypointSprite_Kill(self.waypointsprite_attached);
 766
 767                 if((self.flags & FL_POWERUP) | WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // do not spawn powerups initially!
 768                         Item_ScheduleInitialRespawn(self);
 769         }
 770 }
 771
 772 void Item_FindTeam()
 773 {
 774         entity head, e;
 775
 776         if(self.effects & EF_NODRAW)
 777         {
 778                 // marker for item team search
 779                 dprint("Initializing item team ", ftos(self.team), "\n");
 780                 RandomSelection_Init();
 781                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 782                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 783                 e = RandomSelection_chosen_ent;
 784                 e.state = 0;
 785                 Item_Show(e, 1);
 786
 787                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 788                 {
 789                         if(head != e)
 790                         {
 791                                 // make it a non-spawned item
 792                                 Item_Show(head, -1);
 793                                 head.state = 1; // state 1 = initially hidden item
 794                         }
 795                         head.effects &~= EF_NODRAW;
 796                 }
 797
 798                 Item_Reset();
 799         }
 800 }
 801
 802 // Savage: used for item garbage-collection
 803 // TODO: perhaps nice special effect?
 804 void RemoveItem(void)
 805 {
 806         remove(self);
 807 }
 808
 809 // pickup evaluation functions
 810 // these functions decide how desirable an item is to the bots
 811
 812 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 813
 814 float weapon_pickupevalfunc(entity player, entity item)
 815 {
 816         float c, j, position;
 817
 818         // See if I have it already
 819         if(!WEPSET_CONTAINS_ALL_EE(player, item))
 820         {
 821                 // If I can pick it up
 822                 if(!item.spawnshieldtime)
 823                         c = 0;
 824                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 825                 {
 826                         // Skilled bots will grab more
 827                         c = bound(0, skill / 10, 1) * 0.5;
 828                 }
 829                 else
 830                         c = 0;
 831         }
 832         else
 833                 c = 1;
 834
 835         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 836         if( bot_custom_weapon && c )
 837         {
 838                 // Find the highest position on any range
 839                 position = -1;
 840                 for(j = 0; j < WEP_LAST ; ++j){
 841                         if(
 842                                         bot_weapons_far[j] == item.weapon ||
 843                                         bot_weapons_mid[j] == item.weapon ||
 844                                         bot_weapons_close[j] == item.weapon
 845                           )
 846                         {
 847                                 position = j;
 848                                 break;
 849                         }
 850                 }
 851
 852                 // Rate it
 853                 if (position >= 0 )
 854                 {
 855                         position = WEP_LAST - position;
 856                         // item.bot_pickupbasevalue is overwritten here
 857                         return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 858                 }
 859         }
 860
 861         return item.bot_pickupbasevalue * c;
 862 }
 863
 864 float commodity_pickupevalfunc(entity player, entity item)
 865 {
 866         float c, i;
 867         float need_shells = FALSE, need_nails = FALSE, need_rockets = FALSE, need_cells = FALSE, need_fuel = FALSE;
 868         entity wi;
 869         c = 0;
 870
 871         // Detect needed ammo
 872         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 873         {
 874                 wi = get_weaponinfo(i);
 875
 876                 if not(WEPSET_CONTAINS_EW(player, i))
 877                         continue;
 878
 879                 if(wi.items & IT_SHELLS)
 880                         need_shells = TRUE;
 881                 else if(wi.items & IT_NAILS)
 882                         need_nails = TRUE;
 883                 else if(wi.items & IT_ROCKETS)
 884                         need_rockets = TRUE;
 885                 else if(wi.items & IT_CELLS)
 886                         need_cells = TRUE;
 887                 else if(wi.items & IT_FUEL)
 888                         need_cells = TRUE;
 889         }
 890
 891         // TODO: figure out if the player even has the weapon this ammo is for?
 892         // may not affect strategy much though...
 893         // find out how much more ammo/armor/health the player can hold
 894         if (need_shells)
 895         if (item.ammo_shells)
 896         if (player.ammo_shells < g_pickup_shells_max)
 897                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 898         if (need_nails)
 899         if (item.ammo_nails)
 900         if (player.ammo_nails < g_pickup_nails_max)
 901                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 902         if (need_rockets)
 903         if (item.ammo_rockets)
 904         if (player.ammo_rockets < g_pickup_rockets_max)
 905                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 906         if (need_cells)
 907         if (item.ammo_cells)
 908         if (player.ammo_cells < g_pickup_cells_max)
 909                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 910         if (need_fuel)
 911         if (item.ammo_fuel)
 912         if (player.ammo_fuel < g_pickup_fuel_max)
 913                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
 914         if (item.armorvalue)
 915         if (player.armorvalue < item.max_armorvalue)
 916                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 917         if (item.health)
 918         if (player.health < item.max_health)
 919                 c = c + max(0, 1 - player.health / item.max_health);
 920
 921         return item.bot_pickupbasevalue * c;
 922 }
 923
 924 void Item_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 925 {
 926         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 927                 RemoveItem();
 928 }
 929
 930 .float is_item;
 931 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 932 {
 933         startitem_failed = FALSE;
 934
 935         if(self.model == "")
 936                 self.model = itemmodel;
 937
 938         if(self.model == "")
 939     {
 940         error(strcat("^1Tried to spawn ", itemname, " with no model!\n"));
 941         return;
 942     }
 943
 944         if(self.item_pickupsound == "")
 945                 self.item_pickupsound = pickupsound;
 946
 947         if(!self.respawntime) // both need to be set
 948         {
 949                 self.respawntime = defaultrespawntime;
 950                 self.respawntimejitter = defaultrespawntimejitter;
 951         }
 952
 953         self.items = itemid;
 954         self.weapon = weaponid;
 955
 956         if(weaponid)
 957                 WEPSET_COPY_EW(self, weaponid);
 958
 959         self.flags = FL_ITEM | itemflags;
 960
 961         if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
 962         {
 963                 startitem_failed = TRUE;
 964                 remove(self);
 965                 return;
 966         }
 967
 968         // is it a dropped weapon?
 969         if (self.classname == "droppedweapon")
 970         {
 971                 self.reset = SUB_Remove;
 972                 // it's a dropped weapon
 973                 self.movetype = MOVETYPE_TOSS;
 974
 975                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 976                 self.think = RemoveItem;
 977                 self.nextthink = time + 20;
 978
 979                 self.takedamage = DAMAGE_YES;
 980                 self.event_damage = Item_Damage;
 981
 982                 if(self.strength_finished || self.invincible_finished || self.superweapons_finished)
 983                 /*
 984                 if(self.items == 0)
 985                 if(WEPSET_CONTAINS_ALL_AE(WEPBIT_SUPERWEAPONS, self)) // only superweapons
 986                 if(self.ammo_nails == 0)
 987                 if(self.ammo_cells == 0)
 988                 if(self.ammo_rockets == 0)
 989                 if(self.ammo_shells == 0)
 990                 if(self.ammo_fuel == 0)
 991                 if(self.health == 0)
 992                 if(self.armorvalue == 0)
 993                 */
 994                 {
 995                         // if item is worthless after a timer, have it expire then
 996                         self.nextthink = max(self.strength_finished, self.invincible_finished, self.superweapons_finished);
 997                 }
 998
 999                 // don't drop if in a NODROP zone (such as lava)
1000                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
1001                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1002                 {
1003                         startitem_failed = TRUE;
1004                         remove(self);
1005                         return;
1006                 }
1007         }
1008         else
1009         {
1010                 if(!have_pickup_item())
1011                 {
1012                         startitem_failed = TRUE;
1013                         remove (self);
1014                         return;
1015                 }
1016
1017                 if(self.angles != '0 0 0')
1018             self.SendFlags |= ISF_ANGLES;
1019
1020                 self.reset = Item_Reset;
1021                 // it's a level item
1022                 if(self.spawnflags & 1)
1023                         self.noalign = 1;
1024                 if (self.noalign)
1025                         self.movetype = MOVETYPE_NONE;
1026                 else
1027                         self.movetype = MOVETYPE_TOSS;
1028                 // do item filtering according to game mode and other things
1029                 if (!self.noalign)
1030                 {
1031                         // first nudge it off the floor a little bit to avoid math errors
1032                         setorigin(self, self.origin + '0 0 1');
1033                         // set item size before we spawn a spawnfunc_waypoint
1034                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1035                                 setsize (self, '-16 -16 0', '16 16 48');
1036                         else
1037                                 setsize (self, '-16 -16 0', '16 16 32');
1038                         // note droptofloor returns FALSE if stuck/or would fall too far
1039                         droptofloor();
1040                         waypoint_spawnforitem(self);
1041                 }
1042
1043                 /*
1044                  * can't do it that way, as it would break maps
1045                  * TODO make a target_give like entity another way, that perhaps has
1046                  * the weapon name in a key
1047                 if(self.targetname)
1048                 {
1049                         // target_give not yet supported; maybe later
1050                         print("removed targeted ", self.classname, "\n");
1051                         startitem_failed = TRUE;
1052                         remove (self);
1053                         return;
1054                 }
1055                 */
1056
1057                 if(autocvar_spawn_debug >= 2)
1058                 {
1059                         entity otheritem;
1060                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
1061                         {
1062                             // why not flags & fl_item?
1063                                 if(otheritem.is_item)
1064                                 {
1065                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
1066                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
1067                                         error("Mapper sucks.");
1068                                 }
1069                         }
1070                         self.is_item = TRUE;
1071                 }
1072
1073                 WEPSET_OR_AW(weaponsInMap, weaponid);
1074
1075                 precache_model (self.model);
1076                 precache_sound (self.item_pickupsound);
1077
1078                 precache_sound ("misc/itemrespawncountdown.wav");
1079                 if(itemid == IT_STRENGTH)
1080                         precache_sound ("misc/strength_respawn.wav");
1081                 else if(itemid == IT_INVINCIBLE)
1082                         precache_sound ("misc/shield_respawn.wav");
1083                 else
1084                         precache_sound ("misc/itemrespawn.wav");
1085
1086                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
1087                         self.target = "###item###"; // for finding the nearest item using find()
1088         }
1089
1090         self.bot_pickup = TRUE;
1091         self.bot_pickupevalfunc = pickupevalfunc;
1092         self.bot_pickupbasevalue = pickupbasevalue;
1093         self.mdl = self.model;
1094         self.netname = itemname;
1095         self.touch = Item_Touch;
1096         setmodel(self, "null"); // precision set below
1097         //self.effects |= EF_LOWPRECISION;
1098
1099         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1100     {
1101         self.pos1 = '-16 -16 0';
1102         self.pos2 = '16 16 48';
1103     }
1104         else
1105     {
1106         self.pos1 = '-16 -16 0';
1107         self.pos2 = '16 16 32';
1108     }
1109     setsize (self, self.pos1, self.pos2);
1110
1111     if(itemflags & FL_POWERUP)
1112         self.ItemStatus |= ITS_ANIMATE1;
1113
1114         if(self.armorvalue || self.health)
1115         self.ItemStatus |= ITS_ANIMATE2;
1116
1117         if(itemflags & FL_WEAPON)
1118         {
1119                 if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1120             self.colormap = 1024; // color shirt=0 pants=0 grey
1121         else
1122             self.gravity = 1;
1123
1124                 self.ItemStatus |= ITS_ANIMATE1;
1125                 self.ItemStatus |= ISF_COLORMAP;
1126         }
1127
1128         self.state = 0;
1129         if(self.team) // broken, no idea why.
1130         {
1131                 if(!self.cnt)
1132                         self.cnt = 1; // item probability weight
1133
1134                 self.effects |= EF_NODRAW; // marker for item team search
1135                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
1136         }
1137         else
1138                 Item_Reset();
1139
1140     Net_LinkEntity(self, FALSE, 0, ItemSend);
1141
1142         // call this hook after everything else has been done
1143         if(MUTATOR_CALLHOOK(Item_Spawn))
1144         {
1145                 startitem_failed = TRUE;
1146                 remove(self);
1147                 return;
1148         }
1149 }
1150
1151 float weaponswapping;
1152 float internalteam;
1153
1154 void weapon_defaultspawnfunc(float wpn)
1155 {
1156         entity e;
1157         float t;
1158         var .float ammofield;
1159         string s;
1160         entity oldself;
1161         float i, j;
1162         float f;
1163
1164         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
1165         {
1166                 e = get_weaponinfo(wpn);
1167
1168                 if(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
1169                 {
1170                         print("Attempted to spawn a mutator-blocked weapon; these guns will in the future require a mutator\n");
1171                         /*
1172                         objerror("Attempted to spawn a mutator-blocked weapon rejected");
1173                         startitem_failed = TRUE;
1174                         return;
1175                         */
1176                 }
1177
1178                 s = W_Apply_Weaponreplace(e.netname);
1179                 ret_string = s;
1180                 other = e;
1181                 MUTATOR_CALLHOOK(SetWeaponreplace);
1182                 s = ret_string;
1183                 if(s == "")
1184                 {
1185                         remove(self);
1186                         startitem_failed = TRUE;
1187                         return;
1188                 }
1189                 t = tokenize_console(s);
1190                 if(t >= 2)
1191                 {
1192                         self.team = --internalteam;
1193                         oldself = self;
1194                         for(i = 1; i < t; ++i)
1195                         {
1196                                 s = argv(i);
1197                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1198                                 {
1199                                         e = get_weaponinfo(j);
1200                                         if(e.netname == s)
1201                                         {
1202                                                 self = spawn();
1203                                                 copyentity(oldself, self);
1204                                                 self.classname = "replacedweapon";
1205                                                 weapon_defaultspawnfunc(j);
1206                                                 break;
1207                                         }
1208                                 }
1209                                 if(j > WEP_LAST)
1210                                 {
1211                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1212                                 }
1213                         }
1214                         self = oldself;
1215                 }
1216                 if(t >= 1) // always the case!
1217                 {
1218                         s = argv(0);
1219                         wpn = 0;
1220                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1221                         {
1222                                 e = get_weaponinfo(j);
1223                                 if(e.netname == s)
1224                                 {
1225                                         wpn = j;
1226                                         break;
1227                                 }
1228                         }
1229                         if(j > WEP_LAST)
1230                         {
1231                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1232                         }
1233                 }
1234                 if(wpn == 0)
1235                 {
1236                         remove(self);
1237                         startitem_failed = TRUE;
1238                         return;
1239                 }
1240         }
1241
1242         e = get_weaponinfo(wpn);
1243
1244         if(!self.respawntime)
1245         {
1246                 if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1247                 {
1248                         self.respawntime = g_pickup_respawntime_superweapon;
1249                         self.respawntimejitter = g_pickup_respawntimejitter_superweapon;
1250                 }
1251                 else
1252                 {
1253                         self.respawntime = g_pickup_respawntime_weapon;
1254                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
1255                 }
1256         }
1257
1258         if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1259                 if(!self.superweapons_finished)
1260                         self.superweapons_finished = autocvar_g_balance_superweapons_time;
1261
1262         if(e.items)
1263         {
1264                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1265                 {
1266                         if(e.items & j)
1267                         {
1268                                 ammofield = Item_CounterField(j);
1269                                 if(!self.ammofield)
1270                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j), "_weapon"));
1271                         }
1272                 }
1273         }
1274
1275         // pickup anyway
1276         if(g_pickup_weapons_anyway)
1277                 self.pickup_anyway = TRUE;
1278
1279         f = FL_WEAPON;
1280
1281         // no weapon-stay on superweapons
1282         if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1283                 f |= FL_NO_WEAPON_STAY;
1284
1285         // weapon stay isn't supported for teamed weapons
1286         if(self.team)
1287                 f |= FL_NO_WEAPON_STAY;
1288
1289         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapon, f, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1290         if (self.modelindex) // don't precache if self was removed
1291                 weapon_action(e.weapon, WR_PRECACHE);
1292 }
1293
1294 void spawnfunc_weapon_shotgun (void);
1295 void spawnfunc_weapon_uzi (void) {
1296         if(autocvar_sv_q3acompat_machineshotgunswap)
1297         if(self.classname != "droppedweapon")
1298         {
1299                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1300                 return;
1301         }
1302         weapon_defaultspawnfunc(WEP_UZI);
1303 }
1304
1305 void spawnfunc_weapon_shotgun (void) {
1306         if(autocvar_sv_q3acompat_machineshotgunswap)
1307         if(self.classname != "droppedweapon")
1308         {
1309                 weapon_defaultspawnfunc(WEP_UZI);
1310                 return;
1311         }
1312         weapon_defaultspawnfunc(WEP_SHOTGUN);
1313 }
1314
1315 void spawnfunc_weapon_nex (void)
1316 {
1317         weapon_defaultspawnfunc(WEP_NEX);
1318 }
1319
1320 void spawnfunc_weapon_minstanex (void)
1321 {
1322         weapon_defaultspawnfunc(WEP_MINSTANEX);
1323 }
1324
1325 void spawnfunc_weapon_rocketlauncher (void)
1326 {
1327         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1328 }
1329
1330 void spawnfunc_item_rockets (void) {
1331         if(!self.ammo_rockets)
1332                 self.ammo_rockets = g_pickup_rockets;
1333         if(!self.pickup_anyway)
1334                 self.pickup_anyway = g_pickup_ammo_anyway;
1335         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1336 }
1337
1338 void spawnfunc_item_shells (void);
1339 void spawnfunc_item_bullets (void) {
1340         if(!weaponswapping)
1341         if(autocvar_sv_q3acompat_machineshotgunswap)
1342         if(self.classname != "droppedweapon")
1343         {
1344                 weaponswapping = TRUE;
1345                 spawnfunc_item_shells();
1346                 weaponswapping = FALSE;
1347                 return;
1348         }
1349
1350         if(!self.ammo_nails)
1351                 self.ammo_nails = g_pickup_nails;
1352         if(!self.pickup_anyway)
1353                 self.pickup_anyway = g_pickup_ammo_anyway;
1354         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1355 }
1356
1357 void spawnfunc_item_cells (void) {
1358         if(!self.ammo_cells)
1359                 self.ammo_cells = g_pickup_cells;
1360         if(!self.pickup_anyway)
1361                 self.pickup_anyway = g_pickup_ammo_anyway;
1362         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1363 }
1364
1365 void spawnfunc_item_shells (void) {
1366         if(!weaponswapping)
1367         if(autocvar_sv_q3acompat_machineshotgunswap)
1368         if(self.classname != "droppedweapon")
1369         {
1370                 weaponswapping = TRUE;
1371                 spawnfunc_item_bullets();
1372                 weaponswapping = FALSE;
1373                 return;
1374         }
1375
1376         if(!self.ammo_shells)
1377                 self.ammo_shells = g_pickup_shells;
1378         if(!self.pickup_anyway)
1379                 self.pickup_anyway = g_pickup_ammo_anyway;
1380         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1381 }
1382
1383 void spawnfunc_item_armor_small (void) {
1384         if(!self.armorvalue)
1385                 self.armorvalue = g_pickup_armorsmall;
1386         if(!self.max_armorvalue)
1387                 self.max_armorvalue = g_pickup_armorsmall_max;
1388         if(!self.pickup_anyway)
1389                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1390         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1391 }
1392
1393 void spawnfunc_item_armor_medium (void) {
1394         if(!self.armorvalue)
1395                 self.armorvalue = g_pickup_armormedium;
1396         if(!self.max_armorvalue)
1397                 self.max_armorvalue = g_pickup_armormedium_max;
1398         if(!self.pickup_anyway)
1399                 self.pickup_anyway = g_pickup_armormedium_anyway;
1400         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1401 }
1402
1403 void spawnfunc_item_armor_big (void) {
1404         if(!self.armorvalue)
1405                 self.armorvalue = g_pickup_armorbig;
1406         if(!self.max_armorvalue)
1407                 self.max_armorvalue = g_pickup_armorbig_max;
1408         if(!self.pickup_anyway)
1409                 self.pickup_anyway = g_pickup_armorbig_anyway;
1410         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1411 }
1412
1413 void spawnfunc_item_armor_large (void) {
1414         if(!self.armorvalue)
1415                 self.armorvalue = g_pickup_armorlarge;
1416         if(!self.max_armorvalue)
1417                 self.max_armorvalue = g_pickup_armorlarge_max;
1418         if(!self.pickup_anyway)
1419                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1420         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1421 }
1422
1423 void spawnfunc_item_health_small (void) {
1424         if(!self.max_health)
1425                 self.max_health = g_pickup_healthsmall_max;
1426         if(!self.health)
1427                 self.health = g_pickup_healthsmall;
1428         if(!self.pickup_anyway)
1429                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1430         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1431 }
1432
1433 void spawnfunc_item_health_medium (void) {
1434         if(!self.max_health)
1435                 self.max_health = g_pickup_healthmedium_max;
1436         if(!self.health)
1437                 self.health = g_pickup_healthmedium;
1438         if(!self.pickup_anyway)
1439                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1440         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1441 }
1442
1443 void spawnfunc_item_health_large (void) {
1444         if(!self.max_health)
1445                 self.max_health = g_pickup_healthlarge_max;
1446         if(!self.health)
1447                 self.health = g_pickup_healthlarge;
1448         if(!self.pickup_anyway)
1449                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1450         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1451 }
1452
1453 void spawnfunc_item_health_mega (void) {
1454                 if(!self.max_health)
1455                         self.max_health = g_pickup_healthmega_max;
1456                 if(!self.health)
1457                         self.health = g_pickup_healthmega;
1458                 if(!self.pickup_anyway)
1459                         self.pickup_anyway = g_pickup_healthmega_anyway;
1460                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1461 }
1462
1463 // support old misnamed entities
1464 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1465 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1466 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1467 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1468 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1469
1470 void spawnfunc_item_strength (void) {
1471                 precache_sound("weapons/strength_fire.wav");
1472                 if(!self.strength_finished)
1473                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1474                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1475 }
1476
1477 void spawnfunc_item_invincible (void) {
1478                 if(!self.invincible_finished)
1479                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1480                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1481 }
1482
1483 // compatibility:
1484 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1485
1486 float GiveItems(entity e, float beginarg, float endarg);
1487 void target_items_use (void)
1488 {
1489         if(activator.classname == "droppedweapon")
1490         {
1491                 EXACTTRIGGER_TOUCH;
1492                 remove(activator);
1493                 return;
1494         }
1495
1496         if not(IS_PLAYER(activator))
1497                 return;
1498         if(activator.deadflag != DEAD_NO)
1499                 return;
1500         EXACTTRIGGER_TOUCH;
1501
1502         entity e;
1503         for(e = world; (e = find(e, classname, "droppedweapon")); )
1504                 if(e.enemy == activator)
1505                         remove(e);
1506
1507         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1508                 centerprint(activator, self.message);
1509 }
1510
1511 void spawnfunc_target_items (void)
1512 {
1513         float n, i, j;
1514         entity e;
1515
1516         self.use = target_items_use;
1517         if(!self.strength_finished)
1518                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1519         if(!self.invincible_finished)
1520                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1521         if(!self.superweapons_finished)
1522                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1523
1524         precache_sound("misc/itempickup.wav");
1525         precache_sound("misc/megahealth.wav");
1526         precache_sound("misc/armor25.wav");
1527         precache_sound("misc/powerup.wav");
1528         precache_sound("misc/poweroff.wav");
1529         precache_sound("weapons/weaponpickup.wav");
1530
1531         n = tokenize_console(self.netname);
1532         if(argv(0) == "give")
1533         {
1534                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1535         }
1536         else
1537         {
1538                 for(i = 0; i < n; ++i)
1539                 {
1540                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1541                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1542                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1543                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1544                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1545                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1546                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1547                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1548                         else
1549                         {
1550                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1551                                 {
1552                                         e = get_weaponinfo(j);
1553                                         if(argv(i) == e.netname)
1554                                         {
1555                                                 WEPSET_OR_EW(self, j);
1556                                                 if(self.spawnflags == 0 || self.spawnflags == 2)
1557                                                         weapon_action(e.weapon, WR_PRECACHE);
1558                                                 break;
1559                                         }
1560                                 }
1561                                 if(j > WEP_LAST)
1562                                         print("target_items: invalid item ", argv(i), "\n");
1563                         }
1564                 }
1565
1566                 string itemprefix, valueprefix;
1567                 if(self.spawnflags == 0)
1568                 {
1569                         itemprefix = "";
1570                         valueprefix = "";
1571                 }
1572                 else if(self.spawnflags == 1)
1573                 {
1574                         itemprefix = "max ";
1575                         valueprefix = "max ";
1576                 }
1577                 else if(self.spawnflags == 2)
1578                 {
1579                         itemprefix = "min ";
1580                         valueprefix = "min ";
1581                 }
1582                 else if(self.spawnflags == 4)
1583                 {
1584                         itemprefix = "minus ";
1585                         valueprefix = "max ";
1586                 }
1587                 else
1588                 {
1589                         error("invalid spawnflags");
1590 #ifdef GMQCC
1591                         itemprefix = string_null;
1592                         valueprefix = string_null;
1593 #endif
1594                 }
1595
1596                 self.netname = "";
1597                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1598                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1599                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1600                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1601                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * !!(self.items & IT_SUPERWEAPON), "superweapons");
1602                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1603                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1604                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1605                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1606                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1607                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1608                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1609                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1610                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1611                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1612                 {
1613                         e = get_weaponinfo(j);
1614                         if(e.weapon)
1615                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, WEPSET_CONTAINS_EW(self, j), e.netname);
1616                 }
1617         }
1618         self.netname = strzone(self.netname);
1619         //print(self.netname, "\n");
1620
1621         n = tokenize_console(self.netname);
1622         for(i = 0; i < n; ++i)
1623         {
1624                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1625                 {
1626                         e = get_weaponinfo(j);
1627                         if(argv(i) == e.netname)
1628                         {
1629                                 weapon_action(e.weapon, WR_PRECACHE);
1630                                 break;
1631                         }
1632                 }
1633         }
1634 }
1635
1636 void spawnfunc_item_fuel(void)
1637 {
1638         if(!self.ammo_fuel)
1639                 self.ammo_fuel = g_pickup_fuel;
1640         if(!self.pickup_anyway)
1641                 self.pickup_anyway = g_pickup_ammo_anyway;
1642         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1643 }
1644
1645 void spawnfunc_item_fuel_regen(void)
1646 {
1647         if(start_items & IT_FUEL_REGEN)
1648         {
1649                 spawnfunc_item_fuel();
1650                 return;
1651         }
1652         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1653 }
1654
1655 void spawnfunc_item_jetpack(void)
1656 {
1657         if(g_grappling_hook)
1658                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1659         if(!self.ammo_fuel)
1660                 self.ammo_fuel = g_pickup_fuel_jetpack;
1661         if(start_items & IT_JETPACK)
1662         {
1663                 spawnfunc_item_fuel();
1664                 return;
1665         }
1666         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1667 }
1668
1669
1670 #define OP_SET 0
1671 #define OP_MIN 1
1672 #define OP_MAX 2
1673 #define OP_PLUS 3
1674 #define OP_MINUS 4
1675
1676 float GiveWeapon(entity e, float wpn, float op, float val)
1677 {
1678         float v0, v1;
1679         v0 = WEPSET_CONTAINS_EW(e, wpn);
1680         switch(op)
1681         {
1682                 case OP_SET:
1683                         if(val > 0)
1684                                 WEPSET_OR_EW(e, wpn);
1685                         else
1686                                 WEPSET_ANDNOT_EW(e, wpn);
1687                         break;
1688                 case OP_MIN:
1689                 case OP_PLUS:
1690                         if(val > 0)
1691                                 WEPSET_OR_EW(e, wpn);
1692                         break;
1693                 case OP_MAX:
1694                         if(val <= 0)
1695                                 WEPSET_ANDNOT_EW(e, wpn);
1696                         break;
1697                 case OP_MINUS:
1698                         if(val > 0)
1699                                 WEPSET_ANDNOT_EW(e, wpn);
1700                         break;
1701         }
1702         v1 = WEPSET_CONTAINS_EW(e, wpn);
1703         return (v0 != v1);
1704 }
1705
1706 float GiveBit(entity e, .float fld, float bit, float op, float val)
1707 {
1708         float v0, v1;
1709         v0 = (e.fld & bit);
1710         switch(op)
1711         {
1712                 case OP_SET:
1713                         if(val > 0)
1714                                 e.fld |= bit;
1715                         else
1716                                 e.fld &~= bit;
1717                         break;
1718                 case OP_MIN:
1719                 case OP_PLUS:
1720                         if(val > 0)
1721                                 e.fld |= bit;
1722                         break;
1723                 case OP_MAX:
1724                         if(val <= 0)
1725                                 e.fld &~= bit;
1726                         break;
1727                 case OP_MINUS:
1728                         if(val > 0)
1729                                 e.fld &~= bit;
1730                         break;
1731         }
1732         v1 = (e.fld & bit);
1733         return (v0 != v1);
1734 }
1735
1736 float GiveValue(entity e, .float fld, float op, float val)
1737 {
1738         float v0, v1;
1739         v0 = e.fld;
1740         switch(op)
1741         {
1742                 case OP_SET:
1743                         e.fld = val;
1744                         break;
1745                 case OP_MIN:
1746                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1747                         break;
1748                 case OP_MAX:
1749                         e.fld = min(e.fld, val);
1750                         break;
1751                 case OP_PLUS:
1752                         e.fld += val;
1753                         break;
1754                 case OP_MINUS:
1755                         e.fld -= val;
1756                         break;
1757         }
1758         v1 = e.fld;
1759         return (v0 != v1);
1760 }
1761
1762 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1763 {
1764         if(v1 == v0)
1765                 return;
1766         if(v1 <= v0 - t)
1767         {
1768                 if(snd_decr != "")
1769                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTN_NORM);
1770         }
1771         else if(v0 >= v0 + t)
1772         {
1773                 if(snd_incr != "")
1774                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTN_NORM);
1775         }
1776 }
1777
1778 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1779 {
1780         if(v0 < v1)
1781                 e.rotfield = max(e.rotfield, time + rottime);
1782         else if(v0 > v1)
1783                 e.regenfield = max(e.regenfield, time + regentime);
1784 }
1785
1786 #define PREGIVE_WEAPONS(e) WEPSET_DECLARE_A(save_weapons); WEPSET_COPY_AE(save_weapons, e)
1787 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1788 #define POSTGIVE_WEAPON(e,b,snd_incr,snd_decr) GiveSound((e), WEPSET_CONTAINS_AW(save_weapons, b), WEPSET_CONTAINS_EW(e, b), 0, snd_incr, snd_decr)
1789 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1790 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1791 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1792
1793 float GiveItems(entity e, float beginarg, float endarg)
1794 {
1795         float got, i, j, val, op;
1796         float _switchweapon;
1797         entity wi;
1798         string cmd;
1799
1800         val = 999;
1801         op = OP_SET;
1802
1803         got = 0;
1804
1805         _switchweapon = FALSE;
1806         if (e.autoswitch)
1807                 if (e.switchweapon == w_getbestweapon(e))
1808                         _switchweapon = TRUE;
1809
1810         e.strength_finished = max(0, e.strength_finished - time);
1811         e.invincible_finished = max(0, e.invincible_finished - time);
1812         e.superweapons_finished = max(0, e.superweapons_finished - time);
1813
1814         PREGIVE(e, items);
1815         PREGIVE_WEAPONS(e);
1816         PREGIVE(e, strength_finished);
1817         PREGIVE(e, invincible_finished);
1818         PREGIVE(e, superweapons_finished);
1819         PREGIVE(e, ammo_nails);
1820         PREGIVE(e, ammo_cells);
1821         PREGIVE(e, ammo_shells);
1822         PREGIVE(e, ammo_rockets);
1823         PREGIVE(e, ammo_fuel);
1824         PREGIVE(e, armorvalue);
1825         PREGIVE(e, health);
1826
1827         for(i = beginarg; i < endarg; ++i)
1828         {
1829                 cmd = argv(i);
1830
1831                 if(cmd == "0" || stof(cmd))
1832                 {
1833                         val = stof(cmd);
1834                         continue;
1835                 }
1836                 switch(cmd)
1837                 {
1838                         case "no":
1839                                 op = OP_MAX;
1840                                 val = 0;
1841                                 continue;
1842                         case "max":
1843                                 op = OP_MAX;
1844                                 continue;
1845                         case "min":
1846                                 op = OP_MIN;
1847                                 continue;
1848                         case "plus":
1849                                 op = OP_PLUS;
1850                                 continue;
1851                         case "minus":
1852                                 op = OP_MINUS;
1853                                 continue;
1854                         case "ALL":
1855                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1856                                 got += GiveValue(e, strength_finished, op, val);
1857                                 got += GiveValue(e, invincible_finished, op, val);
1858                                 got += GiveValue(e, superweapons_finished, op, val);
1859                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1860                         case "all":
1861                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1862                                 got += GiveValue(e, health, op, val);
1863                                 got += GiveValue(e, armorvalue, op, val);
1864                         case "allweapons":
1865                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1866                                 {
1867                                         wi = get_weaponinfo(j);
1868                                         if(wi.weapon)
1869                                                 if not(wi.spawnflags & WEP_FLAG_MUTATORBLOCKED)
1870                                                         got += GiveWeapon(e, j, op, val);
1871                                 }
1872                         case "allammo":
1873                                 got += GiveValue(e, ammo_cells, op, val);
1874                                 got += GiveValue(e, ammo_shells, op, val);
1875                                 got += GiveValue(e, ammo_nails, op, val);
1876                                 got += GiveValue(e, ammo_rockets, op, val);
1877                                 got += GiveValue(e, ammo_fuel, op, val);
1878                                 break;
1879                         case "unlimited_ammo":
1880                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1881                                 break;
1882                         case "unlimited_weapon_ammo":
1883                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1884                                 break;
1885                         case "unlimited_superweapons":
1886                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1887                                 break;
1888                         case "jetpack":
1889                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1890                                 break;
1891                         case "fuel_regen":
1892                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1893                                 break;
1894                         case "strength":
1895                                 got += GiveValue(e, strength_finished, op, val);
1896                                 break;
1897                         case "invincible":
1898                                 got += GiveValue(e, invincible_finished, op, val);
1899                                 break;
1900                         case "superweapons":
1901                                 got += GiveValue(e, superweapons_finished, op, val);
1902                                 break;
1903                         case "cells":
1904                                 got += GiveValue(e, ammo_cells, op, val);
1905                                 break;
1906                         case "shells":
1907                                 got += GiveValue(e, ammo_shells, op, val);
1908                                 break;
1909                         case "nails":
1910                         case "bullets":
1911                                 got += GiveValue(e, ammo_nails, op, val);
1912                                 break;
1913                         case "rockets":
1914                                 got += GiveValue(e, ammo_rockets, op, val);
1915                                 break;
1916                         case "health":
1917                                 got += GiveValue(e, health, op, val);
1918                                 break;
1919                         case "armor":
1920                                 got += GiveValue(e, armorvalue, op, val);
1921                                 break;
1922                         case "fuel":
1923                                 got += GiveValue(e, ammo_fuel, op, val);
1924                                 break;
1925                         default:
1926                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1927                                 {
1928                                         wi = get_weaponinfo(j);
1929                                         if(cmd == wi.netname)
1930                                         {
1931                                                 got += GiveWeapon(e, j, op, val);
1932                                                 break;
1933                                         }
1934                                 }
1935                                 if(j > WEP_LAST)
1936                                         print("give: invalid item ", cmd, "\n");
1937                                 break;
1938                 }
1939                 val = 999;
1940                 op = OP_SET;
1941         }
1942
1943         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1944         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1945         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1946         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1947         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1948         {
1949                 wi = get_weaponinfo(j);
1950                 if(wi.weapon)
1951                 {
1952                         POSTGIVE_WEAPON(e, j, "weapons/weaponpickup.wav", string_null);
1953                         if not(WEPSET_CONTAINS_AW(save_weapons, j))
1954                                 if(WEPSET_CONTAINS_EW(e, j))
1955                                         weapon_action(wi.weapon, WR_PRECACHE);
1956                 }
1957         }
1958         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1959         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1960         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1961         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1962         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1963         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1964         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
1965         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
1966         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
1967
1968         if(e.superweapons_finished <= 0)
1969                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1970                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1971
1972         if(e.strength_finished <= 0)
1973                 e.strength_finished = 0;
1974         else
1975                 e.strength_finished += time;
1976         if(e.invincible_finished <= 0)
1977                 e.invincible_finished = 0;
1978         else
1979                 e.invincible_finished += time;
1980         if(e.superweapons_finished <= 0)
1981                 e.superweapons_finished = 0;
1982         else
1983                 e.superweapons_finished += time;
1984
1985         if not(WEPSET_CONTAINS_EW(e, e.switchweapon))
1986                 _switchweapon = TRUE;
1987         if(_switchweapon)
1988                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1989
1990         return got;
1991 }
1992 #endif