CMake: make default install prefix actually work
[xonotic/netradiant.git] / CMakeLists.txt
1 cmake_minimum_required(VERSION 2.8.11 FATAL_ERROR)
2 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_LIST_DIR}/cmake")
3
4 project(NetRadiant C CXX)
5 option(BUILD_RADIANT "Build the gui" ON)
6
7 if (CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
8     set(CMAKE_INSTALL_PREFIX "${PROJECT_SOURCE_DIR}/install" CACHE PATH "..." FORCE)
9 endif ()
10
11 #-----------------------------------------------------------------------
12 # Version
13 #-----------------------------------------------------------------------
14
15 # CMake 3.0+ would allow this in project()
16 set(NetRadiant_VERSION_MAJOR 1)
17 set(NetRadiant_VERSION_MINOR 5)
18 set(NetRadiant_VERSION_PATCH 0)
19 set(NetRadiant_VERSION "${NetRadiant_VERSION_MAJOR}.${NetRadiant_VERSION_MINOR}.${NetRadiant_VERSION_PATCH}")
20
21 file(WRITE "${PROJECT_BINARY_DIR}/RADIANT_MAJOR" ${NetRadiant_VERSION_MAJOR})
22 file(WRITE "${PROJECT_BINARY_DIR}/RADIANT_MINOR" ${NetRadiant_VERSION_MINOR})
23 file(WRITE "${PROJECT_BINARY_DIR}/RADIANT_PATCH" ${NetRadiant_VERSION_PATCH})
24
25 set(RADIANT_ABOUTMSG "Custom build" CACHE STRING "About message")
26
27 find_package(Git REQUIRED)
28 execute_process(
29         COMMAND ${GIT_EXECUTABLE} rev-parse --short HEAD
30         WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}
31         OUTPUT_VARIABLE GIT_VERSION
32         OUTPUT_STRIP_TRAILING_WHITESPACE
33 )
34 set(RADIANT_VERSION_STRING "${NetRadiant_VERSION}n")
35 if (GIT_VERSION)
36     set(RADIANT_VERSION_STRING "${RADIANT_VERSION_STRING}-git-${GIT_VERSION}")
37 endif ()
38
39 message(STATUS "Building ${PROJECT_NAME} ${RADIANT_VERSION_STRING} ${RADIANT_ABOUTMSG}")
40
41 #-----------------------------------------------------------------------
42 # Language standard
43 #-----------------------------------------------------------------------
44
45 set(CMAKE_CXX_STANDARD 11)
46 set(CMAKE_CXX_STANDARD_REQUIRED ON)
47 # For some reason the above flags don't really work...
48 if ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang" OR CMAKE_COMPILER_IS_GNUCXX)
49     include(CheckCXXCompilerFlag)
50     check_cxx_compiler_flag(--std=c++${CMAKE_CXX_STANDARD} STD_CXX)
51     if (STD_CXX)
52         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} --std=c++${CMAKE_CXX_STANDARD}")
53     else ()
54         message(SEND_ERROR "Requires C++${CMAKE_CXX_STANDARD} or better")
55     endif ()
56 else ()
57     message(WARNING "Unrecognized compiler: ${CMAKE_CXX_COMPILER_ID}, make sure it supports C++${CMAKE_CXX_STANDARD}")
58 endif ()
59
60 #-----------------------------------------------------------------------
61 # Flags
62 #-----------------------------------------------------------------------
63
64 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-exceptions -fno-rtti")
65 macro(addflags args)
66     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${args}")
67     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${args}")
68 endmacro()
69 addflags("-fno-strict-aliasing")
70 if (NOT WIN32)
71     addflags("-fvisibility=hidden")
72 endif ()
73
74 set(CMAKE_POSITION_INDEPENDENT_CODE 1)
75 set(GTK_NS "GTK2" CACHE STRING "GTK variable prefix")
76
77 #-----------------------------------------------------------------------
78 # Defs
79 #-----------------------------------------------------------------------
80
81 add_definitions(-DRADIANT_VERSION="${NetRadiant_VERSION}")
82 add_definitions(-DRADIANT_MAJOR_VERSION="${NetRadiant_VERSION_MAJOR}")
83 add_definitions(-DRADIANT_MINOR_VERSION="${NetRadiant_VERSION_MINOR}")
84 add_definitions(-DRADIANT_PATCH_VERSION="${NetRadiant_VERSION_PATCH}")
85
86 add_definitions(-DRADIANT_ABOUTMSG="${NetRadiant_ABOUT}")
87
88 if (NOT CMAKE_BUILD_TYPE MATCHES Release)
89     add_definitions(-D_DEBUG=1)
90 endif ()
91
92 if (APPLE)
93     option(XWINDOWS "Build against X11" ON)
94     add_definitions(
95             -DPOSIX=1
96     )
97 elseif (WIN32)
98     add_definitions(
99             -DWIN32=1
100             -D_WIN32=1
101     )
102 else ()
103     set(XWINDOWS ON)
104     add_definitions(
105             -DPOSIX=1
106     )
107 endif ()
108
109 if (XWINDOWS)
110     find_package(X11 REQUIRED)
111     include_directories(${X11_INCLUDE_DIR})
112     add_definitions(-DXWINDOWS=1)
113 endif ()
114
115 include_directories("${PROJECT_SOURCE_DIR}/include")
116 include_directories("${PROJECT_SOURCE_DIR}/libs")
117
118 macro(copy_dlls target)
119     if (WIN32)
120         add_custom_command(TARGET ${target} POST_BUILD
121                 COMMAND bash
122                 ARGS -c "ldd '$<TARGET_FILE:${target}>' | grep -v /c/Windows | awk '{ print $1 }' | while read dll; do cp \"$(which $dll)\" '${PROJECT_BINARY_DIR}'; done"
123                 VERBATIM
124                 )
125     endif ()
126 endmacro()
127
128 #-----------------------------------------------------------------------
129 # Libraries
130 #-----------------------------------------------------------------------
131
132 add_subdirectory(libs)
133 add_subdirectory(include)
134
135 #-----------------------------------------------------------------------
136 # Plugins
137 #-----------------------------------------------------------------------
138
139 if (BUILD_RADIANT)
140     add_subdirectory(contrib)
141 endif ()
142
143 #-----------------------------------------------------------------------
144 # Modules
145 #-----------------------------------------------------------------------
146
147 if (BUILD_RADIANT)
148     add_subdirectory(plugins)
149 endif ()
150
151 #-----------------------------------------------------------------------
152 # Radiant
153 #-----------------------------------------------------------------------
154
155 if (CMAKE_EXECUTABLE_SUFFIX)
156     string(REGEX REPLACE "^[.]" "" RADIANT_EXECUTABLE ${CMAKE_EXECUTABLE_SUFFIX})
157 else ()
158     execute_process(
159             COMMAND uname -m
160             OUTPUT_VARIABLE RADIANT_EXECUTABLE
161             OUTPUT_STRIP_TRAILING_WHITESPACE
162     )
163 endif ()
164
165 macro(radiant_tool name)
166     add_executable(${name} ${ARGN})
167     install(
168             TARGETS ${name}
169             RUNTIME DESTINATION .
170     )
171     if (NOT (CMAKE_EXECUTABLE_SUFFIX STREQUAL ".${RADIANT_EXECUTABLE}"))
172         add_custom_command(TARGET ${name} POST_BUILD
173                 COMMAND ln -f -s "$<TARGET_FILE_NAME:${name}>" "${PROJECT_BINARY_DIR}/${name}.${RADIANT_EXECUTABLE}"
174                 VERBATIM
175                 )
176         install(CODE "execute_process(COMMAND ${CMAKE_COMMAND} -E create_symlink \
177             ${name}${CMAKE_EXECUTABLE_SUFFIX} \
178             ${CMAKE_INSTALL_PREFIX}/${name}.${RADIANT_EXECUTABLE} \
179         )")
180     endif ()
181 endmacro()
182
183 if (BUILD_RADIANT)
184     add_subdirectory(radiant build)
185     set_target_properties(radiant PROPERTIES
186             COMPILE_DEFINITIONS RADIANT_EXECUTABLE="${RADIANT_EXECUTABLE}"
187             )
188 endif ()
189
190 #-----------------------------------------------------------------------
191 # Tools
192 #-----------------------------------------------------------------------
193
194 add_subdirectory(tools)
195
196 file(GLOB DATA_FILES "${PROJECT_SOURCE_DIR}/setup/data/tools/*")
197 file(GLOB DOCS_FILES "${PROJECT_SOURCE_DIR}/docs/*")
198
199 if (NOT (PROJECT_SOURCE_DIR STREQUAL PROJECT_BINARY_DIR))
200     # Copy data files from sources to the build directory
201     message(STATUS "Copying data files")
202     file(COPY ${DATA_FILES} DESTINATION "${PROJECT_BINARY_DIR}")
203     file(COPY ${DOCS_FILES} DESTINATION "${PROJECT_BINARY_DIR}/docs")
204 endif ()
205
206 #-----------------------------------------------------------------------
207 # Game packs
208 #-----------------------------------------------------------------------
209
210 option(DOWNLOAD_GAMEPACKS "Download game packs" ON)
211 add_custom_target(game_packs
212         COMMAND ${CMAKE_COMMAND} -E make_directory games
213         COMMAND DOWNLOAD_GAMEPACKS=yes SOURCE_DIR="${PROJECT_SOURCE_DIR}" "${PROJECT_SOURCE_DIR}/install-gamepacks.sh" "${PROJECT_BINARY_DIR}"
214         COMMENT "Downloading game packs"
215         )
216 if (DOWNLOAD_GAMEPACKS)
217     add_custom_target(game_packs_all ALL DEPENDS game_packs)
218 endif ()
219
220 #-----------------------------------------------------------------------
221 # Install
222 #-----------------------------------------------------------------------
223
224 install(
225         FILES
226         "${PROJECT_BINARY_DIR}/RADIANT_MAJOR"
227         "${PROJECT_BINARY_DIR}/RADIANT_MINOR"
228         "${PROJECT_BINARY_DIR}/RADIANT_PATCH"
229         DESTINATION ${CMAKE_INSTALL_PREFIX}
230 )
231 file(GLOB GAME_FILES "${PROJECT_SOURCE_DIR}/games/*")
232 unset(_tmp)
233 foreach (it ${GAME_FILES})
234     list(APPEND _tmp "${it}/games")
235     file(GLOB GAME_DIR "${it}/*.game")
236     list(APPEND _tmp "${GAME_DIR}")
237 endforeach ()
238 set(GAME_FILES ${_tmp})
239
240 install(
241         DIRECTORY
242         ${PROJECT_SOURCE_DIR}/setup/data/tools/
243         ${PROJECT_SOURCE_DIR}/docs
244         ${GAME_FILES}
245         DESTINATION ${CMAKE_INSTALL_PREFIX}
246 )
247