qcsrc/server/vehicles/raptor.qc

   1 #define RAPTOR_MIN '-80 -80 0'
   2 #define RAPTOR_MAX '80 80 70'
   3
   4 float autocvar_g_vehicle_raptor_respawntime;
   5
   6 float autocvar_g_vehicle_raptor_movestyle;
   7 float autocvar_g_vehicle_raptor_turnspeed;
   8 float autocvar_g_vehicle_raptor_pitchspeed;
   9 float autocvar_g_vehicle_raptor_pitchlimit;
  10
  11 float autocvar_g_vehicle_raptor_speed_forward;
  12 float autocvar_g_vehicle_raptor_speed_strafe;
  13 float autocvar_g_vehicle_raptor_speed_up;
  14 float autocvar_g_vehicle_raptor_speed_down;
  15 float autocvar_g_vehicle_raptor_friction;
  16
  17 float autocvar_g_vehicle_raptor_bomblets;
  18 float autocvar_g_vehicle_raptor_bomblet_alt;
  19 float autocvar_g_vehicle_raptor_bomblet_time;
  20 float autocvar_g_vehicle_raptor_bomblet_damage;
  21 float autocvar_g_vehicle_raptor_bomblet_spread;
  22 float autocvar_g_vehicle_raptor_bomblet_edgedamage;
  23 float autocvar_g_vehicle_raptor_bomblet_radius;
  24 float autocvar_g_vehicle_raptor_bomblet_force;
  25 float autocvar_g_vehicle_raptor_bomblet_explode_delay;
  26 float autocvar_g_vehicle_raptor_bombs_refire;
  27
  28 float autocvar_g_vehicle_raptor_cannon_turnspeed;
  29 float autocvar_g_vehicle_raptor_cannon_turnlimit;
  30 float autocvar_g_vehicle_raptor_cannon_pitchlimit_up;
  31 float autocvar_g_vehicle_raptor_cannon_pitchlimit_down;
  32
  33 float autocvar_g_vehicle_raptor_cannon_locktarget;
  34 float autocvar_g_vehicle_raptor_cannon_locking_time;
  35 float autocvar_g_vehicle_raptor_cannon_locking_releasetime;
  36 float autocvar_g_vehicle_raptor_cannon_locked_time;
  37 float autocvar_g_vehicle_raptor_cannon_predicttarget;
  38
  39 float autocvar_g_vehicle_raptor_cannon_cost;
  40 float autocvar_g_vehicle_raptor_cannon_damage;
  41 float autocvar_g_vehicle_raptor_cannon_radius;
  42 float autocvar_g_vehicle_raptor_cannon_refire;
  43 float autocvar_g_vehicle_raptor_cannon_speed;
  44 float autocvar_g_vehicle_raptor_cannon_spread;
  45
  46
  47 float autocvar_g_vehicle_raptor_energy;
  48 float autocvar_g_vehicle_raptor_energy_regen;
  49 float autocvar_g_vehicle_raptor_energy_regen_pause;
  50
  51 float autocvar_g_vehicle_raptor_health;
  52 float autocvar_g_vehicle_raptor_health_regen;
  53 float autocvar_g_vehicle_raptor_health_regen_pause;
  54
  55 float autocvar_g_vehicle_raptor_shield;
  56 float autocvar_g_vehicle_raptor_shield_regen;
  57 float autocvar_g_vehicle_raptor_shield_regen_pause;
  58
  59 void raptor_spawn();
  60 float raptor_frame();
  61
  62 .entity bomb1;
  63 .entity bomb2;
  64
  65 //#define RAPTOR_RETARDCAMERA
  66
  67 float raptor_altitude(float amax)
  68 {
  69         tracebox(self.origin, self.mins, self.maxs, self.origin - ('0 0 1' * amax), TRUE, self);
  70     return vlen(self.origin - trace_endpos);
  71 }
  72
  73
  74 void raptor_bomblet_boom()
  75 {
  76     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
  77     pointparticles(particleeffectnum("raptor_bomb_impact"), self.origin, trace_plane_normal * 1000, 1);
  78     RadiusDamage (self, self.realowner, autocvar_g_vehicle_raptor_bomblet_damage,
  79                                     autocvar_g_vehicle_raptor_bomblet_edgedamage,
  80                                     autocvar_g_vehicle_raptor_bomblet_radius, world,
  81                                     autocvar_g_vehicle_raptor_bomblet_force, DEATH_SBROCKET, world);
  82     remove(self);
  83 }
  84
  85 void raptor_bomblet_touch()
  86 {
  87     if(other == self.owner)
  88         return;
  89
  90     PROJECTILE_TOUCH;
  91     self.think = raptor_bomblet_boom;
  92     self.nextthink = time + random() * autocvar_g_vehicle_raptor_bomblet_explode_delay;
  93 }
  94
  95 void raptor_bomb_burst()
  96 {
  97     if(self.cnt > time)
  98     if(autocvar_g_vehicle_raptor_bomblet_alt)
  99     {
 100         self.nextthink = time;
 101         traceline(self.origin, self.origin + (normalize(self.velocity) * autocvar_g_vehicle_raptor_bomblet_alt), MOVE_NORMAL, self);
 102         if(trace_fraction == 1.0)
 103             return;
 104
 105         if(vlen(self.origin - self.owner.origin) < autocvar_g_vehicle_raptor_bomblet_radius)
 106             return;
 107     }
 108
 109     entity bomblet;
 110     float i;
 111
 112     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 113     pointparticles(particleeffectnum("rocket_explode"), self.origin, self.velocity, 1);
 114
 115     for(i = 0; i < autocvar_g_vehicle_raptor_bomblets; ++i)
 116     {
 117         bomblet = spawn();
 118         setorigin(bomblet, self.origin);
 119
 120         bomblet.scale       = 0.5;
 121         bomblet.solid       = SOLID_TRIGGER;
 122         bomblet.movetype    = MOVETYPE_TOSS;
 123         bomblet.touch       = raptor_bomblet_touch;
 124         bomblet.think       = raptor_bomblet_boom;
 125         bomblet.nextthink   = time + 5;
 126         bomblet.owner   = self.owner;
 127         bomblet.realowner   = self.realowner;
 128         bomblet.velocity    = normalize(normalize(self.velocity) + (randomvec() * autocvar_g_vehicle_raptor_bomblet_spread)) * vlen(self.velocity);
 129         PROJECTILE_MAKETRIGGER(bomblet);
 130         CSQCProjectile(bomblet, TRUE, PROJECTILE_RAPTORBOMB, TRUE);
 131     }
 132
 133     remove(self);
 134 }
 135
 136 void raptor_bomb_touch()
 137 {
 138     raptor_bomb_burst();
 139 }
 140
 141 void raptor_bombdrop()
 142 {
 143     entity bomb_1, bomb_2;
 144
 145     //self.bomb1.alpha = 0;
 146     //self.bomb2.alpha = 0;
 147
 148     bomb_1 = spawn();
 149     bomb_2 = spawn();
 150
 151     setorigin(bomb_1, gettaginfo(self, gettagindex(self, "bombmount_left")));
 152     setorigin(bomb_2, gettaginfo(self, gettagindex(self, "bombmount_right")));
 153
 154     bomb_1.movetype     = bomb_2.movetype   = MOVETYPE_TOSS;
 155     bomb_1.velocity     = bomb_2.velocity   = self.velocity;
 156     bomb_1.touch        = bomb_2.touch      = raptor_bomb_touch;
 157     bomb_1.think        = bomb_2.think      = raptor_bomb_burst;
 158     bomb_1.cnt          = bomb_2.cnt        = time + 10;
 159
 160     if(autocvar_g_vehicle_raptor_bomblet_alt)
 161         bomb_1.nextthink = bomb_2.nextthink  = time;
 162     else
 163         bomb_1.nextthink = bomb_2.nextthink  = time + autocvar_g_vehicle_raptor_bomblet_time;
 164
 165     bomb_1.owner     = bomb_2.owner      = self;
 166     bomb_1.realowner = bomb_2.realowner  = self.owner;
 167     bomb_1.solid     = bomb_2.solid      = SOLID_BBOX;
 168
 169     PROJECTILE_MAKETRIGGER(bomb_1);
 170     PROJECTILE_MAKETRIGGER(bomb_2);
 171
 172     CSQCProjectile(bomb_1, TRUE, PROJECTILE_RAPTORBOMB, TRUE);
 173     CSQCProjectile(bomb_2, TRUE, PROJECTILE_RAPTORBOMB, TRUE);
 174
 175 }
 176
 177 void raptor_bolt_explode()
 178 {
 179         PROJECTILE_TOUCH;
 180     pointparticles(particleeffectnum("raptor_cannon_impact"), findbetterlocation (self.origin, 8), trace_plane_normal * 1000, 1);
 181     RadiusDamage (self, self.realowner, autocvar_g_vehicle_raptor_cannon_damage, 0, autocvar_g_vehicle_raptor_cannon_radius, world, 25, DEATH_WAKIGUN, world);
 182     sound (self, CHAN_PROJECTILE, "weapons/laserimpact.wav", VOL_BASE, ATTN_NORM);
 183     remove (self);
 184 }
 185
 186 void raptor_fire_cannon(entity gun, string tagname)
 187 {
 188     entity bolt;
 189
 190     bolt = spawn();
 191
 192     PROJECTILE_MAKETRIGGER(bolt);
 193     sound (gun, CHAN_WEAPON, "weapons/lasergun_fire.wav", VOL_BASE, ATTN_NORM);
 194     setorigin(bolt, gettaginfo(gun, gettagindex(gun, tagname)));
 195
 196     bolt.movetype        = MOVETYPE_FLYMISSILE;
 197     bolt.flags           = FL_PROJECTILE | FL_NOTARGET;
 198     bolt.owner           = self;
 199     bolt.realowner       = self.owner;
 200     bolt.touch           = raptor_bolt_explode;
 201     bolt.think           = raptor_bolt_explode;
 202     bolt.nextthink       = time + 9;
 203     bolt.bot_dodge       = TRUE;
 204     bolt.bot_dodgerating = autocvar_g_vehicle_raptor_cannon_damage;
 205     bolt.velocity        = normalize(v_forward + randomvec() * autocvar_g_vehicle_raptor_cannon_spread) * autocvar_g_vehicle_raptor_cannon_speed;
 206
 207     pointparticles(particleeffectnum("raptor_cannon_muzzleflash"), bolt.origin, bolt.velocity, 1);
 208     //pointparticles(particleeffectnum("spiderbot_minigun_muzzleflash"), bolt.origin, bolt.velocity, 1);
 209
 210     CSQCProjectile(bolt, TRUE, PROJECTILE_CRYLINK, TRUE);
 211 }
 212
 213 void raptor_think()
 214 {
 215 }
 216
 217 void raptor_enter()
 218 {
 219     self.movetype       = MOVETYPE_BOUNCEMISSILE;
 220     self.solid          = SOLID_BBOX;
 221     self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_raptor_health);
 222     self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_raptor_shield);
 223     self.velocity_z = 1;
 224 #ifdef RAPTOR_RETARDCAMERA
 225     setorigin(self.vehicle_viewport, self.origin);
 226 #endif
 227 }
 228
 229 void raptor_land()
 230 {
 231     float hgt;
 232
 233     hgt = raptor_altitude(512);
 234     self.velocity = (self.velocity * 0.9) + ('0 0 -1800' * (hgt / 256) * sys_frametime);
 235     self.angles_x *= 0.95;
 236     self.angles_z *= 0.95;
 237
 238     if(hgt < 128)
 239         if(self.frame != 0)
 240             self.frame = max(self.frame - 0.25, 0);
 241
 242     self.bomb1.gun1.avelocity_y = 90 + ((self.frame / 25) * 2000);
 243     self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 244
 245     if(hgt < 16)
 246     {
 247         self.movetype   = MOVETYPE_TOSS;
 248         self.think      = raptor_think;
 249     }
 250
 251     self.nextthink  = time;
 252 }
 253
 254 void raptor_exit(float eject)
 255 {
 256
 257     if(self.deadflag == DEAD_NO)
 258     {
 259         self.think      = raptor_land;
 260         self.nextthink  = time;
 261     }
 262
 263     if not (self.owner)
 264         return;
 265
 266         makevectors(self.angles);
 267         if(eject)
 268         {
 269             setorigin(self.owner,self.origin + v_forward * 100 + '0 0 64');
 270             self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 271         }
 272         else
 273         setorigin(self.owner,self.origin - v_forward * 200 + '0 0 64');
 274
 275     self.owner = world;
 276 }
 277
 278 float raptor_frame()
 279 {
 280     entity player, raptor;
 281     float ftmp, ftmp2;
 282     vector df;
 283
 284     player = self;
 285     raptor   = self.vehicle;
 286     self    = raptor;
 287
 288     if(player.BUTTON_USE && raptor.deadflag == DEAD_NO)
 289     {
 290         self = raptor;
 291         vehicles_exit(VHEF_NORMAL);
 292         self = player;
 293         return 0;
 294     }
 295
 296     if(raptor.deadflag != DEAD_NO)
 297     {
 298         self = player;
 299         player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 300         return 1;
 301     }
 302
 303     // Takeoff sequense
 304     if(raptor.frame < 25)
 305     {
 306         raptor.frame += 0.25;
 307         raptor.velocity_z = min(raptor.velocity_z * 1.5, 256);
 308         self.bomb1.gun1.avelocity_y = 90 + ((raptor.frame / 25) * 2000);
 309         self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 310         player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 311         self = player;
 312         return 1;
 313     }
 314
 315     //collision_run();
 316
 317     crosshair_trace(player);
 318
 319 #if VEHICLES_VIEWROTATE_CROSSHAIR
 320     df = vectoangles(normalize(trace_endpos - self.origin + '0 0 32'));
 321     if(df_x > 180)  df_x -= 360;
 322     if(df_x < -180) df_x += 360;
 323     if(df_y > 180)  df_y -= 360;
 324     if(df_y < -180) df_y += 360;
 325
 326     // Rotate Body
 327     ftmp = autocvar_g_vehicle_raptor_turnspeed * sys_frametime;
 328     ftmp = bound(-ftmp, shortangle_f(df_y - raptor.angles_y, raptor.angles_y), ftmp);
 329
 330     // Turn
 331     //raptor.angles_y = anglemods(raptor.angles_y + ftmp);
 332     raptor.avelocity_y = anglemods(raptor.angles_y + ftmp);
 333
 334     // Pitch Body
 335     ftmp = autocvar_g_vehicle_raptor_pitchspeed  * sys_frametime;
 336     ftmp = bound(-ftmp, shortangle_f(df_x - raptor.angles_x, raptor.angles_x), ftmp);
 337
 338     //raptor.angles_x = bound(-autocvar_g_vehicle_raptor_pitchlimit, anglemods(raptor.angles_x + ftmp), autocvar_g_vehicle_raptor_pitchlimit);
 339     raptor.avelocity_x = bound(-autocvar_g_vehicle_raptor_pitchlimit, anglemods(raptor.angles_x + ftmp), autocvar_g_vehicle_raptor_pitchlimit);
 340 #else
 341     vector vang;
 342     vang = raptor.angles;
 343     df = vectoangles(normalize(trace_endpos - self.origin + '0 0 32'));
 344     vang_x *= -1;
 345     df_x *= -1;
 346     if(df_x > 180)  df_x -= 360;
 347     if(df_x < -180) df_x += 360;
 348     if(df_y > 180)  df_y -= 360;
 349     if(df_y < -180) df_y += 360;
 350
 351     ftmp = shortangle_f(player.v_angle_y - vang_y, vang_y);
 352     if(ftmp > 180)  ftmp -= 360; if(ftmp < -180) ftmp += 360;
 353     raptor.avelocity_y = bound(-autocvar_g_vehicle_raptor_turnspeed, ftmp + raptor.avelocity_y * 0.9, autocvar_g_vehicle_raptor_turnspeed);
 354
 355     // Pitch
 356     ftmp = 0;
 357     if(player.movement_x > 0 && vang_x < autocvar_g_vehicle_raptor_pitchlimit) ftmp = 5;
 358     else if(player.movement_x < 0 && vang_x > -autocvar_g_vehicle_raptor_pitchlimit) ftmp = -20;
 359
 360     df_x = bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x , autocvar_g_vehicle_raptor_pitchlimit);
 361     ftmp = vang_x - bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x + ftmp, autocvar_g_vehicle_raptor_pitchlimit);
 362     raptor.avelocity_x = bound(-autocvar_g_vehicle_raptor_pitchspeed, ftmp + raptor.avelocity_x * 0.9, autocvar_g_vehicle_raptor_pitchspeed);
 363
 364     raptor.angles_x = anglemods(raptor.angles_x);
 365     raptor.angles_y = anglemods(raptor.angles_y);
 366     raptor.angles_z = anglemods(raptor.angles_z);
 367
 368 #endif
 369
 370     if(autocvar_g_vehicle_raptor_movestyle == 1)
 371         makevectors(raptor.angles + ('-1 0 0' * raptor.angles_x));
 372     else
 373         makevectors(player.v_angle);
 374
 375 #ifdef RAPTOR_RETARDCAMERA
 376     float spd, back, up;
 377     spd = vlen(self.velocity) + 0.01;
 378     back = spd / autocvar_g_vehicle_raptor_speed_forward;
 379     up = 1 - back;
 380     back = back;
 381     back = back * 1250;
 382     back += 150;
 383     up = up * 200;
 384     up = up + 100;
 385
 386     setorigin(self.vehicle_viewport, self.origin + (v_up * up) + (v_forward * -back));
 387 #endif
 388
 389     df = raptor.velocity * -autocvar_g_vehicle_raptor_friction;
 390
 391     if(player.movement_x != 0)
 392     {
 393         if(player.movement_x > 0)
 394             df += v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 395         else if(player.movement_x < 0)
 396             df -= v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 397     }
 398
 399     if(player.movement_y != 0)
 400     {
 401         if(player.movement_y < 0)
 402             df -= v_right * autocvar_g_vehicle_raptor_speed_strafe;
 403         else if(player.movement_y > 0)
 404             df += v_right * autocvar_g_vehicle_raptor_speed_strafe;
 405
 406         //raptor.angles_z = bound(-30,raptor.angles_z + (player.movement_y / autocvar_g_vehicle_raptor_speed_strafe),30);
 407     }
 408     else
 409     {
 410         /*raptor.angles_z *= 0.95;
 411         if(raptor.angles_z >= -1 && raptor.angles_z <= -1)
 412             raptor.angles_z = 0;*/
 413     }
 414
 415     if(player.BUTTON_CROUCH)
 416         df -=   v_up * autocvar_g_vehicle_raptor_speed_down;
 417     else if (player.BUTTON_JUMP)
 418         df +=  v_up * autocvar_g_vehicle_raptor_speed_up;
 419
 420
 421
 422     raptor.velocity  += df * frametime;
 423     player.velocity = player.movement  = raptor.velocity;
 424     setorigin(player,raptor.origin + '0 0 32');
 425
 426     vector vf, ad;
 427     // Target lock & predict
 428     if(autocvar_g_vehicle_raptor_cannon_locktarget)
 429     {
 430
 431         vehicles_locktarget((1 / autocvar_g_vehicle_raptor_cannon_locking_time) * frametime,
 432                              (1 / autocvar_g_vehicle_raptor_cannon_locking_releasetime) * frametime,
 433                              autocvar_g_vehicle_raptor_cannon_locked_time);
 434
 435         if(autocvar_g_vehicle_raptor_cannon_predicttarget && self.lock_strength == 1)
 436         {
 437             if(self.lock_target != world)
 438             {
 439                 float i, distance, impact_time;
 440
 441                 vf = real_origin(raptor.lock_target);
 442                 ad = vf;
 443                 for(i = 0; i < 4; ++i)
 444                 {
 445                     distance = vlen(ad - raptor.origin);
 446                     impact_time = distance / autocvar_g_vehicle_raptor_cannon_speed;
 447                     ad = vf + raptor.lock_target.velocity * impact_time;
 448                 }
 449                 trace_endpos = ad;
 450                 UpdateAuxiliaryXhair(player, trace_endpos, '1 1 1', 0);
 451             }
 452         }
 453
 454         if(self.lock_target)
 455         {
 456             if(raptor.lock_strength == 1)
 457                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '1 0 0', 1);
 458             else if(self.lock_strength > 0.5)
 459                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '0 1 0', 1);
 460             else if(self.lock_strength < 0.5)
 461                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '0 0 1', 1);
 462         }
 463
 464         /*
 465         if(self.lock_target != world)
 466         if(self.lock_strength == 1)
 467             UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '0 0 1', 1);
 468         else
 469             UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * (1 - self.lock_strength)) + '0 1 0' * self.lock_strength, 1);
 470         */
 471     }
 472
 473     // Aim the gunz
 474     ftmp2 = autocvar_g_vehicle_raptor_cannon_turnspeed * frametime;
 475     ftmp = -ftmp2;
 476
 477     // Gun1
 478     df = gettaginfo(raptor.gun1, gettagindex(raptor.gun1, "fire1"));
 479     ad = df;
 480     vf = v_forward;
 481     df = vectoangles(normalize(trace_endpos - df)); // Find the direction & angle
 482     df = shortangle_vxy(df - (raptor.angles + raptor.gun1.angles), raptor.angles + raptor.gun1.angles);     // Find aim offset
 483     // Bind to aimspeed
 484     df_x = bound(ftmp, df_x, ftmp2);
 485     df_y = bound(ftmp, df_y, ftmp2);
 486     // Bind to limts
 487     raptor.gun1.angles_x = bound(-autocvar_g_vehicle_raptor_cannon_pitchlimit_down, df_x + raptor.gun1.angles_x, autocvar_g_vehicle_raptor_cannon_pitchlimit_up);
 488     raptor.gun1.angles_y = bound(-autocvar_g_vehicle_raptor_cannon_turnlimit,  df_y + raptor.gun1.angles_y, autocvar_g_vehicle_raptor_cannon_turnlimit);
 489
 490     //df = vectoangles(normalize(trace_endpos - df));
 491
 492     //Gun 2
 493     df = gettaginfo(raptor.gun2, gettagindex(raptor.gun2, "fire1"));
 494     ad += df;
 495     vf += v_forward;
 496     df = vectoangles(normalize(trace_endpos - df)); // Find the direction & angle
 497     df = shortangle_vxy(df - (raptor.angles + raptor.gun2.angles), raptor.angles + raptor.gun2.angles);     // Find aim offset
 498     // Bind to aimspeed
 499     df_x = bound(ftmp, df_x, ftmp2);
 500     df_y = bound(ftmp, df_y, ftmp2);
 501     // Bind to limts
 502     raptor.gun2.angles_x = bound(-autocvar_g_vehicle_raptor_cannon_pitchlimit_down, df_x + raptor.gun2.angles_x, autocvar_g_vehicle_raptor_cannon_pitchlimit_up);
 503     raptor.gun2.angles_y = bound(-autocvar_g_vehicle_raptor_cannon_turnlimit,  df_y + raptor.gun2.angles_y, autocvar_g_vehicle_raptor_cannon_turnlimit);
 504
 505
 506     /*
 507     ad = ad * 0.5;
 508     v_forward = vf * 0.5;
 509     traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, raptor);
 510     UpdateAuxiliaryXhair(player, trace_endpos, '0 1 0', 0);
 511     */
 512
 513     if(player.BUTTON_ATCK)
 514     if(raptor.attack_finished_single <= time)
 515     if(raptor.vehicle_energy > autocvar_g_vehicle_raptor_cannon_cost)
 516     {
 517         raptor.misc_bulletcounter += 1;
 518         raptor.attack_finished_single = time + autocvar_g_vehicle_raptor_cannon_refire;
 519         //if(mod(raptor.misc_bulletcounter, 2))
 520         if(raptor.misc_bulletcounter <= 2)
 521             raptor_fire_cannon(self.gun1, "fire1");
 522         else if(raptor.misc_bulletcounter == 3)
 523             raptor_fire_cannon(self.gun2, "fire1");
 524         else
 525         {
 526             raptor.attack_finished_single = time + autocvar_g_vehicle_raptor_cannon_refire * 2;
 527             raptor_fire_cannon(self.gun2, "fire1");
 528             raptor.misc_bulletcounter = 0;
 529         }
 530
 531
 532         raptor.vehicle_energy -= autocvar_g_vehicle_raptor_cannon_cost;
 533
 534         self.cnt = time;
 535     }
 536
 537     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 538         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime);
 539
 540     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 541         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime);
 542
 543     if(self.vehicle_flags  & VHF_ENERGYREGEN)
 544         vehicles_regen(cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime);
 545
 546     player.vehicle_energy = raptor.vehicle_energy / autocvar_g_vehicle_raptor_energy;
 547
 548
 549     if(time > raptor.delay)
 550     {
 551         if(player.BUTTON_ATCK2)
 552         {
 553             raptor_bombdrop();
 554             raptor.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 555         }
 556         player.vehicle_reload1 = 1;
 557     }
 558     else
 559     {
 560         player.vehicle_reload1 = min(time / raptor.delay, 1);
 561         //raptor.bomb1.alpha = raptor.bomb2.alpha = player.vehicle_reload1;
 562     }
 563
 564     VEHICLE_UPDATE_PLAYER(health, raptor);
 565
 566     if(self.vehicle_flags & VHF_HASSHIELD)
 567         VEHICLE_UPDATE_PLAYER(shield, raptor);
 568
 569     player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 570     return 1;
 571 }
 572
 573 void raptor_blowup()
 574 {
 575     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 576     pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 577
 578     self.deadflag    = DEAD_DEAD;
 579     self.vehicle_exit(VHEF_NORMAL);
 580     RadiusDamage (self, self, 250, 15, 250, world, 250, DEATH_WAKIBLOWUP, world);
 581
 582     self.alpha          = -1;
 583     self.movetype       = MOVETYPE_NONE;
 584     self.effects        = EF_NODRAW;
 585     self.colormod       = '0 0 0';
 586     self.avelocity      = '0 0 0';
 587     self.velocity       = '0 0 0';
 588
 589     setorigin(self, self.pos1);
 590     self.touch = SUB_Null;
 591 }
 592
 593 void raptor_die()
 594 {
 595     self.health       = 0;
 596     self.event_damage = SUB_Null;
 597     self.iscreature   = FALSE;
 598     self.solid        = SOLID_CORPSE;
 599     self.takedamage   = DAMAGE_NO;
 600     self.deadflag     = DEAD_DYING;
 601     self.movetype     = MOVETYPE_BOUNCE;
 602
 603     pointparticles(particleeffectnum("rocket_explode"), findbetterlocation (self.origin, 16), '0 0 0', 1);
 604
 605     self.velocity_z += 128;
 606
 607     if(random() < 0.5)
 608         self.avelocity_z  = 45 + random() * 270;
 609     else
 610         self.avelocity_z  = -45 + random() * -270;
 611
 612     self.colormod = '-0.5 -0.5 -0.5';
 613         self.touch     = raptor_blowup;
 614 }
 615
 616 void raptor_spawn()
 617 {
 618     self.frame          = 0;
 619     self.vehicle_health = autocvar_g_vehicle_raptor_health;
 620     self.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 621     self.movetype       = MOVETYPE_TOSS;
 622     self.solid          = SOLID_BBOX;
 623     self.vehicle_energy = 1;
 624
 625     self.bomb1.gun1.avelocity_y = 90;
 626     self.bomb1.gun2.avelocity_y = -90;
 627
 628     setsize(self, RAPTOR_MIN, RAPTOR_MAX );
 629     self.delay = time;
 630 }
 631
 632 void raptor_dinit()
 633 {
 634     entity spinner;
 635     vector ofs;
 636
 637     if not (vehicle_initialize(
 638              "Raptor",
 639              "models/vehicles/raptor.dpm",
 640              "",
 641              "models/vehicles/raptor_cockpit.dpm",
 642              "", "tag_hud", "tag_camera",
 643              HUD_RAPTOR,
 644              RAPTOR_MIN, RAPTOR_MAX,
 645              FALSE,
 646              raptor_spawn, autocvar_g_vehicle_raptor_respawntime,
 647              raptor_frame,
 648              raptor_enter, raptor_exit,
 649              raptor_die,   raptor_think))
 650     {
 651         remove(self);
 652         return;
 653     }
 654     setorigin(self, self.origin + '0 0 50');
 655     //FIXME: Camera is in a bad place in HUD model.
 656     setorigin(self.vehicle_viewport, '5 0 5');
 657
 658     self.frame = 0;
 659
 660     self.bomb1 = spawn();
 661     self.bomb2 = spawn();
 662     self.gun1  = spawn();
 663     self.gun2  = spawn();
 664
 665 #ifdef RAPTOR_RETARDCAMERA
 666     setattachment(self.vehicle_viewport, world, "");
 667 #endif
 668
 669     setmodel(self.bomb1,"models/vehicles/raptor_bomb.dpm");
 670     setmodel(self.bomb2,"models/vehicles/raptor_bomb.dpm");
 671     setmodel(self.gun1, "models/vehicles/raptor_gun.dpm");
 672     setmodel(self.gun2, "models/vehicles/raptor_gun.dpm");
 673
 674     setattachment(self.bomb1, self,"bombmount_left");
 675     setattachment(self.bomb2, self,"bombmount_right");
 676
 677
 678     // FIXME Guns mounts to angled bones
 679     self.bomb1.angles = self.angles;
 680     self.angles = '0 0 0';
 681     // This messes up gun-aim, so work arround it.
 682     //setattachment(self.gun1, self, "gunmount_left");
 683     ofs = gettaginfo(self, gettagindex(self, "gunmount_left"));
 684     ofs -= self.origin;
 685     setattachment(self.gun1, self, "");
 686     setorigin(self.gun1, ofs);
 687
 688     //setattachment(self.gun2, self, "gunmount_right");
 689     ofs = gettaginfo(self, gettagindex(self, "gunmount_right"));
 690     ofs -= self.origin;
 691     setattachment(self.gun2, self, "");
 692     setorigin(self.gun2, ofs);
 693
 694     self.angles = self.bomb1.angles;
 695     self.bomb1.angles = '0 0 0';
 696
 697
 698     spinner = spawn();
 699     spinner.owner = self;
 700     setmodel(spinner,"models/vehicles/spinner.dpm");
 701     setattachment(spinner, self, "engine_left");
 702     spinner.movetype = MOVETYPE_NOCLIP;
 703     spinner.avelocity = '0 90 0';
 704     self.bomb1.gun1 = spinner;
 705
 706     spinner = spawn();
 707     spinner.owner = self;
 708     setmodel(spinner,"models/vehicles/spinner.dpm");
 709     setattachment(spinner, self, "engine_right");
 710     spinner.movetype = MOVETYPE_NOCLIP;
 711     spinner.avelocity = '0 -90 0';
 712     self.bomb1.gun2 = spinner;
 713
 714     self.mass               = 1 ;
 715 }
 716
 717 void spawnfunc_vehicle_raptor()
 718 {
 719     vehicles_configcheck("vehicle_raptor.cfg", autocvar_g_vehicle_raptor_health);
 720
 721     if(autocvar_g_vehicle_raptor_shield)
 722         self.vehicle_flags |= VHF_HASSHIELD;
 723
 724     if(autocvar_g_vehicle_raptor_shield_regen)
 725         self.vehicle_flags |= VHF_SHIELDREGEN;
 726
 727     if(autocvar_g_vehicle_raptor_health_regen)
 728         self.vehicle_flags |= VHF_HEALTHREGEN;
 729
 730     if(autocvar_g_vehicle_raptor_energy_regen)
 731         self.vehicle_flags |= VHF_ENERGYREGEN;
 732
 733     precache_model ("models/vehicles/raptor.dpm");
 734     precache_model ("models/vehicles/raptor_gun.dpm");
 735     precache_model ("models/vehicles/spinner.dpm");
 736     precache_model ("models/vehicles/raptor_cockpit.dpm");
 737     precache_model ("models/vehicles/raptor_bomb.dpm");
 738
 739     self.think = raptor_dinit;
 740     self.nextthink = time + 1;
 741 }