qcsrc/server/w_hagar.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(HAGAR, w_hagar, IT_ROCKETS, 8, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_MID, "hagar", "hagar", _("Hagar"))
   3 #else
   4 #ifdef SVQC
   5 // NO bounce protection, as bounces are limited!
   6
   7 void W_Hagar_Explode (void)
   8 {
   9         self.event_damage = SUB_Null;
  10         RadiusDamage (self, self.realowner, autocvar_g_balance_hagar_primary_damage, autocvar_g_balance_hagar_primary_edgedamage, autocvar_g_balance_hagar_primary_radius, world, autocvar_g_balance_hagar_primary_force, self.projectiledeathtype, other);
  11
  12         remove (self);
  13 }
  14
  15 void W_Hagar_Explode2 (void)
  16 {
  17         self.event_damage = SUB_Null;
  18         RadiusDamage (self, self.realowner, autocvar_g_balance_hagar_secondary_damage, autocvar_g_balance_hagar_secondary_edgedamage, autocvar_g_balance_hagar_secondary_radius, world, autocvar_g_balance_hagar_secondary_force, self.projectiledeathtype, other);
  19
  20         remove (self);
  21 }
  22
  23 void W_Hagar_Touch (void)
  24 {
  25         PROJECTILE_TOUCH;
  26         self.use ();
  27 }
  28
  29 void W_Hagar_Touch2 (void)
  30 {
  31         PROJECTILE_TOUCH;
  32
  33         if(self.cnt > 0 || other.takedamage == DAMAGE_AIM) {
  34                 self.use();
  35         } else {
  36                 self.cnt++;
  37                 pointparticles(particleeffectnum("hagar_bounce"), self.origin, self.velocity, 1);
  38                 self.angles = vectoangles (self.velocity);
  39                 self.owner = world;
  40                 self.projectiledeathtype |= HITTYPE_BOUNCE;
  41         }
  42 }
  43
  44 void W_Hagar_Attack (void)
  45 {
  46         local entity missile;
  47
  48         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_primary_ammo, autocvar_g_balance_hagar_reload_ammo);
  49
  50         W_SetupShot (self, FALSE, 2, "weapons/hagar_fire.wav", CHAN_WEAPON, autocvar_g_balance_hagar_primary_damage);
  51
  52         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  53
  54         missile = spawn ();
  55         missile.owner = missile.realowner = self;
  56         missile.classname = "missile";
  57         missile.bot_dodge = TRUE;
  58         missile.bot_dodgerating = autocvar_g_balance_hagar_primary_damage;
  59         missile.touch = W_Hagar_Touch;
  60         missile.use = W_Hagar_Explode;
  61         missile.think = adaptor_think2use_hittype_splash;
  62         missile.nextthink = time + autocvar_g_balance_hagar_primary_lifetime;
  63         PROJECTILE_MAKETRIGGER(missile);
  64         missile.projectiledeathtype = WEP_HAGAR;
  65         setorigin (missile, w_shotorg);
  66         setsize(missile, '0 0 0', '0 0 0');
  67
  68         missile.movetype = MOVETYPE_FLY;
  69         W_SETUPPROJECTILEVELOCITY(missile, g_balance_hagar_primary);
  70
  71         missile.angles = vectoangles (missile.velocity);
  72         missile.flags = FL_PROJECTILE;
  73
  74         CSQCProjectile(missile, TRUE, PROJECTILE_HAGAR, TRUE);
  75
  76         other = missile; MUTATOR_CALLHOOK(EditProjectile);
  77 }
  78
  79 void W_Hagar_Attack2 (void)
  80 {
  81         local entity missile;
  82
  83         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_secondary_ammo, autocvar_g_balance_hagar_reload_ammo);
  84
  85         W_SetupShot (self, FALSE, 2, "weapons/hagar_fire.wav", CHAN_WEAPON, autocvar_g_balance_hagar_secondary_damage);
  86
  87         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  88
  89         missile = spawn ();
  90         missile.owner = missile.realowner = self;
  91         missile.classname = "missile";
  92         missile.bot_dodge = TRUE;
  93         missile.bot_dodgerating = autocvar_g_balance_hagar_secondary_damage;
  94         missile.touch = W_Hagar_Touch2;
  95         missile.cnt = 0;
  96         missile.use = W_Hagar_Explode2;
  97         missile.think = adaptor_think2use_hittype_splash;
  98         missile.nextthink = time + autocvar_g_balance_hagar_secondary_lifetime_min + random() * autocvar_g_balance_hagar_secondary_lifetime_rand;
  99         PROJECTILE_MAKETRIGGER(missile);
 100         missile.projectiledeathtype = WEP_HAGAR | HITTYPE_SECONDARY;
 101         setorigin (missile, w_shotorg);
 102         setsize(missile, '0 0 0', '0 0 0');
 103
 104         missile.movetype = MOVETYPE_BOUNCEMISSILE;
 105         W_SETUPPROJECTILEVELOCITY(missile, g_balance_hagar_secondary);
 106
 107         missile.angles = vectoangles (missile.velocity);
 108         missile.flags = FL_PROJECTILE;
 109
 110         CSQCProjectile(missile, TRUE, PROJECTILE_HAGAR_BOUNCING, TRUE);
 111
 112         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 113 }
 114
 115 .float hagar_loadstep, hagar_loadblock;
 116 void W_Hagar_Attack2_Load_Release (void)
 117 {
 118         // time to release the rockets we've loaded
 119
 120         local entity missile;
 121         local float counter, shots;
 122         local vector s;
 123         vector forward, right, up;
 124
 125         if(!self.hagar_load)
 126                 return;
 127
 128         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_secondary_ammo * self.hagar_load, autocvar_g_balance_hagar_reload_ammo);
 129
 130         W_SetupShot (self, FALSE, 2, "weapons/hagar_fire.wav", CHAN_WEAPON, autocvar_g_balance_hagar_secondary_damage);
 131         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 132
 133         forward = v_forward;
 134         right = v_right;
 135         up = v_up;
 136
 137         shots = self.hagar_load;
 138         missile = world;
 139         while (counter < shots)
 140         {
 141                 missile = spawn ();
 142                 missile.owner = missile.realowner = self;
 143                 missile.classname = "missile";
 144                 missile.bot_dodge = TRUE;
 145                 missile.bot_dodgerating = autocvar_g_balance_hagar_secondary_damage;
 146
 147                 missile.touch = W_Hagar_Touch; // not bouncy
 148                 missile.use = W_Hagar_Explode2;
 149                 missile.think = adaptor_think2use_hittype_splash;
 150                 missile.nextthink = time + autocvar_g_balance_hagar_secondary_lifetime_min + random() * autocvar_g_balance_hagar_secondary_lifetime_rand;
 151                 PROJECTILE_MAKETRIGGER(missile);
 152                 missile.projectiledeathtype = WEP_HAGAR;
 153                 setorigin (missile, w_shotorg);
 154                 setsize(missile, '0 0 0', '0 0 0');
 155                 missile.movetype = MOVETYPE_FLY;
 156
 157                 s = '0 0 0';
 158                 if (counter == 0)
 159                         s = '0 0 0';
 160                 else
 161                 {
 162                         makevectors('0 360 0' * (0.75 + (counter - 0.5) / (shots - 1)));
 163                         s_y = v_forward_x;
 164                         s_z = v_forward_y;
 165                 }
 166                 s = s * cvar("g_balance_hagar_secondary_spread") * g_weaponspreadfactor;
 167                 W_SetupProjectileVelocityEx(missile, w_shotdir + right * s_y + up * s_z, v_up, cvar("g_balance_hagar_secondary_speed"), 0, 0, 0, FALSE);
 168
 169                 missile.angles = vectoangles (missile.velocity);
 170                 missile.flags = FL_PROJECTILE;
 171
 172                 CSQCProjectile(missile, TRUE, PROJECTILE_HAGAR, TRUE);
 173
 174                 other = missile; MUTATOR_CALLHOOK(EditProjectile);
 175
 176                 counter = counter + 1;
 177         }
 178
 179         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_hagar_secondary_refire, w_ready);
 180         self.hagar_loadstep = time + autocvar_g_balance_hagar_secondary_refire;
 181         self.hagar_load = 0;
 182 }
 183
 184 void W_Hagar_Attack2_Load (void)
 185 {
 186         // loadable hagar secondary attack, must always run each frame
 187
 188         if not(weapon_action(self.weapon, WR_CHECKAMMO2))
 189         {
 190                 W_SwitchToOtherWeapon(self);
 191                 return;
 192         }
 193
 194         local float loaded;
 195         local float used_ammo, enough_ammo;
 196
 197         loaded = self.hagar_load >= autocvar_g_balance_hagar_secondary_load_max;
 198
 199         // check if we have enough ammo for another rocket
 200         used_ammo = autocvar_g_balance_hagar_secondary_ammo;
 201         if(autocvar_g_balance_hagar_reload_ammo)
 202                 enough_ammo = self.weapon_load[WEP_HAGAR] >= used_ammo + (used_ammo * self.hagar_load);
 203         else
 204                 enough_ammo = self.ammo_rockets >= used_ammo + (used_ammo * self.hagar_load);
 205
 206         if(self.BUTTON_ATCK2)
 207         {
 208                 if(self.BUTTON_ATCK && autocvar_g_balance_hagar_secondary_load_abort)
 209                 {
 210                         if(self.hagar_load)
 211                         {
 212                                 // if we pressed primary fire while loading, unload all rockets and abort
 213                                 self.hagar_load = 0;
 214                                 sound(self, CHAN_WEAPON, "weapons/hagar_beep.wav", VOL_BASE, ATTN_NORM);
 215
 216                                 // pause until we can load rockets again, once we re-press the alt fire button
 217                                 self.hagar_loadstep = time + autocvar_g_balance_hagar_secondary_load_speed;
 218
 219                                 // require letting go of the alt fire button before we can load again
 220                                 self.hagar_loadblock = TRUE;
 221                         }
 222                 }
 223                 else
 224                 {
 225                         // check if we can attempt to load another rocket
 226                         if(!self.hagar_loadblock && !loaded && enough_ammo)
 227                         if(self.hagar_loadstep < time)
 228                         {
 229                                 self.hagar_load += 1;
 230                                 sound(self, CHAN_WEAPON2, "weapons/hagar_load.wav", VOL_BASE, ATTN_NORM);
 231
 232                                 // if this is the last rocket we can load, play the beep sound to notify the player of that
 233                                 if(self.hagar_load >= autocvar_g_balance_hagar_secondary_load_max)
 234                                         sound(self, CHAN_WEAPON, "weapons/hagar_beep.wav", VOL_BASE, ATTN_NORM);
 235
 236                                 self.hagar_loadstep = time + autocvar_g_balance_hagar_secondary_load_speed;
 237                         }
 238                 }
 239         }
 240         else if(self.hagar_loadblock)
 241         {
 242                 // the alt fire button was released, so re-enable loading if blocked
 243                 self.hagar_loadblock = FALSE;
 244         }
 245
 246         if(self.hagar_load)
 247         if(!self.BUTTON_ATCK2 || ((loaded || !enough_ammo) && self.hagar_loadstep < time && !autocvar_g_balance_hagar_secondary_load_hold))
 248         if(weapon_prepareattack(0, autocvar_g_balance_hagar_secondary_refire))
 249                 W_Hagar_Attack2_Load_Release();
 250 }
 251
 252 void spawnfunc_weapon_hagar (void)
 253 {
 254         weapon_defaultspawnfunc(WEP_HAGAR);
 255 }
 256
 257 float w_hagar(float req)
 258 {
 259         float ammo_amount;
 260         if (req == WR_AIM)
 261                 if (random()>0.15)
 262                         self.BUTTON_ATCK = bot_aim(autocvar_g_balance_hagar_primary_speed, 0, autocvar_g_balance_hagar_primary_lifetime, FALSE);
 263                 else
 264                 {
 265                         // not using secondary_speed since these are only 15% and should cause some ricochets without re-aiming
 266                         self.BUTTON_ATCK2 = bot_aim(autocvar_g_balance_hagar_primary_speed, 0, autocvar_g_balance_hagar_primary_lifetime, FALSE);
 267                 }
 268         else if (req == WR_THINK)
 269         {
 270                 if(autocvar_g_balance_hagar_reload_ammo && self.clip_load < min(autocvar_g_balance_hagar_primary_ammo, autocvar_g_balance_hagar_secondary_ammo)) // forced reload
 271                         weapon_action(self.weapon, WR_RELOAD);
 272                 else
 273                 {
 274                         local float loadable_secondary;
 275                         loadable_secondary = autocvar_g_balance_hagar_secondary_load && autocvar_g_balance_hagar_secondary;
 276
 277                         if (loadable_secondary)
 278                                 W_Hagar_Attack2_Load(); // must run each frame, even when no firing buttons are pressed
 279                         if (self.BUTTON_ATCK && !self.hagar_load && !self.hagar_loadblock) // not while secondary is loaded or awaiting reset
 280                         {
 281                                 if (weapon_prepareattack(0, autocvar_g_balance_hagar_primary_refire))
 282                                 {
 283                                         W_Hagar_Attack();
 284                                         weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_hagar_primary_refire, w_ready);
 285                                 }
 286                         }
 287                         else if (self.BUTTON_ATCK2 && !loadable_secondary && autocvar_g_balance_hagar_secondary)
 288                         {
 289                                 if (weapon_prepareattack(1, autocvar_g_balance_hagar_secondary_refire))
 290                                 {
 291                                         W_Hagar_Attack2();
 292                                         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_hagar_secondary_refire, w_ready);
 293                                 }
 294                         }
 295                 }
 296         }
 297         else if (req == WR_PRECACHE)
 298         {
 299                 precache_model ("models/weapons/g_hagar.md3");
 300                 precache_model ("models/weapons/v_hagar.md3");
 301                 precache_model ("models/weapons/h_hagar.iqm");
 302                 precache_sound ("weapons/hagar_fire.wav");
 303                 precache_sound ("weapons/hagar_load.wav");
 304                 precache_sound ("weapons/hagar_beep.wav");
 305                 //precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound somewhere else
 306         }
 307         else if (req == WR_SETUP)
 308         {
 309                 weapon_setup(WEP_HAGAR);
 310                 self.current_ammo = ammo_rockets;
 311                 self.hagar_load = 0;
 312         }
 313         else if (req == WR_CHECKAMMO1)
 314         {
 315                 ammo_amount = self.ammo_rockets >= autocvar_g_balance_hagar_primary_ammo;
 316                 ammo_amount += self.weapon_load[WEP_HAGAR] >= autocvar_g_balance_hagar_primary_ammo;
 317                 return ammo_amount;
 318         }
 319         else if (req == WR_CHECKAMMO2)
 320         {
 321                 ammo_amount = self.ammo_rockets >= autocvar_g_balance_hagar_secondary_ammo;
 322                 ammo_amount += self.weapon_load[WEP_HAGAR] >= autocvar_g_balance_hagar_secondary_ammo;
 323                 return ammo_amount;
 324         }
 325         else if (req == WR_PLAYERDEATH)
 326         {
 327                 // if we have any rockets loaded when we die, release them
 328                 if(self.hagar_load && autocvar_g_balance_hagar_secondary_load_releasedeath)
 329                         W_Hagar_Attack2_Load_Release();
 330         }
 331         else if (req == WR_RELOAD)
 332         {
 333                 W_Reload(min(autocvar_g_balance_hagar_primary_ammo, autocvar_g_balance_hagar_secondary_ammo), autocvar_g_balance_hagar_reload_ammo, autocvar_g_balance_hagar_reload_time, "weapons/reload.wav");
 334         }
 335         return TRUE;
 336 };
 337 #endif
 338 #ifdef CSQC
 339 float w_hagar(float req)
 340 {
 341         if(req == WR_IMPACTEFFECT)
 342         {
 343                 vector org2;
 344                 org2 = w_org + w_backoff * 6;
 345                 pointparticles(particleeffectnum("hagar_explode"), org2, '0 0 0', 1);
 346                 if(!w_issilent)
 347                 {
 348                         if (w_random<0.15)
 349                                 sound(self, CHAN_PROJECTILE, "weapons/hagexp1.wav", VOL_BASE, ATTN_NORM);
 350                         else if (w_random<0.7)
 351                                 sound(self, CHAN_PROJECTILE, "weapons/hagexp2.wav", VOL_BASE, ATTN_NORM);
 352                         else
 353                                 sound(self, CHAN_PROJECTILE, "weapons/hagexp3.wav", VOL_BASE, ATTN_NORM);
 354                 }
 355         }
 356         else if(req == WR_PRECACHE)
 357         {
 358                 precache_sound("weapons/hagexp1.wav");
 359                 precache_sound("weapons/hagexp2.wav");
 360                 precache_sound("weapons/hagexp3.wav");
 361         }
 362         else if (req == WR_SUICIDEMESSAGE)
 363                 w_deathtypestring = _("%s played with tiny rockets");
 364         else if (req == WR_KILLMESSAGE)
 365         {
 366                 if(w_deathtype & HITTYPE_BOUNCE) // must be secondary; unchecked: SPLASH
 367                         w_deathtypestring = _("%s hoped %s's missiles wouldn't bounce");
 368                 else // unchecked: SPLASH, SECONDARY
 369                         w_deathtypestring = _("%s was pummeled by %s");
 370         }
 371         return TRUE;
 372 }
 373 #endif
 374 #endif