qcsrc/server/vehicles/racer.qc

   1 #define RACER_MIN '-120 -120 -40'
   2 #define RACER_MAX '120 120 40'
   3 #define RACER_TICRATE 0.05
   4
   5 void racer_exit(float eject);
   6 void racer_enter();
   7
   8 // Auto cvars
   9 float autocvar_g_vehicle_racer_speed_afterburn;
  10 float autocvar_g_vehicle_racer_afterburn_cost;
  11
  12 float autocvar_g_vehicle_racer_anglestabilizer;
  13 float autocvar_g_vehicle_racer_downforce;
  14
  15 float autocvar_g_vehicle_racer_speed_forward;
  16 float autocvar_g_vehicle_racer_speed_strafe;
  17 float autocvar_g_vehicle_racer_springlength;
  18 float autocvar_g_vehicle_racer_upforcedamper;
  19 float autocvar_g_vehicle_racer_friction;
  20
  21 float autocvar_g_vehicle_racer_hovertype;
  22 float autocvar_g_vehicle_racer_hoverpower;
  23
  24 float autocvar_g_vehicle_racer_turnroll;
  25 float autocvar_g_vehicle_racer_turnspeed;
  26 float autocvar_g_vehicle_racer_pitchspeed;
  27
  28 float autocvar_g_vehicle_racer_energy;
  29 float autocvar_g_vehicle_racer_energy_regen;
  30 float autocvar_g_vehicle_racer_energy_regen_pause;
  31
  32 float autocvar_g_vehicle_racer_health;
  33 float autocvar_g_vehicle_racer_health_regen;
  34 float autocvar_g_vehicle_racer_health_regen_pause;
  35
  36 float autocvar_g_vehicle_racer_shield;
  37 float autocvar_g_vehicle_racer_shield_regen;
  38 float autocvar_g_vehicle_racer_shield_regen_pause;
  39
  40 float autocvar_g_vehicle_racer_cannon_cost;
  41 float autocvar_g_vehicle_racer_cannon_damage;
  42 float autocvar_g_vehicle_racer_cannon_radius;
  43 float autocvar_g_vehicle_racer_cannon_refire;
  44 float autocvar_g_vehicle_racer_cannon_speed;
  45 float autocvar_g_vehicle_racer_cannon_spread;
  46 float autocvar_g_vehicle_racer_cannon_force;
  47
  48 float autocvar_g_vehicle_racer_rocket_accel;
  49 float autocvar_g_vehicle_racer_rocket_damage;
  50 float autocvar_g_vehicle_racer_rocket_radius;
  51 float autocvar_g_vehicle_racer_rocket_force;
  52 float autocvar_g_vehicle_racer_rocket_refire;
  53 float autocvar_g_vehicle_racer_rocket_speed;
  54 float autocvar_g_vehicle_racer_rocket_turnrate;
  55
  56 float autocvar_g_vehicle_racer_rocket_locktarget;
  57 float autocvar_g_vehicle_racer_rocket_locking_time;
  58 float autocvar_g_vehicle_racer_rocket_locking_releasetime;
  59 float autocvar_g_vehicle_racer_rocket_locked_time;
  60 float autocvar_g_vehicle_racer_rocket_locked_maxangle;
  61
  62 float autocvar_g_vehicle_racer_respawntime;
  63 float autocvar_g_vehicle_racer_collision_multiplier;
  64
  65 float autocvar_g_vehicle_racer_blowup_radius;
  66 float autocvar_g_vehicle_racer_blowup_coredamage;
  67 float autocvar_g_vehicle_racer_blowup_edgedamage;
  68 float autocvar_g_vehicle_racer_blowup_forceintensity;
  69
  70 var vector racer_force_from_tag(string tag_name, float spring_length, float max_power);
  71
  72 void racer_align4point()
  73 {
  74     vector push_vector, v_add;
  75     float fl_push, fr_push, bl_push, br_push;
  76
  77
  78     push_vector  = racer_force_from_tag("tag_engine_fr", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  79     fr_push      = force_fromtag_normpower;
  80     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  81
  82     push_vector += racer_force_from_tag("tag_engine_fl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  83     fl_push      = force_fromtag_normpower;
  84     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  85
  86     push_vector += racer_force_from_tag("tag_engine_br", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  87     br_push      = force_fromtag_normpower;
  88     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  89
  90     push_vector += racer_force_from_tag("tag_engine_bl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  91     bl_push      = force_fromtag_normpower;
  92     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  93
  94     self.velocity += (push_vector * frametime);
  95
  96     // Anti ocilation
  97     if(self.velocity_z  > 0)
  98         self.velocity_z *= 1 - (autocvar_g_vehicle_racer_upforcedamper * frametime);
  99
 100     self.velocity   += v_add;
 101     //self.velocity_z -= autocvar_sv_gravity * frametime;
 102
 103     push_vector_x =  (fl_push - bl_push);
 104     push_vector_x += (fr_push - br_push);
 105     push_vector_x *= 360;
 106
 107     push_vector_z = (fr_push - fl_push);
 108     push_vector_z += (br_push - bl_push);
 109     push_vector_z *= 360;
 110
 111     // Apply angle diffrance
 112     self.angles_z += push_vector_z * frametime;
 113     self.angles_x += push_vector_x * frametime;
 114
 115     // Apply stabilizer
 116     self.angles_x *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * frametime);
 117     self.angles_z *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * frametime);
 118 }
 119
 120 void racer_fire_cannon(string tagname)
 121 {
 122     vector v;
 123     entity bolt;
 124
 125     v = gettaginfo(self, gettagindex(self, tagname));
 126     bolt = vehicles_projectile("wakizashi_gun_impact", "weapons/laserimpact.wav", "wakizashi_gun_muzzleflash", "weapons/lasergun_fire.wav",
 127                            v, normalize(v_forward + randomvec() * autocvar_g_vehicle_racer_cannon_spread) * autocvar_g_vehicle_racer_cannon_speed,
 128                            autocvar_g_vehicle_racer_cannon_damage, autocvar_g_vehicle_racer_cannon_radius, autocvar_g_vehicle_racer_cannon_force,  0,
 129                            DEATH_WAKIGUN, PROJECTILE_WAKICANNON, 0);
 130
 131         // Fix z-aim (for chase mode)
 132     v = normalize(trace_endpos - bolt.origin);
 133     v_forward_z = v_z * 0.5;
 134     bolt.velocity = v_forward * autocvar_g_vehicle_racer_cannon_speed;
 135 }
 136
 137 void racer_rocket_groundhugger()
 138 {
 139     vector olddir, newdir;
 140     float oldvel, newvel;
 141
 142     self.nextthink  = time;
 143
 144     if(self.owner.deadflag != DEAD_NO || self.cnt < time)
 145     {
 146         self.use();
 147         return;
 148     }
 149
 150     if not (self.realowner.vehicle)
 151     {
 152         UpdateCSQCProjectile(self);
 153         return;
 154     }
 155
 156     olddir = normalize(self.velocity);
 157     oldvel = vlen(self.velocity);
 158     newvel = oldvel + self.lip;
 159
 160     tracebox(self.origin, self.mins, self.maxs, self.origin + olddir * 64, MOVE_WORLDONLY,self);
 161     if(trace_fraction <= 0.5)
 162     {
 163         // Hitting somethign soon, just speed ahead
 164         self.velocity = olddir * newvel;
 165         UpdateCSQCProjectile(self);
 166         return;
 167     }
 168
 169     traceline(trace_endpos, trace_endpos - '0 0 64', MOVE_NORMAL, self);
 170     if(trace_fraction != 1.0)
 171     {
 172         newdir = normalize(trace_endpos + '0 0 64' - self.origin) * autocvar_g_vehicle_racer_rocket_turnrate;
 173         self.velocity = normalize(olddir + newdir) * newvel;
 174     }
 175     else
 176     {
 177         self.velocity = olddir * newvel;
 178         self.velocity_z -= 1600 * sys_frametime; // 2x grav looks better for this one
 179     }
 180
 181     UpdateCSQCProjectile(self);
 182     return;
 183 }
 184
 185 void racer_rocket_tracker()
 186 {
 187     vector olddir, newdir;
 188     float oldvel, newvel;
 189
 190     self.nextthink  = time;
 191
 192     if (self.owner.deadflag != DEAD_NO || self.cnt < time)
 193     {
 194         self.use();
 195         return;
 196     }
 197
 198     if not (self.realowner.vehicle)
 199     {
 200         UpdateCSQCProjectile(self);
 201         return;
 202     }
 203
 204     olddir = normalize(self.velocity);
 205     oldvel = vlen(self.velocity);
 206     newvel = oldvel + self.lip;
 207     makevectors(vectoangles(olddir));
 208
 209     traceline(self.origin, self.origin + v_forward * 64 - '0 0 32', MOVE_NORMAL, self);
 210     newdir = normalize(self.enemy.origin - self.origin);
 211
 212     if(vlen(newdir - v_forward) > autocvar_g_vehicle_racer_rocket_locked_maxangle)
 213     {
 214         //bprint("Target lost!\n");
 215         //dprint("OF:", ftos(vlen(newdir - v_forward)), "\n");
 216         self.think = racer_rocket_groundhugger;
 217         return;
 218     }
 219
 220     if(trace_fraction != 1.0)
 221         newdir_z += 16 * sys_frametime;
 222
 223     self.velocity = normalize(olddir + newdir * autocvar_g_vehicle_racer_rocket_turnrate) * newvel;
 224     self.velocity_z -= 800 * sys_frametime;
 225
 226     UpdateCSQCProjectile(self);
 227     return;
 228 }
 229
 230 void racer_fire_rocket(string tagname, entity trg)
 231 {
 232     vector v;
 233     entity rocket;
 234
 235     v = gettaginfo(self, gettagindex(self, tagname));
 236     rocket = vehicles_projectile("rocket_explode", "weapons/rocket_impact.wav", "", "weapons/rocket_fire.wav",
 237                            v, v_forward * autocvar_g_vehicle_racer_rocket_speed,
 238                            autocvar_g_vehicle_racer_rocket_damage, autocvar_g_vehicle_racer_rocket_radius, autocvar_g_vehicle_racer_rocket_force, 3,
 239                            DEATH_WAKIROCKET, PROJECTILE_WAKIROCKET, 20);
 240
 241     rocket.lip              = autocvar_g_vehicle_racer_rocket_accel * sys_frametime;
 242     rocket.wait             = autocvar_g_vehicle_racer_rocket_turnrate;
 243     rocket.nextthink        = time;
 244     rocket.enemy            = trg;
 245     rocket.cnt              = time + 15;
 246
 247     if(trg)
 248         rocket.think            = racer_rocket_tracker;
 249     else
 250         rocket.think            = racer_rocket_groundhugger;
 251 }
 252
 253 float racer_frame()
 254 {
 255     entity player, racer;
 256     vector df;
 257     float ftmp;
 258
 259     player          = self;
 260     racer           = self.vehicle;
 261
 262     player.BUTTON_ZOOM = player.BUTTON_CROUCH = 0;
 263
 264     self = racer;
 265
 266     if(player.BUTTON_USE)
 267     {
 268         vehicles_exit(VHEF_NORMAL);
 269         self = player;
 270         return 0;
 271     }
 272
 273     if(racer.deadflag != DEAD_NO)
 274     {
 275         self = player;
 276         player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 277         return 1;
 278     }
 279
 280     racer_align4point();
 281
 282     crosshair_trace(player);
 283
 284 #if VEHICLES_VIEWROTATE_CROSSHAIR
 285     float ftmp2;
 286     racer.angles_x *= -1;
 287     df = vectoangles(normalize(trace_endpos - self.origin + '0 0 32'));
 288     if(df_x > 180)  df_x -= 360;
 289     if(df_x < -180) df_x += 360;
 290     if(df_y > 180)  df_y -= 360;
 291     if(df_y < -180) df_y += 360;
 292
 293     // Yaw
 294     ftmp = autocvar_g_vehicle_racer_turnspeed * frametime;
 295     ftmp2 = ftmp * -1;
 296
 297     ftmp = bound(ftmp2, shortangle_f(df_y - racer.angles_y, racer.angles_y), ftmp);
 298     ftmp2 = anglemods(racer.angles_y + ftmp);
 299
 300     // Roll
 301     ftmp = bound(-45, shortangle_f(df_z + ((racer.angles_y - ftmp2) * autocvar_g_vehicle_racer_turnroll), racer.angles_z), 45);
 302     ftmp = anglemods(racer.angles_z + ftmp) * frametime;
 303     racer.angles_z = bound(-65, racer.angles_z + ftmp, 65);
 304
 305     // Turn
 306     racer.angles_y = ftmp2;
 307
 308     // Pitch
 309     ftmp = autocvar_g_vehicle_racer_pitchspeed * frametime;
 310     ftmp2 = ftmp * -1;
 311
 312     ftmp = bound(ftmp2, shortangle_f(player.v_angle_x - racer.angles_x, racer.angles_x), ftmp);
 313     racer.angles_x = anglemods(racer.angles_x + ftmp);
 314
 315     makevectors(racer.angles);
 316     racer.angles_x *= -1;
 317 #else
 318     racer.angles_x *= -1;
 319
 320     // Yaw
 321     ftmp = autocvar_g_vehicle_racer_turnspeed * frametime;
 322     ftmp = bound(-ftmp, shortangle_f(player.v_angle_y - racer.angles_y, racer.angles_y), ftmp);
 323     racer.angles_y = anglemods(racer.angles_y + ftmp);
 324
 325     // Roll
 326     racer.angles_z += -ftmp * autocvar_g_vehicle_racer_turnroll * frametime;
 327
 328     // Pitch
 329     ftmp = autocvar_g_vehicle_racer_pitchspeed  * frametime;
 330     ftmp = bound(-ftmp, shortangle_f(player.v_angle_x - racer.angles_x, racer.angles_x), ftmp);
 331     racer.angles_x = bound(-30, anglemods(racer.angles_x + ftmp), 30);
 332
 333     makevectors(racer.angles);
 334     racer.angles_x *= -1;
 335 #endif
 336
 337     df = racer.velocity * -autocvar_g_vehicle_racer_friction;
 338
 339     if(player.movement_x != 0)
 340     {
 341         if(player.movement_x > 0)
 342             df += v_forward  * autocvar_g_vehicle_racer_speed_forward;
 343         else if(player.movement_x < 0)
 344             df -= v_forward  * autocvar_g_vehicle_racer_speed_forward;
 345     }
 346
 347     if(player.movement_y != 0)
 348     {
 349         if(player.movement_y < 0)
 350             df -= v_right * autocvar_g_vehicle_racer_speed_strafe;
 351         else if(player.movement_y > 0)
 352             df += v_right * autocvar_g_vehicle_racer_speed_strafe;
 353     }
 354
 355     // Afterburn
 356     if (player.BUTTON_JUMP)
 357     if(racer.vehicle_energy >= (autocvar_g_vehicle_racer_afterburn_cost * frametime))
 358     {
 359         racer.wait = time;
 360         racer.vehicle_energy -= autocvar_g_vehicle_racer_afterburn_cost * frametime;
 361         df += (v_forward * autocvar_g_vehicle_racer_speed_afterburn);
 362         self.owner.vehicle_energy = racer.vehicle_energy / autocvar_g_vehicle_racer_energy;
 363     }
 364
 365     racer.velocity  += df * frametime;
 366
 367     df = (vlen(racer.velocity) * autocvar_g_vehicle_racer_downforce * v_up) * frametime;
 368     racer.velocity  = racer.velocity - df;
 369     player.movement = racer.velocity;
 370
 371     if(player.BUTTON_ATCK)
 372     if(time > racer.attack_finished_single)
 373     if(racer.vehicle_energy >= autocvar_g_vehicle_racer_cannon_cost)
 374     {
 375         racer.vehicle_energy -= autocvar_g_vehicle_racer_cannon_cost;
 376         racer.wait = time;
 377
 378         crosshair_trace(player);
 379         if(racer.cnt)
 380         {
 381             racer_fire_cannon("tag_fire1");
 382             racer.cnt = 0;
 383         }
 384         else
 385         {
 386             racer_fire_cannon("tag_fire2");
 387             racer.cnt = 1;
 388         }
 389         racer.attack_finished_single = time + autocvar_g_vehicle_racer_cannon_refire;
 390         self.owner.vehicle_energy = racer.vehicle_energy / autocvar_g_vehicle_racer_energy;
 391     }
 392
 393     if(autocvar_g_vehicle_racer_rocket_locktarget)
 394     {
 395         vehicles_locktarget((1 / autocvar_g_vehicle_racer_rocket_locking_time) * frametime,
 396                          (1 / autocvar_g_vehicle_racer_rocket_locking_releasetime) * frametime,
 397                          autocvar_g_vehicle_racer_rocket_locked_time);
 398
 399         if(self.lock_target)
 400         {
 401             if(racer.lock_strength == 1)
 402                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '1 0 0', 0);
 403             else if(self.lock_strength > 0.5)
 404                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '0 1 0', 0);
 405             else if(self.lock_strength < 0.5)
 406                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '0 0 1', 0);
 407         }
 408     }
 409
 410     if(time > racer.delay)
 411     if(player.BUTTON_ATCK2)
 412     {
 413         self.misc_bulletcounter += 1;
 414         racer.delay = time + 0.2;
 415         if(self.misc_bulletcounter == 1)
 416             racer_fire_rocket("tag_rocket_r", (self.lock_strength == 1 && self.lock_target) ? self.lock_target : world);
 417         else if(self.misc_bulletcounter == 2)
 418         {
 419             racer_fire_rocket("tag_rocket_l", (self.lock_strength == 1 && self.lock_target) ? self.lock_target : world);
 420             self.lock_strength  = 0;
 421             self.lock_target    = world;
 422             self.misc_bulletcounter = 0;
 423
 424             racer.delay = time + autocvar_g_vehicle_racer_rocket_refire;
 425             racer.lip = time;
 426         }
 427     }
 428     player.vehicle_reload1 = (time - racer.lip) / (racer.delay - racer.lip);
 429
 430     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 431         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_racer_shield, autocvar_g_vehicle_racer_shield_regen_pause, autocvar_g_vehicle_racer_shield_regen, frametime);
 432
 433     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 434         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_racer_health, autocvar_g_vehicle_racer_health_regen_pause, autocvar_g_vehicle_racer_health_regen, frametime);
 435
 436     if(self.vehicle_flags  & VHF_ENERGYREGEN)
 437         vehicles_regen(wait, vehicle_energy, autocvar_g_vehicle_racer_energy, autocvar_g_vehicle_racer_energy_regen_pause, autocvar_g_vehicle_racer_energy_regen, frametime);
 438
 439
 440     VEHICLE_UPDATE_PLAYER(health, racer);
 441
 442     if(self.vehicle_flags & VHF_HASSHIELD)
 443         VEHICLE_UPDATE_PLAYER(shield, racer);
 444
 445
 446     player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 447     setorigin(player,racer.origin + '0 0 32');
 448     player.velocity = racer.velocity;
 449
 450     self = player;
 451     return 1;
 452 }
 453
 454 void racer_think()
 455 {
 456     /*
 457     float a, b, c;a = autocvar_g_vehicle_racer_anglestabilizer;
 458     b = autocvar_g_vehicle_racer_springlength;
 459     c = autocvar_g_vehicle_racer_hoverpower;
 460
 461     autocvar_g_vehicle_racer_anglestabilizer = 36;
 462     autocvar_g_vehicle_racer_springlength = 96;
 463     autocvar_g_vehicle_racer_hoverpower = 300;
 464     */
 465
 466     racer_align4point(); //time - self.nextthink);
 467
 468     /*
 469     //if(self.velocity_z > 0)
 470     //    self.velocity_z *= 0.95;
 471
 472     autocvar_g_vehicle_racer_anglestabilizer = a;
 473     autocvar_g_vehicle_racer_springlength = b;
 474     autocvar_g_vehicle_racer_hoverpower = c;
 475     */
 476
 477     self.velocity_x *= 0.9;
 478     self.velocity_y *= 0.9;
 479     self.velocity_z *= 0.8;
 480     self.velocity_z += sin(time * 2) * 16;
 481     self.nextthink = time + 0.05;
 482 }
 483
 484 void racer_enter()
 485 {
 486     self.movetype = MOVETYPE_BOUNCE;
 487     self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_racer_health);
 488     self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_racer_shield);
 489 }
 490
 491 void racer_exit(float eject)
 492 {
 493     self.think      = racer_think;
 494     self.nextthink  = time;
 495     self.movetype   = MOVETYPE_TOSS;
 496
 497     if not (self.owner)
 498         return;
 499
 500         makevectors(self.angles);
 501         if(eject)
 502         {
 503             setorigin(self.owner, self.origin + v_forward * 100 + v_up * 32);
 504             self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 505         }
 506         else
 507         {
 508             setorigin(self.owner, self.origin - v_forward * 100 + v_up * 32);
 509             self.owner.velocity = v_forward * -150;
 510         }
 511     self.owner = world;
 512 }
 513
 514 void racer_spawn()
 515 {
 516     self.think          = racer_think;
 517     self.nextthink      = time;
 518     self.vehicle_health = autocvar_g_vehicle_racer_health;
 519     self.vehicle_shield = autocvar_g_vehicle_racer_shield;
 520
 521     self.movetype       = MOVETYPE_TOSS;
 522     self.solid          = SOLID_SLIDEBOX;
 523     self.delay          = time;
 524     self.scale          = 0.5;
 525
 526     setsize(self, RACER_MIN * 0.5, RACER_MAX * 0.5);
 527 }
 528
 529
 530 void racer_blowup()
 531 {
 532     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 533     pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 534
 535     self.deadflag    = DEAD_DEAD;
 536     self.vehicle_exit(VHEF_NORMAL);
 537
 538     RadiusDamage (self, self, autocvar_g_vehicle_racer_blowup_coredamage,
 539                                         autocvar_g_vehicle_racer_blowup_edgedamage,
 540                                         autocvar_g_vehicle_racer_blowup_radius, world,
 541                                         autocvar_g_vehicle_racer_blowup_forceintensity,
 542                                         DEATH_WAKIBLOWUP, world);
 543
 544     self.alpha = -1;
 545     self.nextthink  = time + autocvar_g_vehicle_racer_respawntime;
 546     self.think      = racer_spawn;
 547     self.movetype   = MOVETYPE_NONE;
 548     self.effects    = EF_NODRAW;
 549
 550     self.colormod  = '0 0 0';
 551     self.avelocity = '0 0 0';
 552     self.velocity  = '0 0 0';
 553
 554     setorigin(self, self.pos1);
 555         self.think     = racer_spawn;
 556         self.nextthink = time + autocvar_g_vehicle_racer_respawntime;
 557 }
 558
 559 void racer_deadtouch()
 560 {
 561     self.avelocity_x *= 0.7;
 562     self.cnt -= 1;
 563     if(self.cnt <= 0)
 564         racer_blowup();
 565 }
 566
 567 void racer_die()
 568 {
 569     self.health       = 0;
 570     self.event_damage = SUB_Null;
 571     self.iscreature   = FALSE;
 572     self.solid        = SOLID_CORPSE;
 573     self.takedamage   = DAMAGE_NO;
 574     self.deadflag     = DEAD_DYING;
 575     self.movetype     = MOVETYPE_BOUNCE;
 576     self.wait         = time;
 577     self.cnt          = 1 + random() * 3;
 578     self.touch        = racer_deadtouch;
 579
 580     pointparticles(particleeffectnum("rocket_explode"), findbetterlocation (self.origin, 16), '0 0 0', 1);
 581
 582     if(random() < 0.5)
 583         self.avelocity_z  = 16;
 584     else
 585         self.avelocity_z  = -16;
 586
 587     self.avelocity_x = -vlen(self.velocity) * 0.2;
 588     self.velocity   += '0 0 700';
 589     self.colormod    = '-0.5 -0.5 -0.5';
 590
 591         self.think     = racer_blowup;
 592         self.nextthink = 2 + time + random() * 3;
 593 }
 594
 595 void racer_dinit()
 596 {
 597     if not (vehicle_initialize(
 598              "Wakizashi",
 599              "models/vehicles/wakizashi.dpm",
 600              "",
 601              "models/vehicles/wakizashi_cockpit.dpm",
 602              "", "", "tag_viewport",
 603              HUD_WAKIZASHI,
 604              0.5 * RACER_MIN, 0.5 * RACER_MAX,
 605              FALSE,
 606              racer_spawn, autocvar_g_vehicle_racer_respawntime,
 607              racer_frame,
 608              racer_enter, racer_exit,
 609              racer_die,   racer_think))
 610     {
 611         remove(self);
 612         return;
 613     }
 614
 615     if(autocvar_g_vehicle_racer_hovertype != 0)
 616         racer_force_from_tag = vehicles_force_fromtag_maglev;
 617     else
 618         racer_force_from_tag = vehicles_force_fromtag_hover;
 619
 620     // FIXME: this be hakkz, fix the models insted (scale body, add tag_viewport to the hudmodel).
 621     self.scale = 0.5;
 622     //setattachment(self.vehicle_hudmodel, self, "");
 623     //setattachment(self.vehicle_viewport, self, "tag_viewport");
 624
 625     self.mass               = 900;
 626 }
 627
 628 void spawnfunc_vehicle_racer()
 629 {
 630
 631     precache_sound ("weapons/laserimpact.wav");
 632     precache_sound ("weapons/lasergun_fire.wav");
 633     precache_sound ("weapons/rocket_fire.wav");
 634     precache_sound ("weapons/rocket_impact.wav");
 635
 636     precache_model ("models/vhshield.md3");
 637     precache_model ("models/vehicles/wakizashi.dpm");
 638     precache_model ("models/vehicles/wakizashi_cockpit.dpm");
 639
 640     vehicles_configcheck("vehicle_racer.cfg", autocvar_g_vehicle_racer_health);
 641     if(autocvar_g_vehicle_racer_energy)
 642         if(autocvar_g_vehicle_racer_energy_regen)
 643             self.vehicle_flags |= VHF_ENERGYREGEN;
 644
 645     if(autocvar_g_vehicle_racer_shield)
 646         self.vehicle_flags |= VHF_HASSHIELD;
 647
 648     if(autocvar_g_vehicle_racer_shield_regen)
 649         self.vehicle_flags |= VHF_SHIELDREGEN;
 650
 651     if(autocvar_g_vehicle_racer_health_regen)
 652         self.vehicle_flags |= VHF_HEALTHREGEN;
 653
 654     self.think = racer_dinit;
 655     self.nextthink = time + 1;
 656 }