qcsrc/server/teamplay.qc

   1 #include "teamplay.qh"
   2
   3 #include "client.qh"
   4 #include "race.qh"
   5 #include "scores.qh"
   6 #include "scores_rules.qh"
   7
   8 #include "bot/api.qh"
   9
  10 #include "command/vote.qh"
  11
  12 #include "mutators/_mod.qh"
  13
  14 #include "../common/deathtypes/all.qh"
  15 #include "../common/gamemodes/_mod.qh"
  16 #include "../common/teams.qh"
  17
  18 void TeamchangeFrags(entity e)
  19 {
  20         PlayerScore_Clear(e);
  21 }
  22
  23 void LogTeamchange(float player_id, float team_number, float type)
  24 {
  25         if(!autocvar_sv_eventlog)
  26                 return;
  27
  28         if(player_id < 1)
  29                 return;
  30
  31         GameLogEcho(strcat(":team:", ftos(player_id), ":", ftos(team_number), ":", ftos(type)));
  32 }
  33
  34 void default_delayedinit(entity this)
  35 {
  36         if(!scores_initialized)
  37                 ScoreRules_generic();
  38 }
  39
  40 void ActivateTeamplay()
  41 {
  42         serverflags |= SERVERFLAG_TEAMPLAY;
  43         teamplay = 1;
  44         cvar_set("teamplay", "2");  // DP needs this for sending proper getstatus replies.
  45 }
  46
  47 void InitGameplayMode()
  48 {
  49         VoteReset();
  50
  51         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
  52         get_mi_min_max(1);
  53         world.mins = mi_min;
  54         world.maxs = mi_max;
  55         // currently, NetRadiant's limit is 131072 qu for each side
  56         // distance from one corner of a 131072qu cube to the opposite corner is approx. 227023 qu
  57         // set the distance according to map size but don't go over the limit to avoid issues with float precision
  58         // in case somebody makes extremely large maps
  59         max_shot_distance = min(230000, vlen(world.maxs - world.mins));
  60
  61         MapInfo_LoadMapSettings(mapname);
  62         serverflags &= ~SERVERFLAG_TEAMPLAY;
  63         teamplay = 0;
  64         cvar_set("teamplay", "0");  // DP needs this for sending proper getstatus replies.
  65
  66         if (!cvar_value_issafe(world.fog))
  67         {
  68                 LOG_INFO("The current map contains a potentially harmful fog setting, ignored\n");
  69                 world.fog = string_null;
  70         }
  71         if(MapInfo_Map_fog != "")
  72                 if(MapInfo_Map_fog == "none")
  73                         world.fog = string_null;
  74                 else
  75                         world.fog = strzone(MapInfo_Map_fog);
  76         clientstuff = strzone(MapInfo_Map_clientstuff);
  77
  78         MapInfo_ClearTemps();
  79
  80         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
  81
  82         cache_mutatormsg = strzone("");
  83         cache_lastmutatormsg = strzone("");
  84
  85         InitializeEntity(NULL, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
  86 }
  87
  88 string GetClientVersionMessage(entity this)
  89 {
  90         if (this.version_mismatch) {
  91                 if(this.version < autocvar_gameversion) {
  92                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
  93                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
  94                 } else {
  95                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
  96                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
  97                 }
  98         } else {
  99                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
 100         }
 101 }
 102
 103 string getwelcomemessage(entity this)
 104 {
 105         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
 106         string modifications = M_ARGV(0, string);
 107
 108         if(g_weaponarena)
 109         {
 110                 if(g_weaponarena_random)
 111                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
 112                 else
 113                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
 114         }
 115         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
 116                 modifications = strcat(modifications, ", No start weapons");
 117         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
 118                 modifications = strcat(modifications, ", Low gravity");
 119         if(g_weapon_stay && !g_cts)
 120                 modifications = strcat(modifications, ", Weapons stay");
 121         if(g_jetpack)
 122                 modifications = strcat(modifications, ", Jet pack");
 123         if(autocvar_g_powerups == 0)
 124                 modifications = strcat(modifications, ", No powerups");
 125         if(autocvar_g_powerups > 0)
 126                 modifications = strcat(modifications, ", Powerups");
 127         modifications = substring(modifications, 2, strlen(modifications) - 2);
 128
 129         string versionmessage = GetClientVersionMessage(this);
 130         string s = strcat(versionmessage, "^8\n^8\nmatch type is ^1", gamemode_name, "^8\n");
 131
 132         if(modifications != "")
 133                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
 134
 135         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
 136         {
 137                 if(cache_lastmutatormsg)
 138                         strunzone(cache_lastmutatormsg);
 139                 if(cache_mutatormsg)
 140                         strunzone(cache_mutatormsg);
 141                 cache_lastmutatormsg = strzone(autocvar_g_mutatormsg);
 142                 cache_mutatormsg = strzone(cache_lastmutatormsg);
 143         }
 144
 145         if (cache_mutatormsg != "") {
 146                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
 147         }
 148
 149         string mutator_msg = "";
 150         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
 151         mutator_msg = M_ARGV(0, string);
 152
 153         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
 154
 155         string motd = autocvar_sv_motd;
 156         if (motd != "") {
 157                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
 158         }
 159         return s;
 160 }
 161
 162 void setcolor(entity this, int clr)
 163 {
 164 #if 0
 165         this.clientcolors = clr;
 166         this.team = (clr & 15) + 1;
 167 #else
 168         builtin_setcolor(this, clr);
 169 #endif
 170 }
 171
 172 void SetPlayerColors(entity pl, float _color)
 173 {
 174         /*string s;
 175         s = ftos(cl);
 176         stuffcmd(pl, strcat("color ", s, " ", s, "\n")  );
 177         pl.team = cl + 1;
 178         //pl.clientcolors = pl.clientcolors - (pl.clientcolors & 15) + cl;
 179         pl.clientcolors = 16*cl + cl;*/
 180
 181         float pants, shirt;
 182         pants = _color & 0x0F;
 183         shirt = _color & 0xF0;
 184
 185
 186         if(teamplay) {
 187                 setcolor(pl, 16*pants + pants);
 188         } else {
 189                 setcolor(pl, shirt + pants);
 190         }
 191 }
 192
 193 bool SetPlayerTeamSimple(entity player, int teamnum)
 194 {
 195         return MoveToTeam(player, teamnum, 6);
 196 }
 197
 198 void SetPlayerTeam(entity pl, float t, float s, float noprint)
 199 {
 200         if (t == s)
 201         {
 202                 return;
 203         }
 204         float teamnum = Team_NumberToTeam(t);
 205         SetPlayerTeamSimple(pl, teamnum);
 206         LogTeamchange(pl.playerid, pl.team, 3);  // log manual team join
 207         if (noprint)
 208         {
 209                 return;
 210         }
 211         bprint(playername(pl, false), "^7 has changed from ", Team_NumberToColoredFullName(s), "^7 to ", Team_NumberToColoredFullName(t), "\n");
 212 }
 213
 214 // set c1...c4 to show what teams are allowed
 215 void CheckAllowedTeams (entity for_whom)
 216 {
 217         int teams_mask = 0;
 218
 219         c1 = c2 = c3 = c4 = -1;
 220         cb1 = cb2 = cb3 = cb4 = 0;
 221
 222         string teament_name = string_null;
 223
 224         bool mutator_returnvalue = MUTATOR_CALLHOOK(CheckAllowedTeams, teams_mask, teament_name, for_whom);
 225         teams_mask = M_ARGV(0, float);
 226         teament_name = M_ARGV(1, string);
 227
 228         if(!mutator_returnvalue)
 229         {
 230                 if(teams_mask & BIT(0)) c1 = 0;
 231                 if(teams_mask & BIT(1)) c2 = 0;
 232                 if(teams_mask & BIT(2)) c3 = 0;
 233                 if(teams_mask & BIT(3)) c4 = 0;
 234         }
 235
 236         // find out what teams are allowed if necessary
 237         if(teament_name)
 238         {
 239                 entity head = find(NULL, classname, teament_name);
 240                 while(head)
 241                 {
 242                         switch(head.team)
 243                         {
 244                                 case NUM_TEAM_1: c1 = 0; break;
 245                                 case NUM_TEAM_2: c2 = 0; break;
 246                                 case NUM_TEAM_3: c3 = 0; break;
 247                                 case NUM_TEAM_4: c4 = 0; break;
 248                         }
 249
 250                         head = find(head, classname, teament_name);
 251                 }
 252         }
 253
 254         // TODO: Balance quantity of bots across > 2 teams when bot_vs_human is set (and remove next line)
 255         if(AvailableTeams() == 2)
 256         if(autocvar_bot_vs_human && for_whom)
 257         {
 258                 if(autocvar_bot_vs_human > 0)
 259                 {
 260                         // find last team available
 261
 262                         if(IS_BOT_CLIENT(for_whom))
 263                         {
 264                                 if(c4 >= 0) { c3 = c2 = c1 = -1; }
 265                                 else if(c3 >= 0) { c4 = c2 = c1 = -1; }
 266                                 else { c4 = c3 = c1 = -1; }
 267                                 // no further cases, we know at least 2 teams exist
 268                         }
 269                         else
 270                         {
 271                                 if(c1 >= 0) { c2 = c3 = c4 = -1; }
 272                                 else if(c2 >= 0) { c1 = c3 = c4 = -1; }
 273                                 else { c1 = c2 = c4 = -1; }
 274                                 // no further cases, bots have one of the teams
 275                         }
 276                 }
 277                 else
 278                 {
 279                         // find first team available
 280
 281                         if(IS_BOT_CLIENT(for_whom))
 282                         {
 283                                 if(c1 >= 0) { c2 = c3 = c4 = -1; }
 284                                 else if(c2 >= 0) { c1 = c3 = c4 = -1; }
 285                                 else { c1 = c2 = c4 = -1; }
 286                                 // no further cases, we know at least 2 teams exist
 287                         }
 288                         else
 289                         {
 290                                 if(c4 >= 0) { c3 = c2 = c1 = -1; }
 291                                 else if(c3 >= 0) { c4 = c2 = c1 = -1; }
 292                                 else { c4 = c3 = c1 = -1; }
 293                                 // no further cases, bots have one of the teams
 294                         }
 295                 }
 296         }
 297
 298         if(!for_whom)
 299                 return;
 300
 301         // if player has a forced team, ONLY allow that one
 302         if(for_whom.team_forced == NUM_TEAM_1 && c1 >= 0)
 303                 c2 = c3 = c4 = -1;
 304         else if(for_whom.team_forced == NUM_TEAM_2 && c2 >= 0)
 305                 c1 = c3 = c4 = -1;
 306         else if(for_whom.team_forced == NUM_TEAM_3 && c3 >= 0)
 307                 c1 = c2 = c4 = -1;
 308         else if(for_whom.team_forced == NUM_TEAM_4 && c4 >= 0)
 309                 c1 = c2 = c3 = -1;
 310 }
 311
 312 float PlayerValue(entity p)
 313 {
 314         return 1;
 315         // FIXME: it always returns 1...
 316 }
 317
 318 // c1...c4 should be set to -1 (not allowed) or 0 (allowed).
 319 // teams that are allowed will now have their player counts stored in c1...c4
 320 void GetTeamCounts(entity ignore)
 321 {
 322         float value, bvalue;
 323         // now count how many players are on each team already
 324
 325         // FIXME: also find and memorize the lowest-scoring bot on each team (in case players must be shuffled around)
 326         // also remember the lowest-scoring player
 327
 328         FOREACH_CLIENT(true, LAMBDA(
 329                 float t;
 330                 if(IS_PLAYER(it) || it.caplayer)
 331                         t = it.team;
 332                 else if(it.team_forced > 0)
 333                         t = it.team_forced; // reserve the spot
 334                 else
 335                         continue;
 336                 if(it != ignore)// && it.netname != "")
 337                 {
 338                         value = PlayerValue(it);
 339                         if(IS_BOT_CLIENT(it))
 340                                 bvalue = value;
 341                         else
 342                                 bvalue = 0;
 343                         if(t == NUM_TEAM_1)
 344                         {
 345                                 if(c1 >= 0)
 346                                 {
 347                                         c1 = c1 + value;
 348                                         cb1 = cb1 + bvalue;
 349                                 }
 350                         }
 351                         if(t == NUM_TEAM_2)
 352                         {
 353                                 if(c2 >= 0)
 354                                 {
 355                                         c2 = c2 + value;
 356                                         cb2 = cb2 + bvalue;
 357                                 }
 358                         }
 359                         if(t == NUM_TEAM_3)
 360                         {
 361                                 if(c3 >= 0)
 362                                 {
 363                                         c3 = c3 + value;
 364                                         cb3 = cb3 + bvalue;
 365                                 }
 366                         }
 367                         if(t == NUM_TEAM_4)
 368                         {
 369                                 if(c4 >= 0)
 370                                 {
 371                                         c4 = c4 + value;
 372                                         cb4 = cb4 + bvalue;
 373                                 }
 374                         }
 375                 }
 376         ));
 377
 378         // if the player who has a forced team has not joined yet, reserve the spot
 379         if(autocvar_g_campaign)
 380         {
 381                 switch(autocvar_g_campaign_forceteam)
 382                 {
 383                         case 1: if(c1 == cb1) ++c1; break;
 384                         case 2: if(c2 == cb2) ++c2; break;
 385                         case 3: if(c3 == cb3) ++c3; break;
 386                         case 4: if(c4 == cb4) ++c4; break;
 387                 }
 388         }
 389 }
 390
 391 float TeamSmallerEqThanTeam(float ta, float tb, entity e)
 392 {
 393         // we assume that CheckAllowedTeams and GetTeamCounts have already been called
 394         float f;
 395         float ca = -1, cb = -1, cba = 0, cbb = 0, sa = 0, sb = 0;
 396
 397         switch(ta)
 398         {
 399                 case 1: ca = c1; cba = cb1; sa = team1_score; break;
 400                 case 2: ca = c2; cba = cb2; sa = team2_score; break;
 401                 case 3: ca = c3; cba = cb3; sa = team3_score; break;
 402                 case 4: ca = c4; cba = cb4; sa = team4_score; break;
 403         }
 404         switch(tb)
 405         {
 406                 case 1: cb = c1; cbb = cb1; sb = team1_score; break;
 407                 case 2: cb = c2; cbb = cb2; sb = team2_score; break;
 408                 case 3: cb = c3; cbb = cb3; sb = team3_score; break;
 409                 case 4: cb = c4; cbb = cb4; sb = team4_score; break;
 410         }
 411
 412         // invalid
 413         if(ca < 0 || cb < 0)
 414                 return false;
 415
 416         // equal
 417         if(ta == tb)
 418                 return true;
 419
 420         if(IS_REAL_CLIENT(e))
 421         {
 422                 if(bots_would_leave)
 423                 {
 424                         ca -= cba * 0.999;
 425                         cb -= cbb * 0.999;
 426                 }
 427         }
 428
 429         // keep teams alive (teams of size 0 always count as smaller, ignoring score)
 430         if(ca < 1)
 431                 if(cb >= 1)
 432                         return true;
 433         if(ca >= 1)
 434                 if(cb < 1)
 435                         return false;
 436
 437         // first, normalize
 438         f = max(ca, cb, 1);
 439         ca /= f;
 440         cb /= f;
 441         f = max(sa, sb, 1);
 442         sa /= f;
 443         sb /= f;
 444
 445         // the more we're at the end of the match, the more take scores into account
 446         f = bound(0, game_completion_ratio * autocvar_g_balance_teams_scorefactor, 1);
 447         ca += (sa - ca) * f;
 448         cb += (sb - cb) * f;
 449
 450         return ca <= cb;
 451 }
 452
 453 // returns # of smallest team (1, 2, 3, 4)
 454 // NOTE: Assumes CheckAllowedTeams has already been called!
 455 float FindSmallestTeam(entity pl, float ignore_pl)
 456 {
 457         int totalteams = 0;
 458         int t = 1; // initialize with a random team?
 459         if(c4 >= 0) t = 4;
 460         if(c3 >= 0) t = 3;
 461         if(c2 >= 0) t = 2;
 462         if(c1 >= 0) t = 1;
 463
 464         // find out what teams are available
 465         //CheckAllowedTeams();
 466
 467         // make sure there are at least 2 teams to join
 468         if(c1 >= 0)
 469                 totalteams = totalteams + 1;
 470         if(c2 >= 0)
 471                 totalteams = totalteams + 1;
 472         if(c3 >= 0)
 473                 totalteams = totalteams + 1;
 474         if(c4 >= 0)
 475                 totalteams = totalteams + 1;
 476
 477         if((autocvar_bot_vs_human || pl.team_forced > 0) && totalteams == 1)
 478                 totalteams += 1;
 479
 480         if(totalteams <= 1)
 481         {
 482                 if(autocvar_g_campaign && pl && IS_REAL_CLIENT(pl))
 483                         return 1; // special case for campaign and player joining
 484                 else if(totalteams == 1) // single team
 485                         LOG_TRACEF("Only 1 team available for %s, you may need to fix your map", MapInfo_Type_ToString(MapInfo_CurrentGametype()));
 486                 else // no teams, major no no
 487                         error(sprintf("No teams available for %s\n", MapInfo_Type_ToString(MapInfo_CurrentGametype())));
 488         }
 489
 490         // count how many players are in each team
 491         if(ignore_pl)
 492                 GetTeamCounts(pl);
 493         else
 494                 GetTeamCounts(NULL);
 495
 496         RandomSelection_Init();
 497
 498         if(TeamSmallerEqThanTeam(1, t, pl))
 499                 t = 1;
 500         if(TeamSmallerEqThanTeam(2, t, pl))
 501                 t = 2;
 502         if(TeamSmallerEqThanTeam(3, t, pl))
 503                 t = 3;
 504         if(TeamSmallerEqThanTeam(4, t, pl))
 505                 t = 4;
 506
 507         // now t is the minimum, or A minimum!
 508         if(t == 1 || TeamSmallerEqThanTeam(1, t, pl))
 509                 RandomSelection_AddFloat(1, 1, 1);
 510         if(t == 2 || TeamSmallerEqThanTeam(2, t, pl))
 511                 RandomSelection_AddFloat(2, 1, 1);
 512         if(t == 3 || TeamSmallerEqThanTeam(3, t, pl))
 513                 RandomSelection_AddFloat(3, 1, 1);
 514         if(t == 4 || TeamSmallerEqThanTeam(4, t, pl))
 515                 RandomSelection_AddFloat(4, 1, 1);
 516
 517         return RandomSelection_chosen_float;
 518 }
 519
 520 int JoinBestTeam(entity this, bool only_return_best, bool forcebestteam)
 521 {
 522         float smallest, selectedteam;
 523
 524         // don't join a team if we're not playing a team game
 525         if(!teamplay)
 526                 return 0;
 527
 528         // find out what teams are available
 529         CheckAllowedTeams(this);
 530
 531         // if we don't care what team he ends up on, put him on whatever team he entered as.
 532         // if he's not on a valid team, then let other code put him on the smallest team
 533         if(!forcebestteam)
 534         {
 535                 if(     c1 >= 0 && this.team == NUM_TEAM_1)
 536                         selectedteam = this.team;
 537                 else if(c2 >= 0 && this.team == NUM_TEAM_2)
 538                         selectedteam = this.team;
 539                 else if(c3 >= 0 && this.team == NUM_TEAM_3)
 540                         selectedteam = this.team;
 541                 else if(c4 >= 0 && this.team == NUM_TEAM_4)
 542                         selectedteam = this.team;
 543                 else
 544                         selectedteam = -1;
 545
 546                 if(selectedteam > 0)
 547                 {
 548                         if(!only_return_best)
 549                         {
 550                                 SetPlayerTeamSimple(this, selectedteam);
 551
 552                                 // when JoinBestTeam is called by client.qc/ClientKill_Now_TeamChange the players team is -1 and thus skipped
 553                                 // when JoinBestTeam is called by client.qc/ClientConnect the player_id is 0 the log attempt is rejected
 554                                 LogTeamchange(this.playerid, this.team, 99);
 555                         }
 556                         return selectedteam;
 557                 }
 558                 // otherwise end up on the smallest team (handled below)
 559         }
 560
 561         smallest = FindSmallestTeam(this, true);
 562
 563         if(!only_return_best && !this.bot_forced_team)
 564         {
 565                 smallest = Team_NumberToTeam(smallest);
 566                 if (smallest != -1)
 567                 {
 568                         TeamchangeFrags(this);
 569                         SetPlayerTeamSimple(this, smallest);
 570                 }
 571                 else
 572                 {
 573                         error("smallest team: invalid team\n");
 574                 }
 575
 576                 LogTeamchange(this.playerid, this.team, 2); // log auto join
 577
 578                 if(!IS_DEAD(this))
 579                         Damage(this, this, this, 100000, DEATH_TEAMCHANGE.m_id, this.origin, '0 0 0');
 580         }
 581
 582         return smallest;
 583 }
 584
 585 //void() ctf_playerchanged;
 586 void SV_ChangeTeam(entity this, float _color)
 587 {
 588         float scolor, dcolor, steam, dteam; //, dbotcount, scount, dcount;
 589
 590         // in normal deathmatch we can just apply the color and we're done
 591         if(!teamplay)
 592                 SetPlayerColors(this, _color);
 593
 594         if(!IS_CLIENT(this))
 595         {
 596                 // since this is an engine function, and gamecode doesn't have any calls earlier than this, do the connecting message here
 597                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_CONNECTING, this.netname);
 598                 return;
 599         }
 600
 601         if(!teamplay)
 602                 return;
 603
 604         scolor = this.clientcolors & 0x0F;
 605         dcolor = _color & 0x0F;
 606
 607         if(scolor == NUM_TEAM_1 - 1)
 608                 steam = 1;
 609         else if(scolor == NUM_TEAM_2 - 1)
 610                 steam = 2;
 611         else if(scolor == NUM_TEAM_3 - 1)
 612                 steam = 3;
 613         else // if(scolor == NUM_TEAM_4 - 1)
 614                 steam = 4;
 615         if(dcolor == NUM_TEAM_1 - 1)
 616                 dteam = 1;
 617         else if(dcolor == NUM_TEAM_2 - 1)
 618                 dteam = 2;
 619         else if(dcolor == NUM_TEAM_3 - 1)
 620                 dteam = 3;
 621         else // if(dcolor == NUM_TEAM_4 - 1)
 622                 dteam = 4;
 623
 624         CheckAllowedTeams(this);
 625
 626         if(dteam == 1 && c1 < 0) dteam = 4;
 627         if(dteam == 4 && c4 < 0) dteam = 3;
 628         if(dteam == 3 && c3 < 0) dteam = 2;
 629         if(dteam == 2 && c2 < 0) dteam = 1;
 630
 631         // not changing teams
 632         if(scolor == dcolor)
 633         {
 634                 SetPlayerTeam(this, dteam, steam, true);
 635                 return;
 636         }
 637
 638         if((autocvar_g_campaign) || (autocvar_g_changeteam_banned && this.wasplayer)) {
 639                 Send_Notification(NOTIF_ONE, this, MSG_INFO, INFO_TEAMCHANGE_NOTALLOWED);
 640                 return; // changing teams is not allowed
 641         }
 642
 643         // autocvar_g_balance_teams_prevent_imbalance only makes sense if autocvar_g_balance_teams is on, as it makes the team selection dialog pointless
 644         if(autocvar_g_balance_teams && autocvar_g_balance_teams_prevent_imbalance)
 645         {
 646                 GetTeamCounts(this);
 647                 if(!TeamSmallerEqThanTeam(dteam, steam, this))
 648                 {
 649                         Send_Notification(NOTIF_ONE, this, MSG_INFO, INFO_TEAMCHANGE_LARGERTEAM);
 650                         return;
 651                 }
 652         }
 653
 654 //      bprint("allow change teams from ", ftos(steam), " to ", ftos(dteam), "\n");
 655
 656         if(IS_PLAYER(this) && steam != dteam)
 657         {
 658                 // reduce frags during a team change
 659                 TeamchangeFrags(this);
 660         }
 661
 662         SetPlayerTeam(this, dteam, steam, !IS_CLIENT(this));
 663
 664         if(IS_PLAYER(this) && steam != dteam)
 665         {
 666                 // kill player when changing teams
 667                 if(!IS_DEAD(this))
 668                         Damage(this, this, this, 100000, DEATH_TEAMCHANGE.m_id, this.origin, '0 0 0');
 669         }
 670 }
 671
 672 void ShufflePlayerOutOfTeam (float source_team)
 673 {
 674         float smallestteam, smallestteam_count, steam;
 675         float lowest_bot_score, lowest_player_score;
 676         entity lowest_bot, lowest_player, selected;
 677
 678         smallestteam = 0;
 679         smallestteam_count = 999999999;
 680
 681         if(c1 >= 0 && c1 < smallestteam_count)
 682         {
 683                 smallestteam = 1;
 684                 smallestteam_count = c1;
 685         }
 686         if(c2 >= 0 && c2 < smallestteam_count)
 687         {
 688                 smallestteam = 2;
 689                 smallestteam_count = c2;
 690         }
 691         if(c3 >= 0 && c3 < smallestteam_count)
 692         {
 693                 smallestteam = 3;
 694                 smallestteam_count = c3;
 695         }
 696         if(c4 >= 0 && c4 < smallestteam_count)
 697         {
 698                 smallestteam = 4;
 699                 smallestteam_count = c4;
 700         }
 701
 702         if(!smallestteam)
 703         {
 704                 bprint("warning: no smallest team\n");
 705                 return;
 706         }
 707
 708         if(source_team == 1)
 709                 steam = NUM_TEAM_1;
 710         else if(source_team == 2)
 711                 steam = NUM_TEAM_2;
 712         else if(source_team == 3)
 713                 steam = NUM_TEAM_3;
 714         else // if(source_team == 4)
 715                 steam = NUM_TEAM_4;
 716
 717         lowest_bot = NULL;
 718         lowest_bot_score = 999999999;
 719         lowest_player = NULL;
 720         lowest_player_score = 999999999;
 721
 722         // find the lowest-scoring player & bot of that team
 723         FOREACH_CLIENT(IS_PLAYER(it) && it.team == steam, LAMBDA(
 724                 if(it.isbot)
 725                 {
 726                         if(it.totalfrags < lowest_bot_score)
 727                         {
 728                                 lowest_bot = it;
 729                                 lowest_bot_score = it.totalfrags;
 730                         }
 731                 }
 732                 else
 733                 {
 734                         if(it.totalfrags < lowest_player_score)
 735                         {
 736                                 lowest_player = it;
 737                                 lowest_player_score = it.totalfrags;
 738                         }
 739                 }
 740         ));
 741
 742         // prefers to move a bot...
 743         if(lowest_bot != NULL)
 744                 selected = lowest_bot;
 745         // but it will move a player if it has to
 746         else
 747                 selected = lowest_player;
 748         // don't do anything if it couldn't find anyone
 749         if(!selected)
 750         {
 751                 bprint("warning: couldn't find a player to move from team\n");
 752                 return;
 753         }
 754
 755         // smallest team gains a member
 756         if(smallestteam == 1)
 757         {
 758                 c1 = c1 + 1;
 759         }
 760         else if(smallestteam == 2)
 761         {
 762                 c2 = c2 + 1;
 763         }
 764         else if(smallestteam == 3)
 765         {
 766                 c3 = c3 + 1;
 767         }
 768         else if(smallestteam == 4)
 769         {
 770                 c4 = c4 + 1;
 771         }
 772         else
 773         {
 774                 bprint("warning: destination team invalid\n");
 775                 return;
 776         }
 777         // source team loses a member
 778         if(source_team == 1)
 779         {
 780                 c1 = c1 + 1;
 781         }
 782         else if(source_team == 2)
 783         {
 784                 c2 = c2 + 2;
 785         }
 786         else if(source_team == 3)
 787         {
 788                 c3 = c3 + 3;
 789         }
 790         else if(source_team == 4)
 791         {
 792                 c4 = c4 + 4;
 793         }
 794         else
 795         {
 796                 bprint("warning: source team invalid\n");
 797                 return;
 798         }
 799
 800         // move the player to the new team
 801         TeamchangeFrags(selected);
 802         SetPlayerTeam(selected, smallestteam, source_team, false);
 803
 804         if(!IS_DEAD(selected))
 805                 Damage(selected, selected, selected, 100000, DEATH_AUTOTEAMCHANGE.m_id, selected.origin, '0 0 0');
 806         Send_Notification(NOTIF_ONE, selected, MSG_CENTER, CENTER_DEATH_SELF_AUTOTEAMCHANGE, selected.team);
 807 }