qcsrc/server/waypointsprites.qc

   1 ..entity owned_by_field;
   2 .float rule;
   3 .string model1;
   4 .string model2;
   5 .string model3;
   6
   7 .float(entity) waypointsprite_visible_for_player;
   8
   9 void WaypointSprite_UpdateSprites(entity e, string m1, string m2, string m3)
  10 {
  11         if(m1 != e.model1)
  12         {
  13                 e.model1 = m1;
  14                 e.SendFlags |= 2;
  15         }
  16         if(m2 != e.model2)
  17         {
  18                 e.model2 = m2;
  19                 e.SendFlags |= 4;
  20         }
  21         if(m3 != e.model3)
  22         {
  23                 e.model3 = m3;
  24                 e.SendFlags |= 8;
  25         }
  26 }
  27
  28 void WaypointSprite_UpdateHealth(entity e, float f)
  29 {
  30         f = bound(0, f, e.max_health);
  31         if(f != e.health || e.pain_finished)
  32         {
  33                 e.health = f;
  34                 e.pain_finished = 0;
  35                 e.SendFlags |= 0x80;
  36         }
  37 }
  38
  39 void WaypointSprite_UpdateMaxHealth(entity e, float f)
  40 {
  41         if(f != e.max_health || e.pain_finished)
  42         {
  43                 e.max_health = f;
  44                 e.pain_finished = 0;
  45                 e.SendFlags |= 0x80;
  46         }
  47 }
  48
  49 void WaypointSprite_UpdateBuildFinished(entity e, float f)
  50 {
  51         if(f != e.pain_finished || e.max_health)
  52         {
  53                 e.max_health = 0;
  54                 e.pain_finished = f;
  55                 e.SendFlags |= 0x80;
  56         }
  57 }
  58
  59 void WaypointSprite_UpdateOrigin(entity e, vector o)
  60 {
  61         if(o != e.origin)
  62         {
  63                 setorigin(e, o);
  64                 e.SendFlags |= 64;
  65         }
  66 }
  67
  68 void WaypointSprite_UpdateRule(entity e, float t, float r)
  69 {
  70         // no check, as this is never called without doing an actual change (usually only once)
  71         e.rule = r;
  72         e.team = t;
  73         e.SendFlags |= 1;
  74 }
  75
  76 void WaypointSprite_UpdateTeamRadar(entity e, float icon, vector col)
  77 {
  78         // no check, as this is never called without doing an actual change (usually only once)
  79         e.cnt = (icon & 0x7F) | (e.cnt & 0x80);
  80         e.colormod = col;
  81         e.SendFlags |= 32;
  82 }
  83
  84 .float waypointsprite_pingtime;
  85 .float waypointsprite_helpmetime;
  86 void WaypointSprite_Ping(entity e)
  87 {
  88         // anti spam
  89         if(time < e.waypointsprite_pingtime)
  90                 return;
  91         e.waypointsprite_pingtime = time + 0.3;
  92         // ALWAYS sends (this causes a radar circle), thus no check
  93         e.cnt |= 0x80;
  94         e.SendFlags |= 32;
  95 }
  96
  97 float waypointsprite_limitedrange, waypointsprite_deployed_lifetime, waypointsprite_deadlifetime;
  98
  99 void WaypointSprite_HelpMePing(entity e)
 100 {
 101         WaypointSprite_Ping(e);
 102         e.waypointsprite_helpmetime = time + waypointsprite_deployed_lifetime;
 103         e.SendFlags |= 32;
 104 }
 105
 106 void WaypointSprite_FadeOutIn(entity e, float t)
 107 {
 108         if(!e.fade_time)
 109         {
 110                 e.fade_time = t;
 111                 e.teleport_time = time + t;
 112         }
 113         else if(t < (e.teleport_time - time))
 114         {
 115                 // accelerate the waypoint's dying
 116                 // ensure:
 117                 //   (e.teleport_time - time) / wp.fade_time stays
 118                 //   e.teleport_time = time + fadetime
 119                 float current_fadetime;
 120                 current_fadetime = e.teleport_time - time;
 121                 e.teleport_time = time + t;
 122                 e.fade_time = e.fade_time * t / current_fadetime;
 123         }
 124
 125         e.SendFlags |= 16;
 126 }
 127
 128 void WaypointSprite_Init()
 129 {
 130         waypointsprite_limitedrange = autocvar_sv_waypointsprite_limitedrange;
 131         waypointsprite_deployed_lifetime = autocvar_sv_waypointsprite_deployed_lifetime;
 132         waypointsprite_deadlifetime = autocvar_sv_waypointsprite_deadlifetime;
 133 }
 134 void WaypointSprite_InitClient(entity e)
 135 {
 136 }
 137
 138 void WaypointSprite_Kill(entity wp)
 139 {
 140         if(!wp)
 141                 return;
 142         if(wp.owner)
 143                 wp.owner.(wp.owned_by_field) = world;
 144         remove(wp);
 145 }
 146
 147 void WaypointSprite_Disown(entity wp, float fadetime)
 148 {
 149         if(!wp)
 150                 return;
 151         if(wp.classname != "sprite_waypoint")
 152         {
 153                 backtrace("Trying to disown a non-waypointsprite");
 154                 return;
 155         }
 156         if(wp.owner)
 157         {
 158                 if(wp.exteriormodeltoclient == wp.owner)
 159                         wp.exteriormodeltoclient = world;
 160                 wp.owner.(wp.owned_by_field) = world;
 161                 wp.owner = world;
 162
 163                 WaypointSprite_FadeOutIn(wp, fadetime);
 164         }
 165 }
 166
 167 void WaypointSprite_Think()
 168 {
 169         float doremove;
 170
 171         doremove = FALSE;
 172
 173         if(self.fade_time)
 174         {
 175                 if(time >= self.teleport_time)
 176                         doremove = TRUE;
 177         }
 178
 179         if(self.exteriormodeltoclient)
 180                 WaypointSprite_UpdateOrigin(self, self.exteriormodeltoclient.origin + self.view_ofs);
 181
 182         if(doremove)
 183                 WaypointSprite_Kill(self);
 184         else
 185                 self.nextthink = time; // WHY?!?
 186 }
 187
 188 float WaypointSprite_visible_for_player(entity e)
 189 {
 190         // personal waypoints
 191         if(self.enemy)
 192                 if(self.enemy != e)
 193                         return FALSE;
 194
 195         // team waypoints
 196         if(self.team && self.rule == SPRITERULE_DEFAULT)
 197         {
 198                 if(self.team != e.team)
 199                         return FALSE;
 200                 if not(IS_PLAYER(e))
 201                         return FALSE;
 202         }
 203
 204         return TRUE;
 205 }
 206
 207 entity WaypointSprite_getviewentity(entity e)
 208 {
 209         if(IS_SPEC(e))
 210                 e = e.enemy;
 211         /* TODO idea (check this breaks nothing)
 212         else if(e.classname == "observer")
 213                 e = world;
 214         */
 215         return e;
 216 }
 217
 218 float WaypointSprite_isteammate(entity e, entity e2)
 219 {
 220         if(teamplay)
 221         {
 222                 if(e2.team != e.team)
 223                         return FALSE;
 224         }
 225         else
 226         {
 227                 if(e2 != e)
 228                         return FALSE;
 229         }
 230         return TRUE;
 231 }
 232
 233 float WaypointSprite_Customize()
 234 {
 235         // this is not in SendEntity because it shall run every frame, not just every update
 236
 237         // make spectators see what the player would see
 238         entity e;
 239         e = WaypointSprite_getviewentity(other);
 240
 241         if(MUTATOR_CALLHOOK(CustomizeWaypoint))
 242                 return FALSE;
 243
 244         return self.waypointsprite_visible_for_player(e);
 245 }
 246
 247 float WaypointSprite_SendEntity(entity to, float sendflags)
 248 {
 249         float dt;
 250
 251         WriteByte(MSG_ENTITY, ENT_CLIENT_WAYPOINT);
 252
 253         sendflags = sendflags & 0x7F;
 254
 255         if(g_nexball)
 256                 sendflags &~= 0x80;
 257         else if(self.max_health || (self.pain_finished && (time < self.pain_finished + 0.25)))
 258                 sendflags |= 0x80;
 259
 260         WriteByte(MSG_ENTITY, sendflags);
 261
 262         if(sendflags & 0x80)
 263         {
 264                 if(self.max_health)
 265                 {
 266                         WriteByte(MSG_ENTITY, (self.health / self.max_health) * 191.0);
 267                 }
 268                 else
 269                 {
 270                         dt = self.pain_finished - time;
 271                         dt = bound(0, dt * 32, 16383);
 272                         WriteByte(MSG_ENTITY, (dt & 0xFF00) / 256 + 192);
 273                         WriteByte(MSG_ENTITY, (dt & 0x00FF));
 274                 }
 275         }
 276
 277         if(sendflags & 64)
 278         {
 279                 WriteCoord(MSG_ENTITY, self.origin_x);
 280                 WriteCoord(MSG_ENTITY, self.origin_y);
 281                 WriteCoord(MSG_ENTITY, self.origin_z);
 282         }
 283
 284         if(sendflags & 1)
 285         {
 286                 WriteByte(MSG_ENTITY, self.team);
 287                 WriteByte(MSG_ENTITY, self.rule);
 288         }
 289
 290         if(sendflags & 2)
 291                 WriteString(MSG_ENTITY, self.model1);
 292
 293         if(sendflags & 4)
 294                 WriteString(MSG_ENTITY, self.model2);
 295
 296         if(sendflags & 8)
 297                 WriteString(MSG_ENTITY, self.model3);
 298
 299         if(sendflags & 16)
 300         {
 301                 WriteCoord(MSG_ENTITY, self.fade_time);
 302                 WriteCoord(MSG_ENTITY, self.teleport_time);
 303                 WriteShort(MSG_ENTITY, self.fade_rate); // maxdist
 304                 float f;
 305                 f = 0;
 306                 if(self.currentammo)
 307                         f |= 1; // hideable
 308                 if(self.exteriormodeltoclient == to)
 309                         f |= 2; // my own
 310                 WriteByte(MSG_ENTITY, f);
 311         }
 312
 313         if(sendflags & 32)
 314         {
 315                 WriteByte(MSG_ENTITY, self.cnt); // icon on radar
 316                 WriteByte(MSG_ENTITY, self.colormod_x * 255.0);
 317                 WriteByte(MSG_ENTITY, self.colormod_y * 255.0);
 318                 WriteByte(MSG_ENTITY, self.colormod_z * 255.0);
 319
 320                 if(WaypointSprite_isteammate(self.owner, WaypointSprite_getviewentity(to)))
 321                 {
 322                         dt = (self.waypointsprite_helpmetime - time) / 0.1;
 323                         if(dt < 0)
 324                                 dt = 0;
 325                         if(dt > 255)
 326                                 dt = 255;
 327                         WriteByte(MSG_ENTITY, dt);
 328                 }
 329                 else
 330                         WriteByte(MSG_ENTITY, 0);
 331         }
 332
 333         return TRUE;
 334 }
 335
 336 void WaypointSprite_Reset()
 337 {
 338         // if a WP wants to time out, let it time out immediately; other WPs ought to be reset/killed by their owners
 339
 340         if(self.fade_time) // there was there before: || g_keyhunt, do we really need this?
 341                 WaypointSprite_Kill(self);
 342 }
 343
 344 entity WaypointSprite_Spawn(
 345         string spr, // sprite
 346         float lifetime, float maxdistance, // lifetime, max distance
 347         entity ref, vector ofs, // position
 348         entity showto, float t, // show to whom? Use a flag to indicate a team
 349         entity own, .entity ownfield, // remove when own gets killed
 350         float hideable, // true when it should be controlled by cl_hidewaypoints
 351         float icon, vector rgb // initial icon and color
 352 )
 353 {
 354         entity wp;
 355         wp = spawn();
 356         wp.classname = "sprite_waypoint";
 357         wp.teleport_time = time + lifetime;
 358         wp.fade_time = lifetime;
 359         wp.exteriormodeltoclient = ref;
 360         if(ref)
 361         {
 362                 wp.view_ofs = ofs;
 363                 setorigin(wp, ref.origin + ofs);
 364         }
 365         else
 366                 setorigin(wp, ofs);
 367         wp.enemy = showto;
 368         wp.team = t;
 369         wp.owner = own;
 370         wp.currentammo = hideable;
 371         if(own)
 372         {
 373                 if(own.ownfield)
 374                         remove(own.ownfield);
 375                 own.ownfield = wp;
 376                 wp.owned_by_field = ownfield;
 377         }
 378         wp.fade_rate = maxdistance;
 379         wp.think = WaypointSprite_Think;
 380         wp.nextthink = time;
 381         wp.model1 = spr;
 382         wp.customizeentityforclient = WaypointSprite_Customize;
 383         wp.waypointsprite_visible_for_player = WaypointSprite_visible_for_player;
 384         wp.reset2 = WaypointSprite_Reset;
 385         wp.cnt = icon;
 386         wp.colormod = rgb;
 387         Net_LinkEntity(wp, FALSE, 0, WaypointSprite_SendEntity);
 388         return wp;
 389 }
 390
 391 entity WaypointSprite_SpawnFixed(
 392         string spr,
 393         vector ofs,
 394         entity own,
 395         .entity ownfield,
 396         float icon, vector rgb // initial icon and color
 397 )
 398 {
 399         return WaypointSprite_Spawn(spr, 0, 0, world, ofs, world, 0, own, ownfield, TRUE, icon, rgb);
 400 }
 401
 402 .entity waypointsprite_deployed_fixed;
 403 entity WaypointSprite_DeployFixed(
 404         string spr,
 405         float limited_range,
 406         vector ofs,
 407         float icon, vector rgb // initial icon and color
 408 )
 409 {
 410         float t, maxdistance;
 411         if(teamplay)
 412                 t = self.team;
 413         else
 414                 t = 0;
 415         if(limited_range)
 416                 maxdistance = waypointsprite_limitedrange;
 417         else
 418                 maxdistance = 0;
 419         return WaypointSprite_Spawn(spr, waypointsprite_deployed_lifetime, maxdistance, world, ofs, world, t, self, waypointsprite_deployed_fixed, FALSE, icon, rgb);
 420 }
 421
 422 .entity waypointsprite_deployed_personal;
 423 entity WaypointSprite_DeployPersonal(
 424         string spr,
 425         vector ofs,
 426         float icon, vector rgb // initial icon and color
 427 )
 428 {
 429         return WaypointSprite_Spawn(spr, 0, 0, world, ofs, world, 0, self, waypointsprite_deployed_personal, FALSE, icon, rgb);
 430 }
 431
 432 .entity waypointsprite_attached;
 433 .entity waypointsprite_attachedforcarrier;
 434 entity WaypointSprite_Attach(
 435         string spr,
 436         float limited_range,
 437         float icon, vector rgb // initial icon and color
 438 )
 439 {
 440         float t, maxdistance;
 441         if(self.waypointsprite_attachedforcarrier)
 442                 return world; // can't attach to FC
 443         if(teamplay)
 444                 t = self.team;
 445         else
 446                 t = 0;
 447         if(limited_range)
 448                 maxdistance = waypointsprite_limitedrange;
 449         else
 450                 maxdistance = 0;
 451         return WaypointSprite_Spawn(spr, waypointsprite_deployed_lifetime, maxdistance, self, '0 0 64', world, t, self, waypointsprite_attached, FALSE, icon, rgb);
 452 }
 453
 454 entity WaypointSprite_AttachCarrier(
 455         string spr,
 456         entity carrier,
 457         float icon, vector rgb // initial icon and color
 458 )
 459 {
 460         entity e;
 461         WaypointSprite_Kill(carrier.waypointsprite_attached); // FC overrides attached
 462         e = WaypointSprite_Spawn(spr, 0, 0, carrier, '0 0 64', world, carrier.team, carrier, waypointsprite_attachedforcarrier, FALSE, icon, rgb);
 463         if(e)
 464         {
 465                 WaypointSprite_UpdateMaxHealth(e, '1 0 0' * healtharmor_maxdamage(start_health, start_armorvalue, autocvar_g_balance_armor_blockpercent) * 2);
 466                 WaypointSprite_UpdateHealth(e, '1 0 0' * healtharmor_maxdamage(carrier.health, carrier.armorvalue, autocvar_g_balance_armor_blockpercent));
 467         }
 468         return e;
 469 }
 470
 471 void WaypointSprite_DetachCarrier(entity carrier)
 472 {
 473         WaypointSprite_Disown(carrier.waypointsprite_attachedforcarrier, waypointsprite_deadlifetime);
 474 }
 475
 476 void WaypointSprite_ClearPersonal()
 477 {
 478         WaypointSprite_Kill(self.waypointsprite_deployed_personal);
 479 }
 480
 481 void WaypointSprite_ClearOwned()
 482 {
 483         WaypointSprite_Kill(self.waypointsprite_deployed_fixed);
 484         WaypointSprite_Kill(self.waypointsprite_deployed_personal);
 485         WaypointSprite_Kill(self.waypointsprite_attached);
 486 }
 487
 488 void WaypointSprite_PlayerDead()
 489 {
 490         WaypointSprite_Disown(self.waypointsprite_attached, waypointsprite_deadlifetime);
 491         WaypointSprite_DetachCarrier(self);
 492 }
 493
 494 void WaypointSprite_PlayerGone()
 495 {
 496         WaypointSprite_Disown(self.waypointsprite_deployed_fixed, waypointsprite_deadlifetime);
 497         WaypointSprite_Kill(self.waypointsprite_deployed_personal);
 498         WaypointSprite_Disown(self.waypointsprite_attached, waypointsprite_deadlifetime);
 499         WaypointSprite_DetachCarrier(self);
 500 }