qcsrc/server/vehicles/raptor.qc

   1 #ifdef SVQC
   2 #define RAPTOR_MIN '-80 -80 0'
   3 #define RAPTOR_MAX '80 80 70'
   4 //#define RAPTOR_ENGINE "sound/vehicles/raptor.wav"
   5 float autocvar_g_vehicle_raptor_respawntime;
   6
   7 float autocvar_g_vehicle_raptor_movestyle;
   8 float autocvar_g_vehicle_raptor_turnspeed;
   9 float autocvar_g_vehicle_raptor_pitchspeed;
  10 float autocvar_g_vehicle_raptor_pitchlimit;
  11
  12 float autocvar_g_vehicle_raptor_speed_forward;
  13 float autocvar_g_vehicle_raptor_speed_strafe;
  14 float autocvar_g_vehicle_raptor_speed_up;
  15 float autocvar_g_vehicle_raptor_speed_down;
  16 float autocvar_g_vehicle_raptor_friction;
  17
  18 float autocvar_g_vehicle_raptor_bomblets;
  19 float autocvar_g_vehicle_raptor_bomblet_alt;
  20 float autocvar_g_vehicle_raptor_bomblet_time;
  21 float autocvar_g_vehicle_raptor_bomblet_damage;
  22 float autocvar_g_vehicle_raptor_bomblet_spread;
  23 float autocvar_g_vehicle_raptor_bomblet_edgedamage;
  24 float autocvar_g_vehicle_raptor_bomblet_radius;
  25 float autocvar_g_vehicle_raptor_bomblet_force;
  26 float autocvar_g_vehicle_raptor_bomblet_explode_delay;
  27 float autocvar_g_vehicle_raptor_bombs_refire;
  28
  29 float autocvar_g_vehicle_raptor_cannon_turnspeed;
  30 float autocvar_g_vehicle_raptor_cannon_turnlimit;
  31 float autocvar_g_vehicle_raptor_cannon_pitchlimit_up;
  32 float autocvar_g_vehicle_raptor_cannon_pitchlimit_down;
  33
  34 float autocvar_g_vehicle_raptor_cannon_locktarget;
  35 float autocvar_g_vehicle_raptor_cannon_locking_time;
  36 float autocvar_g_vehicle_raptor_cannon_locking_releasetime;
  37 float autocvar_g_vehicle_raptor_cannon_locked_time;
  38 float autocvar_g_vehicle_raptor_cannon_predicttarget;
  39
  40 float autocvar_g_vehicle_raptor_cannon_cost;
  41 float autocvar_g_vehicle_raptor_cannon_damage;
  42 float autocvar_g_vehicle_raptor_cannon_radius;
  43 float autocvar_g_vehicle_raptor_cannon_refire;
  44 float autocvar_g_vehicle_raptor_cannon_speed;
  45 float autocvar_g_vehicle_raptor_cannon_spread;
  46 float autocvar_g_vehicle_raptor_cannon_force;
  47
  48 float autocvar_g_vehicle_raptor_energy;
  49 float autocvar_g_vehicle_raptor_energy_regen;
  50 float autocvar_g_vehicle_raptor_energy_regen_pause;
  51
  52 float autocvar_g_vehicle_raptor_health;
  53 float autocvar_g_vehicle_raptor_health_regen;
  54 float autocvar_g_vehicle_raptor_health_regen_pause;
  55
  56 float autocvar_g_vehicle_raptor_shield;
  57 float autocvar_g_vehicle_raptor_shield_regen;
  58 float autocvar_g_vehicle_raptor_shield_regen_pause;
  59
  60 void raptor_spawn();
  61 float raptor_frame();
  62 float raptor_takeoff();
  63
  64 .entity bomb1;
  65 .entity bomb2;
  66
  67 float raptor_altitude(float amax)
  68 {
  69         tracebox(self.origin, self.mins, self.maxs, self.origin - ('0 0 1' * amax), TRUE, self);
  70     return vlen(self.origin - trace_endpos);
  71 }
  72
  73
  74 void raptor_bomblet_boom()
  75 {
  76     RadiusDamage (self, self.realowner, autocvar_g_vehicle_raptor_bomblet_damage,
  77                                     autocvar_g_vehicle_raptor_bomblet_edgedamage,
  78                                     autocvar_g_vehicle_raptor_bomblet_radius, world,
  79                                     autocvar_g_vehicle_raptor_bomblet_force, DEATH_RAPTOR_BOMB, world);
  80     remove(self);
  81 }
  82
  83 void raptor_bomblet_touch()
  84 {
  85     if(other == self.owner)
  86         return;
  87
  88     PROJECTILE_TOUCH;
  89     self.think = raptor_bomblet_boom;
  90     self.nextthink = time + random() * autocvar_g_vehicle_raptor_bomblet_explode_delay;
  91 }
  92
  93 void raptor_bomb_burst()
  94 {
  95     if(self.cnt > time)
  96     if(autocvar_g_vehicle_raptor_bomblet_alt)
  97     {
  98         self.nextthink = time;
  99         traceline(self.origin, self.origin + (normalize(self.velocity) * autocvar_g_vehicle_raptor_bomblet_alt), MOVE_NORMAL, self);
 100         if((trace_fraction == 1.0) || (vlen(self.origin - self.owner.origin) < autocvar_g_vehicle_raptor_bomblet_radius))
 101         {
 102             UpdateCSQCProjectile(self);
 103             return;
 104         }
 105     }
 106
 107     entity bomblet;
 108     float i;
 109
 110     Damage_DamageInfo(self.origin, 0, 0, 0, '0 0 0', DEATH_RAPTOR_BOMB_SPLIT, self);
 111
 112     for(i = 0; i < autocvar_g_vehicle_raptor_bomblets; ++i)
 113     {
 114         bomblet = spawn();
 115         setorigin(bomblet, self.origin);
 116
 117         bomblet.movetype    = MOVETYPE_TOSS;
 118         bomblet.touch       = raptor_bomblet_touch;
 119         bomblet.think       = raptor_bomblet_boom;
 120         bomblet.nextthink   = time + 5;
 121         bomblet.owner       = self.owner;
 122         bomblet.realowner   = self.realowner;
 123         bomblet.velocity    = normalize(normalize(self.velocity) + (randomvec() * autocvar_g_vehicle_raptor_bomblet_spread)) * vlen(self.velocity);
 124
 125         PROJECTILE_MAKETRIGGER(bomblet);
 126         CSQCProjectile(bomblet, TRUE, PROJECTILE_RAPTORBOMBLET, TRUE);
 127     }
 128
 129     remove(self);
 130 }
 131
 132 void raptor_bomb_touch()
 133 {
 134     raptor_bomb_burst();
 135 }
 136
 137 void raptor_bombdrop()
 138 {
 139     entity bomb_1, bomb_2;
 140
 141     bomb_1 = spawn();
 142     bomb_2 = spawn();
 143
 144     setorigin(bomb_1, gettaginfo(self, gettagindex(self, "bombmount_left")));
 145     setorigin(bomb_2, gettaginfo(self, gettagindex(self, "bombmount_right")));
 146
 147     bomb_1.movetype     = bomb_2.movetype   = MOVETYPE_BOUNCE;
 148     bomb_1.velocity     = bomb_2.velocity   = self.velocity;
 149     bomb_1.touch        = bomb_2.touch      = raptor_bomb_touch;
 150     bomb_1.think        = bomb_2.think      = raptor_bomb_burst;
 151     bomb_1.cnt          = bomb_2.cnt        = time + 10;
 152
 153     if(autocvar_g_vehicle_raptor_bomblet_alt)
 154         bomb_1.nextthink = bomb_2.nextthink  = time;
 155     else
 156         bomb_1.nextthink = bomb_2.nextthink  = time + autocvar_g_vehicle_raptor_bomblet_time;
 157
 158     bomb_1.owner     = bomb_2.owner      = self;
 159     bomb_1.realowner = bomb_2.realowner  = self.owner;
 160     bomb_1.solid     = bomb_2.solid      = SOLID_BBOX;
 161     bomb_1.gravity   = bomb_2.gravity    = 1;
 162
 163     PROJECTILE_MAKETRIGGER(bomb_1);
 164     PROJECTILE_MAKETRIGGER(bomb_2);
 165
 166     CSQCProjectile(bomb_1, TRUE, PROJECTILE_RAPTORBOMB, TRUE);
 167     CSQCProjectile(bomb_2, TRUE, PROJECTILE_RAPTORBOMB, TRUE);
 168
 169 }
 170
 171
 172 void raptor_fire_cannon(entity gun, string tagname)
 173 {
 174     entity bolt;
 175     vector b_org;
 176     b_org = gettaginfo(gun, gettagindex(gun, tagname));
 177     bolt = vehicles_projectile("raptor_cannon_muzzleflash", "weapons/lasergun_fire.wav",
 178                            b_org, normalize(v_forward + randomvec() * autocvar_g_vehicle_raptor_cannon_spread) * autocvar_g_vehicle_raptor_cannon_speed,
 179                            autocvar_g_vehicle_raptor_cannon_damage, autocvar_g_vehicle_raptor_cannon_radius, autocvar_g_vehicle_raptor_cannon_force,  0,
 180                            DEATH_RAPTOR_CANNON, PROJECTILE_RAPTORCANNON, 0, TRUE, TRUE);
 181 }
 182
 183 void raptor_think()
 184 {
 185 }
 186
 187 void raptor_enter()
 188 {
 189     self.owner.PlayerPhysplug = raptor_takeoff;
 190     self.movetype       = MOVETYPE_BOUNCEMISSILE;
 191     self.solid          = SOLID_SLIDEBOX;
 192     self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_raptor_health);
 193     self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_raptor_shield);
 194     self.velocity_z = 1; // Nudge upwards to takeoff sequense can work.
 195     self.tur_head.exteriormodeltoclient = self.owner;
 196
 197     self.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 198     self.lip   = time;
 199
 200     if(self.owner.flagcarried)
 201        setorigin(self.owner.flagcarried, '-20 0 96');
 202
 203 }
 204
 205 void raptor_land()
 206 {
 207
 208     float hgt;
 209
 210     hgt = raptor_altitude(512);
 211     self.velocity = (self.velocity * 0.9) + ('0 0 -1800' * (hgt / 256) * sys_frametime);
 212     self.angles_x *= 0.95;
 213     self.angles_z *= 0.95;
 214
 215     if(hgt < 128)
 216         if(self.frame != 0)
 217             self.frame = max(self.frame - 0.25, 0);
 218
 219     self.bomb1.gun1.avelocity_y = 90 + ((self.frame / 25) * 2000);
 220     self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 221
 222     if(hgt < 16)
 223     {
 224         self.movetype   = MOVETYPE_TOSS;
 225         self.think      = raptor_think;
 226     }
 227
 228     self.nextthink  = time;
 229 }
 230
 231 void raptor_exit(float eject)
 232 {
 233     vector spot;
 234     self.tur_head.exteriormodeltoclient = world;
 235
 236     if(self.deadflag == DEAD_NO)
 237     {
 238         self.think      = raptor_land;
 239         self.nextthink  = time;
 240     }
 241
 242     if not (self.owner)
 243         return;
 244
 245         makevectors(self.angles);
 246         if(eject)
 247         {
 248             spot = self.origin + v_forward * 100 + '0 0 64';
 249             spot = vehicles_findgoodexit(spot);
 250             setorigin(self.owner , spot);
 251             self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 252         }
 253         else
 254         {
 255             spot = self.origin - v_forward * 200 + '0 0 64';
 256             spot = vehicles_findgoodexit(spot);
 257             setorigin(self.owner , spot);
 258         }
 259
 260     self.owner = world;
 261 }
 262
 263 float raptor_takeoff()
 264 {
 265     entity player, raptor;
 266
 267     player = self;
 268     raptor = self.vehicle;
 269     self   = raptor;
 270
 271     if(self.sound_nexttime < time)
 272     {
 273         self.sound_nexttime = time + 7.955812; //soundlength("vehicles/raptor_fly.wav");
 274         sound (self, CHAN_TRIGGER, "vehicles/raptor_speed.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 275     }
 276
 277     // Takeoff sequense
 278     if(raptor.frame < 25)
 279     {
 280         raptor.frame += 0.25;
 281         raptor.velocity_z = min(raptor.velocity_z * 1.5, 256);
 282         self.bomb1.gun1.avelocity_y = 90 + ((raptor.frame / 25) * 25000);
 283         self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 284         player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 285
 286         setorigin(player, raptor.origin + '0 0 32');
 287     }
 288     else
 289         player.PlayerPhysplug = raptor_frame;
 290
 291     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 292         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime);
 293
 294     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 295         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime);
 296
 297     if(self.vehicle_flags  & VHF_ENERGYREGEN)
 298         vehicles_regen(cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime);
 299
 300
 301     raptor.bomb1.alpha = raptor.bomb2.alpha = (time - raptor.lip) / (raptor.delay - raptor.lip);
 302     player.vehicle_reload2 = bound(0, raptor.bomb1.alpha * 100, 100);
 303
 304     VEHICLE_UPDATE_PLAYER(health, raptor);
 305     VEHICLE_UPDATE_PLAYER(energy, raptor);
 306     if(self.vehicle_flags & VHF_HASSHIELD)
 307         VEHICLE_UPDATE_PLAYER(shield, raptor);
 308
 309     player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 310     self = player;
 311     return 1;
 312 }
 313
 314 float raptor_frame()
 315 {
 316     entity player, raptor;
 317     float ftmp, ftmp2;
 318     vector df;
 319
 320         if(intermission_running)
 321                 return 1;
 322
 323     player = self;
 324     raptor = self.vehicle;
 325     self   = raptor;
 326
 327     vehicles_painframe();
 328     /*
 329     ftmp = vlen(self.velocity);
 330     if(ftmp > autocvar_g_vehicle_raptor_speed_forward)
 331         ftmp = 1;
 332     else
 333         ftmp = ftmp / autocvar_g_vehicle_raptor_speed_forward;
 334     */
 335
 336     if(self.sound_nexttime < time)
 337     {
 338         self.sound_nexttime = time + 7.955812;
 339         //sound (self.tur_head, CHAN_TRIGGER, "vehicles/raptor_fly.wav", 1 - ftmp,   ATTN_NORM );
 340         sound (self, CHAN_TRIGGER, "vehicles/raptor_speed.wav", 1, ATTN_NORM);
 341         self.wait = ftmp;
 342     }
 343     /*
 344     else if(fabs(ftmp - self.wait) > 0.2)
 345     {
 346         sound (self.tur_head, CHAN_TRIGGER, "", 1 - ftmp,   ATTN_NORM );
 347         sound (self, CHAN_TRIGGER, "", ftmp, ATTN_NORM);
 348         self.wait = ftmp;
 349     }
 350     */
 351
 352
 353     if(raptor.deadflag != DEAD_NO)
 354     {
 355         self = player;
 356         player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 357         return 1;
 358     }
 359     crosshair_trace(player);
 360
 361
 362     vector vang;
 363     vang = raptor.angles;
 364     df = vectoangles(normalize(trace_endpos - self.origin + '0 0 32'));
 365     vang_x *= -1;
 366     df_x *= -1;
 367     if(df_x > 180)  df_x -= 360;
 368     if(df_x < -180) df_x += 360;
 369     if(df_y > 180)  df_y -= 360;
 370     if(df_y < -180) df_y += 360;
 371
 372     ftmp = shortangle_f(player.v_angle_y - vang_y, vang_y);
 373     if(ftmp > 180)  ftmp -= 360; if(ftmp < -180) ftmp += 360;
 374     raptor.avelocity_y = bound(-autocvar_g_vehicle_raptor_turnspeed, ftmp + raptor.avelocity_y * 0.9, autocvar_g_vehicle_raptor_turnspeed);
 375
 376     // Pitch
 377     ftmp = 0;
 378     if(player.movement_x > 0 && vang_x < autocvar_g_vehicle_raptor_pitchlimit) ftmp = 5;
 379     else if(player.movement_x < 0 && vang_x > -autocvar_g_vehicle_raptor_pitchlimit) ftmp = -20;
 380
 381     df_x = bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x , autocvar_g_vehicle_raptor_pitchlimit);
 382     ftmp = vang_x - bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x + ftmp, autocvar_g_vehicle_raptor_pitchlimit);
 383     raptor.avelocity_x = bound(-autocvar_g_vehicle_raptor_pitchspeed, ftmp + raptor.avelocity_x * 0.9, autocvar_g_vehicle_raptor_pitchspeed);
 384
 385     raptor.angles_x = anglemods(raptor.angles_x);
 386     raptor.angles_y = anglemods(raptor.angles_y);
 387     raptor.angles_z = anglemods(raptor.angles_z);
 388
 389
 390     if(autocvar_g_vehicle_raptor_movestyle == 1)
 391         makevectors('0 1 0' * raptor.angles_y);
 392     else
 393         makevectors(player.v_angle);
 394
 395     df = raptor.velocity * -autocvar_g_vehicle_raptor_friction;
 396
 397     if(player.movement_x != 0)
 398     {
 399         if(player.movement_x > 0)
 400             df += v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 401         else if(player.movement_x < 0)
 402             df -= v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 403     }
 404
 405     if(player.movement_y != 0)
 406     {
 407         if(player.movement_y < 0)
 408             df -= v_right * autocvar_g_vehicle_raptor_speed_strafe;
 409         else if(player.movement_y > 0)
 410             df += v_right * autocvar_g_vehicle_raptor_speed_strafe;
 411
 412         raptor.angles_z = bound(-30,raptor.angles_z + (player.movement_y / autocvar_g_vehicle_raptor_speed_strafe),30);
 413     }
 414     else
 415     {
 416         raptor.angles_z *= 0.95;
 417         if(raptor.angles_z >= -1 && raptor.angles_z <= -1)
 418             raptor.angles_z = 0;
 419     }
 420
 421     if(player.BUTTON_CROUCH)
 422         df -=   v_up * autocvar_g_vehicle_raptor_speed_down;
 423     else if (player.BUTTON_JUMP)
 424         df +=  v_up * autocvar_g_vehicle_raptor_speed_up;
 425
 426     raptor.velocity  += df * frametime;
 427     //player.velocity = raptor.velocity;
 428     player.velocity = player.movement  = raptor.velocity;
 429     setorigin(player, raptor.origin + '0 0 32');
 430
 431     vector vf, ad;
 432     // Target lock & predict
 433     if(autocvar_g_vehicle_raptor_cannon_locktarget)
 434     {
 435
 436         vehicles_locktarget((1 / autocvar_g_vehicle_raptor_cannon_locking_time) * frametime,
 437                              (1 / autocvar_g_vehicle_raptor_cannon_locking_releasetime) * frametime,
 438                              autocvar_g_vehicle_raptor_cannon_locked_time);
 439
 440         if(self.lock_target != world)
 441         if(autocvar_g_vehicle_raptor_cannon_predicttarget)
 442         if(self.lock_strength == 1)
 443         {
 444             float i, distance, impact_time;
 445
 446             vf = real_origin(raptor.lock_target);
 447             ad = vf;
 448             for(i = 0; i < 4; ++i)
 449             {
 450                 distance = vlen(ad - raptor.origin);
 451                 impact_time = distance / autocvar_g_vehicle_raptor_cannon_speed;
 452                 ad = vf + raptor.lock_target.velocity * impact_time;
 453             }
 454             trace_endpos = ad;
 455             //UpdateAuxiliaryXhair(player, trace_endpos, '1 1 1', 0);
 456         }
 457
 458         if(self.lock_target)
 459         {
 460             if(raptor.lock_strength == 1)
 461                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '1 0 0', 1);
 462             else if(self.lock_strength > 0.5)
 463                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '0 1 0', 1);
 464             else if(self.lock_strength < 0.5)
 465                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '0 0 1', 1);
 466         }
 467     }
 468
 469     // Aim the gunz
 470     ftmp2 = autocvar_g_vehicle_raptor_cannon_turnspeed * frametime;
 471     ftmp = -ftmp2;
 472
 473     // Gun1
 474     df = gettaginfo(raptor.gun1, gettagindex(raptor.gun1, "fire1"));
 475     ad = df;
 476     vf = v_forward;
 477     df = vectoangles(normalize(trace_endpos - df)); // Find the direction & angle
 478     df = AnglesTransform_ToAngles(AnglesTransform_LeftDivide(AnglesTransform_FromAngles(raptor.angles), AnglesTransform_FromAngles(df))) - raptor.gun1.angles;
 479     df = shortangle_vxy(df, raptor.gun1.angles);
 480
 481     // Bind to aimspeed
 482     df_x = bound(ftmp, df_x, ftmp2);
 483     df_y = bound(ftmp, df_y, ftmp2);
 484     // Bind to limts
 485     raptor.gun1.angles_x = bound(-autocvar_g_vehicle_raptor_cannon_pitchlimit_down, df_x + raptor.gun1.angles_x, autocvar_g_vehicle_raptor_cannon_pitchlimit_up);
 486     raptor.gun1.angles_y = bound(-autocvar_g_vehicle_raptor_cannon_turnlimit,  df_y + raptor.gun1.angles_y, autocvar_g_vehicle_raptor_cannon_turnlimit);
 487
 488     // Gun2
 489     df = gettaginfo(raptor.gun2, gettagindex(raptor.gun2, "fire1"));
 490     ad += df;
 491     vf += v_forward;
 492     df = vectoangles(normalize(trace_endpos - df)); // Find the direction & angle
 493     df = AnglesTransform_ToAngles(AnglesTransform_LeftDivide(AnglesTransform_FromAngles(raptor.angles), AnglesTransform_FromAngles(df))) - raptor.gun2.angles;
 494     df = shortangle_vxy(df, raptor.gun2.angles);
 495
 496     // Bind to aimspeed
 497     df_x = bound(ftmp, df_x, ftmp2);
 498     df_y = bound(ftmp, df_y, ftmp2);
 499     // Bind to limts
 500     raptor.gun2.angles_x = bound(-autocvar_g_vehicle_raptor_cannon_pitchlimit_down, df_x + raptor.gun2.angles_x, autocvar_g_vehicle_raptor_cannon_pitchlimit_up);
 501     raptor.gun2.angles_y = bound(-autocvar_g_vehicle_raptor_cannon_turnlimit,  df_y + raptor.gun2.angles_y, autocvar_g_vehicle_raptor_cannon_turnlimit);
 502
 503     /*
 504     ad = ad * 0.5;
 505     v_forward = vf * 0.5;
 506     traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, raptor);
 507     UpdateAuxiliaryXhair(player, trace_endpos, '0 1 0', 0);
 508     */
 509
 510     if(player.BUTTON_ATCK)
 511     if(raptor.attack_finished_single <= time)
 512     if(raptor.vehicle_energy > autocvar_g_vehicle_raptor_cannon_cost)
 513     {
 514         raptor.misc_bulletcounter += 1;
 515         raptor.attack_finished_single = time + autocvar_g_vehicle_raptor_cannon_refire;
 516         if(raptor.misc_bulletcounter <= 2)
 517             raptor_fire_cannon(self.gun1, "fire1");
 518         else if(raptor.misc_bulletcounter == 3)
 519             raptor_fire_cannon(self.gun2, "fire1");
 520         else
 521         {
 522             raptor.attack_finished_single = time + autocvar_g_vehicle_raptor_cannon_refire * 2;
 523             raptor_fire_cannon(self.gun2, "fire1");
 524             raptor.misc_bulletcounter = 0;
 525         }
 526         raptor.vehicle_energy -= autocvar_g_vehicle_raptor_cannon_cost;
 527         self.cnt = time;
 528     }
 529
 530     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 531         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime);
 532
 533     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 534         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime);
 535
 536     if(self.vehicle_flags  & VHF_ENERGYREGEN)
 537         vehicles_regen(cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime);
 538
 539
 540     if(time > raptor.delay)
 541     if(player.BUTTON_ATCK2)
 542     {
 543         raptor_bombdrop();
 544         raptor.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 545         raptor.lip   = time;
 546     }
 547
 548     raptor.bomb1.alpha = raptor.bomb2.alpha = (time - raptor.lip) / (raptor.delay - raptor.lip);
 549     player.vehicle_reload2 = bound(0, raptor.bomb1.alpha * 100, 100);
 550
 551     VEHICLE_UPDATE_PLAYER(health, raptor);
 552     VEHICLE_UPDATE_PLAYER(energy, raptor);
 553     if(self.vehicle_flags & VHF_HASSHIELD)
 554         VEHICLE_UPDATE_PLAYER(shield, raptor);
 555
 556     player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 557     return 1;
 558 }
 559
 560 void raptor_blowup()
 561 {
 562     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 563     pointparticles(particleeffectnum("explosion_big"), self.origin, '0 0 0', 1);
 564
 565     self.deadflag    = DEAD_DEAD;
 566     self.vehicle_exit(VHEF_NORMAL);
 567     RadiusDamage (self, self, 250, 15, 250, world, 250, DEATH_WAKIBLOWUP, world);
 568
 569     self.alpha          = -1;
 570     self.movetype       = MOVETYPE_NONE;
 571     self.effects        = EF_NODRAW;
 572     self.colormod       = '0 0 0';
 573     self.avelocity      = '0 0 0';
 574     self.velocity       = '0 0 0';
 575
 576     setorigin(self, self.pos1);
 577     self.touch = SUB_Null;
 578     self.nextthink = 0;
 579 }
 580
 581 void raptor_diethink()
 582 {
 583     //self.avelocity += '0 0.5 1' * (random() * 5);
 584     //self.avelocity -= '0 0.5 1' * (random() * 5);
 585
 586     if(random() < 0.1)
 587     {
 588         sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 589         pointparticles(particleeffectnum("explosion_small"), randomvec() * 80 + (self.origin + '0 0 100'), '0 0 0', 1);
 590     }
 591     self.nextthink = time + 0.1;
 592 }
 593
 594 void raptor_die()
 595 {
 596     self.health       = 0;
 597     self.event_damage = SUB_Null;
 598     self.iscreature   = FALSE;
 599     self.solid        = SOLID_CORPSE;
 600     self.takedamage   = DAMAGE_NO;
 601     self.deadflag     = DEAD_DYING;
 602     self.movetype     = MOVETYPE_BOUNCE;
 603     self.think        = raptor_diethink;
 604     self.nextthink    = time;
 605
 606     pointparticles(particleeffectnum("explosion_medium"), findbetterlocation (self.origin, 16), '0 0 0', 1);
 607
 608     self.velocity_z += 600;
 609
 610     self.avelocity = '0 0.5 1' * (random() * 400);
 611     self.avelocity -= '0 0.5 1' * (random() * 400);
 612
 613     self.colormod = '-0.5 -0.5 -0.5';
 614         self.touch     = raptor_blowup;
 615 }
 616
 617 void raptor_spawn()
 618 {
 619     self.frame          = 0;
 620     self.vehicle_health = autocvar_g_vehicle_raptor_health;
 621     self.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 622     self.movetype       = MOVETYPE_TOSS;
 623     self.solid          = SOLID_SLIDEBOX;
 624     self.vehicle_energy = 1;
 625
 626     self.bomb1.gun1.avelocity_y = 90;
 627     self.bomb1.gun2.avelocity_y = -90;
 628
 629     setsize(self, RAPTOR_MIN, RAPTOR_MAX );
 630     self.delay = time;
 631 }
 632
 633 // If we dont do this ever now and then, the raptors rotors
 634 // stop working, presumably due to angle overflow. cute.
 635 void raptor_rotor_anglefix()
 636 {
 637     self.gun1.angles_y = anglemods(self.gun1.angles_y);
 638     self.gun2.angles_y = anglemods(self.gun2.angles_y);
 639     self.nextthink = time + 15;
 640 }
 641
 642 void raptor_dinit()
 643 {
 644     entity spinner;
 645     vector ofs;
 646
 647     if not (vehicle_initialize(
 648              "Raptor",
 649              "models/vehicles/raptor.dpm",
 650              "",
 651              "models/vehicles/raptor_cockpit.dpm",
 652              "", "tag_hud", "tag_camera",
 653              HUD_RAPTOR,
 654              RAPTOR_MIN, RAPTOR_MAX,
 655              FALSE,
 656              raptor_spawn, autocvar_g_vehicle_raptor_respawntime,
 657              raptor_frame,
 658              raptor_enter, raptor_exit,
 659              raptor_die,   raptor_think,
 660              FALSE))
 661     {
 662         remove(self);
 663         return;
 664     }
 665
 666     //FIXME: Camera is in a bad place in HUD model.
 667     //setorigin(self.vehicle_viewport, '25 0 5');
 668
 669     self.frame = 0;
 670
 671     self.bomb1 = spawn();
 672     self.bomb2 = spawn();
 673     self.gun1  = spawn();
 674     self.gun2  = spawn();
 675
 676     setmodel(self.bomb1,"models/vehicles/clusterbomb_folded.md3");
 677     setmodel(self.bomb2,"models/vehicles/clusterbomb_folded.md3");
 678     setmodel(self.gun1, "models/vehicles/raptor_gun.dpm");
 679     setmodel(self.gun2, "models/vehicles/raptor_gun.dpm");
 680     setmodel(self.tur_head, "models/vehicles/raptor_body.dpm");
 681
 682     setattachment(self.bomb1, self,"bombmount_left");
 683     setattachment(self.bomb2, self,"bombmount_right");
 684     setattachment(self.tur_head, self,"root");
 685
 686
 687     // FIXME Guns mounts to angled bones
 688     self.bomb1.angles = self.angles;
 689     self.angles = '0 0 0';
 690     // This messes up gun-aim, so work arround it.
 691     //setattachment(self.gun1, self, "gunmount_left");
 692     ofs = gettaginfo(self, gettagindex(self, "gunmount_left"));
 693     ofs -= self.origin;
 694     setattachment(self.gun1, self, "");
 695     setorigin(self.gun1, ofs);
 696
 697     //setattachment(self.gun2, self, "gunmount_right");
 698     ofs = gettaginfo(self, gettagindex(self, "gunmount_right"));
 699     ofs -= self.origin;
 700     setattachment(self.gun2, self, "");
 701     setorigin(self.gun2, ofs);
 702
 703     self.angles = self.bomb1.angles;
 704     self.bomb1.angles = '0 0 0';
 705
 706     spinner = spawn();
 707     spinner.owner = self;
 708     setmodel(spinner,"models/vehicles/spinner.dpm");
 709     setattachment(spinner, self, "engine_left");
 710     spinner.movetype = MOVETYPE_NOCLIP;
 711     spinner.avelocity = '0 90 0';
 712     self.bomb1.gun1 = spinner;
 713
 714     spinner = spawn();
 715     spinner.owner = self;
 716     setmodel(spinner,"models/vehicles/spinner.dpm");
 717     setattachment(spinner, self, "engine_right");
 718     spinner.movetype = MOVETYPE_NOCLIP;
 719     spinner.avelocity = '0 -90 0';
 720     self.bomb1.gun2 = spinner;
 721
 722     // Sigh.
 723     self.bomb1.think = raptor_rotor_anglefix;
 724     self.bomb1.nextthink = time;
 725
 726     self.mass               = 1 ;
 727 }
 728
 729 void spawnfunc_vehicle_raptor()
 730 {
 731     vehicles_configcheck("vehicle_raptor.cfg", autocvar_g_vehicle_raptor_health);
 732
 733     self.vehicle_flags |= VHF_DMGSHAKE;
 734     self.vehicle_flags |= VHF_DMGROLL;
 735
 736     if(autocvar_g_vehicle_raptor_shield)
 737         self.vehicle_flags |= VHF_HASSHIELD;
 738
 739     if(autocvar_g_vehicle_raptor_shield_regen)
 740         self.vehicle_flags |= VHF_SHIELDREGEN;
 741
 742     if(autocvar_g_vehicle_raptor_health_regen)
 743         self.vehicle_flags |= VHF_HEALTHREGEN;
 744
 745     if(autocvar_g_vehicle_raptor_energy_regen)
 746         self.vehicle_flags |= VHF_ENERGYREGEN;
 747
 748     precache_model ("models/vehicles/raptor.dpm");
 749     precache_model ("models/vehicles/raptor_gun.dpm");
 750     precache_model ("models/vehicles/spinner.dpm");
 751     precache_model ("models/vehicles/raptor_cockpit.dpm");
 752     precache_model ("models/vehicles/clusterbomb.md3");
 753     precache_model ("models/vehicles/clusterbomb_folded.md3");
 754     precache_model ("models/vehicles/raptor_body.dpm");
 755
 756     precache_sound ("vehicles/raptor_fly.wav");
 757     precache_sound ("vehicles/raptor_speed.wav");
 758     precache_sound ("");
 759
 760     self.think = raptor_dinit;
 761     self.nextthink = time + (autocvar_g_vehicles_delayspawn ? autocvar_g_vehicle_raptor_respawntime + (random() * autocvar_g_vehicles_delayspawn_jitter) : 0.5);
 762 }
 763 #endif // SVQC