qcsrc/server/vehicles/vehicles.qc

   1 float autocvar_g_vehicles_crush_dmg;
   2 float autocvar_g_vehicles_crush_force;
   3 float autocvar_g_vehicles_delayspawn;
   4 float autocvar_g_vehicles_delayspawn_jitter;
   5
   6 var float autocvar_g_vehicles_nex_damagerate = 0.5;
   7 var float autocvar_g_vehicles_uzi_damagerate = 0.5;
   8 var float autocvar_g_vehicles_rifle_damagerate = 0.75;
   9 var float autocvar_g_vehicles_minstanex_damagerate = 0.001;
  10 var float autocvar_g_vehicles_tag_damagerate = 5;
  11
  12 float autocvar_g_vehicles;
  13
  14 void vehicles_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force);
  15 void vehicles_return();
  16 void vehicles_enter();
  17 void vehicles_touch();
  18 void vehicles_reset_colors();
  19 void vehicles_clearrturn();
  20 void vehicles_setreturn();
  21
  22
  23 /** AuxiliaryXhair*
  24     Send additional points of interest to be drawn, to vehicle owner
  25 **/
  26 float MAX_AXH = 4;
  27 .entity AuxiliaryXhair[MAX_AXH];
  28
  29 float SendAuxiliaryXhair(entity to, float sf)
  30 {
  31
  32         WriteByte(MSG_ENTITY, ENT_CLIENT_AUXILIARYXHAIR);
  33
  34         WriteByte(MSG_ENTITY, self.cnt);
  35
  36         WriteCoord(MSG_ENTITY, self.origin_x);
  37         WriteCoord(MSG_ENTITY, self.origin_y);
  38         WriteCoord(MSG_ENTITY, self.origin_z);
  39
  40     WriteByte(MSG_ENTITY, rint(self.colormod_x * 255));
  41     WriteByte(MSG_ENTITY, rint(self.colormod_y * 255));
  42     WriteByte(MSG_ENTITY, rint(self.colormod_z * 255));
  43
  44     return TRUE;
  45 }
  46
  47 void UpdateAuxiliaryXhair(entity own, vector loc, vector clr, float axh_id)
  48 {
  49     if (clienttype(own) != CLIENTTYPE_REAL)
  50         return;
  51
  52     entity axh;
  53
  54     axh_id = bound(0, axh_id, MAX_AXH);
  55     axh = own.(AuxiliaryXhair[axh_id]);
  56
  57     if(axh == world || wasfreed(axh))  // MADNESS? THIS IS QQQQCCCCCCCCC (wasfreed, why do you exsist?)
  58     {
  59         axh                     = spawn();
  60         axh.cnt                 = axh_id;
  61         axh.drawonlytoclient    = own;
  62         axh.owner               = own;
  63         Net_LinkEntity(axh, FALSE, 0, SendAuxiliaryXhair);
  64     }
  65
  66     setorigin(axh, loc);
  67     axh.colormod            = clr;
  68     axh.SendFlags           = 0x01;
  69     own.(AuxiliaryXhair[axh_id]) = axh;
  70 }
  71
  72 /*
  73 // SVC_TEMPENTITY based, horrible with even 50 ping. hm.
  74 // WriteByte(MSG_ONE, SVC_TEMPENTITY) uses reliable messagess, never use for thinsg that need continous updates.
  75 void SendAuxiliaryXhair2(entity own, vector loc, vector clr, float axh_id)
  76 {
  77         msgexntity = own;
  78
  79         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  80         WriteByte(MSG_ONE, TE_CSQC_AUXILIARYXHAIR);
  81
  82         WriteByte(MSG_ONE, axh_id);
  83
  84         WriteCoord(MSG_ONE, loc_x);
  85         WriteCoord(MSG_ONE, loc_y);
  86         WriteCoord(MSG_ONE, loc_z);
  87
  88     WriteByte(MSG_ONE, rint(clr_x * 255));
  89     WriteByte(MSG_ONE, rint(clr_y * 255));
  90     WriteByte(MSG_ONE, rint(clr_z * 255));
  91
  92 }
  93 */
  94 // End AuxiliaryXhair
  95
  96 /**
  97     Notifies the client that he enterd a vehicle, and sends
  98     realavent data.
  99
 100     only sends vehicle_id atm (wich is a HUD_* constant, ex. HUD_SPIDERBOT)
 101 **/
 102 void CSQCVehicleSetup(entity own, float vehicle_id)
 103 {
 104     if (clienttype(own) != CLIENTTYPE_REAL)
 105         return;
 106
 107         msg_entity = own;
 108
 109         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 110         WriteByte(MSG_ONE, TE_CSQC_VEHICLESETUP);
 111         if(vehicle_id != 0)
 112             WriteByte(MSG_ONE, vehicle_id);
 113         else
 114         WriteByte(MSG_ONE, 1 + own.vehicle.vehicle_weapon2mode + HUD_VEHICLE_LAST);
 115 }
 116
 117 /** vehicles_locktarget
 118
 119     Generic target locking.
 120
 121     Figure out if what target is "locked" (if any), for missile tracking as such.
 122
 123     after calling, "if(self.lock_target != world && self.lock_strength == 1)" mean
 124     you have a locked in target.
 125
 126     Exspects a crosshair_trace() or equivalent to be
 127     dont before calling.
 128
 129 **/
 130 .entity lock_target;
 131 .float  lock_strength;
 132 .float  lock_time;
 133 .float  lock_soundtime;
 134 float   DAMAGE_TARGETDRONE = 10;
 135
 136 vector targetdrone_getnewspot()
 137 {
 138
 139         vector spot;
 140         float i;
 141         for(i = 0; i < 100; ++i)
 142         {
 143                 spot = self.origin + randomvec() * 1024;
 144                 tracebox(spot, self.mins, self.maxs, spot, MOVE_NORMAL, self);
 145                 if(trace_fraction == 1.0 && trace_startsolid == 0 && trace_allsolid == 0)
 146                         return spot;
 147         }
 148         return self.origin;
 149 }
 150
 151 #if 0
 152 void targetdrone_think();
 153 void targetdrone_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force);
 154 void targetdrone_renwe()
 155 {
 156         self.think = targetdrone_think;
 157         self.nextthink = time + 0.1;
 158         setorigin(self, targetdrone_getnewspot());
 159         self.health = 200;
 160         self.takedamage = DAMAGE_TARGETDRONE;
 161         self.event_damage = targetdrone_damage;
 162         self.solid = SOLID_BBOX;
 163         setmodel(self, "models/runematch/rune.mdl");
 164         self.effects = EF_LOWPRECISION;
 165         self.scale = 10;
 166         self.movetype = MOVETYPE_BOUNCEMISSILE;
 167         setsize(self, '-100 -100 -100', '100 100 100');
 168
 169 }
 170 void targetdrone_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 171 {
 172         self.health -= damage;
 173         if(self.health <= 0)
 174         {
 175                 pointparticles(particleeffectnum("explosion_medium"), self.origin, '0 0 0', 1);
 176
 177                 if(!self.cnt)
 178                         remove(self);
 179                 else
 180                 {
 181                         self.think = targetdrone_renwe;
 182                         self.nextthink = time + 1 + random() * 2;
 183                         self.solid = SOLID_NOT;
 184                         setmodel(self, "");
 185                 }
 186         }
 187 }
 188 entity targetdrone_getfear()
 189 {
 190         entity fear;
 191         float i;
 192
 193         for(i = 64; i <= 1024; i += 64)
 194         {
 195                 fear = findradius(self.origin, i);
 196                 while(fear)
 197                 {
 198                         if(fear.bot_dodge)
 199                                 return fear;
 200
 201                         fear = fear.chain;
 202                 }
 203         }
 204
 205         return world;
 206 }
 207 void targetdrone_think()
 208 {
 209         self.nextthink = time + 0.1;
 210
 211         if(self.wp00)
 212         if(self.wp00.deadflag != DEAD_NO)
 213                 self.wp00 = targetdrone_getfear();
 214
 215         if(!self.wp00)
 216                 self.wp00 = targetdrone_getfear();
 217
 218         vector newdir;
 219
 220         if(self.wp00)
 221                 newdir = steerlib_push(self.wp00.origin) + randomvec() * 0.75;
 222         else
 223                 newdir = randomvec() * 0.75;
 224
 225         newdir = newdir * 0.5 + normalize(self.velocity) * 0.5;
 226
 227         if(self.wp00)
 228                 self.velocity = normalize(newdir) * (500 + (1024 / min(vlen(self.wp00.origin - self.origin), 1024)) * 700);
 229         else
 230                 self.velocity = normalize(newdir) * 750;
 231
 232         tracebox(self.origin, self.mins, self.maxs, self.origin + self.velocity * 2, MOVE_NORMAL, self);
 233         if(trace_fraction != 1.0)
 234                 self.velocity = self.velocity * -1;
 235
 236         //normalize((normalize(self.velocity) * 0.5 + newdir * 0.5)) * 750;
 237 }
 238
 239 void targetdrone_spawn(vector _where, float _autorenew)
 240 {
 241         entity drone = spawn();
 242         setorigin(drone, _where);
 243         drone.think = targetdrone_renwe;
 244         drone.nextthink = time + 0.1;
 245         drone.cnt = _autorenew;
 246 }
 247 #endif
 248
 249 void vehicles_locktarget(float incr, float decr, float _lock_time)
 250 {
 251     if(self.lock_target && self.lock_target.deadflag != DEAD_NO)
 252     {
 253         self.lock_target    = world;
 254         self.lock_strength  = 0;
 255         self.lock_time      = 0;
 256     }
 257
 258     if(self.lock_time > time)
 259     {
 260         if(self.lock_target)
 261         if(self.lock_soundtime < time)
 262         {
 263             self.lock_soundtime = time + 0.5;
 264             play2(self.owner, "vehicles/locked.wav");
 265         }
 266
 267         return;
 268     }
 269
 270     if(trace_ent != world)
 271     {
 272         if(teamplay && trace_ent.team == self.team)
 273             trace_ent = world;
 274
 275         if(trace_ent.deadflag != DEAD_NO)
 276             trace_ent = world;
 277
 278         if not (trace_ent.vehicle_flags & VHF_ISVEHICLE ||
 279                                 trace_ent.turrcaps_flags & TFL_TURRCAPS_ISTURRET ||
 280                                 trace_ent.takedamage == DAMAGE_TARGETDRONE)
 281             trace_ent = world;
 282     }
 283
 284     if(self.lock_target == world && trace_ent != world)
 285         self.lock_target = trace_ent;
 286
 287     if(self.lock_target && trace_ent == self.lock_target)
 288     {
 289         if(self.lock_strength != 1 && self.lock_strength + incr >= 1)
 290         {
 291             play2(self.owner, "vehicles/lock.wav");
 292             self.lock_soundtime = time + 0.8;
 293         }
 294         else if (self.lock_strength != 1 && self.lock_soundtime < time)
 295         {
 296             play2(self.owner, "vehicles/locking.wav");
 297             self.lock_soundtime = time + 0.3;
 298         }
 299
 300     }
 301
 302     // Have a locking target
 303     // Trace hit current target
 304     if(trace_ent == self.lock_target && trace_ent != world)
 305     {
 306         self.lock_strength = min(self.lock_strength + incr, 1);
 307         if(self.lock_strength == 1)
 308             self.lock_time = time + _lock_time;
 309     }
 310     else
 311     {
 312         if(trace_ent)
 313             self.lock_strength = max(self.lock_strength - decr * 2, 0);
 314         else
 315             self.lock_strength = max(self.lock_strength - decr, 0);
 316
 317         if(self.lock_strength == 0)
 318             self.lock_target = world;
 319     }
 320 }
 321
 322 #define VEHICLE_UPDATE_PLAYER(ply,fld,vhname) \
 323 ply.vehicle_##fld = (self.vehicle_##fld / autocvar_g_vehicle_##vhname##_##fld) * 100
 324
 325 #define vehicles_sweap_collision(orig,vel,dt,acm,mult) \
 326 traceline(orig, orig + vel * dt, MOVE_NORMAL, self); \
 327 if(trace_fraction != 1) \
 328     acm += normalize(self.origin - trace_endpos) * (vlen(vel) * mult)
 329
 330 // Hover movement support
 331 float  force_fromtag_power;
 332 float  force_fromtag_normpower;
 333 vector force_fromtag_origin;
 334 vector vehicles_force_fromtag_hover(string tag_name, float spring_length, float max_power)
 335 {
 336     force_fromtag_origin = gettaginfo(self, gettagindex(self, tag_name));
 337     v_forward  = normalize(v_forward) * -1;
 338     traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, self);
 339
 340     force_fromtag_power = (1 - trace_fraction) * max_power;
 341     force_fromtag_normpower = force_fromtag_power / max_power;
 342
 343     return v_forward  * force_fromtag_power;
 344 }
 345
 346 // Experimental hovermode wich uses attraction/repulstion from surface insted of gravity/repulsion
 347 // Can possibly be use to move abt any surface (inclusing walls/celings)
 348 vector vehicles_force_fromtag_maglev(string tag_name, float spring_length, float max_power)
 349 {
 350
 351     force_fromtag_origin = gettaginfo(self, gettagindex(self, tag_name));
 352     v_forward  = normalize(v_forward) * -1;
 353     traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, self);
 354
 355     // TODO - this may NOT be compatible with wall/celing movement, unhardcode 0.25 (engine count multiplier)
 356     if(trace_fraction == 1.0)
 357     {
 358         force_fromtag_normpower = -0.25;
 359         return '0 0 -200';
 360     }
 361
 362     force_fromtag_power = ((1 - trace_fraction) - trace_fraction) * max_power;
 363     force_fromtag_normpower = force_fromtag_power / max_power;
 364
 365     return v_forward  * force_fromtag_power;
 366 }
 367
 368 // Generic vehile projectile system
 369 void vehicles_projectile_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 370 {
 371     // Ignore damage from oterh projectiles from my owner (dont mess up volly's)
 372     if(inflictor.owner == self.owner)
 373         return;
 374
 375     self.health -= damage;
 376     self.velocity += force;
 377     if(self.health < 1)
 378     {
 379         self.takedamage = DAMAGE_NO;
 380         self.event_damage = SUB_Null;
 381         self.think = self.use;
 382         self.nextthink = time;
 383     }
 384 }
 385
 386 void vehicles_projectile_explode()
 387 {
 388     if(self.owner && other != world)
 389     {
 390         if(other == self.owner.vehicle)
 391             return;
 392
 393         if(other == self.owner.vehicle.tur_head)
 394             return;
 395     }
 396
 397         PROJECTILE_TOUCH;
 398
 399         self.event_damage = SUB_Null;
 400     RadiusDamage (self, self.realowner, self.shot_dmg, 0, self.shot_radius, self, self.shot_force, self.totalfrags, other);
 401
 402     remove (self);
 403 }
 404
 405 entity vehicles_projectile(string _mzlfx, string _mzlsound,
 406                            vector _org, vector _vel,
 407                            float _dmg, float _radi, float _force,  float _size,
 408                            float _deahtype, float _projtype, float _health,
 409                            float _cull, float _clianim, entity _owner)
 410 {
 411     entity proj;
 412
 413     proj = spawn();
 414
 415     PROJECTILE_MAKETRIGGER(proj);
 416     setorigin(proj, _org);
 417
 418     proj.shot_dmg         = _dmg;
 419     proj.shot_radius      = _radi;
 420     proj.shot_force       = _force;
 421     proj.totalfrags       = _deahtype;
 422     proj.solid            = SOLID_BBOX;
 423     proj.movetype         = MOVETYPE_FLYMISSILE;
 424     proj.flags            = FL_PROJECTILE;
 425     proj.bot_dodge        = TRUE;
 426     proj.bot_dodgerating  = _dmg;
 427     proj.velocity         = _vel;
 428     proj.touch            = vehicles_projectile_explode;
 429     proj.use              = vehicles_projectile_explode;
 430     proj.owner            = self;
 431     proj.realowner        = _owner;
 432     proj.think            = SUB_Remove;
 433     proj.nextthink        = time + 30;
 434
 435     if(_health)
 436     {
 437         proj.takedamage       = DAMAGE_AIM;
 438         proj.event_damage     = vehicles_projectile_damage;
 439         proj.health           = _health;
 440     }
 441     else
 442         proj.flags           = FL_PROJECTILE | FL_NOTARGET;
 443
 444     if(_mzlsound)
 445         sound (self, CH_WEAPON_A, _mzlsound, VOL_BASE, ATTN_NORM);
 446
 447     if(_mzlfx)
 448         pointparticles(particleeffectnum(_mzlfx), proj.origin, proj.velocity, 1);
 449
 450
 451     setsize (proj, '-1 -1 -1' * _size, '1 1 1' * _size);
 452
 453     CSQCProjectile(proj, _clianim, _projtype, _cull);
 454
 455     return proj;
 456 }
 457 // End generic vehile projectile system
 458
 459 /** vehicles_spawn
 460     Exetuted for all vehicles on (re)spawn.
 461     Sets defaults for newly spawned units.
 462 **/
 463 void vehicles_spawn()
 464 {
 465     dprint("Spawning vehicle: ", self.netname, "\n");
 466
 467     // De-own & reset
 468     self.vehicle_hudmodel.viewmodelforclient = self;
 469
 470     self.owner              = world;
 471     self.touch              = vehicles_touch;
 472     self.event_damage       = vehicles_damage;
 473     self.iscreature         = TRUE;
 474     self.teleportable       = FALSE; // no teleporting for vehicles, too buggy
 475     self.damagedbycontents      = TRUE;
 476     self.movetype           = MOVETYPE_WALK;
 477     self.solid              = SOLID_SLIDEBOX;
 478     self.takedamage         = DAMAGE_AIM;
 479         self.deadflag           = DEAD_NO;
 480     self.bot_attack         = TRUE;
 481     self.flags              = FL_NOTARGET;
 482     self.avelocity          = '0 0 0';
 483     self.velocity           = '0 0 0';
 484
 485     // Reset locking
 486     self.lock_strength      = 0;
 487     self.lock_target        = world;
 488     self.misc_bulletcounter = 0;
 489
 490     // Return to spawn
 491     self.angles             = self.pos2;
 492     setorigin(self, self.pos1 + '0 0 0');
 493     // Show it
 494     pointparticles(particleeffectnum("teleport"), self.origin + '0 0 64', '0 0 0', 1);
 495
 496     if(self.vehicle_controller)
 497         self.team = self.vehicle_controller.team;
 498
 499     vehicles_reset_colors();
 500     self.vehicle_spawn(VHSF_NORMAL);
 501 }
 502
 503 // Better way of determening whats crushable needed! (fl_crushable?)
 504 float vehicles_crushable(entity e)
 505 {
 506     if(e.classname == "player")
 507         return TRUE;
 508
 509     if(e.classname == "monster_zombie")
 510         return TRUE;
 511
 512     return FALSE;
 513 }
 514
 515 void vehilces_impact(float _minspeed, float _speedfac, float _maxpain)
 516 {
 517     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 518         return;
 519
 520     if(self.play_time < time)
 521     {
 522         float wc = vlen(self.velocity - self.oldvelocity);
 523         //dprint("oldvel: ", vtos(self.oldvelocity), "\n");
 524         //dprint("vel: ", vtos(self.velocity), "\n");
 525         if(_minspeed < wc)
 526         {
 527             float take = min(_speedfac * wc, _maxpain);
 528             Damage (self, world, world, take, DEATH_FALL, self.origin, '0 0 0');
 529             self.play_time = time + 0.25;
 530
 531             //dprint("wc: ", ftos(wc), "\n");
 532             //dprint("take: ", ftos(take), "\n");
 533         }
 534     }
 535 }
 536
 537 .void() vehicle_impact;
 538 void vehicles_touch()
 539 {
 540     // Vehicle currently in use
 541     if(self.owner)
 542     {
 543         if(other != world)
 544         if(vehicles_crushable(other))
 545         {
 546             if(vlen(self.velocity) != 0)
 547                 Damage(other, self, self.owner, autocvar_g_vehicles_crush_dmg, DEATH_VHCRUSH, '0 0 0', normalize(other.origin - self.origin) * autocvar_g_vehicles_crush_force);
 548
 549             return; // Dont do selfdamage when hitting "soft targets".
 550         }
 551
 552         if(self.play_time < time)
 553         if(self.vehicle_impact)
 554             self.vehicle_impact();
 555
 556         return;
 557     }
 558
 559     if(other.classname != "player")
 560         return;
 561
 562     if(other.deadflag != DEAD_NO)
 563         return;
 564
 565     if(other.vehicle != world)
 566         return;
 567
 568     vehicles_enter();
 569 }
 570 var float autocvar_g_vehicles_allow_bots = 0;
 571 void vehicles_enter()
 572 {
 573    // Remove this when bots know how to use vehicles
 574
 575     if (clienttype(other) == CLIENTTYPE_BOT)
 576         if (autocvar_g_vehicles_allow_bots)
 577             dprint("Bot enters vehicle\n"); // This is where we need to disconnect (some, all?) normal bot AI and hand over to vehicle's _aiframe()
 578         else
 579             return;
 580
 581     if(self.phase > time)
 582         return;
 583
 584     if(teamplay)
 585     if(self.team)
 586     if(self.team != other.team)
 587         return;
 588
 589     RemoveGrapplingHook(other);
 590
 591     self.vehicle_ammo1   = 0;
 592     self.vehicle_ammo2   = 0;
 593     self.vehicle_reload1 = 0;
 594     self.vehicle_reload2 = 0;
 595     self.vehicle_energy  = 0;
 596
 597     self.owner          = other;
 598     self.switchweapon   = other.switchweapon;
 599
 600     // .viewmodelforclient works better.
 601     //self.vehicle_hudmodel.drawonlytoclient = self.owner;
 602
 603     self.vehicle_hudmodel.viewmodelforclient = self.owner;
 604
 605     self.event_damage         = vehicles_damage;
 606     self.nextthink            = 0;
 607     self.owner.angles         = self.angles;
 608     self.owner.takedamage     = DAMAGE_NO;
 609     self.owner.solid          = SOLID_NOT;
 610     self.owner.movetype       = MOVETYPE_NOCLIP;
 611     self.owner.alpha          = -1;
 612     self.owner.vehicle        = self;
 613     self.owner.event_damage   = SUB_Null;
 614     self.owner.view_ofs       = '0 0 0';
 615     self.colormap             = self.owner.colormap;
 616     if(self.tur_head)
 617         self.tur_head.colormap    = self.owner.colormap;
 618
 619     self.owner.hud            = self.hud;
 620     self.owner.PlayerPhysplug = self.PlayerPhysplug;
 621
 622     self.owner.vehicle_ammo1    = self.vehicle_ammo1;
 623     self.owner.vehicle_ammo2    = self.vehicle_ammo2;
 624     self.owner.vehicle_reload1  = self.vehicle_reload1;
 625     self.owner.vehicle_reload2  = self.vehicle_reload2;
 626
 627     // Cant do this, hides attached objects too.
 628     //self.exteriormodeltoclient = self.owner;
 629     //self.tur_head.exteriormodeltoclient = self.owner;
 630
 631     other.flags &~= FL_ONGROUND;
 632     self.flags  &~= FL_ONGROUND;
 633
 634     self.team                 = self.owner.team;
 635     self.flags               -= FL_NOTARGET;
 636
 637     if (clienttype(other) == CLIENTTYPE_REAL)
 638     {
 639         msg_entity = other;
 640         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
 641         WriteEntity(MSG_ONE, self.vehicle_viewport);
 642
 643         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
 644         if(self.tur_head)
 645         {
 646             WriteAngle(MSG_ONE, self.tur_head.angles_x + self.angles_x); // tilt
 647             WriteAngle(MSG_ONE, self.tur_head.angles_y + self.angles_y); // yaw
 648             WriteAngle(MSG_ONE, 0);                                      // roll
 649         }
 650         else
 651         {
 652             WriteAngle(MSG_ONE,  self.angles_x * -1); // tilt
 653             WriteAngle(MSG_ONE,  self.angles_y);      // yaw
 654             WriteAngle(MSG_ONE,  0);                  // roll
 655         }
 656     }
 657
 658     vehicles_clearrturn();
 659
 660     CSQCVehicleSetup(self.owner, self.hud);
 661
 662     MUTATOR_CALLHOOK(VehicleEnter);
 663
 664     self.vehicle_enter();
 665     antilag_clear(other);
 666 }
 667
 668 /** vehicles_findgoodexit
 669     Locates a valid location for the player to exit the vehicle.
 670     Will first try prefer_spot, then up 100 random spots arround the vehicle
 671     wich are in direct line of sight and empty enougth to hold a players bbox
 672 **/
 673 vector vehicles_findgoodexit(vector prefer_spot)
 674 {
 675     //vector exitspot;
 676     float mysize;
 677
 678     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, prefer_spot, MOVE_NORMAL, self.owner);
 679     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 680         return prefer_spot;
 681
 682     mysize = 1.5 * vlen(self.maxs - self.mins);
 683     float i;
 684     vector v, v2;
 685     v2 = 0.5 * (self.absmin + self.absmax);
 686     for(i = 0; i < 100; ++i)
 687     {
 688         v = randomvec();
 689         v_z = 0;
 690         v = v2 + normalize(v) * mysize;
 691         tracebox(v2, PL_MIN, PL_MAX, v, MOVE_NORMAL, self.owner);
 692         if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 693             return v;
 694     }
 695
 696     /*
 697     exitspot = (self.origin + '0 0 48') + v_forward * mysize;
 698     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 699     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 700         return exitspot;
 701
 702     exitspot = (self.origin + '0 0 48') - v_forward * mysize;
 703     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 704     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 705         return exitspot;
 706
 707     exitspot = (self.origin + '0 0 48') + v_right * mysize;
 708     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 709     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 710         return exitspot;
 711
 712     exitspot = (self.origin + '0 0 48') - v_right * mysize;
 713     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 714     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 715         return exitspot;
 716     */
 717
 718     return self.origin;
 719 }
 720
 721 /** vehicles_exit
 722     Standarrd vehicle release fucntion.
 723     custom code goes in self.vehicle_exit
 724 **/
 725 float vehicles_exit_running;
 726 void vehicles_exit(float eject)
 727 {
 728     entity _vehicle;
 729     entity _player;
 730     entity _oldself = self;
 731
 732     if(vehicles_exit_running)
 733     {
 734         dprint("^1vehicles_exit allready running! this is not good..\n");
 735         return;
 736     }
 737
 738     vehicles_exit_running = TRUE;
 739     if(self.flags & FL_CLIENT)
 740     {
 741         _vehicle = self.vehicle;
 742
 743         if (_vehicle.vehicle_flags & VHF_PLAYERSLOT)
 744         {
 745             _vehicle.vehicle_exit(eject);
 746             self = _oldself;
 747             vehicles_exit_running = FALSE;
 748             return;
 749         }
 750     }
 751     else
 752         _vehicle = self;
 753
 754     _player = _vehicle.owner;
 755
 756     self = _vehicle;
 757
 758     if (_player)
 759     {
 760         if (clienttype(_player) == CLIENTTYPE_REAL)
 761         {
 762             msg_entity = _player;
 763             WriteByte (MSG_ONE, SVC_SETVIEWPORT);
 764             WriteEntity( MSG_ONE, _player);
 765
 766             WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
 767             WriteAngle(MSG_ONE, 0);
 768             WriteAngle(MSG_ONE, _vehicle.angles_y);
 769             WriteAngle(MSG_ONE, 0);
 770         }
 771
 772         setsize(_player, PL_MIN,PL_MAX);
 773
 774         _player.takedamage     = DAMAGE_AIM;
 775         _player.solid          = SOLID_SLIDEBOX;
 776         _player.movetype       = MOVETYPE_WALK;
 777         _player.effects        &~= EF_NODRAW;
 778         _player.alpha          = 1;
 779         _player.PlayerPhysplug = SUB_Null;
 780         _player.vehicle        = world;
 781         _player.view_ofs       = PL_VIEW_OFS;
 782         _player.event_damage   = PlayerDamage;
 783         _player.hud            = HUD_NORMAL;
 784         _player.switchweapon   = _vehicle.switchweapon;
 785
 786         CSQCVehicleSetup(_player, HUD_NORMAL);
 787     }
 788     _vehicle.flags |= FL_NOTARGET;
 789
 790     if(_vehicle.deadflag == DEAD_NO)
 791         _vehicle.avelocity          = '0 0 0';
 792
 793     _vehicle.tur_head.nodrawtoclient             = world;
 794
 795     if(!teamplay)
 796         _vehicle.team = 0;
 797     else
 798
 799     self.team = self.tur_head.team;
 800
 801     MUTATOR_CALLHOOK(VehicleExit);
 802
 803     _vehicle.team = _vehicle.tur_head.team;
 804
 805     sound (_vehicle, CH_TRIGGER_SINGLE, "misc/null.wav", 1, ATTN_NORM);
 806     _vehicle.vehicle_hudmodel.viewmodelforclient = _vehicle;
 807     _vehicle.phase = time + 1;
 808
 809     _vehicle.vehicle_exit(eject);
 810
 811     vehicles_setreturn();
 812     vehicles_reset_colors();
 813     _vehicle.owner = world;
 814     self = _oldself;
 815
 816     vehicles_exit_running = FALSE;
 817 }
 818
 819
 820 void vehicles_regen(float timer, .float regen_field, float field_max, float rpause, float regen, float delta_time, float _healthscale)
 821 {
 822     if(self.regen_field < field_max)
 823     if(timer + rpause < time)
 824     {
 825         if(_healthscale)
 826             regen = regen * (self.vehicle_health / self.tur_health);
 827
 828         self.regen_field = min(self.regen_field + regen * delta_time, field_max);
 829
 830         if(self.owner)
 831             self.owner.regen_field = (self.regen_field / field_max) * 100;
 832     }
 833 }
 834
 835 void shieldhit_think()
 836 {
 837     self.alpha -= 0.1;
 838     if (self.alpha <= 0)
 839     {
 840         //setmodel(self, "");
 841         self.alpha = -1;
 842         self.effects |= EF_NODRAW;
 843     }
 844     else
 845     {
 846         self.nextthink = time + 0.1;
 847     }
 848 }
 849
 850 void vehicles_painframe()
 851 {
 852     if(self.owner.vehicle_health <= 50)
 853     if(self.pain_frame < time)
 854     {
 855         float _ftmp;
 856         _ftmp = self.owner.vehicle_health / 50;
 857         self.pain_frame = time + 0.1 + (random() * 0.5 * _ftmp);
 858         pointparticles(particleeffectnum("smoke_small"), (self.origin + (randomvec() * 80)), '0 0 0', 1);
 859
 860         if(self.vehicle_flags & VHF_DMGSHAKE)
 861             self.velocity += randomvec() * 30;
 862
 863         if(self.vehicle_flags & VHF_DMGROLL)
 864             if(self.vehicle_flags & VHF_DMGHEADROLL)
 865                 self.tur_head.angles += randomvec();
 866             else
 867                 self.angles += randomvec();
 868
 869     }
 870 }
 871
 872 void vehicles_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 873 {
 874     self.dmg_time = time;
 875
 876     if(DEATH_ISWEAPON(deathtype, WEP_NEX))
 877         damage *= autocvar_g_vehicles_nex_damagerate;
 878
 879     if(DEATH_ISWEAPON(deathtype, WEP_UZI))
 880         damage *= autocvar_g_vehicles_uzi_damagerate;
 881
 882     if(DEATH_ISWEAPON(deathtype, WEP_RIFLE))
 883         damage *= autocvar_g_vehicles_rifle_damagerate;
 884
 885     if(DEATH_ISWEAPON(deathtype, WEP_MINSTANEX))
 886         damage *= autocvar_g_vehicles_minstanex_damagerate;
 887
 888     if(DEATH_ISWEAPON(deathtype, WEP_SEEKER))
 889         damage *= autocvar_g_vehicles_tag_damagerate;
 890
 891     self.enemy = attacker;
 892
 893     if((self.vehicle_flags & VHF_HASSHIELD) && (self.vehicle_shield > 0))
 894     {
 895         if (wasfreed(self.vehicle_shieldent) || self.vehicle_shieldent == world)
 896         {
 897             self.vehicle_shieldent = spawn();
 898             self.vehicle_shieldent.effects = EF_LOWPRECISION;
 899
 900             setmodel(self.vehicle_shieldent, "models/vhshield.md3");
 901             setattachment(self.vehicle_shieldent, self, "");
 902             setorigin(self.vehicle_shieldent, real_origin(self) - self.origin);
 903             self.vehicle_shieldent.scale       = 256 / vlen(self.maxs - self.mins);
 904             self.vehicle_shieldent.think       = shieldhit_think;
 905         }
 906
 907         self.vehicle_shieldent.colormod    = '1 1 1';
 908         self.vehicle_shieldent.alpha       = 0.45;
 909         self.vehicle_shieldent.angles      = vectoangles(normalize(hitloc - (self.origin + self.vehicle_shieldent.origin))) - self.angles;
 910         self.vehicle_shieldent.nextthink   = time;
 911         self.vehicle_shieldent.effects &~= EF_NODRAW;
 912
 913         self.vehicle_shield -= damage;
 914
 915         if(self.vehicle_shield < 0)
 916         {
 917             self.vehicle_health            -= fabs(self.vehicle_shield);
 918             self.vehicle_shieldent.colormod = '2 0 0';
 919             self.vehicle_shield             = 0;
 920             self.vehicle_shieldent.alpha    = 0.75;
 921
 922                 if(sound_allowed(MSG_BROADCAST, attacker))
 923                 spamsound (self, CH_PAIN, "onslaught/ons_hit2.wav", VOL_BASE, ATTN_NORM);   // FIXME: PLACEHOLDER
 924         }
 925         else
 926                 if(sound_allowed(MSG_BROADCAST, attacker))
 927                 spamsound (self, CH_PAIN, "onslaught/electricity_explode.wav", VOL_BASE, ATTN_NORM);  // FIXME: PLACEHOLDER
 928
 929     }
 930     else
 931     {
 932         self.vehicle_health -= damage;
 933
 934         if(sound_allowed(MSG_BROADCAST, attacker))
 935             spamsound (self, CH_PAIN, "onslaught/ons_hit2.wav", VOL_BASE, ATTN_NORM);  // FIXME: PLACEHOLDER
 936     }
 937
 938         if(self.damageforcescale < 1 && self.damageforcescale > 0)
 939                 self.velocity += force * self.damageforcescale;
 940         else
 941                 self.velocity += force;
 942
 943     if(self.vehicle_health <= 0)
 944     {
 945         if(self.owner)
 946             if(self.vehicle_flags & VHF_DEATHEJECT)
 947                 vehicles_exit(VHEF_EJECT);
 948             else
 949                 vehicles_exit(VHEF_RELESE);
 950
 951
 952         antilag_clear(self);
 953
 954         self.vehicle_die();
 955         vehicles_setreturn();
 956     }
 957 }
 958
 959 void vehicles_clearrturn()
 960 {
 961     entity ret;
 962     // Remove "return helper", if any.
 963     ret = findchain(classname, "vehicle_return");
 964     while(ret)
 965     {
 966         if(ret.wp00 == self)
 967         {
 968             ret.classname   = "";
 969             ret.think       = SUB_Remove;
 970             ret.nextthink   = time + 0.1;
 971
 972             if(ret.waypointsprite_attached)
 973                 WaypointSprite_Kill(ret.waypointsprite_attached);
 974
 975             return;
 976         }
 977         ret = ret.chain;
 978     }
 979 }
 980
 981 void vehicles_return()
 982 {
 983     pointparticles(particleeffectnum("teleport"), self.wp00.origin + '0 0 64', '0 0 0', 1);
 984
 985     self.wp00.think     = vehicles_spawn;
 986     self.wp00.nextthink = time;
 987
 988     if(self.waypointsprite_attached)
 989         WaypointSprite_Kill(self.waypointsprite_attached);
 990
 991     remove(self);
 992 }
 993
 994 void vehicles_showwp_goaway()
 995 {
 996     if(self.waypointsprite_attached)
 997         WaypointSprite_Kill(self.waypointsprite_attached);
 998
 999     remove(self);
1000
1001 }
1002
1003 void vehicles_showwp()
1004 {
1005     entity oldself;
1006     vector rgb;
1007
1008     if(self.cnt)
1009     {
1010         self.think      = vehicles_return;
1011         self.nextthink  = self.cnt;
1012     }
1013     else
1014     {
1015         self.think      = vehicles_return;
1016         self.nextthink  = time +1;
1017
1018         oldself = self;
1019         self = spawn();
1020         setmodel(self, "null");
1021         self.team = oldself.wp00.team;
1022         self.wp00 = oldself.wp00;
1023         setorigin(self, oldself.wp00.pos1);
1024
1025         self.nextthink = time + 5;
1026         self.think = vehicles_showwp_goaway;
1027     }
1028
1029     if(teamplay && self.team)
1030             rgb = TeamColor(self.team);
1031     else
1032             rgb = '1 1 1';
1033     WaypointSprite_Spawn("vehicle", 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
1034     if(self.waypointsprite_attached)
1035     {
1036         WaypointSprite_UpdateRule(self.waypointsprite_attached, self.wp00.team, SPRITERULE_DEFAULT);
1037         if(oldself == world)
1038             WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, self.nextthink);
1039         WaypointSprite_Ping(self.waypointsprite_attached);
1040     }
1041
1042     if(oldself != world)
1043         self = oldself;
1044 }
1045
1046 void vehicles_setreturn()
1047 {
1048     entity ret;
1049
1050     vehicles_clearrturn();
1051
1052     ret = spawn();
1053     ret.classname   = "vehicle_return";
1054     ret.wp00       = self;
1055     ret.team        = self.team;
1056     ret.think       = vehicles_showwp;
1057
1058     if(self.deadflag != DEAD_NO)
1059     {
1060         ret.cnt         = time + self.vehicle_respawntime;
1061         ret.nextthink   = min(time + self.vehicle_respawntime, time + self.vehicle_respawntime - 5);
1062     }
1063     else
1064     {
1065         ret.nextthink   = min(time + self.vehicle_respawntime, time + self.vehicle_respawntime - 1);
1066     }
1067
1068     setmodel(ret, "null");
1069     setorigin(ret, self.pos1 + '0 0 96');
1070
1071 }
1072
1073 void vehicles_reset_colors()
1074 {
1075     entity e;
1076     float _effects, _colormap;
1077     vector _glowmod, _colormod;
1078
1079     if(autocvar_g_nodepthtestplayers)
1080         _effects = EF_NODEPTHTEST;
1081
1082     if(autocvar_g_fullbrightplayers)
1083         _effects |= EF_FULLBRIGHT;
1084
1085     if(self.team)
1086         _colormap = 1024 + (self.team - 1) * 17;
1087     else
1088         _colormap = 1024;
1089
1090     _glowmod  = '0 0 0';
1091     _colormod = '0 0 0';
1092
1093     // Find all ents attacked to main model and setup effects, colormod etc.
1094     e = findchainentity(tag_entity, self);
1095     while(e)
1096     {
1097         if(e != self.vehicle_shieldent)
1098         {
1099             e.effects   = _effects; //  | EF_LOWPRECISION;
1100             e.colormod  = _colormod;
1101             e.colormap  = _colormap;
1102             e.alpha     = 1;
1103         }
1104         e = e.chain;
1105     }
1106
1107     self.vehicle_hudmodel.effects  = self.effects  = _effects; // | EF_LOWPRECISION;
1108     self.vehicle_hudmodel.colormod = self.colormod = _colormod;
1109     self.vehicle_hudmodel.colormap = self.colormap = _colormap;
1110     self.vehicle_viewport.effects = (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NOGUNBOB | EF_NOSHADOW | EF_LOWPRECISION | EF_SELECTABLE | EF_TELEPORT_BIT);
1111
1112     self.alpha     = 1;
1113     self.avelocity = '0 0 0';
1114     self.velocity  = '0 0 0';
1115     self.effects   = _effects;
1116 }
1117
1118 void vehicle_use()
1119 {
1120     dprint("vehicle ",self.netname, " used by ", activator.classname, "\n");
1121
1122     self.tur_head.team = activator.team;
1123
1124     if(self.tur_head.team == 0)
1125         self.active = ACTIVE_NOT;
1126     else
1127         self.active = ACTIVE_ACTIVE;
1128
1129     if(self.active == ACTIVE_ACTIVE && self.deadflag == DEAD_NO)
1130     {
1131         dprint("^3Eat shit yall!\n");
1132         vehicles_setreturn();
1133         vehicles_reset_colors();
1134     }
1135     else if(self.active == ACTIVE_NOT && self.deadflag != DEAD_NO)
1136     {
1137
1138     }
1139 }
1140
1141 float vehicle_addplayerslot(    entity _owner,
1142                                 entity _slot,
1143                                 float _hud,
1144                                 string _hud_model,
1145                                 float() _framefunc,
1146                                 void(float) _exitfunc)
1147 {
1148     if not (_owner.vehicle_flags & VHF_MULTISLOT)
1149         _owner.vehicle_flags |= VHF_MULTISLOT;
1150
1151     _slot.PlayerPhysplug = _framefunc;
1152     _slot.vehicle_exit = _exitfunc;
1153     _slot.hud = _hud;
1154     _slot.vehicle_flags = VHF_PLAYERSLOT;
1155     _slot.vehicle_viewport = spawn();
1156     _slot.vehicle_hudmodel = spawn();
1157     _slot.vehicle_hudmodel.viewmodelforclient = _slot;
1158     _slot.vehicle_viewport.effects = (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NOGUNBOB | EF_NOSHADOW | EF_LOWPRECISION | EF_SELECTABLE | EF_TELEPORT_BIT);
1159
1160     setmodel(_slot.vehicle_hudmodel, _hud_model);
1161     setmodel(_slot.vehicle_viewport, "null");
1162
1163     setattachment(_slot.vehicle_hudmodel, _slot, "");
1164     setattachment(_slot.vehicle_viewport, _slot.vehicle_hudmodel, "");
1165
1166     return TRUE;
1167 }
1168
1169 float vehicle_initialize(string  net_name,
1170                          string  bodymodel,
1171                          string  topmodel,
1172                          string  hudmodel,
1173                          string  toptag,
1174                          string  hudtag,
1175                          string  viewtag,
1176                          float   vhud,
1177                          vector  min_s,
1178                          vector  max_s,
1179                          float   nodrop,
1180                          void(float _spawnflag)  spawnproc,
1181                          float   _respawntime,
1182                          float() physproc,
1183                          void()  enterproc,
1184                          void(float extflag) exitfunc,
1185                          void() dieproc,
1186                          void() thinkproc,
1187                          float  use_csqc,
1188                          float _max_health,
1189                          float _max_shield)
1190 {
1191         if(!autocvar_g_vehicles)
1192                 return FALSE;
1193
1194     if(self.targetname)
1195     {
1196         self.vehicle_controller = find(world, target, self.targetname);
1197         if(!self.vehicle_controller)
1198         {
1199             bprint("^1WARNING: ^7Vehicle with invalid .targetname\n");
1200         }
1201         else
1202         {
1203             self.team = self.vehicle_controller.team;
1204             self.use = vehicle_use;
1205
1206             if(teamplay)
1207             {
1208                 if(self.vehicle_controller.team == 0)
1209                     self.active = ACTIVE_NOT;
1210                 else
1211                     self.active = ACTIVE_ACTIVE;
1212             }
1213         }
1214     }
1215
1216     precache_sound("onslaught/ons_hit2.wav");
1217     precache_sound("onslaught/electricity_explode.wav");
1218
1219
1220     addstat(STAT_HUD, AS_INT,  hud);
1221         addstat(STAT_VEHICLESTAT_HEALTH,  AS_INT, vehicle_health);
1222         addstat(STAT_VEHICLESTAT_SHIELD,  AS_INT, vehicle_shield);
1223         addstat(STAT_VEHICLESTAT_ENERGY,  AS_INT, vehicle_energy);
1224
1225         addstat(STAT_VEHICLESTAT_AMMO1,   AS_INT, vehicle_ammo1);
1226         addstat(STAT_VEHICLESTAT_RELOAD1, AS_INT, vehicle_reload1);
1227
1228         addstat(STAT_VEHICLESTAT_AMMO2,   AS_INT, vehicle_ammo2);
1229         addstat(STAT_VEHICLESTAT_RELOAD2, AS_INT, vehicle_reload2);
1230
1231     if(bodymodel == "")
1232         error("vehicles: missing bodymodel!");
1233
1234     if(hudmodel == "")
1235         error("vehicles: missing hudmodel!");
1236
1237     if(net_name == "")
1238         self.netname = self.classname;
1239     else
1240         self.netname = net_name;
1241
1242     if(self.team && !teamplay)
1243         self.team = 0;
1244
1245     self.vehicle_flags |= VHF_ISVEHICLE;
1246
1247     setmodel(self, bodymodel);
1248
1249     self.vehicle_viewport   = spawn();
1250     self.vehicle_hudmodel   = spawn();
1251     self.tur_head           = spawn();
1252     self.tur_head.owner     = self;
1253     self.takedamage         = DAMAGE_AIM;
1254     self.bot_attack         = TRUE;
1255     self.iscreature         = TRUE;
1256     self.teleportable       = FALSE; // no teleporting for vehicles, too buggy
1257     self.damagedbycontents      = TRUE;
1258     self.hud                = vhud;
1259     self.tur_health          = _max_health;
1260     self.tur_head.tur_health = _max_shield;
1261     self.vehicle_die         = dieproc;
1262     self.vehicle_exit        = exitfunc;
1263     self.vehicle_enter       = enterproc;
1264     self.PlayerPhysplug      = physproc;
1265     self.event_damage        = vehicles_damage;
1266     self.touch               = vehicles_touch;
1267     self.think               = vehicles_spawn;
1268     self.nextthink           = time;
1269     self.vehicle_respawntime = _respawntime;
1270     self.vehicle_spawn       = spawnproc;
1271     self.effects             = EF_NODRAW;
1272     if(g_assault || !autocvar_g_vehicles_delayspawn)
1273         self.nextthink = time + 0.5;
1274     else
1275         self.nextthink = time + _respawntime + (random() * autocvar_g_vehicles_delayspawn_jitter);
1276
1277
1278     if(autocvar_g_nodepthtestplayers)
1279         self.effects = self.effects | EF_NODEPTHTEST;
1280
1281     if(autocvar_g_fullbrightplayers)
1282         self.effects = self.effects | EF_FULLBRIGHT;
1283
1284     setmodel(self.vehicle_hudmodel, hudmodel);
1285     setmodel(self.vehicle_viewport, "null");
1286
1287     if(topmodel != "")
1288     {
1289         setmodel(self.tur_head, topmodel);
1290         setattachment(self.tur_head, self, toptag);
1291         setattachment(self.vehicle_hudmodel, self.tur_head, hudtag);
1292         setattachment(self.vehicle_viewport, self.vehicle_hudmodel, viewtag);
1293     }
1294     else
1295     {
1296         setattachment(self.tur_head, self, "");
1297         setattachment(self.vehicle_hudmodel, self, hudtag);
1298         setattachment(self.vehicle_viewport, self.vehicle_hudmodel, viewtag);
1299     }
1300
1301     setsize(self, min_s, max_s);
1302     if not (nodrop)
1303     {
1304         setorigin(self, self.origin);
1305         tracebox(self.origin + '0 0 100', min_s, max_s, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
1306         setorigin(self, trace_endpos);
1307     }
1308
1309     self.pos1 = self.origin;
1310     self.pos2 = self.angles;
1311     self.tur_head.team = self.team;
1312
1313     return TRUE;
1314 }
1315
1316 vector vehicle_aimturret(entity _vehic, vector _target, entity _turrret, string _tagname,
1317                          float _pichlimit_min, float _pichlimit_max,
1318                          float _rotlimit_min, float _rotlimit_max, float _aimspeed)
1319 {
1320     vector vtmp, vtag;
1321     float ftmp;
1322     vtag = gettaginfo(_turrret, gettagindex(_turrret, _tagname));
1323     vtmp = vectoangles(normalize(_target - vtag));
1324     vtmp = AnglesTransform_ToAngles(AnglesTransform_LeftDivide(AnglesTransform_FromAngles(_vehic.angles), AnglesTransform_FromAngles(vtmp))) - _turrret.angles;
1325     vtmp = AnglesTransform_Normalize(vtmp, TRUE);
1326     ftmp = _aimspeed * frametime;
1327     vtmp_y = bound(-ftmp, vtmp_y, ftmp);
1328     vtmp_x = bound(-ftmp, vtmp_x, ftmp);
1329     _turrret.angles_y = bound(_rotlimit_min, _turrret.angles_y + vtmp_y, _rotlimit_max);
1330     _turrret.angles_x = bound(_pichlimit_min, _turrret.angles_x + vtmp_x, _pichlimit_max);
1331     return vtag;
1332 }
1333
1334 void vehicles_gib_explode()
1335 {
1336         sound (self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
1337         pointparticles(particleeffectnum("explosion_small"), randomvec() * 80 + (self.origin + '0 0 100'), '0 0 0', 1);
1338         remove(self);
1339 }
1340
1341 void vehicles_gib_think()
1342 {
1343         self.alpha -= 0.1;
1344         if(self.cnt >= time)
1345                 remove(self);
1346         else
1347                 self.nextthink = time + 0.1;
1348 }
1349
1350 entity vehicle_tossgib(entity _template, vector _vel, string _tag, float _burn, float _explode, float _maxtime, vector _rot)
1351 {
1352         entity _gib = spawn();
1353         setmodel(_gib, _template.model);
1354         setorigin(_gib, gettaginfo(self, gettagindex(self, _tag)));
1355         _gib.velocity = _vel;
1356         _gib.movetype = MOVETYPE_TOSS;
1357         _gib.solid = SOLID_CORPSE;
1358         _gib.colormod = '-0.5 -0.5 -0.5';
1359         _gib.effects = EF_LOWPRECISION;
1360         _gib.avelocity = _rot;
1361
1362         if(_burn)
1363                 _gib.effects |= EF_FLAME;
1364
1365         if(_explode)
1366         {
1367                 _gib.think = vehicles_gib_explode;
1368                 _gib.nextthink = time + random() * _explode;
1369                 _gib.touch = vehicles_gib_explode;
1370         }
1371         else
1372         {
1373                 _gib.cnt = time + _maxtime;
1374                 _gib.think = vehicles_gib_think;
1375                 _gib.nextthink = time + _maxtime - 1;
1376                 _gib.alpha = 1;
1377         }
1378         return _gib;
1379 }
1380
1381 /*
1382 vector predict_target(entity _targ, vector _from, float _shot_speed)
1383 {
1384     float i;                // loop
1385     float _distance;        // How far to target
1386     float _impact_time;     // How long untill projectile impacts
1387     vector _predict_pos;    // Predicted enemy location
1388     vector _original_origin;// Where target is before predicted
1389
1390      _original_origin = real_origin(_targ); // Typicaly center of target BBOX
1391
1392     _predict_pos = _original_origin;
1393     for(i = 0; i < 4; ++i)  // Loop a few times to increase prediction accuracy (increase loop count if accuracy is to low)
1394     {
1395         _distance = vlen(_predict_pos - _from); // Get distance to previos predicted location
1396         _impact_time = _distance / _shot_speed; // Calculate impact time
1397         _predict_pos = _original_origin + _targ.velocity * _impact_time; // Calculate new predicted location
1398     }
1399
1400     return _predict_pos;
1401 }
1402 */