qcsrc/server/w_electro.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(ELECTRO, w_electro, IT_CELLS, 5, WEP_FLAG_NORMAL | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_MID, "electro", "electro", _("Electro"));
   3 #else
   4 #ifdef SVQC
   5 .float electro_count;
   6 .float electro_secondarytime;
   7
   8 .float electro_load;
   9
  10 void W_Electro_SetAmmoCounter()
  11 {
  12         // set clip_load to the weapon we have switched to, if the gun uses reloading
  13         if(!autocvar_g_balance_electro_reload_ammo)
  14                 self.clip_load = 0; // also keeps crosshair ammo from displaying
  15         else
  16         {
  17                 self.clip_load = self.electro_load;
  18                 self.clip_size = autocvar_g_balance_electro_reload_ammo; // for the crosshair ammo display
  19         }
  20 }
  21
  22 void W_Electro_ReloadedAndReady()
  23 {
  24         float t;
  25
  26         // now do the ammo transfer
  27         self.clip_load = self.old_clip_load; // restore the ammo counter, in case we still had ammo in the weapon before reloading
  28         while(self.clip_load < autocvar_g_balance_electro_reload_ammo && self.ammo_cells) // make sure we don't add more ammo than we have
  29         {
  30                 self.clip_load += 1;
  31                 self.ammo_cells -= 1;
  32         }
  33         self.electro_load = self.clip_load;
  34
  35         t = ATTACK_FINISHED(self) - autocvar_g_balance_electro_reload_time - 1;
  36         ATTACK_FINISHED(self) = t;
  37         w_ready();
  38 }
  39
  40 void W_Electro_Reload()
  41 {
  42         // return if reloading is disabled for this weapon
  43         if(!autocvar_g_balance_electro_reload_ammo)
  44                 return;
  45
  46         if(!W_ReloadCheck(self.ammo_cells))
  47                 return;
  48
  49         float t;
  50
  51         sound (self, CHAN_WEAPON2, "weapons/reload.wav", VOL_BASE, ATTN_NORM);
  52
  53         t = max(time, ATTACK_FINISHED(self)) + autocvar_g_balance_electro_reload_time + 1;
  54         ATTACK_FINISHED(self) = t;
  55
  56         weapon_thinkf(WFRAME_RELOAD, autocvar_g_balance_electro_reload_time, W_Electro_ReloadedAndReady);
  57
  58         self.old_clip_load = self.clip_load;
  59         self.clip_load = -1;
  60 }
  61
  62 void W_Plasma_Explode_Combo (void);
  63
  64 void W_Plasma_TriggerCombo(vector org, float rad, entity own)
  65 {
  66         local entity e;
  67         e = WarpZone_FindRadius(org, rad, TRUE);
  68         while (e)
  69         {
  70                 if (e.classname == "plasma")
  71                 {
  72                         // change owner to whoever caused the combo explosion
  73                         e.owner = own;
  74                         e.takedamage = DAMAGE_NO;
  75                         e.classname = "plasma_chain";
  76                         e.think = W_Plasma_Explode_Combo;
  77                         e.nextthink = time + vlen(e.WarpZone_findradius_dist) / autocvar_g_balance_electro_combo_speed; // delay combo chains, looks cooler
  78                 }
  79                 e = e.chain;
  80         }
  81 }
  82
  83 void W_Plasma_Explode (void)
  84 {
  85         if(other.takedamage == DAMAGE_AIM)
  86                 if(other.classname == "player")
  87                         if(IsDifferentTeam(self.owner, other))
  88                                 if(other.deadflag == DEAD_NO)
  89                                         if(IsFlying(other))
  90                                                 AnnounceTo(self.owner, "electrobitch");
  91
  92         self.event_damage = SUB_Null;
  93         self.takedamage = DAMAGE_NO;
  94         if (self.movetype == MOVETYPE_BOUNCE)
  95         {
  96                 RadiusDamage (self, self.owner, autocvar_g_balance_electro_secondary_damage, autocvar_g_balance_electro_secondary_edgedamage, autocvar_g_balance_electro_secondary_radius, world, autocvar_g_balance_electro_secondary_force, self.projectiledeathtype, other);
  97         }
  98         else
  99         {
 100                 W_Plasma_TriggerCombo(self.origin, autocvar_g_balance_electro_primary_comboradius, self.owner);
 101                 RadiusDamage (self, self.owner, autocvar_g_balance_electro_primary_damage, autocvar_g_balance_electro_primary_edgedamage, autocvar_g_balance_electro_primary_radius, world, autocvar_g_balance_electro_primary_force, self.projectiledeathtype, other);
 102         }
 103
 104         remove (self);
 105 }
 106
 107 void W_Plasma_Explode_Combo (void)
 108 {
 109         W_Plasma_TriggerCombo(self.origin, autocvar_g_balance_electro_combo_comboradius, self.owner);
 110
 111         self.event_damage = SUB_Null;
 112         RadiusDamage (self, self.owner, autocvar_g_balance_electro_combo_damage, autocvar_g_balance_electro_combo_edgedamage, autocvar_g_balance_electro_combo_radius, world, autocvar_g_balance_electro_combo_force, WEP_ELECTRO | HITTYPE_BOUNCE, world); // use THIS type for a combo because primary can't bounce
 113         remove (self);
 114 }
 115
 116 void W_Plasma_Touch (void)
 117 {
 118         //self.velocity = self.velocity  * 0.1;
 119
 120         PROJECTILE_TOUCH;
 121         if (other.takedamage == DAMAGE_AIM) {
 122                 W_Plasma_Explode ();
 123         } else {
 124                 //UpdateCSQCProjectile(self);
 125                 spamsound (self, CHAN_PROJECTILE, "weapons/electro_bounce.wav", VOL_BASE, ATTN_NORM);
 126                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 127         }
 128 }
 129
 130 void W_Plasma_TouchExplode (void)
 131 {
 132         PROJECTILE_TOUCH;
 133         W_Plasma_Explode ();
 134 }
 135
 136 void W_Plasma_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 137 {
 138         if(self.health <= 0)
 139                 return;
 140         // note: combos are usually triggered by W_Plasma_TriggerCombo, not damage
 141         self.health = self.health - damage;
 142         if (self.health <= 0)
 143         {
 144                 self.takedamage = DAMAGE_NO;
 145                 self.nextthink = time;
 146                 if (inflictor.classname == "plasma_chain" || inflictor.classname == "plasma_prim")
 147                 {
 148                         // change owner to whoever caused the combo explosion
 149                         self.owner = inflictor.owner;
 150                         self.classname = "plasma_chain";
 151                         self.think = W_Plasma_Explode_Combo;
 152                         self.nextthink = time + min(autocvar_g_balance_electro_combo_radius, vlen(self.origin - inflictor.origin)) / autocvar_g_balance_electro_combo_speed; // delay combo chains, looks cooler
 153                                 //                  ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ bounding the length, because inflictor may be in a galaxy far far away (warpzones)
 154                 }
 155                 else
 156                 {
 157                         self.use = W_Plasma_Explode;
 158                         self.think = adaptor_think2use; // not _hittype_splash, as this runs "immediately"
 159                 }
 160         }
 161 }
 162
 163 void W_Electro_Attack()
 164 {
 165         local entity proj;
 166
 167         W_SetupShot_ProjectileSize (self, '0 0 -3', '0 0 -3', FALSE, 2, "weapons/electro_fire.wav", CHAN_WEAPON, autocvar_g_balance_electro_primary_damage);
 168
 169         pointparticles(particleeffectnum("electro_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 170
 171         proj = spawn ();
 172         proj.classname = "plasma_prim";
 173         proj.owner = self;
 174         proj.bot_dodge = TRUE;
 175         proj.bot_dodgerating = autocvar_g_balance_electro_primary_damage;
 176         proj.use = W_Plasma_Explode;
 177         proj.think = adaptor_think2use_hittype_splash;
 178         proj.nextthink = time + autocvar_g_balance_electro_primary_lifetime;
 179         PROJECTILE_MAKETRIGGER(proj);
 180         proj.projectiledeathtype = WEP_ELECTRO;
 181         setorigin(proj, w_shotorg);
 182
 183         proj.movetype = MOVETYPE_FLY;
 184         W_SETUPPROJECTILEVELOCITY(proj, g_balance_electro_primary);
 185         proj.angles = vectoangles(proj.velocity);
 186         proj.touch = W_Plasma_TouchExplode;
 187         setsize(proj, '0 0 -3', '0 0 -3');
 188         proj.flags = FL_PROJECTILE;
 189
 190         //sound (proj, CHAN_PAIN, "weapons/electro_fly.wav", VOL_BASE, ATTN_NORM);
 191         //sounds bad
 192
 193         CSQCProjectile(proj, TRUE, PROJECTILE_ELECTRO_BEAM, TRUE);
 194
 195         other = proj; MUTATOR_CALLHOOK(EditProjectile);
 196
 197         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 198         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 199         {
 200                 if(autocvar_g_balance_electro_reload_ammo)
 201                 {
 202                         self.clip_load -= autocvar_g_balance_electro_primary_ammo;
 203                         self.electro_load = self.clip_load;
 204                 }
 205                 else
 206                         self.ammo_cells -= autocvar_g_balance_electro_primary_ammo;
 207         }
 208 }
 209
 210 void W_Electro_Attack2()
 211 {
 212         local entity proj;
 213
 214         W_SetupShot_ProjectileSize (self, '0 0 -4', '0 0 -4', FALSE, 2, "weapons/electro_fire2.wav", CHAN_WEAPON, autocvar_g_balance_electro_secondary_damage);
 215
 216         w_shotdir = v_forward; // no TrueAim for grenades please
 217
 218         pointparticles(particleeffectnum("electro_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 219
 220         proj = spawn ();
 221         proj.classname = "plasma";
 222         proj.owner = self;
 223         proj.use = W_Plasma_Explode;
 224         proj.think = adaptor_think2use_hittype_splash;
 225         proj.bot_dodge = TRUE;
 226         proj.bot_dodgerating = autocvar_g_balance_electro_secondary_damage;
 227         proj.nextthink = time + autocvar_g_balance_electro_secondary_lifetime;
 228         PROJECTILE_MAKETRIGGER(proj);
 229         proj.projectiledeathtype = WEP_ELECTRO | HITTYPE_SECONDARY;
 230         setorigin(proj, w_shotorg);
 231
 232         //proj.glow_size = 50;
 233         //proj.glow_color = 45;
 234         proj.movetype = MOVETYPE_BOUNCE;
 235         W_SETUPPROJECTILEVELOCITY_UP(proj, g_balance_electro_secondary);
 236         proj.touch = W_Plasma_Touch;
 237         setsize(proj, '0 0 -4', '0 0 -4');
 238         proj.takedamage = DAMAGE_YES;
 239         proj.damageforcescale = autocvar_g_balance_electro_secondary_damageforcescale;
 240         proj.health = autocvar_g_balance_electro_secondary_health;
 241         proj.event_damage = W_Plasma_Damage;
 242         proj.flags = FL_PROJECTILE;
 243
 244         proj.bouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 245         proj.bouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 246
 247 #if 0
 248         entity p2;
 249         p2 = spawn();
 250         copyentity(proj, p2);
 251         setmodel(p2, "models/ebomb.mdl");
 252         setsize(p2, proj.mins, proj.maxs);
 253 #endif
 254
 255         CSQCProjectile(proj, TRUE, PROJECTILE_ELECTRO, FALSE); // no culling, it has sound
 256
 257         other = proj; MUTATOR_CALLHOOK(EditProjectile);
 258
 259         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 260         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 261         {
 262                 if(autocvar_g_balance_electro_reload_ammo)
 263                 {
 264                         self.clip_load -= autocvar_g_balance_electro_secondary_ammo;
 265                         self.electro_load = self.clip_load;
 266                 }
 267                 else
 268                         self.ammo_cells -= autocvar_g_balance_electro_secondary_ammo;
 269         }
 270 }
 271
 272 .vector hook_start, hook_end;
 273 float lgbeam_send(entity to, float sf)
 274 {
 275         WriteByte(MSG_ENTITY, ENT_CLIENT_LGBEAM);
 276         sf = sf & 0x7F;
 277         if(sound_allowed(MSG_BROADCAST, self.owner))
 278                 sf |= 0x80;
 279         WriteByte(MSG_ENTITY, sf);
 280         if(sf & 1)
 281         {
 282                 WriteByte(MSG_ENTITY, num_for_edict(self.owner));
 283                 WriteCoord(MSG_ENTITY, autocvar_g_balance_electro_primary_range);
 284         }
 285         if(sf & 2)
 286         {
 287                 WriteCoord(MSG_ENTITY, self.hook_start_x);
 288                 WriteCoord(MSG_ENTITY, self.hook_start_y);
 289                 WriteCoord(MSG_ENTITY, self.hook_start_z);
 290         }
 291         if(sf & 4)
 292         {
 293                 WriteCoord(MSG_ENTITY, self.hook_end_x);
 294                 WriteCoord(MSG_ENTITY, self.hook_end_y);
 295                 WriteCoord(MSG_ENTITY, self.hook_end_z);
 296         }
 297         return TRUE;
 298 }
 299 .entity lgbeam;
 300 .float prevlgfire;
 301 void lgbeam_think()
 302 {
 303         self.owner.prevlgfire = time;
 304         if (self != self.owner.lgbeam)
 305         {
 306                 remove(self);
 307                 return;
 308         }
 309         if (self.owner.weaponentity.state != WS_INUSE || (self.owner.ammo_cells <= 0 && !(self.owner.items & IT_UNLIMITED_WEAPON_AMMO)) || self.owner.deadflag != DEAD_NO || !self.owner.BUTTON_ATCK || self.owner.freezetag_frozen)
 310         {
 311                 if(self == self.owner.lgbeam)
 312                         self.owner.lgbeam = world;
 313                 remove(self);
 314                 return;
 315         }
 316
 317         self.nextthink = time;
 318
 319         makevectors(self.owner.v_angle);
 320
 321         float dt, f;
 322         dt = frametime;
 323         if not(self.owner.items & IT_UNLIMITED_WEAPON_AMMO)
 324         {
 325
 326                 /*dt = min(dt, self.owner.ammo_cells / autocvar_g_balance_electro_primary_ammo);
 327                 self.owner.ammo_cells = max(0, self.owner.ammo_cells - autocvar_g_balance_electro_primary_ammo * frametime);*/
 328
 329                 // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 330                 if(autocvar_g_balance_electro_primary_ammo)
 331                 {
 332                         if(autocvar_g_balance_electro_reload_ammo)
 333                         {
 334                                 dt = min(dt, self.owner.clip_load / autocvar_g_balance_electro_primary_ammo);
 335                                 self.owner.clip_load = max(0, self.owner.clip_load - autocvar_g_balance_electro_primary_ammo * frametime);
 336                                 self.electro_load = self.clip_load;
 337                         }
 338                         else
 339                         {
 340                                 dt = min(dt, self.owner.ammo_cells / autocvar_g_balance_electro_primary_ammo);
 341                                 self.owner.ammo_cells = max(0, self.owner.ammo_cells - autocvar_g_balance_electro_primary_ammo * frametime);
 342                         }
 343                 }
 344         }
 345
 346         W_SetupShot_Range(self.owner, TRUE, 0, "", 0, autocvar_g_balance_electro_primary_damage * dt, autocvar_g_balance_electro_primary_range);
 347         WarpZone_traceline_antilag(self.owner, w_shotorg, w_shotend, MOVE_NORMAL, self.owner, ANTILAG_LATENCY(self.owner));
 348
 349         // apply the damage
 350         if(trace_ent)
 351         {
 352                 vector force;
 353                 force = w_shotdir * autocvar_g_balance_electro_primary_force + '0 0 1' * autocvar_g_balance_electro_primary_force_up;
 354
 355                 f = ExponentialFalloff(autocvar_g_balance_electro_primary_falloff_mindist, autocvar_g_balance_electro_primary_falloff_maxdist, autocvar_g_balance_electro_primary_falloff_halflifedist, vlen(WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos) - w_shotorg));
 356
 357                 if(accuracy_isgooddamage(self.owner, trace_ent))
 358                         accuracy_add(self.owner, WEP_ELECTRO, 0, autocvar_g_balance_electro_primary_damage * dt * f);
 359                 Damage (trace_ent, self.owner, self.owner, autocvar_g_balance_electro_primary_damage * dt * f, WEP_ELECTRO, trace_endpos, force * dt);
 360         }
 361         W_Plasma_TriggerCombo(trace_endpos, autocvar_g_balance_electro_primary_comboradius, self.owner);
 362
 363         // draw effect
 364         if(w_shotorg != self.hook_start)
 365         {
 366                 self.SendFlags |= 2;
 367                 self.hook_start = w_shotorg;
 368         }
 369         if(w_shotend != self.hook_end)
 370         {
 371                 self.SendFlags |= 4;
 372                 self.hook_end = w_shotend;
 373         }
 374 }
 375
 376 // experimental lightning gun
 377 void W_Electro_Attack3 (void)
 378 {
 379         // only play fire sound if 0.5 sec has passed since player let go the fire button
 380         if(time - self.prevlgfire > 0.5)
 381                 sound (self, CHAN_WEAPON, "weapons/lgbeam_fire.wav", VOL_BASE, ATTN_NORM);
 382
 383         entity beam, oldself;
 384
 385         self.lgbeam = beam = spawn();
 386         beam.classname = "lgbeam";
 387         beam.solid = SOLID_NOT;
 388         beam.think = lgbeam_think;
 389         beam.owner = self;
 390         beam.movetype = MOVETYPE_NONE;
 391         beam.shot_spread = 0;
 392         beam.bot_dodge = TRUE;
 393         beam.bot_dodgerating = autocvar_g_balance_electro_primary_damage;
 394         Net_LinkEntity(beam, FALSE, 0, lgbeam_send);
 395
 396         oldself = self;
 397         self = beam;
 398         self.think();
 399         self = oldself;
 400 }
 401
 402 void ElectroInit()
 403 {
 404         weapon_action(WEP_ELECTRO, WR_PRECACHE);
 405         electro_shotorigin[0] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ELECTRO), FALSE, FALSE, 1);
 406         electro_shotorigin[1] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ELECTRO), FALSE, FALSE, 2);
 407         electro_shotorigin[2] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ELECTRO), FALSE, FALSE, 3);
 408         electro_shotorigin[3] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ELECTRO), FALSE, FALSE, 4);
 409 }
 410
 411 void spawnfunc_weapon_electro (void)
 412 {
 413         weapon_defaultspawnfunc(WEP_ELECTRO);
 414 }
 415
 416 void w_electro_checkattack()
 417 {
 418         if(self.electro_count > 1)
 419         if(self.BUTTON_ATCK2)
 420         if(weapon_prepareattack(1, -1))
 421         {
 422                 W_Electro_Attack2();
 423                 self.electro_count -= 1;
 424                 weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_electro_secondary_animtime, w_electro_checkattack);
 425                 return;
 426         }
 427
 428         w_ready();
 429 }
 430
 431 .float bot_secondary_electromooth;
 432 .float BUTTON_ATCK_prev;
 433 float w_electro(float req)
 434 {
 435         if (req == WR_AIM)
 436         {
 437                 self.BUTTON_ATCK=FALSE;
 438                 self.BUTTON_ATCK2=FALSE;
 439                 if(vlen(self.origin-self.enemy.origin) > 1000)
 440                         self.bot_secondary_electromooth = 0;
 441                 if(self.bot_secondary_electromooth == 0)
 442                 {
 443                         float shoot;
 444
 445                         if(autocvar_g_balance_electro_primary_speed)
 446                                 shoot = bot_aim(autocvar_g_balance_electro_primary_speed, 0, autocvar_g_balance_electro_primary_lifetime, FALSE);
 447                         else
 448                                 shoot = bot_aim(1000000, 0, 0.001, FALSE);
 449
 450                         if(shoot)
 451                         {
 452                                 self.BUTTON_ATCK = TRUE;
 453                                 if(random() < 0.01) self.bot_secondary_electromooth = 1;
 454                         }
 455                 }
 456                 else
 457                 {
 458                         if(bot_aim(autocvar_g_balance_electro_secondary_speed, autocvar_g_balance_grenadelauncher_secondary_speed_up, autocvar_g_balance_electro_secondary_lifetime, TRUE))
 459                         {
 460                                 self.BUTTON_ATCK2 = TRUE;
 461                                 if(random() < 0.03) self.bot_secondary_electromooth = 0;
 462                         }
 463                 }
 464         }
 465         else if (req == WR_THINK)
 466         {
 467                 if(autocvar_g_balance_electro_reload_ammo && self.clip_load < min(autocvar_g_balance_electro_primary_ammo, autocvar_g_balance_electro_secondary_ammo)) // forced reload
 468                         W_Electro_Reload();
 469                 else if (self.BUTTON_ATCK)
 470                 {
 471                         if(autocvar_g_balance_electro_lightning)
 472                                 if(self.BUTTON_ATCK_prev)
 473                                 {
 474                                         // prolong the animtime while the gun is being fired
 475                                         if(self.animstate_startframe == self.anim_shoot_x && self.animstate_numframes == self.anim_shoot_y)
 476                                                 weapon_thinkf(WFRAME_DONTCHANGE, autocvar_g_balance_electro_primary_animtime, w_ready);
 477                                         else
 478                                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_electro_primary_animtime, w_ready);
 479                                 }
 480                         if (weapon_prepareattack(0, (autocvar_g_balance_electro_lightning ? 0 : autocvar_g_balance_electro_primary_refire)))
 481                         {
 482                                 if(autocvar_g_balance_electro_lightning)
 483                                 {
 484                                         if ((!self.lgbeam) || wasfreed(self.lgbeam))
 485                                         {
 486                                                 W_Electro_Attack3();
 487                                         }
 488                                         if(!self.BUTTON_ATCK_prev)
 489                                         {
 490                                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_electro_primary_animtime, w_ready);
 491                                                 self.BUTTON_ATCK_prev = 1;
 492                                         }
 493                                 }
 494                                 else
 495                                 {
 496                                         W_Electro_Attack();
 497                                         weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_electro_primary_animtime, w_ready);
 498                                 }
 499                         }
 500                 } else {
 501                         if(autocvar_g_balance_electro_lightning)
 502                         {
 503                                 if (self.BUTTON_ATCK_prev != 0)
 504                                 {
 505                                         weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_electro_primary_animtime, w_ready);
 506                                         ATTACK_FINISHED(self) = time + autocvar_g_balance_electro_primary_refire * W_WeaponRateFactor();
 507                                 }
 508                                 self.BUTTON_ATCK_prev = 0;
 509                         }
 510
 511                         if (self.BUTTON_ATCK2)
 512                         {
 513                                 if (time >= self.electro_secondarytime)
 514                                 if (weapon_prepareattack(1, autocvar_g_balance_electro_secondary_refire))
 515                                 {
 516                                         W_Electro_Attack2();
 517                                         self.electro_count = autocvar_g_balance_electro_secondary_count;
 518                                         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_electro_secondary_animtime, w_electro_checkattack);
 519                                         self.electro_secondarytime = time + autocvar_g_balance_electro_secondary_refire2 * W_WeaponRateFactor();
 520                                 }
 521                         }
 522                 }
 523
 524         if(self.wish_reload)
 525         {
 526             if(self.switchweapon == self.weapon)
 527             {
 528                 if(self.weaponentity.state == WS_READY)
 529                 {
 530                     self.wish_reload = 0;
 531                     W_Electro_Reload();
 532                 }
 533             }
 534         }
 535         }
 536         else if (req == WR_PRECACHE)
 537         {
 538                 precache_model ("models/weapons/g_electro.md3");
 539                 precache_model ("models/weapons/v_electro.md3");
 540                 precache_model ("models/weapons/h_electro.iqm");
 541                 precache_sound ("weapons/electro_bounce.wav");
 542                 precache_sound ("weapons/electro_fire.wav");
 543                 precache_sound ("weapons/electro_fire2.wav");
 544                 precache_sound ("weapons/electro_impact.wav");
 545                 precache_sound ("weapons/electro_impact_combo.wav");
 546                 if(autocvar_g_balance_electro_lightning)
 547                 {
 548                         precache_sound ("weapons/lgbeam_fire.wav");
 549                 }
 550         }
 551         else if (req == WR_SETUP)
 552         {
 553                 weapon_setup(WEP_ELECTRO);
 554                 W_Electro_SetAmmoCounter();
 555         }
 556         else if (req == WR_CHECKAMMO1)
 557         {
 558                 if(autocvar_g_balance_electro_reload_ammo)
 559                 {
 560                         if(autocvar_g_balance_electro_lightning)
 561                                 return !autocvar_g_balance_electro_primary_ammo || (self.electro_load > 0);
 562                         else
 563                                 return self.electro_load >= autocvar_g_balance_electro_primary_ammo;
 564                 }
 565                 else
 566                 {
 567                         if(autocvar_g_balance_electro_lightning)
 568                                 return !autocvar_g_balance_electro_primary_ammo || (self.ammo_cells > 0);
 569                         else
 570                                 return self.ammo_cells >= autocvar_g_balance_electro_primary_ammo;
 571                 }
 572         }
 573         else if (req == WR_CHECKAMMO2)
 574         {
 575                 if(autocvar_g_balance_electro_reload_ammo)
 576                         return self.electro_load >= autocvar_g_balance_electro_secondary_ammo;
 577                 else
 578                         return self.ammo_cells >= autocvar_g_balance_electro_secondary_ammo;
 579         }
 580         else if (req == WR_RESETPLAYER)
 581         {
 582                 self.electro_secondarytime = time;
 583         }
 584         else if (req == WR_RELOAD)
 585         {
 586                 W_Shotgun_Reload();
 587         }
 588         return TRUE;
 589 };
 590 #endif
 591 #ifdef CSQC
 592 float w_electro(float req)
 593 {
 594         if(req == WR_IMPACTEFFECT)
 595         {
 596                 vector org2;
 597                 org2 = w_org + w_backoff * 6;
 598                 if(w_deathtype & HITTYPE_SECONDARY)
 599                 {
 600                         pointparticles(particleeffectnum("electro_ballexplode"), org2, '0 0 0', 1);
 601                         if(!w_issilent)
 602                                 sound(self, CHAN_PROJECTILE, "weapons/electro_impact.wav", VOL_BASE, ATTN_NORM);
 603                 }
 604                 else
 605                 {
 606                         if(w_deathtype & HITTYPE_BOUNCE)
 607                         {
 608                                 // this is sent as "primary (w_deathtype & HITTYPE_BOUNCE)" to distinguish it from (w_deathtype & HITTYPE_SECONDARY) bounced balls
 609                                 pointparticles(particleeffectnum("electro_combo"), org2, '0 0 0', 1);
 610                                 if(!w_issilent)
 611                                         sound(self, CHAN_PROJECTILE, "weapons/electro_impact_combo.wav", VOL_BASE, ATTN_NORM);
 612                         }
 613                         else
 614                         {
 615                                 pointparticles(particleeffectnum("electro_impact"), org2, '0 0 0', 1);
 616                                 if(!w_issilent)
 617                                         sound(self, CHAN_PROJECTILE, "weapons/electro_impact.wav", VOL_BASE, ATTN_NORM);
 618                         }
 619                 }
 620         }
 621         else if(req == WR_PRECACHE)
 622         {
 623                 precache_sound("weapons/electro_impact.wav");
 624                 precache_sound("weapons/electro_impact_combo.wav");
 625         }
 626         else if (req == WR_SUICIDEMESSAGE)
 627         {
 628                 if(w_deathtype & HITTYPE_SECONDARY)
 629                         w_deathtypestring = "%s could not remember where they put plasma";
 630                 else
 631                         w_deathtypestring = "%s played with plasma";
 632         }
 633         else if (req == WR_KILLMESSAGE)
 634         {
 635                 if(w_deathtype & HITTYPE_SECONDARY)
 636                 {
 637                         if(w_deathtype & HITTYPE_SPLASH) // unchecked: BOUNCE
 638                                 w_deathtypestring = "%s just noticed %s's blue ball";
 639                         else // unchecked: BOUNCE
 640                                 w_deathtypestring = "%s got in touch with %s's blue ball";
 641                 }
 642                 else
 643                 {
 644                         if(w_deathtype & HITTYPE_BOUNCE) // combo
 645                                 w_deathtypestring = "%s felt the electrifying air of %s's combo";
 646                         else if(w_deathtype & HITTYPE_SPLASH)
 647                                 w_deathtypestring = "%s got too close to %s's blue beam";
 648                         else
 649                                 w_deathtypestring = "%s was blasted by %s's blue beam";
 650                 }
 651         }
 652         return TRUE;
 653 }
 654 #endif
 655 #endif