qcsrc/warpzonelib/server.qc

   1 // for think function
   2 .vector warpzone_save_origin;
   3 .vector warpzone_save_angles;
   4 .vector warpzone_save_eorigin;
   5 .vector warpzone_save_eangles;
   6
   7 // for all entities
   8 .vector warpzone_oldorigin, warpzone_oldvelocity, warpzone_oldangles;
   9 .float warpzone_teleport_time;
  10 .entity warpzone_teleport_zone;
  11
  12 void WarpZone_StoreProjectileData(entity e)
  13 {
  14         e.warpzone_oldorigin = e.origin;
  15         e.warpzone_oldvelocity = e.velocity;
  16         e.warpzone_oldangles = e.angles;
  17 }
  18
  19 void WarpZone_TeleportPlayer(entity teleporter, entity player, vector to, vector to_angles, vector to_velocity)
  20 {
  21         setorigin (player, to);
  22         player.oldorigin = to; // for DP's unsticking
  23         player.angles = to_angles;
  24         player.fixangle = TRUE;
  25         player.velocity = to_velocity;
  26
  27         BITXOR_ASSIGN(player.effects, EF_TELEPORT_BIT);
  28
  29         if(player.classname == "player")
  30                 BITCLR_ASSIGN(player.flags, FL_ONGROUND);
  31
  32         WarpZone_PostTeleportPlayer_Callback(player);
  33 }
  34
  35 float WarpZone_Teleported_Send(entity to, float sf)
  36 {
  37         WriteByte(MSG_ENTITY, ENT_CLIENT_WARPZONE_TELEPORTED);
  38         WriteCoord(MSG_ENTITY, self.angles_x);
  39         WriteCoord(MSG_ENTITY, self.angles_y);
  40         WriteCoord(MSG_ENTITY, self.angles_z);
  41         return TRUE;
  42 }
  43
  44 #define WARPZONE_TELEPORT_FIXSOLID(ret) \
  45         do \
  46         { \
  47                 setorigin(player, o1 - player.view_ofs); \
  48                 if(WarpZoneLib_MoveOutOfSolid(player)) \
  49                 { \
  50                         o1 = player.origin + player.view_ofs; \
  51                         setorigin(player, o0 - player.view_ofs); \
  52                 } \
  53                 else \
  54                 { \
  55                         print("would have to put player in solid, won't do that\n"); \
  56                         setorigin(player, o0 - player.view_ofs); \
  57                         return (ret); \
  58                 } \
  59         } \
  60         while(0)
  61 #define WARPZONE_TELEPORT_DOTELEPORT() \
  62         do \
  63         { \
  64                 WarpZone_RefSys_Add(player, wz); \
  65                 WarpZone_TeleportPlayer(wz, player, o1 - player.view_ofs, a1, v1); \
  66                 WarpZone_StoreProjectileData(player); \
  67                 player.warpzone_teleport_time = time; \
  68                 player.warpzone_teleport_zone = wz; \
  69         } \
  70         while(0)
  71
  72 float WarpZone_Teleport(entity wz, entity player, float f0, float f1)
  73 {
  74         vector o0, a0, v0, o1, a1, v1;
  75
  76         o0 = player.origin + player.view_ofs;
  77         v0 = player.velocity;
  78         a0 = player.angles;
  79
  80         o1 = WarpZone_TransformOrigin(wz, o0);
  81         v1 = WarpZone_TransformVelocity(wz, v0);
  82         if(clienttype(player) != CLIENTTYPE_NOTACLIENT)
  83                 a1 = WarpZone_TransformVAngles(wz, player.v_angle);
  84         else
  85                 a1 = WarpZone_TransformAngles(wz, a0);
  86
  87         if(f0 != 0 || f1 != 0)
  88         {
  89                 // retry last move but behind the warpzone!
  90                 // we must first go back as far as we can, then forward again, to not cause double touch events!
  91
  92                 tracebox(o1 - player.view_ofs + v1 * frametime * f1, player.mins, player.maxs, o1 - player.view_ofs + v1 * frametime * f0, MOVE_WORLDONLY, player);
  93                 {
  94                         entity own;
  95                         own = player.owner;
  96                         player.owner = world;
  97                         tracebox(trace_endpos, player.mins, player.maxs, o1 - player.view_ofs + v1 * frametime * f1, MOVE_NORMAL, player); // this should get us through the warpzone
  98                         player.owner = own;
  99                 }
 100                 o1 = trace_endpos + player.view_ofs;
 101
 102                 float d, dv;
 103                 d = WarpZone_TargetPlaneDist(wz, o1);
 104                 dv = WarpZone_TargetPlaneDist(wz, v1);
 105                 if(d < 0)
 106                         o1 = o1 - v1 * (d / dv);
 107         }
 108
 109         // put him inside solid
 110         tracebox(o1 - player.view_ofs, player.mins, player.maxs, o1 - player.view_ofs, MOVE_NOMONSTERS, player);
 111         if(trace_startsolid)
 112                 WARPZONE_TELEPORT_FIXSOLID(0);
 113
 114         WARPZONE_TELEPORT_DOTELEPORT();
 115
 116 #ifndef WARPZONE_USE_FIXANGLE
 117         if(player.classname == "player")
 118         {
 119                 // instead of fixangle, send the transform to the client for smoother operation
 120                 player.fixangle = FALSE;
 121
 122                 entity ts = spawn();
 123                 setmodel(ts, "null");
 124                 ts.SendEntity = WarpZone_Teleported_Send;
 125                 ts.SendFlags = 0xFFFFFF;
 126                 ts.drawonlytoclient = player;
 127                 ts.think = SUB_Remove;
 128                 ts.nextthink = time + 1;
 129                 ts.owner = player;
 130                 ts.enemy = wz;
 131                 ts.effects = EF_NODEPTHTEST;
 132                 ts.classname = "warpzone_teleported";
 133                 ts.angles = wz.warpzone_transform;
 134         }
 135 #endif
 136
 137         return 1;
 138 }
 139
 140 void WarpZone_Touch (void)
 141 {
 142         entity oldself;
 143
 144         if(other.classname == "trigger_warpzone")
 145                 return;
 146
 147         if(other.warpzone_teleport_time == time) // already teleported this frame
 148                 return;
 149
 150         // FIXME needs a better check to know what is safe to teleport and what not
 151         if(other.movetype == MOVETYPE_NONE || other.movetype == MOVETYPE_FOLLOW)
 152                 return;
 153
 154         if(WarpZoneLib_ExactTrigger_Touch())
 155                 return;
 156
 157         if(WarpZone_PlaneDist(self, other.origin + other.view_ofs) >= 0) // wrong side of the trigger_warpzone (don't teleport yet)
 158                 return;
 159
 160         if(WarpZone_Teleport(self, other, -1, 0))
 161         {
 162                 string save1, save2;
 163                 activator = other;
 164
 165                 save1 = self.target; self.target = string_null;
 166                 save2 = self.target3; self.target3 = string_null;
 167                 SUB_UseTargets();
 168                 if not(self.target) self.target = save1;
 169                 if not(self.target3) self.target3 = save2;
 170
 171                 oldself = self;
 172                 self = self.enemy;
 173                 save1 = self.target; self.target = string_null;
 174                 save2 = self.target2; self.target2 = string_null;
 175                 SUB_UseTargets();
 176                 if not(self.target) self.target = save1;
 177                 if not(self.target2) self.target2 = save2;
 178                 self = oldself;
 179         }
 180         else
 181         {
 182                 dprint("WARPZONE FAIL AHAHAHAHAH))\n");
 183         }
 184 }
 185
 186 float WarpZone_Send(entity to, float sendflags)
 187 {
 188         float f;
 189         WriteByte(MSG_ENTITY, ENT_CLIENT_WARPZONE);
 190
 191         // we must send this flag for clientside to match properly too
 192         f = 0;
 193         if(self.warpzone_isboxy)
 194                 BITSET_ASSIGN(f, 1);
 195         if(self.warpzone_fadestart)
 196                 BITSET_ASSIGN(f, 2);
 197         if(self.origin != '0 0 0')
 198                 BITSET_ASSIGN(f, 4);
 199         WriteByte(MSG_ENTITY, f);
 200
 201         // we need THESE to render the warpzone (and cull properly)...
 202         if(f & 4)
 203         {
 204                 WriteCoord(MSG_ENTITY, self.origin_x);
 205                 WriteCoord(MSG_ENTITY, self.origin_y);
 206                 WriteCoord(MSG_ENTITY, self.origin_z);
 207         }
 208
 209         WriteShort(MSG_ENTITY, self.modelindex);
 210         WriteCoord(MSG_ENTITY, self.mins_x);
 211         WriteCoord(MSG_ENTITY, self.mins_y);
 212         WriteCoord(MSG_ENTITY, self.mins_z);
 213         WriteCoord(MSG_ENTITY, self.maxs_x);
 214         WriteCoord(MSG_ENTITY, self.maxs_y);
 215         WriteCoord(MSG_ENTITY, self.maxs_z);
 216         WriteByte(MSG_ENTITY, bound(1, self.scale * 16, 255));
 217
 218         // we need THESE to calculate the proper transform
 219         WriteCoord(MSG_ENTITY, self.warpzone_origin_x);
 220         WriteCoord(MSG_ENTITY, self.warpzone_origin_y);
 221         WriteCoord(MSG_ENTITY, self.warpzone_origin_z);
 222         WriteCoord(MSG_ENTITY, self.warpzone_angles_x);
 223         WriteCoord(MSG_ENTITY, self.warpzone_angles_y);
 224         WriteCoord(MSG_ENTITY, self.warpzone_angles_z);
 225         WriteCoord(MSG_ENTITY, self.warpzone_targetorigin_x);
 226         WriteCoord(MSG_ENTITY, self.warpzone_targetorigin_y);
 227         WriteCoord(MSG_ENTITY, self.warpzone_targetorigin_z);
 228         WriteCoord(MSG_ENTITY, self.warpzone_targetangles_x);
 229         WriteCoord(MSG_ENTITY, self.warpzone_targetangles_y);
 230         WriteCoord(MSG_ENTITY, self.warpzone_targetangles_z);
 231
 232         if(f & 2)
 233         {
 234                 WriteShort(MSG_ENTITY, self.warpzone_fadestart);
 235                 WriteShort(MSG_ENTITY, self.warpzone_fadeend);
 236         }
 237
 238         return TRUE;
 239 }
 240
 241 float WarpZone_Camera_Send(entity to, float sendflags)
 242 {
 243         float f;
 244         WriteByte(MSG_ENTITY, ENT_CLIENT_WARPZONE_CAMERA);
 245
 246         if(self.warpzone_fadestart)
 247                 BITSET_ASSIGN(f, 2);
 248         if(self.origin != '0 0 0')
 249                 BITSET_ASSIGN(f, 4);
 250         WriteByte(MSG_ENTITY, f);
 251
 252         // we need THESE to render the warpzone (and cull properly)...
 253         if(f & 4)
 254         {
 255                 WriteCoord(MSG_ENTITY, self.origin_x);
 256                 WriteCoord(MSG_ENTITY, self.origin_y);
 257                 WriteCoord(MSG_ENTITY, self.origin_z);
 258         }
 259
 260         WriteShort(MSG_ENTITY, self.modelindex);
 261         WriteCoord(MSG_ENTITY, self.mins_x);
 262         WriteCoord(MSG_ENTITY, self.mins_y);
 263         WriteCoord(MSG_ENTITY, self.mins_z);
 264         WriteCoord(MSG_ENTITY, self.maxs_x);
 265         WriteCoord(MSG_ENTITY, self.maxs_y);
 266         WriteCoord(MSG_ENTITY, self.maxs_z);
 267         WriteByte(MSG_ENTITY, bound(1, self.scale * 16, 255));
 268
 269         // we need THESE to calculate the proper transform
 270         WriteCoord(MSG_ENTITY, self.enemy.origin_x);
 271         WriteCoord(MSG_ENTITY, self.enemy.origin_y);
 272         WriteCoord(MSG_ENTITY, self.enemy.origin_z);
 273         WriteCoord(MSG_ENTITY, self.enemy.angles_x);
 274         WriteCoord(MSG_ENTITY, self.enemy.angles_y);
 275         WriteCoord(MSG_ENTITY, self.enemy.angles_z);
 276
 277         if(f & 2)
 278         {
 279                 WriteShort(MSG_ENTITY, self.warpzone_fadestart);
 280                 WriteShort(MSG_ENTITY, self.warpzone_fadeend);
 281         }
 282
 283         return TRUE;
 284 }
 285
 286 float WarpZone_CheckProjectileImpact(entity player)
 287 {
 288         vector o0, a0, v0;
 289
 290         o0 = player.origin + player.view_ofs;
 291         v0 = player.velocity;
 292         a0 = player.angles;
 293
 294         // if player hit a warpzone, abort
 295         entity wz;
 296         wz = WarpZone_Find(o0 + player.mins, o0 + player.maxs);
 297         if(!wz)
 298                 return 0;
 299
 300         print("impactfilter found something - and it even gets handled correctly - please tell divVerent that this code apparently gets triggered again\n");
 301
 302         // retry previous move
 303         setorigin(player, player.warpzone_oldorigin);
 304         player.velocity = player.warpzone_oldvelocity;
 305         if(WarpZone_Teleport(wz, player, 0, 1))
 306         {
 307                 entity oldself;
 308                 string save1, save2;
 309
 310                 oldself = self;
 311                 self = wz;
 312                 other = player;
 313                 activator = player;
 314
 315                 save1 = self.target; self.target = string_null;
 316                 save2 = self.target3; self.target3 = string_null;
 317                 SUB_UseTargets();
 318                 if not(self.target) self.target = save1;
 319                 if not(self.target3) self.target3 = save2;
 320
 321                 self = self.enemy;
 322                 save1 = self.target; self.target = string_null;
 323                 save2 = self.target2; self.target2 = string_null;
 324                 SUB_UseTargets();
 325                 if not(self.target) self.target = save1;
 326                 if not(self.target2) self.target2 = save2;
 327                 self = oldself;
 328         }
 329         else
 330         {
 331                 setorigin(player, o0);
 332                 player.velocity = v0;
 333         }
 334
 335         return +1;
 336 }
 337 float WarpZone_Projectile_Touch()
 338 {
 339         float f;
 340         if(other.classname == "trigger_warpzone")
 341                 return TRUE;
 342
 343         // no further impacts if we teleported this frame!
 344         if(self.warpzone_teleport_time == time)
 345                 return TRUE;
 346
 347         // this SEEMS to not happen at the moment, but if it did, it would be more reliable
 348         {
 349                 float save_dpstartcontents;
 350                 float save_dphitcontents;
 351                 float save_dphitq3surfaceflags;
 352                 string save_dphittexturename;
 353                 float save_allsolid;
 354                 float save_startsolid;
 355                 float save_fraction;
 356                 vector save_endpos;
 357                 vector save_plane_normal;
 358                 float save_plane_dist;
 359                 entity save_ent;
 360                 float save_inopen;
 361                 float save_inwater;
 362                 save_dpstartcontents = trace_dpstartcontents;
 363                 save_dphitcontents = trace_dphitcontents;
 364                 save_dphitq3surfaceflags = trace_dphitq3surfaceflags;
 365                 save_dphittexturename = trace_dphittexturename;
 366                 save_allsolid = trace_allsolid;
 367                 save_startsolid = trace_startsolid;
 368                 save_fraction = trace_fraction;
 369                 save_endpos = trace_endpos;
 370                 save_plane_normal = trace_plane_normal;
 371                 save_plane_dist = trace_plane_dist;
 372                 save_ent = trace_ent;
 373                 save_inopen = trace_inopen;
 374                 save_inwater = trace_inwater;
 375                 if((f = WarpZone_CheckProjectileImpact(self)) != 0)
 376                         return (f > 0);
 377                 trace_dpstartcontents = save_dpstartcontents;
 378                 trace_dphitcontents = save_dphitcontents;
 379                 trace_dphitq3surfaceflags = save_dphitq3surfaceflags;
 380                 trace_dphittexturename = save_dphittexturename;
 381                 trace_allsolid = save_allsolid;
 382                 trace_startsolid = save_startsolid;
 383                 trace_fraction = save_fraction;
 384                 trace_endpos = save_endpos;
 385                 trace_plane_normal = save_plane_normal;
 386                 trace_plane_dist = save_plane_dist;
 387                 trace_ent = save_ent;
 388                 trace_inopen = save_inopen;
 389                 trace_inwater = save_inwater;
 390         }
 391
 392         if(WarpZone_Projectile_Touch_ImpactFilter_Callback())
 393                 return TRUE;
 394
 395         if(self.warpzone_teleport_time == time)
 396         {
 397                 // sequence: hit warpzone, get teleported, hit wall
 398                 // print("2 hits 1 frame\n");
 399                 setorigin(self, self.warpzone_oldorigin);
 400                 self.velocity = self.warpzone_oldvelocity;
 401                 self.angles = self.warpzone_oldangles;
 402                 return TRUE;
 403         }
 404         return FALSE;
 405 }
 406
 407 void WarpZone_InitStep_FindOriginTarget()
 408 {
 409         if(self.killtarget != "")
 410         {
 411                 self.aiment = find(world, targetname, self.killtarget);
 412                 if(self.aiment == world)
 413                 {
 414                         error("Warp zone with nonexisting killtarget");
 415                         return;
 416                 }
 417                 self.killtarget = string_null;
 418         }
 419 }
 420
 421 void WarpZonePosition_InitStep_FindTarget()
 422 {
 423         if(self.target == "")
 424         {
 425                 error("Warp zone position with no target");
 426                 return;
 427         }
 428         self.enemy = find(world, targetname, self.target);
 429         if(self.enemy == world)
 430         {
 431                 error("Warp zone position with nonexisting target");
 432                 return;
 433         }
 434         if(self.enemy.aiment)
 435         {
 436                 // already is positioned
 437                 error("Warp zone position targeting already oriented warpzone");
 438                 return;
 439         }
 440         self.enemy.aiment = self;
 441 }
 442
 443 void WarpZoneCamera_Think(void)
 444 {
 445         if(self.warpzone_save_origin != self.origin
 446         || self.warpzone_save_angles != self.angles
 447         || self.warpzone_save_eorigin != self.enemy.origin
 448         || self.warpzone_save_eangles != self.enemy.angles)
 449         {
 450                 WarpZone_Camera_SetUp(self, self.enemy.origin, self.enemy.angles);
 451                 self.warpzone_save_origin = self.origin;
 452                 self.warpzone_save_angles = self.angles;
 453                 self.warpzone_save_eorigin = self.enemy.origin;
 454                 self.warpzone_save_eangles = self.enemy.angles;
 455         }
 456         self.nextthink = time;
 457 }
 458
 459 void WarpZoneCamera_InitStep_FindTarget()
 460 {
 461         entity e;
 462         float i;
 463         if(self.target == "")
 464         {
 465                 error("Camera with no target");
 466                 return;
 467         }
 468         self.enemy = world;
 469         for(e = world, i = 0; (e = find(e, targetname, self.target)); )
 470                 if(random() * ++i < 1)
 471                         self.enemy = e;
 472         if(self.enemy == world)
 473         {
 474                 error("Camera with nonexisting target");
 475                 return;
 476         }
 477         warpzone_cameras_exist = 1;
 478         WarpZone_Camera_SetUp(self, self.enemy.origin, self.enemy.angles);
 479         self.SendFlags = 0xFFFFFF;
 480         if(self.spawnflags & 1)
 481         {
 482                 self.think = WarpZoneCamera_Think;
 483                 self.nextthink = time;
 484         }
 485         else
 486                 self.nextthink = 0;
 487 }
 488
 489 void WarpZone_InitStep_UpdateTransform()
 490 {
 491         vector org, ang, norm, point;
 492         float area;
 493         vector tri, a, b, c, p, q, n;
 494         float i_s, i_t, n_t;
 495         string tex;
 496
 497         org = self.origin;
 498         if(org == '0 0 0')
 499                 org = 0.5 * (self.mins + self.maxs);
 500
 501         norm = point = '0 0 0';
 502         area = 0;
 503         for(i_s = 0; ; ++i_s)
 504         {
 505                 tex = getsurfacetexture(self, i_s);
 506                 if not(tex)
 507                         break; // this is beyond the last one
 508                 if(tex == "textures/common/trigger" || tex == "trigger")
 509                         continue;
 510                 n_t = getsurfacenumtriangles(self, i_s);
 511                 for(i_t = 0; i_t < n_t; ++i_t)
 512                 {
 513                         tri = getsurfacetriangle(self, i_s, i_t);
 514                         a = getsurfacepoint(self, i_s, tri_x);
 515                         b = getsurfacepoint(self, i_s, tri_y);
 516                         c = getsurfacepoint(self, i_s, tri_z);
 517                         p = b - a;
 518                         q = c - a;
 519                         n =     '1 0 0' * (q_y * p_z - q_z * p_y)
 520                         +       '0 1 0' * (q_z * p_x - q_x * p_z)
 521                         +       '0 0 1' * (q_x * p_y - q_y * p_x);
 522                         area = area + vlen(n);
 523                         norm = norm + n;
 524                         point = point + vlen(n) * (a + b + c);
 525                 }
 526         }
 527         if(area > 0)
 528         {
 529                 norm = norm * (1 / area);
 530                 point = point * (1 / (3 * area));
 531                 if(vlen(norm) < 0.99)
 532                 {
 533                         print("trigger_warpzone near ", vtos(self.aiment.origin), " is nonplanar. BEWARE.\n");
 534                         area = 0; // no autofixing in this case
 535                 }
 536                 norm = normalize(norm);
 537         }
 538
 539         if(self.aiment)
 540         {
 541                 org = self.aiment.origin;
 542                 ang = self.aiment.angles;
 543                 if(area > 0)
 544                 {
 545                         org = org - ((org - point) * norm) * norm; // project to plane
 546                         makevectors(ang);
 547                         if(norm * v_forward < 0)
 548                         {
 549                                 print("Position target of trigger_warpzone near ", vtos(self.aiment.origin), " points into trigger_warpzone. BEWARE.\n");
 550                                 norm = -1 * norm;
 551                         }
 552                         ang = vectoangles(norm, v_up); // keep rotation, but turn exactly against plane
 553                         ang_x = -ang_x;
 554                         if(norm * v_forward < 0.99)
 555                                 print("trigger_warpzone near ", vtos(self.aiment.origin), " has been turned to match plane orientation (", vtos(self.aiment.angles), " -> ", vtos(ang), "\n");
 556                         if(vlen(org - self.aiment.origin) > 0.5)
 557                                 print("trigger_warpzone near ", vtos(self.aiment.origin), " has been moved to match the plane (", vtos(self.aiment.origin), " -> ", vtos(org), ").\n");
 558                 }
 559         }
 560         else if(area > 0)
 561         {
 562                 org = point;
 563                 ang = vectoangles(norm);
 564                 ang_x = -ang_x;
 565         }
 566         else
 567                 error("cannot infer origin/angles for this warpzone, please use a killtarget or a trigger_warpzone_position");
 568
 569         self.warpzone_origin = org;
 570         self.warpzone_angles = ang;
 571 }
 572
 573 void WarpZone_InitStep_ClearTarget()
 574 {
 575         if(self.enemy)
 576                 self.enemy.enemy = world;
 577         self.enemy = world;
 578 }
 579
 580 entity warpzone_first; .entity warpzone_next;
 581 void WarpZone_InitStep_FindTarget()
 582 {
 583         float i;
 584         entity e, e2;
 585
 586         if(self.enemy)
 587                 return;
 588
 589         // this way only one of the two ents needs to target
 590         if(self.target != "")
 591         {
 592                 self.enemy = self; // so the if(!e.enemy) check also skips self, saves one IF
 593
 594                 e2 = world;
 595                 for(e = world, i = 0; (e = find(e, targetname, self.target)); )
 596                         if(!e.enemy)
 597                                 if(e.classname == self.classname) // possibly non-warpzones may use the same targetname!
 598                                         if(random() * ++i < 1)
 599                                                 e2 = e;
 600                 if(!e2)
 601                 {
 602                         self.enemy = world;
 603                         error("Warpzone with non-existing target");
 604                         return;
 605                 }
 606                 self.enemy = e2;
 607                 e2.enemy = self;
 608         }
 609 }
 610
 611 void WarpZone_Think();
 612 void WarpZone_InitStep_FinalizeTransform()
 613 {
 614         if(!self.enemy || self.enemy.enemy != self)
 615         {
 616                 error("Invalid warp zone detected. Killed.");
 617                 return;
 618         }
 619
 620         warpzone_warpzones_exist = 1;
 621         WarpZone_SetUp(self, self.warpzone_origin, self.warpzone_angles, self.enemy.warpzone_origin, self.enemy.warpzone_angles);
 622         self.touch = WarpZone_Touch;
 623         self.SendFlags = 0xFFFFFF;
 624         if(self.spawnflags & 1)
 625         {
 626                 self.think = WarpZone_Think;
 627                 self.nextthink = time;
 628         }
 629         else
 630                 self.nextthink = 0;
 631 }
 632
 633 float warpzone_initialized;
 634 entity warpzone_first;
 635 entity warpzone_position_first;
 636 entity warpzone_camera_first;
 637 .entity warpzone_next;
 638 void spawnfunc_misc_warpzone_position(void)
 639 {
 640         // "target", "angles", "origin"
 641         self.warpzone_next = warpzone_position_first;
 642         warpzone_position_first = self;
 643 }
 644 void spawnfunc_trigger_warpzone_position(void)
 645 {
 646         spawnfunc_misc_warpzone_position();
 647 }
 648 void spawnfunc_trigger_warpzone(void)
 649 {
 650         // warp zone entities must have:
 651         // "killtarget" pointing to a target_position with a direction arrow
 652         //              that points AWAY from the warp zone, and that is inside
 653         //              the warp zone trigger
 654         // "target"     pointing to an identical warp zone at another place in
 655         //              the map, with another killtarget to designate its
 656         //              orientation
 657
 658 #ifndef WARPZONE_USE_FIXANGLE
 659         // used when teleporting
 660         precache_model("null");
 661 #endif
 662
 663         if(!self.scale)
 664                 self.scale = self.modelscale;
 665         if(!self.scale)
 666                 self.scale = 1;
 667         string m;
 668         m = self.model;
 669         WarpZoneLib_ExactTrigger_Init();
 670         if(m != "")
 671         {
 672                 precache_model(m);
 673                 setmodel(self, m); // no precision needed
 674         }
 675         setorigin(self, self.origin);
 676         if(self.scale)
 677                 setsize(self, self.mins * self.scale, self.maxs * self.scale);
 678         else
 679                 setsize(self, self.mins, self.maxs);
 680         self.SendEntity = WarpZone_Send;
 681         self.SendFlags = 0xFFFFFF;
 682         BITSET_ASSIGN(self.effects, EF_NODEPTHTEST);
 683         self.warpzone_next = warpzone_first;
 684         warpzone_first = self;
 685 }
 686 void spawnfunc_func_camera(void)
 687 {
 688         if(!self.scale)
 689                 self.scale = self.modelscale;
 690         if(!self.scale)
 691                 self.scale = 1;
 692         if(self.model != "")
 693         {
 694                 precache_model(self.model);
 695                 setmodel(self, self.model); // no precision needed
 696         }
 697         setorigin(self, self.origin);
 698         if(self.scale)
 699                 setsize(self, self.mins * self.scale, self.maxs * self.scale);
 700         else
 701                 setsize(self, self.mins, self.maxs);
 702         if(!self.solid)
 703                 self.solid = SOLID_BSP;
 704         else if(self.solid < 0)
 705                 self.solid = SOLID_NOT;
 706         self.SendEntity = WarpZone_Camera_Send;
 707         self.SendFlags = 0xFFFFFF;
 708         self.warpzone_next = warpzone_camera_first;
 709         warpzone_camera_first = self;
 710 }
 711 void WarpZones_Reconnect()
 712 {
 713         entity e;
 714         e = self;
 715         for(self = warpzone_first; self; self = self.warpzone_next)
 716                 WarpZone_InitStep_ClearTarget();
 717         for(self = warpzone_first; self; self = self.warpzone_next)
 718                 WarpZone_InitStep_FindTarget();
 719         for(self = warpzone_camera_first; self; self = self.warpzone_next)
 720                 WarpZoneCamera_InitStep_FindTarget();
 721         for(self = warpzone_first; self; self = self.warpzone_next)
 722                 WarpZone_InitStep_FinalizeTransform();
 723         self = e;
 724 }
 725
 726 void WarpZone_Think()
 727 {
 728         if(self.warpzone_save_origin != self.origin
 729         || self.warpzone_save_angles != self.angles
 730         || self.warpzone_save_eorigin != self.enemy.origin
 731         || self.warpzone_save_eangles != self.enemy.angles)
 732         {
 733                 entity oldself;
 734                 oldself = self;
 735                 WarpZone_InitStep_UpdateTransform();
 736                 self = self.enemy;
 737                 WarpZone_InitStep_UpdateTransform();
 738                 self = oldself;
 739                 WarpZone_InitStep_FinalizeTransform();
 740                 self = self.enemy;
 741                 WarpZone_InitStep_FinalizeTransform();
 742                 self = oldself;
 743                 self.warpzone_save_origin = self.origin;
 744                 self.warpzone_save_angles = self.angles;
 745                 self.warpzone_save_eorigin = self.enemy.origin;
 746                 self.warpzone_save_eangles = self.enemy.angles;
 747         }
 748         self.nextthink = time;
 749 }
 750
 751 void WarpZone_StartFrame()
 752 {
 753         entity e;
 754         if(warpzone_initialized == 0)
 755         {
 756                 warpzone_initialized = 1;
 757                 e = self;
 758                 for(self = warpzone_first; self; self = self.warpzone_next)
 759                         WarpZone_InitStep_FindOriginTarget();
 760                 for(self = warpzone_position_first; self; self = self.warpzone_next)
 761                         WarpZonePosition_InitStep_FindTarget();
 762                 for(self = warpzone_first; self; self = self.warpzone_next)
 763                         WarpZone_InitStep_UpdateTransform();
 764                 self = e;
 765                 WarpZones_Reconnect();
 766         }
 767
 768         if(warpzone_warpzones_exist)
 769         {
 770                 entity oldself, oldother;
 771                 oldself = self;
 772                 oldother = other;
 773                 for(e = world; (e = nextent(e)); )
 774                 {
 775                         WarpZone_StoreProjectileData(e);
 776                         float f;
 777                         f = clienttype(e);
 778                         if(f == CLIENTTYPE_REAL)
 779                         {
 780                                 if(e.solid != SOLID_NOT) // not spectating?
 781                                         continue;
 782                                 if(e.movetype != MOVETYPE_NOCLIP && e.movetype != MOVETYPE_FLY) // not spectating? (this is to catch observers)
 783                                         continue;
 784                                 self = WarpZone_Find(e.origin + e.mins, e.origin + e.maxs);
 785                                 if(!self)
 786                                         continue;
 787                                 other = e;
 788                                 if(WarpZoneLib_ExactTrigger_Touch())
 789                                         continue;
 790                                 if(WarpZone_PlaneDist(self, e.origin + e.view_ofs) <= 0)
 791                                         WarpZone_Teleport(self, e, -1, 0); // NOT triggering targets by this!
 792                         }
 793                         if(f == CLIENTTYPE_NOTACLIENT)
 794                         {
 795                                 for(; (e = nextent(e)); )
 796                                         WarpZone_StoreProjectileData(e);
 797                                 break;
 798                         }
 799                 }
 800                 self = oldself;
 801                 other = oldother;
 802         }
 803 }
 804
 805 .float warpzone_reconnecting;
 806 float visible_to_some_client(entity ent)
 807 {
 808         entity e;
 809         for(e = nextent(world); clienttype(e) != CLIENTTYPE_NOTACLIENT; e = nextent(e))
 810                 if(e.classname == "player" && clienttype(e) == CLIENTTYPE_REAL)
 811                         if(checkpvs(e.origin + e.view_ofs, ent))
 812                                 return 1;
 813         return 0;
 814 }
 815 void trigger_warpzone_reconnect_use()
 816 {
 817         entity e;
 818         e = self;
 819         // NOTE: this matches for target, not targetname, but of course
 820         // targetname must be set too on the other entities
 821         for(self = warpzone_first; self; self = self.warpzone_next)
 822                 self.warpzone_reconnecting = ((e.target == "" || self.target == e.target) && !((e.spawnflags & 1) && (visible_to_some_client(self) || visible_to_some_client(self.enemy))));
 823         for(self = warpzone_camera_first; self; self = self.warpzone_next)
 824                 self.warpzone_reconnecting = ((e.target == "" || self.target == e.target) && !((e.spawnflags & 1) && visible_to_some_client(self)));
 825         for(self = warpzone_first; self; self = self.warpzone_next)
 826                 if(self.warpzone_reconnecting)
 827                         WarpZone_InitStep_ClearTarget();
 828         for(self = warpzone_first; self; self = self.warpzone_next)
 829                 if(self.warpzone_reconnecting)
 830                         WarpZone_InitStep_FindTarget();
 831         for(self = warpzone_camera_first; self; self = self.warpzone_next)
 832                 if(self.warpzone_reconnecting)
 833                         WarpZoneCamera_InitStep_FindTarget();
 834         for(self = warpzone_first; self; self = self.warpzone_next)
 835                 if(self.warpzone_reconnecting || self.enemy.warpzone_reconnecting)
 836                         WarpZone_InitStep_FinalizeTransform();
 837         self = e;
 838 }
 839
 840 void spawnfunc_trigger_warpzone_reconnect()
 841 {
 842         self.use = trigger_warpzone_reconnect_use;
 843 }
 844
 845 void spawnfunc_target_warpzone_reconnect()
 846 {
 847         spawnfunc_trigger_warpzone_reconnect(); // both names make sense here :(
 848 }
 849
 850 void WarpZone_PlayerPhysics_FixVAngle(void)
 851 {
 852 #ifndef WARPZONE_DONT_FIX_VANGLE
 853         if(clienttype(self) == CLIENTTYPE_REAL)
 854         if(self.v_angle_z <= 360) // if not already adjusted
 855         if(time - self.ping * 0.001 < self.warpzone_teleport_time)
 856         {
 857                 self.v_angle = WarpZone_TransformVAngles(self.warpzone_teleport_zone, self.v_angle);
 858                 self.v_angle_z += 720; // mark as adjusted
 859         }
 860 #endif
 861 }