qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2
   3 #include "anticheat.qh"
   4 #include "antilag.qh"
   5 #include "bot/bot.qh"
   6 #include "campaign.qh"
   7 #include "cheats.qh"
   8 #include "cl_client.qh"
   9 #include "command/common.qh"
  10 #include "command/getreplies.qh"
  11 #include "command/sv_cmd.qh"
  12 #include "command/vote.qh"
  13 #include "g_hook.qh"
  14 #include "ipban.qh"
  15 #include "mapvoting.qh"
  16 #include "mutators/all.qh"
  17 #include "race.qh"
  18 #include "scores.qh"
  19 #include "teamplay.qh"
  20 #include "weapons/weaponstats.qh"
  21 #include "../common/constants.qh"
  22 #include "../common/deathtypes/all.qh"
  23 #include "../common/mapinfo.qh"
  24 #include "../common/monsters/all.qh"
  25 #include "../common/monsters/sv_monsters.qh"
  26 #include "../common/vehicles/all.qh"
  27 #include "../common/notifications.qh"
  28 #include "../common/physics/player.qh"
  29 #include "../common/playerstats.qh"
  30 #include "../common/stats.qh"
  31 #include "../common/teams.qh"
  32 #include "../common/triggers/trigger/secret.qh"
  33 #include "../common/triggers/target/music.qh"
  34 #include "../common/util.qh"
  35 #include "../common/items/all.qh"
  36 #include "../common/weapons/all.qh"
  37
  38 const float LATENCY_THINKRATE = 10;
  39 .float latency_sum;
  40 .float latency_cnt;
  41 .float latency_time;
  42 entity pingplreport;
  43 void PingPLReport_Think()
  44 {SELFPARAM();
  45         float delta;
  46         entity e;
  47
  48         delta = 3 / maxclients;
  49         if(delta < sys_frametime)
  50                 delta = 0;
  51         self.nextthink = time + delta;
  52
  53         e = edict_num(self.cnt + 1);
  54         if(IS_REAL_CLIENT(e))
  55         {
  56                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  57                 WriteByte(MSG_BROADCAST, self.cnt);
  58                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  59                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  60                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  61
  62                 // record latency times for clients throughout the match so we can report it to playerstats
  63                 if(time > (e.latency_time + LATENCY_THINKRATE))
  64                 {
  65                         e.latency_sum += e.ping;
  66                         e.latency_cnt += 1;
  67                         e.latency_time = time;
  68                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  69                 }
  70         }
  71         else
  72         {
  73                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  74                 WriteByte(MSG_BROADCAST, self.cnt);
  75                 WriteShort(MSG_BROADCAST, 0);
  76                 WriteByte(MSG_BROADCAST, 0);
  77                 WriteByte(MSG_BROADCAST, 0);
  78         }
  79         self.cnt = (self.cnt + 1) % maxclients;
  80 }
  81 void PingPLReport_Spawn()
  82 {
  83         pingplreport = new(pingplreport);
  84         make_pure(pingplreport);
  85         pingplreport.think = PingPLReport_Think;
  86         pingplreport.nextthink = time;
  87 }
  88
  89 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  90 string redirection_target;
  91 float world_initialized;
  92
  93 string GetGametype();
  94 void ShuffleMaplist();
  95
  96 void SetDefaultAlpha()
  97 {
  98         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
  99         {
 100                 default_player_alpha = autocvar_g_player_alpha;
 101                 if(default_player_alpha == 0)
 102                         default_player_alpha = 1;
 103                 default_weapon_alpha = default_player_alpha;
 104         }
 105 }
 106
 107 void GotoFirstMap()
 108 {SELFPARAM();
 109         float n;
 110         if(autocvar__sv_init)
 111         {
 112                 // cvar_set("_sv_init", "0");
 113                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 114                 // to this "init" map on a dedicated server will cause no permanent
 115                 // harm
 116                 if(autocvar_g_maplist_shuffle)
 117                         ShuffleMaplist();
 118                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 119                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 120
 121                 MapInfo_Enumerate();
 122                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 123
 124                 if(!DoNextMapOverride(1))
 125                         GotoNextMap(1);
 126
 127                 return;
 128         }
 129
 130         if(time < 5)
 131         {
 132                 self.nextthink = time;
 133         }
 134         else
 135         {
 136                 self.nextthink = time + 1;
 137                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 138         }
 139 }
 140
 141 void cvar_changes_init()
 142 {
 143         float h;
 144         string k, v, d;
 145         float n, i, adding, pureadding;
 146
 147         if(cvar_changes)
 148                 strunzone(cvar_changes);
 149         cvar_changes = string_null;
 150         if(cvar_purechanges)
 151                 strunzone(cvar_purechanges);
 152         cvar_purechanges = string_null;
 153         cvar_purechanges_count = 0;
 154
 155         h = buf_create();
 156         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 157         n = buf_getsize(h);
 158
 159         adding = true;
 160         pureadding = true;
 161
 162         for(i = 0; i < n; ++i)
 163         {
 164                 k = bufstr_get(h, i);
 165
 166 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 167 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 168 #define BADCVAR(p) if(k == p) continue
 169
 170                 // general excludes and namespaces for server admin used cvars
 171                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 172
 173                 // internal
 174                 BADPREFIX("csqc_");
 175                 BADPREFIX("cvar_check_");
 176                 BADCVAR("gamecfg");
 177                 BADCVAR("g_configversion");
 178                 BADCVAR("g_maplist_index");
 179                 BADCVAR("halflifebsp");
 180                 BADCVAR("sv_mapformat_is_quake2");
 181                 BADCVAR("sv_mapformat_is_quake3");
 182                 BADPREFIX("sv_world");
 183
 184                 // client
 185                 BADPREFIX("chase_");
 186                 BADPREFIX("cl_");
 187                 BADPREFIX("con_");
 188                 BADPREFIX("scoreboard_");
 189                 BADPREFIX("g_campaign");
 190                 BADPREFIX("g_waypointsprite_");
 191                 BADPREFIX("gl_");
 192                 BADPREFIX("joy");
 193                 BADPREFIX("hud_");
 194                 BADPREFIX("m_");
 195                 BADPREFIX("menu_");
 196                 BADPREFIX("net_slist_");
 197                 BADPREFIX("r_");
 198                 BADPREFIX("sbar_");
 199                 BADPREFIX("scr_");
 200                 BADPREFIX("snd_");
 201                 BADPREFIX("show");
 202                 BADPREFIX("sensitivity");
 203                 BADPREFIX("userbind");
 204                 BADPREFIX("v_");
 205                 BADPREFIX("vid_");
 206                 BADPREFIX("crosshair");
 207                 BADCVAR("mod_q3bsp_lightmapmergepower");
 208                 BADCVAR("mod_q3bsp_nolightmaps");
 209                 BADCVAR("fov");
 210                 BADCVAR("mastervolume");
 211                 BADCVAR("volume");
 212                 BADCVAR("bgmvolume");
 213
 214                 // private
 215                 BADCVAR("developer");
 216                 BADCVAR("log_dest_udp");
 217                 BADCVAR("net_address");
 218                 BADCVAR("net_address_ipv6");
 219                 BADCVAR("port");
 220                 BADCVAR("savedgamecfg");
 221                 BADCVAR("serverconfig");
 222                 BADCVAR("sv_autoscreenshot");
 223                 BADCVAR("sv_heartbeatperiod");
 224                 BADCVAR("sv_vote_master_password");
 225                 BADCVAR("sys_colortranslation");
 226                 BADCVAR("sys_specialcharactertranslation");
 227                 BADCVAR("timeformat");
 228                 BADCVAR("timestamps");
 229                 BADPREFIX("developer_");
 230                 BADPREFIX("g_ban_");
 231                 BADPREFIX("g_banned_list");
 232                 BADPREFIX("g_chat_flood_");
 233                 BADPREFIX("g_ghost_items");
 234                 BADPREFIX("g_playerstats_");
 235                 BADPREFIX("g_respawn_ghosts");
 236                 BADPREFIX("g_voice_flood_");
 237                 BADPREFIX("log_file");
 238                 BADPREFIX("rcon_");
 239                 BADPREFIX("sv_allowdownloads");
 240                 BADPREFIX("sv_autodemo");
 241                 BADPREFIX("sv_curl_");
 242                 BADPREFIX("sv_eventlog");
 243                 BADPREFIX("sv_logscores_");
 244                 BADPREFIX("sv_master");
 245                 BADPREFIX("sv_weaponstats_");
 246                 BADPREFIX("sv_waypointsprite_");
 247                 BADCVAR("rescan_pending");
 248
 249                 // these can contain player IDs, so better hide
 250                 BADPREFIX("g_forced_team_");
 251
 252                 // mapinfo
 253                 BADCVAR("fraglimit");
 254                 BADCVAR("g_assault");
 255                 BADCVAR("g_ca");
 256                 BADCVAR("g_ca_teams");
 257                 BADCVAR("g_ctf");
 258                 BADCVAR("g_cts");
 259                 BADCVAR("g_dm");
 260                 BADCVAR("g_domination");
 261                 BADCVAR("g_domination_default_teams");
 262                 BADCVAR("g_freezetag");
 263                 BADCVAR("g_freezetag_teams");
 264                 BADCVAR("g_invasion_teams");
 265                 BADCVAR("g_keepaway");
 266                 BADCVAR("g_keyhunt");
 267                 BADCVAR("g_keyhunt_teams");
 268                 BADCVAR("g_lms");
 269                 BADCVAR("g_nexball");
 270                 BADCVAR("g_onslaught");
 271                 BADCVAR("g_race");
 272                 BADCVAR("g_race_qualifying_timelimit");
 273                 BADCVAR("g_tdm");
 274                 BADCVAR("g_tdm_teams");
 275                 BADCVAR("leadlimit");
 276                 BADCVAR("nextmap");
 277                 BADCVAR("teamplay");
 278                 BADCVAR("timelimit");
 279
 280                 // long
 281                 BADCVAR("hostname");
 282                 BADCVAR("g_maplist");
 283                 BADCVAR("g_maplist_mostrecent");
 284                 BADCVAR("sv_motd");
 285
 286                 v = cvar_string(k);
 287                 d = cvar_defstring(k);
 288                 if(v == d)
 289                         continue;
 290
 291                 if(adding)
 292                 {
 293                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 294                         if(strlen(cvar_changes) > 16384)
 295                         {
 296                                 cvar_changes = "// too many settings have been changed to show them here\n";
 297                                 adding = 0;
 298                         }
 299                 }
 300
 301                 // now check if the changes are actually gameplay relevant
 302
 303                 // does nothing visible
 304                 BADCVAR("captureleadlimit_override");
 305                 BADCVAR("g_balance_kill_delay");
 306                 BADCVAR("g_ca_point_limit");
 307                 BADCVAR("g_ca_point_leadlimit");
 308                 BADCVAR("g_ctf_captimerecord_always");
 309                 BADCVAR("g_ctf_flag_glowtrails");
 310                 BADCVAR("g_ctf_flag_pickup_verbosename");
 311                 BADCVAR("g_domination_point_leadlimit");
 312                 BADCVAR("g_forced_respawn");
 313                 BADCVAR("g_freezetag_point_limit");
 314                 BADCVAR("g_freezetag_point_leadlimit");
 315                 BADCVAR("g_keyhunt_point_leadlimit");
 316                 BADPREFIX("g_mod_");
 317                 BADCVAR("g_invasion_point_limit");
 318                 BADCVAR("g_nexball_goalleadlimit");
 319                 BADCVAR("g_tdm_point_limit");
 320                 BADCVAR("g_tdm_point_leadlimit");
 321                 BADCVAR("leadlimit_and_fraglimit");
 322                 BADCVAR("leadlimit_override");
 323                 BADCVAR("pausable");
 324                 BADCVAR("sv_allow_fullbright");
 325                 BADCVAR("sv_checkforpacketsduringsleep");
 326                 BADCVAR("sv_timeout");
 327                 BADPREFIX("sv_timeout_");
 328                 BADPREFIX("crypto_");
 329                 BADPREFIX("g_chat_");
 330                 BADPREFIX("g_ctf_captimerecord_");
 331                 BADPREFIX("g_maplist_votable_");
 332                 BADPREFIX("net_");
 333                 BADPREFIX("prvm_");
 334                 BADPREFIX("skill_");
 335                 BADPREFIX("sv_cullentities_");
 336                 BADPREFIX("sv_maxidle_");
 337                 BADPREFIX("sv_vote_");
 338                 BADPREFIX("timelimit_");
 339                 BADCVAR("gameversion");
 340                 BADPREFIX("gameversion_");
 341                 BADCVAR("sv_minigames");
 342                 BADPREFIX("sv_minigames_");
 343                 BADCVAR("sv_namechangetimer");
 344
 345                 // allowed changes to server admins (please sync this to server.cfg)
 346                 // vi commands:
 347                 //   :/"impure"/,$d
 348                 //   :g!,^\/\/[^ /],d
 349                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 350                 //   :%!sort
 351                 // yes, this does contain some redundant stuff, don't really care
 352                 BADCVAR("bot_config_file");
 353                 BADCVAR("bot_number");
 354                 BADCVAR("bot_prefix");
 355                 BADCVAR("bot_suffix");
 356                 BADCVAR("capturelimit_override");
 357                 BADCVAR("fraglimit_override");
 358                 BADCVAR("gametype");
 359                 BADCVAR("g_antilag");
 360                 BADCVAR("g_balance_teams");
 361                 BADCVAR("g_balance_teams_prevent_imbalance");
 362                 BADCVAR("g_balance_teams_scorefactor");
 363                 BADCVAR("g_ban_sync_trusted_servers");
 364                 BADCVAR("g_ban_sync_uri");
 365                 BADCVAR("g_ca_teams_override");
 366                 BADCVAR("g_ctf_ignore_frags");
 367                 BADCVAR("g_domination_point_limit");
 368                 BADCVAR("g_domination_teams_override");
 369                 BADCVAR("g_freezetag_teams_override");
 370                 BADCVAR("g_friendlyfire");
 371                 BADCVAR("g_fullbrightitems");
 372                 BADCVAR("g_fullbrightplayers");
 373                 BADCVAR("g_keyhunt_point_limit");
 374                 BADCVAR("g_keyhunt_teams_override");
 375                 BADCVAR("g_lms_lives_override");
 376                 BADCVAR("g_maplist");
 377                 BADCVAR("g_maplist_check_waypoints");
 378                 BADCVAR("g_maplist_mostrecent_count");
 379                 BADCVAR("g_maplist_shuffle");
 380                 BADCVAR("g_maplist_votable");
 381                 BADCVAR("g_maplist_votable_abstain");
 382                 BADCVAR("g_maplist_votable_nodetail");
 383                 BADCVAR("g_maplist_votable_suggestions");
 384                 BADCVAR("g_maxplayers");
 385                 BADCVAR("g_mirrordamage");
 386                 BADCVAR("g_nexball_goallimit");
 387                 BADCVAR("g_powerups");
 388                 BADCVAR("g_start_delay");
 389                 BADCVAR("g_tdm_teams_override");
 390                 BADCVAR("g_warmup");
 391                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 392                 BADCVAR("hostname");
 393                 BADCVAR("log_file");
 394                 BADCVAR("maxplayers");
 395                 BADCVAR("minplayers");
 396                 BADCVAR("net_address");
 397                 BADCVAR("port");
 398                 BADCVAR("rcon_password");
 399                 BADCVAR("rcon_restricted_commands");
 400                 BADCVAR("rcon_restricted_password");
 401                 BADCVAR("skill");
 402                 BADCVAR("sv_adminnick");
 403                 BADCVAR("sv_autoscreenshot");
 404                 BADCVAR("sv_autotaunt");
 405                 BADCVAR("sv_curl_defaulturl");
 406                 BADCVAR("sv_defaultcharacter");
 407                 BADCVAR("sv_defaultplayercolors");
 408                 BADCVAR("sv_defaultplayermodel");
 409                 BADCVAR("sv_defaultplayerskin");
 410                 BADCVAR("sv_maxidle");
 411                 BADCVAR("sv_maxrate");
 412                 BADCVAR("sv_motd");
 413                 BADCVAR("sv_public");
 414                 BADCVAR("sv_ready_restart");
 415                 BADCVAR("sv_status_privacy");
 416                 BADCVAR("sv_taunt");
 417                 BADCVAR("sv_vote_call");
 418                 BADCVAR("sv_vote_commands");
 419                 BADCVAR("sv_vote_majority_factor");
 420                 BADCVAR("sv_vote_master");
 421                 BADCVAR("sv_vote_master_commands");
 422                 BADCVAR("sv_vote_master_password");
 423                 BADCVAR("sv_vote_simple_majority_factor");
 424                 BADCVAR("teamplay_mode");
 425                 BADCVAR("timelimit_override");
 426                 BADCVAR("g_spawnshieldtime");
 427                 BADPREFIX("g_warmup_");
 428                 BADPREFIX("sv_ready_restart_");
 429
 430                 // mutators that announce themselves properly to the server browser
 431                 BADCVAR("g_instagib");
 432                 BADCVAR("g_new_toys");
 433                 BADCVAR("g_nix");
 434                 BADCVAR("g_grappling_hook");
 435                 BADCVAR("g_jetpack");
 436
 437 #undef BADPREFIX
 438 #undef BADCVAR
 439
 440                 if(pureadding)
 441                 {
 442                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 443                         if(strlen(cvar_purechanges) > 16384)
 444                         {
 445                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 446                                 pureadding = 0;
 447                         }
 448                 }
 449                 ++cvar_purechanges_count;
 450                 // WARNING: this variable is used for the server list
 451                 // NEVER dare to skip this code!
 452                 // Hacks to intentionally appearing as "pure server" even though you DO have
 453                 // modified settings may be punished by removal from the server list.
 454                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 455                 // though.
 456         }
 457         buf_del(h);
 458         if(cvar_changes == "")
 459                 cvar_changes = "// this server runs at default server settings\n";
 460         else
 461                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 462         cvar_changes = strzone(cvar_changes);
 463         if(cvar_purechanges == "")
 464                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 465         else
 466                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 467         cvar_purechanges = strzone(cvar_purechanges);
 468 }
 469
 470 void detect_maptype()
 471 {
 472 #if 0
 473         vector o, v;
 474         float i;
 475
 476         for (;;)
 477         {
 478                 o = world.mins;
 479                 o.x += random() * (world.maxs.x - world.mins.x);
 480                 o.y += random() * (world.maxs.y - world.mins.y);
 481                 o.z += random() * (world.maxs.z - world.mins.z);
 482
 483                 tracebox(o, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), o - '0 0 32768', MOVE_WORLDONLY, world);
 484                 if(trace_fraction == 1)
 485                         continue;
 486
 487                 v = trace_endpos;
 488
 489                 for(i = 0; i < 64; i += 4)
 490                 {
 491                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 492         if(trace_fraction == 1)
 493                 continue;
 494                         LOG_INFO(ftos(i), " -> ", vtos(trace_endpos), "\n");
 495                 }
 496
 497                 break;
 498         }
 499 #endif
 500 }
 501
 502 entity randomseed;
 503 bool RandomSeed_Send(entity this, entity to, int sf)
 504 {
 505         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 506         WriteShort(MSG_ENTITY, self.cnt);
 507         return true;
 508 }
 509 void RandomSeed_Think()
 510 {SELFPARAM();
 511         self.cnt = bound(0, floor(random() * 65536), 65535);
 512         self.nextthink = time + 5;
 513
 514         self.SendFlags |= 1;
 515 }
 516 void RandomSeed_Spawn()
 517 {SELFPARAM();
 518         randomseed = new(randomseed);
 519         make_pure(randomseed);
 520         randomseed.think = RandomSeed_Think;
 521         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 522
 523         WITH(entity, self, randomseed, randomseed.think()); // sets random seed and nextthink
 524 }
 525
 526 spawnfunc(__init_dedicated_server)
 527 {
 528         // handler for _init/_init map (only for dedicated server initialization)
 529
 530         world_initialized = -1; // don't complain
 531         cvar = cvar_normal;
 532         cvar_string = cvar_string_normal;
 533         cvar_set = cvar_set_normal;
 534
 535         remove = remove_unsafely;
 536
 537         entity e = spawn();
 538         e.think = GotoFirstMap;
 539         e.nextthink = time; // this is usually 1 at this point
 540
 541         e = new(info_player_deathmatch);  // safeguard against player joining
 542
 543         self.classname = "worldspawn"; // safeguard against various stuff ;)
 544
 545         // needs to be done so early because of the constants they create
 546         static_init();
 547         static_init_late();
 548         static_init_precache();
 549
 550         MapInfo_Enumerate();
 551         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 552 }
 553
 554 void __init_dedicated_server_shutdown() {
 555         MapInfo_Shutdown();
 556 }
 557
 558 void Map_MarkAsRecent(string m);
 559 float world_already_spawned;
 560 void Nagger_Init();
 561 void ClientInit_Spawn();
 562 void WeaponStats_Init();
 563 void WeaponStats_Shutdown();
 564 spawnfunc(worldspawn)
 565 {
 566         server_is_dedicated = boolean(stof(cvar_defstring("is_dedicated")));
 567
 568         {
 569                 bool wantrestart = false;
 570
 571                 if (!server_is_dedicated)
 572                 {
 573                         // force unloading of server pk3 files when starting a listen server
 574                         localcmd("\nfs_rescan\n");
 575                         // restore csqc_progname too
 576                         string expect = "csprogs.dat";
 577                         wantrestart = cvar_string_normal("csqc_progname") != expect;
 578                         cvar_set_normal("csqc_progname", expect);
 579                 }
 580                 else
 581                 {
 582                         // Try to use versioned csprogs from pk3
 583                         // Only ever use versioned csprogs.dat files on dedicated servers;
 584                         // we need to reset csqc_progname on clients ourselves, and it's easier if the client's release name is constant
 585                         string pk3csprogs = "csprogs-" WATERMARK ".dat";
 586                         if (cvar_string_normal("csqc_progname") != pk3csprogs && fexists(pk3csprogs))
 587                         {
 588                                 cvar_set_normal("csqc_progname", pk3csprogs);
 589                                 wantrestart = true;
 590                         }
 591                         // Check for updates on startup
 592                         // We do it this way for atomicity so that connecting clients still match the server progs and don't disconnect
 593                         int sentinel = fopen("progs.txt", FILE_READ);
 594                         if (sentinel >= 0)
 595                         {
 596                                 string switchversion = fgets(sentinel);
 597                                 fclose(sentinel);
 598                                 if (switchversion != "" && switchversion != WATERMARK)
 599                                 {
 600                                         LOG_INFOF("Switching progs: " WATERMARK " -> %s\n", switchversion);
 601                                         // if it doesn't exist, assume either:
 602                                         //   a) the current program was overwritten
 603                                         //   b) this is a client only update
 604                                         string newprogs = sprintf("progs-%s.dat", switchversion);
 605                                         if (fexists(newprogs))
 606                                         {
 607                                                 cvar_set_normal("sv_progs", newprogs);
 608                                                 wantrestart = true;
 609                                         }
 610                                         string newcsprogs = sprintf("csprogs-%s.dat", switchversion);
 611                                         if (fexists(newcsprogs))
 612                                         {
 613                                                 cvar_set_normal("csqc_progname", newcsprogs);
 614                                                 wantrestart = true;
 615                                         }
 616                                 }
 617                         }
 618                 }
 619                 if (wantrestart) changelevel(mapname);
 620                 // let initialization continue, shutdown depends on it
 621         }
 622
 623         float fd, l;
 624         string s;
 625
 626         cvar = cvar_normal;
 627         cvar_string = cvar_string_normal;
 628         cvar_set = cvar_set_normal;
 629
 630         if(world_already_spawned)
 631                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 632         world_already_spawned = true;
 633
 634         remove = remove_safely; // during spawning, watch what you remove!
 635
 636         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 637
 638         compressShortVector_init();
 639
 640         maxclients = 0;
 641         for (entity head = nextent(world); head; head = nextent(head))
 642         {
 643                 ++maxclients;
 644         }
 645
 646         // needs to be done so early because of the constants they create
 647         static_init();
 648
 649         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 650
 651         TemporaryDB = db_create();
 652
 653         // 0 normal
 654         lightstyle(0, "m");
 655
 656         // 1 FLICKER (first variety)
 657         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 658
 659         // 2 SLOW STRONG PULSE
 660         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 661
 662         // 3 CANDLE (first variety)
 663         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 664
 665         // 4 FAST STROBE
 666         lightstyle(4, "mamamamamama");
 667
 668         // 5 GENTLE PULSE 1
 669         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 670
 671         // 6 FLICKER (second variety)
 672         lightstyle(6, "nmonqnmomnmomomno");
 673
 674         // 7 CANDLE (second variety)
 675         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 676
 677         // 8 CANDLE (third variety)
 678         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 679
 680         // 9 SLOW STROBE (fourth variety)
 681         lightstyle(9, "aaaaaaaazzzzzzzz");
 682
 683         // 10 FLUORESCENT FLICKER
 684         lightstyle(10, "mmamammmmammamamaaamammma");
 685
 686         // 11 SLOW PULSE NOT FADE TO BLACK
 687         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 688
 689         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 690
 691         // 63 testing
 692         lightstyle(63, "a");
 693
 694         if(autocvar_g_campaign)
 695                 CampaignPreInit();
 696
 697         Map_MarkAsRecent(mapname);
 698
 699         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 700
 701         InitGameplayMode();
 702         static_init_late();
 703         static_init_precache();
 704         readlevelcvars();
 705         GrappleHookInit();
 706
 707         player_count = 0;
 708         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 709         if(bot_waypoints_for_items == 1)
 710                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 711                         bot_waypoints_for_items = 0;
 712
 713         precache();
 714
 715         WaypointSprite_Init();
 716
 717         GameLogInit(); // prepare everything
 718         // NOTE for matchid:
 719         // changing the logic generating it is okay. But:
 720         // it HAS to stay <= 64 chars
 721         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 722         if(autocvar_sv_eventlog)
 723         {
 724                 s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 725                 matchid = strzone(s);
 726
 727                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 728                 s = ":gameinfo:mutators:LIST";
 729
 730                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
 731                 s = ret_string;
 732
 733                 // initialiation stuff, not good in the mutator system
 734                 if(!autocvar_g_use_ammunition)
 735                         s = strcat(s, ":no_use_ammunition");
 736
 737                 // initialiation stuff, not good in the mutator system
 738                 if(autocvar_g_pickup_items == 0)
 739                         s = strcat(s, ":no_pickup_items");
 740                 if(autocvar_g_pickup_items > 0)
 741                         s = strcat(s, ":pickup_items");
 742
 743                 // initialiation stuff, not good in the mutator system
 744                 if(autocvar_g_weaponarena != "0")
 745                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 746
 747                 // TODO to mutator system
 748                 if(autocvar_g_norecoil)
 749                         s = strcat(s, ":norecoil");
 750
 751                 // TODO to mutator system
 752                 if(autocvar_g_powerups == 0)
 753                         s = strcat(s, ":no_powerups");
 754                 if(autocvar_g_powerups > 0)
 755                         s = strcat(s, ":powerups");
 756
 757                 GameLogEcho(s);
 758                 GameLogEcho(":gameinfo:end");
 759         }
 760         else
 761                 matchid = strzone(ftos(random()));
 762
 763         cvar_set("nextmap", "");
 764
 765         SetDefaultAlpha();
 766
 767         if(autocvar_g_campaign)
 768                 CampaignPostInit();
 769
 770         Ban_LoadBans();
 771
 772         MapInfo_Enumerate();
 773         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 774
 775         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 776         {
 777                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 778                 if(fd != -1)
 779                 {
 780                         while((s = fgets(fd)))
 781                         {
 782                                 l = tokenize_console(s);
 783                                 if(l < 2)
 784                                         continue;
 785                                 if(argv(0) == "cd")
 786                                 {
 787                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 788                                         LOG_INFO("  cdtrack ", argv(2), "\n");
 789                                 }
 790                                 else if(argv(0) == "fog")
 791                                 {
 792                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 793                                         LOG_INFO("  \"fog\" \"", s, "\"\n");
 794                                 }
 795                                 else if(argv(0) == "set")
 796                                 {
 797                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 798                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 799                                 }
 800                                 else if(argv(0) != "//")
 801                                 {
 802                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 803                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 804                                 }
 805                         }
 806                         fclose(fd);
 807                 }
 808         }
 809
 810         WeaponStats_Init();
 811
 812         Nagger_Init();
 813
 814         next_pingtime = time + 5;
 815
 816         detect_maptype();
 817
 818         // set up information replies for clients and server to use
 819         maplist_reply = strzone(getmaplist());
 820         lsmaps_reply = strzone(getlsmaps());
 821         monsterlist_reply = strzone(getmonsterlist());
 822         for(int i = 0; i < 10; ++i)
 823         {
 824                 s = getrecords(i);
 825                 if (s)
 826                         records_reply[i] = strzone(s);
 827         }
 828         ladder_reply = strzone(getladder());
 829         rankings_reply = strzone(getrankings());
 830
 831         // begin other init
 832         ClientInit_Spawn();
 833         RandomSeed_Spawn();
 834         PingPLReport_Spawn();
 835
 836         CheatInit();
 837
 838         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 839
 840         // fill sv_curl_serverpackages from .serverpackage files
 841         if (autocvar_sv_curl_serverpackages_auto)
 842         {
 843                 s = "csprogs-" WATERMARK ".txt";
 844                 // remove automatically managed files from the list to prevent duplicates
 845                 for (int i = 0, n = tokenize_console(cvar_string("sv_curl_serverpackages")); i < n; ++i)
 846                 {
 847                         string pkg = argv(i);
 848                         if (startsWith(pkg, "csprogs-")) continue;
 849                         if (endsWith(pkg, "-serverpackage.txt")) continue;
 850                         if (endsWith(pkg, ".serverpackage")) continue;  // OLD legacy
 851                         s = cons(s, pkg);
 852                 }
 853                 // add automatically managed files to the list
 854                 #define X(match) MACRO_BEGIN { \
 855                         fd = search_begin(match, true, false); \
 856                         if (fd >= 0) \
 857                         { \
 858                                 for (int i = 0, j = search_getsize(fd); i < j; ++i) \
 859                                 { \
 860                                         s = cons(s, search_getfilename(fd, i)); \
 861                                 } \
 862                                 search_end(fd); \
 863                         } \
 864                 } MACRO_END
 865                 X("*-serverpackage.txt");
 866                 X("*.serverpackage");
 867                 #undef X
 868                 cvar_set("sv_curl_serverpackages", s);
 869         }
 870
 871         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 872         modname = "Xonotic";
 873         // physics/balance/config changes that count as mod
 874         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 875                 modname = cvar_string("g_mod_physics");
 876         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 877                 modname = cvar_string("g_mod_balance");
 878         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 879                 modname = cvar_string("g_mod_config");
 880         // extra mutators that deserve to count as mod
 881         MUTATOR_CALLHOOK(SetModname);
 882
 883         // save it for later
 884         modname = strzone(modname);
 885
 886         WinningConditionHelper(); // set worldstatus
 887
 888         world_initialized = 1;
 889 }
 890
 891 spawnfunc(light)
 892 {
 893         //makestatic (self); // Who the f___ did that?
 894         remove(self);
 895 }
 896
 897 string GetGametype()
 898 {
 899         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 900 }
 901
 902 string GetMapname()
 903 {
 904         return mapname;
 905 }
 906
 907 float Map_Count, Map_Current;
 908 string Map_Current_Name;
 909
 910 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 911 float GetMaplistPosition()
 912 {
 913         float pos, idx;
 914         string map;
 915
 916         map = GetMapname();
 917         idx = autocvar_g_maplist_index;
 918
 919         if(idx >= 0)
 920                 if(idx < Map_Count)
 921                         if(map == argv(idx))
 922                                 return idx;
 923
 924         for(pos = 0; pos < Map_Count; ++pos)
 925                 if(map == argv(pos))
 926                         return pos;
 927
 928         // resume normal maplist rotation if current map is not in g_maplist
 929         return idx;
 930 }
 931
 932 float MapHasRightSize(string map)
 933 {
 934         float fh;
 935         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 936         if(autocvar_g_maplist_check_waypoints)
 937         {
 938                 LOG_TRACE("checkwp "); LOG_TRACE(map);
 939                 if(!fexists(strcat("maps/", map, ".waypoints")))
 940                 {
 941                         LOG_TRACE(": no waypoints\n");
 942                         return false;
 943                 }
 944                 LOG_TRACE(": has waypoints\n");
 945         }
 946
 947         // open map size restriction file
 948         LOG_TRACE("opensize "); LOG_TRACE(map);
 949         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 950         if(fh >= 0)
 951         {
 952                 float mapmin, mapmax;
 953                 LOG_TRACE(": ok, ");
 954                 mapmin = stof(fgets(fh));
 955                 mapmax = stof(fgets(fh));
 956                 fclose(fh);
 957                 if(player_count < mapmin)
 958                 {
 959                         LOG_TRACE("not enough\n");
 960                         return false;
 961                 }
 962                 if(player_count > mapmax)
 963                 {
 964                         LOG_TRACE("too many\n");
 965                         return false;
 966                 }
 967                 LOG_TRACE("right size\n");
 968                 return true;
 969         }
 970         LOG_TRACE(": not found\n");
 971         return true;
 972 }
 973
 974 string Map_Filename(float position)
 975 {
 976         return strcat("maps/", argv(position), ".bsp");
 977 }
 978
 979 void Map_MarkAsRecent(string m)
 980 {
 981         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
 982 }
 983
 984 float Map_IsRecent(string m)
 985 {
 986         return strhasword(autocvar_g_maplist_mostrecent, m);
 987 }
 988
 989 float Map_Check(float position, float pass)
 990 {
 991         string filename;
 992         string map_next;
 993         map_next = argv(position);
 994         if(pass <= 1)
 995         {
 996                 if(Map_IsRecent(map_next))
 997                         return 0;
 998         }
 999         filename = Map_Filename(position);
1000         if(MapInfo_CheckMap(map_next))
1001         {
1002                 if(pass == 2)
1003                         return 1;
1004                 if(MapHasRightSize(map_next))
1005                         return 1;
1006                 return 0;
1007         }
1008         else
1009                 LOG_TRACE( "Couldn't select '", filename, "'..\n" );
1010
1011         return 0;
1012 }
1013
1014 void Map_Goto_SetStr(string nextmapname)
1015 {
1016         if(getmapname_stored != "")
1017                 strunzone(getmapname_stored);
1018         if(nextmapname == "")
1019                 getmapname_stored = "";
1020         else
1021                 getmapname_stored = strzone(nextmapname);
1022 }
1023
1024 void Map_Goto_SetFloat(float position)
1025 {
1026         cvar_set("g_maplist_index", ftos(position));
1027         Map_Goto_SetStr(argv(position));
1028 }
1029
1030 void Map_Goto(float reinit)
1031 {
1032         MapInfo_LoadMap(getmapname_stored, reinit);
1033 }
1034
1035 // return codes of map selectors:
1036 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1037 //   -2 = permanent failure
1038 float() MaplistMethod_Iterate = // usual method
1039 {
1040         float pass, i;
1041
1042         LOG_TRACE("Trying MaplistMethod_Iterate\n");
1043
1044         for(pass = 1; pass <= 2; ++pass)
1045         {
1046                 for(i = 1; i < Map_Count; ++i)
1047                 {
1048                         float mapindex;
1049                         mapindex = (i + Map_Current) % Map_Count;
1050                         if(Map_Check(mapindex, pass))
1051                                 return mapindex;
1052                 }
1053         }
1054         return -1;
1055 }
1056
1057 float() MaplistMethod_Repeat = // fallback method
1058 {
1059         LOG_TRACE("Trying MaplistMethod_Repeat\n");
1060
1061         if(Map_Check(Map_Current, 2))
1062                 return Map_Current;
1063         return -2;
1064 }
1065
1066 float() MaplistMethod_Random = // random map selection
1067 {
1068         float i, imax;
1069
1070         LOG_TRACE("Trying MaplistMethod_Random\n");
1071
1072         imax = 42;
1073
1074         for(i = 0; i <= imax; ++i)
1075         {
1076                 float mapindex;
1077                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1078                 if(Map_Check(mapindex, 1))
1079                         return mapindex;
1080         }
1081         return -1;
1082 }
1083
1084 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1085 // the exponent sets a bias on the map selection:
1086 // the higher the exponent, the less likely "shortly repeated" same maps are
1087 {
1088         float i, j, imax, insertpos;
1089
1090         LOG_TRACE("Trying MaplistMethod_Shuffle\n");
1091
1092         imax = 42;
1093
1094         for(i = 0; i <= imax; ++i)
1095         {
1096                 string newlist;
1097
1098                 // now reinsert this at another position
1099                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1100                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1101                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1102                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1103
1104                 // insert the current map there
1105                 newlist = "";
1106                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1107                         newlist = strcat(newlist, " ", argv(j));
1108                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1109                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1110                         newlist = strcat(newlist, " ", argv(j));
1111                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1112                 cvar_set("g_maplist", newlist);
1113                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1114
1115                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1116                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1117                 if(Map_Check(Map_Current, 1))
1118                         return Map_Current;
1119         }
1120         return -1;
1121 }
1122
1123 void Maplist_Init()
1124 {
1125         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1126         float i;
1127         for (i = 0; i < Map_Count; ++i)
1128                 if (Map_Check(i, 2))
1129                         break;
1130         if (i == Map_Count)
1131         {
1132                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1133                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1134                 if(autocvar_g_maplist_shuffle)
1135                         ShuffleMaplist();
1136                 localcmd("\nmenu_cmd sync\n");
1137                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1138         }
1139         if(Map_Count == 0)
1140                 error("empty maplist, cannot select a new map");
1141         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1142
1143         if(Map_Current_Name)
1144                 strunzone(Map_Current_Name);
1145         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1146         // this may or may not be correct, but who cares, in the worst case a map
1147         // isn't chosen in the first pass that should have been
1148 }
1149
1150 string GetNextMap()
1151 {
1152         float nextMap;
1153
1154         Maplist_Init();
1155         nextMap = -1;
1156
1157         if(nextMap == -1)
1158                 if(autocvar_g_maplist_shuffle > 0)
1159                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1160
1161         if(nextMap == -1)
1162                 if(autocvar_g_maplist_selectrandom)
1163                         nextMap = MaplistMethod_Random();
1164
1165         if(nextMap == -1)
1166                 nextMap = MaplistMethod_Iterate();
1167
1168         if(nextMap == -1)
1169                 nextMap = MaplistMethod_Repeat();
1170
1171         if(nextMap >= 0)
1172         {
1173                 Map_Goto_SetFloat(nextMap);
1174                 return getmapname_stored;
1175         }
1176
1177         return "";
1178 }
1179
1180 float DoNextMapOverride(float reinit)
1181 {
1182         if(autocvar_g_campaign)
1183         {
1184                 CampaignPostIntermission();
1185                 alreadychangedlevel = true;
1186                 return true;
1187         }
1188         if(autocvar_quit_when_empty)
1189         {
1190                 if(player_count <= currentbots)
1191                 {
1192                         localcmd("quit\n");
1193                         alreadychangedlevel = true;
1194                         return true;
1195                 }
1196         }
1197         if(autocvar_quit_and_redirect != "")
1198         {
1199                 redirection_target = strzone(autocvar_quit_and_redirect);
1200                 alreadychangedlevel = true;
1201                 return true;
1202         }
1203         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1204         {
1205                 localcmd("restart\n");
1206                 alreadychangedlevel = true;
1207                 return true;
1208         }
1209         if(autocvar_nextmap != "")
1210         {
1211                 string m;
1212                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1213                 cvar_set("nextmap",m);
1214
1215                 if(!m || gametypevote)
1216                         return false;
1217                 if(autocvar_sv_vote_gametype)
1218                 {
1219                         Map_Goto_SetStr(m);
1220                         return false;
1221                 }
1222
1223                 if(MapInfo_CheckMap(m))
1224                 {
1225                         Map_Goto_SetStr(m);
1226                         Map_Goto(reinit);
1227                         alreadychangedlevel = true;
1228                         return true;
1229                 }
1230         }
1231         if(!reinit && autocvar_lastlevel)
1232         {
1233                 cvar_settemp_restore();
1234                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1235                 alreadychangedlevel = true;
1236                 return true;
1237         }
1238         return false;
1239 }
1240
1241 void GotoNextMap(float reinit)
1242 {
1243         //string nextmap;
1244         //float n, nummaps;
1245         //string s;
1246         if (alreadychangedlevel)
1247                 return;
1248         alreadychangedlevel = true;
1249
1250         string nextMap;
1251
1252         nextMap = GetNextMap();
1253         if(nextMap == "")
1254                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1255         Map_Goto(reinit);
1256 }
1257
1258
1259 /*
1260 ============
1261 IntermissionThink
1262
1263 When the player presses attack or jump, change to the next level
1264 ============
1265 */
1266 .float autoscreenshot;
1267 void IntermissionThink()
1268 {SELFPARAM();
1269         FixIntermissionClient(self);
1270
1271         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1272         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1273
1274         if( (server_screenshot || client_screenshot)
1275                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1276         {
1277                 self.autoscreenshot = -1;
1278                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1279                 return;
1280         }
1281
1282         if (time < intermission_exittime)
1283                 return;
1284
1285         if(!mapvote_initialized)
1286                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1287                         return;
1288
1289         MapVote_Start();
1290 }
1291
1292 /*
1293 ============
1294 FindIntermission
1295
1296 Returns the entity to view from
1297 ============
1298 */
1299 /*
1300 entity FindIntermission()
1301 {
1302         local   entity spot;
1303         local   float cyc;
1304
1305 // look for info_intermission first
1306         spot = find (world, classname, "info_intermission");
1307         if (spot)
1308         {       // pick a random one
1309                 cyc = random() * 4;
1310                 while (cyc > 1)
1311                 {
1312                         spot = find (spot, classname, "info_intermission");
1313                         if (!spot)
1314                                 spot = find (spot, classname, "info_intermission");
1315                         cyc = cyc - 1;
1316                 }
1317                 return spot;
1318         }
1319
1320 // then look for the start position
1321         spot = find (world, classname, "info_player_start");
1322         if (spot)
1323                 return spot;
1324
1325 // testinfo_player_start is only found in regioned levels
1326         spot = find (world, classname, "testplayerstart");
1327         if (spot)
1328                 return spot;
1329
1330 // then look for the start position
1331         spot = find (world, classname, "info_player_deathmatch");
1332         if (spot)
1333                 return spot;
1334
1335         //objerror ("FindIntermission: no spot");
1336         return world;
1337 }
1338 */
1339
1340 /*
1341 ===============================================================================
1342
1343 RULES
1344
1345 ===============================================================================
1346 */
1347
1348 void DumpStats(float final)
1349 {
1350         float file;
1351         string s;
1352         float to_console;
1353         float to_eventlog;
1354         float to_file;
1355         float i;
1356
1357         to_console = autocvar_sv_logscores_console;
1358         to_eventlog = autocvar_sv_eventlog;
1359         to_file = autocvar_sv_logscores_file;
1360
1361         if(!final)
1362         {
1363                 to_console = true; // always print printstats replies
1364                 to_eventlog = false; // but never print them to the event log
1365         }
1366
1367         if(to_eventlog)
1368                 if(autocvar_sv_eventlog_console)
1369                         to_console = false; // otherwise we get the output twice
1370
1371         if(final)
1372                 s = ":scores:";
1373         else
1374                 s = ":status:";
1375         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1376
1377         if(to_console)
1378                 LOG_INFO(s, "\n");
1379         if(to_eventlog)
1380                 GameLogEcho(s);
1381
1382         file = -1;
1383         if(to_file)
1384         {
1385                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1386                 if(file == -1)
1387                         to_file = false;
1388                 else
1389                         fputs(file, strcat(s, "\n"));
1390         }
1391
1392         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1393         if(to_console)
1394                 LOG_INFO(s, "\n");
1395         if(to_eventlog)
1396                 GameLogEcho(s);
1397         if(to_file)
1398                 fputs(file, strcat(s, "\n"));
1399
1400         FOREACH_CLIENT(IS_REAL_CLIENT(it) || (IS_BOT_CLIENT(it) && autocvar_sv_logscores_bots), LAMBDA(
1401                 s = strcat(":player:see-labels:", GetPlayerScoreString(it, 0), ":");
1402                 s = strcat(s, ftos(rint(time - it.jointime)), ":");
1403                 if(IS_PLAYER(it) || MUTATOR_CALLHOOK(GetPlayerStatus, it, s))
1404                         s = strcat(s, ftos(it.team), ":");
1405                 else
1406                         s = strcat(s, "spectator:");
1407
1408                 if(to_console)
1409                         LOG_INFO(s, it.netname, "\n");
1410                 if(to_eventlog)
1411                         GameLogEcho(strcat(s, ftos(it.playerid), ":", it.netname));
1412                 if(to_file)
1413                         fputs(file, strcat(s, it.netname, "\n"));
1414         ));
1415
1416         if(teamplay)
1417         {
1418                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1419                 if(to_console)
1420                         LOG_INFO(s, "\n");
1421                 if(to_eventlog)
1422                         GameLogEcho(s);
1423                 if(to_file)
1424                         fputs(file, strcat(s, "\n"));
1425
1426                 for(i = 1; i < 16; ++i)
1427                 {
1428                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1429                         s = strcat(s, ":", ftos(i));
1430                         if(to_console)
1431                                 LOG_INFO(s, "\n");
1432                         if(to_eventlog)
1433                                 GameLogEcho(s);
1434                         if(to_file)
1435                                 fputs(file, strcat(s, "\n"));
1436                 }
1437         }
1438
1439         if(to_console)
1440                 LOG_INFO(":end\n");
1441         if(to_eventlog)
1442                 GameLogEcho(":end");
1443         if(to_file)
1444         {
1445                 fputs(file, ":end\n");
1446                 fclose(file);
1447         }
1448 }
1449
1450 void FixIntermissionClient(entity e)
1451 {
1452         if(!e.autoscreenshot) // initial call
1453         {
1454                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1455                 e.health = -2342;
1456                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1457                 e.solid = SOLID_NOT;
1458                 e.movetype = MOVETYPE_NONE;
1459                 e.takedamage = DAMAGE_NO;
1460                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1461                 {
1462                     .entity weaponentity = weaponentities[slot];
1463                         if(e.(weaponentity))
1464                         {
1465                                 e.(weaponentity).effects = EF_NODRAW;
1466                                 if (e.(weaponentity).weaponchild)
1467                                         e.(weaponentity).weaponchild.effects = EF_NODRAW;
1468                         }
1469                 }
1470                 if(IS_REAL_CLIENT(e))
1471                 {
1472                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1473                         RandomSelection_Init();
1474                         FOREACH_WORD(autocvar_sv_intermission_cdtrack, true, LAMBDA(
1475                                 RandomSelection_Add(NULL, 0, it, 1, 1);
1476                         ));
1477                         if (RandomSelection_chosen_string != "")
1478                         {
1479                                 stuffcmd(e, sprintf("\ncd loop %s\n", RandomSelection_chosen_string));
1480                         }
1481                         msg_entity = e;
1482                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1483                 }
1484         }
1485 }
1486
1487 /*
1488 go to the next level for deathmatch
1489 only called if a time or frag limit has expired
1490 */
1491 void NextLevel()
1492 {
1493         gameover = true;
1494
1495         intermission_running = 1;
1496
1497 // enforce a wait time before allowing changelevel
1498         if(player_count > 0)
1499                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1500         else
1501                 intermission_exittime = -1;
1502
1503         /*
1504         WriteByte (MSG_ALL, SVC_CDTRACK);
1505         WriteByte (MSG_ALL, 3);
1506         WriteByte (MSG_ALL, 3);
1507         // done in FixIntermission
1508         */
1509
1510         //pos = FindIntermission ();
1511
1512         VoteReset();
1513
1514         DumpStats(true);
1515
1516         // send statistics
1517         PlayerStats_GameReport(true);
1518         WeaponStats_Shutdown();
1519
1520         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1521
1522         if(autocvar_sv_eventlog)
1523                 GameLogEcho(":gameover");
1524
1525         GameLogClose();
1526
1527         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
1528                 FixIntermissionClient(it);
1529                 if(it.winning)
1530                         bprint(it.netname, " ^7wins.\n");
1531         ));
1532
1533         entity oldself = self;
1534         target_music_kill();
1535         self = oldself;
1536
1537         if(autocvar_g_campaign)
1538                 CampaignPreIntermission();
1539
1540         MUTATOR_CALLHOOK(MatchEnd);
1541
1542         localcmd("\nsv_hook_gameend\n");
1543 }
1544
1545 /*
1546 ============
1547 CheckRules_Player
1548
1549 Exit deathmatch games upon conditions
1550 ============
1551 */
1552 void CheckRules_Player()
1553 {SELFPARAM();
1554         if (gameover)   // someone else quit the game already
1555                 return;
1556
1557         if(!IS_DEAD(self))
1558                 self.play_time += frametime;
1559
1560         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1561         //   (div0: and that in CheckRules_World please)
1562 }
1563
1564
1565 float InitiateSuddenDeath()
1566 {
1567         // Check first whether normal overtimes could be added before initiating suddendeath mode
1568         // - for this timelimit_overtime needs to be >0 of course
1569         // - also check the winning condition calculated in the previous frame and only add normal overtime
1570         //   again, if at the point at which timelimit would be extended again, still no winner was found
1571         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1572         {
1573                 return 1; // need to call InitiateOvertime later
1574         }
1575         else
1576         {
1577                 if(!checkrules_suddendeathend)
1578                 {
1579                         if(autocvar_g_campaign)
1580                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1581                         else
1582                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1583                         if(g_race && !g_race_qualifying)
1584                                 race_StartCompleting();
1585                 }
1586                 return 0;
1587         }
1588 }
1589
1590 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1591 {
1592         ++checkrules_overtimesadded;
1593         //add one more overtime by simply extending the timelimit
1594         float tl;
1595         tl = autocvar_timelimit;
1596         tl += autocvar_timelimit_overtime;
1597         cvar_set("timelimit", ftos(tl));
1598
1599         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1600 }
1601
1602 float GetWinningCode(float fraglimitreached, float equality)
1603 {
1604         if(autocvar_g_campaign == 1)
1605                 if(fraglimitreached)
1606                         return WINNING_YES;
1607                 else
1608                         return WINNING_NO;
1609
1610         else
1611                 if(equality)
1612                         if(fraglimitreached)
1613                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1614                         else
1615                                 return WINNING_NEVER;
1616                 else
1617                         if(fraglimitreached)
1618                                 return WINNING_YES;
1619                         else
1620                                 return WINNING_NO;
1621 }
1622
1623 // set the .winning flag for exactly those players with a given field value
1624 void SetWinners(.float field, float value)
1625 {
1626         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(it.winning = (it.(field) == value)));
1627 }
1628
1629 // set the .winning flag for those players with a given field value
1630 void AddWinners(.float field, float value)
1631 {
1632         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
1633                 if(it.(field) == value)
1634                         it.winning = 1;
1635         ));
1636 }
1637
1638 // clear the .winning flags
1639 void ClearWinners()
1640 {
1641         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(it.winning = 0));
1642 }
1643
1644 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1645 // they win. Otherwise the defending team wins once the timelimit passes.
1646 void assault_new_round();
1647 float WinningCondition_Assault()
1648 {SELFPARAM();
1649         float status;
1650
1651         WinningConditionHelper(); // set worldstatus
1652
1653         status = WINNING_NO;
1654         // as the timelimit has not yet passed just assume the defending team will win
1655         if(assault_attacker_team == NUM_TEAM_1)
1656         {
1657                 SetWinners(team, NUM_TEAM_2);
1658         }
1659         else
1660         {
1661                 SetWinners(team, NUM_TEAM_1);
1662         }
1663
1664         entity ent;
1665         ent = find(world, classname, "target_assault_roundend");
1666         if(ent)
1667         {
1668                 if(ent.winning) // round end has been triggered by attacking team
1669                 {
1670                         bprint("ASSAULT: round completed...\n");
1671                         SetWinners(team, assault_attacker_team);
1672
1673                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1674
1675                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1676                         {
1677                                 status = WINNING_YES;
1678                         }
1679                         else
1680                         {
1681                                 WITH(entity, self, ent, assault_new_round());
1682                         }
1683                 }
1684         }
1685
1686         return status;
1687 }
1688
1689 void ShuffleMaplist()
1690 {
1691         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1692 }
1693
1694 float leaderfrags;
1695 float WinningCondition_Scores(float limit, float leadlimit)
1696 {
1697         float limitreached;
1698
1699         // TODO make everything use THIS winning condition (except LMS)
1700         WinningConditionHelper();
1701
1702         if(teamplay)
1703         {
1704                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1705                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1706                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1707                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1708         }
1709
1710         ClearWinners();
1711         if(WinningConditionHelper_winner)
1712                 WinningConditionHelper_winner.winning = 1;
1713         if(WinningConditionHelper_winnerteam >= 0)
1714                 SetWinners(team, WinningConditionHelper_winnerteam);
1715
1716         if(WinningConditionHelper_lowerisbetter)
1717         {
1718                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1719                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1720                 limit = -limit;
1721         }
1722
1723         if(WinningConditionHelper_zeroisworst)
1724                 leadlimit = 0; // not supported in this mode
1725
1726         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1727         // these modes always score in increments of 1, thus this makes sense
1728         {
1729                 if(leaderfrags != WinningConditionHelper_topscore)
1730                 {
1731                         leaderfrags = WinningConditionHelper_topscore;
1732
1733                         if (limit)
1734                         if (leaderfrags == limit - 1)
1735                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1736                         else if (leaderfrags == limit - 2)
1737                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1738                         else if (leaderfrags == limit - 3)
1739                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1740                 }
1741         }
1742
1743         limitreached = false;
1744         if(limit)
1745                 if(WinningConditionHelper_topscore >= limit)
1746                         limitreached = true;
1747         if(leadlimit)
1748         {
1749                 float leadlimitreached;
1750                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1751                 if(autocvar_leadlimit_and_fraglimit)
1752                         limitreached = (limitreached && leadlimitreached);
1753                 else
1754                         limitreached = (limitreached || leadlimitreached);
1755         }
1756
1757         if(limit)
1758                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1759
1760         return GetWinningCode(
1761                 WinningConditionHelper_topscore && limitreached,
1762                 WinningConditionHelper_equality
1763         );
1764 }
1765
1766 float WinningCondition_RanOutOfSpawns()
1767 {
1768         if(have_team_spawns <= 0)
1769                 return WINNING_NO;
1770
1771         if(!autocvar_g_spawn_useallspawns)
1772                 return WINNING_NO;
1773
1774         if(!some_spawn_has_been_used)
1775                 return WINNING_NO;
1776
1777         team1_score = team2_score = team3_score = team4_score = 0;
1778
1779         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it), LAMBDA(
1780                 switch(it.team)
1781                 {
1782                         case NUM_TEAM_1: team1_score = 1; break;
1783                         case NUM_TEAM_2: team2_score = 1; break;
1784                         case NUM_TEAM_3: team3_score = 1; break;
1785                         case NUM_TEAM_4: team4_score = 1; break;
1786                 }
1787         ));
1788
1789         FOREACH_ENTITY_CLASS("info_player_deathmatch", true, LAMBDA(
1790                 switch(it.team)
1791                 {
1792                         case NUM_TEAM_1: team1_score = 1; break;
1793                         case NUM_TEAM_2: team2_score = 1; break;
1794                         case NUM_TEAM_3: team3_score = 1; break;
1795                         case NUM_TEAM_4: team4_score = 1; break;
1796                 }
1797         ));
1798
1799         ClearWinners();
1800         if(team1_score + team2_score + team3_score + team4_score == 0)
1801         {
1802                 checkrules_equality = true;
1803                 return WINNING_YES;
1804         }
1805         else if(team1_score + team2_score + team3_score + team4_score == 1)
1806         {
1807                 float t, i;
1808                 if(team1_score)
1809                         t = NUM_TEAM_1;
1810                 else if(team2_score)
1811                         t = NUM_TEAM_2;
1812                 else if(team3_score)
1813                         t = NUM_TEAM_3;
1814                 else // if(team4_score)
1815                         t = NUM_TEAM_4;
1816                 CheckAllowedTeams(world);
1817                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1818                 {
1819                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
1820                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
1821                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
1822                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
1823                 }
1824
1825                 AddWinners(team, t);
1826                 return WINNING_YES;
1827         }
1828         else
1829                 return WINNING_NO;
1830 }
1831
1832 /*
1833 ============
1834 CheckRules_World
1835
1836 Exit deathmatch games upon conditions
1837 ============
1838 */
1839 void CheckRules_World()
1840 {
1841         float timelimit;
1842         float fraglimit;
1843         float leadlimit;
1844
1845         VoteThink();
1846         MapVote_Think();
1847
1848         SetDefaultAlpha();
1849
1850         if (gameover)   // someone else quit the game already
1851         {
1852                 if(player_count == 0) // Nobody there? Then let's go to the next map
1853                         MapVote_Start();
1854                         // this will actually check the player count in the next frame
1855                         // again, but this shouldn't hurt
1856                 return;
1857         }
1858
1859         timelimit = autocvar_timelimit * 60;
1860         fraglimit = autocvar_fraglimit;
1861         leadlimit = autocvar_leadlimit;
1862
1863         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1864         {
1865                 if(timelimit > 0)
1866                         timelimit = 0; // timelimit is not made for warmup
1867                 if(fraglimit > 0)
1868                         fraglimit = 0; // no fraglimit for now
1869                 leadlimit = 0; // no leadlimit for now
1870         }
1871
1872         if(timelimit > 0)
1873         {
1874                 timelimit += game_starttime;
1875         }
1876         else if (timelimit < 0)
1877         {
1878                 // endmatch
1879                 NextLevel();
1880                 return;
1881         }
1882
1883         float wantovertime;
1884         wantovertime = 0;
1885
1886         if(timelimit > game_starttime)
1887                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
1888         else
1889                 game_completion_ratio = 0;
1890
1891         if(checkrules_suddendeathend)
1892         {
1893                 if(!checkrules_suddendeathwarning)
1894                 {
1895                         checkrules_suddendeathwarning = true;
1896                         if(g_race && !g_race_qualifying)
1897                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
1898                         else
1899                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
1900                 }
1901         }
1902         else
1903         {
1904                 if (timelimit && time >= timelimit)
1905                 {
1906                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1907                         {
1908                                 float totalplayers;
1909                                 float playerswithlaps;
1910                                 float readyplayers;
1911                                 totalplayers = playerswithlaps = readyplayers = 0;
1912                                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
1913                                         ++totalplayers;
1914                                         if(PlayerScore_Add(it, SP_RACE_FASTEST, 0))
1915                                                 ++playerswithlaps;
1916                                         if(it.ready)
1917                                                 ++readyplayers;
1918                                 ));
1919
1920                                 // at least 2 of the players have completed a lap: start the RACE
1921                                 // otherwise, the players should end the qualifying on their own
1922                                 if(readyplayers || playerswithlaps >= 2)
1923                                 {
1924                                         checkrules_suddendeathend = 0;
1925                                         ReadyRestart(); // go to race
1926                                         return;
1927                                 }
1928                                 else
1929                                         wantovertime |= InitiateSuddenDeath();
1930                         }
1931                         else
1932                                 wantovertime |= InitiateSuddenDeath();
1933                 }
1934         }
1935
1936         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1937         {
1938                 NextLevel();
1939                 return;
1940         }
1941
1942         int checkrules_status = WinningCondition_RanOutOfSpawns();
1943         if(checkrules_status == WINNING_YES)
1944                 bprint("Hey! Someone ran out of spawns!\n");
1945         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
1946                 checkrules_status = ret_float;
1947         else
1948                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1949
1950         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1951         {
1952                 checkrules_status = WINNING_NEVER;
1953                 checkrules_overtimesadded = -1;
1954                 wantovertime |= InitiateSuddenDeath();
1955         }
1956
1957         if(checkrules_status == WINNING_NEVER)
1958                 // equality cases! Nobody wins if the overtime ends in a draw.
1959                 ClearWinners();
1960
1961         if(wantovertime)
1962         {
1963                 if(checkrules_status == WINNING_NEVER)
1964                         InitiateOvertime();
1965                 else
1966                         checkrules_status = WINNING_YES;
1967         }
1968
1969         if(checkrules_suddendeathend)
1970                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1971                         checkrules_status = WINNING_YES;
1972
1973         if(checkrules_status == WINNING_YES)
1974         {
1975                 //print("WINNING\n");
1976                 NextLevel();
1977         }
1978 }
1979
1980 string GotoMap(string m)
1981 {
1982         m = GameTypeVote_MapInfo_FixName(m);
1983         if (!m)
1984                 return "The map you suggested is not available on this server.";
1985         if (!autocvar_sv_vote_gametype)
1986         if(!MapInfo_CheckMap(m))
1987                 return "The map you suggested does not support the current game mode.";
1988         cvar_set("nextmap", m);
1989         cvar_set("timelimit", "-1");
1990         if(mapvote_initialized || alreadychangedlevel)
1991         {
1992                 if(DoNextMapOverride(0))
1993                         return "Map switch initiated.";
1994                 else
1995                         return "Hm... no. For some reason I like THIS map more.";
1996         }
1997         else
1998                 return "Map switch will happen after scoreboard.";
1999 }
2000
2001
2002 void EndFrame()
2003 {SELFPARAM();
2004         anticheat_endframe();
2005
2006         float altime;
2007         FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(
2008                 entity e = IS_SPEC(it) ? it.enemy : it;
2009                 if(e.typehitsound)
2010                         it.typehit_time = time;
2011                 else if(e.damage_dealt)
2012                 {
2013                         it.hit_time = time;
2014                         it.damage_dealt_total += ceil(e.damage_dealt);
2015                 }
2016         ));
2017         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2018         // add 1 frametime because after this, engine SV_Physics
2019         // increases time by a frametime and then networks the frame
2020         // add another frametime because client shows everything with
2021         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2022         // needed!
2023         FOREACH_CLIENT(true, LAMBDA(
2024                 it.typehitsound = false;
2025                 it.damage_dealt = 0;
2026                 setself(it);
2027                 antilag_record(it, altime);
2028         ));
2029         FOREACH_ENTITY_FLAGS(flags, FL_MONSTER, LAMBDA(
2030                 setself(it);
2031                 antilag_record(it, altime);
2032         ));
2033         FOREACH_CLIENT(PS(it), LAMBDA(
2034                 PlayerState s = PS(it);
2035                 s.ps_push(s, it);
2036         ));
2037 }
2038
2039
2040 /*
2041  * RedirectionThink:
2042  * returns true if redirecting
2043  */
2044 float redirection_timeout;
2045 float redirection_nextthink;
2046 float RedirectionThink()
2047 {SELFPARAM();
2048         float clients_found;
2049
2050         if(redirection_target == "")
2051                 return false;
2052
2053         if(!redirection_timeout)
2054         {
2055                 cvar_set("sv_public", "-2");
2056                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2057                 if(redirection_target == "self")
2058                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2059                 else
2060                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2061         }
2062
2063         if(time < redirection_nextthink)
2064                 return true;
2065
2066         redirection_nextthink = time + 1;
2067
2068         clients_found = 0;
2069         FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(
2070                 setself(it);
2071                 // TODO add timer
2072                 LOG_INFO("Redirecting: sending connect command to ", self.netname, "\n");
2073                 if(redirection_target == "self")
2074                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2075                 else
2076                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2077                 ++clients_found;
2078         ));
2079
2080         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.\n");
2081
2082         if(time > redirection_timeout || clients_found == 0)
2083                 localcmd("\nwait; wait; wait; quit\n");
2084
2085         return true;
2086 }
2087
2088 void TargetMusic_RestoreGame();
2089 void RestoreGame()
2090 {
2091         // Loaded from a save game
2092         // some things then break, so let's work around them...
2093
2094         // Progs DB (capture records)
2095         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2096
2097         // Mapinfo
2098         MapInfo_Shutdown();
2099         MapInfo_Enumerate();
2100         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2101         WeaponStats_Init();
2102
2103         TargetMusic_RestoreGame();
2104 }
2105
2106 void Shutdown()
2107 {
2108         gameover = 2;
2109
2110         if(world_initialized > 0)
2111         {
2112                 world_initialized = 0;
2113                 LOG_TRACE("Saving persistent data...\n");
2114                 Ban_SaveBans();
2115
2116                 // playerstats with unfinished match
2117                 PlayerStats_GameReport(false);
2118
2119                 if(!cheatcount_total)
2120                 {
2121                         if(autocvar_sv_db_saveasdump)
2122                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2123                         else
2124                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2125                 }
2126                 if(autocvar_developer)
2127                 {
2128                         if(autocvar_sv_db_saveasdump)
2129                                 db_dump(TemporaryDB, "server-temp.db");
2130                         else
2131                                 db_save(TemporaryDB, "server-temp.db");
2132                 }
2133                 CheatShutdown(); // must be after cheatcount check
2134                 db_close(ServerProgsDB);
2135                 db_close(TemporaryDB);
2136                 LOG_TRACE("Saving persistent data... done!\n");
2137                 // tell the bot system the game is ending now
2138                 bot_endgame();
2139
2140                 WeaponStats_Shutdown();
2141                 MapInfo_Shutdown();
2142         }
2143         else if(world_initialized == 0)
2144         {
2145                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data\n");
2146         }
2147         else
2148         {
2149                 __init_dedicated_server_shutdown();
2150         }
2151 }