qcsrc/server/vehicles/raptor.qc

   1 #define RAPTOR_MIN '-80 -80 0'
   2 #define RAPTOR_MAX '80 80 70'
   3
   4 float autocvar_g_vehicle_raptor_respawntime;
   5
   6 float autocvar_g_vehicle_raptor_movestyle;
   7 float autocvar_g_vehicle_raptor_turnspeed;
   8 float autocvar_g_vehicle_raptor_pitchspeed;
   9 float autocvar_g_vehicle_raptor_pitchlimit;
  10
  11 float autocvar_g_vehicle_raptor_speed_forward;
  12 float autocvar_g_vehicle_raptor_speed_strafe;
  13 float autocvar_g_vehicle_raptor_speed_up;
  14 float autocvar_g_vehicle_raptor_speed_down;
  15
  16 float autocvar_g_vehicle_raptor_bomblets;
  17 float autocvar_g_vehicle_raptor_bomblet_alt;
  18 float autocvar_g_vehicle_raptor_bomblet_time;
  19 float autocvar_g_vehicle_raptor_bomblet_damage;
  20 float autocvar_g_vehicle_raptor_bomblet_spread;
  21 float autocvar_g_vehicle_raptor_bomblet_edgedamage;
  22 float autocvar_g_vehicle_raptor_bomblet_radius;
  23 float autocvar_g_vehicle_raptor_bomblet_force;
  24 float autocvar_g_vehicle_raptor_bombs_refire;
  25
  26 float autocvar_g_vehicle_raptor_guns_turnspeed;
  27 float autocvar_g_vehicle_raptor_guns_turnlimit;
  28 float autocvar_g_vehicle_raptor_guns_pitchlimit_up;
  29 float autocvar_g_vehicle_raptor_guns_pitchlimit_down;
  30
  31 float autocvar_g_vehicle_raptor_cannon_locktarget;
  32 float autocvar_g_vehicle_raptor_cannon_predicttarget;
  33 float autocvar_g_vehicle_raptor_cannon_cost;
  34 float autocvar_g_vehicle_raptor_cannon_damage;
  35 float autocvar_g_vehicle_raptor_cannon_radius;
  36 float autocvar_g_vehicle_raptor_cannon_refire;
  37 float autocvar_g_vehicle_raptor_cannon_speed;
  38 float autocvar_g_vehicle_raptor_cannon_spread;
  39
  40
  41 float autocvar_g_vehicle_raptor_energy;
  42 float autocvar_g_vehicle_raptor_energy_regen;
  43 float autocvar_g_vehicle_raptor_energy_regen_pause;
  44
  45 float autocvar_g_vehicle_raptor_health;
  46 float autocvar_g_vehicle_raptor_health_regen;
  47 float autocvar_g_vehicle_raptor_health_regen_pause;
  48
  49 float autocvar_g_vehicle_raptor_shield;
  50 float autocvar_g_vehicle_raptor_shield_regen;
  51 float autocvar_g_vehicle_raptor_shield_regen_pause;
  52
  53 void raptor_spawn();
  54 //void raptor_return();
  55 float raptor_frame();
  56 //float raptor_takeoff();
  57
  58 .entity bomb1;
  59 .entity bomb2;
  60
  61 float raptor_altitude(float amax)
  62 {
  63         tracebox(self.origin, self.mins, self.maxs, self.origin - ('0 0 1' * amax), TRUE, self);
  64     return vlen(self.origin - trace_endpos);
  65 }
  66
  67 void raptor_bombs_return()
  68 {
  69     self.owner.bomb1.alpha = 1;
  70     self.owner.bomb2.alpha = 1;
  71     remove(self);
  72 }
  73
  74 void raptor_bomblet_boom()
  75 {
  76     if(other == self.owner || other.owner == self.owner)
  77         return;
  78
  79     pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
  80     RadiusDamage (self, self.enemy, autocvar_g_vehicle_raptor_bomblet_damage,
  81                                     autocvar_g_vehicle_raptor_bomblet_edgedamage,
  82                                     autocvar_g_vehicle_raptor_bomblet_radius, world,
  83                                     autocvar_g_vehicle_raptor_bomblet_force, DEATH_SBROCKET, world);
  84     remove(self);
  85 }
  86
  87 void raptor_bomb_burst()
  88 {
  89     self.angles = vectoangles(self.velocity);
  90
  91
  92     if(autocvar_g_vehicle_raptor_bomblet_alt)
  93     {
  94         self.nextthink = time;
  95         // FIXME: this can make bombs stic forever if fierd at low altitude and land close to vehicle.
  96         traceline(self.origin, self.origin + (normalize(self.velocity) * autocvar_g_vehicle_raptor_bomblet_alt), MOVE_NORMAL, self);
  97         if(trace_fraction == 1.0)
  98             return;
  99
 100         if(vlen(self.origin - self.owner.origin) < autocvar_g_vehicle_raptor_bomblet_radius)
 101             return;
 102     }
 103
 104     entity bomblet;
 105     float i,v;
 106     vector d;
 107
 108     v = vlen(self.velocity);
 109     d = normalize(self.velocity);
 110     pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 111
 112     for(i = 0; i < autocvar_g_vehicle_raptor_bomblets; ++i)
 113     {
 114
 115         bomblet = spawn();
 116         setorigin(bomblet,self.origin);
 117
 118         setmodel(bomblet,"models/vehicles/raptor_bomb.dpm");
 119         bomblet.scale = 0.5;
 120
 121         bomblet.solid       = SOLID_TRIGGER;
 122         bomblet.movetype    = MOVETYPE_BOUNCE;
 123         bomblet.touch       = raptor_bomblet_boom;
 124         bomblet.think       = raptor_bomblet_boom;
 125         bomblet.nextthink   = time + 5;
 126         bomblet.owner       = self.owner;
 127
 128         bomblet.modelflags = MF_GRENADE;
 129
 130         bomblet.velocity = normalize(d + (randomvec() * autocvar_g_vehicle_raptor_bomblet_spread)) * v;
 131
 132         bomblet.angles = vectoangles(bomblet.velocity);
 133     }
 134
 135     remove(self);
 136 }
 137
 138 void raptor_bomb_touch()
 139 {
 140     raptor_bomb_burst();
 141 }
 142
 143 void raptor_bombdrop()
 144 {
 145     entity bomb_1, bomb_2;
 146
 147     self.bomb1.alpha = 0.25;
 148     self.bomb2.alpha = 0.25;
 149
 150     bomb_1 = spawn();
 151     bomb_2 = spawn();
 152
 153     setmodel(bomb_1,"models/vehicles/raptor_bomb.dpm");
 154     setmodel(bomb_2,"models/vehicles/raptor_bomb.dpm");
 155
 156     setorigin(bomb_1, gettaginfo(self, gettagindex(self, "bombmount_left")));
 157     setorigin(bomb_2, gettaginfo(self, gettagindex(self, "bombmount_right")));
 158
 159     bomb_1.movetype  = bomb_2.movetype   = MOVETYPE_TOSS;
 160     bomb_1.velocity  = bomb_2.velocity   = self.velocity;
 161     bomb_1.touch     = bomb_2.touch      = raptor_bomb_touch;
 162     bomb_1.think     = bomb_2.think      = raptor_bomb_burst;
 163
 164     if(autocvar_g_vehicle_raptor_bomblet_alt)
 165         bomb_1.nextthink = bomb_2.nextthink  = time;
 166     else
 167         bomb_1.nextthink = bomb_2.nextthink  = time + autocvar_g_vehicle_raptor_bomblet_time;
 168
 169     bomb_1.avelocity = bomb_2.avelocity  = '0 0 180';
 170     bomb_1.owner     = bomb_2.owner      = self;
 171     bomb_1.enemy     = bomb_2.enemy      = self.owner;
 172     bomb_1.angles    = bomb_2.angles     = self.angles;
 173     bomb_1.solid     = bomb_2.solid      = SOLID_BBOX;
 174
 175     bomb_1 = spawn();
 176     bomb_1.owner = self;
 177     bomb_1.think = raptor_bombs_return;
 178     bomb_1.nextthink = time + autocvar_g_vehicle_raptor_bombs_refire;
 179 }
 180
 181 void raptor_bolt_explode()
 182 {
 183         PROJECTILE_TOUCH;
 184     pointparticles(particleeffectnum("raptor_cannon_impact"), findbetterlocation (self.origin, 8), trace_plane_normal * 1000, 1);
 185     RadiusDamage (self, self.realowner, autocvar_g_vehicle_raptor_cannon_damage, 0, autocvar_g_vehicle_raptor_cannon_radius, world, 150, DEATH_WAKIGUN, world);
 186     sound (self, CHAN_PROJECTILE, "weapons/laserimpact.wav", VOL_BASE, ATTN_NORM);
 187     remove (self);
 188 }
 189
 190 void raptor_fire_cannon(entity gun, string tagname)
 191 {
 192     entity bolt;
 193
 194     bolt = spawn();
 195
 196     PROJECTILE_MAKETRIGGER(bolt);
 197     sound (gun, CHAN_WEAPON, "weapons/lasergun_fire.wav", VOL_BASE, ATTN_NORM);
 198     setorigin(bolt, gettaginfo(gun, gettagindex(gun, tagname)));
 199
 200     bolt.movetype        = MOVETYPE_FLYMISSILE;
 201     bolt.flags           = FL_PROJECTILE | FL_NOTARGET;
 202     bolt.owner           = self;
 203     bolt.realowner       = self.owner;
 204     bolt.touch           = raptor_bolt_explode;
 205     bolt.think           = raptor_bolt_explode;
 206     bolt.nextthink       = time + 9;
 207     bolt.bot_dodge       = TRUE;
 208     bolt.bot_dodgerating = autocvar_g_vehicle_raptor_cannon_damage;
 209     bolt.velocity        = normalize(v_forward + randomvec() * autocvar_g_vehicle_raptor_cannon_spread) * autocvar_g_vehicle_raptor_cannon_speed;
 210
 211     pointparticles(particleeffectnum("raptor_cannon_muzzleflash"), bolt.origin, bolt.velocity, 1);
 212
 213     CSQCProjectile(bolt, TRUE, PROJECTILE_CRYLINK   , TRUE);
 214 }
 215
 216 void raptor_think()
 217 {
 218 }
 219
 220 void raptor_enter()
 221 {
 222     self.movetype   = MOVETYPE_BOUNCEMISSILE;
 223     self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_raptor_health);
 224     self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_raptor_shield);
 225     self.velocity_z = 1;
 226 }
 227
 228 void raptor_land()
 229 {
 230     float hgt;
 231
 232     hgt = raptor_altitude(512);
 233     self.velocity = (self.velocity * 0.9) + ('0 0 -1800' * (hgt / 256) * sys_frametime);
 234     self.angles_x *= 0.95;
 235     self.angles_z *= 0.95;
 236
 237     if(hgt < 128)
 238         if(self.frame != 0)
 239             self.frame = max(self.frame - 0.25, 0);
 240
 241     self.bomb1.gun1.avelocity_y = 90 + ((self.frame / 25) * 2000);
 242     self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 243
 244     if(hgt < 16)
 245     {
 246         self.movetype   = MOVETYPE_BOUNCE;
 247         self.think      = raptor_think;
 248     }
 249
 250     self.nextthink  = time;
 251 }
 252
 253 void raptor_exit(float eject)
 254 {
 255
 256     if(self.deadflag == DEAD_NO)
 257     {
 258         vehicles_setreturn(autocvar_g_vehicle_raptor_respawntime, raptor_spawn);
 259         self.think      = raptor_land;
 260         self.nextthink  = time;
 261     }
 262
 263     if not (self.owner)
 264         return;
 265
 266     Release_AuxiliaryXhair(self.owner);
 267         makevectors(self.angles);
 268         if(eject)
 269         {
 270             setorigin(self.owner,self.origin + v_forward * 100 + '0 0 64');
 271             self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 272         }
 273         else
 274         setorigin(self.owner,self.origin - v_forward * 200 + '0 0 64');
 275
 276     self.owner = world;
 277 }
 278
 279 float raptor_frame()
 280 {
 281     entity player, raptor;
 282     float ftmp, ftmp2;
 283     vector df;
 284
 285     player = self;
 286     raptor   = self.vehicle;
 287     self    = raptor;
 288
 289     if(player.BUTTON_USE)
 290     {
 291         self = raptor;
 292         vehicles_exit(VHEF_NORMAL);
 293         self = player;
 294         return 0;
 295     }
 296
 297     if(raptor.deadflag != DEAD_NO)
 298     {
 299         self = player;
 300         player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 301         return 1;
 302     }
 303
 304     // Takeoff sequense
 305     if(raptor.frame < 25)
 306     {
 307         raptor.frame += 0.25;
 308         raptor.velocity_z = min(raptor.velocity_z * 1.5, 256);
 309         self.bomb1.gun1.avelocity_y = 90 + ((raptor.frame / 25) * 2000);
 310         self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 311         return 1;
 312     }
 313
 314     raptor.angles_x *= -1;
 315     // Rotate Body
 316     ftmp = autocvar_g_vehicle_raptor_turnspeed * sys_frametime;
 317     ftmp = bound(-ftmp, shortangle_f(player.v_angle_y - raptor.angles_y, raptor.angles_y), ftmp);
 318
 319     // Turn
 320     raptor.angles_y = anglemods(raptor.angles_y + ftmp);
 321
 322     // Pitch Body
 323     ftmp = autocvar_g_vehicle_raptor_pitchspeed  * sys_frametime;
 324     ftmp = bound(-ftmp, shortangle_f(player.v_angle_x - raptor.angles_x, raptor.angles_x), ftmp);
 325
 326     raptor.angles_x = bound(-autocvar_g_vehicle_raptor_pitchlimit, anglemods(raptor.angles_x + ftmp), autocvar_g_vehicle_raptor_pitchlimit);
 327     raptor.angles_x *= -1;
 328
 329     if(autocvar_g_vehicle_raptor_movestyle == 1)
 330     {
 331         ftmp = raptor.angles_z;
 332         raptor.angles_z = 0;
 333         ftmp2 = raptor.angles_x;
 334         raptor.angles_x = 0;
 335         fixedmakevectors(raptor.angles);
 336         raptor.angles_z = ftmp;
 337         raptor.angles_x = ftmp2;
 338     }
 339     else
 340         makevectors(player.v_angle);
 341
 342     df = raptor.velocity * -1;
 343
 344     if(player.movement_x != 0)
 345     {
 346         if(player.movement_x > 0)
 347             df += v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 348         else if(player.movement_x < 0)
 349             df -= v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 350     }
 351
 352     if(player.movement_y != 0)
 353     {
 354         if(player.movement_y < 0)
 355             df -= v_right * autocvar_g_vehicle_raptor_speed_strafe;
 356         else if(player.movement_y > 0)
 357             df += v_right * autocvar_g_vehicle_raptor_speed_strafe;
 358
 359         raptor.angles_z = bound(-30,raptor.angles_z + (player.movement_y / autocvar_g_vehicle_raptor_speed_strafe),30);
 360     }
 361     else
 362     {
 363         raptor.angles_z *= 0.95;
 364         if(raptor.angles_z >= -1 && raptor.angles_z <= -1)
 365             raptor.angles_z = 0;
 366     }
 367
 368     if(player.BUTTON_CROUCH)
 369         df -=   v_up * autocvar_g_vehicle_raptor_speed_down;
 370     else if (player.BUTTON_JUMP)
 371         df +=  v_up * autocvar_g_vehicle_raptor_speed_up;
 372
 373     raptor.velocity  += df * frametime;
 374     player.velocity = player.movement  = raptor.velocity;
 375     setorigin(player,raptor.origin + '0 0 32');
 376
 377     // Aim the gunz
 378     crosshair_trace(player);
 379     vector vf, ad;
 380     if(autocvar_g_vehicle_raptor_cannon_locktarget)
 381     {
 382         if(trace_ent)
 383         {
 384             if(raptor.gun2.enemy != world)
 385             {
 386                 if(raptor.gun2.enemy == trace_ent)
 387                     raptor.gun2.cnt += 1;
 388                 else
 389                     raptor.gun2.cnt -= 1;
 390             }
 391
 392             raptor.gun2.enemy = trace_ent;
 393
 394             if(raptor.gun2.cnt < 0)
 395             {
 396                 raptor.gun2.enemy = world;
 397                 raptor.gun2.cnt = 0;
 398             }
 399
 400             if(raptor.gun2.cnt > 50)
 401             {
 402                 raptor.gun2.enemy = world;
 403                 raptor.gun2.cnt = 0;
 404
 405                 raptor.gun1.enemy = trace_ent;
 406                 raptor.gun1.cnt = time + 1;
 407             }
 408
 409             // Allready have a lock?
 410             if(raptor.gun1.enemy != world)
 411             {
 412                 // Add 0.5 secs of tracking for each trace hit
 413                 if(trace_ent == raptor.gun1.enemy)
 414                     raptor.gun1.cnt = min(raptor.gun1.cnt + 0.25, time + 5);
 415
 416                 if(raptor.gun1.cnt < time)
 417                     raptor.gun1.enemy = world;
 418             }
 419         }
 420         else
 421             raptor.gun2.cnt = max(raptor.gun2.cnt - 1, 0);
 422
 423         if(raptor.gun1.cnt - time < 0)
 424             raptor.gun1.enemy = world;
 425
 426         if(autocvar_g_vehicle_raptor_cannon_predicttarget)
 427         {
 428             vector o;
 429             if(raptor.gun1.enemy != world)
 430             {
 431                 float i, distance, impact_time;
 432
 433                 vf = real_origin(raptor.gun1.enemy);
 434                 ad = vf;
 435                 o = raptor.origin;
 436                 for(i = 0; i < 4; ++i)
 437                 {
 438
 439                     distance = vlen(ad - o);
 440                     impact_time = distance / autocvar_g_vehicle_raptor_cannon_speed;
 441                     ad = vf + raptor.gun1.enemy.velocity * impact_time;
 442                     o = raptor.origin + raptor.velocity * impact_time;
 443                 }
 444                 trace_endpos = ad;
 445
 446             }
 447         }
 448         else
 449             trace_endpos = real_origin(raptor.gun1.enemy);
 450     }
 451
 452     ftmp2 = autocvar_g_vehicle_raptor_guns_turnspeed * frametime;
 453     ftmp = -ftmp2;
 454
 455     // Gun1
 456     df = gettaginfo(raptor.gun1, gettagindex(raptor.gun1, "fire1"));
 457     ad += df;
 458     vf += v_forward;
 459     df = vectoangles(normalize(trace_endpos - df)); // Find the direction & angle
 460     df = shortangle_vxy(df - (raptor.angles + raptor.gun1.angles), raptor.angles + raptor.gun1.angles);     // Find aim offset
 461     // Bind to aimspeed
 462     df_x = bound(ftmp, df_x, ftmp2);
 463     df_y = bound(ftmp, df_y, ftmp2);
 464     // Bind to limts
 465     raptor.gun1.angles_x = bound(-autocvar_g_vehicle_raptor_guns_pitchlimit_down, df_x + raptor.gun1.angles_x, autocvar_g_vehicle_raptor_guns_pitchlimit_up);
 466     raptor.gun1.angles_y = bound(-autocvar_g_vehicle_raptor_guns_turnlimit,  df_y + raptor.gun1.angles_y, autocvar_g_vehicle_raptor_guns_turnlimit);
 467
 468     //Gun 2
 469     df = gettaginfo(raptor.gun2, gettagindex(raptor.gun2, "fire1"));
 470     ad += df;
 471     vf += v_forward;
 472     df = vectoangles(normalize(trace_endpos - df)); // Find the direction & angle
 473     df = shortangle_vxy(df - (raptor.angles + raptor.gun2.angles), raptor.angles + raptor.gun2.angles);     // Find aim offset
 474     // Bind to aimspeed
 475     df_x = bound(ftmp, df_x, ftmp2);
 476     df_y = bound(ftmp, df_y, ftmp2);
 477     // Bind to limts
 478     raptor.gun2.angles_x = bound(-autocvar_g_vehicle_raptor_guns_pitchlimit_down, df_x + raptor.gun2.angles_x, autocvar_g_vehicle_raptor_guns_pitchlimit_up);
 479     raptor.gun2.angles_y = bound(-autocvar_g_vehicle_raptor_guns_turnlimit,  df_y + raptor.gun2.angles_y, autocvar_g_vehicle_raptor_guns_turnlimit);
 480
 481
 482     if(autocvar_g_vehicle_raptor_cannon_locktarget)
 483     {
 484
 485         if(raptor.gun1.enemy)
 486         {
 487             SpawnOrUpdateAuxiliaryXhair(player, trace_endpos, '1 0 0');
 488         }
 489         else
 490         {
 491             ad = ad * 0.5;
 492             v_forward = vf * 0.5;
 493             traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, raptor);
 494
 495             if(raptor.gun2.enemy != world)
 496             {
 497                 ftmp = raptor.gun2.cnt / 50;
 498                 SpawnOrUpdateAuxiliaryXhair(player, trace_endpos, '1 0 0' * ftmp + '1 1 1' * (1 - ftmp));
 499             }
 500             else
 501                 SpawnOrUpdateAuxiliaryXhair(player, trace_endpos, '1 1 1');
 502
 503         }
 504     }
 505     else
 506         SpawnOrUpdateAuxiliaryXhair(player, trace_endpos, '1 1 1');
 507
 508     if(player.BUTTON_ATCK)
 509     if(raptor.attack_finished_single <= time)
 510     if(raptor.vehicle_energy > autocvar_g_vehicle_raptor_cannon_cost)
 511     {
 512         raptor_fire_cannon(self.gun1, "fire1");
 513         raptor_fire_cannon(self.gun2, "fire1");
 514
 515         raptor.vehicle_energy -= autocvar_g_vehicle_raptor_cannon_cost;
 516         raptor.attack_finished_single = time + autocvar_g_vehicle_raptor_cannon_refire;
 517         self.cnt = time;
 518     }
 519
 520     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 521         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime);
 522
 523     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 524         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime);
 525
 526     if(self.vehicle_flags  & VHF_ENERGYREGEN)
 527         vehicles_regen(cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime);
 528
 529     player.vehicle_energy = raptor.vehicle_energy / autocvar_g_vehicle_raptor_energy;
 530
 531     if(time > raptor.delay)
 532     if(player.BUTTON_ATCK2)
 533     {
 534         raptor_bombdrop();
 535         raptor.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 536         raptor.lip = time;
 537     }
 538
 539     player.vehicle_reload1 = (time - raptor.lip) / (raptor.delay - raptor.lip);
 540     VEHICLE_UPDATE_PLAYER(health, raptor);
 541
 542     if(self.vehicle_flags & VHF_HASSHIELD)
 543         VEHICLE_UPDATE_PLAYER(shield, raptor);
 544
 545     player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 546
 547     self = player;
 548     return 1;
 549 }
 550
 551 void raptor_touch()
 552 {
 553     if(self.owner)
 554     {
 555         if(vlen(self.velocity) == 0)
 556             return;
 557
 558         if(other.classname != "player")
 559             return;
 560
 561         return;
 562     }
 563
 564     if(other.classname != "player")
 565         return;
 566
 567     if(other.deadflag != DEAD_NO)
 568         return;
 569
 570     if(other.vehicle != world)
 571         return;
 572
 573     vehicles_enter();
 574 }
 575
 576 void raptor_blowup()
 577 {
 578     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 579     pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 580
 581     self.deadflag    = DEAD_DEAD;
 582     self.vehicle_exit(VHEF_NORMAL);
 583     RadiusDamage (self, self, 250, 15, 250, world, 250, DEATH_WAKIBLOWUP, world);
 584
 585     self.alpha          = -1;
 586     self.movetype       = MOVETYPE_NONE;
 587     self.effects        = EF_NODRAW;
 588     self.colormod       = '0 0 0';
 589     self.avelocity      = '0 0 0';
 590     self.velocity       = '0 0 0';
 591
 592     setorigin(self, self.pos1);
 593     self.touch = SUB_Null;
 594 }
 595
 596 void raptor_die()
 597 {
 598     self.health       = 0;
 599     self.event_damage = SUB_Null;
 600     self.iscreature   = FALSE;
 601     self.solid        = SOLID_CORPSE;
 602     self.takedamage   = DAMAGE_NO;
 603     self.deadflag     = DEAD_DYING;
 604     self.movetype     = MOVETYPE_BOUNCE;
 605     //self.wait         = time;
 606
 607     pointparticles(particleeffectnum("rocket_explode"), findbetterlocation (self.origin, 16), '0 0 0', 1);
 608
 609     self.velocity_z += 128;
 610
 611     if(random() < 0.5)
 612         self.avelocity_z  = 45 + random() * 270;
 613     else
 614         self.avelocity_z  = -45 + random() * -270;
 615
 616     self.colormod = '-0.5 -0.5 -0.5';
 617
 618         self.touch     = raptor_blowup;
 619         self.think     = raptor_spawn;
 620         self.nextthink = time + autocvar_g_vehicle_raptor_respawntime;
 621 }
 622
 623 void raptor_spawn()
 624 {
 625     self.flags     = FL_NOTARGET;
 626     self.effects   = 0;
 627
 628     self.vehicle_health = autocvar_g_vehicle_raptor_health;
 629     self.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 630     self.event_damage   = vehicles_damage;
 631     self.touch          = raptor_touch;
 632     self.iscreature     = TRUE;
 633     self.movetype       = MOVETYPE_FLY;
 634     self.solid          = SOLID_SLIDEBOX;
 635     self.takedamage     = DAMAGE_AIM;
 636     self.alpha          = 1;
 637         self.colormap       = 1024;
 638         self.deadflag       = DEAD_NO;
 639     self.bot_attack     = TRUE;
 640     self.colormod       = '1 1 1';
 641     self.avelocity      = '0 0 0';
 642     self.velocity       = '0 0 0';
 643     self.vehicle_energy = 1;
 644     self.vehicle_hudmodel.viewmodelforclient = self;
 645
 646     self.bomb1.gun1.avelocity_y = 90;
 647     self.bomb1.gun2.avelocity_y = -90;
 648     self.frame = 0;
 649
 650     setorigin(self, self.pos1);
 651     self.angles = self.pos2;
 652
 653     setsize(self, RAPTOR_MIN, RAPTOR_MAX );
 654     pointparticles(particleeffectnum("teleport"), self.origin + '0 0 64', '0 0 0', 1);
 655     self.delay = time;
 656 }
 657
 658 void raptor_dinit()
 659 {
 660     entity spinner;
 661     vector ofs;
 662
 663     if not (vehicle_initialize(
 664              "Raptor",
 665              "models/vehicles/raptor.dpm",
 666              "",
 667              "models/vehicles/raptor_cockpit.dpm",
 668              "", "tag_hud", "tag_camera",
 669              HUD_RAPTOR,
 670              RAPTOR_MIN, RAPTOR_MAX,
 671              FALSE,
 672              raptor_spawn, raptor_frame,
 673              raptor_enter, raptor_exit,
 674              raptor_die,   raptor_think))
 675     {
 676         remove(self);
 677         return;
 678     }
 679
 680     //FIXME: Camera is in a bad place in HUD model.
 681     setorigin(self.vehicle_viewport, '10 0 3');
 682
 683     self.frame = 0;
 684
 685     self.bomb1 = spawn();
 686     self.bomb2 = spawn();
 687     self.gun1  = spawn();
 688     self.gun2  = spawn();
 689
 690     setmodel(self.bomb1,"models/vehicles/raptor_bomb.dpm");
 691     setmodel(self.bomb2,"models/vehicles/raptor_bomb.dpm");
 692     setmodel(self.gun1, "models/vehicles/raptor_gun.dpm");
 693     setmodel(self.gun2, "models/vehicles/raptor_gun.dpm");
 694
 695     setattachment(self.bomb1, self,"bombmount_left");
 696     setattachment(self.bomb2, self,"bombmount_right");
 697
 698     // FIXME Guns mounts to angled bones
 699     // This messes up gun-aim, so work arround it.
 700     //setattachment(self.gun1, self, "gunmount_left");
 701     ofs = gettaginfo(self, gettagindex(self, "gunmount_left"));
 702     ofs -= self.origin;
 703     setattachment(self.gun1, self, "");
 704     setorigin(self.gun1, ofs);
 705
 706     //setattachment(self.gun2, self, "gunmount_right");
 707     ofs = gettaginfo(self, gettagindex(self, "gunmount_right"));
 708     ofs -= self.origin;
 709     setattachment(self.gun2, self, "");
 710     setorigin(self.gun2, ofs);
 711
 712     spinner = spawn();
 713     spinner.owner = self;
 714     setmodel(spinner,"models/vehicles/spinner.dpm");
 715     setattachment(spinner, self, "engine_left");
 716     spinner.movetype = MOVETYPE_NOCLIP;
 717     spinner.avelocity = '0 90 0';
 718     self.bomb1.gun1 = spinner;
 719
 720     spinner = spawn();
 721     spinner.owner = self;
 722     setmodel(spinner,"models/vehicles/spinner.dpm");
 723     setattachment(spinner, self, "engine_right");
 724     spinner.movetype = MOVETYPE_NOCLIP;
 725     spinner.avelocity = '0 -90 0';
 726     self.bomb1.gun2 = spinner;
 727 }
 728
 729 void spawnfunc_vehicle_raptor()
 730 {
 731     vehicles_configcheck("vehicle_raptor.cfg", autocvar_g_vehicle_raptor_health);
 732
 733     if(autocvar_g_vehicle_raptor_shield)
 734         self.vehicle_flags |= VHF_HASSHIELD;
 735
 736     if(autocvar_g_vehicle_raptor_shield_regen)
 737         self.vehicle_flags |= VHF_SHIELDREGEN;
 738
 739     if(autocvar_g_vehicle_raptor_health_regen)
 740         self.vehicle_flags |= VHF_HEALTHREGEN;
 741
 742     if(autocvar_g_vehicle_raptor_energy_regen)
 743         self.vehicle_flags |= VHF_ENERGYREGEN;
 744
 745     precache_model ("models/vehicles/raptor.dpm");
 746     precache_model ("models/vehicles/raptor_gun.dpm");
 747     precache_model ("models/vehicles/spinner.dpm");
 748     precache_model ("models/vehicles/raptor_cockpit.dpm");
 749     precache_model ("models/vehicles/raptor_bomb.dpm");
 750
 751
 752     self.think = raptor_dinit;
 753     self.nextthink = time + 1;
 754 }