qcsrc/server/w_shotgun.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(SHOTGUN, w_shotgun, IT_SHELLS, 2, WEP_FLAG_NORMAL | WEP_TYPE_HITSCAN, BOT_PICKUP_RATING_LOW, "shotgun", "shotgun", "Shotgun");
   3 #else
   4 #ifdef SVQC
   5 void W_Shotgun_Attack (void)
   6 {
   7         float   sc;
   8         float   ammoamount;
   9         float   bullets;
  10         float   d;
  11         float   f;
  12         float   spread;
  13         float   bulletspeed;
  14         float   bulletconstant;
  15         local entity flash;
  16
  17         ammoamount = cvar("g_balance_shotgun_primary_ammo");
  18         bullets = cvar("g_balance_shotgun_primary_bullets");
  19         d = cvar("g_balance_shotgun_primary_damage");
  20         f = cvar("g_balance_shotgun_primary_force");
  21         spread = cvar("g_balance_shotgun_primary_spread");
  22         bulletspeed = cvar("g_balance_shotgun_primary_speed");
  23         bulletconstant = cvar("g_balance_shotgun_primary_bulletconstant");
  24
  25         W_SetupShot (self, cvar("g_antilag_bullets") && bulletspeed >= cvar("g_antilag_bullets"), 5, "weapons/shotgun_fire.wav", cvar("g_balance_shotgun_primary_damage"));
  26         for (sc = 0;sc < bullets;sc = sc + 1)
  27                 fireBallisticBullet(w_shotorg, w_shotdir, spread, bulletspeed, 5, d, 0, f, WEP_SHOTGUN, 0, 1, bulletconstant);
  28         endFireBallisticBullet();
  29         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
  30                 self.ammo_shells = self.ammo_shells - ammoamount;
  31
  32         pointparticles(particleeffectnum("shotgun_muzzleflash"), w_shotorg, w_shotdir * 1000, cvar("g_balance_shotgun_primary_ammo"));
  33
  34         // casing code
  35         if (cvar("g_casings") >= 1)
  36                 for (sc = 0;sc < ammoamount;sc = sc + 1)
  37                         SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 30) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 1, self);
  38
  39         // muzzle flash for 1st person view
  40         flash = spawn();
  41         setmodel(flash, "models/uziflash.md3"); // precision set below
  42         flash.think = SUB_Remove;
  43         flash.nextthink = time + 0.06;
  44         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
  45         W_AttachToShotorg(flash, '5 0 0');
  46
  47 }
  48
  49 void W_Shotgun_Attack2 (void)
  50 {
  51         float   sc;
  52         float   ammoamount;
  53         float   bullets;
  54         float   d;
  55         float   f;
  56         float   spread;
  57         float   bulletspeed;
  58         float   bulletconstant;
  59         local entity flash;
  60
  61         ammoamount = cvar("g_balance_shotgun_secondary_ammo");
  62         bullets = cvar("g_balance_shotgun_secondary_bullets");
  63         d = cvar("g_balance_shotgun_secondary_damage");
  64         f = cvar("g_balance_shotgun_secondary_force");
  65         spread = cvar("g_balance_shotgun_secondary_spread");
  66         bulletspeed = cvar("g_balance_shotgun_secondary_speed");
  67         bulletconstant = cvar("g_balance_shotgun_secondary_bulletconstant");
  68
  69         W_SetupShot (self, cvar("g_antilag_bullets") && bulletspeed >= cvar("g_antilag_bullets"), 5, "weapons/shotgun_fire.wav", cvar("g_balance_shotgun_secondary_damage"));
  70         for (sc = 0;sc < bullets;sc = sc + 1)
  71                 fireBallisticBullet(w_shotorg, w_shotdir, spread, bulletspeed, 5, d, 0, f, WEP_SHOTGUN | HITTYPE_SECONDARY, 0, 1, bulletconstant);
  72         endFireBallisticBullet();
  73         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
  74                 self.ammo_shells = self.ammo_shells - ammoamount;
  75
  76         pointparticles(particleeffectnum("shotgun_muzzleflash"), w_shotorg, w_shotdir * 1000, cvar("g_balance_shotgun_secondary_ammo"));
  77
  78         // casing code
  79         if (cvar("g_casings") >= 1)
  80                 for (sc = 0;sc < ammoamount;sc = sc + 1)
  81                         SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 30) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 1, self);
  82
  83         flash = spawn();
  84         setmodel(flash, "models/uziflash.md3"); // precision set below
  85         flash.scale = 1.2;
  86         flash.think = SUB_Remove;
  87         flash.nextthink = time + 0.06;
  88         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
  89         W_AttachToShotorg(flash, '5 0 0');
  90 }
  91
  92 void shotgun_meleethink (void)
  93 {
  94         // store time when we started swinging down inside self.cnt
  95         if(!self.cnt)
  96                 self.cnt = time;
  97
  98         makevectors(self.owner.v_angle);
  99         vector angle;
 100         angle = v_forward;
 101
 102         // broken? fix, needs to be easier to hit EDIT: maybe not :)
 103         //WarpZone_tracebox_antilag(self.owner, self.owner.origin + self.owner.view_ofs, self.owner.origin + self.owner.view_ofs + angle * cvar("g_balance_shotgun_secondary_melee_range") - (v_right + v_up) * cvar("g_balance_shotgun_secondary_melee_size"), self.owner.origin + self.owner.view_ofs + (v_right + v_up) * cvar("g_balance_shotgun_secondary_melee_size"), self.owner.origin + self.owner.view_ofs + angle * cvar("g_balance_shotgun_secondary_melee_range"), FALSE, self.owner, ANTILAG_LATENCY(self.owner));
 104         float f;
 105         f = (self.cnt + cvar("g_balance_shotgun_secondary_melee_time") - time) / cvar("g_balance_shotgun_secondary_melee_time") * 2 - 1;
 106         vector targpos;
 107         targpos = self.owner.origin + self.owner.view_ofs + angle * cvar("g_balance_shotgun_secondary_melee_range") + v_right * f * cvar("g_balance_shotgun_secondary_melee_swing") + v_up * f * cvar("g_balance_shotgun_secondary_melee_swing");
 108         WarpZone_traceline_antilag(self.owner, self.owner.origin + self.owner.view_ofs, targpos, FALSE, self.owner, ANTILAG_LATENCY(self.owner));
 109
 110         // apply the damage, also remove self
 111         if(trace_fraction < 1)
 112         {
 113                 vector force;
 114                 force = angle * cvar("g_balance_shotgun_secondary_force");
 115                 Damage (trace_ent, self.owner, self.owner, cvar("g_balance_shotgun_secondary_damage") * ((f + 1) / 2), WEP_SHOTGUN, self.owner.origin + self.owner.view_ofs, force);
 116                 remove(self);
 117         }
 118         else if(time >= self.cnt + cvar("g_balance_shotgun_secondary_melee_time")) // missed, remove ent
 119                 remove(self);
 120         else // continue swinging the weapon in hope of hitting someone :)
 121                 self.nextthink = time;
 122 }
 123
 124 void W_Shotgun_Attack3 (void)
 125 {
 126         sound (self, CHAN_PROJECTILE, "weapons/shotgun_melee.wav", VOL_BASE, ATTN_NORM);
 127         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_shotgun_secondary_animtime"), w_ready);
 128
 129         entity meleetemp;
 130         meleetemp = spawn();
 131         meleetemp.owner = self;
 132         meleetemp.think = shotgun_meleethink;
 133         meleetemp.nextthink = time + cvar("g_balance_shotgun_secondary_melee_delay");
 134 }
 135
 136 // weapon frames
 137 void shotgun_fire2_03()
 138 {
 139         W_Shotgun_Attack2();
 140         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_shotgun_secondary_animtime"), w_ready);
 141 }
 142 void shotgun_fire2_02()
 143 {
 144         W_Shotgun_Attack2();
 145         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_shotgun_secondary_animtime"), shotgun_fire2_03);
 146 }
 147
 148 void spawnfunc_weapon_shotgun(); // defined in t_items.qc
 149
 150 float w_shotgun(float req)
 151 {
 152         if (req == WR_AIM)
 153                 if(vlen(self.origin-self.enemy.origin)>200)
 154                         self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, FALSE);
 155                 else
 156                         self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, FALSE);
 157         else if (req == WR_THINK)
 158         {
 159                 if (self.BUTTON_ATCK)
 160                 if (weapon_prepareattack(0, cvar("g_balance_shotgun_primary_refire")))
 161                 {
 162                         W_Shotgun_Attack();
 163                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_shotgun_primary_animtime"), w_ready);
 164                 }
 165                 if (self.BUTTON_ATCK2 && cvar("g_balance_shotgun_secondary"))
 166                 if (weapon_prepareattack(1, cvar("g_balance_shotgun_secondary_refire")))
 167                 {
 168                         if(cvar("g_balance_shotgun_secondary_melee"))
 169                         {
 170                                 // force playback of the anim by switching to another anim (that we never play) here...
 171                                 weapon_thinkf(WFRAME_FIRE1, 0, W_Shotgun_Attack3);
 172                         }
 173                         else
 174                         {
 175                                 W_Shotgun_Attack2();
 176                                 weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_shotgun_secondary_animtime"), shotgun_fire2_02);
 177                         }
 178                 }
 179         }
 180         else if (req == WR_PRECACHE)
 181         {
 182                 precache_model ("models/uziflash.md3");
 183                 precache_model ("models/weapons/g_shotgun.md3");
 184                 precache_model ("models/weapons/v_shotgun.md3");
 185                 precache_model ("models/weapons/h_shotgun.iqm");
 186                 precache_sound ("misc/itempickup.wav");
 187                 precache_sound ("weapons/shotgun_fire.wav");
 188                 precache_sound ("weapons/shotgun_melee.wav");
 189         }
 190         else if (req == WR_SETUP)
 191                 weapon_setup(WEP_SHOTGUN);
 192         else if (req == WR_CHECKAMMO1)
 193                 return self.ammo_shells >= cvar("g_balance_shotgun_primary_ammo");
 194         else if (req == WR_CHECKAMMO2)
 195         {
 196                 if(cvar("g_balance_shotgun_secondary_melee"))
 197                         return TRUE;
 198                 return self.ammo_shells >= cvar("g_balance_shotgun_secondary_ammo") * 3;
 199         }
 200         return TRUE;
 201 };
 202 #endif
 203 #ifdef CSQC
 204 float w_shotgun(float req)
 205 {
 206         if(req == WR_IMPACTEFFECT)
 207         {
 208                 vector org2;
 209                 org2 = w_org + w_backoff * 2;
 210                 pointparticles(particleeffectnum("shotgun_impact"), org2, w_backoff * 1000, 1);
 211                 if(!w_issilent)
 212                 {
 213                         if(w_random < 0.05)
 214                                 sound(self, CHAN_PROJECTILE, "weapons/ric1.wav", VOL_BASE, ATTN_NORM);
 215                         else if(w_random < 0.1)
 216                                 sound(self, CHAN_PROJECTILE, "weapons/ric2.wav", VOL_BASE, ATTN_NORM);
 217                         else if(w_random < 0.2)
 218                                 sound(self, CHAN_PROJECTILE, "weapons/ric3.wav", VOL_BASE, ATTN_NORM);
 219                 }
 220         }
 221         else if(req == WR_PRECACHE)
 222         {
 223                 precache_sound("weapons/ric1.wav");
 224                 precache_sound("weapons/ric2.wav");
 225                 precache_sound("weapons/ric3.wav");
 226         }
 227         else if (req == WR_SUICIDEMESSAGE)
 228                 w_deathtypestring = "did the impossible";
 229         else if (req == WR_KILLMESSAGE)
 230         {
 231                 w_deathtypestring = "was gunned by"; // unchecked: SECONDARY
 232         }
 233         return TRUE;
 234 }
 235 #endif
 236 #endif