qcsrc/server/g_world.qc

   1 entity pingplreport;
   2 void PingPLReport_Think()
   3 {
   4         float delta;
   5         entity e;
   6
   7         delta = 3 / maxclients;
   8         if(delta < sys_frametime)
   9                 delta = 0;
  10         self.nextthink = time + delta;
  11
  12         e = edict_num(self.cnt + 1);
  13         if(clienttype(e) == CLIENTTYPE_REAL)
  14         {
  15                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  16                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  17                 WriteByte(MSG_BROADCAST, self.cnt);
  18                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  19                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  20                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  21         }
  22         else
  23         {
  24                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  25                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  26                 WriteByte(MSG_BROADCAST, self.cnt);
  27                 WriteShort(MSG_BROADCAST, 0);
  28                 WriteByte(MSG_BROADCAST, 0);
  29                 WriteByte(MSG_BROADCAST, 0);
  30         }
  31         self.cnt = mod(self.cnt + 1, maxclients);
  32 }
  33 void PingPLReport_Spawn()
  34 {
  35         pingplreport = spawn();
  36         pingplreport.classname = "pingplreport";
  37         pingplreport.think = PingPLReport_Think;
  38         pingplreport.nextthink = time;
  39 }
  40
  41 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  42 string redirection_target;
  43 float world_initialized;
  44
  45 string GetMapname();
  46 string GetGametype();
  47 void GotoNextMap(float reinit);
  48 void ShuffleMaplist()
  49 float(float reinit) DoNextMapOverride;
  50
  51 void SetDefaultAlpha()
  52 {
  53         if(autocvar_g_running_guns)
  54         {
  55                 default_player_alpha = -1;
  56                 default_weapon_alpha = +1;
  57         }
  58         else if(g_cloaked)
  59         {
  60                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  61                 default_weapon_alpha = default_player_alpha;
  62         }
  63         else
  64         {
  65                 default_player_alpha = autocvar_g_player_alpha;
  66                 if(default_player_alpha == 0)
  67                         default_player_alpha = 1;
  68                 default_weapon_alpha = default_player_alpha;
  69         }
  70 }
  71
  72 void fteqcc_testbugs()
  73 {
  74         float a, b;
  75
  76         if(!autocvar_developer_fteqccbugs)
  77                 return;
  78
  79         dprint("*** fteqcc test: checking for bugs...\n");
  80
  81         a = 1;
  82         b = 5;
  83         if(sqrt(a) - sqrt(b - a) == 0)
  84                 dprint("*** fteqcc test: found same-function-twice bug\n");
  85         else
  86                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  87
  88         world.cnt = -10;
  89         world.enemy = world;
  90         world.enemy.cnt += 10;
  91         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  92                 dprint("*** fteqcc test: found += bug\n");
  93         else
  94                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  95         world.cnt = 0;
  96 }
  97
  98 void GotoFirstMap()
  99 {
 100         float n;
 101         if(autocvar__sv_init)
 102         {
 103                 // cvar_set("_sv_init", "0");
 104                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 105                 // to this "init" map on a dedicated server will cause no permanent
 106                 // harm
 107                 if(autocvar_g_maplist_shuffle)
 108                         ShuffleMaplist();
 109                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 110                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 111
 112                 MapInfo_Enumerate();
 113                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 114
 115                 if(!DoNextMapOverride(1))
 116                         GotoNextMap(1);
 117
 118                 return;
 119         }
 120
 121         if(time < 5)
 122         {
 123                 self.nextthink = time;
 124         }
 125         else
 126         {
 127                 self.nextthink = time + 1;
 128                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 129         }
 130 }
 131
 132 void cvar_changes_init()
 133 {
 134         float h;
 135         string k, v, d;
 136         float n, i, adding, pureadding;
 137
 138         if(cvar_changes)
 139                 strunzone(cvar_changes);
 140         cvar_changes = string_null;
 141         if(cvar_purechanges)
 142                 strunzone(cvar_purechanges);
 143         cvar_purechanges = string_null;
 144         cvar_purechanges_count = 0;
 145
 146         h = buf_create();
 147         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 148         n = buf_getsize(h);
 149
 150         adding = TRUE;
 151         pureadding = TRUE;
 152
 153         for(i = 0; i < n; ++i)
 154         {
 155                 k = bufstr_get(h, i);
 156
 157 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 158 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 159 #define BADCVAR(p) if(k == p) continue
 160
 161                 // general excludes and namespaces for server admin used cvars
 162                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 163
 164                 // internal
 165                 BADPREFIX("csqc_");
 166                 BADPREFIX("cvar_check_");
 167                 BADCVAR("gamecfg");
 168                 BADCVAR("g_configversion");
 169                 BADCVAR("g_maplist_index");
 170                 BADCVAR("halflifebsp");
 171                 BADPREFIX("sv_world");
 172
 173                 // client
 174                 BADPREFIX("chase_");
 175                 BADPREFIX("cl_");
 176                 BADPREFIX("con_");
 177                 BADPREFIX("scoreboard_");
 178                 BADPREFIX("g_campaign");
 179                 BADPREFIX("g_waypointsprite_");
 180                 BADPREFIX("gl_");
 181                 BADPREFIX("joy");
 182                 BADPREFIX("hud_");
 183                 BADPREFIX("m_");
 184                 BADPREFIX("menu_");
 185                 BADPREFIX("net_slist_");
 186                 BADPREFIX("r_");
 187                 BADPREFIX("sbar_");
 188                 BADPREFIX("scr_");
 189                 BADPREFIX("snd_");
 190                 BADPREFIX("show");
 191                 BADPREFIX("sensitivity");
 192                 BADPREFIX("userbind");
 193                 BADPREFIX("v_");
 194                 BADPREFIX("vid_");
 195                 BADPREFIX("crosshair");
 196                 BADCVAR("mod_q3bsp_lightmapmergepower");
 197                 BADCVAR("mod_q3bsp_nolightmaps");
 198                 BADCVAR("fov");
 199                 BADCVAR("mastervolume");
 200                 BADCVAR("volume");
 201                 BADCVAR("bgmvolume");
 202
 203                 // private
 204                 BADCVAR("developer");
 205                 BADCVAR("log_dest_udp");
 206                 BADCVAR("log_file");
 207                 BADCVAR("net_address");
 208                 BADCVAR("net_address_ipv6");
 209                 BADCVAR("port");
 210                 BADCVAR("savedgamecfg");
 211                 BADCVAR("serverconfig");
 212                 BADCVAR("sv_autoscreenshot");
 213                 BADCVAR("sv_heartbeatperiod");
 214                 BADCVAR("sv_vote_master_password");
 215                 BADCVAR("sys_colortranslation");
 216                 BADCVAR("sys_specialcharactertranslation");
 217                 BADCVAR("timeformat");
 218                 BADCVAR("timestamps");
 219                 BADPREFIX("developer_");
 220                 BADPREFIX("g_ban_");
 221                 BADPREFIX("g_banned_list");
 222                 BADPREFIX("g_chat_flood_");
 223                 BADPREFIX("g_ghost_items");
 224                 BADPREFIX("g_playerstats_");
 225                 BADPREFIX("g_respawn_ghosts");
 226                 BADPREFIX("g_voice_flood_");
 227                 BADPREFIX("rcon_");
 228                 BADPREFIX("sv_allowdownloads");
 229                 BADPREFIX("sv_autodemo");
 230                 BADPREFIX("sv_curl_");
 231                 BADPREFIX("sv_eventlog");
 232                 BADPREFIX("sv_logscores_");
 233                 BADPREFIX("sv_master");
 234                 BADPREFIX("sv_weaponstats_");
 235                 BADPREFIX("sv_waypointsprite_");
 236                 BADCVAR("rescan_pending");
 237
 238                 // these can contain player IDs, so better hide
 239                 BADPREFIX("g_forced_team_");
 240
 241                 // mapinfo
 242                 BADCVAR("fraglimit");
 243                 BADCVAR("g_arena");
 244                 BADCVAR("g_assault");
 245                 BADCVAR("g_ca");
 246                 BADCVAR("g_ctf");
 247                 BADCVAR("g_cts");
 248                 BADCVAR("g_dm");
 249                 BADCVAR("g_domination");
 250                 BADCVAR("g_domination_default_teams");
 251                 BADCVAR("g_freezetag");
 252                 BADCVAR("g_keepaway");
 253                 BADCVAR("g_keyhunt");
 254                 BADCVAR("g_keyhunt_teams");
 255                 BADCVAR("g_keyhunt_teams");
 256                 BADCVAR("g_lms");
 257                 BADCVAR("g_nexball");
 258                 BADCVAR("g_onslaught");
 259                 BADCVAR("g_race");
 260                 BADCVAR("g_race_qualifying_timelimit");
 261                 BADCVAR("g_runematch");
 262                 BADCVAR("g_tdm");
 263                 BADCVAR("g_tdm_teams");
 264                 BADCVAR("leadlimit");
 265                 BADCVAR("nextmap");
 266                 BADCVAR("teamplay");
 267                 BADCVAR("timelimit");
 268
 269                 // long
 270                 BADCVAR("hostname");
 271                 BADCVAR("g_maplist");
 272                 BADCVAR("g_maplist_mostrecent");
 273                 BADCVAR("sv_motd");
 274
 275                 v = cvar_string(k);
 276                 d = cvar_defstring(k);
 277                 if(v == d)
 278                         continue;
 279
 280                 if(adding)
 281                 {
 282                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 283                         if(strlen(cvar_changes) > 16384)
 284                         {
 285                                 cvar_changes = "// too many settings have been changed to show them here\n";
 286                                 adding = 0;
 287                         }
 288                 }
 289
 290                 // now check if the changes are actually gameplay relevant
 291
 292                 // does nothing visible
 293                 BADCVAR("captureleadlimit_override");
 294                 BADCVAR("g_arena_point_leadlimit");
 295                 BADCVAR("g_balance_kill_delay");
 296                 BADCVAR("g_ca_point_leadlimit");
 297                 BADCVAR("g_ctf_captimerecord_always");
 298                 BADCVAR("g_ctf_flag_capture_effects");
 299                 BADCVAR("g_ctf_flag_glowtrails");
 300                 BADCVAR("g_ctf_flag_pickup_effects");
 301                 BADCVAR("g_domination_point_leadlimit");
 302                 BADCVAR("g_forced_respawn");
 303                 BADCVAR("g_keyhunt_point_leadlimit");
 304                 BADPREFIX("g_mod_");
 305                 BADCVAR("g_nexball_goalleadlimit");
 306                 BADCVAR("g_runematch_point_leadlimit");
 307                 BADCVAR("leadlimit_and_fraglimit");
 308                 BADCVAR("leadlimit_override");
 309                 BADCVAR("pausable");
 310                 BADCVAR("sv_allow_fullbright");
 311                 BADCVAR("sv_checkforpacketsduringsleep");
 312                 BADCVAR("sv_fraginfo");
 313                 BADCVAR("sv_timeout");
 314                 BADPREFIX("sv_timeout_");
 315                 BADCVAR("welcome_message_time");
 316                 BADPREFIX("crypto_");
 317                 BADPREFIX("g_chat_");
 318                 BADPREFIX("g_ctf_captimerecord_");
 319                 BADPREFIX("g_maplist_votable_");
 320                 BADPREFIX("net_");
 321                 BADPREFIX("prvm_");
 322                 BADPREFIX("skill_");
 323                 BADPREFIX("sv_cullentities_");
 324                 BADPREFIX("sv_fraginfo_");
 325                 BADPREFIX("sv_maxidle_");
 326                 BADPREFIX("sv_vote_");
 327                 BADPREFIX("timelimit_");
 328                 BADCVAR("gameversion");
 329                 BADPREFIX("gameversion_");
 330                 BADCVAR("sv_namechangetimer");
 331 #ifndef NO_LEGACY_NETWORKING
 332                 BADCVAR("sv_use_csqc_players"); // transition
 333 #endif
 334
 335                 // allowed changes to server admins (please sync this to server.cfg)
 336                 // vi commands:
 337                 //   :/"impure"/,$d
 338                 //   :g!,^\/\/[^ /],d
 339                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 340                 //   :%!sort
 341                 // yes, this does contain some redundant stuff, don't really care
 342                 BADCVAR("bot_config_file");
 343                 BADCVAR("bot_number");
 344                 BADCVAR("bot_prefix");
 345                 BADCVAR("bot_suffix");
 346                 BADCVAR("capturelimit_override");
 347                 BADCVAR("fraglimit_override");
 348                 BADCVAR("gametype");
 349                 BADCVAR("g_antilag");
 350                 BADCVAR("g_balance_teams");
 351                 BADCVAR("g_balance_teams_force");
 352                 BADCVAR("g_ban_sync_trusted_servers");
 353                 BADCVAR("g_ban_sync_uri");
 354                 BADCVAR("g_ctf_ignore_frags");
 355                 BADCVAR("g_domination_point_limit");
 356                 BADCVAR("g_friendlyfire");
 357                 BADCVAR("g_fullbrightitems");
 358                 BADCVAR("g_fullbrightplayers");
 359                 BADCVAR("g_keyhunt_point_limit");
 360                 BADCVAR("g_keyhunt_teams_override");
 361                 BADCVAR("g_lms_lives_override");
 362                 BADCVAR("g_maplist");
 363                 BADCVAR("g_maplist_check_waypoints");
 364                 BADCVAR("g_maplist_mostrecent_count");
 365                 BADCVAR("g_maplist_shuffle");
 366                 BADCVAR("g_maplist_votable");
 367                 BADCVAR("g_maplist_votable_abstain");
 368                 BADCVAR("g_maplist_votable_nodetail");
 369                 BADCVAR("g_maplist_votable_suggestions");
 370                 BADCVAR("g_maxplayers");
 371                 BADCVAR("g_minstagib");
 372                 BADCVAR("g_mirrordamage");
 373                 BADCVAR("g_nexball_goallimit");
 374                 BADCVAR("g_powerups");
 375                 BADCVAR("g_runematch_point_limit");
 376                 BADCVAR("g_start_delay");
 377                 BADCVAR("g_warmup");
 378                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 379                 BADCVAR("hostname");
 380                 BADCVAR("log_file");
 381                 BADCVAR("maxplayers");
 382                 BADCVAR("minplayers");
 383                 BADCVAR("net_address");
 384                 BADCVAR("port");
 385                 BADCVAR("rcon_password");
 386                 BADCVAR("rcon_restricted_commands");
 387                 BADCVAR("rcon_restricted_password");
 388                 BADCVAR("skill");
 389                 BADCVAR("sv_adminnick");
 390                 BADCVAR("sv_autoscreenshot");
 391                 BADCVAR("sv_autotaunt");
 392                 BADCVAR("sv_curl_defaulturl");
 393                 BADCVAR("sv_defaultcharacter");
 394                 BADCVAR("sv_defaultplayercolors");
 395                 BADCVAR("sv_defaultplayermodel");
 396                 BADCVAR("sv_defaultplayerskin");
 397                 BADCVAR("sv_maxidle");
 398                 BADCVAR("sv_maxrate");
 399                 BADCVAR("sv_motd");
 400                 BADCVAR("sv_public");
 401                 BADCVAR("sv_ready_restart");
 402                 BADCVAR("sv_status_privacy");
 403                 BADCVAR("sv_taunt");
 404                 BADCVAR("sv_vote_call");
 405                 BADCVAR("sv_vote_commands");
 406                 BADCVAR("sv_vote_majority_factor");
 407                 BADCVAR("sv_vote_master");
 408                 BADCVAR("sv_vote_master_commands");
 409                 BADCVAR("sv_vote_master_password");
 410                 BADCVAR("sv_vote_simple_majority_factor");
 411                 BADCVAR("sys_ticrate");
 412                 BADCVAR("teamplay_mode");
 413                 BADCVAR("timelimit_override");
 414                 BADCVAR("g_spawnshieldtime");
 415                 BADPREFIX("g_warmup_");
 416                 BADPREFIX("sv_ready_restart_");
 417
 418                 if(autocvar_g_minstagib)
 419                 {
 420                         BADCVAR("g_grappling_hook");
 421                         BADCVAR("g_jetpack");
 422                 }
 423 #undef BADPREFIX
 424 #undef BADCVAR
 425
 426                 if(pureadding)
 427                 {
 428                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 429                         if(strlen(cvar_purechanges) > 16384)
 430                         {
 431                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 432                                 pureadding = 0;
 433                         }
 434                 }
 435                 ++cvar_purechanges_count;
 436                 // WARNING: this variable is used for the server list
 437                 // NEVER dare to skip this code!
 438                 // Hacks to intentionally appearing as "pure server" even though you DO have
 439                 // modified settings may be punished by removal from the server list.
 440                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 441                 // though.
 442         }
 443         buf_del(h);
 444         if(cvar_changes == "")
 445                 cvar_changes = "// this server runs at default server settings\n";
 446         else
 447                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 448         cvar_changes = strzone(cvar_changes);
 449         if(cvar_purechanges == "")
 450                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 451         else
 452                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 453         cvar_purechanges = strzone(cvar_purechanges);
 454 }
 455
 456 void detect_maptype()
 457 {
 458 #if 0
 459         vector o, v;
 460         float i;
 461
 462         for(;;)
 463         {
 464                 o = world.mins;
 465                 o_x += random() * (world.maxs_x - world.mins_x);
 466                 o_y += random() * (world.maxs_y - world.mins_y);
 467                 o_z += random() * (world.maxs_z - world.mins_z);
 468
 469                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 470                 if(trace_fraction == 1)
 471                         continue;
 472
 473                 v = trace_endpos;
 474
 475                 for(i = 0; i < 64; i += 4)
 476                 {
 477                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 478         if(trace_fraction == 1)
 479                 continue;
 480                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 481                 }
 482
 483                 break;
 484         }
 485 #endif
 486 }
 487
 488 entity randomseed;
 489 float RandomSeed_Send(entity to, float sf)
 490 {
 491         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 492         WriteShort(MSG_ENTITY, self.cnt);
 493         return TRUE;
 494 }
 495 void RandomSeed_Think()
 496 {
 497         self.cnt = bound(0, floor(random() * 65536), 65535);
 498         self.nextthink = time + 5;
 499
 500         self.SendFlags |= 1;
 501 }
 502 void RandomSeed_Spawn()
 503 {
 504         randomseed = spawn();
 505         randomseed.think = RandomSeed_Think;
 506         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 507
 508         entity oldself;
 509         oldself = self;
 510         self = randomseed;
 511         self.think(); // sets random seed and nextthink
 512         self = oldself;
 513 }
 514
 515 void spawnfunc___init_dedicated_server(void)
 516 {
 517         // handler for _init/_init map (only for dedicated server initialization)
 518
 519         world_initialized = -1; // don't complain
 520         cvar = cvar_normal;
 521         cvar_string = cvar_string_normal;
 522         cvar_set = cvar_set_normal;
 523
 524         remove = remove_unsafely;
 525
 526         entity e;
 527         e = spawn();
 528         e.think = GotoFirstMap;
 529         e.nextthink = time; // this is usually 1 at this point
 530
 531         e = spawn();
 532         e.classname = "info_player_deathmatch"; // safeguard against player joining
 533
 534         self.classname = "worldspawn"; // safeguard against various stuff ;)
 535
 536         // needs to be done so early because of the constants they create
 537         RegisterWeapons();
 538         RegisterGametypes();
 539
 540         MapInfo_Enumerate();
 541         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 542 }
 543
 544 void Map_MarkAsRecent(string m);
 545 float world_already_spawned;
 546 void RegisterWeapons();
 547 void Nagger_Init();
 548 void ClientInit_Spawn();
 549 void WeaponStats_Init();
 550 void WeaponStats_Shutdown();
 551 void spawnfunc_worldspawn (void)
 552 {
 553         float fd, l, i, j, n;
 554         string s, col;
 555
 556         cvar = cvar_normal;
 557         cvar_string = cvar_string_normal;
 558         cvar_set = cvar_set_normal;
 559
 560         if(world_already_spawned)
 561                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 562         world_already_spawned = TRUE;
 563
 564         remove = remove_safely; // during spawning, watch what you remove!
 565
 566         check_unacceptable_compiler_bugs();
 567
 568         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 569
 570         compressShortVector_init();
 571
 572         allowed_to_spawn = TRUE;
 573
 574         entity head;
 575         head = nextent(world);
 576         maxclients = 0;
 577         while(head)
 578         {
 579                 ++maxclients;
 580                 head = nextent(head);
 581         }
 582
 583         // needs to be done so early because of the constants they create
 584         RegisterWeapons();
 585         RegisterGametypes();
 586
 587         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 588
 589         TemporaryDB = db_create();
 590
 591         // 0 normal
 592         lightstyle(0, "m");
 593
 594         // 1 FLICKER (first variety)
 595         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 596
 597         // 2 SLOW STRONG PULSE
 598         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 599
 600         // 3 CANDLE (first variety)
 601         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 602
 603         // 4 FAST STROBE
 604         lightstyle(4, "mamamamamama");
 605
 606         // 5 GENTLE PULSE 1
 607         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 608
 609         // 6 FLICKER (second variety)
 610         lightstyle(6, "nmonqnmomnmomomno");
 611
 612         // 7 CANDLE (second variety)
 613         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 614
 615         // 8 CANDLE (third variety)
 616         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 617
 618         // 9 SLOW STROBE (fourth variety)
 619         lightstyle(9, "aaaaaaaazzzzzzzz");
 620
 621         // 10 FLUORESCENT FLICKER
 622         lightstyle(10, "mmamammmmammamamaaamammma");
 623
 624         // 11 SLOW PULSE NOT FADE TO BLACK
 625         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 626
 627         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 628
 629         // 63 testing
 630         lightstyle(63, "a");
 631
 632         if(autocvar_g_campaign)
 633                 CampaignPreInit();
 634
 635         Map_MarkAsRecent(mapname);
 636
 637         precache_model ("null"); // we need this one before InitGameplayMode
 638         InitGameplayMode();
 639         readlevelcvars();
 640         GrappleHookInit();
 641         ElectroInit();
 642         LaserInit();
 643
 644         player_count = 0;
 645         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 646         if(bot_waypoints_for_items == 1)
 647                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 648                         bot_waypoints_for_items = 0;
 649
 650         precache();
 651
 652         WaypointSprite_Init();
 653
 654         //if (g_domination)
 655         //      dom_init();
 656
 657         GameLogInit(); // prepare everything
 658         // NOTE for matchid:
 659         // changing the logic generating it is okay. But:
 660         // it HAS to stay <= 64 chars
 661         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 662         if(autocvar_sv_eventlog)
 663         {
 664                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 665                 matchid = strzone(s);
 666
 667                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 668                 s = ":gameinfo:mutators:LIST";
 669
 670                 ret_string = s;
 671                 MUTATOR_CALLHOOK(BuildMutatorsString);
 672                 s = ret_string;
 673
 674                 // simple, probably not good in the mutator system
 675                 if(autocvar_g_grappling_hook)
 676                         s = strcat(s, ":grappling_hook");
 677
 678                 // initialiation stuff, not good in the mutator system
 679                 if(!autocvar_g_use_ammunition)
 680                         s = strcat(s, ":no_use_ammunition");
 681
 682                 // initialiation stuff, not good in the mutator system
 683                 if(autocvar_g_pickup_items == 0)
 684                         s = strcat(s, ":no_pickup_items");
 685                 if(autocvar_g_pickup_items > 0)
 686                         s = strcat(s, ":pickup_items");
 687
 688                 // initialiation stuff, not good in the mutator system
 689                 if(autocvar_g_weaponarena != "0")
 690                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 691
 692                 // TODO to mutator system
 693                 if(autocvar_g_norecoil)
 694                         s = strcat(s, ":norecoil");
 695
 696                 // TODO to mutator system
 697                 if(autocvar_g_midair)
 698                         s = strcat(s, ":midair");
 699
 700                 // TODO to mutator system
 701                 if(autocvar_g_minstagib)
 702                         s = strcat(s, ":minstagib");
 703
 704                 // TODO to mutator system
 705                 if(autocvar_g_powerups == 0)
 706                         s = strcat(s, ":no_powerups");
 707                 if(autocvar_g_powerups > 0)
 708                         s = strcat(s, ":powerups");
 709
 710                 GameLogEcho(s);
 711                 GameLogEcho(":gameinfo:end");
 712         }
 713         else
 714                 matchid = strzone(ftos(random()));
 715
 716         cvar_set("nextmap", "");
 717
 718         SetDefaultAlpha();
 719
 720         if(autocvar_g_campaign)
 721                 CampaignPostInit();
 722
 723         fteqcc_testbugs();
 724
 725         Ban_LoadBans();
 726
 727         MapInfo_Enumerate();
 728         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 729
 730         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 731         {
 732                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 733                 if(fd != -1)
 734                 {
 735                         while((s = fgets(fd)))
 736                         {
 737                                 l = tokenize_console(s);
 738                                 if(l < 2)
 739                                         continue;
 740                                 if(argv(0) == "cd")
 741                                 {
 742                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 743                                         print("  cdtrack ", argv(2), "\n");
 744                                 }
 745                                 else if(argv(0) == "fog")
 746                                 {
 747                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 748                                         print("  \"fog\" \"", s, "\"\n");
 749                                 }
 750                                 else if(argv(0) == "set")
 751                                 {
 752                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 753                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 754                                 }
 755                                 else if(argv(0) != "//")
 756                                 {
 757                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 758                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 759                                 }
 760                         }
 761                         fclose(fd);
 762                 }
 763         }
 764
 765         WeaponStats_Init();
 766
 767         addstat(STAT_WEAPONS, AS_INT, weapons);
 768         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 769         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 770         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 771         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 772         Nagger_Init();
 773
 774         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 775         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 776         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 777         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 778         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 779         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 780         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 781         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 782         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 783         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 784         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 785         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 786         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 787
 788         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 789         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 790
 791         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 792
 793         if(g_ca || g_freezetag)
 794         {
 795                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 796                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 797                 addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 798                 addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 799         }
 800         if(g_freezetag)
 801         {
 802                 addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
 803                 addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
 804         }
 805
 806         // g_movementspeed hack
 807         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 808         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 809         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 810         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 811
 812         // secrets
 813         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 814         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 815
 816         next_pingtime = time + 5;
 817
 818         detect_maptype();
 819
 820         // set up information replies for clients and server to use
 821         lsmaps_reply = "^7Maps available: ";
 822         lsnewmaps_reply = "^7Maps without a record set: ";
 823         for(i = 0, j = 0; i < MapInfo_count; ++i)
 824         {
 825                 if(MapInfo_Get_ByID(i))
 826                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 827                         {
 828                                 if(mod(i, 2))
 829                                         col = "^2";
 830                                 else
 831                                         col = "^3";
 832
 833                                 ++j;
 834
 835                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 836
 837                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 838                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 839                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 840                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 841                         }
 842         }
 843
 844         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 845         lsnewmaps_reply = strzone(strcat(((!g_race && !g_cts) ? "Need to be playing race or CTS for lsnewmaps to work." : lsnewmaps_reply), "\n"));
 846
 847         maplist_reply = "^7Maps in list: ";
 848         n = tokenize_console(autocvar_g_maplist);
 849         for(i = 0, j = 0; i < n; ++i)
 850         {
 851                 if(MapInfo_CheckMap(argv(i)))
 852                 {
 853                         if(mod(j, 2))
 854                                 col = "^2";
 855                         else
 856                                 col = "^3";
 857                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 858                         ++j;
 859                 }
 860         }
 861         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 862         MapInfo_ClearTemps();
 863
 864         for(i = 0; i < 10; ++i)
 865         {
 866                 records_reply[i] = strzone(getrecords(i));
 867         }
 868
 869         ladder_reply = strzone(getladder());
 870
 871         rankings_reply = strzone(getrankings());
 872
 873         // begin other init
 874         ClientInit_Spawn();
 875         RandomSeed_Spawn();
 876         PingPLReport_Spawn();
 877
 878         CheatInit();
 879
 880         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 881
 882         // fill sv_curl_serverpackages from .serverpackage files
 883         if(autocvar_sv_curl_serverpackages_auto)
 884         {
 885                 s = "";
 886                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 887                 for(i = 0; i < n; ++i)
 888                         if(substring(argv(i), -14, -1) != "-serverpackage.txt")
 889                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 890                                 s = strcat(s, " ", argv(i));
 891                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 892                 if(fd >= 0)
 893                 {
 894                         j = search_getsize(fd);
 895                         for(i = 0; i < j; ++i)
 896                                 s = strcat(s, " ", search_getfilename(fd, i));
 897                         search_end(fd);
 898                 }
 899                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 900                 if(fd >= 0)
 901                 {
 902                         j = search_getsize(fd);
 903                         for(i = 0; i < j; ++i)
 904                                 s = strcat(s, " ", search_getfilename(fd, i));
 905                         search_end(fd);
 906                 }
 907                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 908         }
 909
 910         PlayerStats_Init();
 911
 912         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 913         modname = "Xonotic";
 914         // physics/balance/config changes that count as mod
 915         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 916                 modname = cvar_string("g_mod_physics");
 917         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 918                 modname = cvar_string("g_mod_balance");
 919         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 920                 modname = cvar_string("g_mod_config");
 921         // weird mutators that deserve to count as mod
 922         if(autocvar_g_minstagib)
 923                 modname = "MinstaGib";
 924         // extra mutators that deserve to count as mod
 925         MUTATOR_CALLHOOK(SetModname);
 926         // weird game types that deserve to count as mod
 927         if(g_cts)
 928                 modname = "CTS";
 929         // save it for later
 930         modname = strzone(modname);
 931
 932         WinningConditionHelper(); // set worldstatus
 933
 934         world_initialized = 1;
 935 }
 936
 937 void spawnfunc_light (void)
 938 {
 939         //makestatic (self); // Who the f___ did that?
 940         remove(self);
 941 }
 942
 943 string GetGametype()
 944 {
 945         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 946 }
 947
 948 string getmapname_stored;
 949 string GetMapname()
 950 {
 951         return mapname;
 952 }
 953
 954 float Map_Count, Map_Current;
 955 string Map_Current_Name;
 956
 957 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 958 float GetMaplistPosition()
 959 {
 960         float pos, idx;
 961         string map;
 962
 963         map = GetMapname();
 964         idx = autocvar_g_maplist_index;
 965
 966         if(idx >= 0)
 967                 if(idx < Map_Count)
 968                         if(map == argv(idx))
 969                                 return idx;
 970
 971         for(pos = 0; pos < Map_Count; ++pos)
 972                 if(map == argv(pos))
 973                         return pos;
 974
 975         // resume normal maplist rotation if current map is not in g_maplist
 976         return idx;
 977 }
 978
 979 float MapHasRightSize(string map)
 980 {
 981         float fh;
 982         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 983         if(autocvar_g_maplist_check_waypoints)
 984         {
 985                 dprint("checkwp "); dprint(map);
 986                 if(!fexists(strcat("maps/", map, ".waypoints")))
 987                 {
 988                         dprint(": no waypoints\n");
 989                         return FALSE;
 990                 }
 991                 dprint(": has waypoints\n");
 992         }
 993
 994         // open map size restriction file
 995         dprint("opensize "); dprint(map);
 996         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 997         if(fh >= 0)
 998         {
 999                 float mapmin, mapmax;
1000                 dprint(": ok, ");
1001                 mapmin = stof(fgets(fh));
1002                 mapmax = stof(fgets(fh));
1003                 fclose(fh);
1004                 if(player_count < mapmin)
1005                 {
1006                         dprint("not enough\n");
1007                         return FALSE;
1008                 }
1009                 if(player_count > mapmax)
1010                 {
1011                         dprint("too many\n");
1012                         return FALSE;
1013                 }
1014                 dprint("right size\n");
1015                 return TRUE;
1016         }
1017         dprint(": not found\n");
1018         return TRUE;
1019 }
1020
1021 string Map_Filename(float position)
1022 {
1023         return strcat("maps/", argv(position), ".bsp");
1024 }
1025
1026 string strwords(string s, float w)
1027 {
1028         float endpos;
1029         for(endpos = 0; w && endpos >= 0; --w)
1030                 endpos = strstrofs(s, " ", endpos + 1);
1031         if(endpos < 0)
1032                 return s;
1033         else
1034                 return substring(s, 0, endpos);
1035 }
1036
1037 float strhasword(string s, string w)
1038 {
1039         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1040 }
1041
1042 void Map_MarkAsRecent(string m)
1043 {
1044         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1045 }
1046
1047 float Map_IsRecent(string m)
1048 {
1049         return strhasword(autocvar_g_maplist_mostrecent, m);
1050 }
1051
1052 float Map_Check(float position, float pass)
1053 {
1054         string filename;
1055         string map_next;
1056         map_next = argv(position);
1057         if(pass <= 1)
1058         {
1059                 if(Map_IsRecent(map_next))
1060                         return 0;
1061         }
1062         filename = Map_Filename(position);
1063         if(MapInfo_CheckMap(map_next))
1064         {
1065                 if(pass == 2)
1066                         return 1;
1067                 if(MapHasRightSize(map_next))
1068                         return 1;
1069                 return 0;
1070         }
1071         else
1072                 dprint( "Couldn't select '", filename, "'..\n" );
1073
1074         return 0;
1075 }
1076
1077 void Map_Goto_SetStr(string nextmapname)
1078 {
1079         if(getmapname_stored != "")
1080                 strunzone(getmapname_stored);
1081         if(nextmapname == "")
1082                 getmapname_stored = "";
1083         else
1084                 getmapname_stored = strzone(nextmapname);
1085 }
1086
1087 void Map_Goto_SetFloat(float position)
1088 {
1089         cvar_set("g_maplist_index", ftos(position));
1090         Map_Goto_SetStr(argv(position));
1091 }
1092
1093 void Map_Goto(float reinit)
1094 {
1095         MapInfo_LoadMap(getmapname_stored, reinit);
1096 }
1097
1098 // return codes of map selectors:
1099 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1100 //   -2 = permanent failure
1101 float() MaplistMethod_Iterate = // usual method
1102 {
1103         float pass, i;
1104
1105         for(pass = 1; pass <= 2; ++pass)
1106         {
1107                 for(i = 1; i < Map_Count; ++i)
1108                 {
1109                         float mapindex;
1110                         mapindex = mod(i + Map_Current, Map_Count);
1111                         if(Map_Check(mapindex, pass))
1112                                 return mapindex;
1113                 }
1114         }
1115         return -1;
1116 }
1117
1118 float() MaplistMethod_Repeat = // fallback method
1119 {
1120         if(Map_Check(Map_Current, 2))
1121                 return Map_Current;
1122         return -2;
1123 }
1124
1125 float() MaplistMethod_Random = // random map selection
1126 {
1127         float i, imax;
1128
1129         imax = 42;
1130
1131         for(i = 0; i <= imax; ++i)
1132         {
1133                 float mapindex;
1134                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1135                 if(Map_Check(mapindex, 1))
1136                         return mapindex;
1137         }
1138         return -1;
1139 }
1140
1141 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1142 // the exponent sets a bias on the map selection:
1143 // the higher the exponent, the less likely "shortly repeated" same maps are
1144 {
1145         float i, j, imax, insertpos;
1146
1147         imax = 42;
1148
1149         for(i = 0; i <= imax; ++i)
1150         {
1151                 string newlist;
1152
1153                 // now reinsert this at another position
1154                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1155                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1156                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1157                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1158
1159                 // insert the current map there
1160                 newlist = "";
1161                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1162                         newlist = strcat(newlist, " ", argv(j));
1163                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1164                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1165                         newlist = strcat(newlist, " ", argv(j));
1166                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1167                 cvar_set("g_maplist", newlist);
1168                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1169
1170                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1171                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1172                 if(Map_Check(Map_Current, 1))
1173                         return Map_Current;
1174         }
1175         return -1;
1176 }
1177
1178 void Maplist_Init()
1179 {
1180         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1181         if(Map_Count == 0)
1182         {
1183                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1184                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1185                 if(autocvar_g_maplist_shuffle)
1186                         ShuffleMaplist();
1187                 localcmd("\nmenu_cmd sync\n");
1188                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1189         }
1190         if(Map_Count == 0)
1191                 error("empty maplist, cannot select a new map");
1192         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1193
1194         if(Map_Current_Name)
1195                 strunzone(Map_Current_Name);
1196         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1197         // this may or may not be correct, but who cares, in the worst case a map
1198         // isn't chosen in the first pass that should have been
1199 }
1200
1201 string GetNextMap()
1202 {
1203         float nextMap;
1204
1205         Maplist_Init();
1206         nextMap = -1;
1207
1208         if(nextMap == -1)
1209                 if(autocvar_g_maplist_shuffle > 0)
1210                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1211
1212         if(nextMap == -1)
1213                 if(autocvar_g_maplist_selectrandom)
1214                         nextMap = MaplistMethod_Random();
1215
1216         if(nextMap == -1)
1217                 nextMap = MaplistMethod_Iterate();
1218
1219         if(nextMap == -1)
1220                 nextMap = MaplistMethod_Repeat();
1221
1222         if(nextMap >= 0)
1223         {
1224                 Map_Goto_SetFloat(nextMap);
1225                 return getmapname_stored;
1226         }
1227
1228         return "";
1229 }
1230
1231 float DoNextMapOverride(float reinit)
1232 {
1233         if(autocvar_g_campaign)
1234         {
1235                 CampaignPostIntermission();
1236                 alreadychangedlevel = TRUE;
1237                 return TRUE;
1238         }
1239         if(autocvar_quit_when_empty)
1240         {
1241                 if(player_count <= currentbots)
1242                 {
1243                         localcmd("quit\n");
1244                         alreadychangedlevel = TRUE;
1245                         return TRUE;
1246                 }
1247         }
1248         if(autocvar_quit_and_redirect != "")
1249         {
1250                 redirection_target = strzone(autocvar_quit_and_redirect);
1251                 alreadychangedlevel = TRUE;
1252                 return TRUE;
1253         }
1254         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1255         {
1256                 localcmd("restart\n");
1257                 alreadychangedlevel = TRUE;
1258                 return TRUE;
1259         }
1260         if(autocvar_nextmap != "")
1261                 if(MapInfo_CheckMap(autocvar_nextmap))
1262                 {
1263                         Map_Goto_SetStr(autocvar_nextmap);
1264                         Map_Goto(reinit);
1265                         alreadychangedlevel = TRUE;
1266                         return TRUE;
1267                 }
1268         if(!reinit && autocvar_lastlevel)
1269         {
1270                 cvar_settemp_restore();
1271                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1272                 alreadychangedlevel = TRUE;
1273                 return TRUE;
1274         }
1275         return FALSE;
1276 }
1277
1278 void GotoNextMap(float reinit)
1279 {
1280         //string nextmap;
1281         //float n, nummaps;
1282         //string s;
1283         if (alreadychangedlevel)
1284                 return;
1285         alreadychangedlevel = TRUE;
1286
1287         {
1288                 string nextMap;
1289                 float allowReset;
1290
1291                 for(allowReset = 1; allowReset >= 0; --allowReset)
1292                 {
1293                         nextMap = GetNextMap();
1294                         if(nextMap != "")
1295                                 break;
1296
1297                         if(allowReset)
1298                         {
1299                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1300                                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1301                                 if(autocvar_g_maplist_shuffle)
1302                                         ShuffleMaplist();
1303                                 localcmd("\nmenu_cmd sync\n");
1304                         }
1305                         else
1306                         {
1307                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1308                         }
1309                 }
1310                 Map_Goto(reinit);
1311         }
1312 }
1313
1314
1315 /*
1316 ============
1317 IntermissionThink
1318
1319 When the player presses attack or jump, change to the next level
1320 ============
1321 */
1322 .float autoscreenshot;
1323 void() MapVote_Start;
1324 void() MapVote_Think;
1325 float mapvote_initialized;
1326 void IntermissionThink()
1327 {
1328         FixIntermissionClient(self);
1329
1330         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1331         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1332
1333         if( (server_screenshot || client_screenshot)
1334                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1335         {
1336                 self.autoscreenshot = -1;
1337                 if(clienttype(self) == CLIENTTYPE_REAL) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"", GetMapname(), strftime(FALSE, "%s"))); }
1338                 return;
1339         }
1340
1341         if (time < intermission_exittime)
1342                 return;
1343
1344         if(!mapvote_initialized)
1345                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1346                         return;
1347
1348         MapVote_Start();
1349 }
1350
1351 /*
1352 ============
1353 FindIntermission
1354
1355 Returns the entity to view from
1356 ============
1357 */
1358 /*
1359 entity FindIntermission()
1360 {
1361         local   entity spot;
1362         local   float cyc;
1363
1364 // look for info_intermission first
1365         spot = find (world, classname, "info_intermission");
1366         if (spot)
1367         {       // pick a random one
1368                 cyc = random() * 4;
1369                 while (cyc > 1)
1370                 {
1371                         spot = find (spot, classname, "info_intermission");
1372                         if (!spot)
1373                                 spot = find (spot, classname, "info_intermission");
1374                         cyc = cyc - 1;
1375                 }
1376                 return spot;
1377         }
1378
1379 // then look for the start position
1380         spot = find (world, classname, "info_player_start");
1381         if (spot)
1382                 return spot;
1383
1384 // testinfo_player_start is only found in regioned levels
1385         spot = find (world, classname, "testplayerstart");
1386         if (spot)
1387                 return spot;
1388
1389 // then look for the start position
1390         spot = find (world, classname, "info_player_deathmatch");
1391         if (spot)
1392                 return spot;
1393
1394         //objerror ("FindIntermission: no spot");
1395         return world;
1396 }
1397 */
1398
1399 /*
1400 ===============================================================================
1401
1402 RULES
1403
1404 ===============================================================================
1405 */
1406
1407 void DumpStats(float final)
1408 {
1409         float file;
1410         string s;
1411         float to_console;
1412         float to_eventlog;
1413         float to_file;
1414         float i;
1415
1416         to_console = autocvar_sv_logscores_console;
1417         to_eventlog = autocvar_sv_eventlog;
1418         to_file = autocvar_sv_logscores_file;
1419
1420         if(!final)
1421         {
1422                 to_console = TRUE; // always print printstats replies
1423                 to_eventlog = FALSE; // but never print them to the event log
1424         }
1425
1426         if(to_eventlog)
1427                 if(autocvar_sv_eventlog_console)
1428                         to_console = FALSE; // otherwise we get the output twice
1429
1430         if(final)
1431                 s = ":scores:";
1432         else
1433                 s = ":status:";
1434         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1435
1436         if(to_console)
1437                 print(s, "\n");
1438         if(to_eventlog)
1439                 GameLogEcho(s);
1440         if(to_file)
1441         {
1442                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1443                 if(file == -1)
1444                         to_file = FALSE;
1445                 else
1446                         fputs(file, strcat(s, "\n"));
1447         }
1448
1449         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1450         if(to_console)
1451                 print(s, "\n");
1452         if(to_eventlog)
1453                 GameLogEcho(s);
1454         if(to_file)
1455                 fputs(file, strcat(s, "\n"));
1456
1457         FOR_EACH_CLIENT(other)
1458         {
1459                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && autocvar_sv_logscores_bots))
1460                 {
1461                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1462                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1463                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1464                                 s = strcat(s, ftos(other.team), ":");
1465                         else
1466                                 s = strcat(s, "spectator:");
1467
1468                         if(to_console)
1469                                 print(s, other.netname, "\n");
1470                         if(to_eventlog)
1471                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1472                         if(to_file)
1473                                 fputs(file, strcat(s, other.netname, "\n"));
1474                 }
1475         }
1476
1477         if(teamplay)
1478         {
1479                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1480                 if(to_console)
1481                         print(s, "\n");
1482                 if(to_eventlog)
1483                         GameLogEcho(s);
1484                 if(to_file)
1485                         fputs(file, strcat(s, "\n"));
1486
1487                 for(i = 1; i < 16; ++i)
1488                 {
1489                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1490                         s = strcat(s, ":", ftos(i));
1491                         if(to_console)
1492                                 print(s, "\n");
1493                         if(to_eventlog)
1494                                 GameLogEcho(s);
1495                         if(to_file)
1496                                 fputs(file, strcat(s, "\n"));
1497                 }
1498         }
1499
1500         if(to_console)
1501                 print(":end\n");
1502         if(to_eventlog)
1503                 GameLogEcho(":end");
1504         if(to_file)
1505         {
1506                 fputs(file, ":end\n");
1507                 fclose(file);
1508         }
1509 }
1510
1511 void FixIntermissionClient(entity e)
1512 {
1513         string s;
1514         if(!e.autoscreenshot) // initial call
1515         {
1516                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1517                 e.health = -2342;
1518                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1519                 e.solid = SOLID_NOT;
1520                 e.movetype = MOVETYPE_NONE;
1521                 e.takedamage = DAMAGE_NO;
1522                 if(e.weaponentity)
1523                 {
1524                         e.weaponentity.effects = EF_NODRAW;
1525                         if (e.weaponentity.weaponentity)
1526                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1527                 }
1528                 if(clienttype(e) == CLIENTTYPE_REAL)
1529                 {
1530                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1531                         s = autocvar_sv_intermission_cdtrack;
1532                         if(s != "")
1533                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1534                         msg_entity = e;
1535                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1536                 }
1537         }
1538 }
1539
1540 void minstagib_stop_countdown(entity e);
1541 /*
1542 go to the next level for deathmatch
1543 only called if a time or frag limit has expired
1544 */
1545 void NextLevel()
1546 {
1547         gameover = TRUE;
1548
1549         intermission_running = 1;
1550
1551 // enforce a wait time before allowing changelevel
1552         if(player_count > 0)
1553                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1554         else
1555                 intermission_exittime = -1;
1556
1557         /*
1558         WriteByte (MSG_ALL, SVC_CDTRACK);
1559         WriteByte (MSG_ALL, 3);
1560         WriteByte (MSG_ALL, 3);
1561         // done in FixIntermission
1562         */
1563
1564         //pos = FindIntermission ();
1565
1566         VoteReset();
1567
1568         DumpStats(TRUE);
1569
1570         // send statistics
1571         entity e;
1572         PlayerStats_EndMatch(1);
1573         FOR_EACH_CLIENT(e)
1574                 PlayerStats_AddGlobalInfo(e);
1575         PlayerStats_Shutdown();
1576         WeaponStats_Shutdown();
1577
1578         if(autocvar_sv_eventlog)
1579                 GameLogEcho(":gameover");
1580
1581         GameLogClose();
1582
1583         FOR_EACH_PLAYER(other) {
1584                 minstagib_stop_countdown(other);
1585                 FixIntermissionClient(other);
1586                 if(other.winning)
1587                         bprint(other.netname, " ^7wins.\n");
1588         }
1589
1590         if(autocvar_g_campaign)
1591                 CampaignPreIntermission();
1592
1593         localcmd("\nsv_hook_gameend\n");
1594 }
1595
1596 /*
1597 ============
1598 CheckRules_Player
1599
1600 Exit deathmatch games upon conditions
1601 ============
1602 */
1603 void CheckRules_Player()
1604 {
1605         if (gameover)   // someone else quit the game already
1606                 return;
1607
1608         if(self.deadflag == DEAD_NO)
1609                 self.play_time += frametime;
1610
1611         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1612         //   (div0: and that in CheckRules_World please)
1613 }
1614
1615 float checkrules_equality;
1616 float checkrules_suddendeathwarning;
1617 float checkrules_suddendeathend;
1618 float checkrules_overtimesadded; //how many overtimes have been already added
1619
1620 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1621 float WINNING_YES = 1; // winner found
1622 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1623 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1624
1625 float InitiateSuddenDeath()
1626 {
1627         // Check first whether normal overtimes could be added before initiating suddendeath mode
1628         // - for this timelimit_overtime needs to be >0 of course
1629         // - also check the winning condition calculated in the previous frame and only add normal overtime
1630         //   again, if at the point at which timelimit would be extended again, still no winner was found
1631         if ((checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1632         {
1633                 return 1; // need to call InitiateOvertime later
1634         }
1635         else
1636         {
1637                 if(!checkrules_suddendeathend)
1638                 {
1639                         checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1640                         if(g_race && !g_race_qualifying)
1641                                 race_StartCompleting();
1642                 }
1643                 return 0;
1644         }
1645 }
1646
1647 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1648 {
1649         ++checkrules_overtimesadded;
1650         //add one more overtime by simply extending the timelimit
1651         float tl;
1652         tl = autocvar_timelimit;
1653         tl += autocvar_timelimit_overtime;
1654         cvar_set("timelimit", ftos(tl));
1655         string minutesPlural;
1656         if (autocvar_timelimit_overtime == 1)
1657                 minutesPlural = " ^3minute";
1658         else
1659                 minutesPlural = " ^3minutes";
1660
1661         bcenterprint(
1662                 strcat(
1663                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1664                         ftos(autocvar_timelimit_overtime),
1665                         minutesPlural,
1666                         " to the game!"
1667                 )
1668         );
1669 }
1670
1671 float GetWinningCode(float fraglimitreached, float equality)
1672 {
1673         if(autocvar_g_campaign == 1)
1674                 if(fraglimitreached)
1675                         return WINNING_YES;
1676                 else
1677                         return WINNING_NO;
1678
1679         else
1680                 if(equality)
1681                         if(fraglimitreached)
1682                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1683                         else
1684                                 return WINNING_NEVER;
1685                 else
1686                         if(fraglimitreached)
1687                                 return WINNING_YES;
1688                         else
1689                                 return WINNING_NO;
1690 }
1691
1692 // set the .winning flag for exactly those players with a given field value
1693 void SetWinners(.float field, float value)
1694 {
1695         entity head;
1696         FOR_EACH_PLAYER(head)
1697                 head.winning = (head.field == value);
1698 }
1699
1700 // set the .winning flag for those players with a given field value
1701 void AddWinners(.float field, float value)
1702 {
1703         entity head;
1704         FOR_EACH_PLAYER(head)
1705                 if(head.field == value)
1706                         head.winning = 1;
1707 }
1708
1709 // clear the .winning flags
1710 void ClearWinners(void)
1711 {
1712         entity head;
1713         FOR_EACH_PLAYER(head)
1714                 head.winning = 0;
1715 }
1716
1717 // Onslaught winning condition:
1718 // game terminates if only one team has a working generator (or none)
1719 float WinningCondition_Onslaught()
1720 {
1721         entity head;
1722         float t1, t2, t3, t4;
1723
1724         WinningConditionHelper(); // set worldstatus
1725
1726         if(inWarmupStage)
1727                 return WINNING_NO;
1728
1729         // first check if the game has ended
1730         t1 = t2 = t3 = t4 = 0;
1731         head = find(world, classname, "onslaught_generator");
1732         while (head)
1733         {
1734                 if (head.health > 0)
1735                 {
1736                         if (head.team == COLOR_TEAM1) t1 = 1;
1737                         if (head.team == COLOR_TEAM2) t2 = 1;
1738                         if (head.team == COLOR_TEAM3) t3 = 1;
1739                         if (head.team == COLOR_TEAM4) t4 = 1;
1740                 }
1741                 head = find(head, classname, "onslaught_generator");
1742         }
1743         if (t1 + t2 + t3 + t4 < 2)
1744         {
1745                 // game over, only one team remains (or none)
1746                 ClearWinners();
1747                 if (t1) SetWinners(team, COLOR_TEAM1);
1748                 if (t2) SetWinners(team, COLOR_TEAM2);
1749                 if (t3) SetWinners(team, COLOR_TEAM3);
1750                 if (t4) SetWinners(team, COLOR_TEAM4);
1751                 dprint("Have a winner, ending game.\n");
1752                 return WINNING_YES;
1753         }
1754
1755         // Two or more teams remain
1756         return WINNING_NO;
1757 }
1758
1759 float LMS_NewPlayerLives()
1760 {
1761         float fl;
1762         fl = autocvar_fraglimit;
1763         if(fl == 0)
1764                 fl = 999;
1765
1766         // first player has left the game for dying too much? Nobody else can get in.
1767         if(lms_lowest_lives < 1)
1768                 return 0;
1769
1770         if(!autocvar_g_lms_join_anytime)
1771                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
1772                         return 0;
1773
1774         return bound(1, lms_lowest_lives, fl);
1775 }
1776
1777 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1778 // they win. Otherwise the defending team wins once the timelimit passes.
1779 void assault_new_round();
1780 float WinningCondition_Assault()
1781 {
1782         float status;
1783
1784         WinningConditionHelper(); // set worldstatus
1785
1786         status = WINNING_NO;
1787         // as the timelimit has not yet passed just assume the defending team will win
1788         if(assault_attacker_team == COLOR_TEAM1)
1789         {
1790                 SetWinners(team, COLOR_TEAM2);
1791         }
1792         else
1793         {
1794                 SetWinners(team, COLOR_TEAM1);
1795         }
1796
1797         entity ent;
1798         ent = find(world, classname, "target_assault_roundend");
1799         if(ent)
1800         {
1801                 if(ent.winning) // round end has been triggered by attacking team
1802                 {
1803                         bprint("ASSAULT: round completed...\n");
1804                         SetWinners(team, assault_attacker_team);
1805
1806                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1807
1808                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1809                         {
1810                                 status = WINNING_YES;
1811                         }
1812                         else
1813                         {
1814                                 entity oldself;
1815                                 oldself = self;
1816                                 self = ent;
1817                                 assault_new_round();
1818                                 self = oldself;
1819                         }
1820                 }
1821         }
1822
1823         return status;
1824 }
1825
1826 // LMS winning condition: game terminates if and only if there's at most one
1827 // one player who's living lives. Top two scores being equal cancels the time
1828 // limit.
1829 float WinningCondition_LMS()
1830 {
1831         entity head, head2;
1832         float have_player;
1833         float have_players;
1834         float l;
1835
1836         have_player = FALSE;
1837         have_players = FALSE;
1838         l = LMS_NewPlayerLives();
1839
1840         head = find(world, classname, "player");
1841         if(head)
1842                 have_player = TRUE;
1843         head2 = find(head, classname, "player");
1844         if(head2)
1845                 have_players = TRUE;
1846
1847         if(have_player)
1848         {
1849                 // we have at least one player
1850                 if(have_players)
1851                 {
1852                         // two or more active players - continue with the game
1853                 }
1854                 else
1855                 {
1856                         // exactly one player?
1857
1858                         ClearWinners();
1859                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1860
1861                         if(l)
1862                         {
1863                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1864                                 return WINNING_NO;
1865                         }
1866                         else
1867                         {
1868                                 // a winner!
1869                                 // and assign him his first place
1870                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1871                                 return WINNING_YES;
1872                         }
1873                 }
1874         }
1875         else
1876         {
1877                 // nobody is playing at all...
1878                 if(l)
1879                 {
1880                         // wait for players...
1881                 }
1882                 else
1883                 {
1884                         // SNAFU (maybe a draw game?)
1885                         ClearWinners();
1886                         dprint("No players, ending game.\n");
1887                         return WINNING_YES;
1888                 }
1889         }
1890
1891         // When we get here, we have at least two players who are actually LIVING,
1892         // now check if the top two players have equal score.
1893         WinningConditionHelper();
1894
1895         ClearWinners();
1896         if(WinningConditionHelper_winner)
1897                 WinningConditionHelper_winner.winning = TRUE;
1898         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1899                 return WINNING_NEVER;
1900
1901         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1902         return WINNING_NO;
1903 }
1904
1905 void ShuffleMaplist()
1906 {
1907         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1908 }
1909
1910 float leaderfrags;
1911 float WinningCondition_Scores(float limit, float leadlimit)
1912 {
1913         float limitreached;
1914
1915         // TODO make everything use THIS winning condition (except LMS)
1916         WinningConditionHelper();
1917
1918         if(teamplay)
1919         {
1920                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1921                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1922                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1923                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1924         }
1925
1926         ClearWinners();
1927         if(WinningConditionHelper_winner)
1928                 WinningConditionHelper_winner.winning = 1;
1929         if(WinningConditionHelper_winnerteam >= 0)
1930                 SetWinners(team, WinningConditionHelper_winnerteam);
1931
1932         if(WinningConditionHelper_lowerisbetter)
1933         {
1934                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1935                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1936                 limit = -limit;
1937         }
1938
1939         if(WinningConditionHelper_zeroisworst)
1940                 leadlimit = 0; // not supported in this mode
1941
1942         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1943         // these modes always score in increments of 1, thus this makes sense
1944         {
1945                 if(leaderfrags != WinningConditionHelper_topscore)
1946                 {
1947                         leaderfrags = WinningConditionHelper_topscore;
1948
1949                         if (limit)
1950                         if (leaderfrags == limit - 1)
1951                                 Announce("1fragleft");
1952                         else if (leaderfrags == limit - 2)
1953                                 Announce("2fragsleft");
1954                         else if (leaderfrags == limit - 3)
1955                                 Announce("3fragsleft");
1956                 }
1957         }
1958
1959         limitreached = FALSE;
1960         if(limit)
1961                 if(WinningConditionHelper_topscore >= limit)
1962                         limitreached = TRUE;
1963         if(leadlimit)
1964         {
1965                 float leadlimitreached;
1966                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1967                 if(autocvar_leadlimit_and_fraglimit)
1968                         limitreached = (limitreached && leadlimitreached);
1969                 else
1970                         limitreached = (limitreached || leadlimitreached);
1971         }
1972
1973         return GetWinningCode(
1974                 WinningConditionHelper_topscore && limitreached,
1975                 WinningConditionHelper_equality
1976         );
1977 }
1978
1979 float WinningCondition_Race(float fraglimit)
1980 {
1981         float wc;
1982         entity p;
1983         float n, c;
1984
1985         n = 0;
1986         c = 0;
1987         FOR_EACH_PLAYER(p)
1988         {
1989                 ++n;
1990                 if(p.race_completed)
1991                         ++c;
1992         }
1993         if(n && (n == c))
1994                 return WINNING_YES;
1995         wc = WinningCondition_Scores(fraglimit, 0);
1996
1997         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1998         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1999         // do NOT support equality when the laps are all raced!
2000                 return WINNING_STARTSUDDENDEATHOVERTIME;
2001         else
2002                 return WINNING_NEVER;
2003         return wc;
2004 }
2005
2006 float WinningCondition_QualifyingThenRace(float limit)
2007 {
2008         float wc;
2009         wc = WinningCondition_Scores(limit, 0);
2010
2011         // NEVER initiate overtime
2012         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2013         {
2014                 return WINNING_YES;
2015         }
2016
2017         return wc;
2018 }
2019
2020 float WinningCondition_RanOutOfSpawns()
2021 {
2022         entity head;
2023
2024         if(have_team_spawns <= 0)
2025                 return WINNING_NO;
2026
2027         if(autocvar_g_spawn_useallspawns <= 0)
2028                 return WINNING_NO;
2029
2030         if(!some_spawn_has_been_used)
2031                 return WINNING_NO;
2032
2033         team1_score = team2_score = team3_score = team4_score = 0;
2034
2035         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2036         {
2037                 if(head.team == COLOR_TEAM1)
2038                         team1_score = 1;
2039                 else if(head.team == COLOR_TEAM2)
2040                         team2_score = 1;
2041                 else if(head.team == COLOR_TEAM3)
2042                         team3_score = 1;
2043                 else if(head.team == COLOR_TEAM4)
2044                         team4_score = 1;
2045         }
2046
2047         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2048         {
2049                 if(head.team == COLOR_TEAM1)
2050                         team1_score = 1;
2051                 else if(head.team == COLOR_TEAM2)
2052                         team2_score = 1;
2053                 else if(head.team == COLOR_TEAM3)
2054                         team3_score = 1;
2055                 else if(head.team == COLOR_TEAM4)
2056                         team4_score = 1;
2057         }
2058
2059         ClearWinners();
2060         if(team1_score + team2_score + team3_score + team4_score == 0)
2061         {
2062                 checkrules_equality = TRUE;
2063                 return WINNING_YES;
2064         }
2065         else if(team1_score + team2_score + team3_score + team4_score == 1)
2066         {
2067                 float t, i;
2068                 if(team1_score) t = COLOR_TEAM1;
2069                 if(team2_score) t = COLOR_TEAM2;
2070                 if(team3_score) t = COLOR_TEAM3;
2071                 if(team4_score) t = COLOR_TEAM4;
2072                 CheckAllowedTeams(world);
2073                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2074                 {
2075                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2076                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2077                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2078                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2079                 }
2080
2081                 AddWinners(team, t);
2082                 return WINNING_YES;
2083         }
2084         else
2085                 return WINNING_NO;
2086 }
2087
2088 /*
2089 ============
2090 CheckRules_World
2091
2092 Exit deathmatch games upon conditions
2093 ============
2094 */
2095 void ReadyRestart();
2096 void CheckRules_World()
2097 {
2098         float timelimit;
2099         float fraglimit;
2100         float leadlimit;
2101
2102         VoteThink();
2103         MapVote_Think();
2104
2105         SetDefaultAlpha();
2106
2107         /*
2108         MapVote_Think should now do that part
2109         if (intermission_running)
2110                 if (time >= intermission_exittime + 60)
2111                 {
2112                         if(!DoNextMapOverride())
2113                                 GotoNextMap();
2114                         return;
2115                 }
2116         */
2117
2118         if (gameover)   // someone else quit the game already
2119         {
2120                 if(player_count == 0) // Nobody there? Then let's go to the next map
2121                         MapVote_Start();
2122                         // this will actually check the player count in the next frame
2123                         // again, but this shouldn't hurt
2124                 return;
2125         }
2126
2127         timelimit = autocvar_timelimit * 60;
2128         fraglimit = autocvar_fraglimit;
2129         leadlimit = autocvar_leadlimit;
2130
2131         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2132         {
2133                 if(timelimit > 0)
2134                         timelimit = 0; // timelimit is not made for warmup
2135                 if(fraglimit > 0)
2136                         fraglimit = 0; // no fraglimit for now
2137                 leadlimit = 0; // no leadlimit for now
2138         }
2139
2140         if(g_onslaught)
2141                 timelimit = 0; // ONS has its own overtime rule
2142
2143         if(timelimit > 0)
2144         {
2145                 timelimit += game_starttime;
2146         }
2147         else if (timelimit < 0)
2148         {
2149                 // endmatch
2150                 NextLevel();
2151                 return;
2152         }
2153
2154         float wantovertime;
2155         wantovertime = 0;
2156
2157         if(checkrules_suddendeathend)
2158         {
2159                 if(!checkrules_suddendeathwarning)
2160                 {
2161                         checkrules_suddendeathwarning = TRUE;
2162                         if(g_race && !g_race_qualifying)
2163                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2164                         else
2165                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2166                 }
2167         }
2168         else
2169         {
2170                 if (timelimit && time >= timelimit)
2171                 {
2172                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2173                         {
2174                                 float totalplayers;
2175                                 float playerswithlaps;
2176                                 float readyplayers;
2177                                 entity head;
2178                                 totalplayers = playerswithlaps = readyplayers = 0;
2179                                 FOR_EACH_PLAYER(head)
2180                                 {
2181                                         ++totalplayers;
2182                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2183                                                 ++playerswithlaps;
2184                                         if(head.ready)
2185                                                 ++readyplayers;
2186                                 }
2187
2188                                 // at least 2 of the players have completed a lap: start the RACE
2189                                 // otherwise, the players should end the qualifying on their own
2190                                 if(readyplayers || playerswithlaps >= 2)
2191                                 {
2192                                         checkrules_suddendeathend = 0;
2193                                         ReadyRestart(); // go to race
2194                                         return;
2195                                 }
2196                                 else
2197                                         wantovertime |= InitiateSuddenDeath();
2198                         }
2199                         else
2200                                 wantovertime |= InitiateSuddenDeath();
2201                 }
2202         }
2203
2204         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2205         {
2206                 NextLevel();
2207                 return;
2208         }
2209
2210         float checkrules_status;
2211         checkrules_status = WinningCondition_RanOutOfSpawns();
2212         if(checkrules_status == WINNING_YES)
2213         {
2214                 bprint("Hey! Someone ran out of spawns!\n");
2215         }
2216         else if(g_race && !g_race_qualifying && timelimit >= 0)
2217         {
2218                 checkrules_status = WinningCondition_Race(fraglimit);
2219                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2220         }
2221         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2222         {
2223                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2224                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2225         }
2226         else if(g_assault)
2227         {
2228                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2229         }
2230         else if(g_lms)
2231         {
2232                 checkrules_status = WinningCondition_LMS();
2233         }
2234         else if (g_onslaught)
2235         {
2236                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2237         }
2238         else
2239         {
2240                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2241                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2242         }
2243
2244         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2245         {
2246                 checkrules_status = WINNING_NEVER;
2247                 checkrules_overtimesadded = -1;
2248                 wantovertime |= InitiateSuddenDeath();
2249         }
2250
2251         if(checkrules_status == WINNING_NEVER)
2252                 // equality cases! Nobody wins if the overtime ends in a draw.
2253                 ClearWinners();
2254
2255         if(wantovertime)
2256         {
2257                 if(checkrules_status == WINNING_NEVER)
2258                         InitiateOvertime();
2259                 else
2260                         checkrules_status = WINNING_YES;
2261         }
2262
2263         if(checkrules_suddendeathend)
2264                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2265                         checkrules_status = WINNING_YES;
2266
2267         if(checkrules_status == WINNING_YES)
2268         {
2269                 //print("WINNING\n");
2270                 NextLevel();
2271         }
2272 }
2273
2274 float mapvote_nextthink;
2275 float mapvote_initialized;
2276 float mapvote_keeptwotime;
2277 float mapvote_timeout;
2278 string mapvote_message;
2279 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2280 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2281 float mapvote_screenshot_dirs_count;
2282
2283 float mapvote_count;
2284 float mapvote_count_real;
2285 string mapvote_maps[MAPVOTE_COUNT];
2286 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2287 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2288 float mapvote_maps_suggested[MAPVOTE_COUNT];
2289 string mapvote_suggestions[MAPVOTE_COUNT];
2290 float mapvote_suggestion_ptr;
2291 float mapvote_voters;
2292 float mapvote_selections[MAPVOTE_COUNT];
2293 float mapvote_run;
2294 float mapvote_detail;
2295 float mapvote_abstain;
2296 .float mapvote;
2297
2298 void MapVote_ClearAllVotes()
2299 {
2300         FOR_EACH_CLIENT(other)
2301                 other.mapvote = 0;
2302 }
2303
2304 string MapVote_Suggest(string m)
2305 {
2306         float i;
2307         if(m == "")
2308                 return "That's not how to use this command.";
2309         if(!autocvar_g_maplist_votable_suggestions)
2310                 return "Suggestions are not accepted on this server.";
2311         if(mapvote_initialized)
2312                 return "Can't suggest - voting is already in progress!";
2313         m = MapInfo_FixName(m);
2314         if(!m)
2315                 return "The map you suggested is not available on this server.";
2316         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2317                 if(Map_IsRecent(m))
2318                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2319
2320         if(!MapInfo_CheckMap(m))
2321                 return "The map you suggested does not support the current game mode.";
2322         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2323                 if(mapvote_suggestions[i] == m)
2324                         return "This map was already suggested.";
2325         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2326         {
2327                 i = floor(random() * mapvote_suggestion_ptr);
2328         }
2329         else
2330         {
2331                 i = mapvote_suggestion_ptr;
2332                 mapvote_suggestion_ptr += 1;
2333         }
2334         if(mapvote_suggestions[i] != "")
2335                 strunzone(mapvote_suggestions[i]);
2336         mapvote_suggestions[i] = strzone(m);
2337         if(autocvar_sv_eventlog)
2338                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2339         return strcat("Suggestion of ", m, " accepted.");
2340 }
2341
2342 void MapVote_AddVotable(string nextMap, float isSuggestion)
2343 {
2344         float j, i, o;
2345         string pakfile, mapfile;
2346
2347         if(nextMap == "")
2348                 return;
2349         for(j = 0; j < mapvote_count; ++j)
2350                 if(mapvote_maps[j] == nextMap)
2351                         return;
2352         // suggestions might be no longer valid/allowed after gametype switch!
2353         if(isSuggestion)
2354                 if(!MapInfo_CheckMap(nextMap))
2355                         return;
2356         mapvote_maps[mapvote_count] = strzone(nextMap);
2357         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2358
2359         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2360         {
2361                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2362                 pakfile = whichpack(strcat(mapfile, ".tga"));
2363                 if(pakfile == "")
2364                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2365                 if(pakfile == "")
2366                         pakfile = whichpack(strcat(mapfile, ".png"));
2367                 if(pakfile != "")
2368                         break;
2369         }
2370         if(i >= mapvote_screenshot_dirs_count)
2371                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2372         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2373                 pakfile = substring(pakfile, o, -1);
2374
2375         mapvote_maps_screenshot_dir[mapvote_count] = i;
2376         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2377
2378         mapvote_count += 1;
2379 }
2380
2381 void MapVote_Spawn();
2382 void MapVote_Init()
2383 {
2384         float i;
2385         float nmax, smax;
2386
2387         MapVote_ClearAllVotes();
2388
2389         mapvote_count = 0;
2390         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2391         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2392
2393         if(mapvote_abstain)
2394                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2395         else
2396                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2397         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2398
2399         // we need this for AddVotable, as that cycles through the screenshot dirs
2400         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2401         if(mapvote_screenshot_dirs_count == 0)
2402                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2403         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2404         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2405                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2406
2407         if(mapvote_suggestion_ptr)
2408                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2409                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2410
2411         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2412                 MapVote_AddVotable(GetNextMap(), FALSE);
2413
2414         if(mapvote_count == 0)
2415         {
2416                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2417                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2418                 if(autocvar_g_maplist_shuffle)
2419                         ShuffleMaplist();
2420                 localcmd("\nmenu_cmd sync\n");
2421                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2422                         MapVote_AddVotable(GetNextMap(), FALSE);
2423         }
2424
2425         mapvote_count_real = mapvote_count;
2426         if(mapvote_abstain)
2427                 MapVote_AddVotable("don't care", 0);
2428
2429         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2430
2431         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2432         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2433         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2434                 mapvote_keeptwotime = 0;
2435         mapvote_message = "Choose a map and press its key!";
2436
2437         MapVote_Spawn();
2438 }
2439
2440 void MapVote_SendPicture(float id)
2441 {
2442         msg_entity = self;
2443         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2444         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2445         WriteByte(MSG_ONE, id);
2446         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2447 }
2448
2449 float MapVote_GetMapMask()
2450 {
2451         float mask, i, power;
2452         mask = 0;
2453         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2454                 if(mapvote_maps[i] != "")
2455                         mask |= power;
2456         return mask;
2457 }
2458
2459 entity mapvote_ent;
2460 float MapVote_SendEntity(entity to, float sf)
2461 {
2462         float i;
2463
2464         if(sf & 1)
2465                 sf &~= 2; // if we send 1, we don't need to also send 2
2466
2467         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2468         WriteByte(MSG_ENTITY, sf);
2469
2470         if(sf & 1)
2471         {
2472                 // flag 1 == initialization
2473                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2474                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2475                 WriteString(MSG_ENTITY, "");
2476                 WriteByte(MSG_ENTITY, mapvote_count);
2477                 WriteByte(MSG_ENTITY, mapvote_abstain);
2478                 WriteByte(MSG_ENTITY, mapvote_detail);
2479                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2480                 if(mapvote_count <= 8)
2481                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2482                 else
2483                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2484                 for(i = 0; i < mapvote_count; ++i)
2485                         if(mapvote_maps[i] != "")
2486                         {
2487                                 if(mapvote_abstain && i == mapvote_count - 1)
2488                                 {
2489                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2490                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2491                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2492                                 }
2493                                 else
2494                                 {
2495                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2496                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2497                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2498                                 }
2499                         }
2500         }
2501
2502         if(sf & 2)
2503         {
2504                 // flag 2 == update of mask
2505                 if(mapvote_count <= 8)
2506                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2507                 else
2508                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2509         }
2510
2511         if(sf & 4)
2512         {
2513                 if(mapvote_detail)
2514                         for(i = 0; i < mapvote_count; ++i)
2515                                 if(mapvote_maps[i] != "")
2516                                         WriteByte(MSG_ENTITY, mapvote_selections[i]);
2517
2518                 WriteByte(MSG_ENTITY, to.mapvote);
2519         }
2520
2521         return TRUE;
2522 }
2523
2524 void MapVote_Spawn()
2525 {
2526         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2527 }
2528
2529 void MapVote_TouchMask()
2530 {
2531         mapvote_ent.SendFlags |= 2;
2532 }
2533
2534 void MapVote_TouchVotes(entity voter)
2535 {
2536         mapvote_ent.SendFlags |= 4;
2537 }
2538
2539 float MapVote_Finished(float mappos)
2540 {
2541         string result;
2542         float i;
2543         float didntvote;
2544
2545         if(autocvar_sv_eventlog)
2546         {
2547                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2548                 result = strcat(result, ":", ftos(mapvote_selections[mappos]), "::");
2549                 didntvote = mapvote_voters;
2550                 for(i = 0; i < mapvote_count; ++i)
2551                         if(mapvote_maps[i] != "")
2552                         {
2553                                 didntvote -= mapvote_selections[i];
2554                                 if(i != mappos)
2555                                 {
2556                                         result = strcat(result, ":", mapvote_maps[i]);
2557                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2558                                 }
2559                         }
2560                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2561
2562                 GameLogEcho(result);
2563                 if(mapvote_maps_suggested[mappos])
2564                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2565         }
2566
2567         FOR_EACH_REALCLIENT(other)
2568                 FixClientCvars(other);
2569
2570         Map_Goto_SetStr(mapvote_maps[mappos]);
2571         Map_Goto(0);
2572         alreadychangedlevel = TRUE;
2573         return TRUE;
2574 }
2575 void MapVote_CheckRules_1()
2576 {
2577         float i;
2578
2579         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2580         {
2581                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2582                 mapvote_selections[i] = 0;
2583         }
2584
2585         mapvote_voters = 0;
2586         FOR_EACH_REALCLIENT(other)
2587         {
2588                 ++mapvote_voters;
2589                 if(other.mapvote)
2590                 {
2591                         i = other.mapvote - 1;
2592                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2593                         mapvote_selections[i] = mapvote_selections[i] + 1;
2594                 }
2595         }
2596 }
2597
2598 float MapVote_CheckRules_2()
2599 {
2600         float i;
2601         float firstPlace, secondPlace;
2602         float firstPlaceVotes, secondPlaceVotes;
2603         float mapvote_voters_real;
2604         string result;
2605
2606         if(mapvote_count_real == 1)
2607                 return MapVote_Finished(0);
2608
2609         mapvote_voters_real = mapvote_voters;
2610         if(mapvote_abstain)
2611                 mapvote_voters_real -= mapvote_selections[mapvote_count - 1];
2612
2613         RandomSelection_Init();
2614         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2615                 RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2616         firstPlace = RandomSelection_chosen_float;
2617         firstPlaceVotes = RandomSelection_best_priority;
2618         //dprint("First place: ", ftos(firstPlace), "\n");
2619         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2620
2621         RandomSelection_Init();
2622         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2623                 if(i != firstPlace)
2624                         RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2625         secondPlace = RandomSelection_chosen_float;
2626         secondPlaceVotes = RandomSelection_best_priority;
2627         //dprint("Second place: ", ftos(secondPlace), "\n");
2628         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2629
2630         if(firstPlace == -1)
2631                 error("No first place in map vote... WTF?");
2632
2633         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2634                 return MapVote_Finished(firstPlace);
2635
2636         if(mapvote_keeptwotime)
2637                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2638                 {
2639                         float didntvote;
2640                         MapVote_TouchMask();
2641                         mapvote_message = "Now decide between the TOP TWO!";
2642                         mapvote_keeptwotime = 0;
2643                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2644                         result = strcat(result, ":", ftos(firstPlaceVotes));
2645                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2646                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2647                         didntvote = mapvote_voters;
2648                         for(i = 0; i < mapvote_count; ++i)
2649                                 if(mapvote_maps[i] != "")
2650                                 {
2651                                         didntvote -= mapvote_selections[i];
2652                                         if(i != firstPlace)
2653                                                 if(i != secondPlace)
2654                                                 {
2655                                                         result = strcat(result, ":", mapvote_maps[i]);
2656                                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2657                                                         if(i < mapvote_count_real)
2658                                                         {
2659                                                                 strunzone(mapvote_maps[i]);
2660                                                                 mapvote_maps[i] = "";
2661                                                                 strunzone(mapvote_maps_pakfile[i]);
2662                                                                 mapvote_maps_pakfile[i] = "";
2663                                                         }
2664                                                 }
2665                                 }
2666                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2667                         if(autocvar_sv_eventlog)
2668                                 GameLogEcho(result);
2669                 }
2670
2671         return FALSE;
2672 }
2673 void MapVote_Tick()
2674 {
2675         float keeptwo;
2676         float totalvotes;
2677
2678         keeptwo = mapvote_keeptwotime;
2679         MapVote_CheckRules_1(); // count
2680         if(MapVote_CheckRules_2()) // decide
2681                 return;
2682
2683         totalvotes = 0;
2684         FOR_EACH_REALCLIENT(other)
2685         {
2686                 // hide scoreboard again
2687                 if(other.health != 2342)
2688                 {
2689                         other.health = 2342;
2690                         other.impulse = 0;
2691                         if(clienttype(other) == CLIENTTYPE_REAL)
2692                         {
2693                                 msg_entity = other;
2694                                 WriteByte(MSG_ONE, SVC_FINALE);
2695                                 WriteString(MSG_ONE, "");
2696                         }
2697                 }
2698
2699                 // clear possibly invalid votes
2700                 if(mapvote_maps[other.mapvote - 1] == "")
2701                         other.mapvote = 0;
2702                 // use impulses as new vote
2703                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2704                         if(mapvote_maps[other.impulse - 1] != "")
2705                         {
2706                                 other.mapvote = other.impulse;
2707                                 MapVote_TouchVotes(other);
2708                         }
2709                 other.impulse = 0;
2710
2711                 if(other.mapvote)
2712                         ++totalvotes;
2713         }
2714
2715         MapVote_CheckRules_1(); // just count
2716 }
2717 void MapVote_Start()
2718 {
2719         if(mapvote_run)
2720                 return;
2721
2722         // wait for stats to be sent first
2723         if(!playerstats_waitforme)
2724                 return;
2725
2726         MapInfo_Enumerate();
2727         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2728                 mapvote_run = TRUE;
2729 }
2730 void MapVote_Think()
2731 {
2732         if(!mapvote_run)
2733                 return;
2734
2735         if(alreadychangedlevel)
2736                 return;
2737
2738         if(time < mapvote_nextthink)
2739                 return;
2740         //dprint("tick\n");
2741
2742         mapvote_nextthink = time + 0.5;
2743
2744         if(!mapvote_initialized)
2745         {
2746                 if(autocvar_rescan_pending == 1)
2747                 {
2748                         cvar_set("rescan_pending", "2");
2749                         localcmd("fs_rescan\nrescan_pending 3\n");
2750                         return;
2751                 }
2752                 else if(autocvar_rescan_pending == 2)
2753                 {
2754                         return;
2755                 }
2756                 else if(autocvar_rescan_pending == 3)
2757                 {
2758                         // now build missing mapinfo files
2759                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2760                                 return;
2761
2762                         // we're done, start the timer
2763                         cvar_set("rescan_pending", "0");
2764                 }
2765
2766                 mapvote_initialized = TRUE;
2767                 if(DoNextMapOverride(0))
2768                         return;
2769                 if(!autocvar_g_maplist_votable || player_count <= 0)
2770                 {
2771                         GotoNextMap(0);
2772                         return;
2773                 }
2774                 MapVote_Init();
2775         }
2776
2777         MapVote_Tick();
2778 }
2779
2780 string GotoMap(string m)
2781 {
2782         if(!MapInfo_CheckMap(m))
2783                 return "The map you chose is not available on this server.";
2784         cvar_set("nextmap", m);
2785         cvar_set("timelimit", "-1");
2786         if(mapvote_initialized || alreadychangedlevel)
2787         {
2788                 if(DoNextMapOverride(0))
2789                         return "Map switch initiated.";
2790                 else
2791                         return "Hm... no. For some reason I like THIS map more.";
2792         }
2793         else
2794                 return "Map switch will happen after scoreboard.";
2795 }
2796
2797
2798 void EndFrame()
2799 {
2800         float altime;
2801         FOR_EACH_REALCLIENT(self)
2802         {
2803                 if(self.classname == "spectator")
2804                 {
2805                         if(self.enemy.typehitsound)
2806                                 self.typehit_time = time;
2807                         else if(self.enemy.hitsound)
2808                                 self.hit_time = time;
2809                 }
2810                 else
2811                 {
2812                         if(self.typehitsound)
2813                                 self.typehit_time = time;
2814                         else if(self.hitsound)
2815                                 self.hit_time = time;
2816                 }
2817         }
2818         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2819         // add 1 frametime because after this, engine SV_Physics
2820         // increases time by a frametime and then networks the frame
2821         // add another frametime because client shows everything with
2822         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2823         // needed!
2824         FOR_EACH_CLIENT(self)
2825         {
2826                 self.hitsound = FALSE;
2827                 self.typehitsound = FALSE;
2828                 antilag_record(self, altime);
2829         }
2830 }
2831
2832
2833 /*
2834  * RedirectionThink:
2835  * returns TRUE if redirecting
2836  */
2837 float redirection_timeout;
2838 float redirection_nextthink;
2839 float RedirectionThink()
2840 {
2841         float clients_found;
2842
2843         if(redirection_target == "")
2844                 return FALSE;
2845
2846         if(!redirection_timeout)
2847         {
2848                 cvar_set("sv_public", "-2");
2849                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2850                 if(redirection_target == "self")
2851                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2852                 else
2853                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2854         }
2855
2856         if(time < redirection_nextthink)
2857                 return TRUE;
2858
2859         redirection_nextthink = time + 1;
2860
2861         clients_found = 0;
2862         FOR_EACH_REALCLIENT(self)
2863         {
2864                 // TODO add timer
2865                 print("Redirecting: sending connect command to ", self.netname, "\n");
2866                 if(redirection_target == "self")
2867                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2868                 else
2869                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2870                 ++clients_found;
2871         }
2872
2873         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2874
2875         if(time > redirection_timeout || clients_found == 0)
2876                 localcmd("\nwait; wait; wait; quit\n");
2877
2878         return TRUE;
2879 }
2880
2881 void TargetMusic_RestoreGame();
2882 void RestoreGame()
2883 {
2884         // Loaded from a save game
2885         // some things then break, so let's work around them...
2886
2887         // Progs DB (capture records)
2888         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2889
2890         // Mapinfo
2891         MapInfo_Shutdown();
2892         MapInfo_Enumerate();
2893         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2894         WeaponStats_Init();
2895
2896         TargetMusic_RestoreGame();
2897 }
2898
2899 void Shutdown()
2900 {
2901         entity e;
2902
2903         gameover = 2;
2904
2905         if(world_initialized > 0)
2906         {
2907                 world_initialized = 0;
2908                 print("Saving persistent data...\n");
2909                 Ban_SaveBans();
2910
2911                 PlayerStats_EndMatch(0);
2912                 FOR_EACH_CLIENT(e)
2913                         PlayerStats_AddGlobalInfo(e);
2914                 PlayerStats_Shutdown();
2915
2916                 if(!cheatcount_total)
2917                 {
2918                         if(autocvar_sv_db_saveasdump)
2919                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2920                         else
2921                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2922                 }
2923                 if(autocvar_developer)
2924                 {
2925                         if(autocvar_sv_db_saveasdump)
2926                                 db_dump(TemporaryDB, "server-temp.db");
2927                         else
2928                                 db_save(TemporaryDB, "server-temp.db");
2929                 }
2930                 CheatShutdown(); // must be after cheatcount check
2931                 db_close(ServerProgsDB);
2932                 db_close(TemporaryDB);
2933                 print("done!\n");
2934                 // tell the bot system the game is ending now
2935                 bot_endgame();
2936
2937                 WeaponStats_Shutdown();
2938                 MapInfo_Shutdown();
2939         }
2940         else if(world_initialized == 0)
2941         {
2942                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2943         }
2944 }