qcsrc/server/tturrets/units/unit_walker.qc

   1 #define ANIM_NO         0
   2 #define ANIM_TURN       1
   3 #define ANIM_WALK       2
   4 #define ANIM_RUN        3
   5 #define ANIM_STRAFE_L   4
   6 #define ANIM_STRAFE_R   5
   7 #define ANIM_JUMP       6
   8 #define ANIM_LAND       7
   9 #define ANIM_PAIN       8
  10 #define ANIM_MEELE      9
  11 #define ANIM_SWIM       10
  12 #define ANIM_ROAM       11
  13 .float animflag;
  14
  15 #define WALKER_MIN '-70 -70 0'
  16 #define WALKER_MAX '70 70 95'
  17
  18 #define WALKER_PATH(s,e) pathlib_astar(s,e)
  19
  20 float walker_firecheck()
  21 {
  22     if (self.animflag == ANIM_MEELE)
  23         return 0;
  24
  25     return turret_stdproc_firecheck();
  26 }
  27
  28 void walker_meele_do_dmg()
  29 {
  30     vector where;
  31     entity e;
  32
  33     makevectors(self.angles);
  34     where = self.origin + v_forward * 128;
  35
  36     e = findradius(where,32);
  37     while (e)
  38     {
  39         if (turret_validate_target(self,e,self.target_validate_flags))
  40             if (e != self && e.owner != self)
  41                 Damage(e, self, self, autocvar_g_turrets_unit_walker_std_meele_dmg ,DEATH_TURRET_WALKER_MEELE,'0 0 0', v_forward * autocvar_g_turrets_unit_walker_std_meele_force);
  42
  43         e = e.chain;
  44     }
  45 }
  46
  47 void walker_setnoanim()
  48 {
  49     turrets_setframe(ANIM_NO, FALSE);
  50     self.animflag = self.frame;
  51 }
  52 void walker_rocket_explode()
  53 {
  54     if (self.event_damage != SUB_Null)
  55     {
  56         self.event_damage = SUB_Null;
  57         self.takedamage = DAMAGE_NO;
  58         self.think = walker_rocket_explode;
  59         self.nextthink = time;
  60         return;
  61     }
  62
  63     RadiusDamage (self, self.owner, autocvar_g_turrets_unit_walker_std_rocket_dmg, 0, autocvar_g_turrets_unit_walker_std_rocket_radius, world,autocvar_g_turrets_unit_walker_std_rocket_force, DEATH_TURRET_WALKER_ROCKET, world);
  64
  65     remove (self);
  66 }
  67
  68 void walker_rocket_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector vforce)
  69 {
  70     self.health = self.health - damage;
  71     self.velocity = self.velocity + vforce;
  72     if (self.health <= 0)
  73         walker_rocket_explode();
  74 }
  75
  76 #define WALKER_ROCKET_MOVE movelib_move_simple(newdir, autocvar_g_turrets_unit_walker_std_rocket_speed, autocvar_g_turrets_unit_walker_std_rocket_turnrate); UpdateCSQCProjectile(self)
  77 void walker_rocket_loop();
  78 void walker_rocket_think()
  79 {
  80     vector newdir;
  81     float edist;
  82     float itime;
  83     float m_speed;
  84
  85     self.nextthink = time;
  86
  87     edist = vlen(self.enemy.origin - self.origin);
  88
  89     // Simulate crude guidance
  90     if (self.cnt < time)
  91     {
  92         if (edist < 1000)
  93             self.tur_shotorg = randomvec() * min(edist, 64);
  94         else
  95             self.tur_shotorg = randomvec() * min(edist, 256);
  96
  97         self.cnt = time + 0.5;
  98     }
  99
 100     if (edist < 256)
 101         self.tur_shotorg = '0 0 0';
 102
 103     if (self.tur_health < time)
 104     {
 105         self.think      = walker_rocket_explode;
 106         self.nextthink  = time;
 107         return;
 108     }
 109
 110     if (self.shot_dmg != 1337 && random() < 0.01)
 111     {
 112         walker_rocket_loop();
 113         return;
 114     }
 115
 116     m_speed = vlen(self.velocity);
 117
 118     // Enemy dead? just keep on the current heading then.
 119     if (self.enemy == world || self.enemy.deadflag != DEAD_NO)
 120         self.enemy = world;
 121
 122     if (self.enemy)
 123     {
 124         itime = max(edist / m_speed, 1);
 125         newdir = steerlib_pull(self.enemy.origin + self.tur_shotorg);
 126     }
 127     else
 128         newdir  = normalize(self.velocity);
 129
 130     WALKER_ROCKET_MOVE;
 131 }
 132
 133 void walker_rocket_loop3()
 134 {
 135     vector newdir;
 136     self.nextthink = time;
 137
 138     if (self.tur_health < time)
 139     {
 140         self.think = walker_rocket_explode;
 141         return;
 142     }
 143
 144     if (vlen(self.origin - self.tur_shotorg) < 100 )
 145     {
 146         self.think = walker_rocket_think;
 147         return;
 148     }
 149
 150     newdir = steerlib_pull(self.tur_shotorg);
 151     WALKER_ROCKET_MOVE;
 152
 153     self.angles = vectoangles(self.velocity);
 154 }
 155
 156 void walker_rocket_loop2()
 157 {
 158     vector newdir;
 159
 160     self.nextthink = time;
 161
 162     if (self.tur_health < time)
 163     {
 164         self.think = walker_rocket_explode;
 165         return;
 166     }
 167
 168     if (vlen(self.origin - self.tur_shotorg) < 100 )
 169     {
 170         self.tur_shotorg = self.origin - '0 0 200';
 171         self.think = walker_rocket_loop3;
 172         return;
 173     }
 174
 175     newdir = steerlib_pull(self.tur_shotorg);
 176     WALKER_ROCKET_MOVE;
 177 }
 178
 179 void walker_rocket_loop()
 180 {
 181     self.nextthink = time;
 182     self.tur_shotorg = self.origin + '0 0 300';
 183     self.think = walker_rocket_loop2;
 184     self.shot_dmg = 1337;
 185 }
 186
 187 void walker_fire_rocket(vector org)
 188 {
 189     entity rocket;
 190
 191     fixedmakevectors(self.angles);
 192
 193     te_explosion (org);
 194
 195     rocket = spawn ();
 196     setorigin(rocket, org);
 197
 198     sound (self, CH_WEAPON_A, "weapons/hagar_fire.wav", VOL_BASE, ATTN_NORM);
 199     setsize (rocket, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 200
 201     rocket.classname          = "walker_rocket";
 202     rocket.owner              = self;
 203     rocket.bot_dodge          = TRUE;
 204     rocket.bot_dodgerating    = 50;
 205     rocket.takedamage         = DAMAGE_YES;
 206     rocket.damageforcescale   = 2;
 207     rocket.health             = 25;
 208     rocket.tur_shotorg        = randomvec() * 512;
 209     rocket.cnt                = time + 1;
 210     rocket.enemy              = self.enemy;
 211
 212     if (random() < 0.01)
 213         rocket.think          = walker_rocket_loop;
 214     else
 215         rocket.think          = walker_rocket_think;
 216
 217     rocket.event_damage       = walker_rocket_damage;
 218
 219     rocket.nextthink          = time;
 220     rocket.movetype           = MOVETYPE_FLY;
 221     rocket.velocity           = normalize((v_forward + v_up * 0.5) + (randomvec() * 0.2)) * autocvar_g_turrets_unit_walker_std_rocket_speed;
 222     rocket.angles             = vectoangles(rocket.velocity);
 223     rocket.touch              = walker_rocket_explode;
 224     rocket.flags              = FL_PROJECTILE;
 225     rocket.solid              = SOLID_BBOX;
 226     rocket.tur_health         = time + 9;
 227
 228     CSQCProjectile(rocket, FALSE, PROJECTILE_ROCKET, FALSE); // no culling, has fly sound
 229 }
 230
 231 .vector enemy_last_loc;
 232 .float enemy_last_time;
 233 void walker_move_to(vector _target, float _dist)
 234 {
 235     switch (self.waterlevel)
 236     {
 237     case WATERLEVEL_NONE:
 238         if (_dist > 500)
 239             self.animflag = ANIM_RUN;
 240         else
 241             self.animflag = ANIM_WALK;
 242     case WATERLEVEL_WETFEET:
 243     case WATERLEVEL_SWIMMING:
 244         if (self.animflag != ANIM_SWIM)
 245             self.animflag = ANIM_WALK;
 246         else
 247             self.animflag = ANIM_SWIM;
 248         break;
 249     case WATERLEVEL_SUBMERGED:
 250         self.animflag = ANIM_SWIM;
 251     }
 252
 253     self.moveto = _target;
 254     self.steerto = steerlib_attract2(self.moveto, 0.5, 500, 0.95);
 255
 256     if(self.enemy)
 257     {
 258         self.enemy_last_loc = _target;
 259         self.enemy_last_time = time;
 260     }
 261 }
 262
 263 //#define WALKER_FANCYPATHING
 264
 265 void walker_move_path()
 266 {
 267 #ifdef WALKER_FANCYPATHING
 268     // Are we close enougth to a path node to switch to the next?
 269     if (vlen(self.origin  - self.pathcurrent.origin) < 64)
 270         if (self.pathcurrent.path_next == world)
 271         {
 272             // Path endpoint reached
 273             pathlib_deletepath(self.pathcurrent.owner);
 274             self.pathcurrent = world;
 275
 276             if (self.pathgoal)
 277             {
 278                 if (self.pathgoal.use)
 279                     self.pathgoal.use();
 280
 281                 if (self.pathgoal.enemy)
 282                 {
 283                     self.pathcurrent = WALKER_PATH(self.pathgoal.origin,self.pathgoal.enemy.origin);
 284                     self.pathgoal = self.pathgoal.enemy;
 285                 }
 286             }
 287             else
 288                 self.pathgoal = world;
 289         }
 290         else
 291             self.pathcurrent = self.pathcurrent.path_next;
 292
 293     self.moveto = self.pathcurrent.origin;
 294     self.steerto = steerlib_attract2(self.moveto,0.5,500,0.95);
 295     walker_move_to(self.moveto, 0);
 296
 297 #else
 298     if (vlen(self.origin - self.pathcurrent.origin) < 64)
 299         self.pathcurrent = self.pathcurrent.enemy;
 300
 301     if(!self.pathcurrent)
 302         return;
 303
 304     self.moveto = self.pathcurrent.origin;
 305     self.steerto = steerlib_attract2(self.moveto, 0.5, 500, 0.95);
 306     walker_move_to(self.moveto, 0);
 307 #endif
 308 }
 309
 310 .float idletime;
 311
 312
 313
 314 void walker_postthink()
 315 {
 316     fixedmakevectors(self.angles);
 317
 318     if (self.spawnflags & TSF_NO_PATHBREAK && self.pathcurrent)
 319         walker_move_path();
 320     else if (self.enemy == world)
 321     {
 322         if(self.pathcurrent)
 323             walker_move_path();
 324         else
 325         {
 326             if(self.enemy_last_time != 0)
 327             {
 328                 if(vlen(self.origin - self.enemy_last_loc) < 128 || time - self.enemy_last_time > 10)
 329                     self.enemy_last_time = 0;
 330                 else
 331                     walker_move_to(self.enemy_last_loc, 0);
 332             }
 333             else
 334             {
 335                 if(self.animflag != ANIM_NO)
 336                 {
 337                     traceline(self.origin + '0 0 64', self.origin + '0 0 64' + v_forward * 128, MOVE_NORMAL, self);
 338
 339                     if(trace_fraction != 1.0)
 340                         self.tur_head.idletime = -1337;
 341                     else
 342                     {
 343                         traceline(trace_endpos, trace_endpos - '0 0 256', MOVE_NORMAL, self);
 344                         if(trace_fraction == 1.0)
 345                             self.tur_head.idletime = -1337;
 346                     }
 347
 348                     if(self.tur_head.idletime == -1337)
 349                     {
 350                         self.moveto = self.origin + randomvec() * 256;
 351                         self.tur_head.idletime = 0;
 352                     }
 353
 354                     self.moveto = self.moveto * 0.9 + ((self.origin + v_forward * 500) + randomvec() * 400) * 0.1;
 355                     self.moveto_z = self.origin_z + 64;
 356                     walker_move_to(self.moveto, 0);
 357                 }
 358
 359                 if(self.idletime < time)
 360                 {
 361                     if(random() < 0.5 || !(self.spawnflags & TSL_ROAM))
 362                     {
 363                         self.idletime = time + 1 + random() * 5;
 364                         self.moveto = self.origin;
 365                         self.animflag = ANIM_NO;
 366                     }
 367                     else
 368                     {
 369                         self.animflag = ANIM_WALK;
 370                         self.idletime = time + 4 + random() * 2;
 371                         self.moveto = self.origin + randomvec() * 256;
 372                         self.tur_head.moveto = self.moveto;
 373                         self.tur_head.idletime = 0;
 374                     }
 375                 }
 376             }
 377         }
 378     }
 379     else
 380     {
 381         if (self.tur_dist_enemy < autocvar_g_turrets_unit_walker_std_meele_range && self.animflag != ANIM_MEELE)
 382         {
 383             vector wish_angle;
 384
 385             wish_angle = angleofs(self, self.enemy);
 386             if (self.animflag != ANIM_SWIM)
 387             if (fabs(wish_angle_y) < 15)
 388             {
 389                 self.moveto   = self.enemy.origin;
 390                 self.steerto  = steerlib_attract2(self.moveto, 0.5, 500, 0.95);
 391                 self.animflag = ANIM_MEELE;
 392             }
 393         }
 394         else if (self.tur_head.attack_finished_single < time)
 395         {
 396             if(self.tur_head.shot_volly)
 397             {
 398                 self.animflag = ANIM_NO;
 399
 400                 self.tur_head.shot_volly = self.tur_head.shot_volly -1;
 401                 if(self.tur_head.shot_volly == 0)
 402                     self.tur_head.attack_finished_single = time + autocvar_g_turrets_unit_walker_std_rocket_refire;
 403                 else
 404                     self.tur_head.attack_finished_single = time + 0.2;
 405
 406                 if(self.tur_head.shot_volly > 1)
 407                     walker_fire_rocket(gettaginfo(self, gettagindex(self, "tag_rocket01")));
 408                 else
 409                     walker_fire_rocket(gettaginfo(self, gettagindex(self, "tag_rocket02")));
 410             }
 411             else
 412             {
 413                 if (self.tur_dist_enemy > autocvar_g_turrets_unit_walker_std_rockets_range_min)
 414                 if (self.tur_dist_enemy < autocvar_g_turrets_unit_walker_std_rockets_range)
 415                     self.tur_head.shot_volly = 4;
 416             }
 417         }
 418         else
 419         {
 420             if (self.animflag != ANIM_MEELE)
 421                 walker_move_to(self.enemy.origin, self.tur_dist_enemy);
 422         }
 423     }
 424
 425     //if(self.animflag != ANIM_NO)
 426     {
 427         vector real_angle;
 428         float turny, turnx;
 429         float  vz;
 430
 431         real_angle = vectoangles(self.steerto) - self.angles;
 432         vz         = self.velocity_z;
 433
 434         switch (self.animflag)
 435         {
 436             case ANIM_NO:
 437                 movelib_beak_simple(autocvar_g_turrets_unit_walker_speed_stop);
 438                 break;
 439
 440             case ANIM_TURN:
 441                 turny = autocvar_g_turrets_unit_walker_turn;
 442                 movelib_beak_simple(autocvar_g_turrets_unit_walker_speed_stop);
 443                 break;
 444
 445             case ANIM_WALK:
 446                 turny = autocvar_g_turrets_unit_walker_turn_walk;
 447                 movelib_move_simple(v_forward, autocvar_g_turrets_unit_walker_speed_walk, 0.6);
 448                 break;
 449
 450             case ANIM_RUN:
 451                 turny = autocvar_g_turrets_unit_walker_turn_run;
 452                 movelib_move_simple(v_forward, autocvar_g_turrets_unit_walker_speed_run, 0.6);
 453                 break;
 454
 455             case ANIM_STRAFE_L:
 456                 turny = autocvar_g_turrets_unit_walker_turn_strafe;
 457                 movelib_move_simple(v_right * -1, autocvar_g_turrets_unit_walker_speed_walk, 0.8);
 458                 break;
 459
 460             case ANIM_STRAFE_R:
 461                 turny = autocvar_g_turrets_unit_walker_turn_strafe;
 462                 movelib_move_simple(v_right, autocvar_g_turrets_unit_walker_speed_walk, 0.8);
 463                 break;
 464
 465             case ANIM_JUMP:
 466                 self.velocity += '0 0 1' * autocvar_g_turrets_unit_walker_speed_jump;
 467                 break;
 468
 469             case ANIM_LAND:
 470                 break;
 471
 472             case ANIM_PAIN:
 473                 if(self.frame != ANIM_PAIN)
 474                     defer(0.25, walker_setnoanim);
 475
 476                 break;
 477
 478             case ANIM_MEELE:
 479                 if(self.frame != ANIM_MEELE)
 480                 {
 481                     defer(0.41, walker_setnoanim);
 482                     defer(0.21, walker_meele_do_dmg);
 483                 }
 484
 485                 movelib_beak_simple(autocvar_g_turrets_unit_walker_speed_stop);
 486                 break;
 487
 488             case ANIM_SWIM:
 489                 turny = autocvar_g_turrets_unit_walker_turn_swim;
 490                 turnx = autocvar_g_turrets_unit_walker_turn_swim;
 491
 492                 self.angles_x += bound(-10, shortangle_f(real_angle_x, self.angles_x), 10);
 493                 movelib_move_simple(v_forward, autocvar_g_turrets_unit_walker_speed_swim, 0.3);
 494                 vz = self.velocity_z + sin(time * 4) * 8;
 495                 break;
 496
 497             case ANIM_ROAM:
 498                 turny = autocvar_g_turrets_unit_walker_turn_walk;
 499                 movelib_move_simple(v_forward ,autocvar_g_turrets_unit_walker_speed_roam, 0.5);
 500                 break;
 501         }
 502
 503         if(turny)
 504         {
 505             turny = bound( turny * -1, shortangle_f(real_angle_y, self.angles_y), turny );
 506             self.angles_y += turny;
 507         }
 508
 509         if(turnx)
 510         {
 511             turnx = bound( turnx * -1, shortangle_f(real_angle_x, self.angles_x), turnx );
 512             self.angles_x += turnx;
 513         }
 514
 515         self.velocity_z = vz;
 516     }
 517
 518
 519     if(self.origin != self.oldorigin)
 520         self.SendFlags |= TNSF_MOVE;
 521
 522     self.oldorigin = self.origin;
 523     turrets_setframe(self.animflag, FALSE);
 524
 525 }
 526
 527 void walker_attack()
 528 {
 529     sound (self, CH_WEAPON_A, "weapons/uzi_fire.wav", VOL_BASE, ATTN_NORM);
 530     fireBallisticBullet (self.tur_shotorg, self.tur_shotdir_updated, self.shot_spread, self.shot_speed, 5, self.shot_dmg, 0, self.shot_force, DEATH_TURRET_WALKER_GUN, 0, 1, autocvar_g_balance_uzi_bulletconstant);
 531     endFireBallisticBullet();
 532     pointparticles(particleeffectnum("laser_muzzleflash"), self.tur_shotorg, self.tur_shotdir_updated * 1000, 1);
 533 }
 534
 535
 536 void walker_respawnhook()
 537 {
 538     entity e;
 539
 540     // Respawn is called & first spawn to, to set team. need to make sure we do not move the initial spawn.
 541     if(self.movetype  != MOVETYPE_WALK)
 542                 return;
 543
 544     setorigin(self, self.pos1);
 545     self.angles = self.pos2;
 546
 547     if (self.target != "")
 548     {
 549         e = find(world,targetname,self.target);
 550         if (!e)
 551         {
 552             dprint("Warning! initital waypoint for Walker does NOT exsist!\n");
 553             self.target = "";
 554         }
 555
 556         if (e.classname != "turret_checkpoint")
 557             dprint("Warning: not a turrret path\n");
 558         else
 559         {
 560  #ifdef WALKER_FANCYPATHING
 561             self.pathcurrent = WALKER_PATH(self.origin, e.origin);
 562             self.pathgoal = e;
 563 #else
 564             self.pathcurrent = e;
 565 #endif
 566            //self.pathcurrent = WALKER_PATH(self.origin,e.origin);
 567             //self.pathgoal = e;
 568         }
 569     }
 570 }
 571
 572 void walker_diehook()
 573 {
 574 #ifdef self.pathcurrent
 575     if (self.pathcurrent)
 576         pathlib_deletepath(self.pathcurrent.owner);
 577 #endif
 578
 579     self.pathcurrent = world;
 580 }
 581
 582 void turret_walker_dinit()
 583 {
 584
 585     entity e;
 586
 587     if (self.netname == "")      self.netname     = "Walker Turret";
 588
 589     self.ammo_flags = TFL_AMMO_BULLETS | TFL_AMMO_RECHARGE | TFL_AMMO_RECIVE;
 590     self.turrcaps_flags = TFL_TURRCAPS_PLAYERKILL | TFL_TURRCAPS_MOVE ;
 591     self.aim_flags = TFL_AIM_LEAD;
 592
 593     if (autocvar_g_antilag_bullets)
 594         self.turrcaps_flags |= TFL_TURRCAPS_HITSCAN;
 595     else
 596         self.aim_flags      |= TFL_AIM_SHOTTIMECOMPENSATE;
 597
 598
 599     self.turret_respawnhook = walker_respawnhook;
 600     self.turret_diehook = walker_diehook;
 601
 602     self.ticrate = 0.05;
 603     if (turret_stdproc_init("walker_std", "models/turrets/walker_body.md3", "models/turrets/walker_head_minigun.md3", TID_WALKER) == 0)
 604     {
 605         remove(self);
 606         return;
 607     }
 608
 609     self.damage_flags |= TFL_DMG_DEATH_NOGIBS;
 610     self.target_select_flags   = TFL_TARGETSELECT_PLAYERS | TFL_TARGETSELECT_RANGELIMTS | TFL_TARGETSELECT_TEAMCHECK | TFL_TARGETSELECT_LOS;
 611     self.target_validate_flags = TFL_TARGETSELECT_PLAYERS | TFL_TARGETSELECT_RANGELIMTS | TFL_TARGETSELECT_TEAMCHECK | TFL_TARGETSELECT_LOS;
 612
 613     self.iscreature = TRUE;
 614     self.damagedbycontents = TRUE;
 615     self.movetype   = MOVETYPE_WALK;
 616     self.solid      = SOLID_SLIDEBOX;
 617     self.takedamage = DAMAGE_AIM;
 618
 619
 620     setsize(self, WALKER_MIN, WALKER_MAX);
 621
 622     setorigin(self, self.origin);
 623     tracebox(self.origin + '0 0 128', self.mins,self.maxs,self.origin - '0 0 10000', MOVE_NORMAL, self);
 624     setorigin(self, trace_endpos + '0 0 4');
 625     self.pos1 = self.origin;
 626     self.pos2 = self.angles;
 627
 628     self.idle_aim = '0 0 0';
 629     self.turret_firecheckfunc = walker_firecheck;
 630     self.turret_firefunc      = walker_attack;
 631     self.turret_postthink     = walker_postthink;
 632
 633     if (self.target != "")
 634     {
 635         e = find(world, targetname, self.target);
 636         if (!e)
 637         {
 638             dprint("Initital waypoint for walker does NOT exsist, fix your map!\n");
 639             self.target = "";
 640         }
 641
 642         if (e.classname != "turret_checkpoint")
 643             dprint("Warning: not a turrret path\n");
 644         else
 645         {
 646 #ifdef WALKER_FANCYPATHING
 647             self.pathcurrent = WALKER_PATH(self.origin, e.origin);
 648             self.pathgoal = e;
 649 #else
 650             self.pathcurrent = e;
 651 #endif
 652         }
 653     }
 654 }
 655
 656
 657 void spawnfunc_turret_walker()
 658 {
 659     g_turrets_common_precash();
 660
 661     precache_model ("models/turrets/walker_head_minigun.md3");
 662     precache_model ("models/turrets/walker_body.md3");
 663     precache_model ( "models/turrets/rocket.md3");
 664     precache_sound ( "weapons/rocket_impact.wav" );
 665
 666     self.think = turret_walker_dinit;
 667     self.nextthink = time + 0.5;
 668 }