qcsrc/server/g_world.qc

   1 entity pingplreport;
   2 void PingPLReport_Think()
   3 {
   4         float delta;
   5         entity e;
   6
   7         delta = 3 / maxclients;
   8         if(delta < sys_frametime)
   9                 delta = 0;
  10         self.nextthink = time + delta;
  11
  12         e = edict_num(self.cnt + 1);
  13         if(clienttype(e) == CLIENTTYPE_REAL)
  14         {
  15                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  16                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  17                 WriteByte(MSG_BROADCAST, self.cnt);
  18                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  19                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  20                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  21         }
  22         else
  23         {
  24                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  25                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  26                 WriteByte(MSG_BROADCAST, self.cnt);
  27                 WriteShort(MSG_BROADCAST, 0);
  28                 WriteByte(MSG_BROADCAST, 0);
  29                 WriteByte(MSG_BROADCAST, 0);
  30         }
  31         self.cnt = mod(self.cnt + 1, maxclients);
  32 }
  33 void PingPLReport_Spawn()
  34 {
  35         pingplreport = spawn();
  36         pingplreport.classname = "pingplreport";
  37         pingplreport.think = PingPLReport_Think;
  38         pingplreport.nextthink = time;
  39 }
  40
  41 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  42 string redirection_target;
  43 float world_initialized;
  44
  45 string GetMapname();
  46 string GetGametype();
  47 void GotoNextMap();
  48 void ShuffleMaplist()
  49 float() DoNextMapOverride;
  50
  51 void SetDefaultAlpha()
  52 {
  53         if(cvar("g_running_guns"))
  54         {
  55                 default_player_alpha = -1;
  56                 default_weapon_alpha = +1;
  57         }
  58         else if(g_cloaked)
  59         {
  60                 default_player_alpha = cvar("g_balance_cloaked_alpha");
  61                 default_weapon_alpha = default_player_alpha;
  62         }
  63         else
  64         {
  65                 default_player_alpha = cvar("g_player_alpha");
  66                 if(default_player_alpha == 0)
  67                         default_player_alpha = 1;
  68                 default_weapon_alpha = default_player_alpha;
  69         }
  70 }
  71
  72 void fteqcc_testbugs()
  73 {
  74         float a, b;
  75
  76         if(!cvar("developer_fteqccbugs"))
  77                 return;
  78
  79         dprint("*** fteqcc test: checking for bugs...\n");
  80
  81         a = 1;
  82         b = 5;
  83         if(sqrt(a) - sqrt(b - a) == 0)
  84                 dprint("*** fteqcc test: found same-function-twice bug\n");
  85         else
  86                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  87
  88         world.cnt = -10;
  89         world.enemy = world;
  90         world.enemy.cnt += 10;
  91         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  92                 dprint("*** fteqcc test: found += bug\n");
  93         else
  94                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  95         world.cnt = 0;
  96 }
  97
  98 /**
  99  * Takes care of pausing and unpausing the game.
 100  * Centerprints the information about an upcoming or active timeout to all active
 101  * players. Also plays reminder sounds.
 102  */
 103 void timeoutHandler_Think() {
 104         local string timeStr;
 105         local entity plr;
 106         if (timeoutStatus == 1) {
 107                 if (remainingLeadTime > 0) {
 108                         //centerprint the information to every player
 109                         timeStr = getTimeoutText(0);
 110                         FOR_EACH_REALCLIENT(plr) {
 111                                 if(plr.classname == "player") {
 112                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 113                                 }
 114                         }
 115                         remainingLeadTime -= 1;
 116                         //think again in 1 second:
 117                         self.nextthink = time + 1;
 118                 }
 119                 else {
 120                         //now pause the game:
 121                         timeoutStatus = 2;
 122                         //reset all the flood variables
 123                         FOR_EACH_CLIENT(plr) {
 124                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
 125                         }
 126                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 127                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 128                         FOR_EACH_REALPLAYER(plr) {
 129                                 plr.lastV_angle = plr.v_angle;
 130                         }
 131                         self.nextthink = time;
 132                 }
 133         }
 134         else if (timeoutStatus == 2) {
 135                 if (remainingTimeoutTime > 0) {
 136                         timeStr = getTimeoutText(0);
 137                         FOR_EACH_REALCLIENT(plr) {
 138                                 if(plr.classname == "player") {
 139                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 140                                 }
 141                         }
 142                         if(remainingTimeoutTime == cvar("sv_timeout_resumetime")) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 143                                 Announce("prepareforbattle");
 144                         }
 145                         remainingTimeoutTime -= 1;
 146                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 147                 }
 148                 else {
 149                         //unpause the game again
 150                         remainingTimeoutTime = timeoutStatus = 0;
 151                         cvar_set("slowmo", ftos(orig_slowmo));
 152                         //and unlock the fixed view again once there is no timeout active anymore
 153                         FOR_EACH_REALPLAYER(plr) {
 154                                 plr.fixangle = FALSE;
 155                         }
 156                         //get rid of the countdown message
 157                         FOR_EACH_REALCLIENT(plr) {
 158                                 if(plr.classname == "player") {
 159                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 160                                 }
 161                         }
 162                         remove(self);
 163                         return;
 164                 }
 165
 166         }
 167         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 168                 FOR_EACH_REALCLIENT(plr) {
 169                         if(plr.classname == "player") {
 170                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 171                         }
 172                 }
 173                 remove(self);
 174                 return;
 175         }
 176 }
 177
 178 void GotoFirstMap()
 179 {
 180         float n;
 181         if(cvar("_sv_init"))
 182         {
 183                 // cvar_set("_sv_init", "0");
 184                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 185                 // to this "init" map on a dedicated server will cause no permanent
 186                 // harm
 187                 if(cvar("g_maplist_shuffle"))
 188                         ShuffleMaplist();
 189                 n = tokenizebyseparator(cvar_string("g_maplist"), " ");
 190                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 191
 192                 MapInfo_Enumerate();
 193                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 194
 195                 if(!DoNextMapOverride())
 196                         GotoNextMap();
 197
 198                 return;
 199         }
 200
 201         if(time < 5)
 202         {
 203                 self.nextthink = time;
 204         }
 205         else
 206         {
 207                 self.nextthink = time + 1;
 208                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 209         }
 210 }
 211
 212 void cvar_changes_init()
 213 {
 214         float h;
 215         string k, v, d;
 216         float n, i, adding, pureadding;
 217
 218         if(cvar_changes)
 219                 strunzone(cvar_changes);
 220         cvar_changes = string_null;
 221         if(cvar_purechanges)
 222                 strunzone(cvar_purechanges);
 223         cvar_purechanges = string_null;
 224         cvar_purechanges_count = 0;
 225
 226         h = buf_create();
 227         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 228         n = buf_getsize(h);
 229
 230         adding = TRUE;
 231         pureadding = TRUE;
 232
 233         for(i = 0; i < n; ++i)
 234         {
 235                 k = bufstr_get(h, i);
 236
 237 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 238 #define BADCVAR(p) if(k == p) continue
 239                 // internal
 240                 BADPREFIX("csqc_");
 241                 BADPREFIX("cvar_check_");
 242                 BADCVAR("gamecfg");
 243                 BADCVAR("g_configversion");
 244                 BADCVAR("g_maplist_index");
 245                 BADCVAR("halflifebsp");
 246                 BADPREFIX("sv_world");
 247
 248                 // client
 249                 BADPREFIX("chase_");
 250                 BADPREFIX("cl_");
 251                 BADPREFIX("con_");
 252                 BADPREFIX("scoreboard_");
 253                 BADPREFIX("g_campaign");
 254                 BADPREFIX("gl_");
 255                 BADPREFIX("joy");
 256                 BADPREFIX("hud_");
 257                 BADPREFIX("menu_");
 258                 BADPREFIX("net_slist_");
 259                 BADPREFIX("r_");
 260                 BADPREFIX("sbar_");
 261                 BADPREFIX("scr_");
 262                 BADPREFIX("snd_");
 263                 BADPREFIX("userbind");
 264                 BADPREFIX("v_");
 265                 BADPREFIX("vid_");
 266                 BADPREFIX("crosshair");
 267                 BADCVAR("mod_q3bsp_lightmapmergepower");
 268                 BADCVAR("mod_q3bsp_nolightmaps");
 269                 BADCVAR("fov");
 270                 BADCVAR("mastervolume");
 271                 BADCVAR("volume");
 272                 BADCVAR("bgmvolume");
 273
 274                 // private
 275                 BADCVAR("serverconfig");
 276                 BADPREFIX("g_ban_");
 277                 BADPREFIX("g_chat_flood_");
 278                 BADPREFIX("g_voice_flood_");
 279                 BADPREFIX("rcon_");
 280                 BADPREFIX("settemp_");
 281                 BADPREFIX("sv_allowdownloads_");
 282                 BADPREFIX("sv_autodemo");
 283                 BADPREFIX("sv_curl_");
 284                 BADPREFIX("sv_eventlog");
 285                 BADPREFIX("sv_logscores_");
 286                 BADPREFIX("sv_master");
 287                 BADCVAR("g_banned_list");
 288                 BADCVAR("log_dest_udp");
 289                 BADCVAR("log_file");
 290                 BADCVAR("net_address");
 291                 BADCVAR("port");
 292                 BADCVAR("savedgamecfg");
 293                 BADCVAR("sv_heartbeatperiod");
 294                 BADCVAR("sv_vote_master_password");
 295                 BADCVAR("sys_colortranslation");
 296                 BADCVAR("sys_specialcharactertranslation");
 297                 BADCVAR("timestamps");
 298                 BADCVAR("net_address");
 299                 BADCVAR("net_address_ipv6");
 300                 BADPREFIX("sv_weaponstats_");
 301                 BADCVAR("developer");
 302                 BADPREFIX("developer_");
 303
 304                 // mapinfo
 305                 BADCVAR("timelimit");
 306                 BADCVAR("fraglimit");
 307                 BADCVAR("leadlimit");
 308                 BADCVAR("g_tdm_teams");
 309                 BADCVAR("g_keyhunt_teams");
 310                 BADCVAR("g_domination_default_teams");
 311                 BADCVAR("g_race_qualifying_timelimit");
 312                 BADCVAR("g_lms");
 313                 BADCVAR("g_arena");
 314                 BADCVAR("g_ca");
 315                 BADCVAR("g_assault");
 316                 BADCVAR("g_ctf");
 317                 BADCVAR("g_dm");
 318                 BADCVAR("g_domination");
 319                 BADCVAR("g_keyhunt");
 320                 BADCVAR("g_keyhunt_teams");
 321                 BADCVAR("g_onslaught");
 322                 BADCVAR("g_race");
 323                 BADCVAR("g_cts");
 324                 BADCVAR("g_runematch");
 325                 BADCVAR("g_tdm");
 326                 BADCVAR("g_nexball");
 327                 BADCVAR("teamplay");
 328
 329                 // long
 330                 BADCVAR("hostname");
 331                 BADCVAR("g_maplist");
 332                 BADCVAR("g_maplist_mostrecent");
 333                 BADCVAR("sv_motd");
 334
 335                 v = cvar_string(k);
 336                 d = cvar_defstring(k);
 337                 if(v == d)
 338                         continue;
 339
 340                 if(adding)
 341                 {
 342                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 343                         if(strlen(cvar_changes) > 16384)
 344                         {
 345                                 cvar_changes = "// too many settings have been changed to show them here\n";
 346                                 adding = 0;
 347                         }
 348                 }
 349
 350                 // now check if the changes are actually gameplay relevant
 351
 352                 // does nothing visible
 353                 BADCVAR("captureleadlimit_override");
 354                 BADCVAR("g_arena_point_leadlimit");
 355                 BADCVAR("g_ca_point_leadlimit");
 356                 BADCVAR("g_ctf_capture_leadlimit");
 357                 BADCVAR("g_domination_point_leadlimit");
 358                 BADCVAR("g_keyhunt_point_leadlimit");
 359                 BADCVAR("g_nexball_goalleadlimit");
 360                 BADCVAR("g_runematch_point_leadlimit");
 361                 BADCVAR("leadlimit_and_fraglimit");
 362                 BADCVAR("leadlimit_override");
 363                 BADPREFIX("crypto_");
 364                 BADPREFIX("g_chat_");
 365                 BADPREFIX("prvm_");
 366                 BADPREFIX("sv_fragmessage_");
 367                 BADPREFIX("sv_vote_");
 368                 BADPREFIX("timelimit_");
 369
 370                 // allowed changes to server admins (please sync this to server.cfg)
 371                 // vi commands:
 372                 //   :/"impure"/,$d
 373                 //   :g!,^\/\/[^ /],d
 374                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 375                 //   :%!sort
 376                 // yes, this does contain some redundant stuff, don't really care
 377                 BADCVAR("bot_number");
 378                 BADCVAR("bot_prefix");
 379                 BADCVAR("bot_suffix");
 380                 BADCVAR("capturelimit_override");
 381                 BADCVAR("fraglimit_override");
 382                 BADCVAR("gametype");
 383                 BADCVAR("g_antilag");
 384                 BADCVAR("g_balance_teams");
 385                 BADCVAR("g_balance_teams_force");
 386                 BADCVAR("g_ban_sync_trusted_servers");
 387                 BADCVAR("g_ban_sync_uri");
 388                 BADCVAR("g_ctf_capture_limit");
 389                 BADCVAR("g_ctf_ignore_frags");
 390                 BADCVAR("g_ctf_win_mode");
 391                 BADCVAR("g_domination_point_limit");
 392                 BADCVAR("g_fullbrightitems");
 393                 BADCVAR("g_fullbrightplayers");
 394                 BADCVAR("g_keyhunt_point_limit");
 395                 BADCVAR("g_keyhunt_teams_override");
 396                 BADCVAR("g_lms_lives_override");
 397                 BADCVAR("g_maplist");
 398                 BADCVAR("g_maplist_check_waypoints");
 399                 BADCVAR("g_maplist_mostrecent_count");
 400                 BADCVAR("g_maplist_shuffle");
 401                 BADCVAR("g_maplist_votable");
 402                 BADCVAR("g_maplist_votable_abstain");
 403                 BADCVAR("g_maplist_votable_nodetail");
 404                 BADCVAR("g_maplist_votable_suggestions");
 405                 BADCVAR("g_nexball_goallimit");
 406                 BADCVAR("g_runematch_point_limit");
 407                 BADCVAR("g_start_delay");
 408                 BADCVAR("hostname");
 409                 BADCVAR("log_file");
 410                 BADCVAR("maxplayers");
 411                 BADCVAR("minplayers");
 412                 BADCVAR("net_address");
 413                 BADCVAR("port");
 414                 BADCVAR("rcon_password");
 415                 BADCVAR("rcon_restricted_commands");
 416                 BADCVAR("rcon_restricted_password");
 417                 BADCVAR("skill");
 418                 BADCVAR("sv_adminnick");
 419                 BADCVAR("sv_autoscreenshot");
 420                 BADCVAR("sv_curl_defaulturl");
 421                 BADCVAR("sv_defaultcharacter");
 422                 BADCVAR("sv_defaultplayermodel");
 423                 BADCVAR("sv_defaultplayerskin");
 424                 BADCVAR("sv_maxidle");
 425                 BADCVAR("sv_maxrate");
 426                 BADCVAR("sv_motd");
 427                 BADCVAR("sv_public");
 428                 BADCVAR("sv_ready_restart");
 429                 BADCVAR("sv_status_privacy");
 430                 BADCVAR("sv_vote_call");
 431                 BADCVAR("sv_vote_commands");
 432                 BADCVAR("sv_vote_majority_factor");
 433                 BADCVAR("sv_vote_master");
 434                 BADCVAR("sv_vote_master_commands");
 435                 BADCVAR("sv_vote_master_password");
 436                 BADCVAR("sv_vote_simple_majority_factor");
 437                 BADCVAR("timelimit_override");
 438 #undef BADPREFIX
 439 #undef BADCVAR
 440
 441                 if(pureadding)
 442                 {
 443                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 444                         if(strlen(cvar_purechanges) > 16384)
 445                         {
 446                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 447                                 pureadding = 0;
 448                         }
 449                 }
 450                 ++cvar_purechanges_count;
 451         }
 452         buf_del(h);
 453         if(cvar_changes == "")
 454                 cvar_changes = "// this server runs at default server settings\n";
 455         else
 456                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 457         cvar_changes = strzone(cvar_changes);
 458         if(cvar_purechanges == "")
 459                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 460         else
 461                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 462         cvar_purechanges = strzone(cvar_purechanges);
 463 }
 464
 465 void detect_maptype()
 466 {
 467 #if 0
 468         vector o, v;
 469         float i;
 470
 471         for(;;)
 472         {
 473                 o = world.mins;
 474                 o_x += random() * (world.maxs_x - world.mins_x);
 475                 o_y += random() * (world.maxs_y - world.mins_y);
 476                 o_z += random() * (world.maxs_z - world.mins_z);
 477
 478                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 479                 if(trace_fraction == 1)
 480                         continue;
 481
 482                 v = trace_endpos;
 483
 484                 for(i = 0; i < 64; i += 4)
 485                 {
 486                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 487         if(trace_fraction == 1)
 488                 continue;
 489                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 490                 }
 491
 492                 break;
 493         }
 494 #endif
 495 }
 496
 497 entity randomseed;
 498 float RandomSeed_Send(entity to, float sf)
 499 {
 500         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 501         WriteShort(MSG_ENTITY, self.cnt);
 502         return TRUE;
 503 }
 504 void RandomSeed_Think()
 505 {
 506         self.cnt = bound(0, floor(random() * 65536), 65535);
 507         self.nextthink = time + 5;
 508
 509         self.SendFlags |= 1;
 510 }
 511 void RandomSeed_Spawn()
 512 {
 513         randomseed = spawn();
 514         randomseed.think = RandomSeed_Think;
 515         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 516
 517         entity oldself;
 518         oldself = self;
 519         self = randomseed;
 520         self.think(); // sets random seed and nextthink
 521         self = oldself;
 522 }
 523
 524 void spawnfunc___init_dedicated_server(void)
 525 {
 526         // handler for _init/_init map (only for dedicated server initialization)
 527
 528         world_initialized = -1; // don't complain
 529         cvar = cvar_normal;
 530         cvar_string = cvar_string_normal;
 531         cvar_set = cvar_set_normal;
 532
 533         remove = remove_unsafely;
 534
 535         entity e;
 536         e = spawn();
 537         e.think = GotoFirstMap;
 538         e.nextthink = time; // this is usually 1 at this point
 539
 540         e = spawn();
 541         e.classname = "info_player_deathmatch"; // safeguard against player joining
 542
 543         self.classname = "worldspawn"; // safeguard against various stuff ;)
 544
 545         MapInfo_Enumerate();
 546         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 547 }
 548
 549 void Map_MarkAsRecent(string m);
 550 float world_already_spawned;
 551 void RegisterWeapons();
 552 void Nagger_Init();
 553 void ClientInit_Spawn();
 554 void WeaponStats_Init();
 555 void WeaponStats_Shutdown();
 556 void spawnfunc_worldspawn (void)
 557 {
 558         float fd, l, i, j, n;
 559         string s, col;
 560
 561         cvar = cvar_normal;
 562         cvar_string = cvar_string_normal;
 563         cvar_set = cvar_set_normal;
 564
 565         if(world_already_spawned)
 566                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 567         world_already_spawned = TRUE;
 568
 569         remove = remove_safely; // during spawning, watch what you remove!
 570
 571         check_unacceptable_compiler_bugs();
 572
 573         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 574
 575         compressShortVector_init();
 576
 577         allowed_to_spawn = TRUE;
 578
 579         local entity head;
 580         head = nextent(world);
 581         maxclients = 0;
 582         while(head)
 583         {
 584                 ++maxclients;
 585                 head = nextent(head);
 586         }
 587
 588         // needs to be done so early as they would still spawn
 589         RegisterWeapons();
 590
 591         ServerProgsDB = db_load("server.db");
 592
 593         TemporaryDB = db_create();
 594
 595         /*
 596         TODO sound pack system
 597         // initialize sound pack system
 598         soundpack = cvar_string("g_soundpack");
 599         if(soundpack != "")
 600                 soundpack = strcat(soundpack, "/");
 601         soundpack = strzone(soundpack);
 602         */
 603
 604         // 0 normal
 605         lightstyle(0, "m");
 606
 607         // 1 FLICKER (first variety)
 608         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 609
 610         // 2 SLOW STRONG PULSE
 611         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 612
 613         // 3 CANDLE (first variety)
 614         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 615
 616         // 4 FAST STROBE
 617         lightstyle(4, "mamamamamama");
 618
 619         // 5 GENTLE PULSE 1
 620         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 621
 622         // 6 FLICKER (second variety)
 623         lightstyle(6, "nmonqnmomnmomomno");
 624
 625         // 7 CANDLE (second variety)
 626         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 627
 628         // 8 CANDLE (third variety)
 629         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 630
 631         // 9 SLOW STROBE (fourth variety)
 632         lightstyle(9, "aaaaaaaazzzzzzzz");
 633
 634         // 10 FLUORESCENT FLICKER
 635         lightstyle(10, "mmamammmmammamamaaamammma");
 636
 637         // 11 SLOW PULSE NOT FADE TO BLACK
 638         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 639
 640         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 641
 642         // 63 testing
 643         lightstyle(63, "a");
 644
 645         if(cvar("g_campaign"))
 646                 CampaignPreInit();
 647
 648         Map_MarkAsRecent(mapname);
 649
 650         precache_model ("null"); // we need this one before InitGameplayMode
 651         InitGameplayMode();
 652         readlevelcvars();
 653         GrappleHookInit();
 654         ElectroInit();
 655         LaserInit();
 656
 657         player_count = 0;
 658         bot_waypoints_for_items = cvar("g_waypoints_for_items");
 659         if(bot_waypoints_for_items == 1)
 660                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 661                         bot_waypoints_for_items = 0;
 662
 663         // for setting by mapinfo
 664         q3acompat_machineshotgunswap = cvar("sv_q3acompat_machineshotgunswap");
 665         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 666
 667         precache();
 668
 669         WaypointSprite_Init();
 670
 671         //if (g_domination)
 672         //      dom_init();
 673
 674         GameLogInit(); // prepare everything
 675         if(cvar("sv_eventlog"))
 676         {
 677                 s = strcat(cvar_string("sv_eventlog_files_counter"), ".");
 678                 s = strcat(s, ftos(random()));
 679                 matchid = strzone(s);
 680
 681                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 682                 s = ":gameinfo:mutators:LIST";
 683
 684                 ret_string = s;
 685                 MUTATOR_CALLHOOK(BuildMutatorsString);
 686                 s = ret_string;
 687
 688                 if(cvar("g_grappling_hook"))
 689                         s = strcat(s, ":grappling_hook");
 690                 if(!cvar("g_use_ammunition"))
 691                         s = strcat(s, ":no_use_ammunition");
 692                 if(!cvar("g_pickup_items"))
 693                         s = strcat(s, ":no_pickup_items");
 694                 if(cvar_string("g_weaponarena") != "0")
 695                         s = strcat(s, ":", cvar_string("g_weaponarena"), " arena");
 696                 if(cvar("g_vampire"))
 697                         s = strcat(s, ":vampire");
 698                 if(cvar("g_laserguided_missile"))
 699                         s = strcat(s, ":laserguided_missile");
 700                 if(cvar("g_norecoil"))
 701                         s = strcat(s, ":norecoil");
 702                 if(cvar("g_midair"))
 703                         s = strcat(s, ":midair");
 704                 if(cvar("g_minstagib"))
 705                         s = strcat(s, ":minstagib");
 706                 GameLogEcho(s);
 707                 GameLogEcho(":gameinfo:end");
 708         }
 709         else
 710                 matchid = strzone(ftos(random()));
 711
 712         cvar_set("nextmap", "");
 713
 714         SetDefaultAlpha();
 715
 716         if(cvar("g_campaign"))
 717                 CampaignPostInit();
 718
 719         fteqcc_testbugs();
 720
 721         Ban_LoadBans();
 722
 723         MapInfo_Enumerate();
 724         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 725
 726         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 727         {
 728                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 729                 if(fd != -1)
 730                 {
 731                         while((s = fgets(fd)))
 732                         {
 733                                 l = tokenize_console(s);
 734                                 if(l < 2)
 735                                         continue;
 736                                 if(argv(0) == "cd")
 737                                 {
 738                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 739                                         print("  cdtrack ", argv(2), "\n");
 740                                 }
 741                                 else if(argv(0) == "fog")
 742                                 {
 743                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 744                                         print("  \"fog\" \"", s, "\"\n");
 745                                 }
 746                                 else if(argv(0) == "set")
 747                                 {
 748                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 749                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 750                                 }
 751                                 else if(argv(0) != "//")
 752                                 {
 753                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 754                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 755                                 }
 756                         }
 757                         fclose(fd);
 758                 }
 759         }
 760
 761         WeaponStats_Init();
 762
 763         addstat(STAT_WEAPONS, AS_INT, weapons);
 764         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 765         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 766         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 767         Nagger_Init();
 768
 769         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 770         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 771         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 772         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 773         addstat(STAT_DAMAGE_HITS, AS_INT, stat_hit);
 774         addstat(STAT_DAMAGE_FIRED, AS_INT, stat_fired);
 775         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 776         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 777         addstat(STAT_BULLETS_LOADED, AS_INT, campingrifle_bulletcounter);
 778         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 779
 780         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 781
 782         if(g_ca)
 783         {
 784                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 785                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 786         }
 787         // g_movementspeed hack
 788         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 789         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 790         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 791
 792         next_pingtime = time + 5;
 793
 794         detect_maptype();
 795
 796         lsmaps_reply = "^7Maps available: ";
 797         lsnewmaps_reply = "^7Maps without a record set: ";
 798         for(i = 0, j = 0; i < MapInfo_count; ++i)
 799         {
 800                 if(MapInfo_Get_ByID(i))
 801                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 802                         {
 803                                 if(mod(i, 2))
 804                                         col = "^2";
 805                                 else
 806                                         col = "^3";
 807                                 ++j;
 808                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 809                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 810                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 811                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 812                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 813                         }
 814         }
 815         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 816         if (!g_race && !g_cts)
 817                 lsnewmaps_reply = "Need to be playing race or CTS for lsnewmaps to work.";
 818         lsnewmaps_reply = strzone(strcat(lsnewmaps_reply, "\n"));
 819
 820         maplist_reply = "^7Maps in list: ";
 821         n = tokenize_console(cvar_string("g_maplist"));
 822         for(i = 0, j = 0; i < n; ++i)
 823         {
 824                 if(MapInfo_CheckMap(argv(i)))
 825                 {
 826                         if(mod(j, 2))
 827                                 col = "^2";
 828                         else
 829                                 col = "^3";
 830                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 831                         ++j;
 832                 }
 833         }
 834         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 835         MapInfo_ClearTemps();
 836
 837         for(i = 0; i < 10; ++i)
 838         {
 839                 records_reply[i] = strzone(getrecords(i));
 840         }
 841         if(g_cts)
 842                 ladder_reply = strzone(getladder());
 843
 844         rankings_reply = strzone(getrankings());
 845
 846         ClientInit_Spawn();
 847         RandomSeed_Spawn();
 848         PingPLReport_Spawn();
 849
 850         CheatInit();
 851
 852         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 853
 854         // fill sv_curl_serverpackages from .serverpackage files
 855         if(cvar("sv_curl_serverpackages_auto"))
 856         {
 857                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 858                 s = "";
 859                 if(fd >= 0)
 860                 {
 861                         j = search_getsize(fd);
 862                         for(i = 0; i < j; ++i)
 863                                 s = strcat(s, " ", search_getfilename(fd, i));
 864                         search_end(fd);
 865                 }
 866                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 867         }
 868
 869         world_initialized = 1;
 870 }
 871
 872 void spawnfunc_light (void)
 873 {
 874         //makestatic (self); // Who the f___ did that?
 875         remove(self);
 876 }
 877
 878 float TryFile( string pFilename )
 879 {
 880         local float lHandle;
 881         dprint("TryFile(\"", pFilename, "\")\n");
 882         lHandle = fopen( pFilename, FILE_READ );
 883         if( lHandle != -1 ) {
 884                 fclose( lHandle );
 885                 return TRUE;
 886         } else {
 887                 return FALSE;
 888         }
 889 };
 890
 891 string GetGametype()
 892 {
 893         return GametypeNameFromType(game);
 894 }
 895
 896 string getmapname_stored;
 897 string GetMapname()
 898 {
 899         return mapname;
 900 }
 901
 902 float Map_Count, Map_Current;
 903 string Map_Current_Name;
 904
 905 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 906 float GetMaplistPosition()
 907 {
 908         float pos, idx;
 909         string map;
 910
 911         map = GetMapname();
 912         idx = cvar("g_maplist_index");
 913
 914         if(idx >= 0)
 915                 if(idx < Map_Count)
 916                         if(map == argv(idx))
 917                                 return idx;
 918
 919         for(pos = 0; pos < Map_Count; ++pos)
 920                 if(map == argv(pos))
 921                         return pos;
 922
 923         // resume normal maplist rotation if current map is not in g_maplist
 924         return idx;
 925 }
 926
 927 float MapHasRightSize(string map)
 928 {
 929         float fh;
 930         if(currentbots || cvar("bot_number") || player_count < cvar("minplayers"))
 931         if(cvar("g_maplist_check_waypoints"))
 932         {
 933                 dprint("checkwp "); dprint(map);
 934                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
 935                 if(fh < 0)
 936                 {
 937                         dprint(": no waypoints\n");
 938                         return FALSE;
 939                 }
 940                 dprint(": has waypoints\n");
 941                 fclose(fh);
 942         }
 943
 944         // open map size restriction file
 945         dprint("opensize "); dprint(map);
 946         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 947         if(fh >= 0)
 948         {
 949                 float mapmin, mapmax;
 950                 dprint(": ok, ");
 951                 mapmin = stof(fgets(fh));
 952                 mapmax = stof(fgets(fh));
 953                 fclose(fh);
 954                 if(player_count < mapmin)
 955                 {
 956                         dprint("not enough\n");
 957                         return FALSE;
 958                 }
 959                 if(player_count > mapmax)
 960                 {
 961                         dprint("too many\n");
 962                         return FALSE;
 963                 }
 964                 dprint("right size\n");
 965                 return TRUE;
 966         }
 967         dprint(": not found\n");
 968         return TRUE;
 969 }
 970
 971 string Map_Filename(float position)
 972 {
 973         return strcat("maps/", argv(position), ".bsp");
 974 }
 975
 976 string strwords(string s, float w)
 977 {
 978         float endpos;
 979         for(endpos = 0; w && endpos >= 0; --w)
 980                 endpos = strstrofs(s, " ", endpos + 1);
 981         if(endpos < 0)
 982                 return s;
 983         else
 984                 return substring(s, 0, endpos);
 985 }
 986
 987 float strhasword(string s, string w)
 988 {
 989         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 990 }
 991
 992 void Map_MarkAsRecent(string m)
 993 {
 994         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", cvar_string("g_maplist_mostrecent")), max(0, cvar("g_maplist_mostrecent_count"))));
 995 }
 996
 997 float Map_IsRecent(string m)
 998 {
 999         return strhasword(cvar_string("g_maplist_mostrecent"), m);
1000 }
1001
1002 float Map_Check(float position, float pass)
1003 {
1004         string filename;
1005         string map_next;
1006         map_next = argv(position);
1007         if(pass <= 1)
1008         {
1009                 if(Map_IsRecent(map_next))
1010                         return 0;
1011         }
1012         filename = Map_Filename(position);
1013         if(MapInfo_CheckMap(map_next))
1014         {
1015                 if(pass == 2)
1016                         return 1;
1017                 if(MapHasRightSize(map_next))
1018                         return 1;
1019                 return 0;
1020         }
1021         else
1022                 dprint( "Couldn't select '", filename, "'..\n" );
1023
1024         return 0;
1025 }
1026
1027 void Map_Goto_SetStr(string nextmapname)
1028 {
1029         if(getmapname_stored != "")
1030                 strunzone(getmapname_stored);
1031         if(nextmapname == "")
1032                 getmapname_stored = "";
1033         else
1034                 getmapname_stored = strzone(nextmapname);
1035 }
1036
1037 void Map_Goto_SetFloat(float position)
1038 {
1039         cvar_set("g_maplist_index", ftos(position));
1040         Map_Goto_SetStr(argv(position));
1041 }
1042
1043 void GameResetCfg()
1044 {
1045         // settings persist, except...
1046         localcmd("\nsettemp_restore\n");
1047 };
1048
1049 void Map_Goto()
1050 {
1051         GameResetCfg();
1052         MapInfo_LoadMap(getmapname_stored);
1053 }
1054
1055 // return codes of map selectors:
1056 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1057 //   -2 = permanent failure
1058 float() MaplistMethod_Iterate = // usual method
1059 {
1060         float pass, i;
1061
1062         for(pass = 1; pass <= 2; ++pass)
1063         {
1064                 for(i = 1; i < Map_Count; ++i)
1065                 {
1066                         float mapindex;
1067                         mapindex = mod(i + Map_Current, Map_Count);
1068                         if(Map_Check(mapindex, pass))
1069                                 return mapindex;
1070                 }
1071         }
1072         return -1;
1073 }
1074
1075 float() MaplistMethod_Repeat = // fallback method
1076 {
1077         if(Map_Check(Map_Current, 2))
1078                 return Map_Current;
1079         return -2;
1080 }
1081
1082 float() MaplistMethod_Random = // random map selection
1083 {
1084         float i, imax;
1085
1086         imax = 42;
1087
1088         for(i = 0; i <= imax; ++i)
1089         {
1090                 float mapindex;
1091                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1092                 if(Map_Check(mapindex, 1))
1093                         return mapindex;
1094         }
1095         return -1;
1096 }
1097
1098 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1099 // the exponent sets a bias on the map selection:
1100 // the higher the exponent, the less likely "shortly repeated" same maps are
1101 {
1102         float i, j, imax, insertpos;
1103
1104         imax = 42;
1105
1106         for(i = 0; i <= imax; ++i)
1107         {
1108                 string newlist;
1109
1110                 // now reinsert this at another position
1111                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1112                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1113                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1114                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1115
1116                 // insert the current map there
1117                 newlist = "";
1118                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1119                         newlist = strcat(newlist, " ", argv(j));
1120                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1121                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1122                         newlist = strcat(newlist, " ", argv(j));
1123                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1124                 cvar_set("g_maplist", newlist);
1125                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
1126
1127                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1128                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1129                 if(Map_Check(Map_Current, 1))
1130                         return Map_Current;
1131         }
1132         return -1;
1133 }
1134
1135 void Maplist_Init()
1136 {
1137         Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
1138         if(Map_Count == 0)
1139         {
1140                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1141                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1142                 if(cvar("g_maplist_shuffle"))
1143                         ShuffleMaplist();
1144                 localcmd("\nmenu_cmd sync\n");
1145                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
1146         }
1147         if(Map_Count == 0)
1148                 error("empty maplist, cannot select a new map");
1149         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1150
1151         if(Map_Current_Name)
1152                 strunzone(Map_Current_Name);
1153         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1154         // this may or may not be correct, but who cares, in the worst case a map
1155         // isn't chosen in the first pass that should have been
1156 }
1157
1158 string GetNextMap()
1159 {
1160         float nextMap;
1161
1162         Maplist_Init();
1163         nextMap = -1;
1164
1165         if(nextMap == -1)
1166                 if(cvar("g_maplist_shuffle") > 0)
1167                         nextMap = MaplistMethod_Shuffle(cvar("g_maplist_shuffle") + 1);
1168
1169         if(nextMap == -1)
1170                 if(cvar("g_maplist_selectrandom"))
1171                         nextMap = MaplistMethod_Random();
1172
1173         if(nextMap == -1)
1174                 nextMap = MaplistMethod_Iterate();
1175
1176         if(nextMap == -1)
1177                 nextMap = MaplistMethod_Repeat();
1178
1179         if(nextMap >= 0)
1180         {
1181                 Map_Goto_SetFloat(nextMap);
1182                 return getmapname_stored;
1183         }
1184
1185         return "";
1186 };
1187
1188 float DoNextMapOverride()
1189 {
1190         if(cvar("g_campaign"))
1191         {
1192                 CampaignPostIntermission();
1193                 alreadychangedlevel = TRUE;
1194                 return TRUE;
1195         }
1196         if(cvar("quit_when_empty"))
1197         {
1198                 if(player_count <= currentbots)
1199                 {
1200                         localcmd("quit\n");
1201                         alreadychangedlevel = TRUE;
1202                         return TRUE;
1203                 }
1204         }
1205         if(cvar_string("quit_and_redirect") != "")
1206         {
1207                 redirection_target = strzone(cvar_string("quit_and_redirect"));
1208                 alreadychangedlevel = TRUE;
1209                 return TRUE;
1210         }
1211         if (cvar("samelevel")) // if samelevel is set, stay on same level
1212         {
1213                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
1214                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
1215                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
1216                 localcmd("restart\n");
1217                 //changelevel (mapname);
1218                 alreadychangedlevel = TRUE;
1219                 return TRUE;
1220         }
1221         if(cvar_string("nextmap") != "")
1222                 if(MapInfo_CheckMap(cvar_string("nextmap")))
1223                 {
1224                         Map_Goto_SetStr(cvar_string("nextmap"));
1225                         Map_Goto();
1226                         alreadychangedlevel = TRUE;
1227                         return TRUE;
1228                 }
1229         if(cvar("lastlevel"))
1230         {
1231                 GameResetCfg();
1232                 localcmd("set lastlevel 0\ntogglemenu\n");
1233                 alreadychangedlevel = TRUE;
1234                 return TRUE;
1235         }
1236         return FALSE;
1237 };
1238
1239 void GotoNextMap()
1240 {
1241         //local string nextmap;
1242         //local float n, nummaps;
1243         //local string s;
1244         if (alreadychangedlevel)
1245                 return;
1246         alreadychangedlevel = TRUE;
1247
1248         {
1249                 string nextMap;
1250                 float allowReset;
1251
1252                 for(allowReset = 1; allowReset >= 0; --allowReset)
1253                 {
1254                         nextMap = GetNextMap();
1255                         if(nextMap != "")
1256                                 break;
1257
1258                         if(allowReset)
1259                         {
1260                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1261                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1262                                 if(cvar("g_maplist_shuffle"))
1263                                         ShuffleMaplist();
1264                                 localcmd("\nmenu_cmd sync\n");
1265                         }
1266                         else
1267                         {
1268                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1269                         }
1270                 }
1271                 Map_Goto();
1272         }
1273 };
1274
1275
1276 /*
1277 ============
1278 IntermissionThink
1279
1280 When the player presses attack or jump, change to the next level
1281 ============
1282 */
1283 .float autoscreenshot;
1284 void() MapVote_Start;
1285 void() MapVote_Think;
1286 float mapvote_initialized;
1287 void IntermissionThink()
1288 {
1289         FixIntermissionClient(self);
1290
1291         if(cvar("sv_autoscreenshot"))
1292         if(self.autoscreenshot > 0)
1293         if(time > self.autoscreenshot)
1294         {
1295                 self.autoscreenshot = -1;
1296                 if(clienttype(self) == CLIENTTYPE_REAL)
1297                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1298                 return;
1299         }
1300
1301         if (time < intermission_exittime)
1302                 return;
1303
1304         if(!mapvote_initialized)
1305                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
1306                         return;
1307
1308         MapVote_Start();
1309 };
1310
1311 /*
1312 ============
1313 FindIntermission
1314
1315 Returns the entity to view from
1316 ============
1317 */
1318 /*
1319 entity FindIntermission()
1320 {
1321         local   entity spot;
1322         local   float cyc;
1323
1324 // look for info_intermission first
1325         spot = find (world, classname, "info_intermission");
1326         if (spot)
1327         {       // pick a random one
1328                 cyc = random() * 4;
1329                 while (cyc > 1)
1330                 {
1331                         spot = find (spot, classname, "info_intermission");
1332                         if (!spot)
1333                                 spot = find (spot, classname, "info_intermission");
1334                         cyc = cyc - 1;
1335                 }
1336                 return spot;
1337         }
1338
1339 // then look for the start position
1340         spot = find (world, classname, "info_player_start");
1341         if (spot)
1342                 return spot;
1343
1344 // testinfo_player_start is only found in regioned levels
1345         spot = find (world, classname, "testplayerstart");
1346         if (spot)
1347                 return spot;
1348
1349 // then look for the start position
1350         spot = find (world, classname, "info_player_deathmatch");
1351         if (spot)
1352                 return spot;
1353
1354         //objerror ("FindIntermission: no spot");
1355         return world;
1356 };
1357 */
1358
1359 /*
1360 ===============================================================================
1361
1362 RULES
1363
1364 ===============================================================================
1365 */
1366
1367 void DumpStats(float final)
1368 {
1369         local float file;
1370         local string s;
1371         local float to_console;
1372         local float to_eventlog;
1373         local float to_file;
1374         local float i;
1375
1376         to_console = cvar("sv_logscores_console");
1377         to_eventlog = cvar("sv_eventlog");
1378         to_file = cvar("sv_logscores_file");
1379
1380         if(!final)
1381         {
1382                 to_console = TRUE; // always print printstats replies
1383                 to_eventlog = FALSE; // but never print them to the event log
1384         }
1385
1386         if(to_eventlog)
1387                 if(cvar("sv_eventlog_console"))
1388                         to_console = FALSE; // otherwise we get the output twice
1389
1390         if(final)
1391                 s = ":scores:";
1392         else
1393                 s = ":status:";
1394         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1395
1396         if(to_console)
1397                 print(s, "\n");
1398         if(to_eventlog)
1399                 GameLogEcho(s);
1400         if(to_file)
1401         {
1402                 file = fopen(cvar_string("sv_logscores_filename"), FILE_APPEND);
1403                 if(file == -1)
1404                         to_file = FALSE;
1405                 else
1406                         fputs(file, strcat(s, "\n"));
1407         }
1408
1409         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1410         if(to_console)
1411                 print(s, "\n");
1412         if(to_eventlog)
1413                 GameLogEcho(s);
1414         if(to_file)
1415                 fputs(file, strcat(s, "\n"));
1416
1417         FOR_EACH_CLIENT(other)
1418         {
1419                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && cvar("sv_logscores_bots")))
1420                 {
1421                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1422                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1423                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1424                                 s = strcat(s, ftos(other.team), ":");
1425                         else
1426                                 s = strcat(s, "spectator:");
1427
1428                         if(to_console)
1429                                 print(s, other.netname, "\n");
1430                         if(to_eventlog)
1431                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1432                         if(to_file)
1433                                 fputs(file, strcat(s, other.netname, "\n"));
1434                 }
1435         }
1436
1437         if(teams_matter)
1438         {
1439                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1440                 if(to_console)
1441                         print(s, "\n");
1442                 if(to_eventlog)
1443                         GameLogEcho(s);
1444                 if(to_file)
1445                         fputs(file, strcat(s, "\n"));
1446
1447                 for(i = 1; i < 16; ++i)
1448                 {
1449                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1450                         s = strcat(s, ":", ftos(i));
1451                         if(to_console)
1452                                 print(s, "\n");
1453                         if(to_eventlog)
1454                                 GameLogEcho(s);
1455                         if(to_file)
1456                                 fputs(file, strcat(s, "\n"));
1457                 }
1458         }
1459
1460         if(to_console)
1461                 print(":end\n");
1462         if(to_eventlog)
1463                 GameLogEcho(":end");
1464         if(to_file)
1465         {
1466                 fputs(file, ":end\n");
1467                 fclose(file);
1468         }
1469 }
1470
1471 void FixIntermissionClient(entity e)
1472 {
1473         string s;
1474         if(!e.autoscreenshot) // initial call
1475         {
1476                 e.angles = e.v_angle;
1477                 e.angles_x = -e.angles_x;
1478                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1479                 e.health = -2342;
1480                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1481                 e.solid = SOLID_NOT;
1482                 e.movetype = MOVETYPE_NONE;
1483                 e.takedamage = DAMAGE_NO;
1484                 if(e.weaponentity)
1485                 {
1486                         e.weaponentity.effects = EF_NODRAW;
1487                         if (e.weaponentity.weaponentity)
1488                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1489                 }
1490                 if(clienttype(e) == CLIENTTYPE_REAL)
1491                 {
1492                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1493                         s = cvar_string("sv_intermission_cdtrack");
1494                         if(s != "")
1495                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1496                         msg_entity = e;
1497                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1498                 }
1499         }
1500
1501         //e.velocity = '0 0 0';
1502         //e.fixangle = TRUE;
1503
1504         // TODO halt weapon animation
1505 }
1506
1507
1508 /*
1509 go to the next level for deathmatch
1510 only called if a time or frag limit has expired
1511 */
1512 void NextLevel()
1513 {
1514         float i;
1515
1516         gameover = TRUE;
1517
1518         intermission_running = 1;
1519
1520 // enforce a wait time before allowing changelevel
1521         if(player_count > 0)
1522                 intermission_exittime = time + cvar("sv_mapchange_delay");
1523         else
1524                 intermission_exittime = -1;
1525
1526         /*
1527         WriteByte (MSG_ALL, SVC_CDTRACK);
1528         WriteByte (MSG_ALL, 3);
1529         WriteByte (MSG_ALL, 3);
1530         // done in FixIntermission
1531         */
1532
1533         //pos = FindIntermission ();
1534
1535         VoteReset();
1536
1537         DumpStats(TRUE);
1538
1539         if(cvar("sv_eventlog"))
1540                 GameLogEcho(":gameover");
1541
1542         GameLogClose();
1543
1544 // TO DO
1545
1546 // save the stats to a text file on the client
1547 // stuffcmd(other, log_stats "stats/file_name");
1548 // bprint stats
1549 // stuffcmd(other, log_stats "");
1550 // use a filename similar to the demo name
1551         // string file_name;
1552         // file_name = strcat("\nlog_file \"stats/", strftime(TRUE, "%Y-%m-%d_%H-%M"), "_", mapname, ".txt\"");  // open the log file
1553
1554 // write a stats parser for the menu
1555
1556         if(cvar("sv_accuracy_data_send")) {
1557                 string stats_to_send;
1558
1559                 FOR_EACH_CLIENT(other) {  // make the string to send
1560                         FixIntermissionClient(other);
1561
1562                         if(other.cvar_cl_accuracy_data_share) {
1563                                 stats_to_send = strcat(stats_to_send, ":hits:", other.netname);
1564
1565                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
1566                                         stats_to_send = strcat(stats_to_send, ":", ftos(other.stats_hit[i-1]));
1567
1568                                 stats_to_send = strcat(stats_to_send, "\n:fired:", other.netname);
1569
1570                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
1571                                         stats_to_send = strcat(stats_to_send, ":", ftos(other.stats_fired[i-1]));
1572
1573                                 stats_to_send = strcat(stats_to_send, "\n");
1574                         }
1575                 }
1576
1577                 FOR_EACH_REALCLIENT(other) {  // only spam humans
1578                         Score_NicePrint(other);  // print the score
1579
1580                         if(other.cvar_cl_accuracy_data_receive)  // send the stats string to all the willing clients
1581                                 bprint(stats_to_send);
1582                 }
1583         } else { // ye olde message
1584                 FOR_EACH_PLAYER(other) {
1585                         FixIntermissionClient(other);
1586
1587                         if(other.winning)
1588                                 bprint(other.netname, " ^7wins.\n");
1589                 }
1590         }
1591
1592         if(cvar("g_campaign"))
1593                 CampaignPreIntermission();
1594
1595         localcmd("\nsv_hook_gameend\n");
1596 }
1597
1598 /*
1599 ============
1600 CheckRules_Player
1601
1602 Exit deathmatch games upon conditions
1603 ============
1604 */
1605 void CheckRules_Player()
1606 {
1607         if (gameover)   // someone else quit the game already
1608                 return;
1609
1610         if(self.deadflag == DEAD_NO)
1611                 self.play_time += frametime;
1612
1613         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1614         //   (div0: and that in CheckRules_World please)
1615 };
1616
1617 float checkrules_equality;
1618 float checkrules_suddendeathwarning;
1619 float checkrules_suddendeathend;
1620 float checkrules_overtimesadded; //how many overtimes have been already added
1621
1622 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1623 float WINNING_YES = 1; // winner found
1624 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1625 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1626
1627 float InitiateSuddenDeath()
1628 {
1629         // Check first whether normal overtimes could be added before initiating suddendeath mode
1630         // - for this timelimit_overtime needs to be >0 of course
1631         // - also check the winning condition calculated in the previous frame and only add normal overtime
1632         //   again, if at the point at which timelimit would be extended again, still no winner was found
1633         if ((checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < cvar("timelimit_overtimes")) && cvar("timelimit_overtime") && !(g_race && !g_race_qualifying))
1634         {
1635                 return 1; // need to call InitiateOvertime later
1636         }
1637         else
1638         {
1639                 if(!checkrules_suddendeathend)
1640                 {
1641                         checkrules_suddendeathend = time + 60 * cvar("timelimit_suddendeath");
1642                         if(g_race && !g_race_qualifying)
1643                                 race_StartCompleting();
1644                 }
1645                 return 0;
1646         }
1647 }
1648
1649 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1650 {
1651         ++checkrules_overtimesadded;
1652         //add one more overtime by simply extending the timelimit
1653         float tl;
1654         tl = cvar("timelimit");
1655         tl += cvar("timelimit_overtime");
1656         cvar_set("timelimit", ftos(tl));
1657         string minutesPlural;
1658         if (cvar("timelimit_overtime") == 1)
1659                 minutesPlural = " ^3minute";
1660         else
1661                 minutesPlural = " ^3minutes";
1662
1663         bcenterprint(
1664                 strcat(
1665                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1666                         ftos(cvar("timelimit_overtime")),
1667                         minutesPlural,
1668                         " to the game!"
1669                 )
1670         );
1671 }
1672
1673 float GetWinningCode(float fraglimitreached, float equality)
1674 {
1675         if(cvar("g_campaign") == 1)
1676                 if(fraglimitreached)
1677                         return WINNING_YES;
1678                 else
1679                         return WINNING_NO;
1680
1681         else
1682                 if(equality)
1683                         if(fraglimitreached)
1684                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1685                         else
1686                                 return WINNING_NEVER;
1687                 else
1688                         if(fraglimitreached)
1689                                 return WINNING_YES;
1690                         else
1691                                 return WINNING_NO;
1692 }
1693
1694 // set the .winning flag for exactly those players with a given field value
1695 void SetWinners(.float field, float value)
1696 {
1697         entity head;
1698         FOR_EACH_PLAYER(head)
1699                 head.winning = (head.field == value);
1700 }
1701
1702 // set the .winning flag for those players with a given field value
1703 void AddWinners(.float field, float value)
1704 {
1705         entity head;
1706         FOR_EACH_PLAYER(head)
1707                 if(head.field == value)
1708                         head.winning = 1;
1709 }
1710
1711 // clear the .winning flags
1712 void ClearWinners(void)
1713 {
1714         entity head;
1715         FOR_EACH_PLAYER(head)
1716                 head.winning = 0;
1717 }
1718
1719 // Onslaught winning condition:
1720 // game terminates if only one team has a working generator (or none)
1721 float WinningCondition_Onslaught()
1722 {
1723         entity head;
1724         local float t1, t2, t3, t4;
1725
1726         WinningConditionHelper(); // set worldstatus
1727
1728         if(inWarmupStage)
1729                 return WINNING_NO;
1730
1731         // first check if the game has ended
1732         t1 = t2 = t3 = t4 = 0;
1733         head = find(world, classname, "onslaught_generator");
1734         while (head)
1735         {
1736                 if (head.health > 0)
1737                 {
1738                         if (head.team == COLOR_TEAM1) t1 = 1;
1739                         if (head.team == COLOR_TEAM2) t2 = 1;
1740                         if (head.team == COLOR_TEAM3) t3 = 1;
1741                         if (head.team == COLOR_TEAM4) t4 = 1;
1742                 }
1743                 head = find(head, classname, "onslaught_generator");
1744         }
1745         if (t1 + t2 + t3 + t4 < 2)
1746         {
1747                 // game over, only one team remains (or none)
1748                 ClearWinners();
1749                 if (t1) SetWinners(team, COLOR_TEAM1);
1750                 if (t2) SetWinners(team, COLOR_TEAM2);
1751                 if (t3) SetWinners(team, COLOR_TEAM3);
1752                 if (t4) SetWinners(team, COLOR_TEAM4);
1753                 dprint("Have a winner, ending game.\n");
1754                 return WINNING_YES;
1755         }
1756
1757         // Two or more teams remain
1758         return WINNING_NO;
1759 }
1760
1761 float LMS_NewPlayerLives()
1762 {
1763         float fl;
1764         fl = cvar("fraglimit");
1765         if(fl == 0)
1766                 fl = 999;
1767
1768         // first player has left the game for dying too much? Nobody else can get in.
1769         if(lms_lowest_lives < 1)
1770                 return 0;
1771
1772         if(!cvar("g_lms_join_anytime"))
1773                 if(lms_lowest_lives < fl - cvar("g_lms_last_join"))
1774                         return 0;
1775
1776         return bound(1, lms_lowest_lives, fl);
1777 }
1778
1779 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1780 // they win. Otherwise the defending team wins once the timelimit passes.
1781 void assault_new_round();
1782 float WinningCondition_Assault()
1783 {
1784         local float status;
1785
1786         WinningConditionHelper(); // set worldstatus
1787
1788         status = WINNING_NO;
1789         // as the timelimit has not yet passed just assume the defending team will win
1790         if(assault_attacker_team == COLOR_TEAM1)
1791         {
1792                 SetWinners(team, COLOR_TEAM2);
1793         }
1794         else
1795         {
1796                 SetWinners(team, COLOR_TEAM1);
1797         }
1798
1799         local entity ent;
1800         ent = find(world, classname, "target_assault_roundend");
1801         if(ent)
1802         {
1803                 if(ent.winning) // round end has been triggered by attacking team
1804                 {
1805                         bprint("ASSAULT: round completed...\n");
1806                         SetWinners(team, assault_attacker_team);
1807
1808                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1809
1810                         if(ent.cnt == 1 || cvar("g_campaign")) // this was the second round
1811                         {
1812                                 status = WINNING_YES;
1813                         }
1814                         else
1815                         {
1816                                 local entity oldself;
1817                                 oldself = self;
1818                                 self = ent;
1819                                 assault_new_round();
1820                                 self = oldself;
1821                         }
1822                 }
1823         }
1824
1825         return status;
1826 }
1827
1828 // LMS winning condition: game terminates if and only if there's at most one
1829 // one player who's living lives. Top two scores being equal cancels the time
1830 // limit.
1831 float WinningCondition_LMS()
1832 {
1833         entity head, head2;
1834         float have_player;
1835         float have_players;
1836         float l;
1837
1838         have_player = FALSE;
1839         have_players = FALSE;
1840         l = LMS_NewPlayerLives();
1841
1842         head = find(world, classname, "player");
1843         if(head)
1844                 have_player = TRUE;
1845         head2 = find(head, classname, "player");
1846         if(head2)
1847                 have_players = TRUE;
1848
1849         if(have_player)
1850         {
1851                 // we have at least one player
1852                 if(have_players)
1853                 {
1854                         // two or more active players - continue with the game
1855                 }
1856                 else
1857                 {
1858                         // exactly one player?
1859
1860                         ClearWinners();
1861                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1862
1863                         if(l)
1864                         {
1865                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1866                                 return WINNING_NO;
1867                         }
1868                         else
1869                         {
1870                                 // a winner!
1871                                 // and assign him his first place
1872                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1873                                 return WINNING_YES;
1874                         }
1875                 }
1876         }
1877         else
1878         {
1879                 // nobody is playing at all...
1880                 if(l)
1881                 {
1882                         // wait for players...
1883                 }
1884                 else
1885                 {
1886                         // SNAFU (maybe a draw game?)
1887                         ClearWinners();
1888                         dprint("No players, ending game.\n");
1889                         return WINNING_YES;
1890                 }
1891         }
1892
1893         // When we get here, we have at least two players who are actually LIVING,
1894         // now check if the top two players have equal score.
1895         WinningConditionHelper();
1896
1897         ClearWinners();
1898         if(WinningConditionHelper_winner)
1899                 WinningConditionHelper_winner.winning = TRUE;
1900         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1901                 return WINNING_NEVER;
1902
1903         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1904         return WINNING_NO;
1905 }
1906
1907 void ShuffleMaplist()
1908 {
1909         cvar_set("g_maplist", shufflewords(cvar_string("g_maplist")));
1910 }
1911
1912 float leaderfrags;
1913 float WinningCondition_Scores(float limit, float leadlimit)
1914 {
1915         float limitreached;
1916
1917         // TODO make everything use THIS winning condition (except LMS)
1918         WinningConditionHelper();
1919
1920         if(teams_matter)
1921         {
1922                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1923                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1924                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1925                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1926         }
1927
1928         ClearWinners();
1929         if(WinningConditionHelper_winner)
1930                 WinningConditionHelper_winner.winning = 1;
1931         if(WinningConditionHelper_winnerteam >= 0)
1932                 SetWinners(team, WinningConditionHelper_winnerteam);
1933
1934         if(WinningConditionHelper_lowerisbetter)
1935         {
1936                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1937                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1938                 limit = -limit;
1939         }
1940
1941         if(WinningConditionHelper_zeroisworst)
1942                 leadlimit = 0; // not supported in this mode
1943
1944         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1945         // these modes always score in increments of 1, thus this makes sense
1946         {
1947                 if(leaderfrags != WinningConditionHelper_topscore)
1948                 {
1949                         leaderfrags = WinningConditionHelper_topscore;
1950
1951                         if (limit)
1952                         if (leaderfrags == limit - 1)
1953                                 Announce("1fragleft");
1954                         else if (leaderfrags == limit - 2)
1955                                 Announce("2fragsleft");
1956                         else if (leaderfrags == limit - 3)
1957                                 Announce("3fragsleft");
1958                 }
1959         }
1960
1961         limitreached = FALSE;
1962         if(limit)
1963                 if(WinningConditionHelper_topscore >= limit)
1964                         limitreached = TRUE;
1965         if(leadlimit)
1966         {
1967                 float leadlimitreached;
1968                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1969                 if(cvar("leadlimit_and_fraglimit"))
1970                         limitreached = (limitreached && leadlimitreached);
1971                 else
1972                         limitreached = (limitreached || leadlimitreached);
1973         }
1974
1975         return GetWinningCode(
1976                 WinningConditionHelper_topscore && limitreached,
1977                 WinningConditionHelper_equality
1978         );
1979 }
1980
1981 float WinningCondition_Race(float fraglimit)
1982 {
1983         float wc;
1984         entity p;
1985         float n, c;
1986
1987         n = 0;
1988         c = 0;
1989         FOR_EACH_PLAYER(p)
1990         {
1991                 ++n;
1992                 if(p.race_completed)
1993                         ++c;
1994         }
1995         if(n && (n == c))
1996                 return WINNING_YES;
1997         wc = WinningCondition_Scores(fraglimit, 0);
1998
1999         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2000         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2001         // do NOT support equality when the laps are all raced!
2002                 return WINNING_STARTSUDDENDEATHOVERTIME;
2003         else
2004                 return WINNING_NEVER;
2005         return wc;
2006 }
2007
2008 void ReadyRestart();
2009 float WinningCondition_QualifyingThenRace(float limit)
2010 {
2011         float wc;
2012         wc = WinningCondition_Scores(limit, 0);
2013
2014         // NEVER initiate overtime
2015         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2016         {
2017                 return WINNING_YES;
2018         }
2019
2020         return wc;
2021 }
2022
2023 float WinningCondition_RanOutOfSpawns()
2024 {
2025         entity head;
2026
2027         if(have_team_spawns <= 0)
2028                 return WINNING_NO;
2029
2030         if(!some_spawn_has_been_used)
2031                 return WINNING_NO;
2032
2033         team1_score = team2_score = team3_score = team4_score = 0;
2034
2035         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2036         {
2037                 if(head.team == COLOR_TEAM1)
2038                         team1_score = 1;
2039                 else if(head.team == COLOR_TEAM2)
2040                         team2_score = 1;
2041                 else if(head.team == COLOR_TEAM3)
2042                         team3_score = 1;
2043                 else if(head.team == COLOR_TEAM4)
2044                         team4_score = 1;
2045         }
2046
2047         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2048         {
2049                 if(head.team == COLOR_TEAM1)
2050                         team1_score = 1;
2051                 else if(head.team == COLOR_TEAM2)
2052                         team2_score = 1;
2053                 else if(head.team == COLOR_TEAM3)
2054                         team3_score = 1;
2055                 else if(head.team == COLOR_TEAM4)
2056                         team4_score = 1;
2057         }
2058
2059         ClearWinners();
2060         if(team1_score + team2_score + team3_score + team4_score == 0)
2061         {
2062                 checkrules_equality = TRUE;
2063                 return WINNING_YES;
2064         }
2065         else if(team1_score + team2_score + team3_score + team4_score == 1)
2066         {
2067                 float t, i;
2068                 if(team1_score) t = COLOR_TEAM1;
2069                 if(team2_score) t = COLOR_TEAM2;
2070                 if(team3_score) t = COLOR_TEAM3;
2071                 if(team4_score) t = COLOR_TEAM4;
2072                 CheckAllowedTeams(world);
2073                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2074                 {
2075                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2076                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2077                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2078                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2079                 }
2080
2081                 AddWinners(team, t);
2082                 return WINNING_YES;
2083         }
2084         else
2085                 return WINNING_NO;
2086 }
2087
2088 /*
2089 ============
2090 CheckRules_World
2091
2092 Exit deathmatch games upon conditions
2093 ============
2094 */
2095 void CheckRules_World()
2096 {
2097         float timelimit;
2098         float fraglimit;
2099         float leadlimit;
2100
2101         VoteThink();
2102         MapVote_Think();
2103
2104         SetDefaultAlpha();
2105
2106         /*
2107         MapVote_Think should now do that part
2108         if (intermission_running)
2109                 if (time >= intermission_exittime + 60)
2110                 {
2111                         if(!DoNextMapOverride())
2112                                 GotoNextMap();
2113                         return;
2114                 }
2115         */
2116
2117         if (gameover)   // someone else quit the game already
2118         {
2119                 if(player_count == 0) // Nobody there? Then let's go to the next map
2120                         MapVote_Start();
2121                         // this will actually check the player count in the next frame
2122                         // again, but this shouldn't hurt
2123                 return;
2124         }
2125
2126         timelimit = cvar("timelimit") * 60;
2127         fraglimit = cvar("fraglimit");
2128         leadlimit = cvar("leadlimit");
2129
2130         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2131         {
2132                 if(timelimit > 0)
2133                         timelimit = 0; // timelimit is not made for warmup
2134                 if(fraglimit > 0)
2135                         fraglimit = 0; // no fraglimit for now
2136                 leadlimit = 0; // no leadlimit for now
2137         }
2138
2139         if(g_onslaught)
2140                 timelimit = 0; // ONS has its own overtime rule
2141
2142         if(timelimit > 0)
2143         {
2144                 timelimit += game_starttime;
2145         }
2146         else if (timelimit < 0)
2147         {
2148                 // endmatch
2149                 NextLevel();
2150                 return;
2151         }
2152
2153         float wantovertime;
2154         wantovertime = 0;
2155
2156         if(checkrules_suddendeathend)
2157         {
2158                 if(!checkrules_suddendeathwarning)
2159                 {
2160                         checkrules_suddendeathwarning = TRUE;
2161                         if(g_race && !g_race_qualifying)
2162                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2163                         else
2164                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2165                 }
2166         }
2167         else
2168         {
2169                 if (timelimit && time >= timelimit)
2170                 {
2171                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2172                         {
2173                                 float totalplayers;
2174                                 float playerswithlaps;
2175                                 float readyplayers;
2176                                 entity head;
2177                                 totalplayers = playerswithlaps = readyplayers = 0;
2178                                 FOR_EACH_PLAYER(head)
2179                                 {
2180                                         ++totalplayers;
2181                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2182                                                 ++playerswithlaps;
2183                                         if(head.ready)
2184                                                 ++readyplayers;
2185                                 }
2186
2187                                 // at least 2 of the players have completed a lap: start the RACE
2188                                 // otherwise, the players should end the qualifying on their own
2189                                 if(readyplayers || playerswithlaps >= 2)
2190                                 {
2191                                         checkrules_suddendeathend = 0;
2192                                         ReadyRestart(); // go to race
2193                                         return;
2194                                 }
2195                                 else
2196                                         wantovertime |= InitiateSuddenDeath();
2197                         }
2198                         else
2199                                 wantovertime |= InitiateSuddenDeath();
2200                 }
2201         }
2202
2203         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2204         {
2205                 NextLevel();
2206                 return;
2207         }
2208
2209         float checkrules_status;
2210         checkrules_status = WinningCondition_RanOutOfSpawns();
2211         if(checkrules_status == WINNING_YES)
2212         {
2213                 bprint("Hey! Someone ran out of spawns!\n");
2214         }
2215         else if(g_race && !g_race_qualifying && timelimit >= 0)
2216         {
2217                 checkrules_status = WinningCondition_Race(fraglimit);
2218                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2219         }
2220         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2221         {
2222                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2223                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2224         }
2225         else if(g_assault)
2226         {
2227                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2228         }
2229         else if(g_lms)
2230         {
2231                 checkrules_status = WinningCondition_LMS();
2232         }
2233         else if (g_onslaught)
2234         {
2235                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2236         }
2237         else
2238         {
2239                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2240                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2241         }
2242
2243         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2244         {
2245                 checkrules_status = WINNING_NEVER;
2246                 checkrules_overtimesadded = -1;
2247                 wantovertime |= InitiateSuddenDeath();
2248         }
2249
2250         if(checkrules_status == WINNING_NEVER)
2251                 // equality cases! Nobody wins if the overtime ends in a draw.
2252                 ClearWinners();
2253
2254         if(wantovertime)
2255         {
2256                 if(checkrules_status == WINNING_NEVER)
2257                         InitiateOvertime();
2258                 else
2259                         checkrules_status = WINNING_YES;
2260         }
2261
2262         if(checkrules_suddendeathend)
2263                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2264                         checkrules_status = WINNING_YES;
2265
2266         if(checkrules_status == WINNING_YES)
2267         {
2268                 //print("WINNING\n");
2269                 NextLevel();
2270         }
2271 };
2272
2273 float mapvote_nextthink;
2274 float mapvote_initialized;
2275 float mapvote_keeptwotime;
2276 float mapvote_timeout;
2277 string mapvote_message;
2278 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2279 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2280 float mapvote_screenshot_dirs_count;
2281
2282 float mapvote_count;
2283 float mapvote_count_real;
2284 string mapvote_maps[MAPVOTE_COUNT];
2285 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2286 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2287 float mapvote_maps_suggested[MAPVOTE_COUNT];
2288 string mapvote_suggestions[MAPVOTE_COUNT];
2289 float mapvote_suggestion_ptr;
2290 float mapvote_maxlen;
2291 float mapvote_voters;
2292 float mapvote_votes[MAPVOTE_COUNT];
2293 float mapvote_run;
2294 float mapvote_detail;
2295 float mapvote_abstain;
2296 .float mapvote;
2297
2298 void MapVote_ClearAllVotes()
2299 {
2300         FOR_EACH_CLIENT(other)
2301                 other.mapvote = 0;
2302 }
2303
2304 string MapVote_Suggest(string m)
2305 {
2306         float i;
2307         if(m == "")
2308                 return "That's not how to use this command.";
2309         if(!cvar("g_maplist_votable_suggestions"))
2310                 return "Suggestions are not accepted on this server.";
2311         if(mapvote_initialized)
2312                 return "Can't suggest - voting is already in progress!";
2313         m = MapInfo_FixName(m);
2314         if(!m)
2315                 return "The map you suggested is not available on this server.";
2316         if(!cvar("g_maplist_votable_suggestions_override_mostrecent"))
2317                 if(Map_IsRecent(m))
2318                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2319
2320         if(!MapInfo_CheckMap(m))
2321                 return "The map you suggested does not support the current game mode.";
2322         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2323                 if(mapvote_suggestions[i] == m)
2324                         return "This map was already suggested.";
2325         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2326         {
2327                 i = floor(random() * mapvote_suggestion_ptr);
2328         }
2329         else
2330         {
2331                 i = mapvote_suggestion_ptr;
2332                 mapvote_suggestion_ptr += 1;
2333         }
2334         if(mapvote_suggestions[i] != "")
2335                 strunzone(mapvote_suggestions[i]);
2336         mapvote_suggestions[i] = strzone(m);
2337         if(cvar("sv_eventlog"))
2338                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2339         return strcat("Suggestion of ", m, " accepted.");
2340 }
2341
2342 void MapVote_AddVotable(string nextMap, float isSuggestion)
2343 {
2344         float j, i, o;
2345         string pakfile, mapfile;
2346
2347         if(nextMap == "")
2348                 return;
2349         for(j = 0; j < mapvote_count; ++j)
2350                 if(mapvote_maps[j] == nextMap)
2351                         return;
2352         if(strlen(nextMap) > mapvote_maxlen)
2353                 mapvote_maxlen = strlen(nextMap);
2354         mapvote_maps[mapvote_count] = strzone(nextMap);
2355         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2356
2357         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2358         {
2359                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2360                 pakfile = whichpack(strcat(mapfile, ".tga"));
2361                 if(pakfile == "")
2362                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2363                 if(pakfile == "")
2364                         pakfile = whichpack(strcat(mapfile, ".png"));
2365                 if(pakfile != "")
2366                         break;
2367         }
2368         if(i >= mapvote_screenshot_dirs_count)
2369                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2370         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2371                 pakfile = substring(pakfile, o, -1);
2372
2373         mapvote_maps_screenshot_dir[mapvote_count] = i;
2374         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2375
2376         mapvote_count += 1;
2377 }
2378
2379 void MapVote_Spawn();
2380 void MapVote_Init()
2381 {
2382         float i;
2383         float nmax, smax;
2384
2385         MapVote_ClearAllVotes();
2386
2387         mapvote_count = 0;
2388         mapvote_detail = !cvar("g_maplist_votable_nodetail");
2389         mapvote_abstain = cvar("g_maplist_votable_abstain");
2390
2391         if(mapvote_abstain)
2392                 nmax = min(MAPVOTE_COUNT - 1, cvar("g_maplist_votable"));
2393         else
2394                 nmax = min(MAPVOTE_COUNT, cvar("g_maplist_votable"));
2395         smax = min3(nmax, cvar("g_maplist_votable_suggestions"), mapvote_suggestion_ptr);
2396
2397         // we need this for AddVotable, as that cycles through the screenshot dirs
2398         mapvote_screenshot_dirs_count = tokenize_console(cvar_string("g_maplist_votable_screenshot_dir"));
2399         if(mapvote_screenshot_dirs_count == 0)
2400                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2401         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2402         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2403                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2404
2405         if(mapvote_suggestion_ptr)
2406                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2407                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2408
2409         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2410                 MapVote_AddVotable(GetNextMap(), FALSE);
2411
2412         if(mapvote_count == 0)
2413         {
2414                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2415                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2416                 if(cvar("g_maplist_shuffle"))
2417                         ShuffleMaplist();
2418                 localcmd("\nmenu_cmd sync\n");
2419                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2420                         MapVote_AddVotable(GetNextMap(), FALSE);
2421         }
2422
2423         mapvote_count_real = mapvote_count;
2424         if(mapvote_abstain)
2425                 MapVote_AddVotable("don't care", 0);
2426
2427         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2428
2429         mapvote_keeptwotime = time + cvar("g_maplist_votable_keeptwotime");
2430         mapvote_timeout = time + cvar("g_maplist_votable_timeout");
2431         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2432                 mapvote_keeptwotime = 0;
2433         mapvote_message = "Choose a map and press its key!";
2434
2435         MapVote_Spawn();
2436 }
2437
2438 void MapVote_SendPicture(float id)
2439 {
2440         msg_entity = self;
2441         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2442         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2443         WriteByte(MSG_ONE, id);
2444         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2445 }
2446
2447 float GameCommand_MapVote(string cmd)
2448 {
2449         if(!intermission_running)
2450                 return FALSE;
2451
2452         if(cmd == "mv_getpic")
2453         {
2454                 MapVote_SendPicture(stof(argv(1)));
2455                 return TRUE;
2456         }
2457
2458         return FALSE;
2459 }
2460
2461 float MapVote_GetMapMask()
2462 {
2463         float mask, i, power;
2464         mask = 0;
2465         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2466                 if(mapvote_maps[i] != "")
2467                         mask |= power;
2468         return mask;
2469 }
2470
2471 entity mapvote_ent;
2472 float MapVote_SendEntity(entity to, float sf)
2473 {
2474         float i;
2475
2476         if(sf & 1)
2477                 sf &~= 2; // if we send 1, we don't need to also send 2
2478
2479         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2480         WriteByte(MSG_ENTITY, sf);
2481
2482         if(sf & 1)
2483         {
2484                 // flag 1 == initialization
2485                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2486                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2487                 WriteString(MSG_ENTITY, "");
2488                 WriteByte(MSG_ENTITY, mapvote_count);
2489                 WriteByte(MSG_ENTITY, mapvote_abstain);
2490                 WriteByte(MSG_ENTITY, mapvote_detail);
2491                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2492                 if(mapvote_count <= 8)
2493                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2494                 else
2495                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2496                 for(i = 0; i < mapvote_count; ++i)
2497                         if(mapvote_maps[i] != "")
2498                         {
2499                                 if(mapvote_abstain && i == mapvote_count - 1)
2500                                 {
2501                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2502                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2503                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2504                                 }
2505                                 else
2506                                 {
2507                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2508                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2509                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2510                                 }
2511                         }
2512         }
2513
2514         if(sf & 2)
2515         {
2516                 // flag 2 == update of mask
2517                 if(mapvote_count <= 8)
2518                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2519                 else
2520                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2521         }
2522
2523         if(sf & 4)
2524         {
2525                 if(mapvote_detail)
2526                         for(i = 0; i < mapvote_count; ++i)
2527                                 if(mapvote_maps[i] != "")
2528                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2529
2530                 WriteByte(MSG_ENTITY, to.mapvote);
2531         }
2532
2533         return TRUE;
2534 }
2535
2536 void MapVote_Spawn()
2537 {
2538         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2539 }
2540
2541 void MapVote_TouchMask()
2542 {
2543         mapvote_ent.SendFlags |= 2;
2544 }
2545
2546 void MapVote_TouchVotes(entity voter)
2547 {
2548         mapvote_ent.SendFlags |= 4;
2549 }
2550
2551 float MapVote_Finished(float mappos)
2552 {
2553         string result;
2554         float i;
2555         float didntvote;
2556
2557         if(cvar("sv_eventlog"))
2558         {
2559                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2560                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2561                 didntvote = mapvote_voters;
2562                 for(i = 0; i < mapvote_count; ++i)
2563                         if(mapvote_maps[i] != "")
2564                         {
2565                                 didntvote -= mapvote_votes[i];
2566                                 if(i != mappos)
2567                                 {
2568                                         result = strcat(result, ":", mapvote_maps[i]);
2569                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2570                                 }
2571                         }
2572                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2573
2574                 GameLogEcho(result);
2575                 if(mapvote_maps_suggested[mappos])
2576                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2577         }
2578
2579         FOR_EACH_REALCLIENT(other)
2580                 FixClientCvars(other);
2581
2582         Map_Goto_SetStr(mapvote_maps[mappos]);
2583         Map_Goto();
2584         alreadychangedlevel = TRUE;
2585         return TRUE;
2586 }
2587 void MapVote_CheckRules_1()
2588 {
2589         float i;
2590
2591         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2592         {
2593                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2594                 mapvote_votes[i] = 0;
2595         }
2596
2597         mapvote_voters = 0;
2598         FOR_EACH_REALCLIENT(other)
2599         {
2600                 ++mapvote_voters;
2601                 if(other.mapvote)
2602                 {
2603                         i = other.mapvote - 1;
2604                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2605                         mapvote_votes[i] = mapvote_votes[i] + 1;
2606                 }
2607         }
2608 }
2609
2610 float MapVote_CheckRules_2()
2611 {
2612         float i;
2613         float firstPlace, secondPlace;
2614         float firstPlaceVotes, secondPlaceVotes;
2615         float mapvote_voters_real;
2616         string result;
2617
2618         if(mapvote_count_real == 1)
2619                 return MapVote_Finished(0);
2620
2621         mapvote_voters_real = mapvote_voters;
2622         if(mapvote_abstain)
2623                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2624
2625         RandomSelection_Init();
2626         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2627                 RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2628         firstPlace = RandomSelection_chosen_float;
2629         firstPlaceVotes = RandomSelection_best_priority;
2630         //dprint("First place: ", ftos(firstPlace), "\n");
2631         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2632
2633         RandomSelection_Init();
2634         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2635                 if(i != firstPlace)
2636                         RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2637         secondPlace = RandomSelection_chosen_float;
2638         secondPlaceVotes = RandomSelection_best_priority;
2639         //dprint("Second place: ", ftos(secondPlace), "\n");
2640         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2641
2642         if(firstPlace == -1)
2643                 error("No first place in map vote... WTF?");
2644
2645         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2646                 return MapVote_Finished(firstPlace);
2647
2648         if(mapvote_keeptwotime)
2649                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2650                 {
2651                         float didntvote;
2652                         MapVote_TouchMask();
2653                         mapvote_message = "Now decide between the TOP TWO!";
2654                         mapvote_keeptwotime = 0;
2655                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2656                         result = strcat(result, ":", ftos(firstPlaceVotes));
2657                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2658                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2659                         didntvote = mapvote_voters;
2660                         for(i = 0; i < mapvote_count; ++i)
2661                                 if(mapvote_maps[i] != "")
2662                                 {
2663                                         didntvote -= mapvote_votes[i];
2664                                         if(i != firstPlace)
2665                                                 if(i != secondPlace)
2666                                                 {
2667                                                         result = strcat(result, ":", mapvote_maps[i]);
2668                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2669                                                         if(i < mapvote_count_real)
2670                                                         {
2671                                                                 strunzone(mapvote_maps[i]);
2672                                                                 mapvote_maps[i] = "";
2673                                                                 strunzone(mapvote_maps_pakfile[i]);
2674                                                                 mapvote_maps_pakfile[i] = "";
2675                                                         }
2676                                                 }
2677                                 }
2678                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2679                         if(cvar("sv_eventlog"))
2680                                 GameLogEcho(result);
2681                 }
2682
2683         return FALSE;
2684 }
2685 void MapVote_Tick()
2686 {
2687         float keeptwo;
2688         float totalvotes;
2689
2690         keeptwo = mapvote_keeptwotime;
2691         MapVote_CheckRules_1(); // count
2692         if(MapVote_CheckRules_2()) // decide
2693                 return;
2694
2695         totalvotes = 0;
2696         FOR_EACH_REALCLIENT(other)
2697         {
2698                 // hide scoreboard again
2699                 if(other.health != 2342)
2700                 {
2701                         other.health = 2342;
2702                         other.impulse = 0;
2703                         if(clienttype(other) == CLIENTTYPE_REAL)
2704                         {
2705                                 msg_entity = other;
2706                                 WriteByte(MSG_ONE, SVC_FINALE);
2707                                 WriteString(MSG_ONE, "");
2708                         }
2709                 }
2710
2711                 // clear possibly invalid votes
2712                 if(mapvote_maps[other.mapvote - 1] == "")
2713                         other.mapvote = 0;
2714                 // use impulses as new vote
2715                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2716                         if(mapvote_maps[other.impulse - 1] != "")
2717                         {
2718                                 other.mapvote = other.impulse;
2719                                 MapVote_TouchVotes(other);
2720                         }
2721                 other.impulse = 0;
2722
2723                 if(other.mapvote)
2724                         ++totalvotes;
2725         }
2726
2727         MapVote_CheckRules_1(); // just count
2728 }
2729 void MapVote_Start()
2730 {
2731         if(mapvote_run)
2732                 return;
2733
2734         MapInfo_Enumerate();
2735         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2736                 mapvote_run = TRUE;
2737 }
2738 void MapVote_Think()
2739 {
2740         if(!mapvote_run)
2741                 return;
2742
2743         if(alreadychangedlevel)
2744                 return;
2745
2746         if(time < mapvote_nextthink)
2747                 return;
2748         //dprint("tick\n");
2749
2750         mapvote_nextthink = time + 0.5;
2751
2752         if(!mapvote_initialized)
2753         {
2754                 if(cvar("rescan_pending") == 1)
2755                 {
2756                         cvar_set("rescan_pending", "2");
2757                         localcmd("fs_rescan\nrescan_pending 3\n");
2758                         return;
2759                 }
2760                 else if(cvar("rescan_pending") == 2)
2761                 {
2762                         return;
2763                 }
2764                 else if(cvar("rescan_pending") == 3)
2765                 {
2766                         // now build missing mapinfo files
2767                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2768                                 return;
2769
2770                         // we're done, start the timer
2771                         cvar_set("rescan_pending", "0");
2772                 }
2773
2774                 mapvote_initialized = TRUE;
2775                 if(DoNextMapOverride())
2776                         return;
2777                 if(!cvar("g_maplist_votable") || player_count <= 0)
2778                 {
2779                         GotoNextMap();
2780                         return;
2781                 }
2782                 MapVote_Init();
2783         }
2784
2785         MapVote_Tick();
2786 };
2787
2788 string GotoMap(string m)
2789 {
2790         if(!MapInfo_CheckMap(m))
2791                 return "The map you chose is not available on this server.";
2792         cvar_set("nextmap", m);
2793         cvar_set("timelimit", "-1");
2794         if(mapvote_initialized || alreadychangedlevel)
2795         {
2796                 if(DoNextMapOverride())
2797                         return "Map switch initiated.";
2798                 else
2799                         return "Hm... no. For some reason I like THIS map more.";
2800         }
2801         else
2802                 return "Map switch will happen after scoreboard.";
2803 }
2804
2805
2806 void EndFrame()
2807 {
2808         float altime;
2809         FOR_EACH_REALCLIENT(self)
2810         {
2811                 if(self.classname == "spectator")
2812                 {
2813                         if(self.enemy.typehitsound)
2814                                 play2(self, "misc/typehit.wav");
2815                         else if(self.enemy.hitsound && self.cvar_cl_hitsound)
2816                                 play2(self, "misc/hit.wav");
2817                 }
2818                 else
2819                 {
2820                         if(self.typehitsound)
2821                                 play2(self, "misc/typehit.wav");
2822                         else if(self.hitsound && self.cvar_cl_hitsound)
2823                                 play2(self, "misc/hit.wav");
2824                 }
2825         }
2826         altime = time + frametime * (1 + cvar("g_antilag_nudge"));
2827         // add 1 frametime because after this, engine SV_Physics
2828         // increases time by a frametime and then networks the frame
2829         // add another frametime because client shows everything with
2830         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2831         // needed!
2832         FOR_EACH_CLIENT(self)
2833         {
2834                 self.hitsound = FALSE;
2835                 self.typehitsound = FALSE;
2836                 antilag_record(self, altime);
2837         }
2838 }
2839
2840
2841 /*
2842  * RedirectionThink:
2843  * returns TRUE if redirecting
2844  */
2845 float redirection_timeout;
2846 float redirection_nextthink;
2847 float RedirectionThink()
2848 {
2849         float clients_found;
2850
2851         if(redirection_target == "")
2852                 return FALSE;
2853
2854         if(!redirection_timeout)
2855         {
2856                 cvar_set("sv_public", "-2");
2857                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2858                 if(redirection_target == "self")
2859                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2860                 else
2861                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2862         }
2863
2864         if(time < redirection_nextthink)
2865                 return TRUE;
2866
2867         redirection_nextthink = time + 1;
2868
2869         clients_found = 0;
2870         FOR_EACH_REALCLIENT(self)
2871         {
2872                 print("Redirecting: sending connect command to ", self.netname, "\n");
2873                 if(redirection_target == "self")
2874                         stuffcmd(self, "\ndisconnect; reconnect\n");
2875                 else
2876                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2877                 ++clients_found;
2878         }
2879
2880         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2881
2882         if(time > redirection_timeout || clients_found == 0)
2883                 localcmd("\nwait; wait; wait; quit\n");
2884
2885         return TRUE;
2886 }
2887
2888 void TargetMusic_RestoreGame();
2889 void RestoreGame()
2890 {
2891         // Loaded from a save game
2892         // some things then break, so let's work around them...
2893
2894         // Progs DB (capture records)
2895         ServerProgsDB = db_load("server.db");
2896
2897         // Mapinfo
2898         MapInfo_Shutdown();
2899         MapInfo_Enumerate();
2900         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2901         WeaponStats_Init();
2902
2903         TargetMusic_RestoreGame();
2904 }
2905
2906 void SV_Shutdown()
2907 {
2908         if(gameover > 1) // shutting down already?
2909                 return;
2910
2911         gameover = 2; // 2 = server shutting down
2912
2913         if(world_initialized > 0)
2914         {
2915                 world_initialized = 0;
2916                 print("Saving persistent data...\n");
2917                 Ban_SaveBans();
2918                 if(!cheatcount_total)
2919                 {
2920                         if(cvar("sv_db_saveasdump"))
2921                                 db_dump(ServerProgsDB, "server.db");
2922                         else
2923                                 db_save(ServerProgsDB, "server.db");
2924                 }
2925                 if(cvar("developer"))
2926                 {
2927                         if(cvar("sv_db_saveasdump"))
2928                                 db_dump(TemporaryDB, "server-temp.db");
2929                         else
2930                                 db_save(TemporaryDB, "server-temp.db");
2931                 }
2932                 CheatShutdown(); // must be after cheatcount check
2933                 db_close(ServerProgsDB);
2934                 db_close(TemporaryDB);
2935                 print("done!\n");
2936                 // tell the bot system the game is ending now
2937                 bot_endgame();
2938
2939                 WeaponStats_Shutdown();
2940                 MapInfo_Shutdown();
2941         }
2942         else if(world_initialized == 0)
2943         {
2944                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2945         }
2946 }