qcsrc/server/vehicles/racer.qc

   1 #define RACER_MIN '-120 -120 -40'
   2 #define RACER_MAX '120 120 40'
   3 #define RACER_TICRATE 0.05
   4
   5 void racer_exit(float eject);
   6 void racer_enter();
   7
   8 // Auto cvars
   9 float autocvar_g_vehicle_racer_speed_afterburn;
  10 float autocvar_g_vehicle_racer_afterburn_cost;
  11
  12 float autocvar_g_vehicle_racer_anglestabilizer;
  13 float autocvar_g_vehicle_racer_downforce;
  14
  15 float autocvar_g_vehicle_racer_speed_forward;
  16 float autocvar_g_vehicle_racer_speed_strafe;
  17 float autocvar_g_vehicle_racer_springlength;
  18 float autocvar_g_vehicle_racer_upforcedamper;
  19 float autocvar_g_vehicle_racer_friction;
  20
  21 float autocvar_g_vehicle_racer_hovertype;
  22 float autocvar_g_vehicle_racer_hoverpower;
  23
  24 float autocvar_g_vehicle_racer_turnroll;
  25 float autocvar_g_vehicle_racer_turnspeed;
  26 float autocvar_g_vehicle_racer_pitchspeed;
  27
  28 float autocvar_g_vehicle_racer_energy;
  29 float autocvar_g_vehicle_racer_energy_regen;
  30 float autocvar_g_vehicle_racer_energy_regen_pause;
  31
  32 float autocvar_g_vehicle_racer_health;
  33 float autocvar_g_vehicle_racer_health_regen;
  34 float autocvar_g_vehicle_racer_health_regen_pause;
  35
  36 float autocvar_g_vehicle_racer_shield;
  37 float autocvar_g_vehicle_racer_shield_regen;
  38 float autocvar_g_vehicle_racer_shield_regen_pause;
  39
  40 float autocvar_g_vehicle_racer_cannon_cost;
  41 float autocvar_g_vehicle_racer_cannon_damage;
  42 float autocvar_g_vehicle_racer_cannon_radius;
  43 float autocvar_g_vehicle_racer_cannon_refire;
  44 float autocvar_g_vehicle_racer_cannon_speed;
  45 float autocvar_g_vehicle_racer_cannon_spread;
  46 float autocvar_g_vehicle_racer_cannon_force;
  47
  48 float autocvar_g_vehicle_racer_rocket_accel;
  49 float autocvar_g_vehicle_racer_rocket_damage;
  50 float autocvar_g_vehicle_racer_rocket_radius;
  51 float autocvar_g_vehicle_racer_rocket_force;
  52 float autocvar_g_vehicle_racer_rocket_refire;
  53 float autocvar_g_vehicle_racer_rocket_speed;
  54 float autocvar_g_vehicle_racer_rocket_turnrate;
  55
  56 float autocvar_g_vehicle_racer_rocket_locktarget;
  57 float autocvar_g_vehicle_racer_rocket_locking_time;
  58 float autocvar_g_vehicle_racer_rocket_locking_releasetime;
  59 float autocvar_g_vehicle_racer_rocket_locked_time;
  60 float autocvar_g_vehicle_racer_rocket_locked_maxangle;
  61
  62 float autocvar_g_vehicle_racer_respawntime;
  63 float autocvar_g_vehicle_racer_collision_multiplier;
  64
  65 float autocvar_g_vehicle_racer_blowup_radius;
  66 float autocvar_g_vehicle_racer_blowup_coredamage;
  67 float autocvar_g_vehicle_racer_blowup_edgedamage;
  68 float autocvar_g_vehicle_racer_blowup_forceintensity;
  69
  70 var vector racer_force_from_tag(string tag_name, float spring_length, float max_power);
  71
  72 void racer_align4point()
  73 {
  74     vector push_vector, v_add;
  75     float fl_push, fr_push, bl_push, br_push;
  76
  77
  78     push_vector  = racer_force_from_tag("tag_engine_fr", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  79     fr_push      = force_fromtag_normpower;
  80     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  81
  82     push_vector += racer_force_from_tag("tag_engine_fl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  83     fl_push      = force_fromtag_normpower;
  84     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  85
  86     push_vector += racer_force_from_tag("tag_engine_br", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  87     br_push      = force_fromtag_normpower;
  88     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  89
  90     push_vector += racer_force_from_tag("tag_engine_bl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  91     bl_push      = force_fromtag_normpower;
  92     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  93
  94     self.velocity += (push_vector * frametime);
  95
  96     // Anti ocilation
  97     if(self.velocity_z  > 0)
  98         self.velocity_z *= 1 - (autocvar_g_vehicle_racer_upforcedamper * frametime);
  99
 100     self.velocity   += v_add;
 101     //self.velocity_z -= autocvar_sv_gravity * frametime;
 102
 103     push_vector_x =  (fl_push - bl_push);
 104     push_vector_x += (fr_push - br_push);
 105     push_vector_x *= 360;
 106
 107     push_vector_z = (fr_push - fl_push);
 108     push_vector_z += (br_push - bl_push);
 109     push_vector_z *= 360;
 110
 111     // Apply angle diffrance
 112     self.angles_z += push_vector_z * frametime;
 113     self.angles_x += push_vector_x * frametime;
 114
 115     // Apply stabilizer
 116     self.angles_x *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * frametime);
 117     self.angles_z *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * frametime);
 118 }
 119
 120 void racer_fire_cannon(string tagname)
 121 {
 122     vector v;
 123     entity bolt;
 124
 125     v = gettaginfo(self, gettagindex(self, tagname));
 126     bolt = vehicles_projectile("wakizashi_gun_muzzleflash", "weapons/lasergun_fire.wav",
 127                            v, normalize(v_forward + randomvec() * autocvar_g_vehicle_racer_cannon_spread) * autocvar_g_vehicle_racer_cannon_speed,
 128                            autocvar_g_vehicle_racer_cannon_damage, autocvar_g_vehicle_racer_cannon_radius, autocvar_g_vehicle_racer_cannon_force,  0,
 129                            DEATH_WAKIGUN, PROJECTILE_WAKICANNON, 0, TRUE, TRUE);
 130
 131         // Fix z-aim (for chase mode)
 132     v = normalize(trace_endpos - bolt.origin);
 133     v_forward_z = v_z * 0.5;
 134     bolt.velocity = v_forward * autocvar_g_vehicle_racer_cannon_speed;
 135 }
 136
 137 void racer_rocket_groundhugger()
 138 {
 139     vector olddir, newdir;
 140     float oldvel, newvel;
 141
 142     self.nextthink  = time;
 143
 144     if(self.owner.deadflag != DEAD_NO || self.cnt < time)
 145     {
 146         self.use();
 147         return;
 148     }
 149
 150     if not (self.realowner.vehicle)
 151     {
 152         UpdateCSQCProjectile(self);
 153         return;
 154     }
 155
 156     olddir = normalize(self.velocity);
 157     oldvel = vlen(self.velocity);
 158     newvel = oldvel + self.lip;
 159
 160     tracebox(self.origin, self.mins, self.maxs, self.origin + olddir * 64, MOVE_WORLDONLY,self);
 161     if(trace_fraction <= 0.5)
 162     {
 163         // Hitting somethign soon, just speed ahead
 164         self.velocity = olddir * newvel;
 165         UpdateCSQCProjectile(self);
 166         return;
 167     }
 168
 169     traceline(trace_endpos, trace_endpos - '0 0 64', MOVE_NORMAL, self);
 170     if(trace_fraction != 1.0)
 171     {
 172         newdir = normalize(trace_endpos + '0 0 64' - self.origin) * autocvar_g_vehicle_racer_rocket_turnrate;
 173         self.velocity = normalize(olddir + newdir) * newvel;
 174     }
 175     else
 176     {
 177         self.velocity = olddir * newvel;
 178         self.velocity_z -= 1600 * sys_frametime; // 2x grav looks better for this one
 179     }
 180
 181     UpdateCSQCProjectile(self);
 182     return;
 183 }
 184
 185 void racer_rocket_tracker()
 186 {
 187     vector olddir, newdir;
 188     float oldvel, newvel;
 189
 190     self.nextthink  = time;
 191
 192     if (self.owner.deadflag != DEAD_NO || self.cnt < time)
 193     {
 194         self.use();
 195         return;
 196     }
 197
 198     if not (self.realowner.vehicle)
 199     {
 200         UpdateCSQCProjectile(self);
 201         return;
 202     }
 203
 204     olddir = normalize(self.velocity);
 205     oldvel = vlen(self.velocity);
 206     newvel = oldvel + self.lip;
 207     makevectors(vectoangles(olddir));
 208
 209     traceline(self.origin, self.origin + v_forward * 64 - '0 0 32', MOVE_NORMAL, self);
 210     newdir = normalize(self.enemy.origin - self.origin);
 211
 212     if(vlen(newdir - v_forward) > autocvar_g_vehicle_racer_rocket_locked_maxangle)
 213     {
 214         //bprint("Target lost!\n");
 215         //dprint("OF:", ftos(vlen(newdir - v_forward)), "\n");
 216         self.think = racer_rocket_groundhugger;
 217         return;
 218     }
 219
 220     if(trace_fraction != 1.0)
 221         newdir_z += 16 * sys_frametime;
 222
 223     self.velocity = normalize(olddir + newdir * autocvar_g_vehicle_racer_rocket_turnrate) * newvel;
 224     self.velocity_z -= 800 * sys_frametime;
 225
 226     UpdateCSQCProjectile(self);
 227     return;
 228 }
 229
 230 void racer_fire_rocket(string tagname, entity trg)
 231 {
 232     vector v;
 233     entity rocket;
 234
 235     v = gettaginfo(self, gettagindex(self, tagname));
 236     rocket = vehicles_projectile("wakizashi_rocket_launch", "weapons/rocket_fire.wav",
 237                            v, v_forward * autocvar_g_vehicle_racer_rocket_speed,
 238                            autocvar_g_vehicle_racer_rocket_damage, autocvar_g_vehicle_racer_rocket_radius, autocvar_g_vehicle_racer_rocket_force, 3,
 239                            DEATH_WAKIROCKET, PROJECTILE_WAKIROCKET, 20, FALSE, FALSE);
 240
 241     rocket.lip              = autocvar_g_vehicle_racer_rocket_accel * sys_frametime;
 242     rocket.wait             = autocvar_g_vehicle_racer_rocket_turnrate;
 243     rocket.nextthink        = time;
 244     rocket.enemy            = trg;
 245     rocket.cnt              = time + 15;
 246
 247     if(trg)
 248         rocket.think            = racer_rocket_tracker;
 249     else
 250         rocket.think            = racer_rocket_groundhugger;
 251 }
 252
 253 float racer_frame()
 254 {
 255     entity player, racer;
 256     vector df;
 257     float ftmp;
 258
 259     player          = self;
 260     racer           = self.vehicle;
 261
 262     player.BUTTON_ZOOM = player.BUTTON_CROUCH = 0;
 263
 264     self = racer;
 265
 266     if(player.BUTTON_USE)
 267     {
 268         vehicles_exit(VHEF_NORMAL);
 269         self = player;
 270         return 0;
 271     }
 272
 273     if(racer.deadflag != DEAD_NO)
 274     {
 275         self = player;
 276         player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 277         return 1;
 278     }
 279
 280     racer_align4point();
 281
 282     crosshair_trace(player);
 283
 284 #if VEHICLES_VIEWROTATE_CROSSHAIR
 285     float ftmp2;
 286     racer.angles_x *= -1;
 287     df = vectoangles(normalize(trace_endpos - self.origin + '0 0 32'));
 288     if(df_x > 180)  df_x -= 360;
 289     if(df_x < -180) df_x += 360;
 290     if(df_y > 180)  df_y -= 360;
 291     if(df_y < -180) df_y += 360;
 292
 293     // Yaw
 294     ftmp = autocvar_g_vehicle_racer_turnspeed * frametime;
 295     ftmp2 = ftmp * -1;
 296
 297     ftmp = bound(ftmp2, shortangle_f(df_y - racer.angles_y, racer.angles_y), ftmp);
 298     ftmp2 = anglemods(racer.angles_y + ftmp);
 299
 300     // Roll
 301     ftmp = bound(-45, shortangle_f(df_z + ((racer.angles_y - ftmp2) * autocvar_g_vehicle_racer_turnroll), racer.angles_z), 45);
 302     ftmp = anglemods(racer.angles_z + ftmp) * frametime;
 303     racer.angles_z = bound(-65, racer.angles_z + ftmp, 65);
 304
 305     // Turn
 306     racer.angles_y = ftmp2;
 307
 308     // Pitch
 309     ftmp = autocvar_g_vehicle_racer_pitchspeed * frametime;
 310     ftmp2 = ftmp * -1;
 311
 312     ftmp = bound(ftmp2, shortangle_f(player.v_angle_x - racer.angles_x, racer.angles_x), ftmp);
 313     racer.angles_x = anglemods(racer.angles_x + ftmp);
 314
 315     makevectors(racer.angles);
 316     racer.angles_x *= -1;
 317 #else
 318     racer.angles_x *= -1;
 319
 320     // Yaw
 321     ftmp = autocvar_g_vehicle_racer_turnspeed * frametime;
 322     ftmp = bound(-ftmp, shortangle_f(player.v_angle_y - racer.angles_y, racer.angles_y), ftmp);
 323     racer.angles_y = anglemods(racer.angles_y + ftmp);
 324
 325     // Roll
 326     racer.angles_z += -ftmp * autocvar_g_vehicle_racer_turnroll * frametime;
 327
 328     // Pitch
 329     ftmp = autocvar_g_vehicle_racer_pitchspeed  * frametime;
 330     ftmp = bound(-ftmp, shortangle_f(player.v_angle_x - racer.angles_x, racer.angles_x), ftmp);
 331     racer.angles_x = bound(-30, anglemods(racer.angles_x + ftmp), 30);
 332
 333     makevectors(racer.angles);
 334     racer.angles_x *= -1;
 335 #endif
 336
 337     ftmp = racer.velocity_z;
 338     df = racer.velocity * -autocvar_g_vehicle_racer_friction;
 339     racer.velocity_z = ftmp;
 340
 341     if(player.movement_x != 0)
 342     {
 343         if(player.movement_x > 0)
 344             df += v_forward  * autocvar_g_vehicle_racer_speed_forward;
 345         else if(player.movement_x < 0)
 346             df -= v_forward  * autocvar_g_vehicle_racer_speed_forward;
 347     }
 348
 349     if(player.movement_y != 0)
 350     {
 351         if(player.movement_y < 0)
 352             df -= v_right * autocvar_g_vehicle_racer_speed_strafe;
 353         else if(player.movement_y > 0)
 354             df += v_right * autocvar_g_vehicle_racer_speed_strafe;
 355     }
 356
 357     // Afterburn
 358     if (player.BUTTON_JUMP)
 359     if(racer.vehicle_energy >= (autocvar_g_vehicle_racer_afterburn_cost * frametime))
 360     {
 361         racer.wait = time;
 362         racer.vehicle_energy -= autocvar_g_vehicle_racer_afterburn_cost * frametime;
 363         df += (v_forward * autocvar_g_vehicle_racer_speed_afterburn);
 364         //self.owner.vehicle_energy = racer.vehicle_energy / autocvar_g_vehicle_racer_energy;
 365     }
 366
 367     racer.velocity  += df * frametime;
 368
 369     df = (vlen(racer.velocity) * autocvar_g_vehicle_racer_downforce * v_up) * frametime;
 370     racer.velocity  = racer.velocity - df;
 371     player.movement = racer.velocity;
 372
 373     if(player.BUTTON_ATCK)
 374     if(time > racer.attack_finished_single)
 375     if(racer.vehicle_energy >= autocvar_g_vehicle_racer_cannon_cost)
 376     {
 377         racer.vehicle_energy -= autocvar_g_vehicle_racer_cannon_cost;
 378         racer.wait = time;
 379
 380         crosshair_trace(player);
 381         if(racer.cnt)
 382         {
 383             racer_fire_cannon("tag_fire1");
 384             racer.cnt = 0;
 385         }
 386         else
 387         {
 388             racer_fire_cannon("tag_fire2");
 389             racer.cnt = 1;
 390         }
 391         racer.attack_finished_single = time + autocvar_g_vehicle_racer_cannon_refire;
 392         //self.owner.vehicle_energy = racer.vehicle_energy / autocvar_g_vehicle_racer_energy;
 393     }
 394
 395     if(autocvar_g_vehicle_racer_rocket_locktarget)
 396     {
 397         vehicles_locktarget((1 / autocvar_g_vehicle_racer_rocket_locking_time) * frametime,
 398                          (1 / autocvar_g_vehicle_racer_rocket_locking_releasetime) * frametime,
 399                          autocvar_g_vehicle_racer_rocket_locked_time);
 400
 401         if(self.lock_target)
 402         {
 403             if(racer.lock_strength == 1)
 404                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '1 0 0', 0);
 405             else if(self.lock_strength > 0.5)
 406                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '0 1 0', 0);
 407             else if(self.lock_strength < 0.5)
 408                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '0 0 1', 0);
 409         }
 410     }
 411
 412     if(time > racer.delay)
 413     if(player.BUTTON_ATCK2)
 414     {
 415         self.misc_bulletcounter += 1;
 416         racer.delay = time + 0.2;
 417         if(self.misc_bulletcounter == 1)
 418             racer_fire_rocket("tag_rocket_r", (self.lock_strength == 1 && self.lock_target) ? self.lock_target : world);
 419         else if(self.misc_bulletcounter == 2)
 420         {
 421             racer_fire_rocket("tag_rocket_l", (self.lock_strength == 1 && self.lock_target) ? self.lock_target : world);
 422             self.lock_strength  = 0;
 423             self.lock_target    = world;
 424             self.misc_bulletcounter = 0;
 425
 426             racer.delay = time + autocvar_g_vehicle_racer_rocket_refire;
 427             racer.lip = time;
 428         }
 429     }
 430     player.vehicle_reload1 = bound(0, 100 * ((time - racer.lip) / (racer.delay - racer.lip)), 100);
 431
 432     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 433         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_racer_shield, autocvar_g_vehicle_racer_shield_regen_pause, autocvar_g_vehicle_racer_shield_regen, frametime);
 434
 435     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 436         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_racer_health, autocvar_g_vehicle_racer_health_regen_pause, autocvar_g_vehicle_racer_health_regen, frametime);
 437
 438     if(self.vehicle_flags  & VHF_ENERGYREGEN)
 439         vehicles_regen(wait, vehicle_energy, autocvar_g_vehicle_racer_energy, autocvar_g_vehicle_racer_energy_regen_pause, autocvar_g_vehicle_racer_energy_regen, frametime);
 440
 441
 442     VEHICLE_UPDATE_PLAYER(health, racer);
 443     VEHICLE_UPDATE_PLAYER(energy, racer);
 444
 445     if(self.vehicle_flags & VHF_HASSHIELD)
 446         VEHICLE_UPDATE_PLAYER(shield, racer);
 447
 448
 449     player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 450     setorigin(player,racer.origin + '0 0 32');
 451     player.velocity = racer.velocity;
 452
 453     self = player;
 454     return 1;
 455 }
 456
 457 void racer_think()
 458 {
 459     /*
 460     float a, b, c;a = autocvar_g_vehicle_racer_anglestabilizer;
 461     b = autocvar_g_vehicle_racer_springlength;
 462     c = autocvar_g_vehicle_racer_hoverpower;
 463
 464     autocvar_g_vehicle_racer_anglestabilizer = 36;
 465     autocvar_g_vehicle_racer_springlength = 96;
 466     autocvar_g_vehicle_racer_hoverpower = 300;
 467     */
 468
 469     racer_align4point(); //time - self.nextthink);
 470
 471     /*
 472     //if(self.velocity_z > 0)
 473     //    self.velocity_z *= 0.95;
 474
 475     autocvar_g_vehicle_racer_anglestabilizer = a;
 476     autocvar_g_vehicle_racer_springlength = b;
 477     autocvar_g_vehicle_racer_hoverpower = c;
 478     */
 479
 480     self.velocity_x *= 0.9;
 481     self.velocity_y *= 0.9;
 482     self.velocity_z *= 0.8;
 483     self.velocity_z += sin(time * 2) * 16;
 484     self.nextthink = time + 0.05;
 485 }
 486
 487 void racer_enter()
 488 {
 489     self.movetype = MOVETYPE_BOUNCE;
 490     self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_racer_health);
 491     self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_racer_shield);
 492 }
 493
 494 void racer_exit(float eject)
 495 {
 496     self.think      = racer_think;
 497     self.nextthink  = time;
 498     self.movetype   = MOVETYPE_TOSS;
 499
 500     if not (self.owner)
 501         return;
 502
 503         makevectors(self.angles);
 504         if(eject)
 505         {
 506             setorigin(self.owner, self.origin + v_forward * 100 + v_up * 32);
 507             self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 508         }
 509         else
 510         {
 511             setorigin(self.owner, self.origin - v_forward * 100 + v_up * 32);
 512             self.owner.velocity = v_forward * -150;
 513         }
 514     self.owner = world;
 515 }
 516
 517 void racer_spawn()
 518 {
 519     self.think          = racer_think;
 520     self.nextthink      = time;
 521     self.vehicle_health = autocvar_g_vehicle_racer_health;
 522     self.vehicle_shield = autocvar_g_vehicle_racer_shield;
 523
 524     self.movetype       = MOVETYPE_TOSS;
 525     self.solid          = SOLID_SLIDEBOX;
 526     self.delay          = time;
 527     self.scale          = 0.5;
 528
 529     setsize(self, RACER_MIN * 0.5, RACER_MAX * 0.5);
 530 }
 531
 532
 533 void racer_blowup()
 534 {
 535     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 536     pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 537
 538     self.deadflag    = DEAD_DEAD;
 539     self.vehicle_exit(VHEF_NORMAL);
 540
 541     RadiusDamage (self, self, autocvar_g_vehicle_racer_blowup_coredamage,
 542                                         autocvar_g_vehicle_racer_blowup_edgedamage,
 543                                         autocvar_g_vehicle_racer_blowup_radius, world,
 544                                         autocvar_g_vehicle_racer_blowup_forceintensity,
 545                                         DEATH_WAKIBLOWUP, world);
 546
 547     self.alpha = -1;
 548     self.nextthink  = time + autocvar_g_vehicle_racer_respawntime;
 549     self.think      = racer_spawn;
 550     self.movetype   = MOVETYPE_NONE;
 551     self.effects    = EF_NODRAW;
 552
 553     self.colormod  = '0 0 0';
 554     self.avelocity = '0 0 0';
 555     self.velocity  = '0 0 0';
 556
 557     setorigin(self, self.pos1);
 558         self.think     = racer_spawn;
 559         self.nextthink = time + autocvar_g_vehicle_racer_respawntime;
 560 }
 561
 562 void racer_deadtouch()
 563 {
 564     self.avelocity_x *= 0.7;
 565     self.cnt -= 1;
 566     if(self.cnt <= 0)
 567         racer_blowup();
 568 }
 569
 570 void racer_die()
 571 {
 572     self.health       = 0;
 573     self.event_damage = SUB_Null;
 574     self.iscreature   = FALSE;
 575     self.solid        = SOLID_CORPSE;
 576     self.takedamage   = DAMAGE_NO;
 577     self.deadflag     = DEAD_DYING;
 578     self.movetype     = MOVETYPE_BOUNCE;
 579     self.wait         = time;
 580     self.cnt          = 1 + random() * 3;
 581     self.touch        = racer_deadtouch;
 582
 583     pointparticles(particleeffectnum("rocket_explode"), findbetterlocation (self.origin, 16), '0 0 0', 1);
 584
 585     if(random() < 0.5)
 586         self.avelocity_z  = 16;
 587     else
 588         self.avelocity_z  = -16;
 589
 590     self.avelocity_x = -vlen(self.velocity) * 0.2;
 591     self.velocity   += '0 0 700';
 592     self.colormod    = '-0.5 -0.5 -0.5';
 593
 594         self.think     = racer_blowup;
 595         self.nextthink = 2 + time + random() * 3;
 596 }
 597
 598 void racer_dinit()
 599 {
 600     if not (vehicle_initialize(
 601              "Wakizashi",
 602              "models/vehicles/wakizashi.dpm",
 603              "",
 604              "models/vehicles/wakizashi_cockpit.dpm",
 605              "", "", "tag_viewport",
 606              HUD_WAKIZASHI,
 607              0.5 * RACER_MIN, 0.5 * RACER_MAX,
 608              FALSE,
 609              racer_spawn, autocvar_g_vehicle_racer_respawntime,
 610              racer_frame,
 611              racer_enter, racer_exit,
 612              racer_die,   racer_think))
 613     {
 614         remove(self);
 615         return;
 616     }
 617
 618     if(autocvar_g_vehicle_racer_hovertype != 0)
 619         racer_force_from_tag = vehicles_force_fromtag_maglev;
 620     else
 621         racer_force_from_tag = vehicles_force_fromtag_hover;
 622
 623     // FIXME: this be hakkz, fix the models insted (scale body, add tag_viewport to the hudmodel).
 624     self.scale = 0.5;
 625     setattachment(self.vehicle_hudmodel, self, "");
 626     setattachment(self.vehicle_viewport, self, "tag_viewport");
 627
 628     self.mass               = 900;
 629 }
 630
 631 void spawnfunc_vehicle_racer()
 632 {
 633
 634     precache_sound ("weapons/laserimpact.wav");
 635     precache_sound ("weapons/lasergun_fire.wav");
 636     precache_sound ("weapons/rocket_fire.wav");
 637     precache_sound ("weapons/rocket_impact.wav");
 638
 639     precache_model ("models/vhshield.md3");
 640     precache_model ("models/vehicles/wakizashi.dpm");
 641     precache_model ("models/vehicles/wakizashi_cockpit.dpm");
 642
 643     vehicles_configcheck("vehicle_racer.cfg", autocvar_g_vehicle_racer_health);
 644     if(autocvar_g_vehicle_racer_energy)
 645         if(autocvar_g_vehicle_racer_energy_regen)
 646             self.vehicle_flags |= VHF_ENERGYREGEN;
 647
 648     if(autocvar_g_vehicle_racer_shield)
 649         self.vehicle_flags |= VHF_HASSHIELD;
 650
 651     if(autocvar_g_vehicle_racer_shield_regen)
 652         self.vehicle_flags |= VHF_SHIELDREGEN;
 653
 654     if(autocvar_g_vehicle_racer_health_regen)
 655         self.vehicle_flags |= VHF_HEALTHREGEN;
 656
 657     self.think = racer_dinit;
 658     self.nextthink = time + 1;
 659 }