qcsrc/server/vehicles/racer.qc

   1 #define RACER_MIN '-120 -120 -40'
   2 #define RACER_MAX '120 120 40'
   3 #define RACER_ENGINE "sound/vehicles/racer.wav"
   4
   5 #ifdef SVQC
   6 void racer_exit(float eject);
   7 void racer_enter();
   8
   9 // Auto cvars
  10 float autocvar_g_vehicle_racer_speed_afterburn;
  11 float autocvar_g_vehicle_racer_afterburn_cost;
  12
  13 float autocvar_g_vehicle_racer_anglestabilizer;
  14 float autocvar_g_vehicle_racer_downforce;
  15
  16 float autocvar_g_vehicle_racer_speed_forward;
  17 float autocvar_g_vehicle_racer_speed_strafe;
  18 float autocvar_g_vehicle_racer_springlength;
  19 float autocvar_g_vehicle_racer_upforcedamper;
  20 float autocvar_g_vehicle_racer_friction;
  21
  22 float autocvar_g_vehicle_racer_hovertype;
  23 float autocvar_g_vehicle_racer_hoverpower;
  24
  25 float autocvar_g_vehicle_racer_turnroll;
  26 float autocvar_g_vehicle_racer_turnspeed;
  27 float autocvar_g_vehicle_racer_pitchspeed;
  28
  29 float autocvar_g_vehicle_racer_energy;
  30 float autocvar_g_vehicle_racer_energy_regen;
  31 float autocvar_g_vehicle_racer_energy_regen_pause;
  32
  33 float autocvar_g_vehicle_racer_health;
  34 float autocvar_g_vehicle_racer_health_regen;
  35 float autocvar_g_vehicle_racer_health_regen_pause;
  36
  37 float autocvar_g_vehicle_racer_shield;
  38 float autocvar_g_vehicle_racer_shield_regen;
  39 float autocvar_g_vehicle_racer_shield_regen_pause;
  40
  41 float autocvar_g_vehicle_racer_cannon_cost;
  42 float autocvar_g_vehicle_racer_cannon_damage;
  43 float autocvar_g_vehicle_racer_cannon_radius;
  44 float autocvar_g_vehicle_racer_cannon_refire;
  45 float autocvar_g_vehicle_racer_cannon_speed;
  46 float autocvar_g_vehicle_racer_cannon_spread;
  47 float autocvar_g_vehicle_racer_cannon_force;
  48
  49 float autocvar_g_vehicle_racer_rocket_accel;
  50 float autocvar_g_vehicle_racer_rocket_damage;
  51 float autocvar_g_vehicle_racer_rocket_radius;
  52 float autocvar_g_vehicle_racer_rocket_force;
  53 float autocvar_g_vehicle_racer_rocket_refire;
  54 float autocvar_g_vehicle_racer_rocket_speed;
  55 float autocvar_g_vehicle_racer_rocket_turnrate;
  56
  57 float autocvar_g_vehicle_racer_rocket_locktarget;
  58 float autocvar_g_vehicle_racer_rocket_locking_time;
  59 float autocvar_g_vehicle_racer_rocket_locking_releasetime;
  60 float autocvar_g_vehicle_racer_rocket_locked_time;
  61 float autocvar_g_vehicle_racer_rocket_locked_maxangle;
  62
  63 float autocvar_g_vehicle_racer_respawntime;
  64
  65 float autocvar_g_vehicle_racer_blowup_radius;
  66 float autocvar_g_vehicle_racer_blowup_coredamage;
  67 float autocvar_g_vehicle_racer_blowup_edgedamage;
  68 float autocvar_g_vehicle_racer_blowup_forceintensity;
  69
  70 var vector racer_force_from_tag(string tag_name, float spring_length, float max_power);
  71
  72 void racer_align4point()
  73 {
  74     vector push_vector, v_add;
  75     float fl_push, fr_push, bl_push, br_push;
  76
  77
  78     push_vector  = racer_force_from_tag("tag_engine_fr", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  79     fr_push      = force_fromtag_normpower;
  80     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  81
  82     push_vector += racer_force_from_tag("tag_engine_fl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  83     fl_push      = force_fromtag_normpower;
  84     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  85
  86     push_vector += racer_force_from_tag("tag_engine_br", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  87     br_push      = force_fromtag_normpower;
  88     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  89
  90     push_vector += racer_force_from_tag("tag_engine_bl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  91     bl_push      = force_fromtag_normpower;
  92     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  93
  94     self.velocity += (push_vector * frametime);
  95
  96     // Anti ocilation
  97     if(self.velocity_z  > 0)
  98         self.velocity_z *= 1 - (autocvar_g_vehicle_racer_upforcedamper * frametime);
  99
 100     self.velocity   += v_add;
 101     //self.velocity_z -= autocvar_sv_gravity * frametime;
 102
 103     push_vector_x =  (fl_push - bl_push);
 104     push_vector_x += (fr_push - br_push);
 105     push_vector_x *= 360;
 106
 107     push_vector_z = (fr_push - fl_push);
 108     push_vector_z += (br_push - bl_push);
 109     push_vector_z *= 360;
 110
 111     // Apply angle diffrance
 112     self.angles_z += push_vector_z * frametime;
 113     self.angles_x += push_vector_x * frametime;
 114
 115     // Apply stabilizer
 116     self.angles_x *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * frametime);
 117     self.angles_z *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * frametime);
 118 }
 119
 120 void racer_fire_cannon(string tagname)
 121 {
 122     vector v;
 123     entity bolt;
 124
 125     v = gettaginfo(self, gettagindex(self, tagname));
 126     bolt = vehicles_projectile("wakizashi_gun_muzzleflash", "weapons/lasergun_fire.wav",
 127                            v, normalize(v_forward + randomvec() * autocvar_g_vehicle_racer_cannon_spread) * autocvar_g_vehicle_racer_cannon_speed,
 128                            autocvar_g_vehicle_racer_cannon_damage, autocvar_g_vehicle_racer_cannon_radius, autocvar_g_vehicle_racer_cannon_force,  0,
 129                            DEATH_WAKIGUN, PROJECTILE_WAKICANNON, 0, TRUE, TRUE);
 130
 131         // Fix z-aim (for chase mode)
 132     v = normalize(trace_endpos - bolt.origin);
 133     v_forward_z = v_z * 0.5;
 134     bolt.velocity = v_forward * autocvar_g_vehicle_racer_cannon_speed;
 135 }
 136
 137 void racer_rocket_groundhugger()
 138 {
 139     vector olddir, newdir;
 140     float oldvel, newvel;
 141
 142     self.nextthink  = time;
 143
 144     if(self.owner.deadflag != DEAD_NO || self.cnt < time)
 145     {
 146         self.use();
 147         return;
 148     }
 149
 150     if not (self.realowner.vehicle)
 151     {
 152         UpdateCSQCProjectile(self);
 153         return;
 154     }
 155
 156     olddir = normalize(self.velocity);
 157     oldvel = vlen(self.velocity);
 158     newvel = oldvel + self.lip;
 159
 160     tracebox(self.origin, self.mins, self.maxs, self.origin + olddir * 64, MOVE_WORLDONLY,self);
 161     if(trace_fraction <= 0.5)
 162     {
 163         // Hitting somethign soon, just speed ahead
 164         self.velocity = olddir * newvel;
 165         UpdateCSQCProjectile(self);
 166         return;
 167     }
 168
 169     traceline(trace_endpos, trace_endpos - '0 0 64', MOVE_NORMAL, self);
 170     if(trace_fraction != 1.0)
 171     {
 172         newdir = normalize(trace_endpos + '0 0 64' - self.origin) * autocvar_g_vehicle_racer_rocket_turnrate;
 173         self.velocity = normalize(olddir + newdir) * newvel;
 174     }
 175     else
 176     {
 177         self.velocity = olddir * newvel;
 178         self.velocity_z -= 1600 * sys_frametime; // 2x grav looks better for this one
 179     }
 180
 181     UpdateCSQCProjectile(self);
 182     return;
 183 }
 184
 185 void racer_rocket_tracker()
 186 {
 187     vector olddir, newdir;
 188     float oldvel, newvel;
 189
 190     self.nextthink  = time;
 191
 192     if (self.owner.deadflag != DEAD_NO || self.cnt < time)
 193     {
 194         self.use();
 195         return;
 196     }
 197
 198     if not (self.realowner.vehicle)
 199     {
 200         UpdateCSQCProjectile(self);
 201         return;
 202     }
 203
 204     olddir = normalize(self.velocity);
 205     oldvel = vlen(self.velocity);
 206     newvel = oldvel + self.lip;
 207     makevectors(vectoangles(olddir));
 208
 209     traceline(self.origin, self.origin + v_forward * 64 - '0 0 32', MOVE_NORMAL, self);
 210     newdir = normalize(self.enemy.origin - self.origin);
 211
 212     if(vlen(newdir - v_forward) > autocvar_g_vehicle_racer_rocket_locked_maxangle)
 213     {
 214         //bprint("Target lost!\n");
 215         //dprint("OF:", ftos(vlen(newdir - v_forward)), "\n");
 216         self.think = racer_rocket_groundhugger;
 217         return;
 218     }
 219
 220     if(trace_fraction != 1.0)
 221         newdir_z += 16 * sys_frametime;
 222
 223     self.velocity = normalize(olddir + newdir * autocvar_g_vehicle_racer_rocket_turnrate) * newvel;
 224     self.velocity_z -= 800 * sys_frametime;
 225
 226     UpdateCSQCProjectile(self);
 227     return;
 228 }
 229
 230 void racer_fire_rocket(string tagname, entity trg)
 231 {
 232     vector v;
 233     entity rocket;
 234
 235     v = gettaginfo(self, gettagindex(self, tagname));
 236     rocket = vehicles_projectile("wakizashi_rocket_launch", "weapons/rocket_fire.wav",
 237                            v, v_forward * autocvar_g_vehicle_racer_rocket_speed,
 238                            autocvar_g_vehicle_racer_rocket_damage, autocvar_g_vehicle_racer_rocket_radius, autocvar_g_vehicle_racer_rocket_force, 3,
 239                            DEATH_WAKIROCKET, PROJECTILE_WAKIROCKET, 20, FALSE, FALSE);
 240
 241     rocket.lip              = autocvar_g_vehicle_racer_rocket_accel * sys_frametime;
 242     rocket.wait             = autocvar_g_vehicle_racer_rocket_turnrate;
 243     rocket.nextthink        = time;
 244     rocket.enemy            = trg;
 245     rocket.cnt              = time + 15;
 246
 247     if(trg)
 248         rocket.think            = racer_rocket_tracker;
 249     else
 250         rocket.think            = racer_rocket_groundhugger;
 251 }
 252
 253 float racer_frame()
 254 {
 255     entity player, racer;
 256     vector df;
 257     float ftmp;
 258
 259     player          = self;
 260     racer           = self.vehicle;
 261
 262     player.BUTTON_ZOOM = player.BUTTON_CROUCH = 0;
 263
 264     self = racer;
 265
 266     /*
 267     if(player.BUTTON_USE)
 268     {
 269         vehicles_exit(VHEF_NORMAL);
 270         self = player;
 271         return 0;
 272     }
 273     */
 274
 275     if(racer.deadflag != DEAD_NO)
 276     {
 277         self = player;
 278         player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 279         return 1;
 280     }
 281
 282     racer_align4point();
 283
 284     crosshair_trace(player);
 285
 286     racer.angles_x *= -1;
 287
 288     // Yaw
 289     ftmp = autocvar_g_vehicle_racer_turnspeed * frametime;
 290     ftmp = bound(-ftmp, shortangle_f(player.v_angle_y - racer.angles_y, racer.angles_y), ftmp);
 291     racer.angles_y = anglemods(racer.angles_y + ftmp);
 292
 293     // Roll
 294     racer.angles_z += -ftmp * autocvar_g_vehicle_racer_turnroll * frametime;
 295
 296     // Pitch
 297     ftmp = autocvar_g_vehicle_racer_pitchspeed  * frametime;
 298     ftmp = bound(-ftmp, shortangle_f(player.v_angle_x - racer.angles_x, racer.angles_x), ftmp);
 299     racer.angles_x = bound(-30, anglemods(racer.angles_x + ftmp), 30);
 300
 301     makevectors(racer.angles);
 302     racer.angles_x *= -1;
 303
 304
 305     ftmp = racer.velocity_z;
 306     df = racer.velocity * -autocvar_g_vehicle_racer_friction;
 307     racer.velocity_z = ftmp;
 308
 309     if(player.movement_x != 0)
 310     {
 311         if(player.movement_x > 0)
 312             df += v_forward  * autocvar_g_vehicle_racer_speed_forward;
 313         else if(player.movement_x < 0)
 314             df -= v_forward  * autocvar_g_vehicle_racer_speed_forward;
 315     }
 316
 317     if(player.movement_y != 0)
 318     {
 319         if(player.movement_y < 0)
 320             df -= v_right * autocvar_g_vehicle_racer_speed_strafe;
 321         else if(player.movement_y > 0)
 322             df += v_right * autocvar_g_vehicle_racer_speed_strafe;
 323     }
 324
 325     if(vlen(player.movement) != 0)
 326     {
 327         if(self.sound_nexttime < time || self.sounds != 1)
 328         {
 329             self.sounds = 1;
 330             self.sound_nexttime = time + 10.922667; //soundlength("vehicles/racer_move.wav");
 331             sound (self, CHAN_TRIGGER, "vehicles/racer_move.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 332         }
 333     }
 334     else
 335     {
 336         if(self.sound_nexttime < time || self.sounds != 0)
 337         {
 338             self.sounds = 0;
 339             self.sound_nexttime = time + 11.888604; //soundlength("vehicles/racer_idle.wav");
 340             sound (self, CHAN_TRIGGER, "vehicles/racer_idle.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 341         }
 342     }
 343
 344     // Afterburn
 345     if (player.BUTTON_JUMP && racer.vehicle_energy >= (autocvar_g_vehicle_racer_afterburn_cost * frametime))
 346     {
 347         racer.wait = time;
 348         racer.vehicle_energy -= autocvar_g_vehicle_racer_afterburn_cost * frametime;
 349         df += (v_forward * autocvar_g_vehicle_racer_speed_afterburn);
 350
 351         if(self.strength_finished < time)
 352         {
 353             //self.sounds = 2;
 354             self.strength_finished = time + 10.922667; //soundlength("vehicles/racer_boost.wav");
 355             sound (self, CHAN_PAIN, "vehicles/racer_boost.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 356         }
 357     }
 358     else
 359     {
 360         self.strength_finished = 0;
 361         sound (self, CHAN_PAIN, "misc/null.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 362     }
 363
 364
 365     racer.velocity  += df * frametime;
 366
 367     df = (vlen(racer.velocity) * autocvar_g_vehicle_racer_downforce * v_up) * frametime;
 368     racer.velocity  = racer.velocity - df;
 369     player.movement = racer.velocity;
 370
 371     if(player.BUTTON_ATCK)
 372     if(time > racer.attack_finished_single)
 373     if(racer.vehicle_energy >= autocvar_g_vehicle_racer_cannon_cost)
 374     {
 375         racer.vehicle_energy -= autocvar_g_vehicle_racer_cannon_cost;
 376         racer.wait = time;
 377
 378         crosshair_trace(player);
 379         if(racer.cnt)
 380         {
 381             racer_fire_cannon("tag_fire1");
 382             racer.cnt = 0;
 383         }
 384         else
 385         {
 386             racer_fire_cannon("tag_fire2");
 387             racer.cnt = 1;
 388         }
 389         racer.attack_finished_single = time + autocvar_g_vehicle_racer_cannon_refire;
 390         //self.owner.vehicle_energy = racer.vehicle_energy / autocvar_g_vehicle_racer_energy;
 391     }
 392
 393     if(autocvar_g_vehicle_racer_rocket_locktarget)
 394     {
 395         vehicles_locktarget((1 / autocvar_g_vehicle_racer_rocket_locking_time) * frametime,
 396                          (1 / autocvar_g_vehicle_racer_rocket_locking_releasetime) * frametime,
 397                          autocvar_g_vehicle_racer_rocket_locked_time);
 398
 399         if(self.lock_target)
 400         {
 401             if(racer.lock_strength == 1)
 402                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '1 0 0', 0);
 403             else if(self.lock_strength > 0.5)
 404                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '0 1 0', 0);
 405             else if(self.lock_strength < 0.5)
 406                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '0 0 1', 0);
 407         }
 408     }
 409
 410     if(time > racer.delay)
 411     if(player.BUTTON_ATCK2)
 412     {
 413         self.misc_bulletcounter += 1;
 414         racer.delay = time + 0.3;
 415         if(self.misc_bulletcounter == 1)
 416             racer_fire_rocket("tag_rocket_r", (self.lock_strength == 1 && self.lock_target) ? self.lock_target : world);
 417         else if(self.misc_bulletcounter == 2)
 418         {
 419             racer_fire_rocket("tag_rocket_l", (self.lock_strength == 1 && self.lock_target) ? self.lock_target : world);
 420             self.lock_strength  = 0;
 421             self.lock_target    = world;
 422             self.misc_bulletcounter = 0;
 423
 424             racer.delay = time + autocvar_g_vehicle_racer_rocket_refire;
 425             racer.lip = time;
 426         }
 427     }
 428     player.vehicle_reload1 = bound(0, 100 * ((time - racer.lip) / (racer.delay - racer.lip)), 100);
 429
 430     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 431         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_racer_shield, autocvar_g_vehicle_racer_shield_regen_pause, autocvar_g_vehicle_racer_shield_regen, frametime);
 432
 433     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 434         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_racer_health, autocvar_g_vehicle_racer_health_regen_pause, autocvar_g_vehicle_racer_health_regen, frametime);
 435
 436     if(self.vehicle_flags  & VHF_ENERGYREGEN)
 437         vehicles_regen(wait, vehicle_energy, autocvar_g_vehicle_racer_energy, autocvar_g_vehicle_racer_energy_regen_pause, autocvar_g_vehicle_racer_energy_regen, frametime);
 438
 439
 440     VEHICLE_UPDATE_PLAYER(health, racer);
 441     VEHICLE_UPDATE_PLAYER(energy, racer);
 442
 443     if(self.vehicle_flags & VHF_HASSHIELD)
 444         VEHICLE_UPDATE_PLAYER(shield, racer);
 445
 446
 447     player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 448     setorigin(player,racer.origin + '0 0 32');
 449     player.velocity = racer.velocity;
 450
 451     self = player;
 452     return 1;
 453 }
 454
 455 void racer_think()
 456 {
 457     /*
 458     float a, b, c;a = autocvar_g_vehicle_racer_anglestabilizer;
 459     b = autocvar_g_vehicle_racer_springlength;
 460     c = autocvar_g_vehicle_racer_hoverpower;
 461
 462     autocvar_g_vehicle_racer_anglestabilizer = 36;
 463     autocvar_g_vehicle_racer_springlength = 96;
 464     autocvar_g_vehicle_racer_hoverpower = 300;
 465     */
 466
 467     racer_align4point(); //time - self.nextthink);
 468
 469     /*
 470     //if(self.velocity_z > 0)
 471     //    self.velocity_z *= 0.95;
 472
 473     autocvar_g_vehicle_racer_anglestabilizer = a;
 474     autocvar_g_vehicle_racer_springlength = b;
 475     autocvar_g_vehicle_racer_hoverpower = c;
 476     */
 477
 478     self.velocity_x *= 0.9;
 479     self.velocity_y *= 0.9;
 480     self.velocity_z *= 0.8;
 481     self.velocity_z += sin(time * 2) * 16;
 482     self.nextthink = time; // + 0.05;
 483 }
 484
 485 void racer_enter()
 486 {
 487     self.movetype = MOVETYPE_BOUNCE;
 488     self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_racer_health);
 489     self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_racer_shield);
 490 }
 491
 492 void racer_exit(float eject)
 493 {
 494     vector spot;
 495
 496     self.think      = racer_think;
 497     self.nextthink  = time;
 498     self.movetype   = MOVETYPE_TOSS;
 499
 500     if not (self.owner)
 501         return;
 502
 503         makevectors(self.angles);
 504         if(eject)
 505         {
 506             spot = self.origin + v_forward * 100 + '0 0 64';
 507             spot = vehicles_findgoodexit(spot);
 508             setorigin(self.owner , spot);
 509             self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 510         }
 511         else
 512         {
 513             spot = self.origin - v_forward * 200 + '0 0 64';
 514             spot = vehicles_findgoodexit(spot);
 515             setorigin(self.owner , spot);
 516         }
 517
 518     self.owner = world;
 519 }
 520
 521 void racer_spawn()
 522 {
 523     self.think          = racer_think;
 524     self.nextthink      = time;
 525     self.vehicle_health = autocvar_g_vehicle_racer_health;
 526     self.vehicle_shield = autocvar_g_vehicle_racer_shield;
 527
 528     self.movetype       = MOVETYPE_TOSS;
 529     self.solid          = SOLID_SLIDEBOX;
 530     self.delay          = time;
 531     self.scale          = 0.5;
 532
 533     setsize(self, RACER_MIN * 0.5, RACER_MAX * 0.5);
 534 }
 535
 536
 537 void racer_blowup()
 538 {
 539     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 540     pointparticles(particleeffectnum("explosion_big"), self.origin, '0 0 0', 1);
 541
 542     self.deadflag    = DEAD_DEAD;
 543     self.vehicle_exit(VHEF_NORMAL);
 544
 545     RadiusDamage (self, self, autocvar_g_vehicle_racer_blowup_coredamage,
 546                                         autocvar_g_vehicle_racer_blowup_edgedamage,
 547                                         autocvar_g_vehicle_racer_blowup_radius, world,
 548                                         autocvar_g_vehicle_racer_blowup_forceintensity,
 549                                         DEATH_WAKIBLOWUP, world);
 550
 551     self.alpha = -1;
 552     self.nextthink  = time + autocvar_g_vehicle_racer_respawntime;
 553     self.think      = racer_spawn;
 554     self.movetype   = MOVETYPE_NONE;
 555     self.effects    = EF_NODRAW;
 556
 557     self.colormod  = '0 0 0';
 558     self.avelocity = '0 0 0';
 559     self.velocity  = '0 0 0';
 560
 561     setorigin(self, self.pos1);
 562         self.think     = racer_spawn;
 563         self.nextthink = time + autocvar_g_vehicle_racer_respawntime;
 564 }
 565
 566 void racer_deadtouch()
 567 {
 568     dprint("Boink!\n");
 569     self.avelocity_x *= 0.7;
 570     self.cnt -= 1;
 571     if(self.cnt <= 0)
 572         racer_blowup();
 573 }
 574
 575 void racer_die()
 576 {
 577     self.health       = 0;
 578     self.event_damage = SUB_Null;
 579     self.iscreature   = FALSE;
 580     self.solid        = SOLID_CORPSE;
 581     self.takedamage   = DAMAGE_NO;
 582     self.deadflag     = DEAD_DYING;
 583     self.movetype     = MOVETYPE_BOUNCE;
 584     self.wait         = time;
 585     self.cnt          = 1 + random() * 2;
 586     self.touch        = racer_deadtouch;
 587
 588     pointparticles(particleeffectnum("explosion_medium"), self.origin, '0 0 0', 1);
 589
 590     if(random() < 0.5)
 591         self.avelocity_z  = 32;
 592     else
 593         self.avelocity_z  = -32;
 594
 595     self.avelocity_x = -vlen(self.velocity) * 0.2;
 596     self.velocity   += '0 0 700';
 597     self.colormod    = '-0.5 -0.5 -0.5';
 598
 599         self.think     = racer_blowup;
 600         self.nextthink = 2 + time + random() * 3;
 601 }
 602
 603 void racer_dinit()
 604 {
 605     if not (vehicle_initialize(
 606              "Wakizashi",
 607              "models/vehicles/wakizashi.dpm",
 608              "",
 609              "models/vehicles/wakizashi_cockpit.dpm",
 610              "", "", "tag_viewport",
 611              HUD_WAKIZASHI,
 612              0.5 * RACER_MIN, 0.5 * RACER_MAX,
 613              FALSE,
 614              racer_spawn, autocvar_g_vehicle_racer_respawntime,
 615              racer_frame,
 616              racer_enter, racer_exit,
 617              racer_die,   racer_think,
 618              TRUE))
 619     {
 620         remove(self);
 621         return;
 622     }
 623
 624     if(autocvar_g_vehicle_racer_hovertype != 0)
 625         racer_force_from_tag = vehicles_force_fromtag_maglev;
 626     else
 627         racer_force_from_tag = vehicles_force_fromtag_hover;
 628
 629     // FIXME: this be hakkz, fix the models insted (scale body, add tag_viewport to the hudmodel).
 630     self.scale = 0.5;
 631     setattachment(self.vehicle_hudmodel, self, "");
 632     setattachment(self.vehicle_viewport, self, "tag_viewport");
 633
 634     self.mass               = 900;
 635 }
 636
 637 void spawnfunc_vehicle_racer()
 638 {
 639
 640     precache_sound ("weapons/laserimpact.wav");
 641     precache_sound ("weapons/lasergun_fire.wav");
 642     precache_sound ("weapons/rocket_fire.wav");
 643     precache_sound ("weapons/rocket_impact.wav");
 644
 645     precache_sound ("vehicles/racer_idle.wav");
 646     precache_sound ("vehicles/racer_move.wav");
 647     precache_sound ("vehicles/racer_boost.wav");
 648
 649     precache_model ("models/vhshield.md3");
 650     precache_model ("models/vehicles/wakizashi.dpm");
 651     precache_model ("models/vehicles/wakizashi_cockpit.dpm");
 652
 653     vehicles_configcheck("vehicle_racer.cfg", autocvar_g_vehicle_racer_health);
 654     if(autocvar_g_vehicle_racer_energy)
 655         if(autocvar_g_vehicle_racer_energy_regen)
 656             self.vehicle_flags |= VHF_ENERGYREGEN;
 657
 658     if(autocvar_g_vehicle_racer_shield)
 659         self.vehicle_flags |= VHF_HASSHIELD;
 660
 661     if(autocvar_g_vehicle_racer_shield_regen)
 662         self.vehicle_flags |= VHF_SHIELDREGEN;
 663
 664     if(autocvar_g_vehicle_racer_health_regen)
 665         self.vehicle_flags |= VHF_HEALTHREGEN;
 666
 667     self.think = racer_dinit;
 668     self.nextthink = time + (autocvar_g_vehicles_delayspawn ? autocvar_g_vehicle_racer_respawntime + (random() * autocvar_g_vehicles_delayspawn_jitter) : 0.5);
 669 }
 670 #endif // SVQC