qcsrc/server/vehicles/racer.qc

   1 #define RACER_MIN '-120 -120 -40'
   2 #define RACER_MAX '120 120 40'
   3 #define RACER_ENGINE "sound/vehicles/racer.wav"
   4
   5 #ifdef SVQC
   6 void racer_exit(float eject);
   7 void racer_enter();
   8
   9 // Auto cvars
  10 float autocvar_g_vehicle_racer_speed_afterburn;
  11 float autocvar_g_vehicle_racer_afterburn_cost;
  12
  13 float autocvar_g_vehicle_racer_anglestabilizer;
  14 float autocvar_g_vehicle_racer_downforce;
  15
  16 float autocvar_g_vehicle_racer_speed_forward;
  17 float autocvar_g_vehicle_racer_speed_strafe;
  18 float autocvar_g_vehicle_racer_springlength;
  19 float autocvar_g_vehicle_racer_upforcedamper;
  20 float autocvar_g_vehicle_racer_friction;
  21
  22 float autocvar_g_vehicle_racer_hovertype;
  23 float autocvar_g_vehicle_racer_hoverpower;
  24
  25 float autocvar_g_vehicle_racer_turnroll;
  26 float autocvar_g_vehicle_racer_turnspeed;
  27 float autocvar_g_vehicle_racer_pitchspeed;
  28
  29 float autocvar_g_vehicle_racer_energy;
  30 float autocvar_g_vehicle_racer_energy_regen;
  31 float autocvar_g_vehicle_racer_energy_regen_pause;
  32
  33 float autocvar_g_vehicle_racer_health;
  34 float autocvar_g_vehicle_racer_health_regen;
  35 float autocvar_g_vehicle_racer_health_regen_pause;
  36
  37 float autocvar_g_vehicle_racer_shield;
  38 float autocvar_g_vehicle_racer_shield_regen;
  39 float autocvar_g_vehicle_racer_shield_regen_pause;
  40
  41 float autocvar_g_vehicle_racer_cannon_cost;
  42 float autocvar_g_vehicle_racer_cannon_damage;
  43 float autocvar_g_vehicle_racer_cannon_radius;
  44 float autocvar_g_vehicle_racer_cannon_refire;
  45 float autocvar_g_vehicle_racer_cannon_speed;
  46 float autocvar_g_vehicle_racer_cannon_spread;
  47 float autocvar_g_vehicle_racer_cannon_force;
  48
  49 float autocvar_g_vehicle_racer_rocket_accel;
  50 float autocvar_g_vehicle_racer_rocket_damage;
  51 float autocvar_g_vehicle_racer_rocket_radius;
  52 float autocvar_g_vehicle_racer_rocket_force;
  53 float autocvar_g_vehicle_racer_rocket_refire;
  54 float autocvar_g_vehicle_racer_rocket_speed;
  55 float autocvar_g_vehicle_racer_rocket_turnrate;
  56
  57 float autocvar_g_vehicle_racer_rocket_locktarget;
  58 float autocvar_g_vehicle_racer_rocket_locking_time;
  59 float autocvar_g_vehicle_racer_rocket_locking_releasetime;
  60 float autocvar_g_vehicle_racer_rocket_locked_time;
  61 float autocvar_g_vehicle_racer_rocket_locked_maxangle;
  62
  63 float autocvar_g_vehicle_racer_respawntime;
  64
  65 float autocvar_g_vehicle_racer_blowup_radius;
  66 float autocvar_g_vehicle_racer_blowup_coredamage;
  67 float autocvar_g_vehicle_racer_blowup_edgedamage;
  68 float autocvar_g_vehicle_racer_blowup_forceintensity;
  69
  70 var vector racer_force_from_tag(string tag_name, float spring_length, float max_power);
  71
  72 void racer_align4point()
  73 {
  74     vector push_vector, v_add;
  75     float fl_push, fr_push, bl_push, br_push;
  76
  77
  78     push_vector  = racer_force_from_tag("tag_engine_fr", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  79     fr_push      = force_fromtag_normpower;
  80     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  81
  82     push_vector += racer_force_from_tag("tag_engine_fl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  83     fl_push      = force_fromtag_normpower;
  84     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  85
  86     push_vector += racer_force_from_tag("tag_engine_br", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  87     br_push      = force_fromtag_normpower;
  88     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  89
  90     push_vector += racer_force_from_tag("tag_engine_bl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  91     bl_push      = force_fromtag_normpower;
  92     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  93
  94     self.velocity += (push_vector * frametime);
  95
  96     // Anti ocilation
  97     if(self.velocity_z  > 0)
  98         self.velocity_z *= 1 - (autocvar_g_vehicle_racer_upforcedamper * frametime);
  99
 100     self.velocity   += v_add;
 101     //self.velocity_z -= autocvar_sv_gravity * frametime;
 102
 103     push_vector_x =  (fl_push - bl_push);
 104     push_vector_x += (fr_push - br_push);
 105     push_vector_x *= 360;
 106
 107     push_vector_z = (fr_push - fl_push);
 108     push_vector_z += (br_push - bl_push);
 109     push_vector_z *= 360;
 110
 111     // Apply angle diffrance
 112     self.angles_z += push_vector_z * frametime;
 113     self.angles_x += push_vector_x * frametime;
 114
 115     // Apply stabilizer
 116     self.angles_x *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * frametime);
 117     self.angles_z *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * frametime);
 118 }
 119
 120 void racer_fire_cannon(string tagname)
 121 {
 122     vector v;
 123     entity bolt;
 124
 125     v = gettaginfo(self, gettagindex(self, tagname));
 126     bolt = vehicles_projectile("wakizashi_gun_muzzleflash", "weapons/lasergun_fire.wav",
 127                            v, normalize(v_forward + randomvec() * autocvar_g_vehicle_racer_cannon_spread) * autocvar_g_vehicle_racer_cannon_speed,
 128                            autocvar_g_vehicle_racer_cannon_damage, autocvar_g_vehicle_racer_cannon_radius, autocvar_g_vehicle_racer_cannon_force,  0,
 129                            DEATH_WAKIGUN, PROJECTILE_WAKICANNON, 0, TRUE, TRUE);
 130
 131         // Fix z-aim (for chase mode)
 132     v = normalize(trace_endpos - bolt.origin);
 133     v_forward_z = v_z * 0.5;
 134     bolt.velocity = v_forward * autocvar_g_vehicle_racer_cannon_speed;
 135 }
 136
 137 void racer_rocket_groundhugger()
 138 {
 139     vector olddir, newdir;
 140     float oldvel, newvel;
 141
 142     self.nextthink  = time;
 143
 144     if(self.owner.deadflag != DEAD_NO || self.cnt < time)
 145     {
 146         self.use();
 147         return;
 148     }
 149
 150     if not (self.realowner.vehicle)
 151     {
 152         UpdateCSQCProjectile(self);
 153         return;
 154     }
 155
 156     olddir = normalize(self.velocity);
 157     oldvel = vlen(self.velocity);
 158     newvel = oldvel + self.lip;
 159
 160     tracebox(self.origin, self.mins, self.maxs, self.origin + olddir * 64, MOVE_WORLDONLY,self);
 161     if(trace_fraction <= 0.5)
 162     {
 163         // Hitting somethign soon, just speed ahead
 164         self.velocity = olddir * newvel;
 165         UpdateCSQCProjectile(self);
 166         return;
 167     }
 168
 169     traceline(trace_endpos, trace_endpos - '0 0 64', MOVE_NORMAL, self);
 170     if(trace_fraction != 1.0)
 171     {
 172         newdir = normalize(trace_endpos + '0 0 64' - self.origin) * autocvar_g_vehicle_racer_rocket_turnrate;
 173         self.velocity = normalize(olddir + newdir) * newvel;
 174     }
 175     else
 176     {
 177         self.velocity = olddir * newvel;
 178         self.velocity_z -= 1600 * sys_frametime; // 2x grav looks better for this one
 179     }
 180
 181     UpdateCSQCProjectile(self);
 182     return;
 183 }
 184
 185 void racer_rocket_tracker()
 186 {
 187     vector olddir, newdir;
 188     float oldvel, newvel;
 189
 190     self.nextthink  = time;
 191
 192     if (self.owner.deadflag != DEAD_NO || self.cnt < time)
 193     {
 194         self.use();
 195         return;
 196     }
 197
 198     if not (self.realowner.vehicle)
 199     {
 200         UpdateCSQCProjectile(self);
 201         return;
 202     }
 203
 204     olddir = normalize(self.velocity);
 205     oldvel = vlen(self.velocity);
 206     newvel = oldvel + self.lip;
 207     makevectors(vectoangles(olddir));
 208
 209     traceline(self.origin, self.origin + v_forward * 64 - '0 0 32', MOVE_NORMAL, self);
 210     newdir = normalize(self.enemy.origin - self.origin);
 211
 212     if(vlen(newdir - v_forward) > autocvar_g_vehicle_racer_rocket_locked_maxangle)
 213     {
 214         //bprint("Target lost!\n");
 215         //dprint("OF:", ftos(vlen(newdir - v_forward)), "\n");
 216         self.think = racer_rocket_groundhugger;
 217         return;
 218     }
 219
 220     if(trace_fraction != 1.0)
 221         newdir_z += 16 * sys_frametime;
 222
 223     self.velocity = normalize(olddir + newdir * autocvar_g_vehicle_racer_rocket_turnrate) * newvel;
 224     self.velocity_z -= 800 * sys_frametime;
 225
 226     UpdateCSQCProjectile(self);
 227     return;
 228 }
 229
 230 void racer_fire_rocket(string tagname, entity trg)
 231 {
 232     vector v;
 233     entity rocket;
 234
 235     v = gettaginfo(self, gettagindex(self, tagname));
 236     rocket = vehicles_projectile("wakizashi_rocket_launch", "weapons/rocket_fire.wav",
 237                            v, v_forward * autocvar_g_vehicle_racer_rocket_speed,
 238                            autocvar_g_vehicle_racer_rocket_damage, autocvar_g_vehicle_racer_rocket_radius, autocvar_g_vehicle_racer_rocket_force, 3,
 239                            DEATH_WAKIROCKET, PROJECTILE_WAKIROCKET, 20, FALSE, FALSE);
 240
 241     rocket.lip              = autocvar_g_vehicle_racer_rocket_accel * sys_frametime;
 242     rocket.wait             = autocvar_g_vehicle_racer_rocket_turnrate;
 243     rocket.nextthink        = time;
 244     rocket.enemy            = trg;
 245     rocket.cnt              = time + 15;
 246
 247     if(trg)
 248         rocket.think            = racer_rocket_tracker;
 249     else
 250         rocket.think            = racer_rocket_groundhugger;
 251 }
 252
 253 float racer_frame()
 254 {
 255     entity player, racer;
 256     vector df;
 257     float ftmp;
 258
 259     player          = self;
 260     racer           = self.vehicle;
 261
 262     player.BUTTON_ZOOM = player.BUTTON_CROUCH = 0;
 263
 264     self = racer;
 265
 266 #ifdef VEHICLES_CSQC
 267     racer.SendFlags |= VSF_MOVEMENT;
 268
 269     // Send a origin update every 10'th serevr frame.
 270     racer.framecounter += 1;
 271     if(racer.framecounter >= 600)
 272     {
 273         racer.SendFlags |= VSF_ORIGIN;
 274         racer.framecounter = 0;
 275     }
 276 #endif
 277
 278     if(player.BUTTON_USE)
 279     {
 280         vehicles_exit(VHEF_NORMAL);
 281         self = player;
 282         return 0;
 283     }
 284
 285     if(racer.deadflag != DEAD_NO)
 286     {
 287         self = player;
 288         player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 289         return 1;
 290     }
 291
 292     racer_align4point();
 293
 294     crosshair_trace(player);
 295
 296 #if VEHICLES_VIEWROTATE_CROSSHAIR
 297     float ftmp2;
 298     racer.angles_x *= -1;
 299     df = vectoangles(normalize(trace_endpos - self.origin + '0 0 32'));
 300     if(df_x > 180)  df_x -= 360;
 301     if(df_x < -180) df_x += 360;
 302     if(df_y > 180)  df_y -= 360;
 303     if(df_y < -180) df_y += 360;
 304
 305     // Yaw
 306     ftmp = autocvar_g_vehicle_racer_turnspeed * frametime;
 307     ftmp2 = ftmp * -1;
 308
 309     ftmp = bound(ftmp2, shortangle_f(df_y - racer.angles_y, racer.angles_y), ftmp);
 310     ftmp2 = anglemods(racer.angles_y + ftmp);
 311
 312     // Roll
 313     ftmp = bound(-45, shortangle_f(df_z + ((racer.angles_y - ftmp2) * autocvar_g_vehicle_racer_turnroll), racer.angles_z), 45);
 314     ftmp = anglemods(racer.angles_z + ftmp) * frametime;
 315     racer.angles_z = bound(-65, racer.angles_z + ftmp, 65);
 316
 317     // Turn
 318     racer.angles_y = ftmp2;
 319
 320     // Pitch
 321     ftmp = autocvar_g_vehicle_racer_pitchspeed * frametime;
 322     ftmp2 = ftmp * -1;
 323
 324     ftmp = bound(ftmp2, shortangle_f(player.v_angle_x - racer.angles_x, racer.angles_x), ftmp);
 325     racer.angles_x = anglemods(racer.angles_x + ftmp);
 326
 327     makevectors(racer.angles);
 328     racer.angles_x *= -1;
 329 #else
 330     racer.angles_x *= -1;
 331
 332     // Yaw
 333     ftmp = autocvar_g_vehicle_racer_turnspeed * frametime;
 334     ftmp = bound(-ftmp, shortangle_f(player.v_angle_y - racer.angles_y, racer.angles_y), ftmp);
 335     racer.angles_y = anglemods(racer.angles_y + ftmp);
 336
 337     // Roll
 338     racer.angles_z += -ftmp * autocvar_g_vehicle_racer_turnroll * frametime;
 339
 340     // Pitch
 341     ftmp = autocvar_g_vehicle_racer_pitchspeed  * frametime;
 342     ftmp = bound(-ftmp, shortangle_f(player.v_angle_x - racer.angles_x, racer.angles_x), ftmp);
 343     racer.angles_x = bound(-30, anglemods(racer.angles_x + ftmp), 30);
 344
 345     makevectors(racer.angles);
 346     racer.angles_x *= -1;
 347 #endif
 348
 349     ftmp = racer.velocity_z;
 350     df = racer.velocity * -autocvar_g_vehicle_racer_friction;
 351     racer.velocity_z = ftmp;
 352
 353     if(player.movement_x != 0)
 354     {
 355         if(player.movement_x > 0)
 356             df += v_forward  * autocvar_g_vehicle_racer_speed_forward;
 357         else if(player.movement_x < 0)
 358             df -= v_forward  * autocvar_g_vehicle_racer_speed_forward;
 359     }
 360
 361     if(player.movement_y != 0)
 362     {
 363         if(player.movement_y < 0)
 364             df -= v_right * autocvar_g_vehicle_racer_speed_strafe;
 365         else if(player.movement_y > 0)
 366             df += v_right * autocvar_g_vehicle_racer_speed_strafe;
 367     }
 368
 369     if(vlen(player.movement) != 0)
 370     {
 371         if(self.sound_nexttime < time || self.sounds != 1)
 372         {
 373             self.sounds = 1;
 374             self.sound_nexttime = time + 10.922667; //soundlength("vehicles/racer_move.wav");
 375             sound (self, CHAN_VOICE, "vehicles/racer_move.wav", VOL_BASE, ATTN_NORM);
 376         }
 377     }
 378     else
 379     {
 380         if(self.sound_nexttime < time || self.sounds != 0)
 381         {
 382             self.sounds = 0;
 383             self.sound_nexttime = time + 11.888604; //soundlength("vehicles/racer_idle.wav");
 384             sound (self, CHAN_VOICE, "vehicles/racer_idle.wav", VOL_BASE, ATTN_NORM);
 385         }
 386     }
 387
 388     // Afterburn
 389     if (player.BUTTON_JUMP && racer.vehicle_energy >= (autocvar_g_vehicle_racer_afterburn_cost * frametime))
 390     {
 391         racer.wait = time;
 392         racer.vehicle_energy -= autocvar_g_vehicle_racer_afterburn_cost * frametime;
 393         df += (v_forward * autocvar_g_vehicle_racer_speed_afterburn);
 394
 395         if(self.strength_finished < time)
 396         {
 397             //self.sounds = 2;
 398             self.strength_finished = time + 10.922667; //soundlength("vehicles/racer_boost.wav");
 399             sound (self, CHAN_PLAYER, "vehicles/racer_boost.wav", VOL_BASE, ATTN_NORM);
 400         }
 401     }
 402     else
 403     {
 404         self.strength_finished = 0;
 405         sound (self, CHAN_PLAYER, "misc/null.wav", VOL_BASE, ATTN_NORM);
 406     }
 407
 408
 409     racer.velocity  += df * frametime;
 410
 411     df = (vlen(racer.velocity) * autocvar_g_vehicle_racer_downforce * v_up) * frametime;
 412     racer.velocity  = racer.velocity - df;
 413     player.movement = racer.velocity;
 414
 415     if(player.BUTTON_ATCK)
 416     if(time > racer.attack_finished_single)
 417     if(racer.vehicle_energy >= autocvar_g_vehicle_racer_cannon_cost)
 418     {
 419         racer.vehicle_energy -= autocvar_g_vehicle_racer_cannon_cost;
 420         racer.wait = time;
 421
 422         crosshair_trace(player);
 423         if(racer.cnt)
 424         {
 425             racer_fire_cannon("tag_fire1");
 426             racer.cnt = 0;
 427         }
 428         else
 429         {
 430             racer_fire_cannon("tag_fire2");
 431             racer.cnt = 1;
 432         }
 433         racer.attack_finished_single = time + autocvar_g_vehicle_racer_cannon_refire;
 434         //self.owner.vehicle_energy = racer.vehicle_energy / autocvar_g_vehicle_racer_energy;
 435     }
 436
 437     if(autocvar_g_vehicle_racer_rocket_locktarget)
 438     {
 439         vehicles_locktarget((1 / autocvar_g_vehicle_racer_rocket_locking_time) * frametime,
 440                          (1 / autocvar_g_vehicle_racer_rocket_locking_releasetime) * frametime,
 441                          autocvar_g_vehicle_racer_rocket_locked_time);
 442
 443         if(self.lock_target)
 444         {
 445             if(racer.lock_strength == 1)
 446                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '1 0 0', 0);
 447             else if(self.lock_strength > 0.5)
 448                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '0 1 0', 0);
 449             else if(self.lock_strength < 0.5)
 450                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '0 0 1', 0);
 451         }
 452     }
 453
 454     if(time > racer.delay)
 455     if(player.BUTTON_ATCK2)
 456     {
 457         self.misc_bulletcounter += 1;
 458         racer.delay = time + 0.2;
 459         if(self.misc_bulletcounter == 1)
 460             racer_fire_rocket("tag_rocket_r", (self.lock_strength == 1 && self.lock_target) ? self.lock_target : world);
 461         else if(self.misc_bulletcounter == 2)
 462         {
 463             racer_fire_rocket("tag_rocket_l", (self.lock_strength == 1 && self.lock_target) ? self.lock_target : world);
 464             self.lock_strength  = 0;
 465             self.lock_target    = world;
 466             self.misc_bulletcounter = 0;
 467
 468             racer.delay = time + autocvar_g_vehicle_racer_rocket_refire;
 469             racer.lip = time;
 470         }
 471     }
 472     player.vehicle_reload1 = bound(0, 100 * ((time - racer.lip) / (racer.delay - racer.lip)), 100);
 473
 474     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 475         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_racer_shield, autocvar_g_vehicle_racer_shield_regen_pause, autocvar_g_vehicle_racer_shield_regen, frametime);
 476
 477     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 478         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_racer_health, autocvar_g_vehicle_racer_health_regen_pause, autocvar_g_vehicle_racer_health_regen, frametime);
 479
 480     if(self.vehicle_flags  & VHF_ENERGYREGEN)
 481         vehicles_regen(wait, vehicle_energy, autocvar_g_vehicle_racer_energy, autocvar_g_vehicle_racer_energy_regen_pause, autocvar_g_vehicle_racer_energy_regen, frametime);
 482
 483
 484     VEHICLE_UPDATE_PLAYER(health, racer);
 485     VEHICLE_UPDATE_PLAYER(energy, racer);
 486
 487     if(self.vehicle_flags & VHF_HASSHIELD)
 488         VEHICLE_UPDATE_PLAYER(shield, racer);
 489
 490
 491     player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 492     setorigin(player,racer.origin + '0 0 32');
 493     player.velocity = racer.velocity;
 494
 495     self = player;
 496     return 1;
 497 }
 498
 499 void racer_think()
 500 {
 501     /*
 502     float a, b, c;a = autocvar_g_vehicle_racer_anglestabilizer;
 503     b = autocvar_g_vehicle_racer_springlength;
 504     c = autocvar_g_vehicle_racer_hoverpower;
 505
 506     autocvar_g_vehicle_racer_anglestabilizer = 36;
 507     autocvar_g_vehicle_racer_springlength = 96;
 508     autocvar_g_vehicle_racer_hoverpower = 300;
 509     */
 510
 511     racer_align4point(); //time - self.nextthink);
 512 #ifdef VEHICLES_CSQC
 513     self.SendFlags |= VSF_MOVEMENT;
 514
 515     // Send a origin update every 10'th serevr frame.
 516     self.framecounter += 1;
 517     if(self.framecounter >= 10)
 518     {
 519         self.SendFlags |= VSF_ORIGIN;
 520         self.framecounter = 0;
 521     }
 522 #endif
 523     /*
 524     //if(self.velocity_z > 0)
 525     //    self.velocity_z *= 0.95;
 526
 527     autocvar_g_vehicle_racer_anglestabilizer = a;
 528     autocvar_g_vehicle_racer_springlength = b;
 529     autocvar_g_vehicle_racer_hoverpower = c;
 530     */
 531
 532     self.velocity_x *= 0.9;
 533     self.velocity_y *= 0.9;
 534     self.velocity_z *= 0.8;
 535     self.velocity_z += sin(time * 2) * 16;
 536     self.nextthink = time; // + 0.05;
 537 }
 538
 539 void racer_enter()
 540 {
 541     self.movetype = MOVETYPE_BOUNCE;
 542     self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_racer_health);
 543     self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_racer_shield);
 544 #ifdef VEHICLES_CSQC
 545     if(self.SendEntity)
 546         self.SendFlags |= VSF_SETUP;
 547 #endif
 548 }
 549
 550 void racer_exit(float eject)
 551 {
 552     vector spot;
 553
 554     self.think      = racer_think;
 555     self.nextthink  = time;
 556     self.movetype   = MOVETYPE_TOSS;
 557
 558     if not (self.owner)
 559         return;
 560
 561         makevectors(self.angles);
 562         if(eject)
 563         {
 564             spot = self.origin + v_forward * 100 + '0 0 64';
 565             spot = vehicles_findgoodexit(spot);
 566             setorigin(self.owner , spot);
 567             self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 568         }
 569         else
 570         {
 571             spot = self.origin - v_forward * 200 + '0 0 64';
 572             spot = vehicles_findgoodexit(spot);
 573             setorigin(self.owner , spot);
 574         }
 575
 576     self.owner = world;
 577 }
 578
 579 void racer_spawn()
 580 {
 581     self.think          = racer_think;
 582     self.nextthink      = time;
 583     self.vehicle_health = autocvar_g_vehicle_racer_health;
 584     self.vehicle_shield = autocvar_g_vehicle_racer_shield;
 585
 586     self.movetype       = MOVETYPE_TOSS;
 587     self.solid          = SOLID_SLIDEBOX;
 588     self.delay          = time;
 589     self.scale          = 0.5;
 590
 591     setsize(self, RACER_MIN * 0.5, RACER_MAX * 0.5);
 592 }
 593
 594
 595 void racer_blowup()
 596 {
 597     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 598     pointparticles(particleeffectnum("explosion_big"), self.origin, '0 0 0', 1);
 599
 600     self.deadflag    = DEAD_DEAD;
 601     self.vehicle_exit(VHEF_NORMAL);
 602
 603     RadiusDamage (self, self, autocvar_g_vehicle_racer_blowup_coredamage,
 604                                         autocvar_g_vehicle_racer_blowup_edgedamage,
 605                                         autocvar_g_vehicle_racer_blowup_radius, world,
 606                                         autocvar_g_vehicle_racer_blowup_forceintensity,
 607                                         DEATH_WAKIBLOWUP, world);
 608
 609     self.alpha = -1;
 610     self.nextthink  = time + autocvar_g_vehicle_racer_respawntime;
 611     self.think      = racer_spawn;
 612     self.movetype   = MOVETYPE_NONE;
 613     self.effects    = EF_NODRAW;
 614
 615     self.colormod  = '0 0 0';
 616     self.avelocity = '0 0 0';
 617     self.velocity  = '0 0 0';
 618
 619     setorigin(self, self.pos1);
 620         self.think     = racer_spawn;
 621         self.nextthink = time + autocvar_g_vehicle_racer_respawntime;
 622 }
 623
 624 void racer_deadtouch()
 625 {
 626     dprint("Boink!\n");
 627     self.avelocity_x *= 0.7;
 628     self.cnt -= 1;
 629     if(self.cnt <= 0)
 630         racer_blowup();
 631 }
 632
 633 void racer_die()
 634 {
 635     self.health       = 0;
 636     self.event_damage = SUB_Null;
 637     self.iscreature   = FALSE;
 638     self.solid        = SOLID_CORPSE;
 639     self.takedamage   = DAMAGE_NO;
 640     self.deadflag     = DEAD_DYING;
 641     self.movetype     = MOVETYPE_BOUNCE;
 642     self.wait         = time;
 643     self.cnt          = 1 + random() * 2;
 644     self.touch        = racer_deadtouch;
 645
 646     pointparticles(particleeffectnum("explosion_medium"), self.origin, '0 0 0', 1);
 647
 648     if(random() < 0.5)
 649         self.avelocity_z  = 32;
 650     else
 651         self.avelocity_z  = -32;
 652
 653     self.avelocity_x = -vlen(self.velocity) * 0.2;
 654     self.velocity   += '0 0 700';
 655     self.colormod    = '-0.5 -0.5 -0.5';
 656
 657         self.think     = racer_blowup;
 658         self.nextthink = 2 + time + random() * 3;
 659 }
 660
 661 #ifdef VEHICLES_CSQC
 662 void racer_send_exta(entity to)
 663 {
 664
 665 }
 666 #endif
 667
 668 void racer_dinit()
 669 {
 670     if not (vehicle_initialize(
 671              "Wakizashi",
 672              "models/vehicles/wakizashi.dpm",
 673              "",
 674              "models/vehicles/wakizashi_cockpit.dpm",
 675              "", "", "tag_viewport",
 676              HUD_WAKIZASHI,
 677              0.5 * RACER_MIN, 0.5 * RACER_MAX,
 678              FALSE,
 679              racer_spawn, autocvar_g_vehicle_racer_respawntime,
 680              racer_frame,
 681              racer_enter, racer_exit,
 682              racer_die,   racer_think,
 683              TRUE))
 684     {
 685         remove(self);
 686         return;
 687     }
 688 #ifdef VEHICLES_CSQC
 689     self.vehile_send_exta = racer_send_exta;
 690 #endif
 691     if(autocvar_g_vehicle_racer_hovertype != 0)
 692         racer_force_from_tag = vehicles_force_fromtag_maglev;
 693     else
 694         racer_force_from_tag = vehicles_force_fromtag_hover;
 695
 696     // FIXME: this be hakkz, fix the models insted (scale body, add tag_viewport to the hudmodel).
 697     self.scale = 0.5;
 698     setattachment(self.vehicle_hudmodel, self, "");
 699     setattachment(self.vehicle_viewport, self, "tag_viewport");
 700
 701     self.mass               = 900;
 702 }
 703
 704 void spawnfunc_vehicle_racer()
 705 {
 706
 707     precache_sound ("weapons/laserimpact.wav");
 708     precache_sound ("weapons/lasergun_fire.wav");
 709     precache_sound ("weapons/rocket_fire.wav");
 710     precache_sound ("weapons/rocket_impact.wav");
 711
 712     precache_sound ("vehicles/racer_idle.wav");
 713     precache_sound ("vehicles/racer_move.wav");
 714     precache_sound ("vehicles/racer_boost.wav");
 715
 716     precache_model ("models/vhshield.md3");
 717     precache_model ("models/vehicles/wakizashi.dpm");
 718     precache_model ("models/vehicles/wakizashi_cockpit.dpm");
 719
 720     vehicles_configcheck("vehicle_racer.cfg", autocvar_g_vehicle_racer_health);
 721     if(autocvar_g_vehicle_racer_energy)
 722         if(autocvar_g_vehicle_racer_energy_regen)
 723             self.vehicle_flags |= VHF_ENERGYREGEN;
 724
 725     if(autocvar_g_vehicle_racer_shield)
 726         self.vehicle_flags |= VHF_HASSHIELD;
 727
 728     if(autocvar_g_vehicle_racer_shield_regen)
 729         self.vehicle_flags |= VHF_SHIELDREGEN;
 730
 731     if(autocvar_g_vehicle_racer_health_regen)
 732         self.vehicle_flags |= VHF_HEALTHREGEN;
 733
 734     self.think = racer_dinit;
 735     self.nextthink = time + (autocvar_g_vehicles_delayspawn ? autocvar_g_vehicle_racer_respawntime + (random() * autocvar_g_vehicles_delayspawn_jitter) : 0.5);
 736 }
 737
 738 #endif // SVQC
 739
 740 #ifdef CSQC
 741 #ifdef VEHICLES_CSQC
 742 void racer_draw()
 743 {
 744     /*float dt;
 745
 746     dt = time - self.lastupdate;
 747     self.lastupdate = time;
 748     if(dt < 0)
 749         return;
 750     */
 751     //self.origin += dt * self.velocity;
 752     //self.origin_z -= dt * getstatf(STAT_MOVEVARS_GRAVITY);
 753     //setorigin(self, self.origin);
 754
 755     if(vehicle_hudmodel.owner  == self)
 756     {
 757         setorigin(vehicle_hudmodel, self.origin);
 758         vehicle_hudmodel.angles = self.angles;
 759     }
 760
 761
 762 }
 763
 764 void racer_draw2d()
 765 {
 766
 767 }
 768
 769 void racer_read_extra()
 770 {
 771
 772 }
 773
 774 entity racer_hud;
 775 entity racer_vp;
 776 void racer_hud_draw()
 777 {
 778
 779 }
 780
 781 void vehicle_racer_assemble()
 782 {
 783     setmodel(self, "models/vehicles/wakizashi.dpm");
 784     self.scale = 0.5;
 785     self.movetype = MOVETYPE_BOUNCE;
 786
 787     //self.entremove = VehicleRacerRemove;
 788     setsize(self,  '-60 -60 -20', '60 60 20');
 789     self.draw = racer_draw;
 790     self.drawmask = MASK_NORMAL;
 791     self.solid = SOLID_BBOX;
 792     self.lastupdate = time;
 793     self.vehile_read_exta = racer_read_extra;
 794
 795     if(racer_hud == world)
 796     {
 797         dprint("SpawnHUUUOOOUUUDDD\n");
 798         racer_hud = spawn();
 799         setmodel(racer_hud, "models/vehicles/wakizashi_cockpit.dpm");
 800         racer_hud.drawmask = MASK_NORMAL;
 801         racer_hud.renderflags = RF_VIEWMODEL;
 802         racer_hud.scale = 0.5;
 803     }
 804     vehicle_hudmodel = racer_hud; // FIXME!!
 805     racer_hud.draw   = racer_hud_draw;
 806 }
 807 #endif
 808 #endif //CSQC