qcsrc/server/w_shotgun.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(SHOTGUN, w_shotgun, IT_SHELLS, 2, WEP_FLAG_NORMAL | WEP_TYPE_HITSCAN, BOT_PICKUP_RATING_LOW, "shotgun", "shotgun", _("Shotgun"))
   3 #else
   4 #ifdef SVQC
   5 void W_Shotgun_Attack (void)
   6 {
   7         float   sc;
   8         float   ammoamount;
   9         float   bullets;
  10         float   d;
  11         float   f;
  12         float   spread;
  13         float   bulletspeed;
  14         float   bulletconstant;
  15         local entity flash;
  16
  17         W_SniperRifle_CheckReloadAndReady();
  18         if(self.sniperrifle_bulletcounter < 0)
  19                 return; // reloading, so we are done
  20
  21         ammoamount = autocvar_g_balance_shotgun_primary_ammo;
  22         bullets = autocvar_g_balance_shotgun_primary_bullets;
  23         d = autocvar_g_balance_shotgun_primary_damage;
  24         f = autocvar_g_balance_shotgun_primary_force;
  25         spread = autocvar_g_balance_shotgun_primary_spread;
  26         bulletspeed = autocvar_g_balance_shotgun_primary_speed;
  27         bulletconstant = autocvar_g_balance_shotgun_primary_bulletconstant;
  28
  29         W_SetupShot (self, autocvar_g_antilag_bullets && bulletspeed >= autocvar_g_antilag_bullets, 5, "weapons/shotgun_fire.wav", CHAN_WEAPON, d * bullets);
  30         for (sc = 0;sc < bullets;sc = sc + 1)
  31                 fireBallisticBullet(w_shotorg, w_shotdir, spread, bulletspeed, 5, d, 0, f, WEP_SHOTGUN, 0, 1, bulletconstant);
  32         endFireBallisticBullet();
  33         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
  34                 self.ammo_shells = self.ammo_shells - ammoamount;
  35
  36         pointparticles(particleeffectnum("shotgun_muzzleflash"), w_shotorg, w_shotdir * 1000, autocvar_g_balance_shotgun_primary_ammo);
  37
  38         // casing code
  39         if (autocvar_g_casings >= 1)
  40                 for (sc = 0;sc < ammoamount;sc = sc + 1)
  41                         SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 30) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 1, self);
  42
  43         // muzzle flash for 1st person view
  44         flash = spawn();
  45         setmodel(flash, "models/uziflash.md3"); // precision set below
  46         flash.think = SUB_Remove;
  47         flash.nextthink = time + 0.06;
  48         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
  49         W_AttachToShotorg(flash, '5 0 0');
  50
  51         self.sniperrifle_bulletcounter = self.sniperrifle_bulletcounter - 1;
  52 }
  53
  54 void shotgun_meleethink (void)
  55 {
  56         // store time when we started swinging down inside self.cnt
  57         if(!self.cnt)
  58                 self.cnt = time;
  59
  60         makevectors(self.owner.v_angle);
  61         vector angle;
  62         angle = v_forward;
  63
  64         float meleetime;
  65         meleetime = autocvar_g_balance_shotgun_secondary_melee_time * W_WeaponRateFactor();
  66
  67         // perform trace
  68         float f;
  69         f = (self.cnt + meleetime - time) / meleetime * 2 - 1;
  70         vector targpos;
  71         targpos = self.owner.origin + self.owner.view_ofs + angle * autocvar_g_balance_shotgun_secondary_melee_range + v_right * f * autocvar_g_balance_shotgun_secondary_melee_swing + v_up * f * autocvar_g_balance_shotgun_secondary_melee_swing;
  72
  73         WarpZone_traceline_antilag(self.owner, self.owner.origin + self.owner.view_ofs, targpos, FALSE, self.owner, ANTILAG_LATENCY(self.owner));
  74
  75         // apply the damage, also remove self
  76         if(trace_fraction < 1 && trace_ent.takedamage == DAMAGE_AIM && (trace_ent.classname == "player" || trace_ent.classname == "body"))
  77         {
  78                 vector force;
  79                 force = angle * autocvar_g_balance_shotgun_secondary_force;
  80                 if(accuracy_isgooddamage(self.owner, trace_ent))
  81                         accuracy_add(self.owner, WEP_SHOTGUN, 0, autocvar_g_balance_shotgun_secondary_damage * min(1, f + 1));
  82                 Damage (trace_ent, self.owner, self.owner, autocvar_g_balance_shotgun_secondary_damage * min(1, f + 1), WEP_SHOTGUN | HITTYPE_SECONDARY , self.owner.origin + self.owner.view_ofs, force);
  83                 remove(self);
  84         }
  85         else if(time >= self.cnt + meleetime) // missed, remove ent
  86                 remove(self);
  87         else // continue swinging the weapon in hope of hitting someone :)
  88                 self.nextthink = time;
  89 }
  90
  91 void W_Shotgun_Attack2 (void)
  92 {
  93         sound (self, CHAN_PROJECTILE, "weapons/shotgun_melee.wav", VOL_BASE, ATTN_NORM);
  94         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_shotgun_secondary_animtime, w_ready);
  95
  96         entity meleetemp;
  97         meleetemp = spawn();
  98         meleetemp.owner = self;
  99         meleetemp.think = shotgun_meleethink;
 100         meleetemp.nextthink = time + autocvar_g_balance_shotgun_secondary_melee_delay;
 101         W_SetupShot_Range(self, TRUE, 0, "", 0, autocvar_g_balance_shotgun_secondary_damage, autocvar_g_balance_shotgun_secondary_melee_range);
 102 }
 103
 104 void spawnfunc_weapon_shotgun(); // defined in t_items.qc
 105
 106 .float shotgun_primarytime;
 107
 108 float w_shotgun(float req)
 109 {
 110         if (req == WR_AIM)
 111                 if(vlen(self.origin-self.enemy.origin) <= autocvar_g_balance_shotgun_secondary_melee_range)
 112                         self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, FALSE);
 113                 else
 114                         self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, FALSE);
 115         else if (req == WR_THINK)
 116         {
 117                 if(self.sniperrifle_bulletcounter < 0) // forced reload (e.g. because interrupted)
 118             self.wish_reload = 1;
 119                 else
 120                 {
 121                         if (self.BUTTON_ATCK)
 122                         {
 123                                 if (time >= self.shotgun_primarytime) // handle refire separately so the secondary can be fired straight after a primary
 124                                 {
 125                                         if(weapon_prepareattack(0, autocvar_g_balance_shotgun_primary_animtime))
 126                                         {
 127                                                 W_Shotgun_Attack();
 128                                                 self.shotgun_primarytime = time + autocvar_g_balance_shotgun_primary_refire;
 129                                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_shotgun_primary_animtime, w_ready);
 130                                         }
 131                                 }
 132                         }
 133                         if (self.BUTTON_ATCK2 && autocvar_g_balance_shotgun_secondary)
 134                         if (weapon_prepareattack(1, autocvar_g_balance_shotgun_secondary_refire))
 135                         {
 136                                 // attempt forcing playback of the anim by switching to another anim (that we never play) here...
 137                                 weapon_thinkf(WFRAME_FIRE1, 0, W_Shotgun_Attack2);
 138                         }
 139                 }
 140         if(self.wish_reload)
 141         {
 142             if(self.switchweapon == self.weapon)
 143             {
 144                 if(self.weaponentity.state == WS_READY)
 145                 {
 146                     self.wish_reload = 0;
 147                     W_SniperRifle_Reload();
 148                 }
 149             }
 150         }
 151         }
 152         else if (req == WR_PRECACHE)
 153         {
 154                 precache_model ("models/uziflash.md3");
 155                 precache_model ("models/weapons/g_shotgun.md3");
 156                 precache_model ("models/weapons/v_shotgun.md3");
 157                 precache_model ("models/weapons/h_shotgun.iqm");
 158                 precache_sound ("misc/itempickup.wav");
 159                 precache_sound ("weapons/shotgun_fire.wav");
 160                 precache_sound ("weapons/shotgun_melee.wav");
 161         }
 162         else if (req == WR_SETUP)
 163                 weapon_setup(WEP_SHOTGUN);
 164         else if (req == WR_CHECKAMMO1)
 165                 return self.ammo_shells >= autocvar_g_balance_shotgun_primary_ammo;
 166         else if (req == WR_CHECKAMMO2)
 167         {
 168                 return TRUE;
 169         }
 170         return TRUE;
 171 };
 172 #endif
 173 #ifdef CSQC
 174 .float prevric;
 175 float w_shotgun(float req)
 176 {
 177         if(req == WR_IMPACTEFFECT)
 178         {
 179                 vector org2;
 180                 org2 = w_org + w_backoff * 2;
 181                 pointparticles(particleeffectnum("shotgun_impact"), org2, w_backoff * 1000, 1);
 182                 if(!w_issilent && time - self.prevric > 0.25)
 183                 {
 184                         if(w_random < 0.0165)
 185                                 sound(self, CHAN_PROJECTILE, "weapons/ric1.wav", VOL_BASE, ATTN_NORM);
 186                         else if(w_random < 0.033)
 187                                 sound(self, CHAN_PROJECTILE, "weapons/ric2.wav", VOL_BASE, ATTN_NORM);
 188                         else if(w_random < 0.05)
 189                                 sound(self, CHAN_PROJECTILE, "weapons/ric3.wav", VOL_BASE, ATTN_NORM);
 190                         self.prevric = time;
 191                 }
 192         }
 193         else if(req == WR_PRECACHE)
 194         {
 195                 precache_sound("weapons/ric1.wav");
 196                 precache_sound("weapons/ric2.wav");
 197                 precache_sound("weapons/ric3.wav");
 198         }
 199         else if (req == WR_SUICIDEMESSAGE)
 200                 w_deathtypestring = "%s did the impossible";
 201         else if (req == WR_KILLMESSAGE)
 202         {
 203                 if(w_deathtype & HITTYPE_SECONDARY)
 204                         w_deathtypestring = "%2$s ^7slapped %1$s ^7around a bit with a large ^2shotgun";
 205                 else
 206                         w_deathtypestring = "%s was gunned by %s";
 207         }
 208         return TRUE;
 209 }
 210 #endif
 211 #endif