qcsrc/server/vehicles/raptor.qc

   1 #define RAPTOR_MIN '-80 -80 0'
   2 #define RAPTOR_MAX '80 80 70'
   3
   4 float autocvar_g_vehicle_raptor_respawntime;
   5
   6 float autocvar_g_vehicle_raptor_movestyle;
   7 float autocvar_g_vehicle_raptor_turnspeed;
   8 float autocvar_g_vehicle_raptor_pitchspeed;
   9 float autocvar_g_vehicle_raptor_pitchlimit;
  10
  11 float autocvar_g_vehicle_raptor_speed_forward;
  12 float autocvar_g_vehicle_raptor_speed_strafe;
  13 float autocvar_g_vehicle_raptor_speed_up;
  14 float autocvar_g_vehicle_raptor_speed_down;
  15 float autocvar_g_vehicle_raptor_friction;
  16
  17 float autocvar_g_vehicle_raptor_bomblets;
  18 float autocvar_g_vehicle_raptor_bomblet_alt;
  19 float autocvar_g_vehicle_raptor_bomblet_time;
  20 float autocvar_g_vehicle_raptor_bomblet_damage;
  21 float autocvar_g_vehicle_raptor_bomblet_spread;
  22 float autocvar_g_vehicle_raptor_bomblet_edgedamage;
  23 float autocvar_g_vehicle_raptor_bomblet_radius;
  24 float autocvar_g_vehicle_raptor_bomblet_force;
  25 float autocvar_g_vehicle_raptor_bomblet_explode_delay;
  26 float autocvar_g_vehicle_raptor_bombs_refire;
  27
  28 float autocvar_g_vehicle_raptor_cannon_turnspeed;
  29 float autocvar_g_vehicle_raptor_cannon_turnlimit;
  30 float autocvar_g_vehicle_raptor_cannon_pitchlimit_up;
  31 float autocvar_g_vehicle_raptor_cannon_pitchlimit_down;
  32
  33 float autocvar_g_vehicle_raptor_cannon_locktarget;
  34 float autocvar_g_vehicle_raptor_cannon_locking_time;
  35 float autocvar_g_vehicle_raptor_cannon_locking_releasetime;
  36 float autocvar_g_vehicle_raptor_cannon_locked_time;
  37 float autocvar_g_vehicle_raptor_cannon_predicttarget;
  38
  39 float autocvar_g_vehicle_raptor_cannon_cost;
  40 float autocvar_g_vehicle_raptor_cannon_damage;
  41 float autocvar_g_vehicle_raptor_cannon_radius;
  42 float autocvar_g_vehicle_raptor_cannon_refire;
  43 float autocvar_g_vehicle_raptor_cannon_speed;
  44 float autocvar_g_vehicle_raptor_cannon_spread;
  45 float autocvar_g_vehicle_raptor_cannon_force;
  46
  47 float autocvar_g_vehicle_raptor_energy;
  48 float autocvar_g_vehicle_raptor_energy_regen;
  49 float autocvar_g_vehicle_raptor_energy_regen_pause;
  50
  51 float autocvar_g_vehicle_raptor_health;
  52 float autocvar_g_vehicle_raptor_health_regen;
  53 float autocvar_g_vehicle_raptor_health_regen_pause;
  54
  55 float autocvar_g_vehicle_raptor_shield;
  56 float autocvar_g_vehicle_raptor_shield_regen;
  57 float autocvar_g_vehicle_raptor_shield_regen_pause;
  58
  59 void raptor_spawn();
  60 float raptor_frame();
  61 float raptor_takeoff();
  62
  63 .entity bomb1;
  64 .entity bomb2;
  65
  66 //#define RAPTOR_RETARDCAMERA
  67
  68 float raptor_altitude(float amax)
  69 {
  70         tracebox(self.origin, self.mins, self.maxs, self.origin - ('0 0 1' * amax), TRUE, self);
  71     return vlen(self.origin - trace_endpos);
  72 }
  73
  74
  75 void raptor_bomblet_boom()
  76 {
  77     RadiusDamage (self, self.realowner, autocvar_g_vehicle_raptor_bomblet_damage,
  78                                     autocvar_g_vehicle_raptor_bomblet_edgedamage,
  79                                     autocvar_g_vehicle_raptor_bomblet_radius, world,
  80                                     autocvar_g_vehicle_raptor_bomblet_force, DEATH_RAPTOR_BOMB, world);
  81     remove(self);
  82 }
  83
  84 void raptor_bomblet_touch()
  85 {
  86     if(other == self.owner)
  87         return;
  88
  89     PROJECTILE_TOUCH;
  90     self.think = raptor_bomblet_boom;
  91     self.nextthink = time + random() * autocvar_g_vehicle_raptor_bomblet_explode_delay;
  92 }
  93
  94 void raptor_bomb_burst()
  95 {
  96     if(self.cnt > time)
  97     if(autocvar_g_vehicle_raptor_bomblet_alt)
  98     {
  99         self.nextthink = time;
 100         traceline(self.origin, self.origin + (normalize(self.velocity) * autocvar_g_vehicle_raptor_bomblet_alt), MOVE_NORMAL, self);
 101         if((trace_fraction == 1.0) || (vlen(self.origin - self.owner.origin) < autocvar_g_vehicle_raptor_bomblet_radius))
 102         {
 103             UpdateCSQCProjectile(self);
 104             return;
 105         }
 106     }
 107
 108     entity bomblet;
 109     float i;
 110
 111     //sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 112     //pointparticles(particleeffectnum("raptor_bomb_spread"), self.origin, self.velocity, 1);
 113
 114     Damage_DamageInfo(self.origin, 0, 0, 0, '0 0 0', DEATH_RAPTOR_BOMB_SPLIT, self);
 115
 116     for(i = 0; i < autocvar_g_vehicle_raptor_bomblets; ++i)
 117     {
 118         bomblet = spawn();
 119         setorigin(bomblet, self.origin);
 120
 121         bomblet.movetype    = MOVETYPE_TOSS;
 122         bomblet.touch       = raptor_bomblet_touch;
 123         bomblet.think       = raptor_bomblet_boom;
 124         bomblet.nextthink   = time + 5;
 125         bomblet.owner       = self.owner;
 126         bomblet.realowner   = self.realowner;
 127         bomblet.velocity    = normalize(normalize(self.velocity) + (randomvec() * autocvar_g_vehicle_raptor_bomblet_spread)) * vlen(self.velocity);
 128
 129         PROJECTILE_MAKETRIGGER(bomblet);
 130         CSQCProjectile(bomblet, TRUE, PROJECTILE_RAPTORBOMBLET, TRUE);
 131     }
 132
 133     remove(self);
 134 }
 135
 136 void raptor_bomb_touch()
 137 {
 138     raptor_bomb_burst();
 139 }
 140
 141 void raptor_bombdrop()
 142 {
 143     entity bomb_1, bomb_2;
 144
 145     //self.bomb1.alpha = 0;
 146     //self.bomb2.alpha = 0;
 147
 148     bomb_1 = spawn();
 149     bomb_2 = spawn();
 150
 151     setorigin(bomb_1, gettaginfo(self, gettagindex(self, "bombmount_left")));
 152     setorigin(bomb_2, gettaginfo(self, gettagindex(self, "bombmount_right")));
 153
 154     bomb_1.movetype     = bomb_2.movetype   = MOVETYPE_BOUNCE;
 155     bomb_1.velocity     = bomb_2.velocity   = self.velocity;
 156     bomb_1.touch        = bomb_2.touch      = raptor_bomb_touch;
 157     bomb_1.think        = bomb_2.think      = raptor_bomb_burst;
 158     bomb_1.cnt          = bomb_2.cnt        = time + 10;
 159
 160     if(autocvar_g_vehicle_raptor_bomblet_alt)
 161         bomb_1.nextthink = bomb_2.nextthink  = time;
 162     else
 163         bomb_1.nextthink = bomb_2.nextthink  = time + autocvar_g_vehicle_raptor_bomblet_time;
 164
 165     bomb_1.owner     = bomb_2.owner      = self;
 166     bomb_1.realowner = bomb_2.realowner  = self.owner;
 167     bomb_1.solid     = bomb_2.solid      = SOLID_BBOX;
 168     bomb_1.gravity   = bomb_2.gravity    = 1;
 169
 170     PROJECTILE_MAKETRIGGER(bomb_1);
 171     PROJECTILE_MAKETRIGGER(bomb_2);
 172
 173     CSQCProjectile(bomb_1, TRUE, PROJECTILE_RAPTORBOMB, TRUE);
 174     CSQCProjectile(bomb_2, TRUE, PROJECTILE_RAPTORBOMB, TRUE);
 175
 176 }
 177
 178
 179 void raptor_fire_cannon(entity gun, string tagname)
 180 {
 181     entity bolt;
 182     vector b_org;
 183     b_org = gettaginfo(gun, gettagindex(gun, tagname));
 184     bolt = vehicles_projectile("raptor_cannon_muzzleflash", "weapons/lasergun_fire.wav",
 185                            b_org, normalize(v_forward + randomvec() * autocvar_g_vehicle_raptor_cannon_spread) * autocvar_g_vehicle_raptor_cannon_speed,
 186                            autocvar_g_vehicle_raptor_cannon_damage, autocvar_g_vehicle_raptor_cannon_radius, autocvar_g_vehicle_raptor_cannon_force,  0,
 187                            DEATH_RAPTOR_CANNON, PROJECTILE_RAPTORCANNON, 0, TRUE, TRUE);
 188 }
 189
 190 void raptor_think()
 191 {
 192 }
 193
 194 void raptor_enter()
 195 {
 196     self.owner.PlayerPhysplug = raptor_takeoff;
 197     self.movetype       = MOVETYPE_FLY;
 198     self.solid          = SOLID_BBOX;
 199     self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_raptor_health);
 200     self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_raptor_shield);
 201     self.velocity_z = 1; // Nudge upwards to takeoff sequense can work.
 202     self.tur_head.exteriormodeltoclient = self.owner;
 203
 204 #ifdef RAPTOR_RETARDCAMERA
 205     setorigin(self.vehicle_viewport, self.origin);
 206 #endif
 207 }
 208
 209 void raptor_land()
 210 {
 211     float hgt;
 212
 213     hgt = raptor_altitude(512);
 214     self.velocity = (self.velocity * 0.9) + ('0 0 -1800' * (hgt / 256) * sys_frametime);
 215     self.angles_x *= 0.95;
 216     self.angles_z *= 0.95;
 217
 218     if(hgt < 128)
 219         if(self.frame != 0)
 220             self.frame = max(self.frame - 0.25, 0);
 221
 222     self.bomb1.gun1.avelocity_y = 90 + ((self.frame / 25) * 2000);
 223     self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 224
 225     if(hgt < 16)
 226     {
 227         self.movetype   = MOVETYPE_TOSS;
 228         self.think      = raptor_think;
 229     }
 230
 231     self.nextthink  = time;
 232 }
 233
 234 void raptor_exit(float eject)
 235 {
 236     self.tur_head.exteriormodeltoclient = world;
 237
 238     if(self.deadflag == DEAD_NO)
 239     {
 240         self.think      = raptor_land;
 241         self.nextthink  = time;
 242     }
 243
 244     if not (self.owner)
 245         return;
 246
 247         makevectors(self.angles);
 248         if(eject)
 249         {
 250             setorigin(self.owner,self.origin + v_forward * 100 + '0 0 64');
 251             self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 252         }
 253         else
 254         setorigin(self.owner,self.origin - v_forward * 200 + '0 0 64');
 255
 256     self.owner = world;
 257 }
 258
 259 float raptor_takeoff()
 260 {
 261     entity player, raptor;
 262
 263     player = self;
 264     raptor = self.vehicle;
 265     self   = raptor;
 266
 267     // Takeoff sequense
 268     if(raptor.frame < 25)
 269     {
 270         raptor.frame += 0.25;
 271         raptor.velocity_z = min(raptor.velocity_z * 1.5, 256);
 272         self.bomb1.gun1.avelocity_y = 90 + ((raptor.frame / 25) * 25000);
 273         self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 274         player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 275
 276         setorigin(player, raptor.origin + '0 0 32');
 277     }
 278     else
 279         player.PlayerPhysplug = raptor_frame;
 280
 281     player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 282     self = player;
 283     return 1;
 284 }
 285
 286 float raptor_frame()
 287 {
 288     entity player, raptor;
 289     float ftmp, ftmp2;
 290     vector df;
 291
 292     player = self;
 293     raptor = self.vehicle;
 294     self   = raptor;
 295
 296     if(player.BUTTON_USE && raptor.deadflag == DEAD_NO)
 297     {
 298         self = raptor;
 299         vehicles_exit(VHEF_NORMAL);
 300         self = player;
 301         return 0;
 302     }
 303
 304     if(raptor.deadflag != DEAD_NO)
 305     {
 306         self = player;
 307         player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 308         return 1;
 309     }
 310
 311     crosshair_trace(player);
 312
 313 #if VEHICLES_VIEWROTATE_CROSSHAIR
 314     df = vectoangles(normalize(trace_endpos - self.origin + '0 0 32'));
 315     if(df_x > 180)  df_x -= 360;
 316     if(df_x < -180) df_x += 360;
 317     if(df_y > 180)  df_y -= 360;
 318     if(df_y < -180) df_y += 360;
 319
 320     // Rotate Body
 321     ftmp = autocvar_g_vehicle_raptor_turnspeed * sys_frametime;
 322     ftmp = bound(-ftmp, shortangle_f(df_y - raptor.angles_y, raptor.angles_y), ftmp);
 323
 324     // Turn
 325     //raptor.angles_y = anglemods(raptor.angles_y + ftmp);
 326     raptor.avelocity_y = anglemods(raptor.angles_y + ftmp);
 327
 328     // Pitch Body
 329     ftmp = autocvar_g_vehicle_raptor_pitchspeed  * sys_frametime;
 330     ftmp = bound(-ftmp, shortangle_f(df_x - raptor.angles_x, raptor.angles_x), ftmp);
 331
 332     //raptor.angles_x = bound(-autocvar_g_vehicle_raptor_pitchlimit, anglemods(raptor.angles_x + ftmp), autocvar_g_vehicle_raptor_pitchlimit);
 333     raptor.avelocity_x = bound(-autocvar_g_vehicle_raptor_pitchlimit, anglemods(raptor.angles_x + ftmp), autocvar_g_vehicle_raptor_pitchlimit);
 334 #else
 335     vector vang;
 336     vang = raptor.angles;
 337     df = vectoangles(normalize(trace_endpos - self.origin + '0 0 32'));
 338     vang_x *= -1;
 339     df_x *= -1;
 340     if(df_x > 180)  df_x -= 360;
 341     if(df_x < -180) df_x += 360;
 342     if(df_y > 180)  df_y -= 360;
 343     if(df_y < -180) df_y += 360;
 344
 345     ftmp = shortangle_f(player.v_angle_y - vang_y, vang_y);
 346     if(ftmp > 180)  ftmp -= 360; if(ftmp < -180) ftmp += 360;
 347     raptor.avelocity_y = bound(-autocvar_g_vehicle_raptor_turnspeed, ftmp + raptor.avelocity_y * 0.9, autocvar_g_vehicle_raptor_turnspeed);
 348
 349     // Pitch
 350     ftmp = 0;
 351     if(player.movement_x > 0 && vang_x < autocvar_g_vehicle_raptor_pitchlimit) ftmp = 5;
 352     else if(player.movement_x < 0 && vang_x > -autocvar_g_vehicle_raptor_pitchlimit) ftmp = -20;
 353
 354     df_x = bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x , autocvar_g_vehicle_raptor_pitchlimit);
 355     ftmp = vang_x - bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x + ftmp, autocvar_g_vehicle_raptor_pitchlimit);
 356     raptor.avelocity_x = bound(-autocvar_g_vehicle_raptor_pitchspeed, ftmp + raptor.avelocity_x * 0.9, autocvar_g_vehicle_raptor_pitchspeed);
 357
 358     raptor.angles_x = anglemods(raptor.angles_x);
 359     raptor.angles_y = anglemods(raptor.angles_y);
 360     raptor.angles_z = anglemods(raptor.angles_z);
 361
 362 #endif
 363
 364     if(autocvar_g_vehicle_raptor_movestyle == 1)
 365         makevectors('0 1 0' * raptor.angles_y);
 366     else
 367         makevectors(player.v_angle);
 368
 369 #ifdef RAPTOR_RETARDCAMERA
 370     float spd, back, up;
 371     spd = vlen(self.velocity) + 0.01;
 372     back = spd / autocvar_g_vehicle_raptor_speed_forward;
 373     up = 1 - back;
 374     back = back;
 375     back = back * 1250;
 376     back += 150;
 377     up = up * 200;
 378     up = up + 100;
 379
 380     setorigin(self.vehicle_viewport, self.origin + (v_up * up) + (v_forward * -back));
 381 #endif
 382
 383     df = raptor.velocity * -autocvar_g_vehicle_raptor_friction;
 384
 385     if(player.movement_x != 0)
 386     {
 387         if(player.movement_x > 0)
 388             df += v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 389         else if(player.movement_x < 0)
 390             df -= v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 391     }
 392
 393     if(player.movement_y != 0)
 394     {
 395         if(player.movement_y < 0)
 396             df -= v_right * autocvar_g_vehicle_raptor_speed_strafe;
 397         else if(player.movement_y > 0)
 398             df += v_right * autocvar_g_vehicle_raptor_speed_strafe;
 399
 400         raptor.angles_z = bound(-30,raptor.angles_z + (player.movement_y / autocvar_g_vehicle_raptor_speed_strafe),30);
 401     }
 402     else
 403     {
 404         raptor.angles_z *= 0.95;
 405         if(raptor.angles_z >= -1 && raptor.angles_z <= -1)
 406             raptor.angles_z = 0;
 407     }
 408
 409     if(player.BUTTON_CROUCH)
 410         df -=   v_up * autocvar_g_vehicle_raptor_speed_down;
 411     else if (player.BUTTON_JUMP)
 412         df +=  v_up * autocvar_g_vehicle_raptor_speed_up;
 413
 414     raptor.velocity  += df * frametime;
 415     player.velocity = player.movement  = raptor.velocity;
 416     setorigin(player,raptor.origin + '0 0 32');
 417
 418     vector vf, ad;
 419     // Target lock & predict
 420     if(autocvar_g_vehicle_raptor_cannon_locktarget)
 421     {
 422
 423         vehicles_locktarget((1 / autocvar_g_vehicle_raptor_cannon_locking_time) * frametime,
 424                              (1 / autocvar_g_vehicle_raptor_cannon_locking_releasetime) * frametime,
 425                              autocvar_g_vehicle_raptor_cannon_locked_time);
 426
 427         if(self.lock_target != world)
 428         if(autocvar_g_vehicle_raptor_cannon_predicttarget)
 429         if(self.lock_strength == 1)
 430         {
 431             float i, distance, impact_time;
 432
 433             vf = real_origin(raptor.lock_target);
 434             ad = vf;
 435             for(i = 0; i < 4; ++i)
 436             {
 437                 distance = vlen(ad - raptor.origin);
 438                 impact_time = distance / autocvar_g_vehicle_raptor_cannon_speed;
 439                 ad = vf + raptor.lock_target.velocity * impact_time;
 440             }
 441             trace_endpos = ad;
 442             //UpdateAuxiliaryXhair(player, trace_endpos, '1 1 1', 0);
 443         }
 444
 445         if(self.lock_target)
 446         {
 447             if(raptor.lock_strength == 1)
 448                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '1 0 0', 1);
 449             else if(self.lock_strength > 0.5)
 450                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '0 1 0', 1);
 451             else if(self.lock_strength < 0.5)
 452                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '0 0 1', 1);
 453         }
 454     }
 455
 456     // Aim the gunz
 457     ftmp2 = autocvar_g_vehicle_raptor_cannon_turnspeed * frametime;
 458     ftmp = -ftmp2;
 459
 460     // Gun1
 461     df = gettaginfo(raptor.gun1, gettagindex(raptor.gun1, "fire1"));
 462     //ad = df;
 463     //vf = v_forward;
 464     df = vectoangles(normalize(trace_endpos - df)); // Find the direction & angle
 465     df = shortangle_vxy(df - (raptor.angles + raptor.gun1.angles), raptor.angles + raptor.gun1.angles);     // Find aim offset
 466     // Bind to aimspeed
 467     df_x = bound(ftmp, df_x, ftmp2);
 468     df_y = bound(ftmp, df_y, ftmp2);
 469     // Bind to limts
 470     raptor.gun1.angles_x = bound(-autocvar_g_vehicle_raptor_cannon_pitchlimit_down, df_x + raptor.gun1.angles_x, autocvar_g_vehicle_raptor_cannon_pitchlimit_up);
 471     raptor.gun1.angles_y = bound(-autocvar_g_vehicle_raptor_cannon_turnlimit,  df_y + raptor.gun1.angles_y, autocvar_g_vehicle_raptor_cannon_turnlimit);
 472
 473     //df = vectoangles(normalize(trace_endpos - df));
 474
 475     //Gun 2
 476     df = gettaginfo(raptor.gun2, gettagindex(raptor.gun2, "fire1"));
 477     //ad += df;
 478     //vf += v_forward;
 479     df = vectoangles(normalize(trace_endpos - df)); // Find the direction & angle
 480     df = shortangle_vxy(df - (raptor.angles + raptor.gun2.angles), raptor.angles + raptor.gun2.angles);     // Find aim offset
 481     // Bind to aimspeed
 482     df_x = bound(ftmp, df_x, ftmp2);
 483     df_y = bound(ftmp, df_y, ftmp2);
 484     // Bind to limts
 485     raptor.gun2.angles_x = bound(-autocvar_g_vehicle_raptor_cannon_pitchlimit_down, df_x + raptor.gun2.angles_x, autocvar_g_vehicle_raptor_cannon_pitchlimit_up);
 486     raptor.gun2.angles_y = bound(-autocvar_g_vehicle_raptor_cannon_turnlimit,  df_y + raptor.gun2.angles_y, autocvar_g_vehicle_raptor_cannon_turnlimit);
 487
 488     /*
 489     ad = ad * 0.5;
 490     v_forward = vf * 0.5;
 491     traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, raptor);
 492     UpdateAuxiliaryXhair(player, trace_endpos, '0 1 0', 0);
 493     */
 494
 495     if(player.BUTTON_ATCK)
 496     if(raptor.attack_finished_single <= time)
 497     if(raptor.vehicle_energy > autocvar_g_vehicle_raptor_cannon_cost)
 498     {
 499         raptor.misc_bulletcounter += 1;
 500         raptor.attack_finished_single = time + autocvar_g_vehicle_raptor_cannon_refire;
 501         if(raptor.misc_bulletcounter <= 2)
 502             raptor_fire_cannon(self.gun1, "fire1");
 503         else if(raptor.misc_bulletcounter == 3)
 504             raptor_fire_cannon(self.gun2, "fire1");
 505         else
 506         {
 507             raptor.attack_finished_single = time + autocvar_g_vehicle_raptor_cannon_refire * 2;
 508             raptor_fire_cannon(self.gun2, "fire1");
 509             raptor.misc_bulletcounter = 0;
 510         }
 511         raptor.vehicle_energy -= autocvar_g_vehicle_raptor_cannon_cost;
 512         self.cnt = time;
 513     }
 514
 515     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 516         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime);
 517
 518     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 519         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime);
 520
 521     if(self.vehicle_flags  & VHF_ENERGYREGEN)
 522         vehicles_regen(cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime);
 523
 524
 525     if(time > raptor.delay)
 526     if(player.BUTTON_ATCK2)
 527     {
 528         raptor_bombdrop();
 529         raptor.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 530         raptor.lip   = time;
 531     }
 532
 533     raptor.bomb1.alpha = raptor.bomb2.alpha = (time - raptor.lip) / (raptor.delay - raptor.lip);
 534     player.vehicle_reload2 = bound(0, raptor.bomb1.alpha * 100, 100);
 535
 536     VEHICLE_UPDATE_PLAYER(health, raptor);
 537     VEHICLE_UPDATE_PLAYER(energy, raptor);
 538     if(self.vehicle_flags & VHF_HASSHIELD)
 539         VEHICLE_UPDATE_PLAYER(shield, raptor);
 540
 541
 542
 543     player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 544     return 1;
 545 }
 546
 547 void raptor_blowup()
 548 {
 549     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 550     pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 551
 552     self.deadflag    = DEAD_DEAD;
 553     self.vehicle_exit(VHEF_NORMAL);
 554     RadiusDamage (self, self, 250, 15, 250, world, 250, DEATH_WAKIBLOWUP, world);
 555
 556     self.alpha          = -1;
 557     self.movetype       = MOVETYPE_NONE;
 558     self.effects        = EF_NODRAW;
 559     self.colormod       = '0 0 0';
 560     self.avelocity      = '0 0 0';
 561     self.velocity       = '0 0 0';
 562
 563     setorigin(self, self.pos1);
 564     self.touch = SUB_Null;
 565 }
 566
 567 void raptor_die()
 568 {
 569     self.health       = 0;
 570     self.event_damage = SUB_Null;
 571     self.iscreature   = FALSE;
 572     self.solid        = SOLID_CORPSE;
 573     self.takedamage   = DAMAGE_NO;
 574     self.deadflag     = DEAD_DYING;
 575     self.movetype     = MOVETYPE_BOUNCE;
 576
 577     pointparticles(particleeffectnum("rocket_explode"), findbetterlocation (self.origin, 16), '0 0 0', 1);
 578
 579     self.velocity_z += 128;
 580
 581     if(random() < 0.5)
 582         self.avelocity_z  = 45 + random() * 270;
 583     else
 584         self.avelocity_z  = -45 + random() * -270;
 585
 586     self.colormod = '-0.5 -0.5 -0.5';
 587         self.touch     = raptor_blowup;
 588 }
 589
 590 void raptor_spawn()
 591 {
 592     self.frame          = 0;
 593     self.vehicle_health = autocvar_g_vehicle_raptor_health;
 594     self.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 595     self.movetype       = MOVETYPE_TOSS;
 596     self.solid          = SOLID_BBOX;
 597     self.vehicle_energy = 1;
 598
 599     self.bomb1.gun1.avelocity_y = 90;
 600     self.bomb1.gun2.avelocity_y = -90;
 601
 602     setsize(self, RAPTOR_MIN, RAPTOR_MAX );
 603     self.delay = time;
 604 }
 605
 606 // If we dont do this ever now and then, the raptors rotors
 607 // stop working, presumably due to angle overflow. cute.
 608 void raptor_rotor_anglefix()
 609 {
 610     self.gun1.angles_y = anglemods(self.gun1.angles_y);
 611     self.gun2.angles_y = anglemods(self.gun2.angles_y);
 612     self.nextthink = time + 15;
 613 }
 614
 615 void raptor_dinit()
 616 {
 617     entity spinner;
 618     vector ofs;
 619
 620     if not (vehicle_initialize(
 621              "Raptor",
 622              "models/vehicles/raptor.dpm",
 623              "",
 624              "models/vehicles/raptor_cockpit.dpm",
 625              "", "tag_hud", "tag_camera",
 626              HUD_RAPTOR,
 627              RAPTOR_MIN, RAPTOR_MAX,
 628              FALSE,
 629              raptor_spawn, autocvar_g_vehicle_raptor_respawntime,
 630              raptor_frame,
 631              raptor_enter, raptor_exit,
 632              raptor_die,   raptor_think,
 633              FALSE))
 634     {
 635         remove(self);
 636         return;
 637     }
 638
 639     //FIXME: Camera is in a bad place in HUD model.
 640     //setorigin(self.vehicle_viewport, '25 0 5');
 641
 642     self.frame = 0;
 643
 644     self.bomb1 = spawn();
 645     self.bomb2 = spawn();
 646     self.gun1  = spawn();
 647     self.gun2  = spawn();
 648
 649 #ifdef RAPTOR_RETARDCAMERA
 650     setattachment(self.vehicle_viewport, world, "");
 651 #endif
 652
 653     setmodel(self.bomb1,"models/vehicles/clusterbomb_folded.md3");
 654     setmodel(self.bomb2,"models/vehicles/clusterbomb_folded.md3");
 655     setmodel(self.gun1, "models/vehicles/raptor_gun.dpm");
 656     setmodel(self.gun2, "models/vehicles/raptor_gun.dpm");
 657     setmodel(self.tur_head, "models/vehicles/raptor_body.dpm");
 658
 659     setattachment(self.bomb1, self,"bombmount_left");
 660     setattachment(self.bomb2, self,"bombmount_right");
 661     setattachment(self.tur_head, self,"root");
 662
 663
 664     // FIXME Guns mounts to angled bones
 665     self.bomb1.angles = self.angles;
 666     self.angles = '0 0 0';
 667     // This messes up gun-aim, so work arround it.
 668     //setattachment(self.gun1, self, "gunmount_left");
 669     ofs = gettaginfo(self, gettagindex(self, "gunmount_left"));
 670     ofs -= self.origin;
 671     setattachment(self.gun1, self, "");
 672     setorigin(self.gun1, ofs);
 673
 674     //setattachment(self.gun2, self, "gunmount_right");
 675     ofs = gettaginfo(self, gettagindex(self, "gunmount_right"));
 676     ofs -= self.origin;
 677     setattachment(self.gun2, self, "");
 678     setorigin(self.gun2, ofs);
 679
 680     self.angles = self.bomb1.angles;
 681     self.bomb1.angles = '0 0 0';
 682
 683     spinner = spawn();
 684     spinner.owner = self;
 685     setmodel(spinner,"models/vehicles/spinner.dpm");
 686     setattachment(spinner, self, "engine_left");
 687     spinner.movetype = MOVETYPE_NOCLIP;
 688     spinner.avelocity = '0 90 0';
 689     self.bomb1.gun1 = spinner;
 690
 691     spinner = spawn();
 692     spinner.owner = self;
 693     setmodel(spinner,"models/vehicles/spinner.dpm");
 694     setattachment(spinner, self, "engine_right");
 695     spinner.movetype = MOVETYPE_NOCLIP;
 696     spinner.avelocity = '0 -90 0';
 697     self.bomb1.gun2 = spinner;
 698
 699     // Sigh.
 700     self.bomb1.think = raptor_rotor_anglefix;
 701     self.bomb1.nextthink = time;
 702
 703     self.mass               = 1 ;
 704 }
 705
 706 void spawnfunc_vehicle_raptor()
 707 {
 708     vehicles_configcheck("vehicle_raptor.cfg", autocvar_g_vehicle_raptor_health);
 709
 710     if(autocvar_g_vehicle_raptor_shield)
 711         self.vehicle_flags |= VHF_HASSHIELD;
 712
 713     if(autocvar_g_vehicle_raptor_shield_regen)
 714         self.vehicle_flags |= VHF_SHIELDREGEN;
 715
 716     if(autocvar_g_vehicle_raptor_health_regen)
 717         self.vehicle_flags |= VHF_HEALTHREGEN;
 718
 719     if(autocvar_g_vehicle_raptor_energy_regen)
 720         self.vehicle_flags |= VHF_ENERGYREGEN;
 721
 722     precache_model ("models/vehicles/raptor.dpm");
 723     precache_model ("models/vehicles/raptor_gun.dpm");
 724     precache_model ("models/vehicles/spinner.dpm");
 725     precache_model ("models/vehicles/raptor_cockpit.dpm");
 726     precache_model ("models/vehicles/clusterbomb.md3");
 727     precache_model ("models/vehicles/clusterbomb_folded.md3");
 728     precache_model ("models/vehicles/raptor_body.dpm");
 729
 730     self.think = raptor_dinit;
 731     self.nextthink = time + 1;
 732 }