qcsrc/server/w_grenadelauncher.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(GRENADE_LAUNCHER, w_glauncher, IT_ROCKETS, 4, WEP_FLAG_NORMAL | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_MID, "gl", "grenadelauncher", _("Mortar"))
   3 #else
   4 #ifdef SVQC
   5 .float gl_detonate_later;
   6 .float gl_bouncecnt;
   7
   8 .float grenadelauncher_load;
   9
  10 void W_GrenadeLauncher_SetAmmoCounter()
  11 {
  12         // set clip_load to the weapon we have switched to, if the gun uses reloading
  13         if(!autocvar_g_balance_grenadelauncher_reload_ammo)
  14                 self.clip_load = 0; // also keeps crosshair ammo from displaying
  15         else
  16         {
  17                 self.clip_load = self.grenadelauncher_load;
  18                 self.clip_size = autocvar_g_balance_grenadelauncher_reload_ammo; // for the crosshair ammo display
  19         }
  20 }
  21
  22 void W_GrenadeLauncher_ReloadedAndReady()
  23 {
  24         float t;
  25
  26         // now do the ammo transfer
  27         self.clip_load = self.old_clip_load; // restore the ammo counter, in case we still had ammo in the weapon before reloading
  28         while(self.clip_load < autocvar_g_balance_grenadelauncher_reload_ammo && self.ammo_rockets) // make sure we don't add more ammo than we have
  29         {
  30                 self.clip_load += 1;
  31                 self.ammo_rockets -= 1;
  32         }
  33         self.grenadelauncher_load = self.clip_load;
  34
  35         t = ATTACK_FINISHED(self) - autocvar_g_balance_grenadelauncher_reload_time - 1;
  36         ATTACK_FINISHED(self) = t;
  37         w_ready();
  38 }
  39
  40 void W_GrenadeLauncher_Reload()
  41 {
  42         // return if reloading is disabled for this weapon
  43         if(!autocvar_g_balance_grenadelauncher_reload_ammo)
  44                 return;
  45
  46         if(!W_ReloadCheck(self.ammo_rockets))
  47                 return;
  48
  49         float t;
  50
  51         sound (self, CHAN_WEAPON2, "weapons/reload.wav", VOL_BASE, ATTN_NORM);
  52
  53         t = max(time, ATTACK_FINISHED(self)) + autocvar_g_balance_grenadelauncher_reload_time + 1;
  54         ATTACK_FINISHED(self) = t;
  55
  56         weapon_thinkf(WFRAME_RELOAD, autocvar_g_balance_grenadelauncher_reload_time, W_GrenadeLauncher_ReloadedAndReady);
  57
  58         self.old_clip_load = self.clip_load;
  59         self.clip_load = -1;
  60 }
  61
  62 void W_Grenade_Explode (void)
  63 {
  64         if(other.takedamage == DAMAGE_AIM)
  65                 if(other.classname == "player")
  66                         if(IsDifferentTeam(self.owner, other))
  67                                 if(other.deadflag == DEAD_NO)
  68                                         if(IsFlying(other))
  69                                                 AnnounceTo(self.owner, "airshot");
  70
  71         self.event_damage = SUB_Null;
  72         self.takedamage = DAMAGE_NO;
  73
  74         if(self.movetype == MOVETYPE_NONE)
  75                 self.velocity = self.oldvelocity;
  76
  77         RadiusDamage (self, self.owner, autocvar_g_balance_grenadelauncher_primary_damage, autocvar_g_balance_grenadelauncher_primary_edgedamage, autocvar_g_balance_grenadelauncher_primary_radius, world, autocvar_g_balance_grenadelauncher_primary_force, self.projectiledeathtype, other);
  78
  79         remove (self);
  80 }
  81
  82 void W_Grenade_Explode2 (void)
  83 {
  84         if(other.takedamage == DAMAGE_AIM)
  85                 if(other.classname == "player")
  86                         if(IsDifferentTeam(self.owner, other))
  87                                 if(IsFlying(other))
  88                                         AnnounceTo(self.owner, "airshot");
  89
  90         self.event_damage = SUB_Null;
  91         self.takedamage = DAMAGE_NO;
  92
  93         if(self.movetype == MOVETYPE_NONE)
  94                 self.velocity = self.oldvelocity;
  95
  96         RadiusDamage (self, self.owner, autocvar_g_balance_grenadelauncher_secondary_damage, autocvar_g_balance_grenadelauncher_secondary_edgedamage, autocvar_g_balance_grenadelauncher_secondary_radius, world, autocvar_g_balance_grenadelauncher_secondary_force, self.projectiledeathtype, other);
  97
  98         remove (self);
  99 }
 100
 101 void W_Grenade_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 102 {
 103         if (self.health <= 0)
 104                 return;
 105         self.health = self.health - damage;
 106         if (self.health <= 0)
 107         {
 108                 W_PrepareExplosionByDamage(attacker, self.think);
 109         }
 110 }
 111
 112 void W_Grenade_Think1 (void)
 113 {
 114         self.nextthink = time;
 115         if (time > self.cnt)
 116         {
 117                 other = world;
 118                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 119                 W_Grenade_Explode ();
 120                 return;
 121         }
 122         if(self.gl_detonate_later && self.gl_bouncecnt >= autocvar_g_balance_grenadelauncher_primary_remote_minbouncecnt)
 123                 W_Grenade_Explode();
 124 }
 125
 126 void W_Grenade_Touch1 (void)
 127 {
 128         PROJECTILE_TOUCH;
 129         if (other.takedamage == DAMAGE_AIM || autocvar_g_balance_grenadelauncher_primary_type == 0) // always explode when hitting a player, or if normal mortar projectile
 130         {
 131                 self.use ();
 132         }
 133         else if (autocvar_g_balance_grenadelauncher_primary_type == 1) // bounce
 134         {
 135                 float r;
 136                 r = random() * 6;
 137                 if(r < 1)
 138                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce1.wav", VOL_BASE, ATTN_NORM);
 139                 else if(r < 2)
 140                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce2.wav", VOL_BASE, ATTN_NORM);
 141                 else if(r < 3)
 142                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce3.wav", VOL_BASE, ATTN_NORM);
 143                 else if(r < 4)
 144                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce4.wav", VOL_BASE, ATTN_NORM);
 145                 else if(r < 5)
 146                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce5.wav", VOL_BASE, ATTN_NORM);
 147                 else
 148                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce6.wav", VOL_BASE, ATTN_NORM);
 149                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 150                 self.gl_bouncecnt += 1;
 151         }
 152         else if(autocvar_g_balance_grenadelauncher_primary_type == 2 && (!other || (other.takedamage != DAMAGE_AIM && other.movetype == MOVETYPE_NONE))) // stick
 153         {
 154                 spamsound (self, CHAN_PROJECTILE, "weapons/grenade_stick.wav", VOL_BASE, ATTN_NORM);
 155
 156                 // let it stick whereever it is
 157                 self.oldvelocity = self.velocity;
 158                 self.velocity = '0 0 0';
 159                 self.movetype = MOVETYPE_NONE; // also disables gravity
 160                 self.gravity = 0; // nope, it does NOT! maybe a bug in CSQC code? TODO
 161                 UpdateCSQCProjectile(self);
 162
 163                 // do not respond to any more touches
 164                 self.solid = SOLID_NOT;
 165
 166                 self.nextthink = min(self.nextthink, time + autocvar_g_balance_grenadelauncher_primary_lifetime2);
 167         }
 168 }
 169
 170 void W_Grenade_Touch2 (void)
 171 {
 172         PROJECTILE_TOUCH;
 173         if (other.takedamage == DAMAGE_AIM || autocvar_g_balance_grenadelauncher_secondary_type == 0) // always explode when hitting a player, or if normal mortar projectile
 174         {
 175                 self.use ();
 176         }
 177         else if (autocvar_g_balance_grenadelauncher_secondary_type == 1) // bounce
 178         {
 179                 float r;
 180                 r = random() * 6;
 181                 if(r < 1)
 182                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce1.wav", VOL_BASE, ATTN_NORM);
 183                 else if(r < 2)
 184                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce2.wav", VOL_BASE, ATTN_NORM);
 185                 else if(r < 3)
 186                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce3.wav", VOL_BASE, ATTN_NORM);
 187                 else if(r < 4)
 188                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce4.wav", VOL_BASE, ATTN_NORM);
 189                 else if(r < 5)
 190                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce5.wav", VOL_BASE, ATTN_NORM);
 191                 else
 192                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce6.wav", VOL_BASE, ATTN_NORM);
 193                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 194                 self.gl_bouncecnt += 1;
 195         }
 196         else if(autocvar_g_balance_grenadelauncher_secondary_type == 2 && (!other || (other.takedamage != DAMAGE_AIM && other.movetype == MOVETYPE_NONE))) // stick
 197         {
 198                 spamsound (self, CHAN_PROJECTILE, "weapons/grenade_stick.wav", VOL_BASE, ATTN_NORM);
 199
 200                 // let it stick whereever it is
 201                 self.oldvelocity = self.velocity;
 202                 self.velocity = '0 0 0';
 203                 self.movetype = MOVETYPE_NONE; // also disables gravity
 204                 self.gravity = 0; // nope, it does NOT! maybe a bug in CSQC code? TODO
 205                 UpdateCSQCProjectile(self);
 206
 207                 // do not respond to any more touches
 208                 self.solid = SOLID_NOT;
 209
 210                 self.nextthink = min(self.nextthink, time + autocvar_g_balance_grenadelauncher_secondary_lifetime2);
 211         }
 212 }
 213
 214 void W_Grenade_Attack (void)
 215 {
 216         local entity gren;
 217
 218         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 219         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 220         {
 221                 if(autocvar_g_balance_grenadelauncher_reload_ammo)
 222                 {
 223                         self.clip_load -= autocvar_g_balance_grenadelauncher_primary_ammo;
 224                         self.grenadelauncher_load = self.clip_load;
 225                 }
 226                 else
 227                         self.ammo_rockets -= autocvar_g_balance_grenadelauncher_primary_ammo;
 228         }
 229
 230         W_SetupShot_ProjectileSize (self, '-3 -3 -3', '3 3 3', FALSE, 4, "weapons/grenade_fire.wav", CHAN_WEAPON, autocvar_g_balance_grenadelauncher_primary_damage);
 231         w_shotdir = v_forward; // no TrueAim for grenades please
 232
 233         pointparticles(particleeffectnum("grenadelauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 234
 235         gren = spawn ();
 236         gren.owner = self;
 237         gren.classname = "grenade";
 238         gren.bot_dodge = TRUE;
 239         gren.bot_dodgerating = autocvar_g_balance_grenadelauncher_primary_damage;
 240         gren.movetype = MOVETYPE_BOUNCE;
 241         gren.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 242         gren.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 243         PROJECTILE_MAKETRIGGER(gren);
 244         gren.projectiledeathtype = WEP_GRENADE_LAUNCHER;
 245         setorigin(gren, w_shotorg);
 246         setsize(gren, '-3 -3 -3', '3 3 3');
 247
 248         gren.cnt = time + autocvar_g_balance_grenadelauncher_primary_lifetime;
 249         gren.nextthink = time;
 250         gren.think = W_Grenade_Think1;
 251         gren.use = W_Grenade_Explode;
 252         gren.touch = W_Grenade_Touch1;
 253
 254         gren.takedamage = DAMAGE_YES;
 255         gren.health = autocvar_g_balance_grenadelauncher_primary_health;
 256         gren.damageforcescale = autocvar_g_balance_grenadelauncher_primary_damageforcescale;
 257         gren.event_damage = W_Grenade_Damage;
 258         W_SETUPPROJECTILEVELOCITY_UP(gren, g_balance_grenadelauncher_primary);
 259
 260         gren.angles = vectoangles (gren.velocity);
 261         gren.flags = FL_PROJECTILE;
 262
 263         if(autocvar_g_balance_grenadelauncher_primary_type == 0 || autocvar_g_balance_grenadelauncher_primary_type == 2)
 264                 CSQCProjectile(gren, TRUE, PROJECTILE_GRENADE, TRUE);
 265         else
 266                 CSQCProjectile(gren, TRUE, PROJECTILE_GRENADE_BOUNCING, TRUE);
 267
 268         other = gren; MUTATOR_CALLHOOK(EditProjectile);
 269 }
 270
 271 void W_Grenade_Attack2 (void)
 272 {
 273         local entity gren;
 274
 275         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 276         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 277         {
 278                 if(autocvar_g_balance_grenadelauncher_reload_ammo)
 279                 {
 280                         self.clip_load -= autocvar_g_balance_grenadelauncher_secondary_ammo;
 281                         self.grenadelauncher_load = self.clip_load;
 282                 }
 283                 else
 284                         self.ammo_rockets -= autocvar_g_balance_grenadelauncher_secondary_ammo;
 285         }
 286
 287         W_SetupShot_ProjectileSize (self, '-3 -3 -3', '3 3 3', FALSE, 4, "weapons/grenade_fire.wav", CHAN_WEAPON, autocvar_g_balance_grenadelauncher_secondary_damage);
 288         w_shotdir = v_forward; // no TrueAim for grenades please
 289
 290         pointparticles(particleeffectnum("grenadelauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 291
 292         gren = spawn ();
 293         gren.owner = self;
 294         gren.classname = "grenade";
 295         gren.bot_dodge = TRUE;
 296         gren.bot_dodgerating = autocvar_g_balance_grenadelauncher_secondary_damage;
 297         gren.movetype = MOVETYPE_BOUNCE;
 298         gren.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 299         gren.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 300         PROJECTILE_MAKETRIGGER(gren);
 301         gren.projectiledeathtype = WEP_GRENADE_LAUNCHER | HITTYPE_SECONDARY;
 302         setorigin(gren, w_shotorg);
 303         setsize(gren, '-3 -3 -3', '3 3 3');
 304
 305         gren.nextthink = time + autocvar_g_balance_grenadelauncher_secondary_lifetime;
 306         gren.think = adaptor_think2use_hittype_splash;
 307         gren.use = W_Grenade_Explode2;
 308         gren.touch = W_Grenade_Touch2;
 309
 310         gren.takedamage = DAMAGE_YES;
 311         gren.health = autocvar_g_balance_grenadelauncher_secondary_health;
 312         gren.damageforcescale = autocvar_g_balance_grenadelauncher_secondary_damageforcescale;
 313         gren.event_damage = W_Grenade_Damage;
 314         W_SETUPPROJECTILEVELOCITY_UP(gren, g_balance_grenadelauncher_secondary);
 315
 316         gren.angles = vectoangles (gren.velocity);
 317         gren.flags = FL_PROJECTILE;
 318
 319         if(autocvar_g_balance_grenadelauncher_secondary_type == 0 || autocvar_g_balance_grenadelauncher_secondary_type == 2)
 320                 CSQCProjectile(gren, TRUE, PROJECTILE_GRENADE, TRUE);
 321         else
 322                 CSQCProjectile(gren, TRUE, PROJECTILE_GRENADE_BOUNCING, TRUE);
 323
 324         other = gren; MUTATOR_CALLHOOK(EditProjectile);
 325 }
 326
 327 void spawnfunc_weapon_grenadelauncher (void)
 328 {
 329         weapon_defaultspawnfunc(WEP_GRENADE_LAUNCHER);
 330 }
 331
 332 .float bot_secondary_grenademooth;
 333 float w_glauncher(float req)
 334 {
 335         entity nade;
 336         float nadefound;
 337
 338         if (req == WR_AIM)
 339         {
 340                 self.BUTTON_ATCK = FALSE;
 341                 self.BUTTON_ATCK2 = FALSE;
 342                 if (self.bot_secondary_grenademooth == 0)
 343                 {
 344                         if(bot_aim(autocvar_g_balance_grenadelauncher_primary_speed, autocvar_g_balance_grenadelauncher_primary_speed_up, autocvar_g_balance_grenadelauncher_primary_lifetime, TRUE))
 345                         {
 346                                 self.BUTTON_ATCK = TRUE;
 347                                 if(random() < 0.01) self.bot_secondary_grenademooth = 1;
 348                         }
 349                 }
 350                 else
 351                 {
 352                         if(bot_aim(autocvar_g_balance_grenadelauncher_secondary_speed, autocvar_g_balance_grenadelauncher_secondary_speed_up, autocvar_g_balance_grenadelauncher_secondary_lifetime, TRUE))
 353                         {
 354                                 self.BUTTON_ATCK2 = TRUE;
 355                                 if(random() < 0.02) self.bot_secondary_grenademooth = 0;
 356                         }
 357                 }
 358         }
 359         else if (req == WR_THINK)
 360         {
 361                 if(autocvar_g_balance_grenadelauncher_reload_ammo && self.clip_load < min(autocvar_g_balance_grenadelauncher_primary_ammo, autocvar_g_balance_grenadelauncher_secondary_ammo)) // forced reload
 362                         W_GrenadeLauncher_Reload();
 363                 else if (self.BUTTON_ATCK)
 364                 {
 365                         if (weapon_prepareattack(0, autocvar_g_balance_grenadelauncher_primary_refire))
 366                         {
 367                                 W_Grenade_Attack();
 368                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_grenadelauncher_primary_animtime, w_ready);
 369                         }
 370                 }
 371                 else if (self.BUTTON_ATCK2)
 372                 {
 373                         if (cvar("g_balance_grenadelauncher_secondary_remote_detonateprimary"))
 374                         {
 375                                 nadefound = 0;
 376                                 for(nade = world; (nade = find(nade, classname, "grenade")); ) if(nade.owner == self)
 377                                 {
 378                                         if(!nade.gl_detonate_later)
 379                                         {
 380                                                 nade.gl_detonate_later = TRUE;
 381                                                 nadefound = 1;
 382                                         }
 383                                 }
 384                                 if(nadefound)
 385                                         sound (self, CHAN_WEAPON2, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 386                         }
 387                         else if (weapon_prepareattack(1, autocvar_g_balance_grenadelauncher_secondary_refire))
 388                         {
 389                                 W_Grenade_Attack2();
 390                                 weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_grenadelauncher_secondary_animtime, w_ready);
 391                         }
 392                 }
 393         if(self.wish_reload)
 394         {
 395             if(self.switchweapon == self.weapon)
 396             {
 397                 if(self.weaponentity.state == WS_READY)
 398                 {
 399                     self.wish_reload = 0;
 400                     W_GrenadeLauncher_Reload();
 401                 }
 402             }
 403         }
 404         }
 405         else if (req == WR_PRECACHE)
 406         {
 407                 precache_model ("models/weapons/g_gl.md3");
 408                 precache_model ("models/weapons/v_gl.md3");
 409                 precache_model ("models/weapons/h_gl.iqm");
 410                 precache_sound ("weapons/grenade_bounce1.wav");
 411                 precache_sound ("weapons/grenade_bounce2.wav");
 412                 precache_sound ("weapons/grenade_bounce3.wav");
 413                 precache_sound ("weapons/grenade_bounce4.wav");
 414                 precache_sound ("weapons/grenade_bounce5.wav");
 415                 precache_sound ("weapons/grenade_bounce6.wav");
 416                 precache_sound ("weapons/grenade_stick.wav");
 417                 precache_sound ("weapons/grenade_fire.wav");
 418         }
 419         else if (req == WR_SETUP)
 420         {
 421                 weapon_setup(WEP_GRENADE_LAUNCHER);
 422                 W_GrenadeLauncher_SetAmmoCounter();
 423         }
 424         else if (req == WR_CHECKAMMO1)
 425         {
 426                 if(autocvar_g_balance_grenadelauncher_reload_ammo)
 427                         return self.grenadelauncher_load >= autocvar_g_balance_grenadelauncher_primary_ammo;
 428                 else
 429                         return self.ammo_rockets >= autocvar_g_balance_grenadelauncher_primary_ammo;
 430         }
 431         else if (req == WR_CHECKAMMO2)
 432         {
 433                 if(autocvar_g_balance_grenadelauncher_reload_ammo)
 434                         return self.grenadelauncher_load >= autocvar_g_balance_grenadelauncher_secondary_ammo;
 435                 else
 436                         return self.ammo_rockets >= autocvar_g_balance_grenadelauncher_secondary_ammo;
 437         }
 438         return TRUE;
 439 };
 440 #endif
 441 #ifdef CSQC
 442 float w_glauncher(float req)
 443 {
 444         if(req == WR_IMPACTEFFECT)
 445         {
 446                 vector org2;
 447                 org2 = w_org + w_backoff * 12;
 448                 pointparticles(particleeffectnum("grenade_explode"), org2, '0 0 0', 1);
 449                 if(!w_issilent)
 450                         sound(self, CHAN_PROJECTILE, "weapons/grenade_impact.wav", VOL_BASE, ATTN_NORM);
 451         }
 452         else if(req == WR_PRECACHE)
 453         {
 454                 precache_sound("weapons/grenade_impact.wav");
 455         }
 456         else if (req == WR_SUICIDEMESSAGE)
 457         {
 458                 if(w_deathtype & HITTYPE_SECONDARY)
 459                         w_deathtypestring = "%s tried out his own grenade";
 460                 else
 461                         w_deathtypestring = "%s detonated";
 462         }
 463         else if (req == WR_KILLMESSAGE)
 464         {
 465                 if(w_deathtype & HITTYPE_SPLASH)
 466                         if(w_deathtype & HITTYPE_BOUNCE) // (must be secondary then)
 467                                 w_deathtypestring = "%s didn't see %s's grenade";
 468                         else // unchecked: SECONDARY
 469                                 w_deathtypestring = "%s almost dodged %s's grenade";
 470                 else // unchecked: SECONDARY, BOUNCE
 471                         w_deathtypestring = "%s ate %s's grenade";
 472         }
 473         else if (req == WR_RELOAD)
 474         {
 475                 W_GrenadeLauncher_Reload();
 476         }
 477         return TRUE;
 478 }
 479 #endif
 480 #endif