qcsrc/server/g_world.qc

   1 #define LATENCY_THINKRATE 10
   2 .float latency_sum;
   3 .float latency_cnt;
   4 .float latency_time;
   5 entity pingplreport;
   6 void PingPLReport_Think()
   7 {
   8         float delta;
   9         entity e;
  10
  11         delta = 3 / maxclients;
  12         if(delta < sys_frametime)
  13                 delta = 0;
  14         self.nextthink = time + delta;
  15
  16         e = edict_num(self.cnt + 1);
  17         if(IS_REAL_CLIENT(e))
  18         {
  19                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  20                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  21                 WriteByte(MSG_BROADCAST, self.cnt);
  22                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  23                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  24                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  25
  26                 // record latency times for clients throughout the match so we can report it to playerstats
  27                 if(time > (e.latency_time + LATENCY_THINKRATE))
  28                 {
  29                         e.latency_sum += e.ping;
  30                         e.latency_cnt += 1;
  31                         e.latency_time = time;
  32                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  33                 }
  34         }
  35         else
  36         {
  37                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  38                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  39                 WriteByte(MSG_BROADCAST, self.cnt);
  40                 WriteShort(MSG_BROADCAST, 0);
  41                 WriteByte(MSG_BROADCAST, 0);
  42                 WriteByte(MSG_BROADCAST, 0);
  43         }
  44         self.cnt = mod(self.cnt + 1, maxclients);
  45 }
  46 void PingPLReport_Spawn()
  47 {
  48         pingplreport = spawn();
  49         pingplreport.classname = "pingplreport";
  50         pingplreport.think = PingPLReport_Think;
  51         pingplreport.nextthink = time;
  52 }
  53
  54 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  55 string redirection_target;
  56 float world_initialized;
  57
  58 string GetMapname();
  59 string GetGametype();
  60 void GotoNextMap(float reinit);
  61 void ShuffleMaplist();
  62 float(float reinit) DoNextMapOverride;
  63
  64 void SetDefaultAlpha()
  65 {
  66         if(autocvar_g_running_guns)
  67         {
  68                 default_player_alpha = -1;
  69                 default_weapon_alpha = +1;
  70         }
  71         else if(g_cloaked)
  72         {
  73                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  74                 default_weapon_alpha = default_player_alpha;
  75         }
  76         else
  77         {
  78                 default_player_alpha = autocvar_g_player_alpha;
  79                 if(default_player_alpha == 0)
  80                         default_player_alpha = 1;
  81                 default_weapon_alpha = default_player_alpha;
  82         }
  83 }
  84
  85 void fteqcc_testbugs()
  86 {
  87         float a, b;
  88
  89         if(!autocvar_developer_fteqccbugs)
  90                 return;
  91
  92         dprint("*** fteqcc test: checking for bugs...\n");
  93
  94         a = 1;
  95         b = 5;
  96         if(sqrt(a) - sqrt(b - a) == 0)
  97                 dprint("*** fteqcc test: found same-function-twice bug\n");
  98         else
  99                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
 100
 101         world.cnt = -10;
 102         world.enemy = world;
 103         world.enemy.cnt += 10;
 104         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
 105                 dprint("*** fteqcc test: found += bug\n");
 106         else
 107                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
 108         world.cnt = 0;
 109 }
 110
 111 void GotoFirstMap()
 112 {
 113         float n;
 114         if(autocvar__sv_init)
 115         {
 116                 // cvar_set("_sv_init", "0");
 117                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 118                 // to this "init" map on a dedicated server will cause no permanent
 119                 // harm
 120                 if(autocvar_g_maplist_shuffle)
 121                         ShuffleMaplist();
 122                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 123                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 124
 125                 MapInfo_Enumerate();
 126                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 127
 128                 if(!DoNextMapOverride(1))
 129                         GotoNextMap(1);
 130
 131                 return;
 132         }
 133
 134         if(time < 5)
 135         {
 136                 self.nextthink = time;
 137         }
 138         else
 139         {
 140                 self.nextthink = time + 1;
 141                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 142         }
 143 }
 144
 145 void cvar_changes_init()
 146 {
 147         float h;
 148         string k, v, d;
 149         float n, i, adding, pureadding;
 150
 151         if(cvar_changes)
 152                 strunzone(cvar_changes);
 153         cvar_changes = string_null;
 154         if(cvar_purechanges)
 155                 strunzone(cvar_purechanges);
 156         cvar_purechanges = string_null;
 157         cvar_purechanges_count = 0;
 158
 159         h = buf_create();
 160         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 161         n = buf_getsize(h);
 162
 163         adding = TRUE;
 164         pureadding = TRUE;
 165
 166         for(i = 0; i < n; ++i)
 167         {
 168                 k = bufstr_get(h, i);
 169
 170 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 171 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 172 #define BADCVAR(p) if(k == p) continue
 173
 174                 // general excludes and namespaces for server admin used cvars
 175                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 176
 177                 // internal
 178                 BADPREFIX("csqc_");
 179                 BADPREFIX("cvar_check_");
 180                 BADCVAR("gamecfg");
 181                 BADCVAR("g_configversion");
 182                 BADCVAR("g_maplist_index");
 183                 BADCVAR("halflifebsp");
 184                 BADPREFIX("sv_world");
 185
 186                 // client
 187                 BADPREFIX("chase_");
 188                 BADPREFIX("cl_");
 189                 BADPREFIX("con_");
 190                 BADPREFIX("scoreboard_");
 191                 BADPREFIX("g_campaign");
 192                 BADPREFIX("g_waypointsprite_");
 193                 BADPREFIX("gl_");
 194                 BADPREFIX("joy");
 195                 BADPREFIX("hud_");
 196                 BADPREFIX("m_");
 197                 BADPREFIX("menu_");
 198                 BADPREFIX("net_slist_");
 199                 BADPREFIX("r_");
 200                 BADPREFIX("sbar_");
 201                 BADPREFIX("scr_");
 202                 BADPREFIX("snd_");
 203                 BADPREFIX("show");
 204                 BADPREFIX("sensitivity");
 205                 BADPREFIX("userbind");
 206                 BADPREFIX("v_");
 207                 BADPREFIX("vid_");
 208                 BADPREFIX("crosshair");
 209                 BADCVAR("mod_q3bsp_lightmapmergepower");
 210                 BADCVAR("mod_q3bsp_nolightmaps");
 211                 BADCVAR("fov");
 212                 BADCVAR("mastervolume");
 213                 BADCVAR("volume");
 214                 BADCVAR("bgmvolume");
 215
 216                 // private
 217                 BADCVAR("developer");
 218                 BADCVAR("log_dest_udp");
 219                 BADCVAR("log_file");
 220                 BADCVAR("net_address");
 221                 BADCVAR("net_address_ipv6");
 222                 BADCVAR("port");
 223                 BADCVAR("savedgamecfg");
 224                 BADCVAR("serverconfig");
 225                 BADCVAR("sv_autoscreenshot");
 226                 BADCVAR("sv_heartbeatperiod");
 227                 BADCVAR("sv_vote_master_password");
 228                 BADCVAR("sys_colortranslation");
 229                 BADCVAR("sys_specialcharactertranslation");
 230                 BADCVAR("timeformat");
 231                 BADCVAR("timestamps");
 232                 BADPREFIX("developer_");
 233                 BADPREFIX("g_ban_");
 234                 BADPREFIX("g_banned_list");
 235                 BADPREFIX("g_chat_flood_");
 236                 BADPREFIX("g_ghost_items");
 237                 BADPREFIX("g_playerstats_");
 238                 BADPREFIX("g_respawn_ghosts");
 239                 BADPREFIX("g_voice_flood_");
 240                 BADPREFIX("rcon_");
 241                 BADPREFIX("sv_allowdownloads");
 242                 BADPREFIX("sv_autodemo");
 243                 BADPREFIX("sv_curl_");
 244                 BADPREFIX("sv_eventlog");
 245                 BADPREFIX("sv_logscores_");
 246                 BADPREFIX("sv_master");
 247                 BADPREFIX("sv_weaponstats_");
 248                 BADPREFIX("sv_waypointsprite_");
 249                 BADCVAR("rescan_pending");
 250
 251                 // these can contain player IDs, so better hide
 252                 BADPREFIX("g_forced_team_");
 253
 254                 // mapinfo
 255                 BADCVAR("fraglimit");
 256                 BADCVAR("g_arena");
 257                 BADCVAR("g_assault");
 258                 BADCVAR("g_ca");
 259                 BADCVAR("g_ca_teams");
 260                 BADCVAR("g_ctf");
 261                 BADCVAR("g_cts");
 262                 BADCVAR("g_dm");
 263                 BADCVAR("g_domination");
 264                 BADCVAR("g_domination_default_teams");
 265                 BADCVAR("g_freezetag");
 266                 BADCVAR("g_freezetag_teams");
 267                 BADCVAR("g_keepaway");
 268                 BADCVAR("g_keyhunt");
 269                 BADCVAR("g_keyhunt_teams");
 270                 BADCVAR("g_lms");
 271                 BADCVAR("g_nexball");
 272                 BADCVAR("g_onslaught");
 273                 BADCVAR("g_race");
 274                 BADCVAR("g_race_qualifying_timelimit");
 275                 BADCVAR("g_tdm");
 276                 BADCVAR("g_tdm_teams");
 277                 BADCVAR("leadlimit");
 278                 BADCVAR("nextmap");
 279                 BADCVAR("teamplay");
 280                 BADCVAR("timelimit");
 281
 282                 // long
 283                 BADCVAR("hostname");
 284                 BADCVAR("g_maplist");
 285                 BADCVAR("g_maplist_mostrecent");
 286                 BADCVAR("sv_motd");
 287
 288                 v = cvar_string(k);
 289                 d = cvar_defstring(k);
 290                 if(v == d)
 291                         continue;
 292
 293                 if(adding)
 294                 {
 295                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 296                         if(strlen(cvar_changes) > 16384)
 297                         {
 298                                 cvar_changes = "// too many settings have been changed to show them here\n";
 299                                 adding = 0;
 300                         }
 301                 }
 302
 303                 // now check if the changes are actually gameplay relevant
 304
 305                 // does nothing visible
 306                 BADCVAR("captureleadlimit_override");
 307                 BADCVAR("g_arena_point_leadlimit");
 308                 BADCVAR("g_balance_kill_delay");
 309                 BADCVAR("g_ca_point_leadlimit");
 310                 BADCVAR("g_ctf_captimerecord_always");
 311                 BADCVAR("g_ctf_flag_glowtrails");
 312                 BADCVAR("g_ctf_flag_pickup_verbosename");
 313                 BADCVAR("g_domination_point_leadlimit");
 314                 BADCVAR("g_forced_respawn");
 315                 BADCVAR("g_keyhunt_point_leadlimit");
 316                 BADPREFIX("g_mod_");
 317                 BADCVAR("g_nexball_goalleadlimit");
 318                 BADCVAR("leadlimit_and_fraglimit");
 319                 BADCVAR("leadlimit_override");
 320                 BADCVAR("pausable");
 321                 BADCVAR("sv_allow_fullbright");
 322                 BADCVAR("sv_checkforpacketsduringsleep");
 323                 BADCVAR("sv_fraginfo");
 324                 BADCVAR("sv_timeout");
 325                 BADPREFIX("sv_timeout_");
 326                 BADCVAR("welcome_message_time");
 327                 BADPREFIX("crypto_");
 328                 BADPREFIX("g_chat_");
 329                 BADPREFIX("g_ctf_captimerecord_");
 330                 BADPREFIX("g_maplist_votable_");
 331                 BADPREFIX("net_");
 332                 BADPREFIX("prvm_");
 333                 BADPREFIX("skill_");
 334                 BADPREFIX("sv_cullentities_");
 335                 BADPREFIX("sv_fraginfo_");
 336                 BADPREFIX("sv_maxidle_");
 337                 BADPREFIX("sv_vote_");
 338                 BADPREFIX("timelimit_");
 339                 BADCVAR("gameversion");
 340                 BADPREFIX("gameversion_");
 341                 BADCVAR("sv_namechangetimer");
 342
 343                 // allowed changes to server admins (please sync this to server.cfg)
 344                 // vi commands:
 345                 //   :/"impure"/,$d
 346                 //   :g!,^\/\/[^ /],d
 347                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 348                 //   :%!sort
 349                 // yes, this does contain some redundant stuff, don't really care
 350                 BADCVAR("bot_config_file");
 351                 BADCVAR("bot_number");
 352                 BADCVAR("bot_prefix");
 353                 BADCVAR("bot_suffix");
 354                 BADCVAR("capturelimit_override");
 355                 BADCVAR("fraglimit_override");
 356                 BADCVAR("gametype");
 357                 BADCVAR("g_antilag");
 358                 BADCVAR("g_balance_teams");
 359                 BADCVAR("g_balance_teams_prevent_imbalance");
 360                 BADCVAR("g_balance_teams_scorefactor");
 361                 BADCVAR("g_ban_sync_trusted_servers");
 362                 BADCVAR("g_ban_sync_uri");
 363                 BADCVAR("g_ca_teams_override");
 364                 BADCVAR("g_ctf_ignore_frags");
 365                 BADCVAR("g_domination_point_limit");
 366                 BADCVAR("g_freezetag_teams_override");
 367                 BADCVAR("g_friendlyfire");
 368                 BADCVAR("g_fullbrightitems");
 369                 BADCVAR("g_fullbrightplayers");
 370                 BADCVAR("g_keyhunt_point_limit");
 371                 BADCVAR("g_keyhunt_teams_override");
 372                 BADCVAR("g_lms_lives_override");
 373                 BADCVAR("g_maplist");
 374                 BADCVAR("g_maplist_check_waypoints");
 375                 BADCVAR("g_maplist_mostrecent_count");
 376                 BADCVAR("g_maplist_shuffle");
 377                 BADCVAR("g_maplist_votable");
 378                 BADCVAR("g_maplist_votable_abstain");
 379                 BADCVAR("g_maplist_votable_nodetail");
 380                 BADCVAR("g_maplist_votable_suggestions");
 381                 BADCVAR("g_maxplayers");
 382                 BADCVAR("g_mirrordamage");
 383                 BADCVAR("g_nexball_goallimit");
 384                 BADCVAR("g_powerups");
 385                 BADCVAR("g_start_delay");
 386                 BADCVAR("g_warmup");
 387                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 388                 BADCVAR("hostname");
 389                 BADCVAR("log_file");
 390                 BADCVAR("maxplayers");
 391                 BADCVAR("minplayers");
 392                 BADCVAR("net_address");
 393                 BADCVAR("port");
 394                 BADCVAR("rcon_password");
 395                 BADCVAR("rcon_restricted_commands");
 396                 BADCVAR("rcon_restricted_password");
 397                 BADCVAR("skill");
 398                 BADCVAR("sv_adminnick");
 399                 BADCVAR("sv_autoscreenshot");
 400                 BADCVAR("sv_autotaunt");
 401                 BADCVAR("sv_curl_defaulturl");
 402                 BADCVAR("sv_defaultcharacter");
 403                 BADCVAR("sv_defaultplayercolors");
 404                 BADCVAR("sv_defaultplayermodel");
 405                 BADCVAR("sv_defaultplayerskin");
 406                 BADCVAR("sv_maxidle");
 407                 BADCVAR("sv_maxrate");
 408                 BADCVAR("sv_motd");
 409                 BADCVAR("sv_public");
 410                 BADCVAR("sv_ready_restart");
 411                 BADCVAR("sv_status_privacy");
 412                 BADCVAR("sv_taunt");
 413                 BADCVAR("sv_vote_call");
 414                 BADCVAR("sv_vote_commands");
 415                 BADCVAR("sv_vote_majority_factor");
 416                 BADCVAR("sv_vote_master");
 417                 BADCVAR("sv_vote_master_commands");
 418                 BADCVAR("sv_vote_master_password");
 419                 BADCVAR("sv_vote_simple_majority_factor");
 420                 BADCVAR("sys_ticrate");
 421                 BADCVAR("teamplay_mode");
 422                 BADCVAR("timelimit_override");
 423                 BADCVAR("g_spawnshieldtime");
 424                 BADPREFIX("g_warmup_");
 425                 BADPREFIX("sv_ready_restart_");
 426
 427                 // mutators that announce themselves properly to the server browser
 428                 BADCVAR("g_minstagib");
 429                 BADCVAR("g_new_toys");
 430                 BADCVAR("g_nix");
 431                 BADCVAR("g_grappling_hook");
 432                 BADCVAR("g_jetpack");
 433
 434 #undef BADPREFIX
 435 #undef BADCVAR
 436
 437                 if(pureadding)
 438                 {
 439                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 440                         if(strlen(cvar_purechanges) > 16384)
 441                         {
 442                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 443                                 pureadding = 0;
 444                         }
 445                 }
 446                 ++cvar_purechanges_count;
 447                 // WARNING: this variable is used for the server list
 448                 // NEVER dare to skip this code!
 449                 // Hacks to intentionally appearing as "pure server" even though you DO have
 450                 // modified settings may be punished by removal from the server list.
 451                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 452                 // though.
 453         }
 454         buf_del(h);
 455         if(cvar_changes == "")
 456                 cvar_changes = "// this server runs at default server settings\n";
 457         else
 458                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 459         cvar_changes = strzone(cvar_changes);
 460         if(cvar_purechanges == "")
 461                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 462         else
 463                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 464         cvar_purechanges = strzone(cvar_purechanges);
 465 }
 466
 467 void detect_maptype()
 468 {
 469 #if 0
 470         vector o, v;
 471         float i;
 472
 473         for(;;)
 474         {
 475                 o = world.mins;
 476                 o_x += random() * (world.maxs_x - world.mins_x);
 477                 o_y += random() * (world.maxs_y - world.mins_y);
 478                 o_z += random() * (world.maxs_z - world.mins_z);
 479
 480                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 481                 if(trace_fraction == 1)
 482                         continue;
 483
 484                 v = trace_endpos;
 485
 486                 for(i = 0; i < 64; i += 4)
 487                 {
 488                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 489         if(trace_fraction == 1)
 490                 continue;
 491                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 492                 }
 493
 494                 break;
 495         }
 496 #endif
 497 }
 498
 499 entity randomseed;
 500 float RandomSeed_Send(entity to, float sf)
 501 {
 502         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 503         WriteShort(MSG_ENTITY, self.cnt);
 504         return TRUE;
 505 }
 506 void RandomSeed_Think()
 507 {
 508         self.cnt = bound(0, floor(random() * 65536), 65535);
 509         self.nextthink = time + 5;
 510
 511         self.SendFlags |= 1;
 512 }
 513 void RandomSeed_Spawn()
 514 {
 515         randomseed = spawn();
 516         randomseed.think = RandomSeed_Think;
 517         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 518
 519         entity oldself;
 520         oldself = self;
 521         self = randomseed;
 522         self.think(); // sets random seed and nextthink
 523         self = oldself;
 524 }
 525
 526 void spawnfunc___init_dedicated_server(void)
 527 {
 528         // handler for _init/_init map (only for dedicated server initialization)
 529
 530         world_initialized = -1; // don't complain
 531         cvar = cvar_normal;
 532         cvar_string = cvar_string_normal;
 533         cvar_set = cvar_set_normal;
 534
 535         remove = remove_unsafely;
 536
 537         entity e;
 538         e = spawn();
 539         e.think = GotoFirstMap;
 540         e.nextthink = time; // this is usually 1 at this point
 541
 542         e = spawn();
 543         e.classname = "info_player_deathmatch"; // safeguard against player joining
 544
 545         self.classname = "worldspawn"; // safeguard against various stuff ;)
 546
 547         // needs to be done so early because of the constants they create
 548         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 549         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 550         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 551         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 552         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 553
 554         MapInfo_Enumerate();
 555         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 556 }
 557
 558 void Map_MarkAsRecent(string m);
 559 float world_already_spawned;
 560 void Nagger_Init();
 561 void ClientInit_Spawn();
 562 void WeaponStats_Init();
 563 void WeaponStats_Shutdown();
 564 void spawnfunc_worldspawn (void)
 565 {
 566         float fd, l, i, j, n;
 567         string s;
 568
 569         cvar = cvar_normal;
 570         cvar_string = cvar_string_normal;
 571         cvar_set = cvar_set_normal;
 572
 573         if(world_already_spawned)
 574                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 575         world_already_spawned = TRUE;
 576
 577         remove = remove_safely; // during spawning, watch what you remove!
 578
 579         check_unacceptable_compiler_bugs();
 580
 581         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 582
 583         compressShortVector_init();
 584
 585         entity head;
 586         head = nextent(world);
 587         maxclients = 0;
 588         while(head)
 589         {
 590                 ++maxclients;
 591                 head = nextent(head);
 592         }
 593
 594         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? TRUE : FALSE);
 595
 596         // needs to be done so early because of the constants they create
 597         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 598         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 599         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 600         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 601         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 602
 603         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 604
 605         TemporaryDB = db_create();
 606
 607         // 0 normal
 608         lightstyle(0, "m");
 609
 610         // 1 FLICKER (first variety)
 611         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 612
 613         // 2 SLOW STRONG PULSE
 614         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 615
 616         // 3 CANDLE (first variety)
 617         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 618
 619         // 4 FAST STROBE
 620         lightstyle(4, "mamamamamama");
 621
 622         // 5 GENTLE PULSE 1
 623         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 624
 625         // 6 FLICKER (second variety)
 626         lightstyle(6, "nmonqnmomnmomomno");
 627
 628         // 7 CANDLE (second variety)
 629         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 630
 631         // 8 CANDLE (third variety)
 632         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 633
 634         // 9 SLOW STROBE (fourth variety)
 635         lightstyle(9, "aaaaaaaazzzzzzzz");
 636
 637         // 10 FLUORESCENT FLICKER
 638         lightstyle(10, "mmamammmmammamamaaamammma");
 639
 640         // 11 SLOW PULSE NOT FADE TO BLACK
 641         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 642
 643         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 644
 645         // 63 testing
 646         lightstyle(63, "a");
 647
 648         if(autocvar_g_campaign)
 649                 CampaignPreInit();
 650
 651         Map_MarkAsRecent(mapname);
 652
 653         PlayerStats_Init(); // we need this to be initiated before InitGameplayMode
 654
 655         precache_model ("null"); // we need this one before InitGameplayMode
 656         InitGameplayMode();
 657         readlevelcvars();
 658         GrappleHookInit();
 659         ElectroInit();
 660         LaserInit();
 661
 662         player_count = 0;
 663         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 664         if(bot_waypoints_for_items == 1)
 665                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 666                         bot_waypoints_for_items = 0;
 667
 668         precache();
 669
 670         WaypointSprite_Init();
 671
 672         GameLogInit(); // prepare everything
 673         // NOTE for matchid:
 674         // changing the logic generating it is okay. But:
 675         // it HAS to stay <= 64 chars
 676         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 677         if(autocvar_sv_eventlog)
 678         {
 679                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 680                 matchid = strzone(s);
 681
 682                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 683                 s = ":gameinfo:mutators:LIST";
 684
 685                 ret_string = s;
 686                 MUTATOR_CALLHOOK(BuildMutatorsString);
 687                 s = ret_string;
 688
 689                 // simple, probably not good in the mutator system
 690                 if(autocvar_g_grappling_hook)
 691                         s = strcat(s, ":grappling_hook");
 692
 693                 // initialiation stuff, not good in the mutator system
 694                 if(!autocvar_g_use_ammunition)
 695                         s = strcat(s, ":no_use_ammunition");
 696
 697                 // initialiation stuff, not good in the mutator system
 698                 if(autocvar_g_pickup_items == 0)
 699                         s = strcat(s, ":no_pickup_items");
 700                 if(autocvar_g_pickup_items > 0)
 701                         s = strcat(s, ":pickup_items");
 702
 703                 // initialiation stuff, not good in the mutator system
 704                 if(autocvar_g_weaponarena != "0")
 705                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 706
 707                 // TODO to mutator system
 708                 if(autocvar_g_norecoil)
 709                         s = strcat(s, ":norecoil");
 710
 711                 // TODO to mutator system
 712                 if(autocvar_g_powerups == 0)
 713                         s = strcat(s, ":no_powerups");
 714                 if(autocvar_g_powerups > 0)
 715                         s = strcat(s, ":powerups");
 716
 717                 GameLogEcho(s);
 718                 GameLogEcho(":gameinfo:end");
 719         }
 720         else
 721                 matchid = strzone(ftos(random()));
 722
 723         cvar_set("nextmap", "");
 724
 725         SetDefaultAlpha();
 726
 727         if(autocvar_g_campaign)
 728                 CampaignPostInit();
 729
 730         fteqcc_testbugs();
 731
 732         Ban_LoadBans();
 733
 734         MapInfo_Enumerate();
 735         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 736
 737         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 738         {
 739                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 740                 if(fd != -1)
 741                 {
 742                         while((s = fgets(fd)))
 743                         {
 744                                 l = tokenize_console(s);
 745                                 if(l < 2)
 746                                         continue;
 747                                 if(argv(0) == "cd")
 748                                 {
 749                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 750                                         print("  cdtrack ", argv(2), "\n");
 751                                 }
 752                                 else if(argv(0) == "fog")
 753                                 {
 754                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 755                                         print("  \"fog\" \"", s, "\"\n");
 756                                 }
 757                                 else if(argv(0) == "set")
 758                                 {
 759                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 760                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 761                                 }
 762                                 else if(argv(0) != "//")
 763                                 {
 764                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 765                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 766                                 }
 767                         }
 768                         fclose(fd);
 769                 }
 770         }
 771
 772         WeaponStats_Init();
 773
 774         WepSet_AddStat();
 775         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 776         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 777         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 778         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 779         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 780         Nagger_Init();
 781
 782         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 783         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 784         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 785         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 786         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 787         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 788         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 789         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 790         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 791         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 792         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 793         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 794         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 795
 796         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 797         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 798
 799         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 800
 801         // freeze attacks
 802         addstat(STAT_FROZEN, AS_INT, frozen);
 803         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, revive_progress);
 804
 805         // g_movementspeed hack
 806         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 807         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 808         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 809         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 810
 811         // secrets
 812         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 813         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 814
 815         // monsters
 816         addstat(STAT_MONSTERS_TOTAL, AS_FLOAT, stat_monsters_total);
 817         addstat(STAT_MONSTERS_KILLED, AS_FLOAT, stat_monsters_killed);
 818
 819         // misc
 820         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 821
 822         next_pingtime = time + 5;
 823
 824         detect_maptype();
 825
 826         // set up information replies for clients and server to use
 827         maplist_reply = strzone(getmaplist());
 828         lsmaps_reply = strzone(getlsmaps());
 829         for(i = 0; i < 10; ++i)
 830         {
 831                 s = getrecords(i);
 832                 if (s)
 833                         records_reply[i] = strzone(s);
 834         }
 835         ladder_reply = strzone(getladder());
 836         rankings_reply = strzone(getrankings());
 837
 838         // begin other init
 839         ClientInit_Spawn();
 840         RandomSeed_Spawn();
 841         PingPLReport_Spawn();
 842
 843         CheatInit();
 844
 845         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 846
 847         // fill sv_curl_serverpackages from .serverpackage files
 848         if(autocvar_sv_curl_serverpackages_auto)
 849         {
 850                 s = "";
 851                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 852                 for(i = 0; i < n; ++i)
 853                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 854                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 855                                 s = strcat(s, " ", argv(i));
 856                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 857                 if(fd >= 0)
 858                 {
 859                         j = search_getsize(fd);
 860                         for(i = 0; i < j; ++i)
 861                                 s = strcat(s, " ", search_getfilename(fd, i));
 862                         search_end(fd);
 863                 }
 864                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 865                 if(fd >= 0)
 866                 {
 867                         j = search_getsize(fd);
 868                         for(i = 0; i < j; ++i)
 869                                 s = strcat(s, " ", search_getfilename(fd, i));
 870                         search_end(fd);
 871                 }
 872                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 873         }
 874
 875         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 876         modname = "Xonotic";
 877         // physics/balance/config changes that count as mod
 878         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 879                 modname = cvar_string("g_mod_physics");
 880         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 881                 modname = cvar_string("g_mod_balance");
 882         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 883                 modname = cvar_string("g_mod_config");
 884         // extra mutators that deserve to count as mod
 885         MUTATOR_CALLHOOK(SetModname);
 886
 887         // save it for later
 888         modname = strzone(modname);
 889
 890         WinningConditionHelper(); // set worldstatus
 891
 892         world_initialized = 1;
 893 }
 894
 895 void spawnfunc_light (void)
 896 {
 897         //makestatic (self); // Who the f___ did that?
 898         remove(self);
 899 }
 900
 901 string GetGametype()
 902 {
 903         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 904 }
 905
 906 string getmapname_stored;
 907 string GetMapname()
 908 {
 909         return mapname;
 910 }
 911
 912 float Map_Count, Map_Current;
 913 string Map_Current_Name;
 914
 915 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 916 float GetMaplistPosition()
 917 {
 918         float pos, idx;
 919         string map;
 920
 921         map = GetMapname();
 922         idx = autocvar_g_maplist_index;
 923
 924         if(idx >= 0)
 925                 if(idx < Map_Count)
 926                         if(map == argv(idx))
 927                                 return idx;
 928
 929         for(pos = 0; pos < Map_Count; ++pos)
 930                 if(map == argv(pos))
 931                         return pos;
 932
 933         // resume normal maplist rotation if current map is not in g_maplist
 934         return idx;
 935 }
 936
 937 float MapHasRightSize(string map)
 938 {
 939         float fh;
 940         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 941         if(autocvar_g_maplist_check_waypoints)
 942         {
 943                 dprint("checkwp "); dprint(map);
 944                 if(!fexists(strcat("maps/", map, ".waypoints")))
 945                 {
 946                         dprint(": no waypoints\n");
 947                         return FALSE;
 948                 }
 949                 dprint(": has waypoints\n");
 950         }
 951
 952         // open map size restriction file
 953         dprint("opensize "); dprint(map);
 954         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 955         if(fh >= 0)
 956         {
 957                 float mapmin, mapmax;
 958                 dprint(": ok, ");
 959                 mapmin = stof(fgets(fh));
 960                 mapmax = stof(fgets(fh));
 961                 fclose(fh);
 962                 if(player_count < mapmin)
 963                 {
 964                         dprint("not enough\n");
 965                         return FALSE;
 966                 }
 967                 if(player_count > mapmax)
 968                 {
 969                         dprint("too many\n");
 970                         return FALSE;
 971                 }
 972                 dprint("right size\n");
 973                 return TRUE;
 974         }
 975         dprint(": not found\n");
 976         return TRUE;
 977 }
 978
 979 string Map_Filename(float position)
 980 {
 981         return strcat("maps/", argv(position), ".bsp");
 982 }
 983
 984 string strwords(string s, float w)
 985 {
 986         float endpos;
 987         for(endpos = 0; w && endpos >= 0; --w)
 988                 endpos = strstrofs(s, " ", endpos + 1);
 989         if(endpos < 0)
 990                 return s;
 991         else
 992                 return substring(s, 0, endpos);
 993 }
 994
 995 float strhasword(string s, string w)
 996 {
 997         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 998 }
 999
1000 void Map_MarkAsRecent(string m)
1001 {
1002         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1003 }
1004
1005 float Map_IsRecent(string m)
1006 {
1007         return strhasword(autocvar_g_maplist_mostrecent, m);
1008 }
1009
1010 float Map_Check(float position, float pass)
1011 {
1012         string filename;
1013         string map_next;
1014         map_next = argv(position);
1015         if(pass <= 1)
1016         {
1017                 if(Map_IsRecent(map_next))
1018                         return 0;
1019         }
1020         filename = Map_Filename(position);
1021         if(MapInfo_CheckMap(map_next))
1022         {
1023                 if(pass == 2)
1024                         return 1;
1025                 if(MapHasRightSize(map_next))
1026                         return 1;
1027                 return 0;
1028         }
1029         else
1030                 dprint( "Couldn't select '", filename, "'..\n" );
1031
1032         return 0;
1033 }
1034
1035 void Map_Goto_SetStr(string nextmapname)
1036 {
1037         if(getmapname_stored != "")
1038                 strunzone(getmapname_stored);
1039         if(nextmapname == "")
1040                 getmapname_stored = "";
1041         else
1042                 getmapname_stored = strzone(nextmapname);
1043 }
1044
1045 void Map_Goto_SetFloat(float position)
1046 {
1047         cvar_set("g_maplist_index", ftos(position));
1048         Map_Goto_SetStr(argv(position));
1049 }
1050
1051 void Map_Goto(float reinit)
1052 {
1053         MapInfo_LoadMap(getmapname_stored, reinit);
1054 }
1055
1056 // return codes of map selectors:
1057 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1058 //   -2 = permanent failure
1059 float() MaplistMethod_Iterate = // usual method
1060 {
1061         float pass, i;
1062
1063         for(pass = 1; pass <= 2; ++pass)
1064         {
1065                 for(i = 1; i < Map_Count; ++i)
1066                 {
1067                         float mapindex;
1068                         mapindex = mod(i + Map_Current, Map_Count);
1069                         if(Map_Check(mapindex, pass))
1070                                 return mapindex;
1071                 }
1072         }
1073         return -1;
1074 }
1075
1076 float() MaplistMethod_Repeat = // fallback method
1077 {
1078         if(Map_Check(Map_Current, 2))
1079                 return Map_Current;
1080         return -2;
1081 }
1082
1083 float() MaplistMethod_Random = // random map selection
1084 {
1085         float i, imax;
1086
1087         imax = 42;
1088
1089         for(i = 0; i <= imax; ++i)
1090         {
1091                 float mapindex;
1092                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1093                 if(Map_Check(mapindex, 1))
1094                         return mapindex;
1095         }
1096         return -1;
1097 }
1098
1099 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1100 // the exponent sets a bias on the map selection:
1101 // the higher the exponent, the less likely "shortly repeated" same maps are
1102 {
1103         float i, j, imax, insertpos;
1104
1105         imax = 42;
1106
1107         for(i = 0; i <= imax; ++i)
1108         {
1109                 string newlist;
1110
1111                 // now reinsert this at another position
1112                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1113                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1114                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1115                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1116
1117                 // insert the current map there
1118                 newlist = "";
1119                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1120                         newlist = strcat(newlist, " ", argv(j));
1121                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1122                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1123                         newlist = strcat(newlist, " ", argv(j));
1124                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1125                 cvar_set("g_maplist", newlist);
1126                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1127
1128                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1129                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1130                 if(Map_Check(Map_Current, 1))
1131                         return Map_Current;
1132         }
1133         return -1;
1134 }
1135
1136 void Maplist_Init()
1137 {
1138         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1139         if(Map_Count == 0)
1140         {
1141                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1142                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1143                 if(autocvar_g_maplist_shuffle)
1144                         ShuffleMaplist();
1145                 localcmd("\nmenu_cmd sync\n");
1146                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1147         }
1148         if(Map_Count == 0)
1149                 error("empty maplist, cannot select a new map");
1150         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1151
1152         if(Map_Current_Name)
1153                 strunzone(Map_Current_Name);
1154         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1155         // this may or may not be correct, but who cares, in the worst case a map
1156         // isn't chosen in the first pass that should have been
1157 }
1158
1159 string GetNextMap()
1160 {
1161         float nextMap;
1162
1163         Maplist_Init();
1164         nextMap = -1;
1165
1166         if(nextMap == -1)
1167                 if(autocvar_g_maplist_shuffle > 0)
1168                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1169
1170         if(nextMap == -1)
1171                 if(autocvar_g_maplist_selectrandom)
1172                         nextMap = MaplistMethod_Random();
1173
1174         if(nextMap == -1)
1175                 nextMap = MaplistMethod_Iterate();
1176
1177         if(nextMap == -1)
1178                 nextMap = MaplistMethod_Repeat();
1179
1180         if(nextMap >= 0)
1181         {
1182                 Map_Goto_SetFloat(nextMap);
1183                 return getmapname_stored;
1184         }
1185
1186         return "";
1187 }
1188
1189 float DoNextMapOverride(float reinit)
1190 {
1191         if(autocvar_g_campaign)
1192         {
1193                 CampaignPostIntermission();
1194                 alreadychangedlevel = TRUE;
1195                 return TRUE;
1196         }
1197         if(autocvar_quit_when_empty)
1198         {
1199                 if(player_count <= currentbots)
1200                 {
1201                         localcmd("quit\n");
1202                         alreadychangedlevel = TRUE;
1203                         return TRUE;
1204                 }
1205         }
1206         if(autocvar_quit_and_redirect != "")
1207         {
1208                 redirection_target = strzone(autocvar_quit_and_redirect);
1209                 alreadychangedlevel = TRUE;
1210                 return TRUE;
1211         }
1212         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1213         {
1214                 localcmd("restart\n");
1215                 alreadychangedlevel = TRUE;
1216                 return TRUE;
1217         }
1218         if(autocvar_nextmap != "")
1219                 if(MapInfo_CheckMap(autocvar_nextmap))
1220                 {
1221                         Map_Goto_SetStr(autocvar_nextmap);
1222                         Map_Goto(reinit);
1223                         alreadychangedlevel = TRUE;
1224                         return TRUE;
1225                 }
1226         if(!reinit && autocvar_lastlevel)
1227         {
1228                 cvar_settemp_restore();
1229                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1230                 alreadychangedlevel = TRUE;
1231                 return TRUE;
1232         }
1233         return FALSE;
1234 }
1235
1236 void GotoNextMap(float reinit)
1237 {
1238         //string nextmap;
1239         //float n, nummaps;
1240         //string s;
1241         if (alreadychangedlevel)
1242                 return;
1243         alreadychangedlevel = TRUE;
1244
1245         {
1246                 string nextMap;
1247                 float allowReset;
1248
1249                 for(allowReset = 1; allowReset >= 0; --allowReset)
1250                 {
1251                         nextMap = GetNextMap();
1252                         if(nextMap != "")
1253                                 break;
1254
1255                         if(allowReset)
1256                         {
1257                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1258                                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1259                                 if(autocvar_g_maplist_shuffle)
1260                                         ShuffleMaplist();
1261                                 localcmd("\nmenu_cmd sync\n");
1262                         }
1263                         else
1264                         {
1265                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1266                         }
1267                 }
1268                 Map_Goto(reinit);
1269         }
1270 }
1271
1272
1273 /*
1274 ============
1275 IntermissionThink
1276
1277 When the player presses attack or jump, change to the next level
1278 ============
1279 */
1280 .float autoscreenshot;
1281 void() MapVote_Start;
1282 void() MapVote_Think;
1283 float mapvote_initialized;
1284 void IntermissionThink()
1285 {
1286         FixIntermissionClient(self);
1287
1288         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1289         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1290
1291         if( (server_screenshot || client_screenshot)
1292                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1293         {
1294                 self.autoscreenshot = -1;
1295                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(FALSE, "%s"))); }
1296                 return;
1297         }
1298
1299         if (time < intermission_exittime)
1300                 return;
1301
1302         if(!mapvote_initialized)
1303                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1304                         return;
1305
1306         MapVote_Start();
1307 }
1308
1309 /*
1310 ============
1311 FindIntermission
1312
1313 Returns the entity to view from
1314 ============
1315 */
1316 /*
1317 entity FindIntermission()
1318 {
1319         local   entity spot;
1320         local   float cyc;
1321
1322 // look for info_intermission first
1323         spot = find (world, classname, "info_intermission");
1324         if (spot)
1325         {       // pick a random one
1326                 cyc = random() * 4;
1327                 while (cyc > 1)
1328                 {
1329                         spot = find (spot, classname, "info_intermission");
1330                         if (!spot)
1331                                 spot = find (spot, classname, "info_intermission");
1332                         cyc = cyc - 1;
1333                 }
1334                 return spot;
1335         }
1336
1337 // then look for the start position
1338         spot = find (world, classname, "info_player_start");
1339         if (spot)
1340                 return spot;
1341
1342 // testinfo_player_start is only found in regioned levels
1343         spot = find (world, classname, "testplayerstart");
1344         if (spot)
1345                 return spot;
1346
1347 // then look for the start position
1348         spot = find (world, classname, "info_player_deathmatch");
1349         if (spot)
1350                 return spot;
1351
1352         //objerror ("FindIntermission: no spot");
1353         return world;
1354 }
1355 */
1356
1357 /*
1358 ===============================================================================
1359
1360 RULES
1361
1362 ===============================================================================
1363 */
1364
1365 void DumpStats(float final)
1366 {
1367         float file;
1368         string s;
1369         float to_console;
1370         float to_eventlog;
1371         float to_file;
1372         float i;
1373
1374         to_console = autocvar_sv_logscores_console;
1375         to_eventlog = autocvar_sv_eventlog;
1376         to_file = autocvar_sv_logscores_file;
1377
1378         if(!final)
1379         {
1380                 to_console = TRUE; // always print printstats replies
1381                 to_eventlog = FALSE; // but never print them to the event log
1382         }
1383
1384         if(to_eventlog)
1385                 if(autocvar_sv_eventlog_console)
1386                         to_console = FALSE; // otherwise we get the output twice
1387
1388         if(final)
1389                 s = ":scores:";
1390         else
1391                 s = ":status:";
1392         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1393
1394         if(to_console)
1395                 print(s, "\n");
1396         if(to_eventlog)
1397                 GameLogEcho(s);
1398
1399         file = -1;
1400         if(to_file)
1401         {
1402                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1403                 if(file == -1)
1404                         to_file = FALSE;
1405                 else
1406                         fputs(file, strcat(s, "\n"));
1407         }
1408
1409         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1410         if(to_console)
1411                 print(s, "\n");
1412         if(to_eventlog)
1413                 GameLogEcho(s);
1414         if(to_file)
1415                 fputs(file, strcat(s, "\n"));
1416
1417         FOR_EACH_CLIENT(other)
1418         {
1419                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1420                 {
1421                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1422                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1423                         if(IS_PLAYER(other) || g_arena || other.caplayer == 1 || g_lms)
1424                                 s = strcat(s, ftos(other.team), ":");
1425                         else
1426                                 s = strcat(s, "spectator:");
1427
1428                         if(to_console)
1429                                 print(s, other.netname, "\n");
1430                         if(to_eventlog)
1431                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1432                         if(to_file)
1433                                 fputs(file, strcat(s, other.netname, "\n"));
1434                 }
1435         }
1436
1437         if(teamplay)
1438         {
1439                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1440                 if(to_console)
1441                         print(s, "\n");
1442                 if(to_eventlog)
1443                         GameLogEcho(s);
1444                 if(to_file)
1445                         fputs(file, strcat(s, "\n"));
1446
1447                 for(i = 1; i < 16; ++i)
1448                 {
1449                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1450                         s = strcat(s, ":", ftos(i));
1451                         if(to_console)
1452                                 print(s, "\n");
1453                         if(to_eventlog)
1454                                 GameLogEcho(s);
1455                         if(to_file)
1456                                 fputs(file, strcat(s, "\n"));
1457                 }
1458         }
1459
1460         if(to_console)
1461                 print(":end\n");
1462         if(to_eventlog)
1463                 GameLogEcho(":end");
1464         if(to_file)
1465         {
1466                 fputs(file, ":end\n");
1467                 fclose(file);
1468         }
1469 }
1470
1471 void FixIntermissionClient(entity e)
1472 {
1473         string s;
1474         if(!e.autoscreenshot) // initial call
1475         {
1476                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1477                 e.health = -2342;
1478                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1479                 e.solid = SOLID_NOT;
1480                 e.movetype = MOVETYPE_NONE;
1481                 e.takedamage = DAMAGE_NO;
1482                 if(e.weaponentity)
1483                 {
1484                         e.weaponentity.effects = EF_NODRAW;
1485                         if (e.weaponentity.weaponentity)
1486                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1487                 }
1488                 if(IS_REAL_CLIENT(e))
1489                 {
1490                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1491                         s = autocvar_sv_intermission_cdtrack;
1492                         if(s != "")
1493                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1494                         msg_entity = e;
1495                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1496                 }
1497         }
1498 }
1499
1500 /*
1501 go to the next level for deathmatch
1502 only called if a time or frag limit has expired
1503 */
1504 void NextLevel()
1505 {
1506         gameover = TRUE;
1507
1508         intermission_running = 1;
1509
1510 // enforce a wait time before allowing changelevel
1511         if(player_count > 0)
1512                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1513         else
1514                 intermission_exittime = -1;
1515
1516         /*
1517         WriteByte (MSG_ALL, SVC_CDTRACK);
1518         WriteByte (MSG_ALL, 3);
1519         WriteByte (MSG_ALL, 3);
1520         // done in FixIntermission
1521         */
1522
1523         //pos = FindIntermission ();
1524
1525         VoteReset();
1526
1527         DumpStats(TRUE);
1528
1529         // send statistics
1530         entity e;
1531         PlayerStats_EndMatch(1);
1532         FOR_EACH_CLIENT(e)
1533                 PlayerStats_AddGlobalInfo(e);
1534         PlayerStats_Shutdown();
1535         WeaponStats_Shutdown();
1536
1537         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1538
1539         if(autocvar_sv_eventlog)
1540                 GameLogEcho(":gameover");
1541
1542         GameLogClose();
1543
1544         FOR_EACH_PLAYER(other) {
1545                 FixIntermissionClient(other);
1546                 if(other.winning)
1547                         bprint(other.netname, " ^7wins.\n");
1548         }
1549
1550         if(autocvar_g_campaign)
1551                 CampaignPreIntermission();
1552
1553         MUTATOR_CALLHOOK(MatchEnd);
1554
1555         localcmd("\nsv_hook_gameend\n");
1556 }
1557
1558 /*
1559 ============
1560 CheckRules_Player
1561
1562 Exit deathmatch games upon conditions
1563 ============
1564 */
1565 void CheckRules_Player()
1566 {
1567         if (gameover)   // someone else quit the game already
1568                 return;
1569
1570         if(self.deadflag == DEAD_NO)
1571                 self.play_time += frametime;
1572
1573         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1574         //   (div0: and that in CheckRules_World please)
1575 }
1576
1577 float checkrules_equality;
1578 float checkrules_suddendeathwarning;
1579 float checkrules_suddendeathend;
1580 float checkrules_overtimesadded; //how many overtimes have been already added
1581
1582 const float WINNING_NO = 0; // no winner, but time limits may terminate the game
1583 const float WINNING_YES = 1; // winner found
1584 const float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1585 const float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1586
1587 float InitiateSuddenDeath()
1588 {
1589         // Check first whether normal overtimes could be added before initiating suddendeath mode
1590         // - for this timelimit_overtime needs to be >0 of course
1591         // - also check the winning condition calculated in the previous frame and only add normal overtime
1592         //   again, if at the point at which timelimit would be extended again, still no winner was found
1593         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1594         {
1595                 return 1; // need to call InitiateOvertime later
1596         }
1597         else
1598         {
1599                 if(!checkrules_suddendeathend)
1600                 {
1601                         if(autocvar_g_campaign)
1602                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1603                         else
1604                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1605                         if(g_race && !g_race_qualifying)
1606                                 race_StartCompleting();
1607                 }
1608                 return 0;
1609         }
1610 }
1611
1612 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1613 {
1614         ++checkrules_overtimesadded;
1615         //add one more overtime by simply extending the timelimit
1616         float tl;
1617         tl = autocvar_timelimit;
1618         tl += autocvar_timelimit_overtime;
1619         cvar_set("timelimit", ftos(tl));
1620
1621         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1622 }
1623
1624 float GetWinningCode(float fraglimitreached, float equality)
1625 {
1626         if(autocvar_g_campaign == 1)
1627                 if(fraglimitreached)
1628                         return WINNING_YES;
1629                 else
1630                         return WINNING_NO;
1631
1632         else
1633                 if(equality)
1634                         if(fraglimitreached)
1635                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1636                         else
1637                                 return WINNING_NEVER;
1638                 else
1639                         if(fraglimitreached)
1640                                 return WINNING_YES;
1641                         else
1642                                 return WINNING_NO;
1643 }
1644
1645 // set the .winning flag for exactly those players with a given field value
1646 void SetWinners(.float field, float value)
1647 {
1648         entity head;
1649         FOR_EACH_PLAYER(head)
1650                 head.winning = (head.field == value);
1651 }
1652
1653 // set the .winning flag for those players with a given field value
1654 void AddWinners(.float field, float value)
1655 {
1656         entity head;
1657         FOR_EACH_PLAYER(head)
1658                 if(head.field == value)
1659                         head.winning = 1;
1660 }
1661
1662 // clear the .winning flags
1663 void ClearWinners(void)
1664 {
1665         entity head;
1666         FOR_EACH_PLAYER(head)
1667                 head.winning = 0;
1668 }
1669
1670 // Onslaught winning condition:
1671 // game terminates if only one team has a working generator (or none)
1672 float WinningCondition_Onslaught()
1673 {
1674         entity head;
1675         float t1, t2, t3, t4;
1676
1677         WinningConditionHelper(); // set worldstatus
1678
1679         if(inWarmupStage)
1680                 return WINNING_NO;
1681
1682         // first check if the game has ended
1683         t1 = t2 = t3 = t4 = 0;
1684         head = find(world, classname, "onslaught_generator");
1685         while (head)
1686         {
1687                 if (head.health > 0)
1688                 {
1689                         if (head.team == NUM_TEAM_1) t1 = 1;
1690                         if (head.team == NUM_TEAM_2) t2 = 1;
1691                         if (head.team == NUM_TEAM_3) t3 = 1;
1692                         if (head.team == NUM_TEAM_4) t4 = 1;
1693                 }
1694                 head = find(head, classname, "onslaught_generator");
1695         }
1696         if (t1 + t2 + t3 + t4 < 2)
1697         {
1698                 // game over, only one team remains (or none)
1699                 ClearWinners();
1700                 if (t1) SetWinners(team, NUM_TEAM_1);
1701                 if (t2) SetWinners(team, NUM_TEAM_2);
1702                 if (t3) SetWinners(team, NUM_TEAM_3);
1703                 if (t4) SetWinners(team, NUM_TEAM_4);
1704                 dprint("Have a winner, ending game.\n");
1705                 return WINNING_YES;
1706         }
1707
1708         // Two or more teams remain
1709         return WINNING_NO;
1710 }
1711
1712 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1713 // they win. Otherwise the defending team wins once the timelimit passes.
1714 void assault_new_round();
1715 float WinningCondition_Assault()
1716 {
1717         float status;
1718
1719         WinningConditionHelper(); // set worldstatus
1720
1721         status = WINNING_NO;
1722         // as the timelimit has not yet passed just assume the defending team will win
1723         if(assault_attacker_team == NUM_TEAM_1)
1724         {
1725                 SetWinners(team, NUM_TEAM_2);
1726         }
1727         else
1728         {
1729                 SetWinners(team, NUM_TEAM_1);
1730         }
1731
1732         entity ent;
1733         ent = find(world, classname, "target_assault_roundend");
1734         if(ent)
1735         {
1736                 if(ent.winning) // round end has been triggered by attacking team
1737                 {
1738                         bprint("ASSAULT: round completed...\n");
1739                         SetWinners(team, assault_attacker_team);
1740
1741                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1742
1743                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1744                         {
1745                                 status = WINNING_YES;
1746                         }
1747                         else
1748                         {
1749                                 entity oldself;
1750                                 oldself = self;
1751                                 self = ent;
1752                                 assault_new_round();
1753                                 self = oldself;
1754                         }
1755                 }
1756         }
1757
1758         return status;
1759 }
1760
1761 // LMS winning condition: game terminates if and only if there's at most one
1762 // one player who's living lives. Top two scores being equal cancels the time
1763 // limit.
1764 float WinningCondition_LMS()
1765 {
1766         entity head, head2;
1767         float have_player;
1768         float have_players;
1769         float l;
1770
1771         have_player = FALSE;
1772         have_players = FALSE;
1773         l = LMS_NewPlayerLives();
1774
1775         head = find(world, classname, "player");
1776         if(head)
1777                 have_player = TRUE;
1778         head2 = find(head, classname, "player");
1779         if(head2)
1780                 have_players = TRUE;
1781
1782         if(have_player)
1783         {
1784                 // we have at least one player
1785                 if(have_players)
1786                 {
1787                         // two or more active players - continue with the game
1788                 }
1789                 else
1790                 {
1791                         // exactly one player?
1792
1793                         ClearWinners();
1794                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1795
1796                         if(l)
1797                         {
1798                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1799                                 return WINNING_NO;
1800                         }
1801                         else
1802                         {
1803                                 // a winner!
1804                                 // and assign him his first place
1805                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1806                                 return WINNING_YES;
1807                         }
1808                 }
1809         }
1810         else
1811         {
1812                 // nobody is playing at all...
1813                 if(l)
1814                 {
1815                         // wait for players...
1816                 }
1817                 else
1818                 {
1819                         // SNAFU (maybe a draw game?)
1820                         ClearWinners();
1821                         dprint("No players, ending game.\n");
1822                         return WINNING_YES;
1823                 }
1824         }
1825
1826         // When we get here, we have at least two players who are actually LIVING,
1827         // now check if the top two players have equal score.
1828         WinningConditionHelper();
1829
1830         ClearWinners();
1831         if(WinningConditionHelper_winner)
1832                 WinningConditionHelper_winner.winning = TRUE;
1833         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1834                 return WINNING_NEVER;
1835
1836         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1837         return WINNING_NO;
1838 }
1839
1840 void ShuffleMaplist()
1841 {
1842         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1843 }
1844
1845 float leaderfrags;
1846 float WinningCondition_Scores(float limit, float leadlimit)
1847 {
1848         float limitreached;
1849
1850         // TODO make everything use THIS winning condition (except LMS)
1851         WinningConditionHelper();
1852
1853         if(teamplay)
1854         {
1855                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1856                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1857                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1858                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1859         }
1860
1861         ClearWinners();
1862         if(WinningConditionHelper_winner)
1863                 WinningConditionHelper_winner.winning = 1;
1864         if(WinningConditionHelper_winnerteam >= 0)
1865                 SetWinners(team, WinningConditionHelper_winnerteam);
1866
1867         if(WinningConditionHelper_lowerisbetter)
1868         {
1869                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1870                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1871                 limit = -limit;
1872         }
1873
1874         if(WinningConditionHelper_zeroisworst)
1875                 leadlimit = 0; // not supported in this mode
1876
1877         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1878         // these modes always score in increments of 1, thus this makes sense
1879         {
1880                 if(leaderfrags != WinningConditionHelper_topscore)
1881                 {
1882                         leaderfrags = WinningConditionHelper_topscore;
1883
1884                         if (limit)
1885                         if (leaderfrags == limit - 1)
1886                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1887                         else if (leaderfrags == limit - 2)
1888                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1889                         else if (leaderfrags == limit - 3)
1890                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1891                 }
1892         }
1893
1894         limitreached = FALSE;
1895         if(limit)
1896                 if(WinningConditionHelper_topscore >= limit)
1897                         limitreached = TRUE;
1898         if(leadlimit)
1899         {
1900                 float leadlimitreached;
1901                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1902                 if(autocvar_leadlimit_and_fraglimit)
1903                         limitreached = (limitreached && leadlimitreached);
1904                 else
1905                         limitreached = (limitreached || leadlimitreached);
1906         }
1907
1908         if(limit)
1909                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1910
1911         return GetWinningCode(
1912                 WinningConditionHelper_topscore && limitreached,
1913                 WinningConditionHelper_equality
1914         );
1915 }
1916
1917 float WinningCondition_Race(float fraglimit)
1918 {
1919         float wc;
1920         entity p;
1921         float n, c;
1922
1923         n = 0;
1924         c = 0;
1925         FOR_EACH_PLAYER(p)
1926         {
1927                 ++n;
1928                 if(p.race_completed)
1929                         ++c;
1930         }
1931         if(n && (n == c))
1932                 return WINNING_YES;
1933         wc = WinningCondition_Scores(fraglimit, 0);
1934
1935         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1936         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1937         // do NOT support equality when the laps are all raced!
1938                 return WINNING_STARTSUDDENDEATHOVERTIME;
1939         else
1940                 return WINNING_NEVER;
1941 }
1942
1943 float WinningCondition_QualifyingThenRace(float limit)
1944 {
1945         float wc;
1946         wc = WinningCondition_Scores(limit, 0);
1947
1948         // NEVER initiate overtime
1949         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1950         {
1951                 return WINNING_YES;
1952         }
1953
1954         return wc;
1955 }
1956
1957 float WinningCondition_RanOutOfSpawns()
1958 {
1959         entity head;
1960
1961         if(have_team_spawns <= 0)
1962                 return WINNING_NO;
1963
1964         if(autocvar_g_spawn_useallspawns <= 0)
1965                 return WINNING_NO;
1966
1967         if(!some_spawn_has_been_used)
1968                 return WINNING_NO;
1969
1970         team1_score = team2_score = team3_score = team4_score = 0;
1971
1972         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1973         {
1974                 if(head.team == NUM_TEAM_1)
1975                         team1_score = 1;
1976                 else if(head.team == NUM_TEAM_2)
1977                         team2_score = 1;
1978                 else if(head.team == NUM_TEAM_3)
1979                         team3_score = 1;
1980                 else if(head.team == NUM_TEAM_4)
1981                         team4_score = 1;
1982         }
1983
1984         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1985         {
1986                 if(head.team == NUM_TEAM_1)
1987                         team1_score = 1;
1988                 else if(head.team == NUM_TEAM_2)
1989                         team2_score = 1;
1990                 else if(head.team == NUM_TEAM_3)
1991                         team3_score = 1;
1992                 else if(head.team == NUM_TEAM_4)
1993                         team4_score = 1;
1994         }
1995
1996         ClearWinners();
1997         if(team1_score + team2_score + team3_score + team4_score == 0)
1998         {
1999                 checkrules_equality = TRUE;
2000                 return WINNING_YES;
2001         }
2002         else if(team1_score + team2_score + team3_score + team4_score == 1)
2003         {
2004                 float t, i;
2005                 if(team1_score)
2006                         t = NUM_TEAM_1;
2007                 else if(team2_score)
2008                         t = NUM_TEAM_2;
2009                 else if(team3_score)
2010                         t = NUM_TEAM_3;
2011                 else // if(team4_score)
2012                         t = NUM_TEAM_4;
2013                 CheckAllowedTeams(world);
2014                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2015                 {
2016                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
2017                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
2018                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
2019                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
2020                 }
2021
2022                 AddWinners(team, t);
2023                 return WINNING_YES;
2024         }
2025         else
2026                 return WINNING_NO;
2027 }
2028
2029 /*
2030 ============
2031 CheckRules_World
2032
2033 Exit deathmatch games upon conditions
2034 ============
2035 */
2036 void ReadyRestart();
2037 void CheckRules_World()
2038 {
2039         float timelimit;
2040         float fraglimit;
2041         float leadlimit;
2042
2043         VoteThink();
2044         MapVote_Think();
2045
2046         SetDefaultAlpha();
2047
2048         /*
2049         MapVote_Think should now do that part
2050         if (intermission_running)
2051                 if (time >= intermission_exittime + 60)
2052                 {
2053                         if(!DoNextMapOverride())
2054                                 GotoNextMap();
2055                         return;
2056                 }
2057         */
2058
2059         if (gameover)   // someone else quit the game already
2060         {
2061                 if(player_count == 0) // Nobody there? Then let's go to the next map
2062                         MapVote_Start();
2063                         // this will actually check the player count in the next frame
2064                         // again, but this shouldn't hurt
2065                 return;
2066         }
2067
2068         timelimit = autocvar_timelimit * 60;
2069         fraglimit = autocvar_fraglimit;
2070         leadlimit = autocvar_leadlimit;
2071
2072         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2073         {
2074                 if(timelimit > 0)
2075                         timelimit = 0; // timelimit is not made for warmup
2076                 if(fraglimit > 0)
2077                         fraglimit = 0; // no fraglimit for now
2078                 leadlimit = 0; // no leadlimit for now
2079         }
2080
2081         if(timelimit > 0)
2082         {
2083                 timelimit += game_starttime;
2084         }
2085         else if (timelimit < 0)
2086         {
2087                 // endmatch
2088                 NextLevel();
2089                 return;
2090         }
2091
2092         if(g_onslaught)
2093                 timelimit = 0; // ONS has its own overtime rule
2094
2095         float wantovertime;
2096         wantovertime = 0;
2097
2098         if(timelimit > game_starttime)
2099                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2100         else
2101                 game_completion_ratio = 0;
2102
2103         if(checkrules_suddendeathend)
2104         {
2105                 if(!checkrules_suddendeathwarning)
2106                 {
2107                         checkrules_suddendeathwarning = TRUE;
2108                         if(g_race && !g_race_qualifying)
2109                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2110                         else
2111                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2112                 }
2113         }
2114         else
2115         {
2116                 if (timelimit && time >= timelimit)
2117                 {
2118                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2119                         {
2120                                 float totalplayers;
2121                                 float playerswithlaps;
2122                                 float readyplayers;
2123                                 entity head;
2124                                 totalplayers = playerswithlaps = readyplayers = 0;
2125                                 FOR_EACH_PLAYER(head)
2126                                 {
2127                                         ++totalplayers;
2128                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2129                                                 ++playerswithlaps;
2130                                         if(head.ready)
2131                                                 ++readyplayers;
2132                                 }
2133
2134                                 // at least 2 of the players have completed a lap: start the RACE
2135                                 // otherwise, the players should end the qualifying on their own
2136                                 if(readyplayers || playerswithlaps >= 2)
2137                                 {
2138                                         checkrules_suddendeathend = 0;
2139                                         ReadyRestart(); // go to race
2140                                         return;
2141                                 }
2142                                 else
2143                                         wantovertime |= InitiateSuddenDeath();
2144                         }
2145                         else
2146                                 wantovertime |= InitiateSuddenDeath();
2147                 }
2148         }
2149
2150         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2151         {
2152                 NextLevel();
2153                 return;
2154         }
2155
2156         float checkrules_status;
2157         checkrules_status = WinningCondition_RanOutOfSpawns();
2158         if(checkrules_status == WINNING_YES)
2159         {
2160                 bprint("Hey! Someone ran out of spawns!\n");
2161         }
2162         else if(g_race && !g_race_qualifying && timelimit >= 0)
2163         {
2164                 checkrules_status = WinningCondition_Race(fraglimit);
2165                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2166         }
2167         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2168         {
2169                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2170                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2171         }
2172         else if(g_assault)
2173         {
2174                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2175         }
2176         else if(g_lms)
2177         {
2178                 checkrules_status = WinningCondition_LMS();
2179         }
2180         else if (g_onslaught)
2181         {
2182                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2183         }
2184         else
2185         {
2186                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2187                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2188         }
2189
2190         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2191         {
2192                 checkrules_status = WINNING_NEVER;
2193                 checkrules_overtimesadded = -1;
2194                 wantovertime |= InitiateSuddenDeath();
2195         }
2196
2197         if(checkrules_status == WINNING_NEVER)
2198                 // equality cases! Nobody wins if the overtime ends in a draw.
2199                 ClearWinners();
2200
2201         if(wantovertime)
2202         {
2203                 if(checkrules_status == WINNING_NEVER)
2204                         InitiateOvertime();
2205                 else
2206                         checkrules_status = WINNING_YES;
2207         }
2208
2209         if(checkrules_suddendeathend)
2210                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2211                         checkrules_status = WINNING_YES;
2212
2213         if(checkrules_status == WINNING_YES)
2214         {
2215                 //print("WINNING\n");
2216                 NextLevel();
2217         }
2218 }
2219
2220 float mapvote_nextthink;
2221 float mapvote_initialized;
2222 float mapvote_keeptwotime;
2223 float mapvote_timeout;
2224 string mapvote_message;
2225 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2226 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2227 float mapvote_screenshot_dirs_count;
2228
2229 float mapvote_count;
2230 float mapvote_count_real;
2231 string mapvote_maps[MAPVOTE_COUNT];
2232 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2233 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2234 float mapvote_maps_suggested[MAPVOTE_COUNT];
2235 string mapvote_suggestions[MAPVOTE_COUNT];
2236 float mapvote_suggestion_ptr;
2237 float mapvote_voters;
2238 float mapvote_selections[MAPVOTE_COUNT];
2239 float mapvote_run;
2240 float mapvote_detail;
2241 float mapvote_abstain;
2242 .float mapvote;
2243
2244 void MapVote_ClearAllVotes()
2245 {
2246         FOR_EACH_CLIENT(other)
2247                 other.mapvote = 0;
2248 }
2249
2250 string MapVote_Suggest(string m)
2251 {
2252         float i;
2253         if(m == "")
2254                 return "That's not how to use this command.";
2255         if(!autocvar_g_maplist_votable_suggestions)
2256                 return "Suggestions are not accepted on this server.";
2257         if(mapvote_initialized)
2258                 return "Can't suggest - voting is already in progress!";
2259         m = MapInfo_FixName(m);
2260         if not(m)
2261                 return "The map you suggested is not available on this server.";
2262         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2263                 if(Map_IsRecent(m))
2264                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2265
2266         if(!MapInfo_CheckMap(m))
2267                 return "The map you suggested does not support the current game mode.";
2268         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2269                 if(mapvote_suggestions[i] == m)
2270                         return "This map was already suggested.";
2271         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2272         {
2273                 i = floor(random() * mapvote_suggestion_ptr);
2274         }
2275         else
2276         {
2277                 i = mapvote_suggestion_ptr;
2278                 mapvote_suggestion_ptr += 1;
2279         }
2280         if(mapvote_suggestions[i] != "")
2281                 strunzone(mapvote_suggestions[i]);
2282         mapvote_suggestions[i] = strzone(m);
2283         if(autocvar_sv_eventlog)
2284                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2285         return strcat("Suggestion of ", m, " accepted.");
2286 }
2287
2288 void MapVote_AddVotable(string nextMap, float isSuggestion)
2289 {
2290         float j, i, o;
2291         string pakfile, mapfile;
2292
2293         if(nextMap == "")
2294                 return;
2295         for(j = 0; j < mapvote_count; ++j)
2296                 if(mapvote_maps[j] == nextMap)
2297                         return;
2298         // suggestions might be no longer valid/allowed after gametype switch!
2299         if(isSuggestion)
2300                 if(!MapInfo_CheckMap(nextMap))
2301                         return;
2302         mapvote_maps[mapvote_count] = strzone(nextMap);
2303         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2304
2305         pakfile = string_null;
2306         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2307         {
2308                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2309                 pakfile = whichpack(strcat(mapfile, ".tga"));
2310                 if(pakfile == "")
2311                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2312                 if(pakfile == "")
2313                         pakfile = whichpack(strcat(mapfile, ".png"));
2314                 if(pakfile != "")
2315                         break;
2316         }
2317         if(i >= mapvote_screenshot_dirs_count)
2318                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2319         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2320                 pakfile = substring(pakfile, o, -1);
2321
2322         mapvote_maps_screenshot_dir[mapvote_count] = i;
2323         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2324
2325         mapvote_count += 1;
2326 }
2327
2328 void MapVote_Spawn();
2329 void MapVote_Init()
2330 {
2331         float i;
2332         float nmax, smax;
2333
2334         MapVote_ClearAllVotes();
2335
2336         mapvote_count = 0;
2337         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2338         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2339
2340         if(mapvote_abstain)
2341                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2342         else
2343                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2344         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2345
2346         // we need this for AddVotable, as that cycles through the screenshot dirs
2347         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2348         if(mapvote_screenshot_dirs_count == 0)
2349                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2350         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2351         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2352                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2353
2354         if(mapvote_suggestion_ptr)
2355                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2356                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2357
2358         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2359                 MapVote_AddVotable(GetNextMap(), FALSE);
2360
2361         if(mapvote_count == 0)
2362         {
2363                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2364                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2365                 if(autocvar_g_maplist_shuffle)
2366                         ShuffleMaplist();
2367                 localcmd("\nmenu_cmd sync\n");
2368                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2369                         MapVote_AddVotable(GetNextMap(), FALSE);
2370         }
2371
2372         mapvote_count_real = mapvote_count;
2373         if(mapvote_abstain)
2374                 MapVote_AddVotable("don't care", 0);
2375
2376         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2377
2378         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2379         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2380         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2381                 mapvote_keeptwotime = 0;
2382         mapvote_message = "Choose a map and press its key!";
2383
2384         MapVote_Spawn();
2385 }
2386
2387 void MapVote_SendPicture(float id)
2388 {
2389         msg_entity = self;
2390         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2391         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2392         WriteByte(MSG_ONE, id);
2393         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2394 }
2395
2396 float MapVote_GetMapMask()
2397 {
2398         float mask, i, power;
2399         mask = 0;
2400         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2401                 if(mapvote_maps[i] != "")
2402                         mask |= power;
2403         return mask;
2404 }
2405
2406 entity mapvote_ent;
2407 float MapVote_SendEntity(entity to, float sf)
2408 {
2409         float i;
2410
2411         if(sf & 1)
2412                 sf &= ~2; // if we send 1, we don't need to also send 2
2413
2414         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2415         WriteByte(MSG_ENTITY, sf);
2416
2417         if(sf & 1)
2418         {
2419                 // flag 1 == initialization
2420                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2421                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2422                 WriteString(MSG_ENTITY, "");
2423                 WriteByte(MSG_ENTITY, mapvote_count);
2424                 WriteByte(MSG_ENTITY, mapvote_abstain);
2425                 WriteByte(MSG_ENTITY, mapvote_detail);
2426                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2427                 if(mapvote_count <= 8)
2428                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2429                 else
2430                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2431                 for(i = 0; i < mapvote_count; ++i)
2432                         if(mapvote_maps[i] != "")
2433                         {
2434                                 if(mapvote_abstain && i == mapvote_count - 1)
2435                                 {
2436                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2437                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2438                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2439                                 }
2440                                 else
2441                                 {
2442                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2443                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2444                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2445                                 }
2446                         }
2447         }
2448
2449         if(sf & 2)
2450         {
2451                 // flag 2 == update of mask
2452                 if(mapvote_count <= 8)
2453                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2454                 else
2455                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2456         }
2457
2458         if(sf & 4)
2459         {
2460                 if(mapvote_detail)
2461                         for(i = 0; i < mapvote_count; ++i)
2462                                 if(mapvote_maps[i] != "")
2463                                         WriteByte(MSG_ENTITY, mapvote_selections[i]);
2464
2465                 WriteByte(MSG_ENTITY, to.mapvote);
2466         }
2467
2468         return TRUE;
2469 }
2470
2471 void MapVote_Spawn()
2472 {
2473         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2474 }
2475
2476 void MapVote_TouchMask()
2477 {
2478         mapvote_ent.SendFlags |= 2;
2479 }
2480
2481 void MapVote_TouchVotes(entity voter)
2482 {
2483         mapvote_ent.SendFlags |= 4;
2484 }
2485
2486 float MapVote_Finished(float mappos)
2487 {
2488         string result;
2489         float i;
2490         float didntvote;
2491
2492         if(autocvar_sv_eventlog)
2493         {
2494                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2495                 result = strcat(result, ":", ftos(mapvote_selections[mappos]), "::");
2496                 didntvote = mapvote_voters;
2497                 for(i = 0; i < mapvote_count; ++i)
2498                         if(mapvote_maps[i] != "")
2499                         {
2500                                 didntvote -= mapvote_selections[i];
2501                                 if(i != mappos)
2502                                 {
2503                                         result = strcat(result, ":", mapvote_maps[i]);
2504                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2505                                 }
2506                         }
2507                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2508
2509                 GameLogEcho(result);
2510                 if(mapvote_maps_suggested[mappos])
2511                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2512         }
2513
2514         FOR_EACH_REALCLIENT(other)
2515                 FixClientCvars(other);
2516
2517         Map_Goto_SetStr(mapvote_maps[mappos]);
2518         Map_Goto(0);
2519         alreadychangedlevel = TRUE;
2520         return TRUE;
2521 }
2522 void MapVote_CheckRules_1()
2523 {
2524         float i;
2525
2526         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2527         {
2528                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2529                 mapvote_selections[i] = 0;
2530         }
2531
2532         mapvote_voters = 0;
2533         FOR_EACH_REALCLIENT(other)
2534         {
2535                 ++mapvote_voters;
2536                 if(other.mapvote)
2537                 {
2538                         i = other.mapvote - 1;
2539                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2540                         mapvote_selections[i] = mapvote_selections[i] + 1;
2541                 }
2542         }
2543 }
2544
2545 float MapVote_CheckRules_2()
2546 {
2547         float i;
2548         float firstPlace, secondPlace;
2549         float firstPlaceVotes, secondPlaceVotes;
2550         float mapvote_voters_real;
2551         string result;
2552
2553         if(mapvote_count_real == 1)
2554                 return MapVote_Finished(0);
2555
2556         mapvote_voters_real = mapvote_voters;
2557         if(mapvote_abstain)
2558                 mapvote_voters_real -= mapvote_selections[mapvote_count - 1];
2559
2560         RandomSelection_Init();
2561         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2562                 RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2563         firstPlace = RandomSelection_chosen_float;
2564         firstPlaceVotes = RandomSelection_best_priority;
2565         //dprint("First place: ", ftos(firstPlace), "\n");
2566         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2567
2568         RandomSelection_Init();
2569         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2570                 if(i != firstPlace)
2571                         RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2572         secondPlace = RandomSelection_chosen_float;
2573         secondPlaceVotes = RandomSelection_best_priority;
2574         //dprint("Second place: ", ftos(secondPlace), "\n");
2575         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2576
2577         if(firstPlace == -1)
2578                 error("No first place in map vote... WTF?");
2579
2580         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2581                 return MapVote_Finished(firstPlace);
2582
2583         if(mapvote_keeptwotime)
2584                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2585                 {
2586                         float didntvote;
2587                         MapVote_TouchMask();
2588                         mapvote_message = "Now decide between the TOP TWO!";
2589                         mapvote_keeptwotime = 0;
2590                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2591                         result = strcat(result, ":", ftos(firstPlaceVotes));
2592                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2593                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2594                         didntvote = mapvote_voters;
2595                         for(i = 0; i < mapvote_count; ++i)
2596                                 if(mapvote_maps[i] != "")
2597                                 {
2598                                         didntvote -= mapvote_selections[i];
2599                                         if(i != firstPlace)
2600                                                 if(i != secondPlace)
2601                                                 {
2602                                                         result = strcat(result, ":", mapvote_maps[i]);
2603                                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2604                                                         if(i < mapvote_count_real)
2605                                                         {
2606                                                                 strunzone(mapvote_maps[i]);
2607                                                                 mapvote_maps[i] = "";
2608                                                                 strunzone(mapvote_maps_pakfile[i]);
2609                                                                 mapvote_maps_pakfile[i] = "";
2610                                                         }
2611                                                 }
2612                                 }
2613                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2614                         if(autocvar_sv_eventlog)
2615                                 GameLogEcho(result);
2616                 }
2617
2618         return FALSE;
2619 }
2620 void MapVote_Tick()
2621 {
2622         float keeptwo;
2623         float totalvotes;
2624
2625         keeptwo = mapvote_keeptwotime;
2626         MapVote_CheckRules_1(); // count
2627         if(MapVote_CheckRules_2()) // decide
2628                 return;
2629
2630         totalvotes = 0;
2631         FOR_EACH_REALCLIENT(other)
2632         {
2633                 // hide scoreboard again
2634                 if(other.health != 2342)
2635                 {
2636                         other.health = 2342;
2637                         other.impulse = 0;
2638                         if(IS_REAL_CLIENT(other))
2639                         {
2640                                 msg_entity = other;
2641                                 WriteByte(MSG_ONE, SVC_FINALE);
2642                                 WriteString(MSG_ONE, "");
2643                         }
2644                 }
2645
2646                 // clear possibly invalid votes
2647                 if(mapvote_maps[other.mapvote - 1] == "")
2648                         other.mapvote = 0;
2649                 // use impulses as new vote
2650                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2651                         if(mapvote_maps[other.impulse - 1] != "")
2652                         {
2653                                 other.mapvote = other.impulse;
2654                                 MapVote_TouchVotes(other);
2655                         }
2656                 other.impulse = 0;
2657
2658                 if(other.mapvote)
2659                         ++totalvotes;
2660         }
2661
2662         MapVote_CheckRules_1(); // just count
2663 }
2664 void MapVote_Start()
2665 {
2666         if(mapvote_run)
2667                 return;
2668
2669         // wait for stats to be sent first
2670         if(!playerstats_waitforme)
2671                 return;
2672
2673         MapInfo_Enumerate();
2674         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2675                 mapvote_run = TRUE;
2676 }
2677 void MapVote_Think()
2678 {
2679         if(!mapvote_run)
2680                 return;
2681
2682         if(alreadychangedlevel)
2683                 return;
2684
2685         if(time < mapvote_nextthink)
2686                 return;
2687         //dprint("tick\n");
2688
2689         mapvote_nextthink = time + 0.5;
2690
2691         if(!mapvote_initialized)
2692         {
2693                 if(autocvar_rescan_pending == 1)
2694                 {
2695                         cvar_set("rescan_pending", "2");
2696                         localcmd("fs_rescan\nrescan_pending 3\n");
2697                         return;
2698                 }
2699                 else if(autocvar_rescan_pending == 2)
2700                 {
2701                         return;
2702                 }
2703                 else if(autocvar_rescan_pending == 3)
2704                 {
2705                         // now build missing mapinfo files
2706                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2707                                 return;
2708
2709                         // we're done, start the timer
2710                         cvar_set("rescan_pending", "0");
2711                 }
2712
2713                 mapvote_initialized = TRUE;
2714                 if(DoNextMapOverride(0))
2715                         return;
2716                 if(!autocvar_g_maplist_votable || player_count <= 0)
2717                 {
2718                         GotoNextMap(0);
2719                         return;
2720                 }
2721                 MapVote_Init();
2722         }
2723
2724         MapVote_Tick();
2725 }
2726
2727 string GotoMap(string m)
2728 {
2729         if(!MapInfo_CheckMap(m))
2730                 return "The map you chose is not available on this server.";
2731         cvar_set("nextmap", m);
2732         cvar_set("timelimit", "-1");
2733         if(mapvote_initialized || alreadychangedlevel)
2734         {
2735                 if(DoNextMapOverride(0))
2736                         return "Map switch initiated.";
2737                 else
2738                         return "Hm... no. For some reason I like THIS map more.";
2739         }
2740         else
2741                 return "Map switch will happen after scoreboard.";
2742 }
2743
2744
2745 void EndFrame()
2746 {
2747         float altime;
2748         FOR_EACH_REALCLIENT(self)
2749         {
2750                 if(IS_SPEC(self))
2751                 {
2752                         if(self.enemy.typehitsound)
2753                                 self.typehit_time = time;
2754                         else if(self.enemy.hitsound)
2755                                 self.hit_time = time;
2756                 }
2757                 else
2758                 {
2759                         if(self.typehitsound)
2760                                 self.typehit_time = time;
2761                         else if(self.hitsound)
2762                                 self.hit_time = time;
2763                 }
2764         }
2765         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2766         // add 1 frametime because after this, engine SV_Physics
2767         // increases time by a frametime and then networks the frame
2768         // add another frametime because client shows everything with
2769         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2770         // needed!
2771         FOR_EACH_CLIENT(self)
2772         {
2773                 self.hitsound = FALSE;
2774                 self.typehitsound = FALSE;
2775                 antilag_record(self, altime);
2776         }
2777 }
2778
2779
2780 /*
2781  * RedirectionThink:
2782  * returns TRUE if redirecting
2783  */
2784 float redirection_timeout;
2785 float redirection_nextthink;
2786 float RedirectionThink()
2787 {
2788         float clients_found;
2789
2790         if(redirection_target == "")
2791                 return FALSE;
2792
2793         if(!redirection_timeout)
2794         {
2795                 cvar_set("sv_public", "-2");
2796                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2797                 if(redirection_target == "self")
2798                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2799                 else
2800                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2801         }
2802
2803         if(time < redirection_nextthink)
2804                 return TRUE;
2805
2806         redirection_nextthink = time + 1;
2807
2808         clients_found = 0;
2809         FOR_EACH_REALCLIENT(self)
2810         {
2811                 // TODO add timer
2812                 print("Redirecting: sending connect command to ", self.netname, "\n");
2813                 if(redirection_target == "self")
2814                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2815                 else
2816                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2817                 ++clients_found;
2818         }
2819
2820         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2821
2822         if(time > redirection_timeout || clients_found == 0)
2823                 localcmd("\nwait; wait; wait; quit\n");
2824
2825         return TRUE;
2826 }
2827
2828 void TargetMusic_RestoreGame();
2829 void RestoreGame()
2830 {
2831         // Loaded from a save game
2832         // some things then break, so let's work around them...
2833
2834         // Progs DB (capture records)
2835         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2836
2837         // Mapinfo
2838         MapInfo_Shutdown();
2839         MapInfo_Enumerate();
2840         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2841         WeaponStats_Init();
2842
2843         TargetMusic_RestoreGame();
2844 }
2845
2846 void Shutdown()
2847 {
2848         entity e;
2849
2850         gameover = 2;
2851
2852         if(world_initialized > 0)
2853         {
2854                 world_initialized = 0;
2855                 print("Saving persistent data...\n");
2856                 Ban_SaveBans();
2857
2858                 PlayerStats_EndMatch(0);
2859                 FOR_EACH_CLIENT(e)
2860                         PlayerStats_AddGlobalInfo(e);
2861                 PlayerStats_Shutdown();
2862
2863                 if(!cheatcount_total)
2864                 {
2865                         if(autocvar_sv_db_saveasdump)
2866                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2867                         else
2868                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2869                 }
2870                 if(autocvar_developer)
2871                 {
2872                         if(autocvar_sv_db_saveasdump)
2873                                 db_dump(TemporaryDB, "server-temp.db");
2874                         else
2875                                 db_save(TemporaryDB, "server-temp.db");
2876                 }
2877                 CheatShutdown(); // must be after cheatcount check
2878                 db_close(ServerProgsDB);
2879                 db_close(TemporaryDB);
2880                 print("done!\n");
2881                 // tell the bot system the game is ending now
2882                 bot_endgame();
2883
2884                 WeaponStats_Shutdown();
2885                 MapInfo_Shutdown();
2886         }
2887         else if(world_initialized == 0)
2888         {
2889                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2890         }
2891 }