qcsrc/server/g_world.qc

   1 entity pingplreport;
   2 void PingPLReport_Think()
   3 {
   4         float delta;
   5         entity e;
   6
   7         delta = 3 / maxclients;
   8         if(delta < sys_frametime)
   9                 delta = 0;
  10         self.nextthink = time + delta;
  11
  12         e = edict_num(self.cnt + 1);
  13         if(clienttype(e) == CLIENTTYPE_REAL)
  14         {
  15                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  16                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  17                 WriteByte(MSG_BROADCAST, self.cnt);
  18                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  19                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  20                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  21         }
  22         else
  23         {
  24                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  25                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  26                 WriteByte(MSG_BROADCAST, self.cnt);
  27                 WriteShort(MSG_BROADCAST, 0);
  28                 WriteByte(MSG_BROADCAST, 0);
  29                 WriteByte(MSG_BROADCAST, 0);
  30         }
  31         self.cnt = mod(self.cnt + 1, maxclients);
  32 }
  33 void PingPLReport_Spawn()
  34 {
  35         pingplreport = spawn();
  36         pingplreport.classname = "pingplreport";
  37         pingplreport.think = PingPLReport_Think;
  38         pingplreport.nextthink = time;
  39 }
  40
  41 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  42 string redirection_target;
  43 float world_initialized;
  44
  45 string GetMapname();
  46 string GetGametype();
  47 void GotoNextMap();
  48 void ShuffleMaplist()
  49 float() DoNextMapOverride;
  50
  51 void SetDefaultAlpha()
  52 {
  53         if(cvar("g_running_guns"))
  54         {
  55                 default_player_alpha = -1;
  56                 default_weapon_alpha = +1;
  57         }
  58         else if(g_cloaked)
  59         {
  60                 default_player_alpha = cvar("g_balance_cloaked_alpha");
  61                 default_weapon_alpha = default_player_alpha;
  62         }
  63         else
  64         {
  65                 default_player_alpha = cvar("g_player_alpha");
  66                 if(default_player_alpha == 0)
  67                         default_player_alpha = 1;
  68                 default_weapon_alpha = default_player_alpha;
  69         }
  70 }
  71
  72 void fteqcc_testbugs()
  73 {
  74         float a, b;
  75
  76         if(!cvar("developer_fteqccbugs"))
  77                 return;
  78
  79         dprint("*** fteqcc test: checking for bugs...\n");
  80
  81         a = 1;
  82         b = 5;
  83         if(sqrt(a) - sqrt(b - a) == 0)
  84                 dprint("*** fteqcc test: found same-function-twice bug\n");
  85         else
  86                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  87
  88         world.cnt = -10;
  89         world.enemy = world;
  90         world.enemy.cnt += 10;
  91         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  92                 dprint("*** fteqcc test: found += bug\n");
  93         else
  94                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  95         world.cnt = 0;
  96 }
  97
  98 /**
  99  * Takes care of pausing and unpausing the game.
 100  * Centerprints the information about an upcoming or active timeout to all active
 101  * players. Also plays reminder sounds.
 102  */
 103 void timeoutHandler_Think() {
 104         local string timeStr;
 105         local entity plr;
 106         if (timeoutStatus == 1) {
 107                 if (remainingLeadTime > 0) {
 108                         //centerprint the information to every player
 109                         timeStr = getTimeoutText(0);
 110                         FOR_EACH_REALCLIENT(plr) {
 111                                 if(plr.classname == "player") {
 112                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 113                                 }
 114                         }
 115                         remainingLeadTime -= 1;
 116                         //think again in 1 second:
 117                         self.nextthink = time + 1;
 118                 }
 119                 else {
 120                         //now pause the game:
 121                         timeoutStatus = 2;
 122                         //reset all the flood variables
 123                         FOR_EACH_CLIENT(plr) {
 124                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
 125                         }
 126                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 127                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 128                         FOR_EACH_REALPLAYER(plr) {
 129                                 plr.lastV_angle = plr.v_angle;
 130                         }
 131                         self.nextthink = time;
 132                 }
 133         }
 134         else if (timeoutStatus == 2) {
 135                 if (remainingTimeoutTime > 0) {
 136                         timeStr = getTimeoutText(0);
 137                         FOR_EACH_REALCLIENT(plr) {
 138                                 if(plr.classname == "player") {
 139                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 140                                 }
 141                         }
 142                         if(remainingTimeoutTime == cvar("sv_timeout_resumetime")) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 143                                 Announce("prepareforbattle");
 144                         }
 145                         remainingTimeoutTime -= 1;
 146                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 147                 }
 148                 else {
 149                         //unpause the game again
 150                         remainingTimeoutTime = timeoutStatus = 0;
 151                         cvar_set("slowmo", ftos(orig_slowmo));
 152                         //and unlock the fixed view again once there is no timeout active anymore
 153                         FOR_EACH_REALPLAYER(plr) {
 154                                 plr.fixangle = FALSE;
 155                         }
 156                         //get rid of the countdown message
 157                         FOR_EACH_REALCLIENT(plr) {
 158                                 if(plr.classname == "player") {
 159                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 160                                 }
 161                         }
 162                         remove(self);
 163                         return;
 164                 }
 165
 166         }
 167         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 168                 FOR_EACH_REALCLIENT(plr) {
 169                         if(plr.classname == "player") {
 170                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 171                         }
 172                 }
 173                 remove(self);
 174                 return;
 175         }
 176 }
 177
 178 void GotoFirstMap()
 179 {
 180         float n;
 181         if(cvar("_sv_init"))
 182         {
 183                 // cvar_set("_sv_init", "0");
 184                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 185                 // to this "init" map on a dedicated server will cause no permanent
 186                 // harm
 187                 if(cvar("g_maplist_shuffle"))
 188                         ShuffleMaplist();
 189                 n = tokenizebyseparator(cvar_string("g_maplist"), " ");
 190                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 191
 192                 MapInfo_Enumerate();
 193                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 194
 195                 if(!DoNextMapOverride())
 196                         GotoNextMap();
 197
 198                 return;
 199         }
 200
 201         if(time < 5)
 202         {
 203                 self.nextthink = time;
 204         }
 205         else
 206         {
 207                 self.nextthink = time + 1;
 208                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 209         }
 210 }
 211
 212 void cvar_changes_init()
 213 {
 214         float h;
 215         string k, v, d;
 216         float n, i, adding, pureadding;
 217
 218         if(cvar_changes)
 219                 strunzone(cvar_changes);
 220         cvar_changes = string_null;
 221         if(cvar_purechanges)
 222                 strunzone(cvar_purechanges);
 223         cvar_purechanges = string_null;
 224         cvar_purechanges_count = 0;
 225
 226         h = buf_create();
 227         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 228         n = buf_getsize(h);
 229
 230         adding = TRUE;
 231         pureadding = TRUE;
 232
 233         for(i = 0; i < n; ++i)
 234         {
 235                 k = bufstr_get(h, i);
 236
 237 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 238 #define BADCVAR(p) if(k == p) continue
 239                 // internal
 240                 BADPREFIX("csqc_");
 241                 BADPREFIX("cvar_check_");
 242                 BADCVAR("gamecfg");
 243                 BADCVAR("g_configversion");
 244                 BADCVAR("g_maplist_index");
 245                 BADCVAR("halflifebsp");
 246                 BADPREFIX("sv_world");
 247
 248                 // client
 249                 BADPREFIX("chase_");
 250                 BADPREFIX("cl_");
 251                 BADPREFIX("con_");
 252                 BADPREFIX("scoreboard_");
 253                 BADPREFIX("g_campaign");
 254                 BADPREFIX("gl_");
 255                 BADPREFIX("joy");
 256                 BADPREFIX("hud_");
 257                 BADPREFIX("menu_");
 258                 BADPREFIX("net_slist_");
 259                 BADPREFIX("r_");
 260                 BADPREFIX("sbar_");
 261                 BADPREFIX("scr_");
 262                 BADPREFIX("snd_");
 263                 BADPREFIX("userbind");
 264                 BADPREFIX("v_");
 265                 BADPREFIX("vid_");
 266                 BADPREFIX("crosshair");
 267                 BADCVAR("mod_q3bsp_lightmapmergepower");
 268                 BADCVAR("mod_q3bsp_nolightmaps");
 269                 BADCVAR("fov");
 270                 BADCVAR("mastervolume");
 271                 BADCVAR("volume");
 272                 BADCVAR("bgmvolume");
 273
 274                 // private
 275                 BADCVAR("serverconfig");
 276                 BADPREFIX("g_ban_");
 277                 BADPREFIX("g_chat_flood_");
 278                 BADPREFIX("g_voice_flood_");
 279                 BADPREFIX("rcon_");
 280                 BADPREFIX("settemp_");
 281                 BADPREFIX("sv_allowdownloads_");
 282                 BADPREFIX("sv_autodemo");
 283                 BADPREFIX("sv_curl_");
 284                 BADPREFIX("sv_eventlog");
 285                 BADPREFIX("sv_logscores_");
 286                 BADPREFIX("sv_master");
 287                 BADCVAR("g_banned_list");
 288                 BADCVAR("log_dest_udp");
 289                 BADCVAR("log_file");
 290                 BADCVAR("net_address");
 291                 BADCVAR("port");
 292                 BADCVAR("savedgamecfg");
 293                 BADCVAR("sv_heartbeatperiod");
 294                 BADCVAR("sv_vote_master_password");
 295                 BADCVAR("sys_colortranslation");
 296                 BADCVAR("sys_specialcharactertranslation");
 297                 BADCVAR("timestamps");
 298                 BADCVAR("net_address");
 299                 BADCVAR("net_address_ipv6");
 300                 BADPREFIX("sv_weaponstats_");
 301                 BADCVAR("developer");
 302                 BADPREFIX("developer_");
 303
 304                 // mapinfo
 305                 BADCVAR("timelimit");
 306                 BADCVAR("fraglimit");
 307                 BADCVAR("g_arena");
 308                 BADCVAR("g_ca");
 309                 BADCVAR("g_assault");
 310                 BADCVAR("g_ctf");
 311                 BADCVAR("g_dm");
 312                 BADCVAR("g_domination");
 313                 BADCVAR("g_keyhunt");
 314                 BADCVAR("g_keyhunt_teams");
 315                 BADCVAR("g_onslaught");
 316                 BADCVAR("g_race");
 317                 BADCVAR("g_cts");
 318                 BADCVAR("g_runematch");
 319                 BADCVAR("g_tdm");
 320                 BADCVAR("g_nexball");
 321                 BADCVAR("teamplay");
 322
 323                 // long
 324                 BADCVAR("hostname");
 325                 BADCVAR("g_maplist");
 326                 BADCVAR("g_maplist_mostrecent");
 327                 BADCVAR("sv_motd");
 328
 329                 v = cvar_string(k);
 330                 d = cvar_defstring(k);
 331                 if(v == d)
 332                         continue;
 333
 334                 if(adding)
 335                 {
 336                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 337                         if(strlen(cvar_changes) > 16384)
 338                         {
 339                                 cvar_changes = "// too many settings have been changed to show them here\n";
 340                                 adding = 0;
 341                         }
 342                 }
 343
 344                 // now check if the changes are actually gameplay relevant
 345
 346                 // does nothing visible
 347                 BADPREFIX("prvm_");
 348                 BADPREFIX("crypto_");
 349                 BADPREFIX("g_chat_");
 350                 BADPREFIX("sv_fragmessage_");
 351                 BADPREFIX("sv_vote_");
 352                 BADPREFIX("timelimit_");
 353
 354                 // allowed changes to server admins (please sync this to server.cfg)
 355                 // vi commands:
 356                 //   :/"impure"/,$d
 357                 //   :g!,^\/\/[^ /],d
 358                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 359                 //   :%!sort
 360                 // yes, this does contain some redundant stuff, don't really care
 361                 BADCVAR("bot_number");
 362                 BADCVAR("bot_prefix");
 363                 BADCVAR("bot_suffix");
 364                 BADCVAR("capturelimit_override");
 365                 BADCVAR("fraglimit_override");
 366                 BADCVAR("gametype");
 367                 BADCVAR("g_antilag");
 368                 BADCVAR("g_balance_teams");
 369                 BADCVAR("g_balance_teams_force");
 370                 BADCVAR("g_ban_sync_trusted_servers");
 371                 BADCVAR("g_ban_sync_uri");
 372                 BADCVAR("g_ctf_capture_limit");
 373                 BADCVAR("g_ctf_ignore_frags");
 374                 BADCVAR("g_ctf_win_mode");
 375                 BADCVAR("g_domination_point_limit");
 376                 BADCVAR("g_fullbrightitems");
 377                 BADCVAR("g_fullbrightplayers");
 378                 BADCVAR("g_keyhunt_point_limit");
 379                 BADCVAR("g_keyhunt_teams_override");
 380                 BADCVAR("g_lms_lives_override");
 381                 BADCVAR("g_maplist");
 382                 BADCVAR("g_maplist_check_waypoints");
 383                 BADCVAR("g_maplist_mostrecent_count");
 384                 BADCVAR("g_maplist_shuffle");
 385                 BADCVAR("g_maplist_votable");
 386                 BADCVAR("g_maplist_votable_abstain");
 387                 BADCVAR("g_maplist_votable_nodetail");
 388                 BADCVAR("g_maplist_votable_suggestions");
 389                 BADCVAR("g_nexball_goallimit");
 390                 BADCVAR("g_runematch_point_limit");
 391                 BADCVAR("g_start_delay");
 392                 BADCVAR("hostname");
 393                 BADCVAR("log_file");
 394                 BADCVAR("maxplayers");
 395                 BADCVAR("minplayers");
 396                 BADCVAR("net_address");
 397                 BADCVAR("port");
 398                 BADCVAR("rcon_password");
 399                 BADCVAR("rcon_restricted_commands");
 400                 BADCVAR("rcon_restricted_password");
 401                 BADCVAR("skill");
 402                 BADCVAR("sv_autoscreenshot");
 403                 BADCVAR("sv_curl_defaulturl");
 404                 BADCVAR("sv_defaultcharacter");
 405                 BADCVAR("sv_defaultplayermodel");
 406                 BADCVAR("sv_defaultplayerskin");
 407                 BADCVAR("sv_maxrate");
 408                 BADCVAR("sv_maxidle");
 409                 BADCVAR("sv_motd");
 410                 BADCVAR("sv_public");
 411                 BADCVAR("sv_ready_restart");
 412                 BADCVAR("sv_status_privacy");
 413                 BADCVAR("sv_vote_call");
 414                 BADCVAR("sv_vote_commands");
 415                 BADCVAR("sv_vote_majority_factor");
 416                 BADCVAR("sv_vote_master");
 417                 BADCVAR("sv_vote_master_commands");
 418                 BADCVAR("sv_vote_master_password");
 419                 BADCVAR("sv_vote_simple_majority_factor");
 420                 BADCVAR("timelimit_override");
 421 #undef BADPREFIX
 422 #undef BADCVAR
 423
 424                 if(pureadding)
 425                 {
 426                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 427                         if(strlen(cvar_purechanges) > 16384)
 428                         {
 429                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 430                                 pureadding = 0;
 431                         }
 432                 }
 433                 ++cvar_purechanges_count;
 434         }
 435         buf_del(h);
 436         if(cvar_changes == "")
 437                 cvar_changes = "// this server runs at default server settings\n";
 438         else
 439                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 440         cvar_changes = strzone(cvar_changes);
 441         if(cvar_purechanges == "")
 442                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 443         else
 444                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 445         cvar_purechanges = strzone(cvar_purechanges);
 446 }
 447
 448 void detect_maptype()
 449 {
 450 #if 0
 451         vector o, v;
 452         float i;
 453
 454         for(;;)
 455         {
 456                 o = world.mins;
 457                 o_x += random() * (world.maxs_x - world.mins_x);
 458                 o_y += random() * (world.maxs_y - world.mins_y);
 459                 o_z += random() * (world.maxs_z - world.mins_z);
 460
 461                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 462                 if(trace_fraction == 1)
 463                         continue;
 464
 465                 v = trace_endpos;
 466
 467                 for(i = 0; i < 64; i += 4)
 468                 {
 469                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 470         if(trace_fraction == 1)
 471                 continue;
 472                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 473                 }
 474
 475                 break;
 476         }
 477 #endif
 478 }
 479
 480 entity randomseed;
 481 float RandomSeed_Send(entity to, float sf)
 482 {
 483         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 484         WriteShort(MSG_ENTITY, self.cnt);
 485         return TRUE;
 486 }
 487 void RandomSeed_Think()
 488 {
 489         self.cnt = bound(0, floor(random() * 65536), 65535);
 490         self.nextthink = time + 5;
 491
 492         self.SendFlags |= 1;
 493 }
 494 void RandomSeed_Spawn()
 495 {
 496         randomseed = spawn();
 497         randomseed.think = RandomSeed_Think;
 498         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 499
 500         entity oldself;
 501         oldself = self;
 502         self = randomseed;
 503         self.think(); // sets random seed and nextthink
 504         self = oldself;
 505 }
 506
 507 void spawnfunc___init_dedicated_server(void)
 508 {
 509         // handler for _init/_init map (only for dedicated server initialization)
 510
 511         world_initialized = -1; // don't complain
 512         cvar = cvar_normal;
 513         cvar_string = cvar_string_normal;
 514         cvar_set = cvar_set_normal;
 515
 516         remove = remove_unsafely;
 517
 518         entity e;
 519         e = spawn();
 520         e.think = GotoFirstMap;
 521         e.nextthink = time; // this is usually 1 at this point
 522
 523         e = spawn();
 524         e.classname = "info_player_deathmatch"; // safeguard against player joining
 525
 526         self.classname = "worldspawn"; // safeguard against various stuff ;)
 527
 528         MapInfo_Enumerate();
 529         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 530 }
 531
 532 void Map_MarkAsRecent(string m);
 533 float world_already_spawned;
 534 void RegisterWeapons();
 535 void Nagger_Init();
 536 void ClientInit_Spawn();
 537 void WeaponStats_Init();
 538 void WeaponStats_Shutdown();
 539 void spawnfunc_worldspawn (void)
 540 {
 541         float fd, l, i, j, n;
 542         string s, col;
 543
 544         cvar = cvar_normal;
 545         cvar_string = cvar_string_normal;
 546         cvar_set = cvar_set_normal;
 547
 548         if(world_already_spawned)
 549                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 550         world_already_spawned = TRUE;
 551
 552         remove = remove_safely; // during spawning, watch what you remove!
 553
 554         check_unacceptable_compiler_bugs();
 555
 556         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 557
 558         compressShortVector_init();
 559
 560         allowed_to_spawn = TRUE;
 561
 562         local entity head;
 563         head = nextent(world);
 564         maxclients = 0;
 565         while(head)
 566         {
 567                 ++maxclients;
 568                 head = nextent(head);
 569         }
 570
 571         // needs to be done so early as they would still spawn
 572         RegisterWeapons();
 573
 574         ServerProgsDB = db_load("server.db");
 575
 576         TemporaryDB = db_create();
 577
 578         /*
 579         TODO sound pack system
 580         // initialize sound pack system
 581         soundpack = cvar_string("g_soundpack");
 582         if(soundpack != "")
 583                 soundpack = strcat(soundpack, "/");
 584         soundpack = strzone(soundpack);
 585         */
 586
 587         // 0 normal
 588         lightstyle(0, "m");
 589
 590         // 1 FLICKER (first variety)
 591         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 592
 593         // 2 SLOW STRONG PULSE
 594         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 595
 596         // 3 CANDLE (first variety)
 597         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 598
 599         // 4 FAST STROBE
 600         lightstyle(4, "mamamamamama");
 601
 602         // 5 GENTLE PULSE 1
 603         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 604
 605         // 6 FLICKER (second variety)
 606         lightstyle(6, "nmonqnmomnmomomno");
 607
 608         // 7 CANDLE (second variety)
 609         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 610
 611         // 8 CANDLE (third variety)
 612         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 613
 614         // 9 SLOW STROBE (fourth variety)
 615         lightstyle(9, "aaaaaaaazzzzzzzz");
 616
 617         // 10 FLUORESCENT FLICKER
 618         lightstyle(10, "mmamammmmammamamaaamammma");
 619
 620         // 11 SLOW PULSE NOT FADE TO BLACK
 621         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 622
 623         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 624
 625         // 63 testing
 626         lightstyle(63, "a");
 627
 628         if(cvar("g_campaign"))
 629                 CampaignPreInit();
 630
 631         Map_MarkAsRecent(mapname);
 632
 633         precache_model ("null"); // we need this one before InitGameplayMode
 634         InitGameplayMode();
 635         readlevelcvars();
 636         GrappleHookInit();
 637         ElectroInit();
 638         LaserInit();
 639
 640         player_count = 0;
 641         bot_waypoints_for_items = cvar("g_waypoints_for_items");
 642         if(bot_waypoints_for_items == 1)
 643                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 644                         bot_waypoints_for_items = 0;
 645
 646         // for setting by mapinfo
 647         q3acompat_machineshotgunswap = cvar("sv_q3acompat_machineshotgunswap");
 648         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 649
 650         precache();
 651
 652         WaypointSprite_Init();
 653
 654         //if (g_domination)
 655         //      dom_init();
 656
 657         GameLogInit(); // prepare everything
 658         if(cvar("sv_eventlog"))
 659         {
 660                 s = strcat(cvar_string("sv_eventlog_files_counter"), ".");
 661                 s = strcat(s, ftos(random()));
 662                 matchid = strzone(s);
 663
 664                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 665                 s = ":gameinfo:mutators:LIST";
 666
 667                 ret_string = s;
 668                 MUTATOR_CALLHOOK(BuildMutatorsString);
 669                 s = ret_string;
 670
 671                 if(cvar("g_grappling_hook"))
 672                         s = strcat(s, ":grappling_hook");
 673                 if(!cvar("g_use_ammunition"))
 674                         s = strcat(s, ":no_use_ammunition");
 675                 if(!cvar("g_pickup_items"))
 676                         s = strcat(s, ":no_pickup_items");
 677                 if(cvar_string("g_weaponarena") != "0")
 678                         s = strcat(s, ":", cvar_string("g_weaponarena"), " arena");
 679                 if(cvar("g_vampire"))
 680                         s = strcat(s, ":vampire");
 681                 if(cvar("g_laserguided_missile"))
 682                         s = strcat(s, ":laserguided_missile");
 683                 if(cvar("g_norecoil"))
 684                         s = strcat(s, ":norecoil");
 685                 if(cvar("g_midair"))
 686                         s = strcat(s, ":midair");
 687                 if(cvar("g_minstagib"))
 688                         s = strcat(s, ":minstagib");
 689                 GameLogEcho(s);
 690                 GameLogEcho(":gameinfo:end");
 691         }
 692         else
 693                 matchid = strzone(ftos(random()));
 694
 695         cvar_set("nextmap", "");
 696
 697         SetDefaultAlpha();
 698
 699         if(cvar("g_campaign"))
 700                 CampaignPostInit();
 701
 702         fteqcc_testbugs();
 703
 704         Ban_LoadBans();
 705
 706         MapInfo_Enumerate();
 707         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 708
 709         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 710         {
 711                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 712                 if(fd != -1)
 713                 {
 714                         while((s = fgets(fd)))
 715                         {
 716                                 l = tokenize_console(s);
 717                                 if(l < 2)
 718                                         continue;
 719                                 if(argv(0) == "cd")
 720                                 {
 721                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 722                                         print("  cdtrack ", argv(2), "\n");
 723                                 }
 724                                 else if(argv(0) == "fog")
 725                                 {
 726                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 727                                         print("  \"fog\" \"", s, "\"\n");
 728                                 }
 729                                 else if(argv(0) == "set")
 730                                 {
 731                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 732                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 733                                 }
 734                                 else if(argv(0) != "//")
 735                                 {
 736                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 737                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 738                                 }
 739                         }
 740                         fclose(fd);
 741                 }
 742         }
 743
 744         WeaponStats_Init();
 745
 746         addstat(STAT_WEAPONS, AS_INT, weapons);
 747         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 748         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 749         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 750         Nagger_Init();
 751
 752         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 753         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 754         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 755         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 756         addstat(STAT_DAMAGE_HITS, AS_INT, stat_hit);
 757         addstat(STAT_DAMAGE_FIRED, AS_INT, stat_fired);
 758         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 759         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 760         addstat(STAT_BULLETS_LOADED, AS_INT, campingrifle_bulletcounter);
 761         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 762
 763         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 764
 765         if(g_ca)
 766         {
 767                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 768                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 769         }
 770         // g_movementspeed hack
 771         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 772         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 773         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 774
 775         next_pingtime = time + 5;
 776
 777         detect_maptype();
 778
 779         lsmaps_reply = "^7Maps available: ";
 780         lsnewmaps_reply = "^7Maps without a record set: ";
 781         for(i = 0, j = 0; i < MapInfo_count; ++i)
 782         {
 783                 if(MapInfo_Get_ByID(i))
 784                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 785                         {
 786                                 if(mod(i, 2))
 787                                         col = "^2";
 788                                 else
 789                                         col = "^3";
 790                                 ++j;
 791                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 792                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 793                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 794                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 795                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 796                         }
 797         }
 798         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 799         if (!g_race && !g_cts)
 800                 lsnewmaps_reply = "Need to be playing race or CTS for lsnewmaps to work.";
 801         lsnewmaps_reply = strzone(strcat(lsnewmaps_reply, "\n"));
 802
 803         maplist_reply = "^7Maps in list: ";
 804         n = tokenize_console(cvar_string("g_maplist"));
 805         for(i = 0, j = 0; i < n; ++i)
 806         {
 807                 if(MapInfo_CheckMap(argv(i)))
 808                 {
 809                         if(mod(j, 2))
 810                                 col = "^2";
 811                         else
 812                                 col = "^3";
 813                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 814                         ++j;
 815                 }
 816         }
 817         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 818         MapInfo_ClearTemps();
 819
 820         for(i = 0; i < 10; ++i)
 821         {
 822                 records_reply[i] = strzone(getrecords(i));
 823         }
 824         if(g_cts)
 825                 ladder_reply = strzone(getladder());
 826
 827         rankings_reply = strzone(getrankings());
 828
 829         ClientInit_Spawn();
 830         RandomSeed_Spawn();
 831         PingPLReport_Spawn();
 832
 833         CheatInit();
 834
 835         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 836
 837         // fill sv_curl_serverpackages from .serverpackage files
 838         if(cvar("sv_curl_serverpackages_auto"))
 839         {
 840                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 841                 s = "";
 842                 if(fd >= 0)
 843                 {
 844                         j = search_getsize(fd);
 845                         for(i = 0; i < j; ++i)
 846                                 s = strcat(s, " ", search_getfilename(fd, i));
 847                         search_end(fd);
 848                 }
 849                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 850         }
 851
 852         world_initialized = 1;
 853 }
 854
 855 void spawnfunc_light (void)
 856 {
 857         //makestatic (self); // Who the f___ did that?
 858         remove(self);
 859 }
 860
 861 float TryFile( string pFilename )
 862 {
 863         local float lHandle;
 864         dprint("TryFile(\"", pFilename, "\")\n");
 865         lHandle = fopen( pFilename, FILE_READ );
 866         if( lHandle != -1 ) {
 867                 fclose( lHandle );
 868                 return TRUE;
 869         } else {
 870                 return FALSE;
 871         }
 872 };
 873
 874 string GetGametype()
 875 {
 876         return GametypeNameFromType(game);
 877 }
 878
 879 string getmapname_stored;
 880 string GetMapname()
 881 {
 882         return mapname;
 883 }
 884
 885 float Map_Count, Map_Current;
 886 string Map_Current_Name;
 887
 888 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 889 float GetMaplistPosition()
 890 {
 891         float pos, idx;
 892         string map;
 893
 894         map = GetMapname();
 895         idx = cvar("g_maplist_index");
 896
 897         if(idx >= 0)
 898                 if(idx < Map_Count)
 899                         if(map == argv(idx))
 900                                 return idx;
 901
 902         for(pos = 0; pos < Map_Count; ++pos)
 903                 if(map == argv(pos))
 904                         return pos;
 905
 906         // resume normal maplist rotation if current map is not in g_maplist
 907         return idx;
 908 }
 909
 910 float MapHasRightSize(string map)
 911 {
 912         float fh;
 913         if(currentbots || cvar("bot_number") || player_count < cvar("minplayers"))
 914         if(cvar("g_maplist_check_waypoints"))
 915         {
 916                 dprint("checkwp "); dprint(map);
 917                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
 918                 if(fh < 0)
 919                 {
 920                         dprint(": no waypoints\n");
 921                         return FALSE;
 922                 }
 923                 dprint(": has waypoints\n");
 924                 fclose(fh);
 925         }
 926
 927         // open map size restriction file
 928         dprint("opensize "); dprint(map);
 929         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 930         if(fh >= 0)
 931         {
 932                 float mapmin, mapmax;
 933                 dprint(": ok, ");
 934                 mapmin = stof(fgets(fh));
 935                 mapmax = stof(fgets(fh));
 936                 fclose(fh);
 937                 if(player_count < mapmin)
 938                 {
 939                         dprint("not enough\n");
 940                         return FALSE;
 941                 }
 942                 if(player_count > mapmax)
 943                 {
 944                         dprint("too many\n");
 945                         return FALSE;
 946                 }
 947                 dprint("right size\n");
 948                 return TRUE;
 949         }
 950         dprint(": not found\n");
 951         return TRUE;
 952 }
 953
 954 string Map_Filename(float position)
 955 {
 956         return strcat("maps/", argv(position), ".bsp");
 957 }
 958
 959 string strwords(string s, float w)
 960 {
 961         float endpos;
 962         for(endpos = 0; w && endpos >= 0; --w)
 963                 endpos = strstrofs(s, " ", endpos + 1);
 964         if(endpos < 0)
 965                 return s;
 966         else
 967                 return substring(s, 0, endpos);
 968 }
 969
 970 float strhasword(string s, string w)
 971 {
 972         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 973 }
 974
 975 void Map_MarkAsRecent(string m)
 976 {
 977         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", cvar_string("g_maplist_mostrecent")), max(0, cvar("g_maplist_mostrecent_count"))));
 978 }
 979
 980 float Map_IsRecent(string m)
 981 {
 982         return strhasword(cvar_string("g_maplist_mostrecent"), m);
 983 }
 984
 985 float Map_Check(float position, float pass)
 986 {
 987         string filename;
 988         string map_next;
 989         map_next = argv(position);
 990         if(pass <= 1)
 991         {
 992                 if(Map_IsRecent(map_next))
 993                         return 0;
 994         }
 995         filename = Map_Filename(position);
 996         if(MapInfo_CheckMap(map_next))
 997         {
 998                 if(pass == 2)
 999                         return 1;
1000                 if(MapHasRightSize(map_next))
1001                         return 1;
1002                 return 0;
1003         }
1004         else
1005                 dprint( "Couldn't select '", filename, "'..\n" );
1006
1007         return 0;
1008 }
1009
1010 void Map_Goto_SetStr(string nextmapname)
1011 {
1012         if(getmapname_stored != "")
1013                 strunzone(getmapname_stored);
1014         if(nextmapname == "")
1015                 getmapname_stored = "";
1016         else
1017                 getmapname_stored = strzone(nextmapname);
1018 }
1019
1020 void Map_Goto_SetFloat(float position)
1021 {
1022         cvar_set("g_maplist_index", ftos(position));
1023         Map_Goto_SetStr(argv(position));
1024 }
1025
1026 void GameResetCfg()
1027 {
1028         // settings persist, except...
1029         localcmd("\nsettemp_restore\n");
1030 };
1031
1032 void Map_Goto()
1033 {
1034         GameResetCfg();
1035         MapInfo_LoadMap(getmapname_stored);
1036 }
1037
1038 // return codes of map selectors:
1039 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1040 //   -2 = permanent failure
1041 float() MaplistMethod_Iterate = // usual method
1042 {
1043         float pass, i;
1044
1045         for(pass = 1; pass <= 2; ++pass)
1046         {
1047                 for(i = 1; i < Map_Count; ++i)
1048                 {
1049                         float mapindex;
1050                         mapindex = mod(i + Map_Current, Map_Count);
1051                         if(Map_Check(mapindex, pass))
1052                                 return mapindex;
1053                 }
1054         }
1055         return -1;
1056 }
1057
1058 float() MaplistMethod_Repeat = // fallback method
1059 {
1060         if(Map_Check(Map_Current, 2))
1061                 return Map_Current;
1062         return -2;
1063 }
1064
1065 float() MaplistMethod_Random = // random map selection
1066 {
1067         float i, imax;
1068
1069         imax = 42;
1070
1071         for(i = 0; i <= imax; ++i)
1072         {
1073                 float mapindex;
1074                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1075                 if(Map_Check(mapindex, 1))
1076                         return mapindex;
1077         }
1078         return -1;
1079 }
1080
1081 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1082 // the exponent sets a bias on the map selection:
1083 // the higher the exponent, the less likely "shortly repeated" same maps are
1084 {
1085         float i, j, imax, insertpos;
1086
1087         imax = 42;
1088
1089         for(i = 0; i <= imax; ++i)
1090         {
1091                 string newlist;
1092
1093                 // now reinsert this at another position
1094                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1095                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1096                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1097                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1098
1099                 // insert the current map there
1100                 newlist = "";
1101                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1102                         newlist = strcat(newlist, " ", argv(j));
1103                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1104                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1105                         newlist = strcat(newlist, " ", argv(j));
1106                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1107                 cvar_set("g_maplist", newlist);
1108                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
1109
1110                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1111                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1112                 if(Map_Check(Map_Current, 1))
1113                         return Map_Current;
1114         }
1115         return -1;
1116 }
1117
1118 void Maplist_Init()
1119 {
1120         Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
1121         if(Map_Count == 0)
1122         {
1123                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1124                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1125                 if(cvar("g_maplist_shuffle"))
1126                         ShuffleMaplist();
1127                 localcmd("\nmenu_cmd sync\n");
1128                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
1129         }
1130         if(Map_Count == 0)
1131                 error("empty maplist, cannot select a new map");
1132         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1133
1134         if(Map_Current_Name)
1135                 strunzone(Map_Current_Name);
1136         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1137         // this may or may not be correct, but who cares, in the worst case a map
1138         // isn't chosen in the first pass that should have been
1139 }
1140
1141 string GetNextMap()
1142 {
1143         float nextMap;
1144
1145         Maplist_Init();
1146         nextMap = -1;
1147
1148         if(nextMap == -1)
1149                 if(cvar("g_maplist_shuffle") > 0)
1150                         nextMap = MaplistMethod_Shuffle(cvar("g_maplist_shuffle") + 1);
1151
1152         if(nextMap == -1)
1153                 if(cvar("g_maplist_selectrandom"))
1154                         nextMap = MaplistMethod_Random();
1155
1156         if(nextMap == -1)
1157                 nextMap = MaplistMethod_Iterate();
1158
1159         if(nextMap == -1)
1160                 nextMap = MaplistMethod_Repeat();
1161
1162         if(nextMap >= 0)
1163         {
1164                 Map_Goto_SetFloat(nextMap);
1165                 return getmapname_stored;
1166         }
1167
1168         return "";
1169 };
1170
1171 float DoNextMapOverride()
1172 {
1173         if(cvar("g_campaign"))
1174         {
1175                 CampaignPostIntermission();
1176                 alreadychangedlevel = TRUE;
1177                 return TRUE;
1178         }
1179         if(cvar("quit_when_empty"))
1180         {
1181                 if(player_count <= currentbots)
1182                 {
1183                         localcmd("quit\n");
1184                         alreadychangedlevel = TRUE;
1185                         return TRUE;
1186                 }
1187         }
1188         if(cvar_string("quit_and_redirect") != "")
1189         {
1190                 redirection_target = strzone(cvar_string("quit_and_redirect"));
1191                 alreadychangedlevel = TRUE;
1192                 return TRUE;
1193         }
1194         if (cvar("samelevel")) // if samelevel is set, stay on same level
1195         {
1196                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
1197                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
1198                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
1199                 localcmd("restart\n");
1200                 //changelevel (mapname);
1201                 alreadychangedlevel = TRUE;
1202                 return TRUE;
1203         }
1204         if(cvar_string("nextmap") != "")
1205                 if(MapInfo_CheckMap(cvar_string("nextmap")))
1206                 {
1207                         Map_Goto_SetStr(cvar_string("nextmap"));
1208                         Map_Goto();
1209                         alreadychangedlevel = TRUE;
1210                         return TRUE;
1211                 }
1212         if(cvar("lastlevel"))
1213         {
1214                 GameResetCfg();
1215                 localcmd("set lastlevel 0\ntogglemenu\n");
1216                 alreadychangedlevel = TRUE;
1217                 return TRUE;
1218         }
1219         return FALSE;
1220 };
1221
1222 void GotoNextMap()
1223 {
1224         //local string nextmap;
1225         //local float n, nummaps;
1226         //local string s;
1227         if (alreadychangedlevel)
1228                 return;
1229         alreadychangedlevel = TRUE;
1230
1231         {
1232                 string nextMap;
1233                 float allowReset;
1234
1235                 for(allowReset = 1; allowReset >= 0; --allowReset)
1236                 {
1237                         nextMap = GetNextMap();
1238                         if(nextMap != "")
1239                                 break;
1240
1241                         if(allowReset)
1242                         {
1243                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1244                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1245                                 if(cvar("g_maplist_shuffle"))
1246                                         ShuffleMaplist();
1247                                 localcmd("\nmenu_cmd sync\n");
1248                         }
1249                         else
1250                         {
1251                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1252                         }
1253                 }
1254                 Map_Goto();
1255         }
1256 };
1257
1258
1259 /*
1260 ============
1261 IntermissionThink
1262
1263 When the player presses attack or jump, change to the next level
1264 ============
1265 */
1266 .float autoscreenshot;
1267 void() MapVote_Start;
1268 void() MapVote_Think;
1269 float mapvote_initialized;
1270 void IntermissionThink()
1271 {
1272         FixIntermissionClient(self);
1273
1274         if(cvar("sv_autoscreenshot"))
1275         if(self.autoscreenshot > 0)
1276         if(time > self.autoscreenshot)
1277         {
1278                 self.autoscreenshot = -1;
1279                 if(clienttype(self) == CLIENTTYPE_REAL)
1280                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1281                 return;
1282         }
1283
1284         if (time < intermission_exittime)
1285                 return;
1286
1287         if(!mapvote_initialized)
1288                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
1289                         return;
1290
1291         MapVote_Start();
1292 };
1293
1294 /*
1295 ============
1296 FindIntermission
1297
1298 Returns the entity to view from
1299 ============
1300 */
1301 /*
1302 entity FindIntermission()
1303 {
1304         local   entity spot;
1305         local   float cyc;
1306
1307 // look for info_intermission first
1308         spot = find (world, classname, "info_intermission");
1309         if (spot)
1310         {       // pick a random one
1311                 cyc = random() * 4;
1312                 while (cyc > 1)
1313                 {
1314                         spot = find (spot, classname, "info_intermission");
1315                         if (!spot)
1316                                 spot = find (spot, classname, "info_intermission");
1317                         cyc = cyc - 1;
1318                 }
1319                 return spot;
1320         }
1321
1322 // then look for the start position
1323         spot = find (world, classname, "info_player_start");
1324         if (spot)
1325                 return spot;
1326
1327 // testinfo_player_start is only found in regioned levels
1328         spot = find (world, classname, "testplayerstart");
1329         if (spot)
1330                 return spot;
1331
1332 // then look for the start position
1333         spot = find (world, classname, "info_player_deathmatch");
1334         if (spot)
1335                 return spot;
1336
1337         //objerror ("FindIntermission: no spot");
1338         return world;
1339 };
1340 */
1341
1342 /*
1343 ===============================================================================
1344
1345 RULES
1346
1347 ===============================================================================
1348 */
1349
1350 void DumpStats(float final)
1351 {
1352         local float file;
1353         local string s;
1354         local float to_console;
1355         local float to_eventlog;
1356         local float to_file;
1357         local float i;
1358
1359         to_console = cvar("sv_logscores_console");
1360         to_eventlog = cvar("sv_eventlog");
1361         to_file = cvar("sv_logscores_file");
1362
1363         if(!final)
1364         {
1365                 to_console = TRUE; // always print printstats replies
1366                 to_eventlog = FALSE; // but never print them to the event log
1367         }
1368
1369         if(to_eventlog)
1370                 if(cvar("sv_eventlog_console"))
1371                         to_console = FALSE; // otherwise we get the output twice
1372
1373         if(final)
1374                 s = ":scores:";
1375         else
1376                 s = ":status:";
1377         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1378
1379         if(to_console)
1380                 print(s, "\n");
1381         if(to_eventlog)
1382                 GameLogEcho(s);
1383         if(to_file)
1384         {
1385                 file = fopen(cvar_string("sv_logscores_filename"), FILE_APPEND);
1386                 if(file == -1)
1387                         to_file = FALSE;
1388                 else
1389                         fputs(file, strcat(s, "\n"));
1390         }
1391
1392         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1393         if(to_console)
1394                 print(s, "\n");
1395         if(to_eventlog)
1396                 GameLogEcho(s);
1397         if(to_file)
1398                 fputs(file, strcat(s, "\n"));
1399
1400         FOR_EACH_CLIENT(other)
1401         {
1402                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && cvar("sv_logscores_bots")))
1403                 {
1404                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1405                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1406                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1407                                 s = strcat(s, ftos(other.team), ":");
1408                         else
1409                                 s = strcat(s, "spectator:");
1410
1411                         if(to_console)
1412                                 print(s, other.netname, "\n");
1413                         if(to_eventlog)
1414                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1415                         if(to_file)
1416                                 fputs(file, strcat(s, other.netname, "\n"));
1417                 }
1418         }
1419
1420         if(teams_matter)
1421         {
1422                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1423                 if(to_console)
1424                         print(s, "\n");
1425                 if(to_eventlog)
1426                         GameLogEcho(s);
1427                 if(to_file)
1428                         fputs(file, strcat(s, "\n"));
1429
1430                 for(i = 1; i < 16; ++i)
1431                 {
1432                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1433                         s = strcat(s, ":", ftos(i));
1434                         if(to_console)
1435                                 print(s, "\n");
1436                         if(to_eventlog)
1437                                 GameLogEcho(s);
1438                         if(to_file)
1439                                 fputs(file, strcat(s, "\n"));
1440                 }
1441         }
1442
1443         if(to_console)
1444                 print(":end\n");
1445         if(to_eventlog)
1446                 GameLogEcho(":end");
1447         if(to_file)
1448         {
1449                 fputs(file, ":end\n");
1450                 fclose(file);
1451         }
1452 }
1453
1454 void FixIntermissionClient(entity e)
1455 {
1456         string s;
1457         if(!e.autoscreenshot) // initial call
1458         {
1459                 e.angles = e.v_angle;
1460                 e.angles_x = -e.angles_x;
1461                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1462                 e.health = -2342;
1463                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1464                 e.solid = SOLID_NOT;
1465                 e.movetype = MOVETYPE_NONE;
1466                 e.takedamage = DAMAGE_NO;
1467                 if(e.weaponentity)
1468                 {
1469                         e.weaponentity.effects = EF_NODRAW;
1470                         if (e.weaponentity.weaponentity)
1471                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1472                 }
1473                 if(clienttype(e) == CLIENTTYPE_REAL)
1474                 {
1475                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1476                         s = cvar_string("sv_intermission_cdtrack");
1477                         if(s != "")
1478                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1479                         msg_entity = e;
1480                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1481                 }
1482         }
1483
1484         //e.velocity = '0 0 0';
1485         //e.fixangle = TRUE;
1486
1487         // TODO halt weapon animation
1488 }
1489
1490
1491 /*
1492 go to the next level for deathmatch
1493 only called if a time or frag limit has expired
1494 */
1495 void NextLevel()
1496 {
1497         float i;
1498
1499         gameover = TRUE;
1500
1501         intermission_running = 1;
1502
1503 // enforce a wait time before allowing changelevel
1504         if(player_count > 0)
1505                 intermission_exittime = time + cvar("sv_mapchange_delay");
1506         else
1507                 intermission_exittime = -1;
1508
1509         /*
1510         WriteByte (MSG_ALL, SVC_CDTRACK);
1511         WriteByte (MSG_ALL, 3);
1512         WriteByte (MSG_ALL, 3);
1513         // done in FixIntermission
1514         */
1515
1516         //pos = FindIntermission ();
1517
1518         VoteReset();
1519
1520         DumpStats(TRUE);
1521
1522         if(cvar("sv_eventlog"))
1523                 GameLogEcho(":gameover");
1524
1525         GameLogClose();
1526
1527 // TO DO
1528
1529 // save the stats to a text file on the client
1530 // stuffcmd(other, log_stats "stats/file_name");
1531 // bprint stats
1532 // stuffcmd(other, log_stats "");
1533 // use a filename similar to the demo name
1534         // string file_name;
1535         // file_name = strcat("\nlog_file \"stats/", strftime(TRUE, "%Y-%m-%d_%H-%M"), "_", mapname, ".txt\"");  // open the log file
1536
1537 // write a stats parser for the menu
1538
1539         if(cvar("sv_accuracy_data_send")) {
1540                 string stats_to_send;
1541
1542                 FOR_EACH_CLIENT(other) {  // make the string to send
1543                         FixIntermissionClient(other);
1544
1545                         if(other.cvar_cl_accuracy_data_share) {
1546                                 stats_to_send = strcat(stats_to_send, ":hits:", other.netname);
1547
1548                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
1549                                         stats_to_send = strcat(stats_to_send, ":", ftos(other.stats_hit[i-1]));
1550
1551                                 stats_to_send = strcat(stats_to_send, "\n:fired:", other.netname);
1552
1553                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
1554                                         stats_to_send = strcat(stats_to_send, ":", ftos(other.stats_fired[i-1]));
1555
1556                                 stats_to_send = strcat(stats_to_send, "\n");
1557                         }
1558                 }
1559
1560                 FOR_EACH_REALCLIENT(other) {  // only spam humans
1561                         Score_NicePrint(other);  // print the score
1562
1563                         if(other.cvar_cl_accuracy_data_receive)  // send the stats string to all the willing clients
1564                                 bprint(stats_to_send);
1565                 }
1566         } else { // ye olde message
1567                 FOR_EACH_PLAYER(other) {
1568                         FixIntermissionClient(other);
1569
1570                         if(other.winning)
1571                                 bprint(other.netname, " ^7wins.\n");
1572                 }
1573         }
1574
1575         if(cvar("g_campaign"))
1576                 CampaignPreIntermission();
1577
1578         localcmd("\nsv_hook_gameend\n");
1579 }
1580
1581 /*
1582 ============
1583 CheckRules_Player
1584
1585 Exit deathmatch games upon conditions
1586 ============
1587 */
1588 void CheckRules_Player()
1589 {
1590         if (gameover)   // someone else quit the game already
1591                 return;
1592
1593         if(self.deadflag == DEAD_NO)
1594                 self.play_time += frametime;
1595
1596         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1597         //   (div0: and that in CheckRules_World please)
1598 };
1599
1600 float checkrules_equality;
1601 float checkrules_suddendeathwarning;
1602 float checkrules_suddendeathend;
1603 float checkrules_overtimesadded; //how many overtimes have been already added
1604
1605 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1606 float WINNING_YES = 1; // winner found
1607 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1608 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1609
1610 float InitiateSuddenDeath()
1611 {
1612         // Check first whether normal overtimes could be added before initiating suddendeath mode
1613         // - for this timelimit_overtime needs to be >0 of course
1614         // - also check the winning condition calculated in the previous frame and only add normal overtime
1615         //   again, if at the point at which timelimit would be extended again, still no winner was found
1616         if ((checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < cvar("timelimit_overtimes")) && cvar("timelimit_overtime") && !(g_race && !g_race_qualifying))
1617         {
1618                 return 1; // need to call InitiateOvertime later
1619         }
1620         else
1621         {
1622                 if(!checkrules_suddendeathend)
1623                 {
1624                         checkrules_suddendeathend = time + 60 * cvar("timelimit_suddendeath");
1625                         if(g_race && !g_race_qualifying)
1626                                 race_StartCompleting();
1627                 }
1628                 return 0;
1629         }
1630 }
1631
1632 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1633 {
1634         ++checkrules_overtimesadded;
1635         //add one more overtime by simply extending the timelimit
1636         float tl;
1637         tl = cvar("timelimit");
1638         tl += cvar("timelimit_overtime");
1639         cvar_set("timelimit", ftos(tl));
1640         string minutesPlural;
1641         if (cvar("timelimit_overtime") == 1)
1642                 minutesPlural = " ^3minute";
1643         else
1644                 minutesPlural = " ^3minutes";
1645
1646         bcenterprint(
1647                 strcat(
1648                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1649                         ftos(cvar("timelimit_overtime")),
1650                         minutesPlural,
1651                         " to the game!"
1652                 )
1653         );
1654 }
1655
1656 float GetWinningCode(float fraglimitreached, float equality)
1657 {
1658         if(cvar("g_campaign") == 1)
1659                 if(fraglimitreached)
1660                         return WINNING_YES;
1661                 else
1662                         return WINNING_NO;
1663
1664         else
1665                 if(equality)
1666                         if(fraglimitreached)
1667                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1668                         else
1669                                 return WINNING_NEVER;
1670                 else
1671                         if(fraglimitreached)
1672                                 return WINNING_YES;
1673                         else
1674                                 return WINNING_NO;
1675 }
1676
1677 // set the .winning flag for exactly those players with a given field value
1678 void SetWinners(.float field, float value)
1679 {
1680         entity head;
1681         FOR_EACH_PLAYER(head)
1682                 head.winning = (head.field == value);
1683 }
1684
1685 // set the .winning flag for those players with a given field value
1686 void AddWinners(.float field, float value)
1687 {
1688         entity head;
1689         FOR_EACH_PLAYER(head)
1690                 if(head.field == value)
1691                         head.winning = 1;
1692 }
1693
1694 // clear the .winning flags
1695 void ClearWinners(void)
1696 {
1697         entity head;
1698         FOR_EACH_PLAYER(head)
1699                 head.winning = 0;
1700 }
1701
1702 // Onslaught winning condition:
1703 // game terminates if only one team has a working generator (or none)
1704 float WinningCondition_Onslaught()
1705 {
1706         entity head;
1707         local float t1, t2, t3, t4;
1708
1709         WinningConditionHelper(); // set worldstatus
1710
1711         if(inWarmupStage)
1712                 return WINNING_NO;
1713
1714         // first check if the game has ended
1715         t1 = t2 = t3 = t4 = 0;
1716         head = find(world, classname, "onslaught_generator");
1717         while (head)
1718         {
1719                 if (head.health > 0)
1720                 {
1721                         if (head.team == COLOR_TEAM1) t1 = 1;
1722                         if (head.team == COLOR_TEAM2) t2 = 1;
1723                         if (head.team == COLOR_TEAM3) t3 = 1;
1724                         if (head.team == COLOR_TEAM4) t4 = 1;
1725                 }
1726                 head = find(head, classname, "onslaught_generator");
1727         }
1728         if (t1 + t2 + t3 + t4 < 2)
1729         {
1730                 // game over, only one team remains (or none)
1731                 ClearWinners();
1732                 if (t1) SetWinners(team, COLOR_TEAM1);
1733                 if (t2) SetWinners(team, COLOR_TEAM2);
1734                 if (t3) SetWinners(team, COLOR_TEAM3);
1735                 if (t4) SetWinners(team, COLOR_TEAM4);
1736                 dprint("Have a winner, ending game.\n");
1737                 return WINNING_YES;
1738         }
1739
1740         // Two or more teams remain
1741         return WINNING_NO;
1742 }
1743
1744 float LMS_NewPlayerLives()
1745 {
1746         float fl;
1747         fl = cvar("fraglimit");
1748         if(fl == 0)
1749                 fl = 999;
1750
1751         // first player has left the game for dying too much? Nobody else can get in.
1752         if(lms_lowest_lives < 1)
1753                 return 0;
1754
1755         if(!cvar("g_lms_join_anytime"))
1756                 if(lms_lowest_lives < fl - cvar("g_lms_last_join"))
1757                         return 0;
1758
1759         return bound(1, lms_lowest_lives, fl);
1760 }
1761
1762 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1763 // they win. Otherwise the defending team wins once the timelimit passes.
1764 void assault_new_round();
1765 float WinningCondition_Assault()
1766 {
1767         local float status;
1768
1769         WinningConditionHelper(); // set worldstatus
1770
1771         status = WINNING_NO;
1772         // as the timelimit has not yet passed just assume the defending team will win
1773         if(assault_attacker_team == COLOR_TEAM1)
1774         {
1775                 SetWinners(team, COLOR_TEAM2);
1776         }
1777         else
1778         {
1779                 SetWinners(team, COLOR_TEAM1);
1780         }
1781
1782         local entity ent;
1783         ent = find(world, classname, "target_assault_roundend");
1784         if(ent)
1785         {
1786                 if(ent.winning) // round end has been triggered by attacking team
1787                 {
1788                         bprint("ASSAULT: round completed...\n");
1789                         SetWinners(team, assault_attacker_team);
1790
1791                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1792
1793                         if(ent.cnt == 1 || cvar("g_campaign")) // this was the second round
1794                         {
1795                                 status = WINNING_YES;
1796                         }
1797                         else
1798                         {
1799                                 local entity oldself;
1800                                 oldself = self;
1801                                 self = ent;
1802                                 assault_new_round();
1803                                 self = oldself;
1804                         }
1805                 }
1806         }
1807
1808         return status;
1809 }
1810
1811 // LMS winning condition: game terminates if and only if there's at most one
1812 // one player who's living lives. Top two scores being equal cancels the time
1813 // limit.
1814 float WinningCondition_LMS()
1815 {
1816         entity head, head2;
1817         float have_player;
1818         float have_players;
1819         float l;
1820
1821         have_player = FALSE;
1822         have_players = FALSE;
1823         l = LMS_NewPlayerLives();
1824
1825         head = find(world, classname, "player");
1826         if(head)
1827                 have_player = TRUE;
1828         head2 = find(head, classname, "player");
1829         if(head2)
1830                 have_players = TRUE;
1831
1832         if(have_player)
1833         {
1834                 // we have at least one player
1835                 if(have_players)
1836                 {
1837                         // two or more active players - continue with the game
1838                 }
1839                 else
1840                 {
1841                         // exactly one player?
1842
1843                         ClearWinners();
1844                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1845
1846                         if(l)
1847                         {
1848                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1849                                 return WINNING_NO;
1850                         }
1851                         else
1852                         {
1853                                 // a winner!
1854                                 // and assign him his first place
1855                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1856                                 return WINNING_YES;
1857                         }
1858                 }
1859         }
1860         else
1861         {
1862                 // nobody is playing at all...
1863                 if(l)
1864                 {
1865                         // wait for players...
1866                 }
1867                 else
1868                 {
1869                         // SNAFU (maybe a draw game?)
1870                         ClearWinners();
1871                         dprint("No players, ending game.\n");
1872                         return WINNING_YES;
1873                 }
1874         }
1875
1876         // When we get here, we have at least two players who are actually LIVING,
1877         // now check if the top two players have equal score.
1878         WinningConditionHelper();
1879
1880         ClearWinners();
1881         if(WinningConditionHelper_winner)
1882                 WinningConditionHelper_winner.winning = TRUE;
1883         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1884                 return WINNING_NEVER;
1885
1886         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1887         return WINNING_NO;
1888 }
1889
1890 void ShuffleMaplist()
1891 {
1892         cvar_set("g_maplist", shufflewords(cvar_string("g_maplist")));
1893 }
1894
1895 float leaderfrags;
1896 float WinningCondition_Scores(float limit, float leadlimit)
1897 {
1898         float limitreached;
1899
1900         // TODO make everything use THIS winning condition (except LMS)
1901         WinningConditionHelper();
1902
1903         if(teams_matter)
1904         {
1905                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1906                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1907                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1908                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1909         }
1910
1911         ClearWinners();
1912         if(WinningConditionHelper_winner)
1913                 WinningConditionHelper_winner.winning = 1;
1914         if(WinningConditionHelper_winnerteam >= 0)
1915                 SetWinners(team, WinningConditionHelper_winnerteam);
1916
1917         if(WinningConditionHelper_lowerisbetter)
1918         {
1919                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1920                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1921                 limit = -limit;
1922         }
1923
1924         if(WinningConditionHelper_zeroisworst)
1925                 leadlimit = 0; // not supported in this mode
1926
1927         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1928         // these modes always score in increments of 1, thus this makes sense
1929         {
1930                 if(leaderfrags != WinningConditionHelper_topscore)
1931                 {
1932                         leaderfrags = WinningConditionHelper_topscore;
1933
1934                         if (limit)
1935                         if (leaderfrags == limit - 1)
1936                                 Announce("1fragleft");
1937                         else if (leaderfrags == limit - 2)
1938                                 Announce("2fragsleft");
1939                         else if (leaderfrags == limit - 3)
1940                                 Announce("3fragsleft");
1941                 }
1942         }
1943
1944         limitreached = FALSE;
1945         if(limit)
1946                 if(WinningConditionHelper_topscore >= limit)
1947                         limitreached = TRUE;
1948         if(leadlimit)
1949         {
1950                 float leadlimitreached;
1951                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1952                 if(cvar("leadlimit_and_fraglimit"))
1953                         limitreached = (limitreached && leadlimitreached);
1954                 else
1955                         limitreached = (limitreached || leadlimitreached);
1956         }
1957
1958         return GetWinningCode(
1959                 WinningConditionHelper_topscore && limitreached,
1960                 WinningConditionHelper_equality
1961         );
1962 }
1963
1964 float WinningCondition_Race(float fraglimit)
1965 {
1966         float wc;
1967         entity p;
1968         float n, c;
1969
1970         n = 0;
1971         c = 0;
1972         FOR_EACH_PLAYER(p)
1973         {
1974                 ++n;
1975                 if(p.race_completed)
1976                         ++c;
1977         }
1978         if(n && (n == c))
1979                 return WINNING_YES;
1980         wc = WinningCondition_Scores(fraglimit, 0);
1981
1982         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1983         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1984         // do NOT support equality when the laps are all raced!
1985                 return WINNING_STARTSUDDENDEATHOVERTIME;
1986         else
1987                 return WINNING_NEVER;
1988         return wc;
1989 }
1990
1991 void ReadyRestart();
1992 float WinningCondition_QualifyingThenRace(float limit)
1993 {
1994         float wc;
1995         wc = WinningCondition_Scores(limit, 0);
1996
1997         // NEVER initiate overtime
1998         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1999         {
2000                 return WINNING_YES;
2001         }
2002
2003         return wc;
2004 }
2005
2006 float WinningCondition_RanOutOfSpawns()
2007 {
2008         entity head;
2009
2010         if(have_team_spawns <= 0)
2011                 return WINNING_NO;
2012
2013         if(!some_spawn_has_been_used)
2014                 return WINNING_NO;
2015
2016         team1_score = team2_score = team3_score = team4_score = 0;
2017
2018         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2019         {
2020                 if(head.team == COLOR_TEAM1)
2021                         team1_score = 1;
2022                 else if(head.team == COLOR_TEAM2)
2023                         team2_score = 1;
2024                 else if(head.team == COLOR_TEAM3)
2025                         team3_score = 1;
2026                 else if(head.team == COLOR_TEAM4)
2027                         team4_score = 1;
2028         }
2029
2030         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2031         {
2032                 if(head.team == COLOR_TEAM1)
2033                         team1_score = 1;
2034                 else if(head.team == COLOR_TEAM2)
2035                         team2_score = 1;
2036                 else if(head.team == COLOR_TEAM3)
2037                         team3_score = 1;
2038                 else if(head.team == COLOR_TEAM4)
2039                         team4_score = 1;
2040         }
2041
2042         ClearWinners();
2043         if(team1_score + team2_score + team3_score + team4_score == 0)
2044         {
2045                 checkrules_equality = TRUE;
2046                 return WINNING_YES;
2047         }
2048         else if(team1_score + team2_score + team3_score + team4_score == 1)
2049         {
2050                 float t, i;
2051                 if(team1_score) t = COLOR_TEAM1;
2052                 if(team2_score) t = COLOR_TEAM2;
2053                 if(team3_score) t = COLOR_TEAM3;
2054                 if(team4_score) t = COLOR_TEAM4;
2055                 CheckAllowedTeams(world);
2056                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2057                 {
2058                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2059                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2060                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2061                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2062                 }
2063
2064                 AddWinners(team, t);
2065                 return WINNING_YES;
2066         }
2067         else
2068                 return WINNING_NO;
2069 }
2070
2071 /*
2072 ============
2073 CheckRules_World
2074
2075 Exit deathmatch games upon conditions
2076 ============
2077 */
2078 void CheckRules_World()
2079 {
2080         float timelimit;
2081         float fraglimit;
2082         float leadlimit;
2083
2084         VoteThink();
2085         MapVote_Think();
2086
2087         SetDefaultAlpha();
2088
2089         /*
2090         MapVote_Think should now do that part
2091         if (intermission_running)
2092                 if (time >= intermission_exittime + 60)
2093                 {
2094                         if(!DoNextMapOverride())
2095                                 GotoNextMap();
2096                         return;
2097                 }
2098         */
2099
2100         if (gameover)   // someone else quit the game already
2101         {
2102                 if(player_count == 0) // Nobody there? Then let's go to the next map
2103                         MapVote_Start();
2104                         // this will actually check the player count in the next frame
2105                         // again, but this shouldn't hurt
2106                 return;
2107         }
2108
2109         timelimit = cvar("timelimit") * 60;
2110         fraglimit = cvar("fraglimit");
2111         leadlimit = cvar("leadlimit");
2112
2113         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2114         {
2115                 if(timelimit > 0)
2116                         timelimit = 0; // timelimit is not made for warmup
2117                 if(fraglimit > 0)
2118                         fraglimit = 0; // no fraglimit for now
2119                 leadlimit = 0; // no leadlimit for now
2120         }
2121
2122         if(g_onslaught)
2123                 timelimit = 0; // ONS has its own overtime rule
2124
2125         if(timelimit > 0)
2126         {
2127                 timelimit += game_starttime;
2128         }
2129         else if (timelimit < 0)
2130         {
2131                 // endmatch
2132                 NextLevel();
2133                 return;
2134         }
2135
2136         float wantovertime;
2137         wantovertime = 0;
2138
2139         if(checkrules_suddendeathend)
2140         {
2141                 if(!checkrules_suddendeathwarning)
2142                 {
2143                         checkrules_suddendeathwarning = TRUE;
2144                         if(g_race && !g_race_qualifying)
2145                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2146                         else
2147                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2148                 }
2149         }
2150         else
2151         {
2152                 if (timelimit && time >= timelimit)
2153                 {
2154                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2155                         {
2156                                 float totalplayers;
2157                                 float playerswithlaps;
2158                                 float readyplayers;
2159                                 entity head;
2160                                 totalplayers = playerswithlaps = readyplayers = 0;
2161                                 FOR_EACH_PLAYER(head)
2162                                 {
2163                                         ++totalplayers;
2164                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2165                                                 ++playerswithlaps;
2166                                         if(head.ready)
2167                                                 ++readyplayers;
2168                                 }
2169
2170                                 // at least 2 of the players have completed a lap: start the RACE
2171                                 // otherwise, the players should end the qualifying on their own
2172                                 if(readyplayers || playerswithlaps >= 2)
2173                                 {
2174                                         checkrules_suddendeathend = 0;
2175                                         ReadyRestart(); // go to race
2176                                         return;
2177                                 }
2178                                 else
2179                                         wantovertime |= InitiateSuddenDeath();
2180                         }
2181                         else
2182                                 wantovertime |= InitiateSuddenDeath();
2183                 }
2184         }
2185
2186         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2187         {
2188                 NextLevel();
2189                 return;
2190         }
2191
2192         float checkrules_status;
2193         checkrules_status = WinningCondition_RanOutOfSpawns();
2194         if(checkrules_status == WINNING_YES)
2195         {
2196                 bprint("Hey! Someone ran out of spawns!\n");
2197         }
2198         else if(g_race && !g_race_qualifying && timelimit >= 0)
2199         {
2200                 checkrules_status = WinningCondition_Race(fraglimit);
2201                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2202         }
2203         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2204         {
2205                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2206                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2207         }
2208         else if(g_assault)
2209         {
2210                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2211         }
2212         else if(g_lms)
2213         {
2214                 checkrules_status = WinningCondition_LMS();
2215         }
2216         else if (g_onslaught)
2217         {
2218                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2219         }
2220         else
2221         {
2222                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2223                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2224         }
2225
2226         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2227         {
2228                 checkrules_status = WINNING_NEVER;
2229                 checkrules_overtimesadded = -1;
2230                 wantovertime |= InitiateSuddenDeath();
2231         }
2232
2233         if(checkrules_status == WINNING_NEVER)
2234                 // equality cases! Nobody wins if the overtime ends in a draw.
2235                 ClearWinners();
2236
2237         if(wantovertime)
2238         {
2239                 if(checkrules_status == WINNING_NEVER)
2240                         InitiateOvertime();
2241                 else
2242                         checkrules_status = WINNING_YES;
2243         }
2244
2245         if(checkrules_suddendeathend)
2246                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2247                         checkrules_status = WINNING_YES;
2248
2249         if(checkrules_status == WINNING_YES)
2250         {
2251                 //print("WINNING\n");
2252                 NextLevel();
2253         }
2254 };
2255
2256 float mapvote_nextthink;
2257 float mapvote_initialized;
2258 float mapvote_keeptwotime;
2259 float mapvote_timeout;
2260 string mapvote_message;
2261 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2262 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2263 float mapvote_screenshot_dirs_count;
2264
2265 float mapvote_count;
2266 float mapvote_count_real;
2267 string mapvote_maps[MAPVOTE_COUNT];
2268 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2269 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2270 float mapvote_maps_suggested[MAPVOTE_COUNT];
2271 string mapvote_suggestions[MAPVOTE_COUNT];
2272 float mapvote_suggestion_ptr;
2273 float mapvote_maxlen;
2274 float mapvote_voters;
2275 float mapvote_votes[MAPVOTE_COUNT];
2276 float mapvote_run;
2277 float mapvote_detail;
2278 float mapvote_abstain;
2279 .float mapvote;
2280
2281 void MapVote_ClearAllVotes()
2282 {
2283         FOR_EACH_CLIENT(other)
2284                 other.mapvote = 0;
2285 }
2286
2287 string MapVote_Suggest(string m)
2288 {
2289         float i;
2290         if(m == "")
2291                 return "That's not how to use this command.";
2292         if(!cvar("g_maplist_votable_suggestions"))
2293                 return "Suggestions are not accepted on this server.";
2294         if(mapvote_initialized)
2295                 return "Can't suggest - voting is already in progress!";
2296         m = MapInfo_FixName(m);
2297         if(!m)
2298                 return "The map you suggested is not available on this server.";
2299         if(!cvar("g_maplist_votable_suggestions_override_mostrecent"))
2300                 if(Map_IsRecent(m))
2301                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2302
2303         if(!MapInfo_CheckMap(m))
2304                 return "The map you suggested does not support the current game mode.";
2305         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2306                 if(mapvote_suggestions[i] == m)
2307                         return "This map was already suggested.";
2308         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2309         {
2310                 i = floor(random() * mapvote_suggestion_ptr);
2311         }
2312         else
2313         {
2314                 i = mapvote_suggestion_ptr;
2315                 mapvote_suggestion_ptr += 1;
2316         }
2317         if(mapvote_suggestions[i] != "")
2318                 strunzone(mapvote_suggestions[i]);
2319         mapvote_suggestions[i] = strzone(m);
2320         if(cvar("sv_eventlog"))
2321                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2322         return strcat("Suggestion of ", m, " accepted.");
2323 }
2324
2325 void MapVote_AddVotable(string nextMap, float isSuggestion)
2326 {
2327         float j, i, o;
2328         string pakfile, mapfile;
2329
2330         if(nextMap == "")
2331                 return;
2332         for(j = 0; j < mapvote_count; ++j)
2333                 if(mapvote_maps[j] == nextMap)
2334                         return;
2335         if(strlen(nextMap) > mapvote_maxlen)
2336                 mapvote_maxlen = strlen(nextMap);
2337         mapvote_maps[mapvote_count] = strzone(nextMap);
2338         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2339
2340         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2341         {
2342                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2343                 pakfile = whichpack(strcat(mapfile, ".tga"));
2344                 if(pakfile == "")
2345                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2346                 if(pakfile == "")
2347                         pakfile = whichpack(strcat(mapfile, ".png"));
2348                 if(pakfile != "")
2349                         break;
2350         }
2351         if(i >= mapvote_screenshot_dirs_count)
2352                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2353         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2354                 pakfile = substring(pakfile, o, -1);
2355
2356         mapvote_maps_screenshot_dir[mapvote_count] = i;
2357         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2358
2359         mapvote_count += 1;
2360 }
2361
2362 void MapVote_Spawn();
2363 void MapVote_Init()
2364 {
2365         float i;
2366         float nmax, smax;
2367
2368         MapVote_ClearAllVotes();
2369
2370         mapvote_count = 0;
2371         mapvote_detail = !cvar("g_maplist_votable_nodetail");
2372         mapvote_abstain = cvar("g_maplist_votable_abstain");
2373
2374         if(mapvote_abstain)
2375                 nmax = min(MAPVOTE_COUNT - 1, cvar("g_maplist_votable"));
2376         else
2377                 nmax = min(MAPVOTE_COUNT, cvar("g_maplist_votable"));
2378         smax = min3(nmax, cvar("g_maplist_votable_suggestions"), mapvote_suggestion_ptr);
2379
2380         // we need this for AddVotable, as that cycles through the screenshot dirs
2381         mapvote_screenshot_dirs_count = tokenize_console(cvar_string("g_maplist_votable_screenshot_dir"));
2382         if(mapvote_screenshot_dirs_count == 0)
2383                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2384         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2385         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2386                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2387
2388         if(mapvote_suggestion_ptr)
2389                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2390                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2391
2392         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2393                 MapVote_AddVotable(GetNextMap(), FALSE);
2394
2395         if(mapvote_count == 0)
2396         {
2397                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2398                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2399                 if(cvar("g_maplist_shuffle"))
2400                         ShuffleMaplist();
2401                 localcmd("\nmenu_cmd sync\n");
2402                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2403                         MapVote_AddVotable(GetNextMap(), FALSE);
2404         }
2405
2406         mapvote_count_real = mapvote_count;
2407         if(mapvote_abstain)
2408                 MapVote_AddVotable("don't care", 0);
2409
2410         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2411
2412         mapvote_keeptwotime = time + cvar("g_maplist_votable_keeptwotime");
2413         mapvote_timeout = time + cvar("g_maplist_votable_timeout");
2414         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2415                 mapvote_keeptwotime = 0;
2416         mapvote_message = "Choose a map and press its key!";
2417
2418         MapVote_Spawn();
2419 }
2420
2421 void MapVote_SendPicture(float id)
2422 {
2423         msg_entity = self;
2424         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2425         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2426         WriteByte(MSG_ONE, id);
2427         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2428 }
2429
2430 float GameCommand_MapVote(string cmd)
2431 {
2432         if(!intermission_running)
2433                 return FALSE;
2434
2435         if(cmd == "mv_getpic")
2436         {
2437                 MapVote_SendPicture(stof(argv(1)));
2438                 return TRUE;
2439         }
2440
2441         return FALSE;
2442 }
2443
2444 float MapVote_GetMapMask()
2445 {
2446         float mask, i, power;
2447         mask = 0;
2448         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2449                 if(mapvote_maps[i] != "")
2450                         mask |= power;
2451         return mask;
2452 }
2453
2454 entity mapvote_ent;
2455 float MapVote_SendEntity(entity to, float sf)
2456 {
2457         float i;
2458
2459         if(sf & 1)
2460                 sf &~= 2; // if we send 1, we don't need to also send 2
2461
2462         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2463         WriteByte(MSG_ENTITY, sf);
2464
2465         if(sf & 1)
2466         {
2467                 // flag 1 == initialization
2468                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2469                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2470                 WriteString(MSG_ENTITY, "");
2471                 WriteByte(MSG_ENTITY, mapvote_count);
2472                 WriteByte(MSG_ENTITY, mapvote_abstain);
2473                 WriteByte(MSG_ENTITY, mapvote_detail);
2474                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2475                 if(mapvote_count <= 8)
2476                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2477                 else
2478                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2479                 for(i = 0; i < mapvote_count; ++i)
2480                         if(mapvote_maps[i] != "")
2481                         {
2482                                 if(mapvote_abstain && i == mapvote_count - 1)
2483                                 {
2484                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2485                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2486                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2487                                 }
2488                                 else
2489                                 {
2490                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2491                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2492                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2493                                 }
2494                         }
2495         }
2496
2497         if(sf & 2)
2498         {
2499                 // flag 2 == update of mask
2500                 if(mapvote_count <= 8)
2501                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2502                 else
2503                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2504         }
2505
2506         if(sf & 4)
2507         {
2508                 if(mapvote_detail)
2509                         for(i = 0; i < mapvote_count; ++i)
2510                                 if(mapvote_maps[i] != "")
2511                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2512
2513                 WriteByte(MSG_ENTITY, to.mapvote);
2514         }
2515
2516         return TRUE;
2517 }
2518
2519 void MapVote_Spawn()
2520 {
2521         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2522 }
2523
2524 void MapVote_TouchMask()
2525 {
2526         mapvote_ent.SendFlags |= 2;
2527 }
2528
2529 void MapVote_TouchVotes(entity voter)
2530 {
2531         mapvote_ent.SendFlags |= 4;
2532 }
2533
2534 float MapVote_Finished(float mappos)
2535 {
2536         string result;
2537         float i;
2538         float didntvote;
2539
2540         if(cvar("sv_eventlog"))
2541         {
2542                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2543                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2544                 didntvote = mapvote_voters;
2545                 for(i = 0; i < mapvote_count; ++i)
2546                         if(mapvote_maps[i] != "")
2547                         {
2548                                 didntvote -= mapvote_votes[i];
2549                                 if(i != mappos)
2550                                 {
2551                                         result = strcat(result, ":", mapvote_maps[i]);
2552                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2553                                 }
2554                         }
2555                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2556
2557                 GameLogEcho(result);
2558                 if(mapvote_maps_suggested[mappos])
2559                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2560         }
2561
2562         FOR_EACH_REALCLIENT(other)
2563                 FixClientCvars(other);
2564
2565         Map_Goto_SetStr(mapvote_maps[mappos]);
2566         Map_Goto();
2567         alreadychangedlevel = TRUE;
2568         return TRUE;
2569 }
2570 void MapVote_CheckRules_1()
2571 {
2572         float i;
2573
2574         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2575         {
2576                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2577                 mapvote_votes[i] = 0;
2578         }
2579
2580         mapvote_voters = 0;
2581         FOR_EACH_REALCLIENT(other)
2582         {
2583                 ++mapvote_voters;
2584                 if(other.mapvote)
2585                 {
2586                         i = other.mapvote - 1;
2587                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2588                         mapvote_votes[i] = mapvote_votes[i] + 1;
2589                 }
2590         }
2591 }
2592
2593 float MapVote_CheckRules_2()
2594 {
2595         float i;
2596         float firstPlace, secondPlace;
2597         float firstPlaceVotes, secondPlaceVotes;
2598         float mapvote_voters_real;
2599         string result;
2600
2601         if(mapvote_count_real == 1)
2602                 return MapVote_Finished(0);
2603
2604         mapvote_voters_real = mapvote_voters;
2605         if(mapvote_abstain)
2606                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2607
2608         RandomSelection_Init();
2609         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2610                 RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2611         firstPlace = RandomSelection_chosen_float;
2612         firstPlaceVotes = RandomSelection_best_priority;
2613         //dprint("First place: ", ftos(firstPlace), "\n");
2614         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2615
2616         RandomSelection_Init();
2617         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2618                 if(i != firstPlace)
2619                         RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2620         secondPlace = RandomSelection_chosen_float;
2621         secondPlaceVotes = RandomSelection_best_priority;
2622         //dprint("Second place: ", ftos(secondPlace), "\n");
2623         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2624
2625         if(firstPlace == -1)
2626                 error("No first place in map vote... WTF?");
2627
2628         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2629                 return MapVote_Finished(firstPlace);
2630
2631         if(mapvote_keeptwotime)
2632                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2633                 {
2634                         float didntvote;
2635                         MapVote_TouchMask();
2636                         mapvote_message = "Now decide between the TOP TWO!";
2637                         mapvote_keeptwotime = 0;
2638                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2639                         result = strcat(result, ":", ftos(firstPlaceVotes));
2640                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2641                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2642                         didntvote = mapvote_voters;
2643                         for(i = 0; i < mapvote_count; ++i)
2644                                 if(mapvote_maps[i] != "")
2645                                 {
2646                                         didntvote -= mapvote_votes[i];
2647                                         if(i != firstPlace)
2648                                                 if(i != secondPlace)
2649                                                 {
2650                                                         result = strcat(result, ":", mapvote_maps[i]);
2651                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2652                                                         if(i < mapvote_count_real)
2653                                                         {
2654                                                                 strunzone(mapvote_maps[i]);
2655                                                                 mapvote_maps[i] = "";
2656                                                                 strunzone(mapvote_maps_pakfile[i]);
2657                                                                 mapvote_maps_pakfile[i] = "";
2658                                                         }
2659                                                 }
2660                                 }
2661                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2662                         if(cvar("sv_eventlog"))
2663                                 GameLogEcho(result);
2664                 }
2665
2666         return FALSE;
2667 }
2668 void MapVote_Tick()
2669 {
2670         float keeptwo;
2671         float totalvotes;
2672
2673         keeptwo = mapvote_keeptwotime;
2674         MapVote_CheckRules_1(); // count
2675         if(MapVote_CheckRules_2()) // decide
2676                 return;
2677
2678         totalvotes = 0;
2679         FOR_EACH_REALCLIENT(other)
2680         {
2681                 // hide scoreboard again
2682                 if(other.health != 2342)
2683                 {
2684                         other.health = 2342;
2685                         other.impulse = 0;
2686                         if(clienttype(other) == CLIENTTYPE_REAL)
2687                         {
2688                                 msg_entity = other;
2689                                 WriteByte(MSG_ONE, SVC_FINALE);
2690                                 WriteString(MSG_ONE, "");
2691                         }
2692                 }
2693
2694                 // clear possibly invalid votes
2695                 if(mapvote_maps[other.mapvote - 1] == "")
2696                         other.mapvote = 0;
2697                 // use impulses as new vote
2698                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2699                         if(mapvote_maps[other.impulse - 1] != "")
2700                         {
2701                                 other.mapvote = other.impulse;
2702                                 MapVote_TouchVotes(other);
2703                         }
2704                 other.impulse = 0;
2705
2706                 if(other.mapvote)
2707                         ++totalvotes;
2708         }
2709
2710         MapVote_CheckRules_1(); // just count
2711 }
2712 void MapVote_Start()
2713 {
2714         if(mapvote_run)
2715                 return;
2716
2717         MapInfo_Enumerate();
2718         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2719                 mapvote_run = TRUE;
2720 }
2721 void MapVote_Think()
2722 {
2723         if(!mapvote_run)
2724                 return;
2725
2726         if(alreadychangedlevel)
2727                 return;
2728
2729         if(time < mapvote_nextthink)
2730                 return;
2731         //dprint("tick\n");
2732
2733         mapvote_nextthink = time + 0.5;
2734
2735         if(!mapvote_initialized)
2736         {
2737                 if(cvar("rescan_pending") == 1)
2738                 {
2739                         cvar_set("rescan_pending", "2");
2740                         localcmd("fs_rescan\nrescan_pending 3\n");
2741                         return;
2742                 }
2743                 else if(cvar("rescan_pending") == 2)
2744                 {
2745                         return;
2746                 }
2747                 else if(cvar("rescan_pending") == 3)
2748                 {
2749                         // now build missing mapinfo files
2750                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2751                                 return;
2752
2753                         // we're done, start the timer
2754                         cvar_set("rescan_pending", "0");
2755                 }
2756
2757                 mapvote_initialized = TRUE;
2758                 if(DoNextMapOverride())
2759                         return;
2760                 if(!cvar("g_maplist_votable") || player_count <= 0)
2761                 {
2762                         GotoNextMap();
2763                         return;
2764                 }
2765                 MapVote_Init();
2766         }
2767
2768         MapVote_Tick();
2769 };
2770
2771 string GotoMap(string m)
2772 {
2773         if(!MapInfo_CheckMap(m))
2774                 return "The map you chose is not available on this server.";
2775         cvar_set("nextmap", m);
2776         cvar_set("timelimit", "-1");
2777         if(mapvote_initialized || alreadychangedlevel)
2778         {
2779                 if(DoNextMapOverride())
2780                         return "Map switch initiated.";
2781                 else
2782                         return "Hm... no. For some reason I like THIS map more.";
2783         }
2784         else
2785                 return "Map switch will happen after scoreboard.";
2786 }
2787
2788
2789 void EndFrame()
2790 {
2791         float altime;
2792         FOR_EACH_REALCLIENT(self)
2793         {
2794                 if(self.classname == "spectator")
2795                 {
2796                         if(self.enemy.typehitsound)
2797                                 play2(self, "misc/typehit.wav");
2798                         else if(self.enemy.hitsound && self.cvar_cl_hitsound)
2799                                 play2(self, "misc/hit.wav");
2800                 }
2801                 else
2802                 {
2803                         if(self.typehitsound)
2804                                 play2(self, "misc/typehit.wav");
2805                         else if(self.hitsound && self.cvar_cl_hitsound)
2806                                 play2(self, "misc/hit.wav");
2807                 }
2808         }
2809         altime = time + frametime * (1 + cvar("g_antilag_nudge"));
2810         // add 1 frametime because after this, engine SV_Physics
2811         // increases time by a frametime and then networks the frame
2812         // add another frametime because client shows everything with
2813         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2814         // needed!
2815         FOR_EACH_CLIENT(self)
2816         {
2817                 self.hitsound = FALSE;
2818                 self.typehitsound = FALSE;
2819                 antilag_record(self, altime);
2820         }
2821 }
2822
2823
2824 /*
2825  * RedirectionThink:
2826  * returns TRUE if redirecting
2827  */
2828 float redirection_timeout;
2829 float redirection_nextthink;
2830 float RedirectionThink()
2831 {
2832         float clients_found;
2833
2834         if(redirection_target == "")
2835                 return FALSE;
2836
2837         if(!redirection_timeout)
2838         {
2839                 cvar_set("sv_public", "-2");
2840                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2841                 if(redirection_target == "self")
2842                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2843                 else
2844                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2845         }
2846
2847         if(time < redirection_nextthink)
2848                 return TRUE;
2849
2850         redirection_nextthink = time + 1;
2851
2852         clients_found = 0;
2853         FOR_EACH_REALCLIENT(self)
2854         {
2855                 print("Redirecting: sending connect command to ", self.netname, "\n");
2856                 if(redirection_target == "self")
2857                         stuffcmd(self, "\ndisconnect; reconnect\n");
2858                 else
2859                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2860                 ++clients_found;
2861         }
2862
2863         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2864
2865         if(time > redirection_timeout || clients_found == 0)
2866                 localcmd("\nwait; wait; wait; quit\n");
2867
2868         return TRUE;
2869 }
2870
2871 void TargetMusic_RestoreGame();
2872 void RestoreGame()
2873 {
2874         // Loaded from a save game
2875         // some things then break, so let's work around them...
2876
2877         // Progs DB (capture records)
2878         ServerProgsDB = db_load("server.db");
2879
2880         // Mapinfo
2881         MapInfo_Shutdown();
2882         MapInfo_Enumerate();
2883         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2884         WeaponStats_Init();
2885
2886         TargetMusic_RestoreGame();
2887 }
2888
2889 void SV_Shutdown()
2890 {
2891         if(gameover > 1) // shutting down already?
2892                 return;
2893
2894         gameover = 2; // 2 = server shutting down
2895
2896         if(world_initialized > 0)
2897         {
2898                 world_initialized = 0;
2899                 print("Saving persistent data...\n");
2900                 Ban_SaveBans();
2901                 if(!cheatcount_total)
2902                 {
2903                         if(cvar("sv_db_saveasdump"))
2904                                 db_dump(ServerProgsDB, "server.db");
2905                         else
2906                                 db_save(ServerProgsDB, "server.db");
2907                 }
2908                 if(cvar("developer"))
2909                 {
2910                         if(cvar("sv_db_saveasdump"))
2911                                 db_dump(TemporaryDB, "server-temp.db");
2912                         else
2913                                 db_save(TemporaryDB, "server-temp.db");
2914                 }
2915                 CheatShutdown(); // must be after cheatcount check
2916                 db_close(ServerProgsDB);
2917                 db_close(TemporaryDB);
2918                 print("done!\n");
2919                 // tell the bot system the game is ending now
2920                 bot_endgame();
2921
2922                 WeaponStats_Shutdown();
2923                 MapInfo_Shutdown();
2924         }
2925         else if(world_initialized == 0)
2926         {
2927                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2928         }
2929 }