qcsrc/server/vehicles/spiderbot.qc

   1 const vector SPIDERBOT_MIN = '-75 -75 10';
   2 const vector SPIDERBOT_MAX  = '75 75 110';
   3
   4 float autocvar_g_vehicle_spiderbot_respawntime;
   5
   6 float autocvar_g_vehicle_spiderbot_crush_dmg;
   7 float autocvar_g_vehicle_spiderbot_crush_force;
   8
   9 float autocvar_g_vehicle_spiderbot_head_pitchlimit_down;
  10 float autocvar_g_vehicle_spiderbot_head_pitchlimit_up;
  11 float autocvar_g_vehicle_spiderbot_head_pitchspeed;
  12 float autocvar_g_vehicle_spiderbot_head_turnlimit;
  13 float autocvar_g_vehicle_spiderbot_head_turnspeed;
  14
  15 //float autocvar_g_vehicle_spiderbot_energy;
  16 //float autocvar_g_vehicle_spiderbot_energy_regen;
  17 //float autocvar_g_vehicle_spiderbot_energy_regen_pause;
  18
  19 float autocvar_g_vehicle_spiderbot_health;
  20 float autocvar_g_vehicle_spiderbot_health_regen;
  21 float autocvar_g_vehicle_spiderbot_health_regen_pause;
  22
  23 float autocvar_g_vehicle_spiderbot_shield;
  24 float autocvar_g_vehicle_spiderbot_shield_regen;
  25 float autocvar_g_vehicle_spiderbot_shield_regen_pause;
  26
  27 float autocvar_g_vehicle_spiderbot_minigun_cooldown;
  28 float autocvar_g_vehicle_spiderbot_minigun_damage;
  29 float autocvar_g_vehicle_spiderbot_minigun_heat;
  30 float autocvar_g_vehicle_spiderbot_minigun_refire;
  31 float autocvar_g_vehicle_spiderbot_minigun_spread;
  32 float autocvar_g_vehicle_spiderbot_movement_inertia;
  33
  34 float autocvar_g_vehicle_spiderbot_rocket_damage;
  35 float autocvar_g_vehicle_spiderbot_rocket_edgedamage;
  36 float autocvar_g_vehicle_spiderbot_rocket_force;
  37 float autocvar_g_vehicle_spiderbot_rocket_health;
  38 float autocvar_g_vehicle_spiderbot_rocket_lifetime;
  39 float autocvar_g_vehicle_spiderbot_rocket_noise;
  40 float autocvar_g_vehicle_spiderbot_rocket_radius;
  41 float autocvar_g_vehicle_spiderbot_rocket_refire;
  42 float autocvar_g_vehicle_spiderbot_rocket_reload;
  43 float autocvar_g_vehicle_spiderbot_rocket_speed;
  44 float autocvar_g_vehicle_spiderbot_rocket_turnrate;
  45
  46 float autocvar_g_vehicle_spiderbot_shield;
  47 float autocvar_g_vehicle_spiderbot_speed_stop;
  48 float autocvar_g_vehicle_spiderbot_speed_strafe;
  49 float autocvar_g_vehicle_spiderbot_speed_walk;
  50 float autocvar_g_vehicle_spiderbot_turnspeed;
  51
  52
  53 float autocvar_g_vehicle_spiderbot_springlength;
  54 float autocvar_g_vehicle_spiderbot_springup;
  55 float autocvar_g_vehicle_spiderbot_springblend;
  56
  57 void spiderbot_exit(float eject);
  58 void spiderbot_enter();
  59 void spiderbot_spawn();
  60
  61 void spiderbot_rocket_explode()
  62 {
  63     vector org2;
  64
  65     if(self.event_damage != SUB_Null)
  66     {
  67         self.event_damage = SUB_Null;
  68         self.think = spiderbot_rocket_explode;
  69         self.nextthink = time;
  70         return;
  71     }
  72
  73     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
  74     org2 = findbetterlocation (self.origin, 16);
  75     pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
  76     w_deathtypestring = "dident escape the rocket barrage";
  77
  78     if(!self.owner)
  79         self.owner = self.realowner;
  80
  81     RadiusDamage (self, self.owner,
  82         autocvar_g_vehicle_spiderbot_rocket_damage,
  83         autocvar_g_vehicle_spiderbot_rocket_edgedamage,
  84         autocvar_g_vehicle_spiderbot_rocket_radius, world,
  85         autocvar_g_vehicle_spiderbot_rocket_force, DEATH_SBROCKET, world);
  86
  87     remove (self);
  88 }
  89
  90 void spiderbot_rocket_touch()
  91 {
  92     if(self.owner)
  93     {
  94         if(other == self.owner.vehicle)
  95             return;
  96
  97         if(other == self.owner.vehicle.tur_head)
  98             return;
  99     }
 100
 101     PROJECTILE_TOUCH;
 102     spiderbot_rocket_explode();
 103 }
 104
 105 void spiderbot_rocket_unguided()
 106 {
 107     vector newdir, olddir;
 108
 109     self.nextthink  = time;
 110
 111
 112     olddir = normalize(self.velocity);
 113     newdir = normalize(self.pos1 - self.origin) + randomvec() * autocvar_g_vehicle_spiderbot_rocket_noise;
 114     self.velocity = normalize(olddir + newdir * autocvar_g_vehicle_spiderbot_rocket_turnrate) * autocvar_g_vehicle_spiderbot_rocket_speed;
 115
 116     UpdateCSQCProjectile(self);
 117
 118     if (self.owner.deadflag != DEAD_NO || self.cnt < time)
 119         spiderbot_rocket_explode();
 120
 121 }
 122
 123 void spiderbot_rocket_guided()
 124 {
 125     vector newdir, olddir;
 126
 127     self.nextthink  = time;
 128
 129     if not (self.owner.vehicle)
 130         self.think = spiderbot_rocket_unguided;
 131
 132     crosshair_trace(self.owner);
 133     olddir = normalize(self.velocity);
 134     newdir = normalize(trace_endpos - self.origin) + randomvec() * autocvar_g_vehicle_spiderbot_rocket_noise;
 135     self.velocity = normalize(olddir + newdir * autocvar_g_vehicle_spiderbot_rocket_turnrate) * autocvar_g_vehicle_spiderbot_rocket_speed;
 136
 137     UpdateCSQCProjectile(self);
 138
 139     if (self.owner.deadflag != DEAD_NO || self.cnt < time)
 140         spiderbot_rocket_explode();
 141 }
 142
 143 void spiderbot_rocket_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 144 {
 145     self.health -= damage;
 146     self.velocity += force;
 147     if(self.health < 1)
 148         spiderbot_rocket_explode();
 149 }
 150
 151 void spiderbot_guide_release()
 152 {
 153     entity rkt;
 154     rkt = findchainentity(owner,self.owner);
 155     if not (rkt)
 156         return;
 157
 158     crosshair_trace(self.owner);
 159     while(rkt)
 160     {
 161         if(rkt.think == spiderbot_rocket_guided)
 162         {
 163             rkt.pos1 = trace_endpos;
 164             rkt.think = spiderbot_rocket_unguided;
 165         }
 166         rkt = rkt.chain;
 167     }
 168 }
 169
 170 void spiderbot_rocket_do()
 171 {
 172     entity rocket;
 173
 174     if (self.owner.BUTTON_ATCK2)
 175     {
 176         if (self.wait == 1)
 177         if (self.tur_head.frame == 9 || self.tur_head.frame == 1)
 178         {
 179             if(self.gun2.cnt < time && self.tur_head.frame == 9)
 180                 self.tur_head.frame = 1;
 181
 182             return;
 183         }
 184         self.wait = 1;
 185     }
 186     else
 187     {
 188         if(self.wait)
 189             spiderbot_guide_release();
 190
 191         self.wait = 0;
 192     }
 193
 194     if(self.gun2.cnt > time)
 195         return;
 196
 197     if (self.tur_head.frame >= 9)
 198         self.tur_head.frame = 1;
 199
 200     if not (self.owner.BUTTON_ATCK2)
 201         return;
 202
 203     sound (self, CHAN_WEAPON, "weapons/rocket_fire.wav", VOL_BASE, ATTN_NORM);
 204     rocket                    = spawn ();
 205     setsize (rocket, '-1 -1 -1', '1 1 1'); // give it some size so it can be shot
 206     setorigin(rocket,gettaginfo(self.tur_head,gettagindex(self.tur_head,"tag_fire")));
 207     te_explosion (rocket.origin);
 208
 209     crosshair_trace(self.owner);
 210
 211     rocket.classname       = "spiderbot_rocket";
 212     rocket.bot_dodge       = TRUE;
 213     rocket.bot_dodgerating = autocvar_g_vehicle_spiderbot_rocket_damage;
 214     rocket.cnt             = time + autocvar_g_vehicle_spiderbot_rocket_lifetime;
 215     rocket.health          = autocvar_g_vehicle_spiderbot_rocket_health;
 216     rocket.takedamage      = DAMAGE_AIM;
 217     rocket.event_damage    = spiderbot_rocket_damage;
 218     rocket.owner           = self.owner;
 219     rocket.nextthink       = time;
 220     rocket.movetype        = MOVETYPE_FLYMISSILE;
 221     rocket.velocity        = normalize(v_forward + (v_up * 0.5) + randomvec() * 0.25) * autocvar_g_vehicle_spiderbot_rocket_speed;
 222     rocket.angles          = vectoangles(rocket.velocity);
 223     rocket.think           = spiderbot_rocket_guided;
 224     rocket.touch           = spiderbot_rocket_touch;
 225     rocket.flags           = FL_PROJECTILE;
 226     rocket.solid           = SOLID_TRIGGER;
 227     rocket.pos1            = trace_endpos;
 228
 229         CSQCProjectile(rocket, FALSE, PROJECTILE_ROCKET, FALSE); // no culling, has fly sound
 230
 231     self.tur_head.frame += 1;
 232     if (self.tur_head.frame == 9)
 233         self.attack_finished_single = autocvar_g_vehicle_spiderbot_rocket_reload;
 234     else
 235         self.attack_finished_single = autocvar_g_vehicle_spiderbot_rocket_refire;
 236
 237     self.gun2.cnt = time + self.attack_finished_single;
 238 }
 239
 240 void spiderbot_minigun_fire(entity gun, float trail)
 241 {
 242     vector v;
 243
 244     v = gettaginfo(gun, gettagindex(gun,"barrels"));
 245     v_forward = normalize(v_forward);
 246     v += v_forward * 50;
 247
 248     fireBullet (v, v_forward, autocvar_g_vehicle_spiderbot_minigun_spread, autocvar_g_vehicle_spiderbot_minigun_damage,
 249         autocvar_g_vehicle_spiderbot_minigun_spread, DEATH_SBMINIGUN, 0);
 250
 251     if(trail)
 252     {
 253         sound (gun, CHAN_WEAPON, "weapons/uzi_fire.wav", VOL_BASE, ATTN_NORM);
 254         trailparticles(self, particleeffectnum("spiderbot_minigun_trail"), v, trace_endpos);
 255         pointparticles(particleeffectnum("spiderbot_minigun_muzzleflash"), v, v_forward * 2500, 1);
 256         pointparticles(particleeffectnum("spiderbot_minigun_impact"), trace_endpos, trace_plane_normal * 2500,1);
 257     }
 258 }
 259
 260 void spiderbot_miniguns_do()
 261 {
 262     float ftmp;
 263
 264     if((self.vehicle_reload1 == 1) || (!self.owner.BUTTON_ATCK))
 265     {
 266         ftmp = 1 / autocvar_g_vehicle_spiderbot_minigun_cooldown * sys_frametime;
 267         self.owner.vehicle_reload1 = max(self.owner.vehicle_reload1 - ftmp, 0);
 268         if(self.owner.vehicle_reload1 <= 0)
 269             self.vehicle_reload1 = 0;
 270
 271         return;
 272     }
 273
 274     if (self.owner.BUTTON_ATCK)
 275     {
 276
 277         // Animate miniguns
 278         self.gun1.angles_z += (1440 * sys_frametime);
 279         self.gun2.angles_z -= (1440 * sys_frametime);
 280         if(self.gun1.angles_z >= 360)
 281         {
 282             self.gun1.angles_z = 0;
 283             self.gun2.angles_z = 360;
 284         }
 285
 286         if (self.tur_head.attack_finished_single < time)
 287         {
 288             // Fire bullets, alternating trails left<->right
 289             self = self.owner;
 290             if(self.misc_bulletcounter == 1)
 291             {
 292                 spiderbot_minigun_fire(self.vehicle.gun1, 0);
 293                 spiderbot_minigun_fire(self.vehicle.gun2, 1);
 294                 self.misc_bulletcounter = 0;
 295             }
 296             else
 297             {
 298                 spiderbot_minigun_fire(self.vehicle.gun1, 1);
 299                 spiderbot_minigun_fire(self.vehicle.gun2, 0);
 300                 self.misc_bulletcounter += 1;
 301             }
 302             self = self.vehicle;
 303
 304             ftmp = autocvar_g_vehicle_spiderbot_minigun_refire / autocvar_g_vehicle_spiderbot_minigun_heat;
 305             self.owner.vehicle_reload1 +=  ftmp;
 306
 307             if(self.owner.vehicle_reload1 >= 1)
 308             {
 309                 self.vehicle_reload1 = 1;
 310                 self.owner.vehicle_reload1 = 1;
 311                 self.tur_head.attack_finished_single = autocvar_g_vehicle_spiderbot_minigun_cooldown + time;
 312             }
 313             else
 314                 self.tur_head.attack_finished_single = autocvar_g_vehicle_spiderbot_minigun_refire + time;
 315         }
 316         return;
 317     }
 318 }
 319
 320 float spiderbot_frame()
 321 {
 322     vector ad;
 323     entity player, spider;
 324     float ftmp;
 325
 326     player = self;
 327     spider = self.vehicle;
 328
 329     player.BUTTON_ZOOM      = 0;
 330     player.BUTTON_CROUCH    = 0;
 331     player.switchweapon     = 0;
 332
 333     if(player.BUTTON_USE)
 334     {
 335         self = spider;
 336         vehicles_exit(VHEF_NORMAL);
 337         self = player;
 338         return 0;
 339     }
 340
 341     self = spider;
 342
 343     crosshair_trace(player);
 344     //UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * player.vehicle_reload2) + ('0 1 0' * (1 - player.vehicle_reload2)), 2);
 345
 346 #if VEHICLES_VIEWROTATE_CROSSHAIR
 347     ad = vectoangles(normalize(trace_endpos - gettaginfo(spider.tur_head,gettagindex(spider.tur_head,"tag_hud")))) - (spider.tur_head.angles + spider.angles);
 348     if(ad_x > 180) ad_x -= 360;
 349     if(ad_x < -180) ad_x += 360;
 350     if(ad_y > 180) ad_y -= 360;
 351     if(ad_y < -180) ad_y += 360;
 352
 353     // Rotate head
 354     ftmp = autocvar_g_vehicle_spiderbot_head_turnspeed * sys_frametime;
 355     ad_y = bound(-ftmp, ad_y, ftmp);
 356     spider.tur_head.angles_y = bound(autocvar_g_vehicle_spiderbot_head_turnlimit * -1, spider.tur_head.angles_y + ad_y, autocvar_g_vehicle_spiderbot_head_turnlimit);
 357
 358     // Pitch head
 359     ftmp = autocvar_g_vehicle_spiderbot_head_pitchspeed * sys_frametime;
 360     //ad_x = bound(-ftmp, ad_x, ftmp);
 361     spider.tur_head.angles_x = bound(autocvar_g_vehicle_spiderbot_head_pitchlimit_down, spider.tur_head.angles_x + ad_x, autocvar_g_vehicle_spiderbot_head_pitchlimit_up);
 362
 363     // Turn Body
 364     ftmp = autocvar_g_vehicle_spiderbot_turnspeed * sys_frametime;
 365     ftmp = bound(-ftmp, spider.tur_head.angles_y, ftmp);
 366 #else
 367
 368     player.v_angle_x *= -1;
 369     ad = player.v_angle - (spider.tur_head.angles + spider.angles);
 370     player.v_angle_x *= -1;
 371     if(ad_x > 180)  ad_x -= 360;
 372     if(ad_x < -180) ad_x += 360;
 373     if(ad_y > 180)  ad_y -= 360;
 374     if(ad_y < -180) ad_y += 360;
 375
 376     // Rotate head
 377     ftmp = autocvar_g_vehicle_spiderbot_head_turnspeed * sys_frametime;
 378     ad_y = bound(-ftmp, ad_y, ftmp);
 379     spider.tur_head.angles_y = bound(autocvar_g_vehicle_spiderbot_head_turnlimit * -1, spider.tur_head.angles_y + ad_y, autocvar_g_vehicle_spiderbot_head_turnlimit);
 380
 381     // Pitch head
 382     ftmp = autocvar_g_vehicle_spiderbot_head_pitchspeed * sys_frametime;
 383     ad_x = bound(ftmp * -1, ad_x, ftmp);
 384     spider.tur_head.angles_x = bound(autocvar_g_vehicle_spiderbot_head_pitchlimit_down, spider.tur_head.angles_x + ad_x, autocvar_g_vehicle_spiderbot_head_pitchlimit_up);
 385
 386     // Turn Body
 387     ftmp = autocvar_g_vehicle_spiderbot_turnspeed * sys_frametime;
 388     ftmp = bound(-ftmp, spider.tur_head.angles_y, ftmp);
 389
 390
 391 #endif
 392     makevectors(spider.angles + '-1 0 0' * spider.angles_x);
 393
 394     /*
 395     vector ofs;
 396     ofs = self.origin + v_up * 128;
 397     te_lightning1(world, ofs, ofs + v_up * 32);
 398     te_lightning1(world, ofs, ofs + v_right * 128);
 399     te_lightning1(world, ofs, ofs + v_forward * 256);
 400     */
 401
 402     movelib_groundalign4point(autocvar_g_vehicle_spiderbot_springlength, autocvar_g_vehicle_spiderbot_springup, autocvar_g_vehicle_spiderbot_springblend);
 403
 404     if(spider.flags & FL_ONGROUND)
 405     {
 406         if(player.BUTTON_JUMP && self.tur_head.wait < time)
 407         {
 408             self.tur_head.wait = time + 2;
 409             player.BUTTON_JUMP = 0;
 410             spider.velocity   = v_forward * 700 + v_up * 600;
 411             spider.frame = 4;
 412         }
 413         else
 414         {
 415             if(vlen(player.movement) == 0)
 416             {
 417                 movelib_beak_simple(autocvar_g_vehicle_spiderbot_speed_stop);
 418                 spider.frame = 5;
 419             }
 420             else
 421             {
 422                 spider.angles_y = anglemods(spider.angles_y + ftmp);
 423                 spider.tur_head.angles_y -= ftmp;
 424
 425                 if(player.movement_x != 0)
 426                 {
 427                     if(player.movement_x > 0)
 428                     {
 429                         player.movement_x = 1;
 430                         spider.frame = 0;
 431                     }
 432                     else if(player.movement_x < 0)
 433                     {
 434                         player.movement_x = -1;
 435                         spider.frame = 1;
 436                     }
 437                     player.movement_y = 0;
 438                     movelib_move_simple(normalize(v_forward * player.movement_x),autocvar_g_vehicle_spiderbot_speed_walk,autocvar_g_vehicle_spiderbot_movement_inertia);
 439                 }
 440                 else if(player.movement_y != 0)
 441                 {
 442                     if(player.movement_y < 0)
 443                     {
 444                         player.movement_y = -1;
 445                         spider.frame = 2;
 446                     }
 447                     else if(player.movement_y > 0)
 448                     {
 449                         player.movement_y = 1;
 450                         spider.frame = 3;
 451                     }
 452                     movelib_move_simple(normalize(v_right * player.movement_y),autocvar_g_vehicle_spiderbot_speed_strafe,autocvar_g_vehicle_spiderbot_movement_inertia);
 453                 }
 454             }
 455         }
 456     }
 457
 458     self.angles_x = bound(-45, self.angles_x, 45);
 459     self.angles_z = bound(-45, self.angles_z, 45);
 460
 461     spiderbot_miniguns_do();
 462     spiderbot_rocket_do();
 463
 464     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 465         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_spiderbot_shield, autocvar_g_vehicle_spiderbot_shield_regen_pause, autocvar_g_vehicle_spiderbot_shield_regen, frametime);
 466
 467     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 468         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_spiderbot_health, autocvar_g_vehicle_spiderbot_health_regen_pause, autocvar_g_vehicle_spiderbot_health_regen, frametime);
 469
 470     player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 471     player.vehicle_ammo2 = spider.tur_head.frame;
 472
 473     if(spider.gun2.cnt <= time)
 474         player.vehicle_reload2 = 1;
 475     else
 476         player.vehicle_reload2 = 1 - ((spider.gun2.cnt - time) / spider.attack_finished_single);
 477
 478     setorigin(player, spider.origin + '0 0 1' * SPIDERBOT_MAX_z);
 479     player.velocity = spider.velocity;
 480
 481     VEHICLE_UPDATE_PLAYER(health, spiderbot);
 482
 483     if(self.vehicle_flags & VHF_HASSHIELD)
 484         VEHICLE_UPDATE_PLAYER(shield, spiderbot);
 485
 486 #if 1 // 0 to enable per-gun impact aux crosshairs
 487     // Avarage gun impact point's -> aux cross
 488     vector vf;
 489     ad = gettaginfo(spider.gun1, gettagindex(spider.gun1, "barrels"));
 490     vf = v_forward;
 491     ad += gettaginfo(spider.gun2, gettagindex(spider.gun2, "barrels"));
 492     vf += v_forward;
 493     ad = ad * 0.5;
 494     v_forward = vf * 0.5;
 495     traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, spider);
 496     UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * player.vehicle_reload1) + ('0 1 0' * (1 - player.vehicle_reload1)), 0);
 497
 498 #else
 499     ad = gettaginfo(spider.gun1, gettagindex(spider.gun1, "barrels"));
 500     traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, spider);
 501     UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * player.vehicle_reload1) + ('0 1 0' * (1 - player.vehicle_reload1)), 0);
 502
 503     ad = gettaginfo(spider.gun2, gettagindex(spider.gun2, "barrels"));
 504     traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, spider);
 505     UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * player.vehicle_reload1) + ('0 1 0' * (1 - player.vehicle_reload1)), 1);
 506 #endif
 507
 508     self = player;
 509     return 1;
 510 }
 511
 512 void spiderbot_think()
 513 {
 514     if(self.flags & FL_ONGROUND)
 515         movelib_beak_simple(autocvar_g_vehicle_spiderbot_speed_stop);
 516
 517     self.nextthink = time;
 518 }
 519
 520 void spiderbot_enter()
 521 {
 522     self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_spiderbot_health);
 523     self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_spiderbot_shield);
 524 }
 525
 526 void spiderbot_exit(float eject)
 527 {
 528     entity e;
 529
 530     vehicles_setreturn(autocvar_g_vehicle_spiderbot_respawntime, spiderbot_spawn);
 531
 532     e = findchain(classname,"spiderbot_rocket");
 533     while(e)
 534     {
 535         if(e.owner == self.owner)
 536         {
 537             e.realowner = self.owner;
 538             e.owner = world;
 539         }
 540         e = e.chain;
 541     }
 542
 543     self.velocity   = '0 0 0';
 544     self.think      = spiderbot_think;
 545     self.nextthink  = time;
 546     self.frame      = 5;
 547
 548     if not (self.owner)
 549         return;
 550
 551         makevectors(self.angles);
 552         if(eject)
 553         {
 554             setorigin(self.owner ,self.origin + v_forward * 100 + '0 0 64');
 555             self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 556         }
 557         else
 558         setorigin(self.owner, self.origin - v_forward * 200 + '0 0 64');
 559
 560     self.owner = world;
 561 }
 562
 563 // Better way of determening whats crushable needed! (fl_crushable?)
 564 float spiderbot_crushable(entity e)
 565 {
 566     if(e.classname == "corpse")
 567         return 1;
 568
 569     if(e.classname == "player")
 570         return 1;
 571
 572     if(e.classname == "monster_zombie")
 573         return 1;
 574
 575     return 0;
 576 }
 577
 578 void spiderbot_touch()
 579 {
 580     if(self.owner)
 581     {
 582         if(vlen(self.velocity) == 0)
 583             return;
 584
 585         if not (spiderbot_crushable(other))
 586             return;
 587
 588         //todo: add check for velocity/angle here (so we dont cush players runing into us from behind)
 589
 590         Damage(other, self, self.owner,autocvar_g_vehicle_spiderbot_crush_dmg,DEATH_SBCRUSH, '0 0 0', normalize(other.origin - self.origin) * autocvar_g_vehicle_spiderbot_crush_force);
 591         return;
 592     }
 593
 594     if(other.classname != "player")
 595         return;
 596
 597     if(other.deadflag != DEAD_NO)
 598         return;
 599
 600     if(other.vehicle != world)
 601         return;
 602
 603     vehicles_enter();
 604 }
 605
 606
 607 void spiderbot_spawn()
 608 {
 609
 610     self.frame              = 5;
 611     self.think              = spiderbot_think;
 612     self.nextthink          = time;
 613     self.owner              = world;
 614     self.vehicle_health     = autocvar_g_vehicle_spiderbot_health;
 615     self.vehicle_shield     = autocvar_g_vehicle_spiderbot_shield;
 616     self.event_damage       = vehicles_damage;
 617     self.iscreature         = TRUE;
 618     self.movetype           = MOVETYPE_WALK;
 619     self.solid              = SOLID_SLIDEBOX;
 620     self.takedamage         = DAMAGE_AIM;
 621     self.touch              = spiderbot_touch;
 622     self.alpha              = self.tur_head.alpha = self.gun1.alpha = self.gun2.alpha = 1;
 623     self.tur_head.angles    = '0 0 0';
 624         self.deadflag           = DEAD_NO;
 625     self.bot_attack         = TRUE;
 626     self.flags              |= FL_NOTARGET;
 627     self.tur_head.frame     = 1;
 628     self.vehicle_hudmodel.viewmodelforclient = self;
 629
 630     setorigin(self, self.pos1 + '0 0 128');
 631     self.angles = self.pos2;
 632
 633     vehicles_common_spawn();
 634
 635 }
 636
 637 void spiderbot_headfade()
 638 {
 639         self.think = spiderbot_headfade;
 640         self.nextthink = self.fade_time;
 641         self.alpha = 1 - (time - self.fade_time) * self.fade_rate;
 642
 643     if(self.cnt < time || self.alpha < 0.1)
 644     {
 645         if(self.alpha > 0.1)
 646         {
 647             sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 648             pointparticles(particleeffectnum("rocket_explode"), self.origin + '0 0 100', '0 0 0', 1);
 649         }
 650         remove(self);
 651     }
 652 }
 653
 654 void spiderbot_blowup()
 655 {
 656     float i;
 657     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 658
 659     for(i = 0; i < 5; ++i)
 660     {
 661         pointparticles(particleeffectnum("rocket_explode"), self.origin + (randomvec() * 200) + '0 0 100', '0 0 0', 1);
 662     }
 663
 664     entity h, g1, g2, b;
 665     b = spawn();
 666     h = spawn();
 667     g1 = spawn();
 668     g2 = spawn();
 669
 670     setmodel(b,  "models/vehicles/spiderbot.dpm");
 671     setmodel(h,  "models/vehicles/spiderbot_top.dpm");
 672     setmodel(g1, "models/vehicles/spiderbot_barrels.dpm");
 673     setmodel(g2, "models/vehicles/spiderbot_barrels.dpm");
 674
 675     setorigin(b, self.origin);
 676     setorigin(h, gettaginfo(self, gettagindex(self, "tag_head")));
 677     h.movetype      = MOVETYPE_BOUNCE;
 678     h.solid         = SOLID_BBOX;
 679     h.velocity      = v_up * (500 + random() * 500) + randomvec() * 128;
 680     h.modelflags    = MF_ROCKET;
 681     h.effects       = EF_FLAME | EF_LOWPRECISION;
 682     h.avelocity     = randomvec() * 360;
 683
 684     h.alpha         = 1;
 685     h.cnt           = time + (3.5 * random());
 686     h.fade_rate     = 1 / min(autocvar_g_vehicle_spiderbot_respawntime, 10);
 687     h.fade_time     = time;
 688     h.think         = spiderbot_headfade;
 689     h.nextthink     = time;
 690
 691     setorigin(g1, gettaginfo(self.tur_head, gettagindex(self.tur_head, "tag_hardpoint01")));
 692     g1.movetype     = MOVETYPE_TOSS;
 693     g1.solid        = SOLID_CORPSE;
 694     g1.velocity     = v_forward * 700 + (randomvec() * 32);
 695     g1.avelocity    = randomvec() * 180;
 696
 697     setorigin(g2, gettaginfo(self.tur_head, gettagindex(self.tur_head, "tag_hardpoint02")));
 698     g2.movetype     = MOVETYPE_TOSS;
 699     g2.solid        = SOLID_CORPSE;
 700     g2.velocity     = v_forward * 700 + (randomvec() * 32);
 701     g2.avelocity    = randomvec() * 180;
 702     b.frame         = 5;
 703
 704     h.colormod = b.colormod = g1.colormod = g2.colormod = '-2 -2 -2';
 705
 706     SUB_SetFade(b,  time, min(autocvar_g_vehicle_spiderbot_respawntime, 10));
 707     //SUB_SetFade(h,  time, min(autocvar_g_vehicle_spiderbot_respawntime, 10));
 708     SUB_SetFade(g1, time, min(autocvar_g_vehicle_spiderbot_respawntime, 10));
 709     SUB_SetFade(g2, time, min(autocvar_g_vehicle_spiderbot_respawntime, 10));
 710
 711     RadiusDamage (self, self, 250, 15, 250, world, 250, DEATH_SBBLOWUP, world);
 712
 713     self.alpha = self.tur_head.alpha = self.gun1.alpha = self.gun2.alpha = -1;
 714     self.nextthink  = time + autocvar_g_vehicle_spiderbot_respawntime;
 715     self.think      = spiderbot_spawn;
 716     self.movetype   = MOVETYPE_NONE;
 717     self.deadflag   = DEAD_DEAD;
 718     self.solid      = SOLID_NOT;
 719     self.tur_head.effects  &~=  EF_FLAME;
 720         self.vehicle_hudmodel.viewmodelforclient = self;
 721
 722     //setorigin(self, self.tur_aimpos);
 723 }
 724
 725 void spiderbot_die()
 726 {
 727     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 728     pointparticles(particleeffectnum("rocket_explode"), self.origin + '0 0 100', '0 0 0', 1);
 729
 730     self.health         = 0;
 731     self.event_damage   = SUB_Null;
 732     self.takedamage     = DAMAGE_NO;
 733     self.touch          = SUB_Null;
 734     self.nextthink      = 1 + time + random() * 2;
 735     self.think          = spiderbot_blowup;
 736     self.deadflag       = DEAD_DYING;
 737         self.frame          = 5;
 738         self.tur_head.effects        |= EF_FLAME;
 739         self.colormod = self.tur_head.colormod = '-1 -1 -1';
 740
 741 }
 742
 743 void vewhicle_spiderbot_dinit()
 744 {
 745     if not (vehicle_initialize(
 746              "Spiderbot",
 747              "models/vehicles/spiderbot.dpm",
 748              "models/vehicles/spiderbot_top.dpm",
 749              "models/vehicles/spiderbot_cockpit.dpm",
 750              "tag_head", "tag_hud", "",
 751              HUD_SPIDERBOT,
 752              SPIDERBOT_MIN, SPIDERBOT_MAX,
 753              FALSE,
 754              spiderbot_spawn, spiderbot_frame,
 755              spiderbot_enter, spiderbot_exit,
 756              spiderbot_die,   spiderbot_think))
 757     {
 758         remove(self);
 759         return;
 760     }
 761
 762     self.gun1               = spawn();
 763     self.gun2               = spawn();
 764
 765     setmodel(self.gun1, "models/vehicles/spiderbot_barrels.dpm");
 766     setmodel(self.gun2, "models/vehicles/spiderbot_barrels.dpm");
 767
 768     setattachment(self.gun1, self.tur_head, "tag_hardpoint01");
 769     setattachment(self.gun2, self.tur_head, "tag_hardpoint02");
 770
 771     self.gravity            = 2;
 772 }
 773
 774 void spawnfunc_vehicle_spiderbot()
 775 {
 776     precache_model ( "models/vhshield.md3");
 777     precache_model ( "models/vehicles/spiderbot.dpm");
 778     precache_model ( "models/vehicles/spiderbot_top.dpm");
 779     precache_model ( "models/vehicles/spiderbot_barrels.dpm");
 780     precache_model ( "models/vehicles/spiderbot_cockpit.dpm");
 781     precache_model ( "models/uziflash.md3");
 782
 783     precache_sound ( "weapons/rocket_impact.wav" );
 784     precache_sound ( "weapons/uzi_fire.wav" );
 785     precache_sound ( "weapons/rocket_impact.wav" );
 786
 787     vehicles_configcheck("vehicle_spiderbot.cfg", autocvar_g_vehicle_spiderbot_health);
 788     if(autocvar_g_vehicle_spiderbot_shield)
 789         self.vehicle_flags |= VHF_HASSHIELD;
 790
 791     if(autocvar_g_vehicle_spiderbot_shield_regen)
 792         self.vehicle_flags |= VHF_SHIELDREGEN;
 793
 794     if(autocvar_g_vehicle_spiderbot_health_regen)
 795         self.vehicle_flags |= VHF_HEALTHREGEN;
 796
 797     self.think = vewhicle_spiderbot_dinit;
 798     self.nextthink = time + 0.5;
 799 }