+// FEATURE: EF_NODRAW workalike
+float EF_BRIGHTFIELD = 1;
+float EF_BRIGHTLIGHT = 4;
+float EF_DIMLIGHT = 8;
+float EF_DOUBLESIDED = 32768;
+float EF_NOSELFSHADOW = 65536;
+float EF_DYNAMICMODELLIGHT = 131072;
+float MF_ROCKET = 1; // leave a trail
+float MF_GRENADE = 2; // leave a trail
+float MF_GIB = 4; // leave a trail
+float MF_ROTATE = 8; // rotate (bonus items)
+float MF_TRACER = 16; // green split trail
+float MF_ZOMGIB = 32; // small blood trail
+float MF_TRACER2 = 64; // orange split trail
+float MF_TRACER3 = 128; // purple trail
+.float csqcmodel_effects;
+.float csqcmodel_modelflags;
+void CSQCModel_Effects_PreUpdate(void)
+{
+ self.effects = self.csqcmodel_effects;
+ self.modelflags = self.csqcmodel_modelflags;
+}
+void CSQCModel_Effects_PostUpdate(void)
+{
+ self.csqcmodel_effects = self.effects;
+ self.csqcmodel_modelflags = self.modelflags;
+ self.effects = 0;
+ self.modelflags = 0;
+ if(self.csqcmodel_teleported)
+ Projectile_ResetTrail(self.origin);
+}
+void CSQCModel_Effects_Apply(void)
+{
+ float eff = self.csqcmodel_effects;
+ eff &~= CSQCMODEL_EF_RESPAWNGHOST;
+
+ self.renderflags &~= (RF_DEPTHHACK | RF_ADDITIVE | RF_FULLBRIGHT | EF_NOSHADOW | RF_USEAXIS);
+ self.effects = 0;
+ self.traileffect = 0;
+
+ if(eff & EF_BRIGHTFIELD)
+ self.traileffect = particleeffectnum("TR_NEXUIZPLASMA");
+ // ignoring EF_MUZZLEFLASH
+ if(eff & EF_BRIGHTLIGHT)
+ adddynamiclight(self.origin, 400, '3 3 3');
+ if(eff & EF_DIMLIGHT)
+ adddynamiclight(self.origin, 200, '1.5 1.5 1.5');
+ if((eff & EF_NODRAW) || (self.alpha < 0))
+ self.drawmask = 0;
+ if(eff & EF_ADDITIVE)
+ self.renderflags |= RF_ADDITIVE;
+ if(eff & EF_BLUE)
+ adddynamiclight(self.origin, 200, '0.15 0.15 1.5');
+ if(eff & EF_RED)
+ adddynamiclight(self.origin, 200, '1.5 0.15 0.15');
+ // ignoring EF_NOGUNBOB
+ if(eff & EF_FULLBRIGHT)
+ self.renderflags |= RF_FULLBRIGHT;
+ if(eff & EF_FLAME)
+ pointparticles(particleeffectnum("EF_FLAME"), self.origin, '0 0 0', bound(0, frametime, 0.1));
+ if(eff & EF_STARDUST)
+ pointparticles(particleeffectnum("EF_STARDUST"), self.origin, '0 0 0', bound(0, frametime, 0.1));
+ if(eff & EF_NOSHADOW)
+ self.renderflags |= RF_NOSHADOW;
+ if(eff & EF_NODEPTHTEST)
+ self.renderflags |= RF_DEPTHHACK;
+ // ignoring EF_SELECTABLE
+ if(eff & EF_DOUBLESIDED)
+ self.effects |= EF_DOUBLESIDED;
+ if(eff & EF_NOSELFSHADOW)
+ self.effects |= EF_NOSELFSHADOW;
+ if(eff & EF_DYNAMICMODELLIGHT)
+ self.renderflags |= RF_DYNAMICMODELLIGHT;
+ // ignoring EF_UNUSED18, EF_UNUSED19, EF_RESTARTANIM_BIT, EF_TELEPORT_BIT, EF_LOWPRECISION
+ if(self.csqcmodel_modelflags & MF_ROCKET)
+ self.traileffect = particleeffectnum("TR_ROCKET");
+ if(self.csqcmodel_modelflags & MF_GRENADE)
+ self.traileffect = particleeffectnum("TR_GRENADE");
+ if(self.csqcmodel_modelflags & MF_GIB)
+ self.traileffect = particleeffectnum("TR_BLOOD");
+ if(self.csqcmodel_modelflags & MF_ROTATE)
+ {
+ self.renderflags |= RF_USEAXIS;
+ makevectors(self.angles + '0 100 0' * fmod(time, 3.6));
+ }
+ if(self.csqcmodel_modelflags & MF_TRACER)
+ self.traileffect = particleeffectnum("TR_WIZSPIKE");
+ if(self.csqcmodel_modelflags & MF_ZOMGIB)
+ self.traileffect = particleeffectnum("TR_SLIGHTBLOOD");
+ if(self.csqcmodel_modelflags & MF_TRACER2)
+ self.traileffect = particleeffectnum("TR_KNIGHTSPIKE");
+ if(self.csqcmodel_modelflags & MF_TRACER3)
+ self.traileffect = particleeffectnum("TR_VORESPIKE");
+
+ if(self.drawmask)
+ Projectile_DrawTrail(self.origin);
+ else
+ Projectile_ResetTrail(self.origin);
+
+ if(self.csqcmodel_effects & CSQCMODEL_EF_RESPAWNGHOST)
+ self.renderflags |= RF_ADDITIVE;
+ // also special in CSQCPlayer_GlowMod_Apply
+}
+
+// FEATURE: auto glowmod
+.vector glowmod;
+void CSQCPlayer_GlowMod_Apply(void)
+{
+ float cm = self.colormap;
+
+ if(self.csqcmodel_effects & CSQCMODEL_EF_RESPAWNGHOST)
+ cm = 1024;
+
+ if(self.colormap > 0)
+ self.glowmod = colormapPaletteColor(((self.colormap >= 1024) ? self.colormap : stof(getplayerkeyvalue(self.colormap - 1, "colors"))) & 0x0F, TRUE) * 2;
+ else
+ self.glowmod = '1 1 1';
+
+ if(autocvar_cl_deathglow > 0)
+ if(self.csqcmodel_isdead)
+ {
+ self.glowmod = self.glowmod * bound(0, 1 - (time - self.death_time) / autocvar_cl_deathglow, 1);
+ // prevent the zero vector
+ self.glowmod_x = max(self.glowmod_x, 0.0001);
+ self.glowmod_y = max(self.glowmod_y, 0.0001);
+ self.glowmod_z = max(self.glowmod_z, 0.0001);
+ }
+}
+
+// general functions
+.float csqcmodel_predraw_run;
+void CSQCModel_Hook_PreDraw()
+{
+ if(self.csqcmodel_predraw_run == framecount)
+ return;
+ self.csqcmodel_predraw_run = framecount;
+
+ if(!self.modelindex || self.model == "null")
+ {
+ self.drawmask = 0;
+ return;
+ }
+ else
+ self.drawmask = MASK_NORMAL;
+
+ if(self.isplayermodel) // this checks if it's a player MODEL!
+ {
+ CSQCPlayer_ForceModel_Apply(self.entnum == player_localnum + 1);
+ CSQCPlayer_GlowMod_Apply();
+ CSQCPlayer_LOD_Apply();
+ CSQCPlayer_FallbackFrame_Apply();
+ }
+
+ CSQCModel_AutoTagIndex_Apply();
+
+ CSQCModel_Effects_Apply();
+}
+
+void CSQCModel_Hook_PreUpdate(float isnew, float isplayer, float islocalplayer)
+{
+ // revert to values from server
+ CSQCModel_Effects_PreUpdate();
+ if(self.isplayermodel)
+ {
+ CSQCPlayer_FallbackFrame_PreUpdate();
+ CSQCPlayer_ForceModel_PreUpdate();
+ }
+}
+
+void CSQCModel_Hook_PostUpdate(float isnew, float isplayer, float islocalplayer)
+{
+ // is it a player model? (shared state)
+ self.isplayermodel = (substring(self.model, 0, 14) == "models/player/");
+
+ // save values set by server
+ if(self.isplayermodel)
+ {
+ CSQCPlayer_ForceModel_PostUpdate();
+ CSQCPlayer_FallbackFrame_PostUpdate(isnew);
+ }
+ CSQCModel_Effects_PostUpdate();
+}