qcsrc/server/weapons/tracing.qc

   1 #include "tracing.qh"
   2
   3 #include <common/effects/all.qh>
   4
   5 #include "accuracy.qh"
   6 #include "common.qh"
   7 #include "hitplot.qh"
   8 #include "weaponsystem.qh"
   9
  10 #include "../g_damage.qh"
  11 #include "../antilag.qh"
  12
  13 #include <common/constants.qh>
  14 #include <common/net_linked.qh>
  15 #include <common/util.qh>
  16
  17 #include <common/weapons/_all.qh>
  18 #include <common/wepent.qh>
  19 #include <common/state.qh>
  20
  21 #include <lib/warpzone/common.qh>
  22
  23 // this function calculates w_shotorg and w_shotdir based on the weapon model
  24 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
  25 // make sure you call makevectors first (FIXME?)
  26 void W_SetupShot_Dir_ProjectileSize_Range(entity ent, .entity weaponentity, vector s_forward, vector mi, vector ma, float antilag, float recoil, Sound snd, float chan, float maxdamage, float range, int deathtype)
  27 {
  28         TC(Sound, snd);
  29         float oldsolid = ent.dphitcontentsmask;
  30         Weapon wep = DEATH_WEAPONOF(deathtype);
  31         if(!IS_CLIENT(ent))
  32                 antilag = false; // no antilag for non-clients!
  33         if (IS_PLAYER(ent) && (wep.spawnflags & WEP_FLAG_PENETRATEWALLS))
  34         {
  35                 // This is the reason rifle, MG, OKMG and other fireBullet weapons don't hit the crosshair when shooting at walls.
  36                 // This is intentional, otherwise if you stand too close to a (glass) wall and attempt to shoot an enemy through it,
  37                 // trueaim will cause the shot to hit the wall exactly but then miss the enemy (unless shooting from eye/center).
  38                 // TODO for fireBullet, find how far the shot will penetrate and aim at that
  39                 //      for fireRailgunbullet, find the farthest target and aim at that
  40                 //      this will avoid issues when another player is passing in front of you when you shoot
  41                 //      (currently such a shot will hit him but then miss the original target)
  42                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  43         }
  44         else
  45                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  46         if(antilag)
  47                 WarpZone_traceline_antilag(NULL, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  48                 // passing NULL, because we do NOT want it to touch dphitcontentsmask
  49         else
  50                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NOMONSTERS, ent);
  51         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  52
  53         w_shotend = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
  54
  55         // un-adjust trueaim if shotend is too close
  56         if(vdist(w_shotend - (ent.origin + ent.view_ofs), <, autocvar_g_trueaim_minrange))
  57                 w_shotend = ent.origin + ent.view_ofs + s_forward * autocvar_g_trueaim_minrange;
  58
  59         // track max damage
  60         if (IS_PLAYER(ent) && accuracy_canbegooddamage(ent))
  61                 accuracy_add(ent, wep, maxdamage, 0);
  62
  63         if(IS_PLAYER(ent))
  64                 W_HitPlotAnalysis(ent, wep, v_forward, v_right, v_up);
  65
  66         vector md = ent.(weaponentity).movedir;
  67         vector vecs = ((md.x > 0) ? md : '0 0 0');
  68
  69         vector dv = v_forward * vecs.x + v_right * -vecs.y + v_up * vecs.z;
  70         w_shotorg = ent.origin + ent.view_ofs;
  71
  72         // now move the shotorg forward as much as requested if possible
  73         if(antilag)
  74         {
  75                 if(CS(ent).antilag_debug)
  76                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + dv, MOVE_NORMAL, ent, CS(ent).antilag_debug);
  77                 else
  78                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + dv, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  79         }
  80         else
  81                 tracebox(w_shotorg, mi, ma, w_shotorg + dv, MOVE_NORMAL, ent);
  82         w_shotorg = trace_endpos;
  83         // calculate the shotdir from the chosen shotorg
  84         if(W_DualWielding(ent))
  85                 w_shotdir = s_forward;
  86         else
  87                 w_shotdir = normalize(w_shotend - w_shotorg);
  88
  89         //vector prevdir = w_shotdir;
  90         //vector prevorg = w_shotorg;
  91         //vector prevend = w_shotend;
  92
  93         if (antilag)
  94         if (!CS(ent).cvar_cl_noantilag)
  95         {
  96                 if (autocvar_g_antilag == 1) // switch to "ghost" if not hitting original
  97                 {
  98                         traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
  99                         if (!trace_ent.takedamage)
 100                         {
 101                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 102                                 if (trace_ent.takedamage && IS_PLAYER(trace_ent))
 103                                 {
 104                                         entity e;
 105                                         e = trace_ent;
 106                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
 107                                         if(trace_ent == e)
 108                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
 109                                 }
 110                         }
 111                 }
 112                 else if(autocvar_g_antilag == 3) // client side hitscan
 113                 {
 114                         // this part MUST use prydon cursor
 115                         if (CS(ent).cursor_trace_ent)                 // client was aiming at someone
 116                         if (CS(ent).cursor_trace_ent != ent)         // just to make sure
 117                         if (CS(ent).cursor_trace_ent.takedamage)      // and that person is killable
 118                         if (IS_PLAYER(CS(ent).cursor_trace_ent)) // and actually a player
 119                         {
 120                                 // verify that the shot would miss without antilag
 121                                 // (avoids an issue where guns would always shoot at their origin)
 122                                 traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 123                                 if (!trace_ent.takedamage)
 124                                 {
 125                                         // verify that the shot would hit if altered
 126                                         traceline(w_shotorg, CS(ent).cursor_trace_ent.origin, MOVE_NORMAL, ent);
 127                                         if (trace_ent == CS(ent).cursor_trace_ent)
 128                                                 w_shotdir = normalize(CS(ent).cursor_trace_ent.origin - w_shotorg);
 129                                         else
 130                                                 LOG_INFO("antilag fail");
 131                                 }
 132                         }
 133                 }
 134         }
 135
 136         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
 137
 138         if (!autocvar_g_norecoil)
 139                 ent.punchangle_x = recoil * -1;
 140
 141         if (snd != SND_Null) {
 142                 sound(ent, chan, snd, (W_DualWielding(ent) ? VOL_BASE * 0.7 : VOL_BASE), ATTN_NORM);
 143                 W_PlayStrengthSound(ent);
 144         }
 145
 146         // nudge w_shotend so a trace to w_shotend hits
 147         w_shotend = w_shotend + normalize(w_shotend - w_shotorg);
 148         //if(w_shotend != prevend) { printf("SERVER: shotEND differs: %s - %s\n", vtos(w_shotend), vtos(prevend)); }
 149         //if(w_shotorg != prevorg) { printf("SERVER: shotORG differs: %s - %s\n", vtos(w_shotorg), vtos(prevorg)); }
 150         //if(w_shotdir != prevdir) { printf("SERVER: shotDIR differs: %s - %s\n", vtos(w_shotdir), vtos(prevdir)); }
 151 }
 152
 153 vector W_CalculateProjectileVelocity(entity actor, vector pvelocity, vector mvelocity, float forceAbsolute)
 154 {
 155         vector mdirection;
 156         float mspeed;
 157         vector outvelocity;
 158
 159         mvelocity = mvelocity * W_WeaponSpeedFactor(actor);
 160
 161         mdirection = normalize(mvelocity);
 162         mspeed = vlen(mvelocity);
 163
 164         outvelocity = get_shotvelocity(pvelocity, mdirection, mspeed, (forceAbsolute ? 0 : autocvar_g_projectiles_newton_style), autocvar_g_projectiles_newton_style_2_minfactor, autocvar_g_projectiles_newton_style_2_maxfactor);
 165
 166         return outvelocity;
 167 }
 168
 169 void W_SetupProjVelocity_Explicit(entity proj, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread, float forceAbsolute)
 170 {
 171         if(proj.owner == NULL)
 172                 error("Unowned missile");
 173
 174         dir = dir + upDir * (pUpSpeed / pSpeed);
 175         dir.z += pZSpeed / pSpeed;
 176         pSpeed *= vlen(dir);
 177         dir = normalize(dir);
 178
 179         #if 0
 180         if(autocvar_g_projectiles_spread_style != mspercallsstyle)
 181         {
 182                 mspercallsum = mspercallcount = 0;
 183                 mspercallsstyle = autocvar_g_projectiles_spread_style;
 184         }
 185         mspercallsum -= gettime(GETTIME_HIRES);
 186         #endif
 187
 188         dir = W_CalculateSpread(dir, spread, g_weaponspreadfactor, autocvar_g_projectiles_spread_style);
 189
 190         #if 0
 191         mspercallsum += gettime(GETTIME_HIRES);
 192         mspercallcount += 1;
 193         LOG_INFO("avg: ", ftos(mspercallcount / mspercallsum), " per sec");
 194         #endif
 195
 196         proj.velocity = W_CalculateProjectileVelocity(proj.owner, proj.owner.velocity, pSpeed * dir, forceAbsolute);
 197 }
 198
 199
 200 // ====================
 201 //  Ballistics Tracing
 202 // ====================
 203
 204 void FireRailgunBullet (entity this, .entity weaponentity, vector start, vector end, float bdamage, float bforce, float mindist, float maxdist, float halflifedist, float forcehalflifedist, int deathtype)
 205 {
 206         entity pseudoprojectile = NULL;
 207
 208         vector dir = normalize(end - start);
 209         float length = vlen(end - start);
 210         vector force = dir * bforce;
 211
 212         // go a little bit into the wall because we need to hit this wall later
 213         end = end + dir;
 214
 215         float totaldmg = 0;
 216
 217         // trace multiple times until we hit a wall, each obstacle will be made
 218         // non-solid so we can hit the next, while doing this we spawn effects and
 219         // note down which entities were hit so we can damage them later
 220         entity o = this;
 221         while (1)
 222         {
 223                 if(CS(this).antilag_debug)
 224                         WarpZone_traceline_antilag (this, start, end, false, o, CS(this).antilag_debug);
 225                 else
 226                         WarpZone_traceline_antilag (this, start, end, false, o, ANTILAG_LATENCY(this));
 227                 if(o && WarpZone_trace_firstzone)
 228                 {
 229                         o = NULL;
 230                         continue;
 231                 }
 232
 233                 if(trace_ent.solid == SOLID_BSP || trace_ent.solid == SOLID_SLIDEBOX)
 234                         Damage_DamageInfo(trace_endpos, bdamage, 0, 0, force, deathtype, trace_ent.species, this);
 235
 236                 // if it is NULL we can't hurt it so stop now
 237                 if (trace_ent == NULL || trace_fraction == 1)
 238                         break;
 239
 240                 // make the entity non-solid so we can hit the next one
 241                 IL_PUSH(g_railgunhit, trace_ent);
 242                 trace_ent.railgunhit = true;
 243                 trace_ent.railgunhitloc = end;
 244                 trace_ent.railgunhitsolidbackup = trace_ent.solid;
 245                 trace_ent.railgundistance = vlen(WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos) - start);
 246                 trace_ent.railgunforce = WarpZone_TransformVelocity(WarpZone_trace_transform, force);
 247
 248                 // stop if this is a wall
 249                 if (trace_ent.solid == SOLID_BSP)
 250                         break;
 251
 252                 // make the entity non-solid
 253                 trace_ent.solid = SOLID_NOT;
 254         }
 255
 256         vector endpoint = trace_endpos;
 257         entity endent = trace_ent;
 258         float endq3surfaceflags = trace_dphitq3surfaceflags;
 259
 260         // find all the entities the railgun hit and restore their solid state
 261         IL_EACH(g_railgunhit, it.railgunhit,
 262         {
 263                 it.solid = it.railgunhitsolidbackup;
 264         });
 265
 266         // spawn a temporary explosion entity for RadiusDamage calls
 267         //explosion = spawn();
 268
 269         // Find all non-hit players the beam passed close by
 270         if(deathtype == WEP_VAPORIZER.m_id || deathtype == WEP_VORTEX.m_id) // WEAPONTODO
 271         {
 272                 FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != this, {
 273                         if(!it.railgunhit)
 274                         if(!(IS_SPEC(it) && it.enemy == this))
 275                         {
 276                                 msg_entity = it;
 277                                 // nearest point on the beam
 278                                 vector beampos = start + dir * bound(0, (msg_entity.origin - start) * dir, length);
 279
 280                                 float f = bound(0, 1 - vlen(beampos - msg_entity.origin) / 512, 1);
 281                                 if(f <= 0)
 282                                         continue;
 283
 284                                 if(!pseudoprojectile)
 285                                         pseudoprojectile = spawn(); // we need this so the sound uses the "entchannel4" volume
 286                                 soundtoat(MSG_ONE, pseudoprojectile, beampos, CH_SHOTS, SND(NEXWHOOSH_RANDOM()), VOL_BASE * f, ATTEN_NONE);
 287                         }
 288                 });
 289
 290                 if(pseudoprojectile)
 291                         delete(pseudoprojectile);
 292         }
 293
 294         // find all the entities the railgun hit and hurt them
 295         IL_EACH(g_railgunhit, it.railgunhit,
 296         {
 297                 // removal from the list is handled below
 298
 299                 // get the details we need to call the damage function
 300                 vector hitloc = it.railgunhitloc;
 301
 302                 float foff = ExponentialFalloff(mindist, maxdist, halflifedist, it.railgundistance);
 303                 float ffs = ExponentialFalloff(mindist, maxdist, forcehalflifedist, it.railgundistance);
 304
 305                 if(accuracy_isgooddamage(this, it))
 306                         totaldmg += bdamage * foff;
 307
 308                 // apply the damage
 309                 if (it.takedamage)
 310                         Damage (it, this, this, bdamage * foff, deathtype, weaponentity, hitloc, it.railgunforce * ffs);
 311
 312                 // create a small explosion to throw gibs around (if applicable)
 313                 //setorigin(explosion, hitloc);
 314                 //RadiusDamage (explosion, this, 10, 0, 50, NULL, NULL, 300, deathtype);
 315
 316                 it.railgunhitloc = '0 0 0';
 317                 it.railgunhitsolidbackup = SOLID_NOT;
 318                 it.railgunhit = false;
 319                 it.railgundistance = 0;
 320         });
 321
 322         IL_CLEAR(g_railgunhit);
 323
 324         // calculate hits and fired shots for hitscan
 325         if(this.(weaponentity))
 326                 accuracy_add(this, this.(weaponentity).m_weapon, 0, min(bdamage, totaldmg));
 327
 328         trace_endpos = endpoint;
 329         trace_ent = endent;
 330         trace_dphitq3surfaceflags = endq3surfaceflags;
 331 }
 332
 333 void fireBullet_trace_callback(vector start, vector hit, vector end)
 334 {
 335         if(vdist(hit - start, >, 16))
 336                 trailparticles(NULL, fireBullet_trace_callback_eff, start, hit);
 337         WarpZone_trace_forent = NULL;
 338         fireBullet_last_hit = NULL;
 339 }
 340
 341 void fireBullet(entity this, .entity weaponentity, vector start, vector dir, float spread, float max_solid_penetration, float damage, float force, float dtype, entity tracer_effect)
 342 {
 343         vector  end;
 344
 345         dir = normalize(dir + randomvec() * spread);
 346         end = start + dir * max_shot_distance;
 347
 348         fireBullet_last_hit = NULL;
 349         fireBullet_trace_callback_eff = tracer_effect;
 350
 351         float solid_penetration_left = 1;
 352         float total_damage = 0;
 353
 354         float lag = ((IS_REAL_CLIENT(this)) ? ANTILAG_LATENCY(this) : 0);
 355         if(lag < 0.001)
 356                 lag = 0;
 357         bool noantilag = ((IS_CLIENT(this)) ? CS(this).cvar_cl_noantilag : false);
 358         if(autocvar_g_antilag == 0 || noantilag)
 359                 lag = 0; // only do hitscan, but no antilag
 360         if(lag)
 361                 antilag_takeback_all(this, lag);
 362
 363         // change shooter to SOLID_BBOX so the shot can hit corpses
 364         int oldsolid = this.dphitcontentsmask;
 365         if(this)
 366                 this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 367
 368         WarpZone_trace_forent = this;
 369
 370         for (;;)
 371         {
 372                 // TODO also show effect while tracing
 373                 WarpZone_TraceBox_ThroughZone(start, '0 0 0', '0 0 0', end, false, WarpZone_trace_forent, NULL, fireBullet_trace_callback);
 374                 dir = WarpZone_TransformVelocity(WarpZone_trace_transform, dir);
 375                 end = WarpZone_TransformOrigin(WarpZone_trace_transform, end);
 376                 start = trace_endpos;
 377                 entity hit = trace_ent;
 378
 379                 // traced up to max_shot_distance and didn't hit anything at all
 380                 if (trace_fraction == 1.0)
 381                         break;
 382
 383                 // When hitting sky, stop.
 384                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
 385                         break;
 386
 387                 // can't use noimpact, as we need to pass through walls
 388                 //if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 389                         //break;
 390
 391                 // if we hit "weapclip", bail out
 392                 //
 393                 // rationale of this check:
 394                 //
 395                 // any shader that is solid, nodraw AND trans is meant to clip weapon
 396                 // shots and players, but has no other effect!
 397                 //
 398                 // if it is not trans, it is caulk and should not have this side effect
 399                 //
 400                 // matching shaders:
 401                 //   common/weapclip (intended)
 402                 //   common/noimpact (is supposed to eat projectiles, but is erased anyway)
 403                 bool is_weapclip = false;
 404                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODRAW)
 405                 if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NONSOLID))
 406                 if (!(trace_dphitcontents & DPCONTENTS_OPAQUE))
 407                         is_weapclip = true;
 408
 409                 if(!hit || hit.solid == SOLID_BSP || hit.solid == SOLID_SLIDEBOX)
 410                         Damage_DamageInfo(start, damage * solid_penetration_left, 0, 0, max(1, force) * dir * solid_penetration_left, dtype, hit.species, this);
 411
 412                 if (hit && hit != WarpZone_trace_forent && hit != fireBullet_last_hit)  // Avoid self-damage (except after going through a warp); avoid hitting the same entity twice (engine bug).
 413                 {
 414                         fireBullet_last_hit = hit;
 415                         yoda = 0;
 416                         MUTATOR_CALLHOOK(FireBullet_Hit, this, hit, start, end, damage, this.(weaponentity));
 417                         damage = M_ARGV(4, float);
 418                         bool gooddamage = accuracy_isgooddamage(this, hit);
 419                         Damage(hit, this, this, damage * solid_penetration_left, dtype, weaponentity, start, force * dir * solid_penetration_left);
 420                         // calculate hits for ballistic weapons
 421                         if(gooddamage)
 422                         {
 423                                 // do not exceed 100%
 424                                 float added_damage = min(damage - total_damage, damage * solid_penetration_left);
 425                                 total_damage += damage * solid_penetration_left;
 426                                 accuracy_add(this, this.(weaponentity).m_weapon, 0, added_damage);
 427                         }
 428                 }
 429
 430                 if (is_weapclip && !autocvar_g_ballistics_penetrate_clips)
 431                         break;
 432
 433                 // go through solid!
 434                 // outside the world? forget it
 435                 if(start.x > world.maxs.x || start.y > world.maxs.y || start.z > world.maxs.z || start.x < world.mins.x || start.y < world.mins.y || start.z < world.mins.z)
 436                         break;
 437
 438                 float maxdist;
 439                 entity hitstore = IS_PLAYER(hit) ? PS(hit) : hit;
 440                 if(max_solid_penetration < 0)
 441                         break;
 442                 else if(hitstore.ballistics_density < -1)
 443                         break; // -2: no solid penetration, ever
 444                 else if(hitstore.ballistics_density < 0)
 445                         maxdist = vlen(hit.maxs - hit.mins) + 1; // -1: infinite travel distance
 446                 else if(hitstore.ballistics_density == 0)
 447                         maxdist = max_solid_penetration * solid_penetration_left;
 448                 else
 449                         maxdist = max_solid_penetration * solid_penetration_left * hitstore.ballistics_density;
 450
 451                 if(maxdist <= autocvar_g_ballistics_mindistance)
 452                         break;
 453
 454                 // move the entity along its velocity until it's out of solid, then let it resume
 455                 // The previously hit entity is ignored here!
 456                 traceline_inverted (start, start + dir * maxdist, MOVE_NORMAL, WarpZone_trace_forent, true, hit);
 457                 if(trace_fraction == 1) // 1: we never got out of solid
 458                         break;
 459
 460                 float dist_taken = max(autocvar_g_ballistics_mindistance, vlen(trace_endpos - start));
 461                 // fraction_used_of_what_is_left = dist_taken / maxdist
 462                 // solid_penetration_left = solid_penetration_left - solid_penetration_left * fraction_used_of_what_is_left
 463                 solid_penetration_left *= 1 - dist_taken / maxdist;
 464                 solid_penetration_left = max(solid_penetration_left, 0);
 465
 466                 // Only show effect when going through a player (invisible otherwise)
 467                 if (hit && (hit.solid != SOLID_BSP))
 468                         if(vdist(trace_endpos - start, >, 4))
 469                                 trailparticles(this, fireBullet_trace_callback_eff, start, trace_endpos);
 470
 471                 start = trace_endpos;
 472
 473                 if(hit.solid == SOLID_BSP)
 474                         Damage_DamageInfo(start, 0, 0, 0, max(1, force) * normalize(dir) * -solid_penetration_left, dtype, 0, this);
 475         }
 476
 477         if(lag)
 478                 antilag_restore_all(this);
 479
 480         // restore shooter solid type
 481         if(this)
 482                 this.dphitcontentsmask = oldsolid;
 483 }