qcsrc/server/vehicles/racer.qc

   1 #define RACER_MIN '-120 -120 -40'
   2 #define RACER_MAX '120 120 40'
   3 #define RACER_TICRATE 0.05
   4
   5 void racer_exit(float eject);
   6 void racer_enter();
   7
   8 // Auto cvars
   9 float autocvar_g_vehicle_racer_speed_afterburn;
  10 float autocvar_g_vehicle_racer_afterburn_cost;
  11
  12 float autocvar_g_vehicle_racer_anglestabilizer;
  13 float autocvar_g_vehicle_racer_downforce;
  14
  15 float autocvar_g_vehicle_racer_speed_forward;
  16 float autocvar_g_vehicle_racer_speed_strafe;
  17 float autocvar_g_vehicle_racer_springlength;
  18 float autocvar_g_vehicle_racer_upforcedamper;
  19
  20 float autocvar_g_vehicle_racer_hovertype;
  21 float autocvar_g_vehicle_racer_hoverpower;
  22
  23 float autocvar_g_vehicle_racer_turnroll;
  24 float autocvar_g_vehicle_racer_turnspeed;
  25 float autocvar_g_vehicle_racer_pitchspeed;
  26
  27 float autocvar_g_vehicle_racer_energy;
  28 float autocvar_g_vehicle_racer_energy_regen;
  29 float autocvar_g_vehicle_racer_energy_regen_pause;
  30
  31 float autocvar_g_vehicle_racer_health;
  32 float autocvar_g_vehicle_racer_health_regen;
  33 float autocvar_g_vehicle_racer_health_regen_pause;
  34
  35 float autocvar_g_vehicle_racer_shield;
  36 float autocvar_g_vehicle_racer_shield_regen;
  37 float autocvar_g_vehicle_racer_shield_regen_pause;
  38
  39 float autocvar_g_vehicle_racer_cannon_cost;
  40 float autocvar_g_vehicle_racer_cannon_damage;
  41 float autocvar_g_vehicle_racer_cannon_radius;
  42 float autocvar_g_vehicle_racer_cannon_refire;
  43 float autocvar_g_vehicle_racer_cannon_speed;
  44 float autocvar_g_vehicle_racer_cannon_spread;
  45 float autocvar_g_vehicle_racer_cannon_force;
  46
  47 float autocvar_g_vehicle_racer_rocket_accel;
  48 float autocvar_g_vehicle_racer_rocket_damage;
  49 float autocvar_g_vehicle_racer_rocket_radius;
  50 float autocvar_g_vehicle_racer_rocket_force;
  51 float autocvar_g_vehicle_racer_rocket_refire;
  52 float autocvar_g_vehicle_racer_rocket_speed;
  53 float autocvar_g_vehicle_racer_rocket_turnrate;
  54
  55 float autocvar_g_vehicle_racer_rocket_locktarget;
  56 float autocvar_g_vehicle_racer_rocket_locking_time;
  57 float autocvar_g_vehicle_racer_rocket_locking_releasetime;
  58 float autocvar_g_vehicle_racer_rocket_locked_time;
  59 float autocvar_g_vehicle_racer_rocket_locked_maxangle;
  60
  61 float autocvar_g_vehicle_racer_respawntime;
  62 float autocvar_g_vehicle_racer_collision_multiplier;
  63
  64 float autocvar_g_vehicle_racer_blowup_radius;
  65 float autocvar_g_vehicle_racer_blowup_coredamage;
  66 float autocvar_g_vehicle_racer_blowup_edgedamage;
  67 float autocvar_g_vehicle_racer_blowup_forceintensity;
  68
  69 var vector racer_force_from_tag(string tag_name, float spring_length, float max_power);
  70
  71 void racer_align4point()
  72 {
  73     vector push_vector, v_add;
  74     float fl_push, fr_push, bl_push, br_push;
  75
  76
  77     push_vector  = racer_force_from_tag("tag_engine_fr", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  78     fr_push      = force_fromtag_normpower;
  79     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  80
  81     push_vector += racer_force_from_tag("tag_engine_fl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  82     fl_push      = force_fromtag_normpower;
  83     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  84
  85     push_vector += racer_force_from_tag("tag_engine_br", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  86     br_push      = force_fromtag_normpower;
  87     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  88
  89     push_vector += racer_force_from_tag("tag_engine_bl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  90     bl_push      = force_fromtag_normpower;
  91     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  92
  93     self.velocity += (push_vector * frametime);
  94
  95     // Anti ocilation
  96     if(self.velocity_z  > 0)
  97         self.velocity_z *= 1 - (autocvar_g_vehicle_racer_upforcedamper * frametime);
  98
  99     self.velocity   += v_add;
 100     //self.velocity_z -= autocvar_sv_gravity * frametime;
 101
 102     push_vector_x =  (fl_push - bl_push);
 103     push_vector_x += (fr_push - br_push);
 104     push_vector_x *= 360;
 105
 106     push_vector_z = (fr_push - fl_push);
 107     push_vector_z += (br_push - bl_push);
 108     push_vector_z *= 360;
 109
 110     // Apply angle diffrance
 111     self.angles_z += push_vector_z * frametime;
 112     self.angles_x += push_vector_x * frametime;
 113
 114     // Apply stabilizer
 115     self.angles_x *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * frametime);
 116     self.angles_z *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * frametime);
 117 }
 118
 119 void racer_fire_cannon(string tagname)
 120 {
 121     vector v;
 122     entity bolt;
 123
 124     v = gettaginfo(self, gettagindex(self, tagname));
 125     bolt = vehicles_projectile("wakizashi_gun_impact", "weapons/laserimpact.wav", "wakizashi_gun_muzzleflash", "weapons/lasergun_fire.wav",
 126                            v, normalize(v_forward + randomvec() * autocvar_g_vehicle_racer_cannon_spread) * autocvar_g_vehicle_racer_cannon_speed,
 127                            autocvar_g_vehicle_racer_cannon_damage, autocvar_g_vehicle_racer_cannon_radius, autocvar_g_vehicle_racer_cannon_force,  0,
 128                            DEATH_WAKIGUN, PROJECTILE_WAKICANNON, 0);
 129
 130         // Fix z-aim (for chase mode)
 131     v = normalize(trace_endpos - bolt.origin);
 132     v_forward_z = v_z * 0.5;
 133     bolt.velocity = v_forward * autocvar_g_vehicle_racer_cannon_speed;
 134 }
 135
 136 void racer_rocket_groundhugger()
 137 {
 138     vector olddir, newdir;
 139     float oldvel, newvel;
 140
 141     self.nextthink  = time;
 142
 143     if(self.owner.deadflag != DEAD_NO || self.cnt < time)
 144     {
 145         self.use();
 146         return;
 147     }
 148
 149     if not (self.realowner.vehicle)
 150     {
 151         UpdateCSQCProjectile(self);
 152         return;
 153     }
 154
 155     olddir = normalize(self.velocity);
 156     oldvel = vlen(self.velocity);
 157     newvel = oldvel + self.lip;
 158
 159     tracebox(self.origin, self.mins, self.maxs, self.origin + olddir * 64, MOVE_WORLDONLY,self);
 160     if(trace_fraction <= 0.5)
 161     {
 162         // Hitting somethign soon, just speed ahead
 163         self.velocity = olddir * newvel;
 164         UpdateCSQCProjectile(self);
 165         return;
 166     }
 167
 168     traceline(trace_endpos, trace_endpos - '0 0 64', MOVE_NORMAL, self);
 169     if(trace_fraction != 1.0)
 170     {
 171         newdir = normalize(trace_endpos + '0 0 64' - self.origin) * autocvar_g_vehicle_racer_rocket_turnrate;
 172         self.velocity = normalize(olddir + newdir) * newvel;
 173     }
 174     else
 175     {
 176         self.velocity = olddir * newvel;
 177         self.velocity_z -= 1600 * sys_frametime; // 2x grav looks better for this one
 178     }
 179
 180     UpdateCSQCProjectile(self);
 181     return;
 182 }
 183
 184 void racer_rocket_tracker()
 185 {
 186     vector olddir, newdir;
 187     float oldvel, newvel;
 188
 189     self.nextthink  = time;
 190
 191     if (self.owner.deadflag != DEAD_NO || self.cnt < time)
 192     {
 193         self.use();
 194         return;
 195     }
 196
 197     if not (self.realowner.vehicle)
 198     {
 199         UpdateCSQCProjectile(self);
 200         return;
 201     }
 202
 203     olddir = normalize(self.velocity);
 204     oldvel = vlen(self.velocity);
 205     newvel = oldvel + self.lip;
 206     makevectors(vectoangles(olddir));
 207
 208     traceline(self.origin, self.origin + v_forward * 64 - '0 0 32', MOVE_NORMAL, self);
 209     newdir = normalize(self.enemy.origin - self.origin);
 210
 211     if(vlen(newdir - v_forward) > autocvar_g_vehicle_racer_rocket_locked_maxangle)
 212     {
 213         //bprint("Target lost!\n");
 214         //dprint("OF:", ftos(vlen(newdir - v_forward)), "\n");
 215         self.think = racer_rocket_groundhugger;
 216         return;
 217     }
 218
 219     if(trace_fraction != 1.0)
 220         newdir_z += 16 * sys_frametime;
 221
 222     self.velocity = normalize(olddir + newdir * autocvar_g_vehicle_racer_rocket_turnrate) * newvel;
 223     self.velocity_z -= 800 * sys_frametime;
 224
 225     UpdateCSQCProjectile(self);
 226     return;
 227 }
 228
 229 void racer_fire_rocket(string tagname, entity trg)
 230 {
 231     vector v;
 232     entity rocket;
 233
 234     v = gettaginfo(self, gettagindex(self, tagname));
 235     rocket = vehicles_projectile("rocket_explode", "weapons/rocket_impact.wav", "", "weapons/rocket_fire.wav",
 236                            v, v_forward * autocvar_g_vehicle_racer_rocket_speed,
 237                            autocvar_g_vehicle_racer_rocket_damage, autocvar_g_vehicle_racer_rocket_radius, autocvar_g_vehicle_racer_rocket_force, 3,
 238                            DEATH_WAKIROCKET, PROJECTILE_WAKIROCKET, 20);
 239
 240     rocket.lip              = autocvar_g_vehicle_racer_rocket_accel * sys_frametime;
 241     rocket.wait             = autocvar_g_vehicle_racer_rocket_turnrate;
 242     rocket.nextthink        = time;
 243     rocket.enemy            = trg;
 244     rocket.cnt              = time + 15;
 245
 246     if(trg)
 247         rocket.think            = racer_rocket_tracker;
 248     else
 249         rocket.think            = racer_rocket_groundhugger;
 250 }
 251
 252 float racer_frame()
 253 {
 254     entity player, racer;
 255     vector df;
 256     float ftmp;
 257
 258     player          = self;
 259     racer           = self.vehicle;
 260
 261     player.BUTTON_ZOOM = player.BUTTON_CROUCH = 0;
 262
 263     self = racer;
 264
 265     if(player.BUTTON_USE)
 266     {
 267         vehicles_exit(VHEF_NORMAL);
 268         self = player;
 269         return 0;
 270     }
 271
 272     if(racer.deadflag != DEAD_NO)
 273     {
 274         self = player;
 275         player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 276         return 1;
 277     }
 278
 279     racer_align4point();
 280
 281     crosshair_trace(player);
 282
 283 #if VEHICLES_VIEWROTATE_CROSSHAIR
 284     float ftmp2;
 285     racer.angles_x *= -1;
 286     df = vectoangles(normalize(trace_endpos - self.origin + '0 0 32'));
 287     if(df_x > 180)  df_x -= 360;
 288     if(df_x < -180) df_x += 360;
 289     if(df_y > 180)  df_y -= 360;
 290     if(df_y < -180) df_y += 360;
 291
 292     // Yaw
 293     ftmp = autocvar_g_vehicle_racer_turnspeed * frametime;
 294     ftmp2 = ftmp * -1;
 295
 296     ftmp = bound(ftmp2, shortangle_f(df_y - racer.angles_y, racer.angles_y), ftmp);
 297     ftmp2 = anglemods(racer.angles_y + ftmp);
 298
 299     // Roll
 300     ftmp = bound(-45, shortangle_f(df_z + ((racer.angles_y - ftmp2) * autocvar_g_vehicle_racer_turnroll), racer.angles_z), 45);
 301     ftmp = anglemods(racer.angles_z + ftmp) * frametime;
 302     racer.angles_z = bound(-65, racer.angles_z + ftmp, 65);
 303
 304     // Turn
 305     racer.angles_y = ftmp2;
 306
 307     // Pitch
 308     ftmp = autocvar_g_vehicle_racer_pitchspeed * frametime;
 309     ftmp2 = ftmp * -1;
 310
 311     ftmp = bound(ftmp2, shortangle_f(player.v_angle_x - racer.angles_x, racer.angles_x), ftmp);
 312     racer.angles_x = anglemods(racer.angles_x + ftmp);
 313
 314     makevectors(racer.angles);
 315     racer.angles_x *= -1;
 316 #else
 317     racer.angles_x *= -1;
 318
 319     // Yaw
 320     ftmp = autocvar_g_vehicle_racer_turnspeed * frametime;
 321     ftmp = bound(-ftmp, shortangle_f(player.v_angle_y - racer.angles_y, racer.angles_y), ftmp);
 322     racer.angles_y = anglemods(racer.angles_y + ftmp);
 323
 324     // Roll
 325     racer.angles_z += -ftmp * autocvar_g_vehicle_racer_turnroll * frametime;
 326
 327     // Pitch
 328     ftmp = autocvar_g_vehicle_racer_pitchspeed  * frametime;
 329     ftmp = bound(-ftmp, shortangle_f(player.v_angle_x - racer.angles_x, racer.angles_x), ftmp);
 330     racer.angles_x = bound(-30, anglemods(racer.angles_x + ftmp), 30);
 331
 332     makevectors(racer.angles);
 333     racer.angles_x *= -1;
 334 #endif
 335
 336     df = racer.velocity * -0.5;
 337
 338     if(player.movement_x != 0)
 339     {
 340         if(player.movement_x > 0)
 341             df += v_forward  * autocvar_g_vehicle_racer_speed_forward;
 342         else if(player.movement_x < 0)
 343             df -= v_forward  * autocvar_g_vehicle_racer_speed_forward;
 344     }
 345
 346     if(player.movement_y != 0)
 347     {
 348         if(player.movement_y < 0)
 349             df -= v_right * autocvar_g_vehicle_racer_speed_strafe;
 350         else if(player.movement_y > 0)
 351             df += v_right * autocvar_g_vehicle_racer_speed_strafe;
 352     }
 353
 354     // Afterburn
 355     if (player.BUTTON_JUMP)
 356     if(racer.vehicle_energy >= (autocvar_g_vehicle_racer_afterburn_cost * frametime))
 357     {
 358         racer.wait = time;
 359         racer.vehicle_energy -= autocvar_g_vehicle_racer_afterburn_cost * frametime;
 360         df += (v_forward * autocvar_g_vehicle_racer_speed_afterburn);
 361         self.owner.vehicle_energy = racer.vehicle_energy / autocvar_g_vehicle_racer_energy;
 362     }
 363
 364     racer.velocity  += df * frametime;
 365
 366     df = (vlen(racer.velocity) * autocvar_g_vehicle_racer_downforce * v_up) * frametime;
 367     racer.velocity  = racer.velocity - df;
 368     player.movement = racer.velocity;
 369
 370     if(player.BUTTON_ATCK)
 371     if(time > racer.attack_finished_single)
 372     if(racer.vehicle_energy >= autocvar_g_vehicle_racer_cannon_cost)
 373     {
 374         racer.vehicle_energy -= autocvar_g_vehicle_racer_cannon_cost;
 375         racer.wait = time;
 376
 377         crosshair_trace(player);
 378         if(racer.cnt)
 379         {
 380             racer_fire_cannon("tag_fire1");
 381             racer.cnt = 0;
 382         }
 383         else
 384         {
 385             racer_fire_cannon("tag_fire2");
 386             racer.cnt = 1;
 387         }
 388         racer.attack_finished_single = time + autocvar_g_vehicle_racer_cannon_refire;
 389         self.owner.vehicle_energy = racer.vehicle_energy / autocvar_g_vehicle_racer_energy;
 390     }
 391
 392     if(autocvar_g_vehicle_racer_rocket_locktarget)
 393     {
 394         vehicles_locktarget((1 / autocvar_g_vehicle_racer_rocket_locking_time) * frametime,
 395                          (1 / autocvar_g_vehicle_racer_rocket_locking_releasetime) * frametime,
 396                          autocvar_g_vehicle_racer_rocket_locked_time);
 397
 398         if(self.lock_target)
 399         {
 400             if(racer.lock_strength == 1)
 401                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '1 0 0', 0);
 402             else if(self.lock_strength > 0.5)
 403                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '0 1 0', 0);
 404             else if(self.lock_strength < 0.5)
 405                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '0 0 1', 0);
 406         }
 407     }
 408
 409     if(time > racer.delay)
 410     if(player.BUTTON_ATCK2)
 411     {
 412         self.misc_bulletcounter += 1;
 413         racer.delay = time + 0.2;
 414         if(self.misc_bulletcounter == 1)
 415             racer_fire_rocket("tag_rocket_r", (self.lock_strength == 1 && self.lock_target) ? self.lock_target : world);
 416         else if(self.misc_bulletcounter == 2)
 417         {
 418             racer_fire_rocket("tag_rocket_l", (self.lock_strength == 1 && self.lock_target) ? self.lock_target : world);
 419             self.lock_strength  = 0;
 420             self.lock_target    = world;
 421             self.misc_bulletcounter = 0;
 422
 423             racer.delay = time + autocvar_g_vehicle_racer_rocket_refire;
 424             racer.lip = time;
 425         }
 426     }
 427     player.vehicle_reload1 = (time - racer.lip) / (racer.delay - racer.lip);
 428
 429     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 430         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_racer_shield, autocvar_g_vehicle_racer_shield_regen_pause, autocvar_g_vehicle_racer_shield_regen, frametime);
 431
 432     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 433         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_racer_health, autocvar_g_vehicle_racer_health_regen_pause, autocvar_g_vehicle_racer_health_regen, frametime);
 434
 435     if(self.vehicle_flags  & VHF_ENERGYREGEN)
 436         vehicles_regen(wait, vehicle_energy, autocvar_g_vehicle_racer_energy, autocvar_g_vehicle_racer_energy_regen_pause, autocvar_g_vehicle_racer_energy_regen, frametime);
 437
 438
 439     VEHICLE_UPDATE_PLAYER(health, racer);
 440
 441     if(self.vehicle_flags & VHF_HASSHIELD)
 442         VEHICLE_UPDATE_PLAYER(shield, racer);
 443
 444
 445     player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 446     setorigin(player,racer.origin + '0 0 32');
 447     player.velocity = racer.velocity;
 448
 449     self = player;
 450     return 1;
 451 }
 452
 453 void racer_think()
 454 {
 455     /*
 456     float a, b, c;a = autocvar_g_vehicle_racer_anglestabilizer;
 457     b = autocvar_g_vehicle_racer_springlength;
 458     c = autocvar_g_vehicle_racer_hoverpower;
 459
 460     autocvar_g_vehicle_racer_anglestabilizer = 36;
 461     autocvar_g_vehicle_racer_springlength = 96;
 462     autocvar_g_vehicle_racer_hoverpower = 300;
 463     */
 464
 465     racer_align4point(); //time - self.nextthink);
 466
 467     /*
 468     //if(self.velocity_z > 0)
 469     //    self.velocity_z *= 0.95;
 470
 471     autocvar_g_vehicle_racer_anglestabilizer = a;
 472     autocvar_g_vehicle_racer_springlength = b;
 473     autocvar_g_vehicle_racer_hoverpower = c;
 474     */
 475
 476     self.velocity_x *= 0.9;
 477     self.velocity_y *= 0.9;
 478     self.velocity_z *= 0.8;
 479     self.velocity_z += sin(time * 2) * 16;
 480     self.nextthink = time + 0.05;
 481 }
 482
 483 void racer_enter()
 484 {
 485     self.movetype = MOVETYPE_BOUNCE; //MISSILE;
 486     self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_racer_health);
 487     self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_racer_shield);
 488 }
 489
 490 void racer_exit(float eject)
 491 {
 492     self.think      = racer_think;
 493     self.nextthink  = time;
 494     self.movetype   = MOVETYPE_TOSS;
 495
 496     if not (self.owner)
 497         return;
 498
 499         makevectors(self.angles);
 500         if(eject)
 501         {
 502             setorigin(self.owner, self.origin + v_forward * 100 + v_up * 32);
 503             self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 504         }
 505         else
 506         {
 507             setorigin(self.owner, self.origin - v_forward * 100 + v_up * 32);
 508             self.owner.velocity = v_forward * -150;
 509         }
 510     self.owner = world;
 511 }
 512
 513 void racer_spawn()
 514 {
 515     self.think          = racer_think;
 516     self.nextthink      = time;
 517     self.vehicle_health = autocvar_g_vehicle_racer_health;
 518     self.vehicle_shield = autocvar_g_vehicle_racer_shield;
 519
 520     self.movetype       = MOVETYPE_TOSS;
 521     self.solid          = SOLID_SLIDEBOX;
 522     self.delay          = time;
 523     self.scale          = 0.5;
 524
 525     setsize(self, RACER_MIN * 0.5, RACER_MAX * 0.5);
 526 }
 527
 528
 529 void racer_blowup()
 530 {
 531     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 532     pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 533
 534     self.deadflag    = DEAD_DEAD;
 535     self.vehicle_exit(VHEF_NORMAL);
 536
 537     RadiusDamage (self, self, autocvar_g_vehicle_racer_blowup_coredamage,
 538                                         autocvar_g_vehicle_racer_blowup_edgedamage,
 539                                         autocvar_g_vehicle_racer_blowup_radius, world,
 540                                         autocvar_g_vehicle_racer_blowup_forceintensity,
 541                                         DEATH_WAKIBLOWUP, world);
 542
 543     self.alpha = -1;
 544     self.nextthink  = time + autocvar_g_vehicle_racer_respawntime;
 545     self.think      = racer_spawn;
 546     self.movetype   = MOVETYPE_NONE;
 547     self.effects    = EF_NODRAW;
 548
 549     self.colormod  = '0 0 0';
 550     self.avelocity = '0 0 0';
 551     self.velocity  = '0 0 0';
 552
 553     setorigin(self, self.pos1);
 554         self.think     = racer_spawn;
 555         self.nextthink = time + autocvar_g_vehicle_racer_respawntime;
 556 }
 557
 558 void racer_deadtouch()
 559 {
 560     self.avelocity_x *= 0.7;
 561     self.cnt -= 1;
 562     if(self.cnt <= 0)
 563         racer_blowup();
 564 }
 565
 566 void racer_die()
 567 {
 568     self.health       = 0;
 569     self.event_damage = SUB_Null;
 570     self.iscreature   = FALSE;
 571     self.solid        = SOLID_CORPSE;
 572     self.takedamage   = DAMAGE_NO;
 573     self.deadflag     = DEAD_DYING;
 574     self.movetype     = MOVETYPE_BOUNCE;
 575     self.wait         = time;
 576     self.cnt          = 1 + random() * 3;
 577     self.touch        = racer_deadtouch;
 578
 579     pointparticles(particleeffectnum("rocket_explode"), findbetterlocation (self.origin, 16), '0 0 0', 1);
 580
 581     if(random() < 0.5)
 582         self.avelocity_z  = 16;
 583     else
 584         self.avelocity_z  = -16;
 585
 586     self.avelocity_x = -vlen(self.velocity) * 0.2;
 587     self.velocity   += '0 0 700';
 588     self.colormod    = '-0.5 -0.5 -0.5';
 589
 590         self.think     = racer_blowup;
 591         self.nextthink = 2 + time + random() * 3;
 592 }
 593
 594 void racer_dinit()
 595 {
 596     if not (vehicle_initialize(
 597              "Wakizashi",
 598              "models/vehicles/wakizashi.dpm",
 599              "",
 600              "models/vehicles/wakizashi_cockpit.dpm",
 601              "", "", "tag_viewport",
 602              HUD_WAKIZASHI,
 603              0.5 * RACER_MIN, 0.5 * RACER_MAX,
 604              FALSE,
 605              racer_spawn, autocvar_g_vehicle_racer_respawntime,
 606              racer_frame,
 607              racer_enter, racer_exit,
 608              racer_die,   racer_think))
 609     {
 610         remove(self);
 611         return;
 612     }
 613
 614     if(autocvar_g_vehicle_racer_hovertype != 0)
 615         racer_force_from_tag = vehicles_force_fromtag_maglev;
 616     else
 617         racer_force_from_tag = vehicles_force_fromtag_hover;
 618
 619     // FIXME: this be hakkz, fix the models insted (scale body, add tag_viewport to the hudmodel).
 620     self.scale = 0.5;
 621     //setattachment(self.vehicle_hudmodel, self, "");
 622     //setattachment(self.vehicle_viewport, self, "tag_viewport");
 623
 624     self.mass               = 900;
 625 }
 626
 627 void spawnfunc_vehicle_racer()
 628 {
 629
 630     precache_sound ("weapons/laserimpact.wav");
 631     precache_sound ("weapons/lasergun_fire.wav");
 632     precache_sound ("weapons/rocket_fire.wav");
 633     precache_sound ("weapons/rocket_impact.wav");
 634
 635     precache_model ("models/vhshield.md3");
 636     precache_model ("models/vehicles/wakizashi.dpm");
 637     precache_model ("models/vehicles/wakizashi_cockpit.dpm");
 638
 639     vehicles_configcheck("vehicle_racer.cfg", autocvar_g_vehicle_racer_health);
 640     if(autocvar_g_vehicle_racer_energy)
 641         if(autocvar_g_vehicle_racer_energy_regen)
 642             self.vehicle_flags |= VHF_ENERGYREGEN;
 643
 644     if(autocvar_g_vehicle_racer_shield)
 645         self.vehicle_flags |= VHF_HASSHIELD;
 646
 647     if(autocvar_g_vehicle_racer_shield_regen)
 648         self.vehicle_flags |= VHF_SHIELDREGEN;
 649
 650     if(autocvar_g_vehicle_racer_health_regen)
 651         self.vehicle_flags |= VHF_HEALTHREGEN;
 652
 653     self.think = racer_dinit;
 654     self.nextthink = time + 1;
 655 }