qcsrc/server/w_rocketlauncher.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(ROCKET_LAUNCHER, w_rlauncher, IT_ROCKETS, 9, WEP_FLAG_NORMAL | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_HIGH, "rl", "rocketlauncher", _("Rocket Launcher"))
   3 #else
   4 #ifdef SVQC
   5 .float rl_release;
   6 .float rl_detonate_later;
   7
   8 void W_RocketLauncher_SetAmmoCounter()
   9 {
  10         // set clip_load to the weapon we have switched to, if the gun uses reloading
  11         if(!autocvar_g_balance_rocketlauncher_reload_ammo)
  12                 self.clip_load = 0; // also keeps crosshair ammo from displaying
  13         else
  14         {
  15                 self.clip_load = self.rocketlauncher_load;
  16                 self.clip_size = autocvar_g_balance_rocketlauncher_reload_ammo; // for the crosshair ammo display
  17         }
  18 }
  19
  20 void W_RocketLauncher_ReloadedAndReady()
  21 {
  22         float t;
  23
  24         // now do the ammo transfer
  25         self.clip_load = self.old_clip_load; // restore the ammo counter, in case we still had ammo in the weapon before reloading
  26         while(self.clip_load < autocvar_g_balance_rocketlauncher_reload_ammo && self.ammo_rockets) // make sure we don't add more ammo than we have
  27         {
  28                 self.clip_load += 1;
  29                 self.ammo_rockets -= 1;
  30         }
  31         self.rocketlauncher_load = self.clip_load;
  32
  33         t = ATTACK_FINISHED(self) - autocvar_g_balance_rocketlauncher_reload_time - 1;
  34         ATTACK_FINISHED(self) = t;
  35         w_ready();
  36 }
  37
  38 void W_RocketLauncher_Reload()
  39 {
  40         // return if reloading is disabled for this weapon
  41         if(!autocvar_g_balance_rocketlauncher_reload_ammo)
  42                 return;
  43
  44         if(!W_ReloadCheck(self.ammo_rockets, autocvar_g_balance_rocketlauncher_ammo))
  45                 return;
  46
  47         float t;
  48
  49         sound (self, CHAN_WEAPON2, "weapons/reload.wav", VOL_BASE, ATTN_NORM);
  50
  51         t = max(time, ATTACK_FINISHED(self)) + autocvar_g_balance_rocketlauncher_reload_time + 1;
  52         ATTACK_FINISHED(self) = t;
  53
  54         weapon_thinkf(WFRAME_RELOAD, autocvar_g_balance_rocketlauncher_reload_time, W_RocketLauncher_ReloadedAndReady);
  55
  56         self.old_clip_load = self.clip_load;
  57         self.clip_load = -1;
  58 }
  59
  60 void W_Rocket_Unregister()
  61 {
  62         if(self.owner && self.owner.lastrocket == self)
  63         {
  64                 self.owner.lastrocket = world;
  65                 // self.owner.rl_release = 1;
  66         }
  67 }
  68
  69 void W_Rocket_Explode ()
  70 {
  71         W_Rocket_Unregister();
  72
  73         if(other.takedamage == DAMAGE_AIM)
  74                 if(other.classname == "player")
  75                         if(IsDifferentTeam(self.owner, other))
  76                                 if(IsFlying(other))
  77                                         AnnounceTo(self.owner, "airshot");
  78
  79         self.event_damage = SUB_Null;
  80         self.takedamage = DAMAGE_NO;
  81
  82         RadiusDamage (self, self.owner, autocvar_g_balance_rocketlauncher_damage, autocvar_g_balance_rocketlauncher_edgedamage, autocvar_g_balance_rocketlauncher_radius, world, autocvar_g_balance_rocketlauncher_force, self.projectiledeathtype, other);
  83
  84         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
  85         {
  86                 if(self.owner.ammo_rockets < autocvar_g_balance_rocketlauncher_ammo)
  87                 {
  88                         self.owner.cnt = WEP_ROCKET_LAUNCHER;
  89                         ATTACK_FINISHED(self.owner) = time;
  90                         self.owner.switchweapon = w_getbestweapon(self.owner);
  91                 }
  92         }
  93         remove (self);
  94 }
  95
  96 void W_Rocket_DoRemoteExplode ()
  97 {
  98         W_Rocket_Unregister();
  99
 100         self.event_damage = SUB_Null;
 101         self.takedamage = DAMAGE_NO;
 102
 103         RadiusDamage (self, self.owner, autocvar_g_balance_rocketlauncher_remote_damage, autocvar_g_balance_rocketlauncher_remote_edgedamage, autocvar_g_balance_rocketlauncher_remote_radius, world, autocvar_g_balance_rocketlauncher_remote_force, self.projectiledeathtype | HITTYPE_BOUNCE, world);
 104
 105         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
 106         {
 107                 if(self.owner.ammo_rockets < autocvar_g_balance_rocketlauncher_ammo)
 108                 {
 109                         self.owner.cnt = WEP_ROCKET_LAUNCHER;
 110                         ATTACK_FINISHED(self.owner) = time;
 111                         self.owner.switchweapon = w_getbestweapon(self.owner);
 112                 }
 113         }
 114         remove (self);
 115 }
 116
 117 entity FindLaserTarget(entity e, float dist_variance, float dot_variance)
 118 {
 119         entity head, selected;
 120         vector dir;
 121         float dist, maxdist,// bestdist,
 122                 dot,// bestdot,
 123                 points, bestpoints;
 124         //bestdist = 9999;
 125         //bestdot = -2;
 126         bestpoints = 0;
 127         maxdist = 800;
 128         selected = world;
 129
 130         makevectors(e.angles);
 131
 132         head = find(world, classname, "laser_target");
 133         while(head)
 134         {
 135                 points = 0;
 136                 dir = normalize(head.origin - self.origin);
 137                 dot = dir * v_forward;
 138                 dist = vlen(head.origin - self.origin);
 139                 if(dist > maxdist)
 140                         dist = maxdist;
 141
 142                 // gain points for being in front
 143                 points = points + ((dot+1)*0.5) * 500
 144                         * (1 + crandom()*dot_variance);
 145                 // gain points for being close away
 146                 points = points + (1 - dist/maxdist) * 1000
 147                         * (1 + crandom()*dot_variance);
 148
 149                 traceline(e.origin, head.origin, TRUE, self);
 150                 if(trace_fraction < 1)
 151                 {
 152                         points = 0;
 153                 }
 154
 155                 if(points > bestpoints)//random() > 0.5)//
 156                 {
 157                         bestpoints = points;
 158                         selected = head;
 159                 }
 160
 161                 head = find(head, classname, "laser_target");
 162         }
 163
 164         //bprint(selected.owner.netname);
 165         //bprint("\n");
 166         return selected;
 167 }
 168
 169 void W_Rocket_RemoteExplode()
 170 {
 171         if(self.owner.deadflag == DEAD_NO)
 172         if(self.owner.lastrocket)
 173         {
 174                 if((self.spawnshieldtime >= 0)
 175                         ? (time >= self.spawnshieldtime) // timer
 176                         : (vlen(NearestPointOnBox(self.owner, self.origin) - self.origin) > autocvar_g_balance_rocketlauncher_remote_radius) // safety device
 177                 )
 178                 {
 179                         W_Rocket_DoRemoteExplode();
 180                 }
 181         }
 182 }
 183
 184 vector rocket_steerto(vector thisdir, vector goaldir, float maxturn_cos)
 185 {
 186         if(thisdir * goaldir > maxturn_cos)
 187                 return goaldir;
 188         float f, m2;
 189         vector v;
 190         // solve:
 191         //   g = normalize(thisdir + goaldir * X)
 192         //   thisdir * g = maxturn
 193         //
 194         //   gg = thisdir + goaldir * X
 195         //   (thisdir * gg)^2 = maxturn^2 * (gg * gg)
 196         //
 197         //   (1 + (thisdir * goaldir) * X)^2 = maxturn^2 * (1 + X*X + 2 * X * thisdir * goaldir)
 198         f = thisdir * goaldir;
 199         //   (1 + f * X)^2 = maxturn^2 * (1 + X*X + 2 * X * f)
 200         //   0 = (m^2 - f^2) * x^2 + (2 * f * (m^2 - 1)) * x + (m^2 - 1)
 201         m2 = maxturn_cos * maxturn_cos;
 202         v = solve_quadratic(m2 - f * f, 2 * f * (m2 - 1), m2 - 1);
 203         return normalize(thisdir + goaldir * v_y); // the larger solution!
 204 }
 205
 206 void W_Rocket_Think (void)
 207 {
 208         vector desireddir, olddir, newdir, desiredorigin, goal;
 209 #if 0
 210         float cosminang, cosmaxang, cosang;
 211 #endif
 212         float velspeed, f;
 213         self.nextthink = time;
 214         if (time > self.cnt)
 215         {
 216                 other = world;
 217                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 218                 W_Rocket_Explode ();
 219                 return;
 220         }
 221
 222         // accelerate
 223         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 224         velspeed = autocvar_g_balance_rocketlauncher_speed * g_weaponspeedfactor - (self.velocity * v_forward);
 225         if (velspeed > 0)
 226                 self.velocity = self.velocity + v_forward * min(autocvar_g_balance_rocketlauncher_speedaccel * g_weaponspeedfactor * frametime, velspeed);
 227
 228         // laser guided, or remote detonation
 229         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
 230         {
 231                 if(self == self.owner.lastrocket)
 232                 if not(self.owner.rl_release)
 233                 if not(self.BUTTON_ATCK2)
 234                 if(autocvar_g_balance_rocketlauncher_guiderate)
 235                 if(time > self.pushltime)
 236                 if(self.owner.deadflag == DEAD_NO)
 237                 {
 238                         f = autocvar_g_balance_rocketlauncher_guideratedelay;
 239                         if(f)
 240                                 f = bound(0, (time - self.pushltime) / f, 1);
 241                         else
 242                                 f = 1;
 243
 244                         velspeed = vlen(self.velocity);
 245
 246                         makevectors(self.owner.v_angle);
 247                         desireddir = WarpZone_RefSys_TransformVelocity(self.owner, self, v_forward);
 248                         desiredorigin = WarpZone_RefSys_TransformOrigin(self.owner, self, self.owner.origin + self.owner.view_ofs);
 249                         olddir = normalize(self.velocity);
 250
 251                         // now it gets tricky... we want to move like some curve to approximate the target direction
 252                         // but we are limiting the rate at which we can turn!
 253                         goal = desiredorigin + ((self.origin - desiredorigin) * desireddir + autocvar_g_balance_rocketlauncher_guidegoal) * desireddir;
 254                         newdir = rocket_steerto(olddir, normalize(goal - self.origin), cos(autocvar_g_balance_rocketlauncher_guiderate * f * frametime * DEG2RAD));
 255
 256                         self.velocity = newdir * velspeed;
 257                         self.angles = vectoangles(self.velocity);
 258
 259                         if(!self.count)
 260                         {
 261                                 pointparticles(particleeffectnum("rocket_guide"), self.origin, self.velocity, 1);
 262                                 // TODO add a better sound here
 263                                 sound (self.owner, CHAN_WEAPON2, "weapons/rocket_mode.wav", VOL_BASE, ATTN_NORM);
 264                                 self.count = 1;
 265                         }
 266                 }
 267
 268                 if(self.rl_detonate_later)
 269                         W_Rocket_RemoteExplode();
 270         }
 271
 272         if(self.csqcprojectile_clientanimate == 0)
 273                 UpdateCSQCProjectile(self);
 274 }
 275
 276 void W_Rocket_Touch (void)
 277 {
 278         if(WarpZone_Projectile_Touch())
 279         {
 280                 if(wasfreed(self))
 281                         W_Rocket_Unregister();
 282                 return;
 283         }
 284         W_Rocket_Unregister();
 285         W_Rocket_Explode ();
 286 }
 287
 288 void W_Rocket_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 289 {
 290         if (self.health <= 0)
 291                 return;
 292         self.health = self.health - damage;
 293         self.angles = vectoangles(self.velocity);
 294         if (self.health <= 0)
 295                 W_PrepareExplosionByDamage(attacker, W_Rocket_Explode);
 296 }
 297
 298 void W_Rocket_Attack (void)
 299 {
 300         local entity missile;
 301         local entity flash;
 302
 303         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 304         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 305         {
 306                 if(autocvar_g_balance_rocketlauncher_reload_ammo)
 307                 {
 308                         self.clip_load -= autocvar_g_balance_rocketlauncher_ammo;
 309                         self.rocketlauncher_load = self.clip_load;
 310                 }
 311                 else
 312                         self.ammo_rockets -= autocvar_g_balance_rocketlauncher_ammo;
 313         }
 314
 315         W_SetupShot_ProjectileSize (self, '-3 -3 -3', '3 3 3', FALSE, 5, "weapons/rocket_fire.wav", CHAN_WEAPON, autocvar_g_balance_rocketlauncher_damage);
 316         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 317
 318         missile = WarpZone_RefSys_SpawnSameRefSys(self);
 319         missile.owner = self;
 320         self.lastrocket = missile;
 321         if(autocvar_g_balance_rocketlauncher_detonatedelay >= 0)
 322                 missile.spawnshieldtime = time + autocvar_g_balance_rocketlauncher_detonatedelay;
 323         else
 324                 missile.spawnshieldtime = -1;
 325         missile.pushltime = time + autocvar_g_balance_rocketlauncher_guidedelay;
 326         missile.classname = "rocket";
 327         missile.bot_dodge = TRUE;
 328         missile.bot_dodgerating = autocvar_g_balance_rocketlauncher_damage * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 329
 330         missile.takedamage = DAMAGE_YES;
 331         missile.damageforcescale = autocvar_g_balance_rocketlauncher_damageforcescale;
 332         missile.health = autocvar_g_balance_rocketlauncher_health;
 333         missile.event_damage = W_Rocket_Damage;
 334
 335         missile.movetype = MOVETYPE_FLY;
 336         PROJECTILE_MAKETRIGGER(missile);
 337         missile.projectiledeathtype = WEP_ROCKET_LAUNCHER;
 338         setsize (missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 339
 340         setorigin (missile, w_shotorg - v_forward * 3); // move it back so it hits the wall at the right point
 341         W_SetupProjectileVelocity(missile, autocvar_g_balance_rocketlauncher_speedstart, 0);
 342         missile.angles = vectoangles (missile.velocity);
 343
 344         missile.touch = W_Rocket_Touch;
 345         missile.think = W_Rocket_Think;
 346         missile.nextthink = time;
 347         missile.cnt = time + autocvar_g_balance_rocketlauncher_lifetime;
 348         missile.flags = FL_PROJECTILE;
 349
 350         CSQCProjectile(missile, autocvar_g_balance_rocketlauncher_guiderate == 0 && autocvar_g_balance_rocketlauncher_speedaccel == 0, PROJECTILE_ROCKET, FALSE); // because of fly sound
 351
 352         // muzzle flash for 1st person view
 353         flash = spawn ();
 354         setmodel (flash, "models/flash.md3"); // precision set below
 355         SUB_SetFade (flash, time, 0.1);
 356         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 357         W_AttachToShotorg(flash, '5 0 0');
 358
 359         // common properties
 360         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 361 }
 362
 363 void spawnfunc_weapon_rocketlauncher (void); // defined in t_items.qc
 364
 365 float w_rlauncher(float req)
 366 {
 367         entity rock;
 368         float rockfound;
 369         if (req == WR_AIM)
 370         {
 371                 // aim and decide to fire if appropriate
 372                 self.BUTTON_ATCK = bot_aim(autocvar_g_balance_rocketlauncher_speed, 0, autocvar_g_balance_rocketlauncher_lifetime, FALSE);
 373                 if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 374                 {
 375                         // decide whether to detonate rockets
 376                         local entity missile, targetlist, targ;
 377                         local float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 378                         local float selfdamage, teamdamage, enemydamage;
 379                         edgedamage = autocvar_g_balance_rocketlauncher_edgedamage;
 380                         coredamage = autocvar_g_balance_rocketlauncher_damage;
 381                         edgeradius = autocvar_g_balance_rocketlauncher_radius;
 382                         recipricoledgeradius = 1 / edgeradius;
 383                         selfdamage = 0;
 384                         teamdamage = 0;
 385                         enemydamage = 0;
 386                         targetlist = findchainfloat(bot_attack, TRUE);
 387                         missile = find(world, classname, "rocket");
 388                         while (missile)
 389                         {
 390                                 if (missile.owner != self)
 391                                 {
 392                                         missile = find(missile, classname, "rocket");
 393                                         continue;
 394                                 }
 395                                 targ = targetlist;
 396                                 while (targ)
 397                                 {
 398                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - missile.origin);
 399                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 400                                         // count potential damage according to type of target
 401                                         if (targ == self)
 402                                                 selfdamage = selfdamage + d;
 403                                         else if (targ.team == self.team && teams_matter)
 404                                                 teamdamage = teamdamage + d;
 405                                         else if (bot_shouldattack(targ))
 406                                                 enemydamage = enemydamage + d;
 407                                         targ = targ.chain;
 408                                 }
 409                                 missile = find(missile, classname, "rocket");
 410                         }
 411                         local float desirabledamage;
 412                         desirabledamage = enemydamage;
 413                         if (time > self.invincible_finished && time > self.spawnshieldtime)
 414                                 desirabledamage = desirabledamage - selfdamage * autocvar_g_balance_selfdamagepercent;
 415                         if (teams_matter && self.team)
 416                                 desirabledamage = desirabledamage - teamdamage;
 417
 418                         missile = find(world, classname, "rocket");
 419                         while (missile)
 420                         {
 421                                 if (missile.owner != self)
 422                                 {
 423                                         missile = find(missile, classname, "rocket");
 424                                         continue;
 425                                 }
 426                                 makevectors(missile.v_angle);
 427                                 targ = targetlist;
 428                                 if (skill > 9) // normal players only do this for the target they are tracking
 429                                 {
 430                                         targ = targetlist;
 431                                         while (targ)
 432                                         {
 433                                                 if (
 434                                                         (v_forward * normalize(missile.origin - targ.origin)< 0.1)
 435                                                         && desirabledamage > 0.1*coredamage
 436                                                 )self.BUTTON_ATCK2 = TRUE;
 437                                                 targ = targ.chain;
 438                                         }
 439                                 }else{
 440                                         local float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 441                                         //As the distance gets larger, a correct detonation gets near imposible
 442                                         //Bots are assumed to use the rocket spawnfunc_light to see if the rocket gets near a player
 443                                         if(v_forward * normalize(missile.origin - self.enemy.origin)< 0.1)
 444                                                 if(self.enemy.classname == "player")
 445                                                         if(desirabledamage >= 0.1*coredamage)
 446                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 447                                                                         self.BUTTON_ATCK2 = TRUE;
 448                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 449                                 }
 450
 451                                 missile = find(missile, classname, "rocket");
 452                         }
 453                         // if we would be doing at X percent of the core damage, detonate it
 454                         // but don't fire a new shot at the same time!
 455                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 456                                 self.BUTTON_ATCK2 = TRUE;
 457                         if ((skill > 6.5) && (selfdamage > self.health))
 458                                 self.BUTTON_ATCK2 = FALSE;
 459                         //if(self.BUTTON_ATCK2 == TRUE)
 460                         //      dprint(ftos(desirabledamage),"\n");
 461                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 462                 }
 463         }
 464         else if (req == WR_THINK)
 465         {
 466                 if(autocvar_g_balance_rocketlauncher_reload_ammo && self.clip_load < autocvar_g_balance_rocketlauncher_ammo) // forced reload
 467                         W_RocketLauncher_Reload();
 468                 else
 469                 {
 470                         if (self.BUTTON_ATCK)
 471                         {
 472                                 if(self.rl_release || autocvar_g_balance_rocketlauncher_guidestop)
 473                                 if(weapon_prepareattack(0, autocvar_g_balance_rocketlauncher_refire))
 474                                 {
 475                                         W_Rocket_Attack();
 476                                         weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_rocketlauncher_animtime, w_ready);
 477                                         self.rl_release = 0;
 478                                 }
 479                         }
 480                         else
 481                                 self.rl_release = 1;
 482
 483                         if (self.BUTTON_ATCK2)
 484                         {
 485                                 rockfound = 0;
 486                                 for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.owner == self)
 487                                 {
 488                                         if(!rock.rl_detonate_later)
 489                                         {
 490                                                 rock.rl_detonate_later = TRUE;
 491                                                 rockfound = 1;
 492                                         }
 493                                 }
 494                                 if(rockfound)
 495                                         sound (self, CHAN_WEAPON2, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 496                         }
 497                 }
 498         if(self.wish_reload)
 499         {
 500             if(self.switchweapon == self.weapon)
 501             {
 502                 if(self.weaponentity.state == WS_READY)
 503                 {
 504                     self.wish_reload = 0;
 505                     W_RocketLauncher_Reload();
 506                 }
 507             }
 508         }
 509         }
 510         else if (req == WR_PRECACHE)
 511         {
 512                 precache_model ("models/flash.md3");
 513                 precache_model ("models/weapons/g_rl.md3");
 514                 precache_model ("models/weapons/v_rl.md3");
 515                 precache_model ("models/weapons/h_rl.iqm");
 516                 precache_sound ("weapons/rocket_det.wav");
 517                 precache_sound ("weapons/rocket_fire.wav");
 518                 precache_sound ("weapons/rocket_mode.wav");
 519                 precache_sound ("weapons/reload.wav");
 520         }
 521         else if (req == WR_SETUP)
 522         {
 523                 weapon_setup(WEP_ROCKET_LAUNCHER);
 524                 W_RocketLauncher_SetAmmoCounter();
 525                 self.rl_release = 1;
 526         }
 527         else if (req == WR_CHECKAMMO1)
 528         {
 529                 if(autocvar_g_balance_rocketlauncher_reload_ammo)
 530                 {
 531                         // don't switch while guiding a missile
 532                         if ((ATTACK_FINISHED(self) <= time || self.weapon != WEP_ROCKET_LAUNCHER)
 533                                 && self.clip_load < autocvar_g_balance_rocketlauncher_ammo)
 534                                 return FALSE;
 535                 }
 536                 else
 537                 {
 538                         // don't switch while guiding a missile
 539                         if ((ATTACK_FINISHED(self) <= time || self.weapon != WEP_ROCKET_LAUNCHER)
 540                                 && self.ammo_rockets < autocvar_g_balance_rocketlauncher_ammo)
 541                                 return FALSE;
 542                 }
 543         }
 544         else if (req == WR_CHECKAMMO2)
 545                 return FALSE;
 546         else if (req == WR_RESETPLAYER)
 547         {
 548                 self.rl_release = 0;
 549         }
 550         else if (req == WR_RELOAD)
 551         {
 552                 W_RocketLauncher_Reload();
 553         }
 554         else if (req == WR_SWITCHABLE)
 555         {
 556                 // checks if this weapon can be switched to, when reloading is enabled
 557                 // returns true if there's either enough load in the weapon to use it,
 558                 // or we have enough ammo to reload the weapon to a usable point
 559                 float ammo_amount;
 560                 ammo_amount = autocvar_g_balance_rocketlauncher_ammo;
 561                 return self.rocketlauncher_load >= ammo_amount || self.ammo_rockets >= ammo_amount;
 562         }
 563         return TRUE;
 564 };
 565 #endif
 566 #ifdef CSQC
 567 float w_rlauncher(float req)
 568 {
 569         if(req == WR_IMPACTEFFECT)
 570         {
 571                 vector org2;
 572                 org2 = w_org + w_backoff * 12;
 573                 pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 574                 if(!w_issilent)
 575                         sound(self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 576         }
 577         else if(req == WR_PRECACHE)
 578         {
 579                 precache_sound("weapons/rocket_impact.wav");
 580         }
 581         else if (req == WR_SUICIDEMESSAGE)
 582                 w_deathtypestring = "%s exploded";
 583         else if (req == WR_KILLMESSAGE)
 584         {
 585                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 586                         w_deathtypestring = "%s got too close to %s's rocket";
 587                 else if(w_deathtype & HITTYPE_SPLASH)
 588                         w_deathtypestring = "%s almost dodged %s's rocket";
 589                 else
 590                         w_deathtypestring = "%s ate %s's rocket";
 591         }
 592         return TRUE;
 593 }
 594 #endif
 595 #endif