qcsrc/server/teamplay.qc

   1 string cache_mutatormsg;
   2 string cache_lastmutatormsg;
   3
   4 // client counts for each team
   5 float c1, c2, c3, c4;
   6 // # of bots on those teams
   7 float cb1, cb2, cb3, cb4;
   8
   9 //float audit_teams_time;
  10
  11 void TeamchangeFrags(entity e)
  12 {
  13         PlayerScore_Clear(e);
  14 }
  15
  16 void tdm_init();
  17 void entcs_init();
  18
  19 void LogTeamchange(float player_id, float team_number, float type)
  20 {
  21         if(!autocvar_sv_eventlog)
  22                 return;
  23
  24         if(player_id < 1)
  25                 return;
  26
  27         GameLogEcho(strcat(":team:", ftos(player_id), ":", ftos(team_number), ":", ftos(type)));
  28 }
  29
  30 void default_delayedinit()
  31 {
  32         if(!scores_initialized)
  33                 ScoreRules_generic();
  34 }
  35
  36 void ActivateTeamplay()
  37 {
  38         serverflags |= SERVERFLAG_TEAMPLAY;
  39         teamplay = 1;
  40 }
  41
  42 void InitGameplayMode()
  43 {
  44         float fraglimit_override, timelimit_override, leadlimit_override, qualifying_override;
  45
  46         qualifying_override = -1;
  47
  48         VoteReset();
  49
  50         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
  51         get_mi_min_max(1);
  52         world.mins = mi_min;
  53         world.maxs = mi_max;
  54
  55         MapInfo_LoadMapSettings(mapname);
  56         teamplay = 0;
  57         serverflags &~= SERVERFLAG_TEAMPLAY;
  58
  59         if not(cvar_value_issafe(world.fog))
  60         {
  61                 print("The current map contains a potentially harmful fog setting, ignored\n");
  62                 world.fog = string_null;
  63         }
  64         if(MapInfo_Map_fog != "")
  65                 if(MapInfo_Map_fog == "none")
  66                         world.fog = string_null;
  67                 else
  68                         world.fog = strzone(MapInfo_Map_fog);
  69         clientstuff = strzone(MapInfo_Map_clientstuff);
  70
  71         MapInfo_ClearTemps();
  72
  73         // set both here, gamemode can override it later
  74         timelimit_override = autocvar_timelimit_override;
  75         fraglimit_override = autocvar_fraglimit_override;
  76         leadlimit_override = autocvar_leadlimit_override;
  77         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
  78
  79         if(g_dm)
  80         {
  81         }
  82
  83         if(g_tdm)
  84         {
  85                 ActivateTeamplay();
  86                 tdm_init();
  87                 if(autocvar_g_tdm_team_spawns)
  88                         have_team_spawns = -1; // request team spawns
  89         }
  90
  91         if(g_domination)
  92         {
  93                 ActivateTeamplay();
  94                 fraglimit_override = autocvar_g_domination_point_limit;
  95                 leadlimit_override = autocvar_g_domination_point_leadlimit;
  96                 MUTATOR_ADD(gamemode_domination);
  97                 have_team_spawns = -1; // request team spawns
  98         }
  99
 100         if(g_ctf)
 101         {
 102                 ActivateTeamplay();
 103                 fraglimit_override = autocvar_capturelimit_override;
 104                 leadlimit_override = autocvar_captureleadlimit_override;
 105                 MUTATOR_ADD(gamemode_ctf);
 106                 have_team_spawns = -1; // request team spawns
 107         }
 108
 109         if(g_td)
 110         {
 111                 fraglimit_override = 0; // no limits in TD - it's a survival mode
 112                 leadlimit_override = 0;
 113                 MUTATOR_ADD(gamemode_td);
 114         }
 115
 116         if(g_lms)
 117         {
 118                 fraglimit_override = autocvar_g_lms_lives_override;
 119                 leadlimit_override = 0; // not supported by LMS
 120                 if(fraglimit_override == 0)
 121                         fraglimit_override = -1;
 122                 lms_lowest_lives = 9999;
 123                 lms_next_place = 0;
 124                 ScoreRules_lms();
 125         }
 126
 127         if(g_arena)
 128         {
 129                 fraglimit_override = autocvar_g_arena_point_limit;
 130                 leadlimit_override = autocvar_g_arena_point_leadlimit;
 131                 maxspawned = autocvar_g_arena_maxspawned;
 132                 if(maxspawned < 2)
 133                         maxspawned = 2;
 134                 arena_roundbased = autocvar_g_arena_roundbased;
 135         }
 136
 137         if(g_ca)
 138         {
 139                 ActivateTeamplay();
 140                 fraglimit_override = autocvar_g_ca_point_limit;
 141                 leadlimit_override = autocvar_g_ca_point_leadlimit;
 142                 precache_sound("ctf/red_capture.wav");
 143                 precache_sound("ctf/blue_capture.wav");
 144         }
 145         if(g_keyhunt)
 146         {
 147                 ActivateTeamplay();
 148                 fraglimit_override = autocvar_g_keyhunt_point_limit;
 149                 leadlimit_override = autocvar_g_keyhunt_point_leadlimit;
 150                 MUTATOR_ADD(gamemode_keyhunt);
 151         }
 152
 153         if(g_freezetag)
 154         {
 155                 ActivateTeamplay();
 156                 fraglimit_override = autocvar_g_freezetag_point_limit;
 157                 leadlimit_override = autocvar_g_freezetag_point_leadlimit;
 158                 MUTATOR_ADD(gamemode_freezetag);
 159         }
 160
 161         if(g_assault)
 162         {
 163                 ActivateTeamplay();
 164                 ScoreRules_assault();
 165                 have_team_spawns = -1; // request team spawns
 166         }
 167
 168         if(g_onslaught)
 169         {
 170                 ActivateTeamplay();
 171                 have_team_spawns = -1; // request team spawns
 172                 MUTATOR_ADD(gamemode_onslaught);
 173         }
 174
 175         if(g_race)
 176         {
 177
 178                 if(autocvar_g_race_teams)
 179                 {
 180                         ActivateTeamplay();
 181                         race_teams = bound(2, autocvar_g_race_teams, 4);
 182                         have_team_spawns = -1; // request team spawns
 183                 }
 184                 else
 185                         race_teams = 0;
 186
 187                 qualifying_override = autocvar_g_race_qualifying_timelimit_override;
 188                 fraglimit_override = autocvar_g_race_laps_limit;
 189                 leadlimit_override = 0; // currently not supported by race
 190         }
 191
 192         if(g_cts)
 193         {
 194                 g_race_qualifying = 1;
 195                 fraglimit_override = 0;
 196                 leadlimit_override = 0;
 197         }
 198
 199         if(g_nexball)
 200         {
 201         fraglimit_override = autocvar_g_nexball_goallimit;
 202         leadlimit_override = autocvar_g_nexball_goalleadlimit;
 203         ActivateTeamplay();
 204         have_team_spawns = -1; // request team spawns
 205             MUTATOR_ADD(gamemode_nexball);
 206         }
 207
 208         if(g_keepaway)
 209         {
 210                 MUTATOR_ADD(gamemode_keepaway);
 211         }
 212
 213         if(teamplay)
 214                 entcs_init();
 215
 216         cache_mutatormsg = strzone("");
 217         cache_lastmutatormsg = strzone("");
 218
 219         // enforce the server's universal frag/time limits
 220         if(!autocvar_g_campaign)
 221         {
 222                 if(fraglimit_override >= 0)
 223                         cvar_set("fraglimit", ftos(fraglimit_override));
 224                 if(timelimit_override >= 0)
 225                         cvar_set("timelimit", ftos(timelimit_override));
 226                 if(leadlimit_override >= 0)
 227                         cvar_set("leadlimit", ftos(leadlimit_override));
 228                 if(qualifying_override >= 0)
 229                         cvar_set("g_race_qualifying_timelimit", ftos(qualifying_override));
 230         }
 231
 232         if(g_race)
 233         {
 234                 // we need to find out the correct value for g_race_qualifying
 235                 if(autocvar_g_campaign)
 236                 {
 237                         g_race_qualifying = 1;
 238                 }
 239                 else if(!autocvar_g_campaign && autocvar_g_race_qualifying_timelimit > 0)
 240                 {
 241                         g_race_qualifying = 2;
 242                         race_fraglimit = autocvar_fraglimit;
 243                         race_leadlimit = autocvar_leadlimit;
 244                         race_timelimit = autocvar_timelimit;
 245                         cvar_set("fraglimit", "0");
 246                         cvar_set("leadlimit", "0");
 247                         cvar_set("timelimit", ftos(autocvar_g_race_qualifying_timelimit));
 248                 }
 249                 else
 250                         g_race_qualifying = 0;
 251         }
 252
 253         if(g_race || g_cts)
 254         {
 255                 if(g_race_qualifying)
 256                         independent_players = 1;
 257
 258                 ScoreRules_race();
 259         }
 260
 261         InitializeEntity(world, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 262 }
 263
 264 string GetClientVersionMessage() {
 265         string versionmsg;
 266         if (self.version_mismatch) {
 267                 if(self.version < autocvar_gameversion) {
 268                         versionmsg = "^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8";
 269                 } else {
 270                         versionmsg = "^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8";
 271                 }
 272         } else {
 273                 versionmsg = "^2client version and server version are compatible.^8";
 274         }
 275         return versionmsg;
 276 }
 277
 278 string getwelcomemessage(void)
 279 {
 280         string s, modifications, motd;
 281
 282         ret_string = "";
 283         MUTATOR_CALLHOOK(BuildMutatorsPrettyString);
 284         modifications = ret_string;
 285
 286         if(g_minstagib)
 287                 modifications = strcat(modifications, ", MinstaGib");
 288         if(g_weaponarena)
 289         {
 290                 if(g_weaponarena_random)
 291                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
 292                 else
 293                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
 294         }
 295         if(autocvar_g_start_weapon_laser == 0)
 296                 modifications = strcat(modifications, ", No start weapons");
 297         if(autocvar_sv_gravity < 800)
 298                 modifications = strcat(modifications, ", Low gravity");
 299         if(g_cloaked && !g_cts)
 300                 modifications = strcat(modifications, ", Cloaked");
 301         if(g_grappling_hook)
 302                 modifications = strcat(modifications, ", Hook");
 303         if(g_midair)
 304                 modifications = strcat(modifications, ", Midair");
 305         if(g_pinata)
 306                 modifications = strcat(modifications, ", Piñata");
 307         if(g_weapon_stay && !g_cts)
 308                 modifications = strcat(modifications, ", Weapons stay");
 309         if(g_bloodloss > 0)
 310                 modifications = strcat(modifications, ", Blood loss");
 311         if(g_jetpack)
 312                 modifications = strcat(modifications, ", Jet pack");
 313         if(autocvar_g_powerups == 0)
 314                 modifications = strcat(modifications, ", No powerups");
 315         if(autocvar_g_powerups > 0)
 316                 modifications = strcat(modifications, ", Powerups");
 317         modifications = substring(modifications, 2, strlen(modifications) - 2);
 318
 319         string versionmessage;
 320         versionmessage = GetClientVersionMessage();
 321
 322         s = strcat("This is Xonotic ", autocvar_g_xonoticversion, "\n", versionmessage);
 323         s = strcat(s, "^8\n\nmatch type is ^1", gamemode_name, "^8\n");
 324
 325         if(modifications != "")
 326                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
 327
 328         if (g_grappling_hook)
 329                 s = strcat(s, "\n\n^3grappling hook^8 is enabled, press 'e' to use it\n");
 330
 331         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
 332         {
 333                 if(cache_lastmutatormsg)
 334                         strunzone(cache_lastmutatormsg);
 335                 if(cache_mutatormsg)
 336                         strunzone(cache_mutatormsg);
 337                 cache_lastmutatormsg = strzone(autocvar_g_mutatormsg);
 338                 cache_mutatormsg = strzone(cache_lastmutatormsg);
 339         }
 340
 341         if (cache_mutatormsg != "") {
 342                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
 343         }
 344
 345         motd = autocvar_sv_motd;
 346         if (motd != "") {
 347                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
 348         }
 349         return s;
 350 }
 351
 352 void SetPlayerColors(entity pl, float _color)
 353 {
 354         /*string s;
 355         s = ftos(cl);
 356         stuffcmd(pl, strcat("color ", s, " ", s, "\n")  );
 357         pl.team = cl + 1;
 358         //pl.clientcolors = pl.clientcolors - (pl.clientcolors & 15) + cl;
 359         pl.clientcolors = 16*cl + cl;*/
 360
 361         float pants, shirt;
 362         pants = _color & 0x0F;
 363         shirt = _color & 0xF0;
 364
 365
 366         if(teamplay) {
 367                 setcolor(pl, 16*pants + pants);
 368         } else {
 369                 setcolor(pl, shirt + pants);
 370         }
 371 }
 372
 373 void SetPlayerTeam(entity pl, float t, float s, float noprint)
 374 {
 375         float _color;
 376
 377         if(t == 4)
 378                 _color = NUM_TEAM_4 - 1;
 379         else if(t == 3)
 380                 _color = NUM_TEAM_3 - 1;
 381         else if(t == 2)
 382                 _color = NUM_TEAM_2 - 1;
 383         else
 384                 _color = NUM_TEAM_1 - 1;
 385
 386         SetPlayerColors(pl,_color);
 387
 388         if(t != s) {
 389                 LogTeamchange(pl.playerid, pl.team, 3);  // log manual team join
 390
 391                 if(!noprint)
 392                 bprint(pl.netname, "^7 has changed from ", Team_NumberToColoredFullName(s), "^7 to ", Team_NumberToColoredFullName(t), "\n");
 393         }
 394
 395 }
 396
 397 // set c1...c4 to show what teams are allowed
 398 void CheckAllowedTeams (entity for_whom)
 399 {
 400         float dm;
 401         entity head;
 402         string teament_name;
 403
 404         c1 = c2 = c3 = c4 = -1;
 405         cb1 = cb2 = cb3 = cb4 = 0;
 406
 407         teament_name = string_null;
 408         if(g_onslaught)
 409         {
 410                 // onslaught is special
 411                 head = findchain(classname, "onslaught_generator");
 412                 while (head)
 413                 {
 414                         if (head.team == NUM_TEAM_1) c1 = 0;
 415                         if (head.team == NUM_TEAM_2) c2 = 0;
 416                         if (head.team == NUM_TEAM_3) c3 = 0;
 417                         if (head.team == NUM_TEAM_4) c4 = 0;
 418                         head = head.chain;
 419                 }
 420         }
 421         else if(g_domination)
 422                 teament_name = "dom_team";
 423         else if(g_ctf)
 424                 teament_name = "ctf_team";
 425         else if(g_tdm)
 426                 teament_name = "tdm_team";
 427         else if(g_nexball)
 428                 teament_name = "nexball_team";
 429         else if(g_assault)
 430                 c1 = c2 = 0; // Assault always has 2 teams
 431         else
 432         {
 433                 // cover anything else by treating it like tdm with no teams spawned
 434                 if(g_race)
 435                         dm = race_teams;
 436                 else
 437                         dm = 2;
 438
 439                 ret_float = dm;
 440                 MUTATOR_CALLHOOK(GetTeamCount);
 441                 dm = ret_float;
 442
 443                 if(dm >= 4)
 444                         c1 = c2 = c3 = c4 = 0;
 445                 else if(dm >= 3)
 446                         c1 = c2 = c3 = 0;
 447                 else
 448                         c1 = c2 = 0;
 449         }
 450
 451         // find out what teams are allowed if necessary
 452         if(teament_name)
 453         {
 454                 head = find(world, classname, teament_name);
 455                 while(head)
 456                 {
 457                         if(!(g_domination && head.netname == ""))
 458                         {
 459                                 if(head.team == NUM_TEAM_1)
 460                                         c1 = 0;
 461                                 else if(head.team == NUM_TEAM_2)
 462                                         c2 = 0;
 463                                 else if(head.team == NUM_TEAM_3)
 464                                         c3 = 0;
 465                                 else if(head.team == NUM_TEAM_4)
 466                                         c4 = 0;
 467                         }
 468                         head = find(head, classname, teament_name);
 469                 }
 470         }
 471
 472         // TODO: Balance quantity of bots across > 2 teams when bot_vs_human is set (and remove next line)
 473         if(c3==-1 && c4==-1)
 474         if(autocvar_bot_vs_human && for_whom)
 475         {
 476                 if(autocvar_bot_vs_human > 0)
 477                 {
 478                         // bots are all blue
 479                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 480                                 c1 = c3 = c4 = -1;
 481                         else
 482                                 c2 = -1;
 483                 }
 484                 else
 485                 {
 486                         // bots are all red
 487                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 488                                 c2 = c3 = c4 = -1;
 489                         else
 490                                 c1 = -1;
 491                 }
 492         }
 493
 494         // if player has a forced team, ONLY allow that one
 495         if(self.team_forced == NUM_TEAM_1 && c1 >= 0)
 496                 c2 = c3 = c4 = -1;
 497         else if(self.team_forced == NUM_TEAM_2 && c2 >= 0)
 498                 c1 = c3 = c4 = -1;
 499         else if(self.team_forced == NUM_TEAM_3 && c3 >= 0)
 500                 c1 = c2 = c4 = -1;
 501         else if(self.team_forced == NUM_TEAM_4 && c4 >= 0)
 502                 c1 = c2 = c3 = -1;
 503 }
 504
 505 float PlayerValue(entity p)
 506 {
 507         return 1;
 508         // FIXME: it always returns 1...
 509 }
 510
 511 // c1...c4 should be set to -1 (not allowed) or 0 (allowed).
 512 // teams that are allowed will now have their player counts stored in c1...c4
 513 void GetTeamCounts(entity ignore)
 514 {
 515         entity head;
 516         float value, bvalue;
 517         // now count how many players are on each team already
 518
 519         // FIXME: also find and memorize the lowest-scoring bot on each team (in case players must be shuffled around)
 520         // also remember the lowest-scoring player
 521
 522         FOR_EACH_CLIENT(head)
 523         {
 524                 float t;
 525                 if(head.classname == "player")
 526                         t = head.team;
 527                 else if(head.team_forced > 0)
 528                         t = head.team_forced; // reserve the spot
 529                 else
 530                         continue;
 531                 if(head != ignore)// && head.netname != "")
 532                 {
 533                         value = PlayerValue(head);
 534                         if(clienttype(head) == CLIENTTYPE_BOT)
 535                                 bvalue = value;
 536                         else
 537                                 bvalue = 0;
 538                         if(t == NUM_TEAM_1)
 539                         {
 540                                 if(c1 >= 0)
 541                                 {
 542                                         c1 = c1 + value;
 543                                         cb1 = cb1 + bvalue;
 544                                 }
 545                         }
 546                         if(t == NUM_TEAM_2)
 547                         {
 548                                 if(c2 >= 0)
 549                                 {
 550                                         c2 = c2 + value;
 551                                         cb2 = cb2 + bvalue;
 552                                 }
 553                         }
 554                         if(t == NUM_TEAM_3)
 555                         {
 556                                 if(c3 >= 0)
 557                                 {
 558                                         c3 = c3 + value;
 559                                         cb3 = cb3 + bvalue;
 560                                 }
 561                         }
 562                         if(t == NUM_TEAM_4)
 563                         {
 564                                 if(c4 >= 0)
 565                                 {
 566                                         c4 = c4 + value;
 567                                         cb4 = cb4 + bvalue;
 568                                 }
 569                         }
 570                 }
 571         }
 572
 573         // if the player who has a forced team has not joined yet, reserve the spot
 574         if(autocvar_g_campaign)
 575         {
 576                 switch(autocvar_g_campaign_forceteam)
 577                 {
 578                         case 1: if(c1 == cb1) ++c1; break;
 579                         case 2: if(c2 == cb2) ++c2; break;
 580                         case 3: if(c3 == cb3) ++c3; break;
 581                         case 4: if(c4 == cb4) ++c4; break;
 582                 }
 583         }
 584 }
 585
 586 float TeamSmallerEqThanTeam(float ta, float tb, entity e)
 587 {
 588         // we assume that CheckAllowedTeams and GetTeamCounts have already been called
 589         float f;
 590         float ca = -1, cb = -1, cba = 0, cbb = 0, sa = 0, sb = 0;
 591
 592         switch(ta)
 593         {
 594                 case 1: ca = c1; cba = cb1; sa = team1_score; break;
 595                 case 2: ca = c2; cba = cb2; sa = team2_score; break;
 596                 case 3: ca = c3; cba = cb3; sa = team3_score; break;
 597                 case 4: ca = c4; cba = cb4; sa = team4_score; break;
 598         }
 599         switch(tb)
 600         {
 601                 case 1: cb = c1; cbb = cb1; sb = team1_score; break;
 602                 case 2: cb = c2; cbb = cb2; sb = team2_score; break;
 603                 case 3: cb = c3; cbb = cb3; sb = team3_score; break;
 604                 case 4: cb = c4; cbb = cb4; sb = team4_score; break;
 605         }
 606
 607         // invalid
 608         if(ca < 0 || cb < 0)
 609                 return FALSE;
 610
 611         // equal
 612         if(ta == tb)
 613                 return TRUE;
 614
 615         if(clienttype(e) == CLIENTTYPE_REAL)
 616         {
 617                 if(bots_would_leave)
 618                 {
 619                         ca -= cba * 0.999;
 620                         cb -= cbb * 0.999;
 621                 }
 622         }
 623
 624         // keep teams alive (teams of size 0 always count as smaller, ignoring score)
 625         if(ca < 1)
 626                 if(cb >= 1)
 627                         return TRUE;
 628         if(ca >= 1)
 629                 if(cb < 1)
 630                         return FALSE;
 631
 632         // first, normalize
 633         f = max(ca, cb, 1);
 634         ca /= f;
 635         cb /= f;
 636         f = max(sa, sb, 1);
 637         sa /= f;
 638         sb /= f;
 639
 640         // the more we're at the end of the match, the more take scores into account
 641         f = bound(0, game_completion_ratio * autocvar_g_balance_teams_scorefactor, 1);
 642         ca += (sa - ca) * f;
 643         cb += (sb - cb) * f;
 644
 645         return ca <= cb;
 646 }
 647
 648 // returns # of smallest team (1, 2, 3, 4)
 649 // NOTE: Assumes CheckAllowedTeams has already been called!
 650 float FindSmallestTeam(entity pl, float ignore_pl)
 651 {
 652         float totalteams, t;
 653         totalteams = 0;
 654
 655         // find out what teams are available
 656         //CheckAllowedTeams();
 657
 658         // make sure there are at least 2 teams to join
 659         if(c1 >= 0)
 660                 totalteams = totalteams + 1;
 661         if(c2 >= 0)
 662                 totalteams = totalteams + 1;
 663         if(c3 >= 0)
 664                 totalteams = totalteams + 1;
 665         if(c4 >= 0)
 666                 totalteams = totalteams + 1;
 667
 668         if((autocvar_bot_vs_human || pl.team_forced > 0) && totalteams == 1)
 669                 totalteams += 1;
 670
 671         if(totalteams <= 1)
 672         {
 673                 if(autocvar_g_campaign && pl && clienttype(pl) == CLIENTTYPE_REAL)
 674                         return 1; // special case for campaign and player joining
 675                 else if(g_domination)
 676                         error("Too few teams available for domination\n");
 677                 else if(g_ctf)
 678                         error("Too few teams available for ctf\n");
 679                 else if(g_keyhunt)
 680                         error("Too few teams available for key hunt\n");
 681                 else if(g_freezetag)
 682                         error("Too few teams available for freeze tag\n");
 683                 else
 684                         error("Too few teams available for team deathmatch\n");
 685         }
 686
 687         // count how many players are in each team
 688         if(ignore_pl)
 689                 GetTeamCounts(pl);
 690         else
 691                 GetTeamCounts(world);
 692
 693         RandomSelection_Init();
 694
 695         t = 1;
 696         if(TeamSmallerEqThanTeam(2, t, pl))
 697                 t = 2;
 698         if(TeamSmallerEqThanTeam(3, t, pl))
 699                 t = 3;
 700         if(TeamSmallerEqThanTeam(4, t, pl))
 701                 t = 4;
 702
 703         // now t is the minimum, or A minimum!
 704         if(t == 1 || TeamSmallerEqThanTeam(1, t, pl))
 705                 RandomSelection_Add(world, 1, string_null, 1, 1);
 706         if(t == 2 || TeamSmallerEqThanTeam(2, t, pl))
 707                 RandomSelection_Add(world, 2, string_null, 1, 1);
 708         if(t == 3 || TeamSmallerEqThanTeam(3, t, pl))
 709                 RandomSelection_Add(world, 3, string_null, 1, 1);
 710         if(t == 4 || TeamSmallerEqThanTeam(4, t, pl))
 711                 RandomSelection_Add(world, 4, string_null, 1, 1);
 712
 713         return RandomSelection_chosen_float;
 714 }
 715
 716 float JoinBestTeam(entity pl, float only_return_best, float forcebestteam)
 717 {
 718         float smallest, selectedteam;
 719
 720         // don't join a team if we're not playing a team game
 721         if(!teamplay)
 722                 return 0;
 723
 724         // find out what teams are available
 725         CheckAllowedTeams(pl);
 726
 727         // if we don't care what team he ends up on, put him on whatever team he entered as.
 728         // if he's not on a valid team, then let other code put him on the smallest team
 729         if(!forcebestteam)
 730         {
 731                 if(     c1 >= 0 && pl.team == NUM_TEAM_1)
 732                         selectedteam = pl.team;
 733                 else if(c2 >= 0 && pl.team == NUM_TEAM_2)
 734                         selectedteam = pl.team;
 735                 else if(c3 >= 0 && pl.team == NUM_TEAM_3)
 736                         selectedteam = pl.team;
 737                 else if(c4 >= 0 && pl.team == NUM_TEAM_4)
 738                         selectedteam = pl.team;
 739                 else
 740                         selectedteam = -1;
 741
 742                 if(selectedteam > 0)
 743                 {
 744                         if(!only_return_best)
 745                         {
 746                                 SetPlayerColors(pl, selectedteam - 1);
 747
 748                                 // when JoinBestTeam is called by client.qc/ClientKill_Now_TeamChange the players team is -1 and thus skipped
 749                                 // when JoinBestTeam is called by cl_client.qc/ClientConnect the player_id is 0 the log attempt is rejected
 750                                 LogTeamchange(pl.playerid, pl.team, 99);
 751                         }
 752                         return selectedteam;
 753                 }
 754                 // otherwise end up on the smallest team (handled below)
 755         }
 756
 757         smallest = FindSmallestTeam(pl, TRUE);
 758
 759         if(!only_return_best && !pl.bot_forced_team)
 760         {
 761                 TeamchangeFrags(self);
 762                 if(smallest == 1)
 763                 {
 764                         SetPlayerColors(pl, NUM_TEAM_1 - 1);
 765                 }
 766                 else if(smallest == 2)
 767                 {
 768                         SetPlayerColors(pl, NUM_TEAM_2 - 1);
 769                 }
 770                 else if(smallest == 3)
 771                 {
 772                         SetPlayerColors(pl, NUM_TEAM_3 - 1);
 773                 }
 774                 else if(smallest == 4)
 775                 {
 776                         SetPlayerColors(pl, NUM_TEAM_4 - 1);
 777                 }
 778                 else
 779                 {
 780                         error("smallest team: invalid team\n");
 781                 }
 782
 783                 LogTeamchange(pl.playerid, pl.team, 2); // log auto join
 784
 785                 if(pl.deadflag == DEAD_NO)
 786                         Damage(pl, pl, pl, 100000, DEATH_TEAMCHANGE, pl.origin, '0 0 0');
 787         }
 788
 789         return smallest;
 790 }
 791
 792 //void() ctf_playerchanged;
 793 void SV_ChangeTeam(float _color)
 794 {
 795         float scolor, dcolor, steam, dteam; //, dbotcount, scount, dcount;
 796
 797         // in normal deathmatch we can just apply the color and we're done
 798         if(!teamplay) {
 799                 SetPlayerColors(self, _color);
 800                 return;
 801         }
 802
 803         scolor = self.clientcolors & 0x0F;
 804         dcolor = _color & 0x0F;
 805
 806         if(scolor == NUM_TEAM_1 - 1)
 807                 steam = 1;
 808         else if(scolor == NUM_TEAM_2 - 1)
 809                 steam = 2;
 810         else if(scolor == NUM_TEAM_3 - 1)
 811                 steam = 3;
 812         else // if(scolor == NUM_TEAM_4 - 1)
 813                 steam = 4;
 814         if(dcolor == NUM_TEAM_1 - 1)
 815                 dteam = 1;
 816         else if(dcolor == NUM_TEAM_2 - 1)
 817                 dteam = 2;
 818         else if(dcolor == NUM_TEAM_3 - 1)
 819                 dteam = 3;
 820         else // if(dcolor == NUM_TEAM_4 - 1)
 821                 dteam = 4;
 822
 823         CheckAllowedTeams(self);
 824
 825         if(dteam == 1 && c1 < 0) dteam = 4;
 826         if(dteam == 4 && c4 < 0) dteam = 3;
 827         if(dteam == 3 && c3 < 0) dteam = 2;
 828         if(dteam == 2 && c2 < 0) dteam = 1;
 829
 830         // not changing teams
 831         if(scolor == dcolor)
 832         {
 833                 //bprint("same team change\n");
 834                 SetPlayerTeam(self, dteam, steam, TRUE);
 835                 return;
 836         }
 837
 838         if((autocvar_g_campaign) || (autocvar_g_changeteam_banned && self.wasplayer)) {
 839                 sprint(self, "Team changes not allowed\n");
 840                 return; // changing teams is not allowed
 841         }
 842
 843         // autocvar_g_balance_teams_prevent_imbalance only makes sense if autocvar_g_balance_teams is on, as it makes the team selection dialog pointless
 844         if(autocvar_g_balance_teams && autocvar_g_balance_teams_prevent_imbalance)
 845         {
 846                 GetTeamCounts(self);
 847                 if(!TeamSmallerEqThanTeam(dteam, steam, self))
 848                 {
 849                         sprint(self, "Cannot change to a larger/better/shinier team\n");
 850                         return;
 851                 }
 852         }
 853
 854 //      bprint("allow change teams from ", ftos(steam), " to ", ftos(dteam), "\n");
 855
 856         if(self.classname == "player" && steam != dteam)
 857         {
 858                 // reduce frags during a team change
 859                 TeamchangeFrags(self);
 860         }
 861
 862         SetPlayerTeam(self, dteam, steam, FALSE);
 863
 864         if(self.classname == "player" && steam != dteam)
 865         {
 866                 // kill player when changing teams
 867                 if(self.deadflag == DEAD_NO)
 868                         Damage(self, self, self, 100000, DEATH_TEAMCHANGE, self.origin, '0 0 0');
 869         }
 870 }
 871
 872 void ShufflePlayerOutOfTeam (float source_team)
 873 {
 874         float smallestteam, smallestteam_count, steam;
 875         float lowest_bot_score, lowest_player_score;
 876         entity head, lowest_bot, lowest_player, selected;
 877
 878         smallestteam = 0;
 879         smallestteam_count = 999999999;
 880
 881         if(c1 >= 0 && c1 < smallestteam_count)
 882         {
 883                 smallestteam = 1;
 884                 smallestteam_count = c1;
 885         }
 886         if(c2 >= 0 && c2 < smallestteam_count)
 887         {
 888                 smallestteam = 2;
 889                 smallestteam_count = c2;
 890         }
 891         if(c3 >= 0 && c3 < smallestteam_count)
 892         {
 893                 smallestteam = 3;
 894                 smallestteam_count = c3;
 895         }
 896         if(c4 >= 0 && c4 < smallestteam_count)
 897         {
 898                 smallestteam = 4;
 899                 smallestteam_count = c4;
 900         }
 901
 902         if(!smallestteam)
 903         {
 904                 bprint("warning: no smallest team\n");
 905                 return;
 906         }
 907
 908         if(source_team == 1)
 909                 steam = NUM_TEAM_1;
 910         else if(source_team == 2)
 911                 steam = NUM_TEAM_2;
 912         else if(source_team == 3)
 913                 steam = NUM_TEAM_3;
 914         else // if(source_team == 4)
 915                 steam = NUM_TEAM_4;
 916
 917         lowest_bot = world;
 918         lowest_bot_score = 999999999;
 919         lowest_player = world;
 920         lowest_player_score = 999999999;
 921
 922         // find the lowest-scoring player & bot of that team
 923         FOR_EACH_PLAYER(head)
 924         {
 925                 if(head.team == steam)
 926                 {
 927                         if(head.isbot)
 928                         {
 929                                 if(head.totalfrags < lowest_bot_score)
 930                                 {
 931                                         lowest_bot = head;
 932                                         lowest_bot_score = head.totalfrags;
 933                                 }
 934                         }
 935                         else
 936                         {
 937                                 if(head.totalfrags < lowest_player_score)
 938                                 {
 939                                         lowest_player = head;
 940                                         lowest_player_score = head.totalfrags;
 941                                 }
 942                         }
 943                 }
 944         }
 945
 946         // prefers to move a bot...
 947         if(lowest_bot != world)
 948                 selected = lowest_bot;
 949         // but it will move a player if it has to
 950         else
 951                 selected = lowest_player;
 952         // don't do anything if it couldn't find anyone
 953         if(!selected)
 954         {
 955                 bprint("warning: couldn't find a player to move from team\n");
 956                 return;
 957         }
 958
 959         // smallest team gains a member
 960         if(smallestteam == 1)
 961         {
 962                 c1 = c1 + 1;
 963         }
 964         else if(smallestteam == 2)
 965         {
 966                 c2 = c2 + 1;
 967         }
 968         else if(smallestteam == 3)
 969         {
 970                 c3 = c3 + 1;
 971         }
 972         else if(smallestteam == 4)
 973         {
 974                 c4 = c4 + 1;
 975         }
 976         else
 977         {
 978                 bprint("warning: destination team invalid\n");
 979                 return;
 980         }
 981         // source team loses a member
 982         if(source_team == 1)
 983         {
 984                 c1 = c1 + 1;
 985         }
 986         else if(source_team == 2)
 987         {
 988                 c2 = c2 + 2;
 989         }
 990         else if(source_team == 3)
 991         {
 992                 c3 = c3 + 3;
 993         }
 994         else if(source_team == 4)
 995         {
 996                 c4 = c4 + 4;
 997         }
 998         else
 999         {
1000                 bprint("warning: source team invalid\n");
1001                 return;
1002         }
1003
1004         // move the player to the new team
1005         TeamchangeFrags(selected);
1006         SetPlayerTeam(selected, smallestteam, source_team, FALSE);
1007
1008         if(selected.deadflag == DEAD_NO)
1009                 Damage(selected, selected, selected, 100000, DEATH_AUTOTEAMCHANGE, selected.origin, '0 0 0');
1010         centerprint(selected, strcat("You have been moved into a different team to improve team balance\nYou are now on: ", Team_ColoredFullName(selected.team)));
1011 }
1012
1013 // code from here on is just to support maps that don't have team entities
1014 void tdm_spawnteam (string teamname, float teamcolor)
1015 {
1016         entity e;
1017         e = spawn();
1018         e.classname = "tdm_team";
1019         e.netname = teamname;
1020         e.cnt = teamcolor;
1021         e.team = e.cnt + 1;
1022 }
1023
1024 // spawn some default teams if the map is not set up for tdm
1025 void tdm_spawnteams()
1026 {
1027         float numteams;
1028
1029         numteams = autocvar_g_tdm_teams_override;
1030         if(numteams < 2)
1031                 numteams = autocvar_g_tdm_teams;
1032         numteams = bound(2, numteams, 4);
1033
1034         tdm_spawnteam("Red", NUM_TEAM_1-1);
1035         tdm_spawnteam("Blue", NUM_TEAM_2-1);
1036         if(numteams >= 3)
1037                 tdm_spawnteam("Yellow", NUM_TEAM_3-1);
1038         if(numteams >= 4)
1039                 tdm_spawnteam("Pink", NUM_TEAM_4-1);
1040 }
1041
1042 void tdm_delayedinit()
1043 {
1044         // if no teams are found, spawn defaults
1045         if (find(world, classname, "tdm_team") == world)
1046                 tdm_spawnteams();
1047 }
1048
1049 void tdm_init()
1050 {
1051         InitializeEntity(world, tdm_delayedinit, INITPRIO_GAMETYPE);
1052 }