qcsrc/server/vote.qc

   1 float VoteCheckNasty(string cmd)
   2 {
   3         if(strstrofs(cmd, ";", 0) >= 0)
   4                 return TRUE;
   5         if(strstrofs(cmd, "\n", 0) >= 0)
   6                 return TRUE;
   7         if(strstrofs(cmd, "\r", 0) >= 0)
   8                 return TRUE;
   9         if(strstrofs(cmd, "$", 0) >= 0)
  10                 return TRUE;
  11         return FALSE;
  12 }
  13
  14 string GetKickVoteVictim_newcommand;
  15 string GetKickVoteVictim_reason;
  16
  17 entity GetKickVoteVictim(string vote, string cmd, entity caller)
  18 {
  19         float tokens;
  20         string ns;
  21         entity e;
  22         string reason;
  23
  24         tokens = tokenize_console(vote);
  25         ns = "";
  26
  27         e = GetCommandPlayerSlotTargetFromTokenizedCommand(tokens, 1);
  28         if(e)
  29         {
  30                 if(ParseCommandPlayerSlotTarget_firsttoken < tokens)
  31                         GetKickVoteVictim_reason = substring(vote, argv_start_index(ParseCommandPlayerSlotTarget_firsttoken), argv_end_index(-1) - argv_start_index(ParseCommandPlayerSlotTarget_firsttoken));
  32                 else
  33                         GetKickVoteVictim_reason = "";
  34
  35                 reason = "";
  36                 if(cmd != "vdo" || GetKickVoteVictim_reason == "")
  37                         reason = "~"; // by convention, ~ prefixes a "unverified" kickban which will not be networked
  38
  39                 if(substring(GetKickVoteVictim_reason, 0, 1) == "~")
  40                 {
  41                         reason = "~";
  42                         GetKickVoteVictim_reason = substring(GetKickVoteVictim_reason, 1, strlen(GetKickVoteVictim_reason) - 1);
  43                 }
  44
  45                 if(caller)
  46                         reason = strcat(reason, "player ", strdecolorize(caller.netname));
  47                 else
  48                         reason = strcat(reason, "console vote");
  49                 if(GetKickVoteVictim_reason != "")
  50                         reason = strcat(reason, ": ", strdecolorize(GetKickVoteVictim_reason));
  51
  52                 if not(cvar_value_issafe(reason))
  53                         reason = uri_escape(reason);
  54
  55                 GetKickVoteVictim_newcommand = strcat(argv(0), " # ", ftos(num_for_edict(e)));
  56                 if(argv(0) == "kickban")
  57                 {
  58                         GetKickVoteVictim_newcommand = strcat(GetKickVoteVictim_newcommand, " ", ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ", reason);
  59                 }
  60                 else if(argv(0) == "kick")
  61                 {
  62                         GetKickVoteVictim_newcommand = strcat(GetKickVoteVictim_newcommand, " ", reason);
  63                 }
  64                 return e;
  65         }
  66
  67         print_to(caller, strcat("Usage: ", cmd, " ", argv(0), " #playernumber (as in \"status\")\n"));
  68         return world;
  69 }
  70
  71 string RemapVote_display;
  72 string RemapVote_vote;
  73 float RemapVote(string vote, string cmd, entity e)
  74 {
  75         float vote_argc;
  76         entity victim;
  77         vote_argc = tokenize_console(vote);
  78
  79         if(!VoteAllowed(argv(0), cmd))
  80                 return FALSE;
  81
  82         // VoteAllowed tokenizes!
  83         vote_argc = tokenize_console(vote);
  84
  85         // remap chmap to gotomap (forces intermission)
  86         if(vote_argc < 2)
  87                 if(argv(0) == "chmap" || argv(0) == "gotomap" || argv(0) == "kick" || argv(0) == "kickban") // won't work without arguments
  88                         return FALSE;
  89         if(argv(0) == "chmap")
  90         {
  91                 vote = strcat("gotomap ", substring(vote, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  92                 vote_argc = tokenize_console(vote);
  93         }
  94         if(argv(0) == "gotomap")
  95         {
  96                 if(!(vote = ValidateMap(substring(vote, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), e)))
  97                         return FALSE;
  98                 vote = strcat("gotomap ", vote);
  99                 vote_argc = tokenize_console(vote); // ValidateMap may have done some stuff to it
 100         }
 101
 102         // make kick and kickban votes a bit nicer (and reject them if formatted badly)
 103         if(argv(0) == "kick" || argv(0) == "kickban")
 104         {
 105                 if(!(victim = GetKickVoteVictim(vote, cmd, e)))
 106                         return FALSE;
 107                 RemapVote_vote = GetKickVoteVictim_newcommand;
 108                 RemapVote_display = strcat("^1", vote, " (^7", victim.netname, "^1): ", GetKickVoteVictim_reason);
 109         }
 110         else
 111         {
 112                 RemapVote_vote = vote;
 113                 RemapVote_display = strzone(strcat("^1", vote));
 114         }
 115
 116         return TRUE;
 117 }
 118
 119 void VoteDialog_UpdateHighlight(float selected) {
 120         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 121         WriteByte(MSG_ONE, TE_CSQC_VOTE);
 122         WriteByte(MSG_ONE, 1);
 123         WriteByte(MSG_ONE, selected);
 124 }
 125
 126 void VoteDialog_Reset() {
 127         WriteByte(MSG_ALL, SVC_TEMPENTITY);
 128         WriteByte(MSG_ALL, TE_CSQC_VOTERESET);
 129 }
 130
 131 float GameCommand_Vote(string s, entity e) {
 132         local float playercount;
 133         float argc;
 134         argc = tokenize_console(s);
 135         if(argv(0) == "help") {
 136                 print_to(e, "  vote COMMANDS ARGUMENTS. See 'vhelp' for more info.");
 137                 return TRUE;
 138         } else if(argv(0) == "vote") {
 139                 if(argv(1) == "") {
 140                         print_to(e, "^1You have to supply a vote command. See 'vhelp' for more info.");
 141                 } else if(argv(1) == "help") {
 142                         VoteHelp(e);
 143                 } else if(argv(1) == "status") {
 144                         if(votecalled) {
 145                                 print_to(e, strcat("^7Vote for ", votecalledvote_display, "^7 called by ^7", VoteNetname(votecaller), "^7."));
 146                         } else {
 147                                 print_to(e, "^1No vote called.");
 148                         }
 149                 } else if(argv(1) == "call") {
 150                         if(!e || autocvar_sv_vote_call) {
 151                                 if(autocvar_sv_vote_nospectators && e && e.classname != "player") {
 152                                         print_to(e, "^1Error: Only players can call a vote."); // TODO invent a cvar name for allowing votes by spectators during warmup anyway
 153                                 }
 154                                 else if(timeoutStatus) { //don't allow a vote call during a timeout
 155                                         print_to(e, "^1Error: You can not call a vote while a timeout is active.");
 156                                 }
 157                                 else if(votecalled) {
 158                                         print_to(e, "^1There is already a vote called.");
 159                                 } else {
 160                                         local string vote;
 161                                         vote = VoteParse(s, argc);
 162                                         if(vote == "") {
 163                                                 print_to(e, "^1Your vote is empty. See 'vhelp' for more info.");
 164                                         } else if(e
 165                                                         && time < e.vote_next) {
 166                                                 print_to(e, strcat("^1You have to wait ^2", ftos(ceil(e.vote_next - time)), "^1 seconds before you can again call a vote."));
 167                                         } else if(VoteCheckNasty(vote)) {
 168                                                 print_to(e, "Syntax error in command. See 'vhelp' for more info.");
 169                                         } else if(RemapVote(vote, "vcall", e)) {
 170                                                 votecalledvote = strzone(RemapVote_vote);
 171                                                 votecalledvote_display = strzone(RemapVote_display);
 172                                                 votecalled = TRUE;
 173                                                 votecalledmaster = FALSE;
 174                                                 votefinished = time + autocvar_sv_vote_timeout;
 175                                                 votecaller = e; // remember who called the vote
 176                                                 if(e) {
 177                                                         e.vote_vote = 1; // of course you vote yes
 178                                                         e.vote_next = time + autocvar_sv_vote_wait;
 179                                                 }
 180                                                 bprint("\{1}^2* ^3", VoteNetname(votecaller), "^2 calls a vote for ", votecalledvote_display, "\n");
 181                                                 if(autocvar_sv_eventlog)
 182                                                         GameLogEcho(strcat(":vote:vcall:", ftos(votecaller.playerid), ":", votecalledvote_display));
 183                                                 VoteCount(); // needed if you are the only one
 184                                                 Nagger_VoteChanged();
 185                                                 msg_entity = e;
 186                                                 VoteDialog_UpdateHighlight(1);
 187
 188                                                 local entity player;
 189                                                 FOR_EACH_REALCLIENT(player)
 190                                                 {
 191                                                         ++playercount;
 192                                                 }
 193                                                 if(playercount > 1) // don't announce a "vote now" sound if player is alone
 194                                                         Announce("votecall");
 195                                         } else {
 196                                                 print_to(e, "^1This vote is not ok. See 'vhelp' for more info.");
 197                                         }
 198                                 }
 199                         } else {
 200                                 print_to(e, "^1Vote calling is NOT allowed.");
 201                         }
 202                 } else if(argv(1) == "stop") {
 203                         if(!votecalled) {
 204                                 print_to(e, "^1No vote called.");
 205                         } else if(e == votecaller) { // the votecaller can stop a vote
 206                                 VoteDialog_Reset();
 207                                 VoteStop(e);
 208                         } else if(!e) { // server admin / console can too
 209                                 VoteDialog_Reset();
 210                                 VoteStop(e);
 211                         } else if(e.vote_master) { // masters can too
 212                                 VoteDialog_Reset();
 213                                 VoteStop(e);
 214                         } else {
 215                                 print_to(e, "^1You are not allowed to stop that Vote.");
 216                         }
 217                 } else if(argv(1) == "master") {
 218                         if(autocvar_sv_vote_master) {
 219                                 if(votecalled) {
 220                                         print_to(e, "^1There is already a vote called.");
 221                                 } else {
 222                                         votecalled = TRUE;
 223                                         votecalledmaster = TRUE;
 224                                         votecalledvote = strzone("XXX");
 225                                         votecalledvote_display = strzone("^3master");
 226                                         votefinished = time + autocvar_sv_vote_timeout;
 227                                         votecaller = e; // remember who called the vote
 228                                         if(e) {
 229                                                 e.vote_vote = 1; // of course you vote yes
 230                                                 e.vote_next = time + autocvar_sv_vote_wait;
 231                                         }
 232                                         bprint("\{1}^2* ^3", VoteNetname(votecaller), "^2 calls a vote to become ^3master^2.\n");
 233                                         if(autocvar_sv_eventlog)
 234                                                 GameLogEcho(strcat(":vote:vcall:", ftos(votecaller.playerid), ":", votecalledvote_display));
 235                                         VoteCount(); // needed if you are the only one
 236                                         Nagger_VoteChanged();
 237                                 }
 238                         } else {
 239                                 print_to(e, "^1Vote to become master is NOT allowed.");
 240                         }
 241                 } else if(argv(1) == "do") {
 242                         if(!e || e.vote_master) {
 243                                 local string dovote;
 244                                 dovote = VoteParse(s, argc);
 245                                 if(dovote == "") {
 246                                         print_to(e, "^1Your command was empty. See 'vhelp' for more info.");
 247                                 } else if(VoteCheckNasty(dovote)) {
 248                                         print_to(e, "Syntax error in command. See 'vhelp' for more info.");
 249                                 } else if(RemapVote(dovote, "vdo", e)) { // strcat seems to be necessary
 250                                         bprint("\{1}^2* ^3", VoteNetname(e), "^2 used their ^3master^2 status to do \"^2", RemapVote_display, "^2\".\n");
 251                                         if(autocvar_sv_eventlog)
 252                                                 GameLogEcho(strcat(":vote:vdo:", ftos(e.playerid), ":", RemapVote_display));
 253                                         localcmd(strcat(RemapVote_vote, "\n"));
 254                                 } else {
 255                                         print_to(e, "^1This command is not ok. See 'vhelp' for more info.");
 256                                 }
 257                         } else {
 258                                 print_to(e, "^1You are NOT a master.  You might need to login or vote to become master first. See 'vhelp' for more info.");
 259                         }
 260                 } else if(argv(1) == "login") {
 261                         local string masterpwd;
 262                         masterpwd = autocvar_sv_vote_master_password;
 263                         if(masterpwd != "") {
 264                                 local float granted;
 265                                 granted = (masterpwd == argv(2));
 266                                 if (e)
 267                                         e.vote_master = granted;
 268                                 if(granted) {
 269                                         print("Accepted master login from ", VoteNetname(e), "\n");
 270                                         bprint("\{1}^2* ^3", VoteNetname(e), "^2 logged in as ^3master^2\n");
 271                                         if(autocvar_sv_eventlog)
 272                                                 GameLogEcho(strcat(":vote:vlogin:", ftos(e.playerid)));
 273                                 }
 274                                 else
 275                                         print("REJECTED master login from ", VoteNetname(e), "\n");
 276                         }
 277                         else
 278                                 print_to(e, "^1Login to become master is NOT allowed.");
 279                 } else if(argv(1) == "yes") {
 280                         if(!votecalled) {
 281                                 print_to(e, "^1No vote called.");
 282                         } else if (!e) {
 283                                 print_to(e, "^1You can't vote from the server console.");
 284                         } else if(e.vote_vote == 0
 285                                   || autocvar_sv_vote_change) {
 286                                 msg_entity = e;
 287                                 VoteDialog_UpdateHighlight(1);
 288                                 print_to(e, "^1You accepted the vote.");
 289                                 e.vote_vote = 1;
 290                                 if(!autocvar_sv_vote_singlecount) {
 291                                         VoteCount();
 292                                 }
 293                         } else {
 294                                 print_to(e, "^1You have already voted.");
 295                         }
 296                 } else if(argv(1) == "no") {
 297                         if(!votecalled) {
 298                                 print_to(e, "^1No vote called.");
 299                         } else if (!e) {
 300                                 print_to(e, "^1You can't vote from the server console.");
 301                         } else if(e.vote_vote == 0
 302                                   || autocvar_sv_vote_change) {
 303                                 msg_entity = e;
 304                                 VoteDialog_UpdateHighlight(2);
 305                                 print_to(e, "^1You rejected the vote.");
 306                                 e.vote_vote = -1;
 307                                 if(!autocvar_sv_vote_singlecount) {
 308                                         VoteCount();
 309                                 }
 310                         } else {
 311                                 print_to(e, "^1You have already voted.");
 312                         }
 313                 } else if(argv(1) == "abstain" || argv(1) == "dontcare") {
 314                         if(!votecalled) {
 315                                 print_to(e, "^1No vote called.");
 316                         } else if (!e) {
 317                                 print_to(e, "^1You can't vote from the server console.");
 318                         } else if(e.vote_vote == 0
 319                                   || autocvar_sv_vote_change) {
 320                                 msg_entity = e;
 321                                 VoteDialog_UpdateHighlight(3);
 322                                 print_to(e, "^1You abstained from your vote.");
 323                                 e.vote_vote = -2;
 324                                 if(!autocvar_sv_vote_singlecount) {
 325                                         VoteCount();
 326                                 }
 327                         } else {
 328                                 print_to(e, "^1You have already voted.");
 329                         }
 330                 } else {
 331                         // ignore this?
 332                         print_to(e, "^1Unknown vote command.");
 333                 }
 334                 return TRUE;
 335         }
 336         return FALSE;
 337 }
 338
 339 void VoteHelp(entity e) {
 340         local string vmasterdis;
 341         if(!autocvar_sv_vote_master) {
 342                 vmasterdis = " ^1(disabled)";
 343         }
 344
 345         local string vlogindis;
 346         if("" == autocvar_sv_vote_master_password) {
 347                 vlogindis = " ^1(disabled)";
 348         }
 349
 350         local string vcalldis;
 351         if(!autocvar_sv_vote_call) {
 352                 vcalldis = " ^1(disabled)";
 353         }
 354
 355         print_to(e, "^7You can use voting with \"^2cmd vote help^7\" \"^2cmd vote status^7\" \"^2cmd vote call ^3COMMAND ARGUMENTS^7\" \"^2cmd vote stop^7\" \"^2cmd vote master^7\" \"^2cmd vote login^7\" \"^2cmd vote do ^3COMMAND ARGUMENTS^7\" \"^2cmd vote yes^7\" \"^2cmd vote no^7\" \"^2cmd vote abstain^7\" \"^2cmd vote dontcare^7\".");
 356         print_to(e, "^7Or if your version is up to date you can use these aliases \"^2vhelp^7\" \"^2vstatus^7\" \"^2vcall ^3COMMAND ARGUMENTS^7\" \"^2vstop^7\" \"^2vmaster^7\" \"^2vlogin^7\" \"^2vdo ^3COMMAND ARGUMENTS^7\" \"^2vyes^7\" \"^2vno^7\" \"^2abstain^7\" \"^2vdontcare^7\".");
 357         print_to(e, "^7\"^2help^7\" shows this info.");
 358         print_to(e, "^7\"^2status^7\" shows if there is a vote called and who called it.");
 359         print_to(e, strcat("^7\"^2call^7\" is used to call a vote. See the list of allowed commands.", vcalldis, "^7"));
 360         print_to(e, "^7\"^2stop^7\" can be used by the vote caller or an admin to stop a vote and maybe correct it.");
 361         print_to(e, strcat("^7\"^2master^7\" call a vote to become master who can execute commands without a vote", vmasterdis, "^7"));
 362         print_to(e, strcat("^7\"^2login^7\" login to become master who can execute commands without a vote.", vlogindis, "^7"));
 363         print_to(e, "^7\"^2do^7\" executes a command if you are a master. See the list of allowed commands.");
 364         print_to(e, "^7\"^2yes^7\", \"^2no^7\", \"^2abstain^7\" and \"^2dontcare^7\" to make your vote.");
 365         print_to(e, "^7If enough of the players vote yes the vote is accepted.");
 366         print_to(e, "^7If enough of the players vote no the vote is rejected.");
 367         print_to(e, strcat("^7If neither the vote will timeout after ", ftos(autocvar_sv_vote_timeout), "^7 seconds."));
 368         print_to(e, "^7You can call a vote for or execute these commands:");
 369         print_to(e, strcat("^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
 370 }
 371
 372 string VoteNetname(entity e)
 373 {
 374         if(e) {
 375                 return e.netname;
 376         } else {
 377                 if(autocvar_sv_adminnick != "") {
 378                         return autocvar_sv_adminnick;
 379                 } else {
 380                         return autocvar_hostname;
 381                 }
 382         }
 383 }
 384
 385 string ValidateMap(string m, entity e)
 386 {
 387         m = MapInfo_FixName(m);
 388         if(!m)
 389         {
 390                 print_to(e, "This map is not available on this server.");
 391                 return string_null;
 392         }
 393         if(!autocvar_sv_vote_override_mostrecent)
 394                 if(Map_IsRecent(m))
 395                 {
 396                         print_to(e, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 397                         return string_null;
 398                 }
 399         if(!MapInfo_CheckMap(m))
 400         {
 401                 print_to(e, strcat("^1Invalid mapname, \"^3", m, "^1\" does not support the current game mode."));
 402                 return string_null;
 403         }
 404
 405         return m;
 406 }
 407
 408
 409 void VoteThink() {
 410         if(votefinished > 0) // a vote was called
 411         if(time > votefinished) // time is up
 412         {
 413                 VoteCount();
 414         }
 415 }
 416
 417 string VoteParse(string all, float argc) {
 418         if(argc < 3)
 419                 return "";
 420         return substring(all, argv_start_index(2), argv_end_index(-1) - argv_start_index(2));
 421 }
 422
 423 float VoteCommandInList(string votecommand, string list)
 424 {
 425         string l;
 426         l = strcat(" ", list, " ");
 427
 428         if(strstrofs(l, strcat(" ", votecommand, " "), 0) >= 0)
 429                 return TRUE;
 430
 431         // if gotomap is allowed, chmap is too, and vice versa
 432         if(votecommand == "gotomap")
 433                 if(strstrofs(l, " chmap ", 0) >= 0)
 434                         return TRUE;
 435         if(votecommand == "chmap")
 436                 if(strstrofs(l, " gotomap ", 0) >= 0)
 437                         return TRUE;
 438
 439         return FALSE;
 440 }
 441
 442 float VoteAllowed(string votecommand, string cmd) {
 443         if(VoteCommandInList(votecommand, autocvar_sv_vote_commands))
 444                 return TRUE;
 445
 446         if(cmd == "vdo")
 447         {
 448                 if(VoteCommandInList(votecommand, autocvar_sv_vote_master_commands))
 449                         return TRUE;
 450         }
 451         else
 452         {
 453                 if(VoteCommandInList(votecommand, autocvar_sv_vote_only_commands))
 454                         return TRUE;
 455         }
 456
 457         return FALSE;
 458 }
 459
 460 void VoteReset() {
 461         local entity player;
 462
 463         FOR_EACH_CLIENT(player)
 464         {
 465                 player.vote_vote = 0;
 466         }
 467
 468         if(votecalled)
 469         {
 470                 strunzone(votecalledvote);
 471                 strunzone(votecalledvote_display);
 472         }
 473
 474         votecalled = FALSE;
 475         votecalledmaster = FALSE;
 476         votefinished = 0;
 477         votecalledvote = string_null;
 478         votecalledvote_display = string_null;
 479 }
 480
 481 void VoteAccept() {
 482         bprint("\{1}^2* ^3", VoteNetname(votecaller), "^2's vote for ^1", votecalledvote_display, "^2 was accepted\n");
 483         if(votecalledmaster)
 484         {
 485                 if(votecaller) {
 486                         votecaller.vote_master = 1;
 487                 }
 488         } else {
 489                 localcmd(strcat(votecalledvote, "\n"));
 490         }
 491         if(votecaller) {
 492                 votecaller.vote_next = 0; // people like your votes,
 493                                           // no wait for next vote
 494         }
 495         VoteReset();
 496         Announce("voteaccept");
 497 }
 498
 499 void VoteReject() {
 500         bprint("\{1}^2* ^3", VoteNetname(votecaller), "^2's vote for ", votecalledvote_display, "^2 was rejected\n");
 501         VoteReset();
 502         Announce("votefail");
 503 }
 504
 505 void VoteTimeout() {
 506         bprint("\{1}^2* ^3", VoteNetname(votecaller), "^2's vote for ", votecalledvote_display, "^2 timed out\n");
 507         VoteReset();
 508         Announce("votefail");
 509 }
 510
 511 void VoteStop(entity stopper) {
 512         bprint("\{1}^2* ^3", VoteNetname(stopper), "^2 stopped ^3", VoteNetname(votecaller), "^2's vote\n");
 513         if(autocvar_sv_eventlog)
 514                 GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid)));
 515         if(stopper == votecaller) {
 516                 // no wait for next vote so you can correct your vote
 517                 if(votecaller) {
 518                         votecaller.vote_next = time + autocvar_sv_vote_stop;
 519                 }
 520         }
 521         VoteReset();
 522 }
 523
 524 void VoteSpam(float yescount, float nocount, float abstaincount, float notvoters, float mincount, string result)
 525 {
 526         string s;
 527         if(mincount >= 0)
 528         {
 529                 s = strcat("\{1}^2* vote results: ^1", ftos(yescount), "^2:^1");
 530                 s = strcat(s, ftos(nocount), "^2 (^1");
 531                 s = strcat(s, ftos(mincount), "^2 needed), ^1");
 532                 s = strcat(s, ftos(abstaincount), "^2 didn't care, ^1");
 533                 s = strcat(s, ftos(notvoters), "^2 didn't vote\n");
 534         }
 535         else
 536         {
 537                 s = strcat("\{1}^2* vote results: ^1", ftos(yescount), "^2:^1");
 538                 s = strcat(s, ftos(nocount), "^2, ^1");
 539                 s = strcat(s, ftos(abstaincount), "^2 didn't care, ^1");
 540                 s = strcat(s, ftos(notvoters), "^2 didn't have to vote\n");
 541         }
 542         bprint(s);
 543         if(autocvar_sv_eventlog)
 544         {
 545                 s = strcat(":vote:v", result, ":", ftos(yescount));
 546                 s = strcat(s, ":", ftos(nocount));
 547                 s = strcat(s, ":", ftos(abstaincount));
 548                 s = strcat(s, ":", ftos(notvoters));
 549                 s = strcat(s, ":", ftos(mincount));
 550                 GameLogEcho(s);
 551         }
 552 }
 553
 554 void VoteDialog_Update(float msg, float vyes, float vno, float needed) {
 555         WriteByte(msg, SVC_TEMPENTITY);
 556         WriteByte(msg, TE_CSQC_VOTE);
 557         WriteByte(msg, 0);
 558         WriteByte(msg, vyes);
 559         WriteByte(msg, vno);
 560         WriteByte(msg, needed);
 561 }
 562
 563 void VoteCount() {
 564         local float playercount;
 565         playercount = 0;
 566         local float yescount;
 567         yescount = 0;
 568         local float nocount;
 569         nocount = 0;
 570         local float abstaincount;
 571         abstaincount = 0;
 572         local entity player;
 573         //same for real players
 574         local float realplayercount;
 575         local float realplayeryescount;
 576         local float realplayernocount;
 577         local float realplayerabstaincount;
 578         realplayercount = realplayernocount = realplayerabstaincount = realplayeryescount = 0;
 579
 580         FOR_EACH_REALCLIENT(player)
 581         {
 582                 if(player.vote_vote == -1) {
 583                         ++nocount;
 584                 } else if(player.vote_vote == 1) {
 585                         ++yescount;
 586                 } else if(player.vote_vote == -2) {
 587                         ++abstaincount;
 588                 }
 589                 ++playercount;
 590                 //do the same for real players
 591                 if(player.classname == "player") {
 592                         if(player.vote_vote == -1) {
 593                                 ++realplayernocount;
 594                         } else if(player.vote_vote == 1) {
 595                                 ++realplayeryescount;
 596                         } else if(player.vote_vote == -2) {
 597                                 ++realplayerabstaincount;
 598                         }
 599                         ++realplayercount;
 600                 }
 601         }
 602
 603         //in tournament mode, if we have at least one player then don't make the vote dependent on spectators (so specs don't have to press F1)
 604         if(autocvar_sv_vote_nospectators)
 605         if(realplayercount > 0) {
 606                 yescount = realplayeryescount;
 607                 nocount = realplayernocount;
 608                 abstaincount = realplayerabstaincount;
 609                 playercount = realplayercount;
 610         }
 611
 612         float votefactor, simplevotefactor;
 613         votefactor = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 614         simplevotefactor = autocvar_sv_vote_simple_majority_factor;
 615         float needed;
 616         needed = floor((playercount - abstaincount) * max(votefactor, simplevotefactor)) + 1;
 617         VoteDialog_Update(MSG_ALL, yescount, nocount, needed);
 618
 619         if(votecalledmaster
 620            && playercount == 1) {
 621                 // if only one player is on the server becoming vote
 622                 // master is not allowed.  This could be used for
 623                 // trolling or worse. 'self' is the user who has
 624                 // called the vote because this function is called
 625                 // by SV_ParseClientCommand. Maybe all voting should
 626                 // be disabled for a single player?
 627                 print_to(votecaller, "^1You are the only player on this server so you can not become vote master.");
 628                 if(votecaller) {
 629                         votecaller.vote_next = 0;
 630                 }
 631                 VoteReset();
 632         } else {
 633                 if(yescount > (playercount - abstaincount) * votefactor)
 634                 {
 635                         VoteSpam(yescount, nocount, abstaincount, playercount - yescount - nocount - abstaincount, -1, "yes");
 636                         VoteAccept();
 637                         VoteDialog_Reset();
 638                 }
 639                 else if(nocount >= (playercount - abstaincount) * (1 - votefactor)) // that means, yescount cannot reach minyes any more
 640                 {
 641                         VoteSpam(yescount, nocount, abstaincount, playercount - yescount - nocount - abstaincount, -1, "no");
 642                         VoteReject();
 643                         VoteDialog_Reset();
 644                 }
 645                 else if(time > votefinished)
 646                 {
 647                         if(simplevotefactor)
 648                         {
 649                                 string result;
 650                                 simplevotefactor = bound(votefactor, simplevotefactor, 0.999);
 651                                 if(yescount > (yescount + nocount) * simplevotefactor)
 652                                         result = "yes";
 653                                 else if(yescount + nocount > 0)
 654                                         result = "no";
 655                                 else
 656                                         result = "timeout";
 657                                 VoteSpam(yescount, nocount, abstaincount, playercount - yescount - nocount - abstaincount, floor(min((playercount - abstaincount) * votefactor, (yescount + nocount) * simplevotefactor)) + 1, result);
 658                                 if(result == "yes")
 659                                         VoteAccept();
 660                                 else if(result == "no")
 661                                         VoteReject();
 662                                 else
 663                                         VoteTimeout();
 664                         }
 665                         else
 666                         {
 667                                 VoteSpam(yescount, nocount, abstaincount, playercount - yescount - nocount - abstaincount, floor((playercount - abstaincount) * votefactor) + 1, "timeout");
 668                                 VoteTimeout();
 669                         }
 670                 VoteDialog_Reset();
 671                 }
 672         }
 673 }