+.string object_clipboard;
+.float material;
+
+const float MATERIAL_NONE = 0;
+const float MATERIAL_METAL = 1;
+const float MATERIAL_STONE = 2;
+const float MATERIAL_WOOD = 3;
+const float MATERIAL_FLESH = 4;
+
+.float touch_timer;
+void sandbox_Object_Touch()
+{
+ // apply material impact effects
+
+ if(self.touch_timer > time)
+ return; // don't execute each frame
+ self.touch_timer = time + 0.1;
+ if not(vlen(self.velocity) > autocvar_g_sandbox_object_material_velocity_min || vlen(other.velocity) > autocvar_g_sandbox_object_material_velocity_min)
+ return; // impact not strong enough
+
+ float intensity;
+ intensity = (vlen(self.velocity) + vlen(other.velocity)) / 2;
+ intensity = bound(0, intensity * autocvar_g_sandbox_object_material_velocity_factor, 1);
+
+ switch(self.material)
+ {
+ case MATERIAL_METAL:
+ sound(self, CH_TRIGGER, strcat("object/impact_metal_", ftos(ceil(random() * 5)) , ".ogg"), VOL_BASE * intensity, ATTN_NORM);
+ pointparticles(particleeffectnum("impact_metal"), self.origin, '0 0 0', intensity * 10); // allow a count from 1 to 10
+ break;
+ case MATERIAL_STONE:
+ sound(self, CH_TRIGGER, strcat("object/impact_stone_", ftos(ceil(random() * 5)) , ".ogg"), VOL_BASE * intensity, ATTN_NORM);
+ pointparticles(particleeffectnum("impact_stone"), self.origin, '0 0 0', intensity * 10); // allow a count from 1 to 10
+ break;
+ case MATERIAL_WOOD:
+ sound(self, CH_TRIGGER, strcat("object/impact_wood_", ftos(ceil(random() * 5)) , ".ogg"), VOL_BASE * intensity, ATTN_NORM);
+ pointparticles(particleeffectnum("impact_wood"), self.origin, '0 0 0', intensity * 10); // allow a count from 1 to 10
+ break;
+ case MATERIAL_FLESH:
+ sound(self, CH_TRIGGER, strcat("object/impact_flesh_", ftos(ceil(random() * 5)) , ".ogg"), VOL_BASE * intensity, ATTN_NORM);
+ pointparticles(particleeffectnum("impact_flesh"), self.origin, '0 0 0', intensity * 10); // allow a count from 1 to 10
+ break;
+ default:
+ break;
+ }
+}
+
+entity sandbox_EditObject_Get()
+{
+ // returns the traced entity if the player can edit it, and world if not
+
+ makevectors(self.v_angle);
+ WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_edit, MOVE_NORMAL, self);
+ if(trace_ent.classname == "object" && trace_ent.realowner == self)
+ return trace_ent;
+ else
+ return world;
+}
+
+void sandbox_EditObject_Scale(entity e, float f)
+{
+ e.scale = f;
+ if(e.scale)
+ {
+ e.scale = bound(autocvar_g_sandbox_object_scale_min, e.scale, autocvar_g_sandbox_object_scale_max);
+ setsize(e, e.mins * e.scale, e.maxs * e.scale); // adapt bounding box size to model size
+ }
+}
+
+entity sandbox_SpawnObject()
+{
+ // spawn a new object with default properties
+
+ entity e;
+ e = spawn();
+ e.realowner = self;
+ e.classname = "object";
+ e.takedamage = DAMAGE_AIM;
+ e.damageforcescale = 1;
+ e.solid = SOLID_BBOX; // SOLID_BSP would be best, but can lag the server badly
+ e.movetype = MOVETYPE_TOSS;
+ e.frame = 0;
+ e.skin = 0;
+ e.material = MATERIAL_NONE;
+
+ e.touch = sandbox_Object_Touch;
+
+ // set origin and direction based on player position and view angle
+ makevectors(self.v_angle);
+ WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_spawn, MOVE_NORMAL, self);
+ setorigin(e, trace_endpos);
+ e.angles_y = self.v_angle_y;
+
+ return e;
+}
+
+string sandbox_Storage_Save(entity e)
+{
+ // save object properties
+ string s;
+
+ s = strcat(e.model, " ");
+ s = strcat(s, ftos(e.skin), " ");
+ s = strcat(s, ftos(e.alpha), " ");
+ s = strcat(s, sprintf("\"%.9v\"", e.colormod), " ");
+ s = strcat(s, sprintf("\"%.9v\"", e.glowmod), " ");
+ s = strcat(s, ftos(e.frame), " ");
+ s = strcat(s, ftos(e.scale), " ");
+ s = strcat(s, ftos(e.movetype), " ");
+ s = strcat(s, ftos(e.damageforcescale), " ");
+ s = strcat(s, ftos(e.material), " ");
+
+ return s;
+}
+
+void sandbox_Storage_Load(entity e, string s)
+{
+ // load object properties
+ tokenize_console(s);
+
+ setmodel(e, argv(0));
+ e.skin = stof(argv(1));
+ e.alpha = stof(argv(2));
+ e.colormod = stov(argv(3));
+ e.glowmod = stov(argv(4));
+ e.frame = stof(argv(5));
+ sandbox_EditObject_Scale(e, stof(argv(6)));
+ e.movetype = stof(argv(7));
+ e.damageforcescale = stof(argv(8));
+ e.material = stof(argv(9));
+}
+