qcsrc/server/g_world.qc

   1 #define LATENCY_THINKRATE 10
   2 .float latency_sum;
   3 .float latency_cnt;
   4 .float latency_time;
   5 entity pingplreport;
   6 void PingPLReport_Think()
   7 {
   8         float delta;
   9         entity e;
  10
  11         delta = 3 / maxclients;
  12         if(delta < sys_frametime)
  13                 delta = 0;
  14         self.nextthink = time + delta;
  15
  16         e = edict_num(self.cnt + 1);
  17         if(clienttype(e) == CLIENTTYPE_REAL)
  18         {
  19                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  20                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  21                 WriteByte(MSG_BROADCAST, self.cnt);
  22                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  23                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  24                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  25
  26                 // record latency times for clients throughout the match so we can report it to playerstats
  27                 if(time > (e.latency_time + LATENCY_THINKRATE))
  28                 {
  29                         e.latency_sum += e.ping;
  30                         e.latency_cnt += 1;
  31                         e.latency_time = time;
  32                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  33                 }
  34         }
  35         else
  36         {
  37                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  38                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  39                 WriteByte(MSG_BROADCAST, self.cnt);
  40                 WriteShort(MSG_BROADCAST, 0);
  41                 WriteByte(MSG_BROADCAST, 0);
  42                 WriteByte(MSG_BROADCAST, 0);
  43         }
  44         self.cnt = mod(self.cnt + 1, maxclients);
  45 }
  46 void PingPLReport_Spawn()
  47 {
  48         pingplreport = spawn();
  49         pingplreport.classname = "pingplreport";
  50         pingplreport.think = PingPLReport_Think;
  51         pingplreport.nextthink = time;
  52 }
  53
  54 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  55 string redirection_target;
  56 float world_initialized;
  57
  58 string GetMapname();
  59 string GetGametype();
  60 void GotoNextMap(float reinit);
  61 void ShuffleMaplist();
  62 float(float reinit) DoNextMapOverride;
  63
  64 void SetDefaultAlpha()
  65 {
  66         if(autocvar_g_running_guns)
  67         {
  68                 default_player_alpha = -1;
  69                 default_weapon_alpha = +1;
  70         }
  71         else if(g_cloaked)
  72         {
  73                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  74                 default_weapon_alpha = default_player_alpha;
  75         }
  76         else
  77         {
  78                 default_player_alpha = autocvar_g_player_alpha;
  79                 if(default_player_alpha == 0)
  80                         default_player_alpha = 1;
  81                 default_weapon_alpha = default_player_alpha;
  82         }
  83 }
  84
  85 void fteqcc_testbugs()
  86 {
  87         float a, b;
  88
  89         if(!autocvar_developer_fteqccbugs)
  90                 return;
  91
  92         dprint("*** fteqcc test: checking for bugs...\n");
  93
  94         a = 1;
  95         b = 5;
  96         if(sqrt(a) - sqrt(b - a) == 0)
  97                 dprint("*** fteqcc test: found same-function-twice bug\n");
  98         else
  99                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
 100
 101         world.cnt = -10;
 102         world.enemy = world;
 103         world.enemy.cnt += 10;
 104         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
 105                 dprint("*** fteqcc test: found += bug\n");
 106         else
 107                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
 108         world.cnt = 0;
 109 }
 110
 111 void GotoFirstMap()
 112 {
 113         float n;
 114         if(autocvar__sv_init)
 115         {
 116                 // cvar_set("_sv_init", "0");
 117                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 118                 // to this "init" map on a dedicated server will cause no permanent
 119                 // harm
 120                 if(autocvar_g_maplist_shuffle)
 121                         ShuffleMaplist();
 122                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 123                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 124
 125                 MapInfo_Enumerate();
 126                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 127
 128                 if(!DoNextMapOverride(1))
 129                         GotoNextMap(1);
 130
 131                 return;
 132         }
 133
 134         if(time < 5)
 135         {
 136                 self.nextthink = time;
 137         }
 138         else
 139         {
 140                 self.nextthink = time + 1;
 141                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 142         }
 143 }
 144
 145 void cvar_changes_init()
 146 {
 147         float h;
 148         string k, v, d;
 149         float n, i, adding, pureadding;
 150
 151         if(cvar_changes)
 152                 strunzone(cvar_changes);
 153         cvar_changes = string_null;
 154         if(cvar_purechanges)
 155                 strunzone(cvar_purechanges);
 156         cvar_purechanges = string_null;
 157         cvar_purechanges_count = 0;
 158
 159         h = buf_create();
 160         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 161         n = buf_getsize(h);
 162
 163         adding = TRUE;
 164         pureadding = TRUE;
 165
 166         for(i = 0; i < n; ++i)
 167         {
 168                 k = bufstr_get(h, i);
 169
 170 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 171 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 172 #define BADCVAR(p) if(k == p) continue
 173
 174                 // general excludes and namespaces for server admin used cvars
 175                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 176
 177                 // internal
 178                 BADPREFIX("csqc_");
 179                 BADPREFIX("cvar_check_");
 180                 BADCVAR("gamecfg");
 181                 BADCVAR("g_configversion");
 182                 BADCVAR("g_maplist_index");
 183                 BADCVAR("halflifebsp");
 184                 BADPREFIX("sv_world");
 185
 186                 // client
 187                 BADPREFIX("chase_");
 188                 BADPREFIX("cl_");
 189                 BADPREFIX("con_");
 190                 BADPREFIX("scoreboard_");
 191                 BADPREFIX("g_campaign");
 192                 BADPREFIX("g_waypointsprite_");
 193                 BADPREFIX("gl_");
 194                 BADPREFIX("joy");
 195                 BADPREFIX("hud_");
 196                 BADPREFIX("m_");
 197                 BADPREFIX("menu_");
 198                 BADPREFIX("net_slist_");
 199                 BADPREFIX("r_");
 200                 BADPREFIX("sbar_");
 201                 BADPREFIX("scr_");
 202                 BADPREFIX("snd_");
 203                 BADPREFIX("show");
 204                 BADPREFIX("sensitivity");
 205                 BADPREFIX("userbind");
 206                 BADPREFIX("v_");
 207                 BADPREFIX("vid_");
 208                 BADPREFIX("crosshair");
 209                 BADCVAR("mod_q3bsp_lightmapmergepower");
 210                 BADCVAR("mod_q3bsp_nolightmaps");
 211                 BADCVAR("fov");
 212                 BADCVAR("mastervolume");
 213                 BADCVAR("volume");
 214                 BADCVAR("bgmvolume");
 215
 216                 // private
 217                 BADCVAR("developer");
 218                 BADCVAR("log_dest_udp");
 219                 BADCVAR("log_file");
 220                 BADCVAR("net_address");
 221                 BADCVAR("net_address_ipv6");
 222                 BADCVAR("port");
 223                 BADCVAR("savedgamecfg");
 224                 BADCVAR("serverconfig");
 225                 BADCVAR("sv_autoscreenshot");
 226                 BADCVAR("sv_heartbeatperiod");
 227                 BADCVAR("sv_vote_master_password");
 228                 BADCVAR("sys_colortranslation");
 229                 BADCVAR("sys_specialcharactertranslation");
 230                 BADCVAR("timeformat");
 231                 BADCVAR("timestamps");
 232                 BADPREFIX("developer_");
 233                 BADPREFIX("g_ban_");
 234                 BADPREFIX("g_banned_list");
 235                 BADPREFIX("g_chat_flood_");
 236                 BADPREFIX("g_ghost_items");
 237                 BADPREFIX("g_playerstats_");
 238                 BADPREFIX("g_respawn_ghosts");
 239                 BADPREFIX("g_voice_flood_");
 240                 BADPREFIX("rcon_");
 241                 BADPREFIX("sv_allowdownloads");
 242                 BADPREFIX("sv_autodemo");
 243                 BADPREFIX("sv_curl_");
 244                 BADPREFIX("sv_eventlog");
 245                 BADPREFIX("sv_logscores_");
 246                 BADPREFIX("sv_master");
 247                 BADPREFIX("sv_weaponstats_");
 248                 BADPREFIX("sv_waypointsprite_");
 249                 BADCVAR("rescan_pending");
 250
 251                 // these can contain player IDs, so better hide
 252                 BADPREFIX("g_forced_team_");
 253
 254                 // mapinfo
 255                 BADCVAR("fraglimit");
 256                 BADCVAR("g_arena");
 257                 BADCVAR("g_assault");
 258                 BADCVAR("g_ca");
 259                 BADCVAR("g_ctf");
 260                 BADCVAR("g_cts");
 261                 BADCVAR("g_dm");
 262                 BADCVAR("g_domination");
 263                 BADCVAR("g_domination_default_teams");
 264                 BADCVAR("g_freezetag");
 265                 BADCVAR("g_keepaway");
 266                 BADCVAR("g_keyhunt");
 267                 BADCVAR("g_keyhunt_teams");
 268                 BADCVAR("g_keyhunt_teams");
 269                 BADCVAR("g_lms");
 270                 BADCVAR("g_nexball");
 271                 BADCVAR("g_onslaught");
 272                 BADCVAR("g_race");
 273                 BADCVAR("g_race_qualifying_timelimit");
 274                 BADCVAR("g_tdm");
 275                 BADCVAR("g_tdm_teams");
 276                 BADCVAR("leadlimit");
 277                 BADCVAR("nextmap");
 278                 BADCVAR("teamplay");
 279                 BADCVAR("timelimit");
 280
 281                 // long
 282                 BADCVAR("hostname");
 283                 BADCVAR("g_maplist");
 284                 BADCVAR("g_maplist_mostrecent");
 285                 BADCVAR("sv_motd");
 286
 287                 v = cvar_string(k);
 288                 d = cvar_defstring(k);
 289                 if(v == d)
 290                         continue;
 291
 292                 if(adding)
 293                 {
 294                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 295                         if(strlen(cvar_changes) > 16384)
 296                         {
 297                                 cvar_changes = "// too many settings have been changed to show them here\n";
 298                                 adding = 0;
 299                         }
 300                 }
 301
 302                 // now check if the changes are actually gameplay relevant
 303
 304                 // does nothing visible
 305                 BADCVAR("captureleadlimit_override");
 306                 BADCVAR("g_arena_point_leadlimit");
 307                 BADCVAR("g_balance_kill_delay");
 308                 BADCVAR("g_ca_point_leadlimit");
 309                 BADCVAR("g_ctf_captimerecord_always");
 310                 BADCVAR("g_ctf_flag_glowtrails");
 311                 BADCVAR("g_ctf_flag_pickup_verbosename");
 312                 BADCVAR("g_domination_point_leadlimit");
 313                 BADCVAR("g_forced_respawn");
 314                 BADCVAR("g_keyhunt_point_leadlimit");
 315                 BADPREFIX("g_mod_");
 316                 BADCVAR("g_nexball_goalleadlimit");
 317                 BADCVAR("leadlimit_and_fraglimit");
 318                 BADCVAR("leadlimit_override");
 319                 BADCVAR("pausable");
 320                 BADCVAR("sv_allow_fullbright");
 321                 BADCVAR("sv_checkforpacketsduringsleep");
 322                 BADCVAR("sv_fraginfo");
 323                 BADCVAR("sv_timeout");
 324                 BADPREFIX("sv_timeout_");
 325                 BADCVAR("welcome_message_time");
 326                 BADPREFIX("crypto_");
 327                 BADPREFIX("g_chat_");
 328                 BADPREFIX("g_ctf_captimerecord_");
 329                 BADPREFIX("g_maplist_votable_");
 330                 BADPREFIX("net_");
 331                 BADPREFIX("prvm_");
 332                 BADPREFIX("skill_");
 333                 BADPREFIX("sv_cullentities_");
 334                 BADPREFIX("sv_fraginfo_");
 335                 BADPREFIX("sv_maxidle_");
 336                 BADPREFIX("sv_vote_");
 337                 BADPREFIX("timelimit_");
 338                 BADCVAR("gameversion");
 339                 BADPREFIX("gameversion_");
 340                 BADCVAR("sv_namechangetimer");
 341
 342                 // allowed changes to server admins (please sync this to server.cfg)
 343                 // vi commands:
 344                 //   :/"impure"/,$d
 345                 //   :g!,^\/\/[^ /],d
 346                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 347                 //   :%!sort
 348                 // yes, this does contain some redundant stuff, don't really care
 349                 BADCVAR("bot_config_file");
 350                 BADCVAR("bot_number");
 351                 BADCVAR("bot_prefix");
 352                 BADCVAR("bot_suffix");
 353                 BADCVAR("capturelimit_override");
 354                 BADCVAR("fraglimit_override");
 355                 BADCVAR("gametype");
 356                 BADCVAR("g_antilag");
 357                 BADCVAR("g_balance_teams");
 358                 BADCVAR("g_balance_teams_prevent_imbalance");
 359                 BADCVAR("g_balance_teams_scorefactor");
 360                 BADCVAR("g_ban_sync_trusted_servers");
 361                 BADCVAR("g_ban_sync_uri");
 362                 BADCVAR("g_ctf_ignore_frags");
 363                 BADCVAR("g_domination_point_limit");
 364                 BADCVAR("g_friendlyfire");
 365                 BADCVAR("g_fullbrightitems");
 366                 BADCVAR("g_fullbrightplayers");
 367                 BADCVAR("g_keyhunt_point_limit");
 368                 BADCVAR("g_keyhunt_teams_override");
 369                 BADCVAR("g_lms_lives_override");
 370                 BADCVAR("g_maplist");
 371                 BADCVAR("g_maplist_check_waypoints");
 372                 BADCVAR("g_maplist_mostrecent_count");
 373                 BADCVAR("g_maplist_shuffle");
 374                 BADCVAR("g_maplist_votable");
 375                 BADCVAR("g_maplist_votable_abstain");
 376                 BADCVAR("g_maplist_votable_nodetail");
 377                 BADCVAR("g_maplist_votable_suggestions");
 378                 BADCVAR("g_maxplayers");
 379                 BADCVAR("g_mirrordamage");
 380                 BADCVAR("g_nexball_goallimit");
 381                 BADCVAR("g_powerups");
 382                 BADCVAR("g_start_delay");
 383                 BADCVAR("g_warmup");
 384                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 385                 BADCVAR("hostname");
 386                 BADCVAR("log_file");
 387                 BADCVAR("maxplayers");
 388                 BADCVAR("minplayers");
 389                 BADCVAR("net_address");
 390                 BADCVAR("port");
 391                 BADCVAR("rcon_password");
 392                 BADCVAR("rcon_restricted_commands");
 393                 BADCVAR("rcon_restricted_password");
 394                 BADCVAR("skill");
 395                 BADCVAR("sv_adminnick");
 396                 BADCVAR("sv_autoscreenshot");
 397                 BADCVAR("sv_autotaunt");
 398                 BADCVAR("sv_curl_defaulturl");
 399                 BADCVAR("sv_defaultcharacter");
 400                 BADCVAR("sv_defaultplayercolors");
 401                 BADCVAR("sv_defaultplayermodel");
 402                 BADCVAR("sv_defaultplayerskin");
 403                 BADCVAR("sv_maxidle");
 404                 BADCVAR("sv_maxrate");
 405                 BADCVAR("sv_motd");
 406                 BADCVAR("sv_public");
 407                 BADCVAR("sv_ready_restart");
 408                 BADCVAR("sv_status_privacy");
 409                 BADCVAR("sv_taunt");
 410                 BADCVAR("sv_vote_call");
 411                 BADCVAR("sv_vote_commands");
 412                 BADCVAR("sv_vote_majority_factor");
 413                 BADCVAR("sv_vote_master");
 414                 BADCVAR("sv_vote_master_commands");
 415                 BADCVAR("sv_vote_master_password");
 416                 BADCVAR("sv_vote_simple_majority_factor");
 417                 BADCVAR("sys_ticrate");
 418                 BADCVAR("teamplay_mode");
 419                 BADCVAR("timelimit_override");
 420                 BADCVAR("g_spawnshieldtime");
 421                 BADPREFIX("g_warmup_");
 422                 BADPREFIX("sv_ready_restart_");
 423
 424                 // mutators that announce themselves properly to the server browser
 425                 BADCVAR("g_minstagib");
 426                 BADCVAR("g_new_toys");
 427                 BADCVAR("g_nix");
 428                 BADCVAR("g_grappling_hook");
 429                 BADCVAR("g_jetpack");
 430
 431 #undef BADPREFIX
 432 #undef BADCVAR
 433
 434                 if(pureadding)
 435                 {
 436                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 437                         if(strlen(cvar_purechanges) > 16384)
 438                         {
 439                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 440                                 pureadding = 0;
 441                         }
 442                 }
 443                 ++cvar_purechanges_count;
 444                 // WARNING: this variable is used for the server list
 445                 // NEVER dare to skip this code!
 446                 // Hacks to intentionally appearing as "pure server" even though you DO have
 447                 // modified settings may be punished by removal from the server list.
 448                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 449                 // though.
 450         }
 451         buf_del(h);
 452         if(cvar_changes == "")
 453                 cvar_changes = "// this server runs at default server settings\n";
 454         else
 455                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 456         cvar_changes = strzone(cvar_changes);
 457         if(cvar_purechanges == "")
 458                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 459         else
 460                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 461         cvar_purechanges = strzone(cvar_purechanges);
 462 }
 463
 464 void detect_maptype()
 465 {
 466 #if 0
 467         vector o, v;
 468         float i;
 469
 470         for(;;)
 471         {
 472                 o = world.mins;
 473                 o_x += random() * (world.maxs_x - world.mins_x);
 474                 o_y += random() * (world.maxs_y - world.mins_y);
 475                 o_z += random() * (world.maxs_z - world.mins_z);
 476
 477                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 478                 if(trace_fraction == 1)
 479                         continue;
 480
 481                 v = trace_endpos;
 482
 483                 for(i = 0; i < 64; i += 4)
 484                 {
 485                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 486         if(trace_fraction == 1)
 487                 continue;
 488                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 489                 }
 490
 491                 break;
 492         }
 493 #endif
 494 }
 495
 496 entity randomseed;
 497 float RandomSeed_Send(entity to, float sf)
 498 {
 499         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 500         WriteShort(MSG_ENTITY, self.cnt);
 501         return TRUE;
 502 }
 503 void RandomSeed_Think()
 504 {
 505         self.cnt = bound(0, floor(random() * 65536), 65535);
 506         self.nextthink = time + 5;
 507
 508         self.SendFlags |= 1;
 509 }
 510 void RandomSeed_Spawn()
 511 {
 512         randomseed = spawn();
 513         randomseed.think = RandomSeed_Think;
 514         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 515
 516         entity oldself;
 517         oldself = self;
 518         self = randomseed;
 519         self.think(); // sets random seed and nextthink
 520         self = oldself;
 521 }
 522
 523 void spawnfunc___init_dedicated_server(void)
 524 {
 525         // handler for _init/_init map (only for dedicated server initialization)
 526
 527         world_initialized = -1; // don't complain
 528         cvar = cvar_normal;
 529         cvar_string = cvar_string_normal;
 530         cvar_set = cvar_set_normal;
 531
 532         remove = remove_unsafely;
 533
 534         entity e;
 535         e = spawn();
 536         e.think = GotoFirstMap;
 537         e.nextthink = time; // this is usually 1 at this point
 538
 539         e = spawn();
 540         e.classname = "info_player_deathmatch"; // safeguard against player joining
 541
 542         self.classname = "worldspawn"; // safeguard against various stuff ;)
 543
 544         // needs to be done so early because of the constants they create
 545         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 546         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 547         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 548         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 549
 550         MapInfo_Enumerate();
 551         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 552 }
 553
 554 void Map_MarkAsRecent(string m);
 555 float world_already_spawned;
 556 void Nagger_Init();
 557 void ClientInit_Spawn();
 558 void WeaponStats_Init();
 559 void WeaponStats_Shutdown();
 560 void spawnfunc_worldspawn (void)
 561 {
 562         float fd, l, i, j, n;
 563         string s, col;
 564
 565         cvar = cvar_normal;
 566         cvar_string = cvar_string_normal;
 567         cvar_set = cvar_set_normal;
 568
 569         if(world_already_spawned)
 570                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 571         world_already_spawned = TRUE;
 572
 573         remove = remove_safely; // during spawning, watch what you remove!
 574
 575         check_unacceptable_compiler_bugs();
 576
 577         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 578
 579         compressShortVector_init();
 580
 581         allowed_to_spawn = TRUE;
 582
 583         entity head;
 584         head = nextent(world);
 585         maxclients = 0;
 586         while(head)
 587         {
 588                 ++maxclients;
 589                 head = nextent(head);
 590         }
 591
 592         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? TRUE : FALSE);
 593
 594         // needs to be done so early because of the constants they create
 595         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 596         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 597         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 598         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 599
 600         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 601
 602         TemporaryDB = db_create();
 603
 604         // 0 normal
 605         lightstyle(0, "m");
 606
 607         // 1 FLICKER (first variety)
 608         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 609
 610         // 2 SLOW STRONG PULSE
 611         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 612
 613         // 3 CANDLE (first variety)
 614         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 615
 616         // 4 FAST STROBE
 617         lightstyle(4, "mamamamamama");
 618
 619         // 5 GENTLE PULSE 1
 620         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 621
 622         // 6 FLICKER (second variety)
 623         lightstyle(6, "nmonqnmomnmomomno");
 624
 625         // 7 CANDLE (second variety)
 626         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 627
 628         // 8 CANDLE (third variety)
 629         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 630
 631         // 9 SLOW STROBE (fourth variety)
 632         lightstyle(9, "aaaaaaaazzzzzzzz");
 633
 634         // 10 FLUORESCENT FLICKER
 635         lightstyle(10, "mmamammmmammamamaaamammma");
 636
 637         // 11 SLOW PULSE NOT FADE TO BLACK
 638         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 639
 640         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 641
 642         // 63 testing
 643         lightstyle(63, "a");
 644
 645         if(autocvar_g_campaign)
 646                 CampaignPreInit();
 647
 648         Map_MarkAsRecent(mapname);
 649
 650         PlayerStats_Init(); // we need this to be initiated before InitGameplayMode
 651
 652         precache_model ("null"); // we need this one before InitGameplayMode
 653         InitGameplayMode();
 654         readlevelcvars();
 655         GrappleHookInit();
 656         ElectroInit();
 657         LaserInit();
 658
 659         player_count = 0;
 660         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 661         if(bot_waypoints_for_items == 1)
 662                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 663                         bot_waypoints_for_items = 0;
 664
 665         precache();
 666
 667         WaypointSprite_Init();
 668
 669         GameLogInit(); // prepare everything
 670         // NOTE for matchid:
 671         // changing the logic generating it is okay. But:
 672         // it HAS to stay <= 64 chars
 673         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 674         if(autocvar_sv_eventlog)
 675         {
 676                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 677                 matchid = strzone(s);
 678
 679                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 680                 s = ":gameinfo:mutators:LIST";
 681
 682                 ret_string = s;
 683                 MUTATOR_CALLHOOK(BuildMutatorsString);
 684                 s = ret_string;
 685
 686                 // simple, probably not good in the mutator system
 687                 if(autocvar_g_grappling_hook)
 688                         s = strcat(s, ":grappling_hook");
 689
 690                 // initialiation stuff, not good in the mutator system
 691                 if(!autocvar_g_use_ammunition)
 692                         s = strcat(s, ":no_use_ammunition");
 693
 694                 // initialiation stuff, not good in the mutator system
 695                 if(autocvar_g_pickup_items == 0)
 696                         s = strcat(s, ":no_pickup_items");
 697                 if(autocvar_g_pickup_items > 0)
 698                         s = strcat(s, ":pickup_items");
 699
 700                 // initialiation stuff, not good in the mutator system
 701                 if(autocvar_g_weaponarena != "0")
 702                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 703
 704                 // TODO to mutator system
 705                 if(autocvar_g_norecoil)
 706                         s = strcat(s, ":norecoil");
 707
 708                 // TODO to mutator system
 709                 if(autocvar_g_midair)
 710                         s = strcat(s, ":midair");
 711
 712                 // TODO to mutator system
 713                 if(autocvar_g_powerups == 0)
 714                         s = strcat(s, ":no_powerups");
 715                 if(autocvar_g_powerups > 0)
 716                         s = strcat(s, ":powerups");
 717
 718                 GameLogEcho(s);
 719                 GameLogEcho(":gameinfo:end");
 720         }
 721         else
 722                 matchid = strzone(ftos(random()));
 723
 724         cvar_set("nextmap", "");
 725
 726         SetDefaultAlpha();
 727
 728         if(autocvar_g_campaign)
 729                 CampaignPostInit();
 730
 731         fteqcc_testbugs();
 732
 733         Ban_LoadBans();
 734
 735         MapInfo_Enumerate();
 736         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 737
 738         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 739         {
 740                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 741                 if(fd != -1)
 742                 {
 743                         while((s = fgets(fd)))
 744                         {
 745                                 l = tokenize_console(s);
 746                                 if(l < 2)
 747                                         continue;
 748                                 if(argv(0) == "cd")
 749                                 {
 750                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 751                                         print("  cdtrack ", argv(2), "\n");
 752                                 }
 753                                 else if(argv(0) == "fog")
 754                                 {
 755                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 756                                         print("  \"fog\" \"", s, "\"\n");
 757                                 }
 758                                 else if(argv(0) == "set")
 759                                 {
 760                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 761                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 762                                 }
 763                                 else if(argv(0) != "//")
 764                                 {
 765                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 766                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 767                                 }
 768                         }
 769                         fclose(fd);
 770                 }
 771         }
 772
 773         WeaponStats_Init();
 774
 775         WEPSET_ADDSTAT();
 776         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 777         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 778         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 779         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 780         Nagger_Init();
 781
 782         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 783         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 784         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 785         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 786         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 787         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 788         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 789         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 790         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 791         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 792         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 793         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 794         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 795
 796         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 797         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 798
 799         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 800
 801         if(g_ca || g_freezetag)
 802         {
 803                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 804                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 805                 addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 806                 addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 807         }
 808         if(g_freezetag)
 809         {
 810                 addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
 811                 addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
 812         }
 813
 814         // g_movementspeed hack
 815         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 816         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 817         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 818         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 819
 820         // secrets
 821         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 822         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 823
 824         // misc
 825         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 826
 827         next_pingtime = time + 5;
 828
 829         detect_maptype();
 830
 831         // set up information replies for clients and server to use
 832         lsmaps_reply = "^7Maps available: ";
 833         lsnewmaps_reply = "^7Maps without a record set: ";
 834         for(i = 0, j = 0; i < MapInfo_count; ++i)
 835         {
 836                 if(MapInfo_Get_ByID(i))
 837                         if not(MapInfo_Map_flags & MapInfo_ForbiddenFlags())
 838                         {
 839                                 if(mod(i, 2))
 840                                         col = "^2";
 841                                 else
 842                                         col = "^3";
 843
 844                                 ++j;
 845
 846                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 847
 848                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 849                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 850                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 851                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 852                         }
 853         }
 854
 855         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 856         lsnewmaps_reply = strzone(strcat(((!g_race && !g_cts) ? "Need to be playing race or CTS for lsnewmaps to work." : lsnewmaps_reply), "\n"));
 857
 858         maplist_reply = "^7Maps in list: ";
 859         n = tokenize_console(autocvar_g_maplist);
 860         for(i = 0, j = 0; i < n; ++i)
 861         {
 862                 if(MapInfo_CheckMap(argv(i)))
 863                 {
 864                         if(mod(j, 2))
 865                                 col = "^2";
 866                         else
 867                                 col = "^3";
 868                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 869                         ++j;
 870                 }
 871         }
 872         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 873         MapInfo_ClearTemps();
 874
 875         for(i = 0; i < 10; ++i)
 876         {
 877                 s = getrecords(i);
 878                 if (s)
 879                         records_reply[i] = strzone(s);
 880         }
 881
 882         ladder_reply = strzone(getladder());
 883
 884         rankings_reply = strzone(getrankings());
 885
 886         // begin other init
 887         ClientInit_Spawn();
 888         RandomSeed_Spawn();
 889         PingPLReport_Spawn();
 890
 891         CheatInit();
 892
 893         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 894
 895         // fill sv_curl_serverpackages from .serverpackage files
 896         if(autocvar_sv_curl_serverpackages_auto)
 897         {
 898                 s = "";
 899                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 900                 for(i = 0; i < n; ++i)
 901                         if(substring(argv(i), -14, -1) != "-serverpackage.txt")
 902                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 903                                 s = strcat(s, " ", argv(i));
 904                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 905                 if(fd >= 0)
 906                 {
 907                         j = search_getsize(fd);
 908                         for(i = 0; i < j; ++i)
 909                                 s = strcat(s, " ", search_getfilename(fd, i));
 910                         search_end(fd);
 911                 }
 912                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 913                 if(fd >= 0)
 914                 {
 915                         j = search_getsize(fd);
 916                         for(i = 0; i < j; ++i)
 917                                 s = strcat(s, " ", search_getfilename(fd, i));
 918                         search_end(fd);
 919                 }
 920                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 921         }
 922
 923         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 924         modname = "Xonotic";
 925         // physics/balance/config changes that count as mod
 926         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 927                 modname = cvar_string("g_mod_physics");
 928         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 929                 modname = cvar_string("g_mod_balance");
 930         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 931                 modname = cvar_string("g_mod_config");
 932         // extra mutators that deserve to count as mod
 933         MUTATOR_CALLHOOK(SetModname);
 934
 935         // save it for later
 936         modname = strzone(modname);
 937
 938         WinningConditionHelper(); // set worldstatus
 939
 940         world_initialized = 1;
 941 }
 942
 943 void spawnfunc_light (void)
 944 {
 945         //makestatic (self); // Who the f___ did that?
 946         remove(self);
 947 }
 948
 949 string GetGametype()
 950 {
 951         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 952 }
 953
 954 string getmapname_stored;
 955 string GetMapname()
 956 {
 957         return mapname;
 958 }
 959
 960 float Map_Count, Map_Current;
 961 string Map_Current_Name;
 962
 963 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 964 float GetMaplistPosition()
 965 {
 966         float pos, idx;
 967         string map;
 968
 969         map = GetMapname();
 970         idx = autocvar_g_maplist_index;
 971
 972         if(idx >= 0)
 973                 if(idx < Map_Count)
 974                         if(map == argv(idx))
 975                                 return idx;
 976
 977         for(pos = 0; pos < Map_Count; ++pos)
 978                 if(map == argv(pos))
 979                         return pos;
 980
 981         // resume normal maplist rotation if current map is not in g_maplist
 982         return idx;
 983 }
 984
 985 float MapHasRightSize(string map)
 986 {
 987         float fh;
 988         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 989         if(autocvar_g_maplist_check_waypoints)
 990         {
 991                 dprint("checkwp "); dprint(map);
 992                 if(!fexists(strcat("maps/", map, ".waypoints")))
 993                 {
 994                         dprint(": no waypoints\n");
 995                         return FALSE;
 996                 }
 997                 dprint(": has waypoints\n");
 998         }
 999
1000         // open map size restriction file
1001         dprint("opensize "); dprint(map);
1002         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1003         if(fh >= 0)
1004         {
1005                 float mapmin, mapmax;
1006                 dprint(": ok, ");
1007                 mapmin = stof(fgets(fh));
1008                 mapmax = stof(fgets(fh));
1009                 fclose(fh);
1010                 if(player_count < mapmin)
1011                 {
1012                         dprint("not enough\n");
1013                         return FALSE;
1014                 }
1015                 if(player_count > mapmax)
1016                 {
1017                         dprint("too many\n");
1018                         return FALSE;
1019                 }
1020                 dprint("right size\n");
1021                 return TRUE;
1022         }
1023         dprint(": not found\n");
1024         return TRUE;
1025 }
1026
1027 string Map_Filename(float position)
1028 {
1029         return strcat("maps/", argv(position), ".bsp");
1030 }
1031
1032 string strwords(string s, float w)
1033 {
1034         float endpos;
1035         for(endpos = 0; w && endpos >= 0; --w)
1036                 endpos = strstrofs(s, " ", endpos + 1);
1037         if(endpos < 0)
1038                 return s;
1039         else
1040                 return substring(s, 0, endpos);
1041 }
1042
1043 float strhasword(string s, string w)
1044 {
1045         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1046 }
1047
1048 void Map_MarkAsRecent(string m)
1049 {
1050         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1051 }
1052
1053 float Map_IsRecent(string m)
1054 {
1055         return strhasword(autocvar_g_maplist_mostrecent, m);
1056 }
1057
1058 float Map_Check(float position, float pass)
1059 {
1060         string filename;
1061         string map_next;
1062         map_next = argv(position);
1063         if(pass <= 1)
1064         {
1065                 if(Map_IsRecent(map_next))
1066                         return 0;
1067         }
1068         filename = Map_Filename(position);
1069         if(MapInfo_CheckMap(map_next))
1070         {
1071                 if(pass == 2)
1072                         return 1;
1073                 if(MapHasRightSize(map_next))
1074                         return 1;
1075                 return 0;
1076         }
1077         else
1078                 dprint( "Couldn't select '", filename, "'..\n" );
1079
1080         return 0;
1081 }
1082
1083 void Map_Goto_SetStr(string nextmapname)
1084 {
1085         if(getmapname_stored != "")
1086                 strunzone(getmapname_stored);
1087         if(nextmapname == "")
1088                 getmapname_stored = "";
1089         else
1090                 getmapname_stored = strzone(nextmapname);
1091 }
1092
1093 void Map_Goto_SetFloat(float position)
1094 {
1095         cvar_set("g_maplist_index", ftos(position));
1096         Map_Goto_SetStr(argv(position));
1097 }
1098
1099 void Map_Goto(float reinit)
1100 {
1101         MapInfo_LoadMap(getmapname_stored, reinit);
1102 }
1103
1104 // return codes of map selectors:
1105 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1106 //   -2 = permanent failure
1107 float() MaplistMethod_Iterate = // usual method
1108 {
1109         float pass, i;
1110
1111         for(pass = 1; pass <= 2; ++pass)
1112         {
1113                 for(i = 1; i < Map_Count; ++i)
1114                 {
1115                         float mapindex;
1116                         mapindex = mod(i + Map_Current, Map_Count);
1117                         if(Map_Check(mapindex, pass))
1118                                 return mapindex;
1119                 }
1120         }
1121         return -1;
1122 }
1123
1124 float() MaplistMethod_Repeat = // fallback method
1125 {
1126         if(Map_Check(Map_Current, 2))
1127                 return Map_Current;
1128         return -2;
1129 }
1130
1131 float() MaplistMethod_Random = // random map selection
1132 {
1133         float i, imax;
1134
1135         imax = 42;
1136
1137         for(i = 0; i <= imax; ++i)
1138         {
1139                 float mapindex;
1140                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1141                 if(Map_Check(mapindex, 1))
1142                         return mapindex;
1143         }
1144         return -1;
1145 }
1146
1147 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1148 // the exponent sets a bias on the map selection:
1149 // the higher the exponent, the less likely "shortly repeated" same maps are
1150 {
1151         float i, j, imax, insertpos;
1152
1153         imax = 42;
1154
1155         for(i = 0; i <= imax; ++i)
1156         {
1157                 string newlist;
1158
1159                 // now reinsert this at another position
1160                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1161                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1162                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1163                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1164
1165                 // insert the current map there
1166                 newlist = "";
1167                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1168                         newlist = strcat(newlist, " ", argv(j));
1169                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1170                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1171                         newlist = strcat(newlist, " ", argv(j));
1172                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1173                 cvar_set("g_maplist", newlist);
1174                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1175
1176                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1177                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1178                 if(Map_Check(Map_Current, 1))
1179                         return Map_Current;
1180         }
1181         return -1;
1182 }
1183
1184 void Maplist_Init()
1185 {
1186         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1187         if(Map_Count == 0)
1188         {
1189                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1190                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1191                 if(autocvar_g_maplist_shuffle)
1192                         ShuffleMaplist();
1193                 localcmd("\nmenu_cmd sync\n");
1194                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1195         }
1196         if(Map_Count == 0)
1197                 error("empty maplist, cannot select a new map");
1198         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1199
1200         if(Map_Current_Name)
1201                 strunzone(Map_Current_Name);
1202         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1203         // this may or may not be correct, but who cares, in the worst case a map
1204         // isn't chosen in the first pass that should have been
1205 }
1206
1207 string GetNextMap()
1208 {
1209         float nextMap;
1210
1211         Maplist_Init();
1212         nextMap = -1;
1213
1214         if(nextMap == -1)
1215                 if(autocvar_g_maplist_shuffle > 0)
1216                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1217
1218         if(nextMap == -1)
1219                 if(autocvar_g_maplist_selectrandom)
1220                         nextMap = MaplistMethod_Random();
1221
1222         if(nextMap == -1)
1223                 nextMap = MaplistMethod_Iterate();
1224
1225         if(nextMap == -1)
1226                 nextMap = MaplistMethod_Repeat();
1227
1228         if(nextMap >= 0)
1229         {
1230                 Map_Goto_SetFloat(nextMap);
1231                 return getmapname_stored;
1232         }
1233
1234         return "";
1235 }
1236
1237 float DoNextMapOverride(float reinit)
1238 {
1239         if(autocvar_g_campaign)
1240         {
1241                 CampaignPostIntermission();
1242                 alreadychangedlevel = TRUE;
1243                 return TRUE;
1244         }
1245         if(autocvar_quit_when_empty)
1246         {
1247                 if(player_count <= currentbots)
1248                 {
1249                         localcmd("quit\n");
1250                         alreadychangedlevel = TRUE;
1251                         return TRUE;
1252                 }
1253         }
1254         if(autocvar_quit_and_redirect != "")
1255         {
1256                 redirection_target = strzone(autocvar_quit_and_redirect);
1257                 alreadychangedlevel = TRUE;
1258                 return TRUE;
1259         }
1260         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1261         {
1262                 localcmd("restart\n");
1263                 alreadychangedlevel = TRUE;
1264                 return TRUE;
1265         }
1266         if(autocvar_nextmap != "")
1267                 if(MapInfo_CheckMap(autocvar_nextmap))
1268                 {
1269                         Map_Goto_SetStr(autocvar_nextmap);
1270                         Map_Goto(reinit);
1271                         alreadychangedlevel = TRUE;
1272                         return TRUE;
1273                 }
1274         if(!reinit && autocvar_lastlevel)
1275         {
1276                 cvar_settemp_restore();
1277                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1278                 alreadychangedlevel = TRUE;
1279                 return TRUE;
1280         }
1281         return FALSE;
1282 }
1283
1284 void GotoNextMap(float reinit)
1285 {
1286         //string nextmap;
1287         //float n, nummaps;
1288         //string s;
1289         if (alreadychangedlevel)
1290                 return;
1291         alreadychangedlevel = TRUE;
1292
1293         {
1294                 string nextMap;
1295                 float allowReset;
1296
1297                 for(allowReset = 1; allowReset >= 0; --allowReset)
1298                 {
1299                         nextMap = GetNextMap();
1300                         if(nextMap != "")
1301                                 break;
1302
1303                         if(allowReset)
1304                         {
1305                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1306                                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1307                                 if(autocvar_g_maplist_shuffle)
1308                                         ShuffleMaplist();
1309                                 localcmd("\nmenu_cmd sync\n");
1310                         }
1311                         else
1312                         {
1313                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1314                         }
1315                 }
1316                 Map_Goto(reinit);
1317         }
1318 }
1319
1320
1321 /*
1322 ============
1323 IntermissionThink
1324
1325 When the player presses attack or jump, change to the next level
1326 ============
1327 */
1328 .float autoscreenshot;
1329 void() MapVote_Start;
1330 void() MapVote_Think;
1331 float mapvote_initialized;
1332 void IntermissionThink()
1333 {
1334         FixIntermissionClient(self);
1335
1336         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1337         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1338
1339         if( (server_screenshot || client_screenshot)
1340                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1341         {
1342                 self.autoscreenshot = -1;
1343                 if(clienttype(self) == CLIENTTYPE_REAL) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"", GetMapname(), strftime(FALSE, "%s"))); }
1344                 return;
1345         }
1346
1347         if (time < intermission_exittime)
1348                 return;
1349
1350         if(!mapvote_initialized)
1351                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1352                         return;
1353
1354         MapVote_Start();
1355 }
1356
1357 /*
1358 ============
1359 FindIntermission
1360
1361 Returns the entity to view from
1362 ============
1363 */
1364 /*
1365 entity FindIntermission()
1366 {
1367         local   entity spot;
1368         local   float cyc;
1369
1370 // look for info_intermission first
1371         spot = find (world, classname, "info_intermission");
1372         if (spot)
1373         {       // pick a random one
1374                 cyc = random() * 4;
1375                 while (cyc > 1)
1376                 {
1377                         spot = find (spot, classname, "info_intermission");
1378                         if (!spot)
1379                                 spot = find (spot, classname, "info_intermission");
1380                         cyc = cyc - 1;
1381                 }
1382                 return spot;
1383         }
1384
1385 // then look for the start position
1386         spot = find (world, classname, "info_player_start");
1387         if (spot)
1388                 return spot;
1389
1390 // testinfo_player_start is only found in regioned levels
1391         spot = find (world, classname, "testplayerstart");
1392         if (spot)
1393                 return spot;
1394
1395 // then look for the start position
1396         spot = find (world, classname, "info_player_deathmatch");
1397         if (spot)
1398                 return spot;
1399
1400         //objerror ("FindIntermission: no spot");
1401         return world;
1402 }
1403 */
1404
1405 /*
1406 ===============================================================================
1407
1408 RULES
1409
1410 ===============================================================================
1411 */
1412
1413 void DumpStats(float final)
1414 {
1415         float file;
1416         string s;
1417         float to_console;
1418         float to_eventlog;
1419         float to_file;
1420         float i;
1421
1422         to_console = autocvar_sv_logscores_console;
1423         to_eventlog = autocvar_sv_eventlog;
1424         to_file = autocvar_sv_logscores_file;
1425
1426         if(!final)
1427         {
1428                 to_console = TRUE; // always print printstats replies
1429                 to_eventlog = FALSE; // but never print them to the event log
1430         }
1431
1432         if(to_eventlog)
1433                 if(autocvar_sv_eventlog_console)
1434                         to_console = FALSE; // otherwise we get the output twice
1435
1436         if(final)
1437                 s = ":scores:";
1438         else
1439                 s = ":status:";
1440         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1441
1442         if(to_console)
1443                 print(s, "\n");
1444         if(to_eventlog)
1445                 GameLogEcho(s);
1446
1447         file = -1;
1448         if(to_file)
1449         {
1450                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1451                 if(file == -1)
1452                         to_file = FALSE;
1453                 else
1454                         fputs(file, strcat(s, "\n"));
1455         }
1456
1457         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1458         if(to_console)
1459                 print(s, "\n");
1460         if(to_eventlog)
1461                 GameLogEcho(s);
1462         if(to_file)
1463                 fputs(file, strcat(s, "\n"));
1464
1465         FOR_EACH_CLIENT(other)
1466         {
1467                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && autocvar_sv_logscores_bots))
1468                 {
1469                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1470                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1471                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1472                                 s = strcat(s, ftos(other.team), ":");
1473                         else
1474                                 s = strcat(s, "spectator:");
1475
1476                         if(to_console)
1477                                 print(s, other.netname, "\n");
1478                         if(to_eventlog)
1479                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1480                         if(to_file)
1481                                 fputs(file, strcat(s, other.netname, "\n"));
1482                 }
1483         }
1484
1485         if(teamplay)
1486         {
1487                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1488                 if(to_console)
1489                         print(s, "\n");
1490                 if(to_eventlog)
1491                         GameLogEcho(s);
1492                 if(to_file)
1493                         fputs(file, strcat(s, "\n"));
1494
1495                 for(i = 1; i < 16; ++i)
1496                 {
1497                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1498                         s = strcat(s, ":", ftos(i));
1499                         if(to_console)
1500                                 print(s, "\n");
1501                         if(to_eventlog)
1502                                 GameLogEcho(s);
1503                         if(to_file)
1504                                 fputs(file, strcat(s, "\n"));
1505                 }
1506         }
1507
1508         if(to_console)
1509                 print(":end\n");
1510         if(to_eventlog)
1511                 GameLogEcho(":end");
1512         if(to_file)
1513         {
1514                 fputs(file, ":end\n");
1515                 fclose(file);
1516         }
1517 }
1518
1519 void FixIntermissionClient(entity e)
1520 {
1521         string s;
1522         if(!e.autoscreenshot) // initial call
1523         {
1524                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1525                 e.health = -2342;
1526                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1527                 e.solid = SOLID_NOT;
1528                 e.movetype = MOVETYPE_NONE;
1529                 e.takedamage = DAMAGE_NO;
1530                 if(e.weaponentity)
1531                 {
1532                         e.weaponentity.effects = EF_NODRAW;
1533                         if (e.weaponentity.weaponentity)
1534                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1535                 }
1536                 if(clienttype(e) == CLIENTTYPE_REAL)
1537                 {
1538                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1539                         s = autocvar_sv_intermission_cdtrack;
1540                         if(s != "")
1541                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1542                         msg_entity = e;
1543                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1544                 }
1545         }
1546 }
1547
1548 /*
1549 go to the next level for deathmatch
1550 only called if a time or frag limit has expired
1551 */
1552 void NextLevel()
1553 {
1554         gameover = TRUE;
1555
1556         intermission_running = 1;
1557
1558 // enforce a wait time before allowing changelevel
1559         if(player_count > 0)
1560                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1561         else
1562                 intermission_exittime = -1;
1563
1564         /*
1565         WriteByte (MSG_ALL, SVC_CDTRACK);
1566         WriteByte (MSG_ALL, 3);
1567         WriteByte (MSG_ALL, 3);
1568         // done in FixIntermission
1569         */
1570
1571         //pos = FindIntermission ();
1572
1573         VoteReset();
1574
1575         DumpStats(TRUE);
1576
1577         // send statistics
1578         entity e;
1579         PlayerStats_EndMatch(1);
1580         FOR_EACH_CLIENT(e)
1581                 PlayerStats_AddGlobalInfo(e);
1582         PlayerStats_Shutdown();
1583         WeaponStats_Shutdown();
1584
1585         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1586
1587         if(autocvar_sv_eventlog)
1588                 GameLogEcho(":gameover");
1589
1590         GameLogClose();
1591
1592         FOR_EACH_PLAYER(other) {
1593                 FixIntermissionClient(other);
1594                 if(other.winning)
1595                         bprint(other.netname, " ^7wins.\n");
1596         }
1597
1598         if(autocvar_g_campaign)
1599                 CampaignPreIntermission();
1600
1601         MUTATOR_CALLHOOK(MatchEnd);
1602
1603         localcmd("\nsv_hook_gameend\n");
1604 }
1605
1606 /*
1607 ============
1608 CheckRules_Player
1609
1610 Exit deathmatch games upon conditions
1611 ============
1612 */
1613 void CheckRules_Player()
1614 {
1615         if (gameover)   // someone else quit the game already
1616                 return;
1617
1618         if(self.deadflag == DEAD_NO)
1619                 self.play_time += frametime;
1620
1621         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1622         //   (div0: and that in CheckRules_World please)
1623 }
1624
1625 float checkrules_equality;
1626 float checkrules_suddendeathwarning;
1627 float checkrules_suddendeathend;
1628 float checkrules_overtimesadded; //how many overtimes have been already added
1629
1630 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1631 float WINNING_YES = 1; // winner found
1632 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1633 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1634
1635 float InitiateSuddenDeath()
1636 {
1637         // Check first whether normal overtimes could be added before initiating suddendeath mode
1638         // - for this timelimit_overtime needs to be >0 of course
1639         // - also check the winning condition calculated in the previous frame and only add normal overtime
1640         //   again, if at the point at which timelimit would be extended again, still no winner was found
1641         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1642         {
1643                 return 1; // need to call InitiateOvertime later
1644         }
1645         else
1646         {
1647                 if(!checkrules_suddendeathend)
1648                 {
1649                         if(autocvar_g_campaign)
1650                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1651                         else
1652                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1653                         if(g_race && !g_race_qualifying)
1654                                 race_StartCompleting();
1655                 }
1656                 return 0;
1657         }
1658 }
1659
1660 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1661 {
1662         ++checkrules_overtimesadded;
1663         //add one more overtime by simply extending the timelimit
1664         float tl;
1665         tl = autocvar_timelimit;
1666         tl += autocvar_timelimit_overtime;
1667         cvar_set("timelimit", ftos(tl));
1668
1669         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime);
1670 }
1671
1672 float GetWinningCode(float fraglimitreached, float equality)
1673 {
1674         if(autocvar_g_campaign == 1)
1675                 if(fraglimitreached)
1676                         return WINNING_YES;
1677                 else
1678                         return WINNING_NO;
1679
1680         else
1681                 if(equality)
1682                         if(fraglimitreached)
1683                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1684                         else
1685                                 return WINNING_NEVER;
1686                 else
1687                         if(fraglimitreached)
1688                                 return WINNING_YES;
1689                         else
1690                                 return WINNING_NO;
1691 }
1692
1693 // set the .winning flag for exactly those players with a given field value
1694 void SetWinners(.float field, float value)
1695 {
1696         entity head;
1697         FOR_EACH_PLAYER(head)
1698                 head.winning = (head.field == value);
1699 }
1700
1701 // set the .winning flag for those players with a given field value
1702 void AddWinners(.float field, float value)
1703 {
1704         entity head;
1705         FOR_EACH_PLAYER(head)
1706                 if(head.field == value)
1707                         head.winning = 1;
1708 }
1709
1710 // clear the .winning flags
1711 void ClearWinners(void)
1712 {
1713         entity head;
1714         FOR_EACH_PLAYER(head)
1715                 head.winning = 0;
1716 }
1717
1718 // Onslaught winning condition:
1719 // game terminates if only one team has a working generator (or none)
1720 float WinningCondition_Onslaught()
1721 {
1722         entity head;
1723         float t1, t2, t3, t4;
1724
1725         WinningConditionHelper(); // set worldstatus
1726
1727         if(inWarmupStage)
1728                 return WINNING_NO;
1729
1730         // first check if the game has ended
1731         t1 = t2 = t3 = t4 = 0;
1732         head = find(world, classname, "onslaught_generator");
1733         while (head)
1734         {
1735                 if (head.health > 0)
1736                 {
1737                         if (head.team == NUM_TEAM_1) t1 = 1;
1738                         if (head.team == NUM_TEAM_2) t2 = 1;
1739                         if (head.team == NUM_TEAM_3) t3 = 1;
1740                         if (head.team == NUM_TEAM_4) t4 = 1;
1741                 }
1742                 head = find(head, classname, "onslaught_generator");
1743         }
1744         if (t1 + t2 + t3 + t4 < 2)
1745         {
1746                 // game over, only one team remains (or none)
1747                 ClearWinners();
1748                 if (t1) SetWinners(team, NUM_TEAM_1);
1749                 if (t2) SetWinners(team, NUM_TEAM_2);
1750                 if (t3) SetWinners(team, NUM_TEAM_3);
1751                 if (t4) SetWinners(team, NUM_TEAM_4);
1752                 dprint("Have a winner, ending game.\n");
1753                 return WINNING_YES;
1754         }
1755
1756         // Two or more teams remain
1757         return WINNING_NO;
1758 }
1759
1760 float LMS_NewPlayerLives()
1761 {
1762         float fl;
1763         fl = autocvar_fraglimit;
1764         if(fl == 0)
1765                 fl = 999;
1766
1767         // first player has left the game for dying too much? Nobody else can get in.
1768         if(lms_lowest_lives < 1)
1769                 return 0;
1770
1771         if(!autocvar_g_lms_join_anytime)
1772                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
1773                         return 0;
1774
1775         return bound(1, lms_lowest_lives, fl);
1776 }
1777
1778 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1779 // they win. Otherwise the defending team wins once the timelimit passes.
1780 void assault_new_round();
1781 float WinningCondition_Assault()
1782 {
1783         float status;
1784
1785         WinningConditionHelper(); // set worldstatus
1786
1787         status = WINNING_NO;
1788         // as the timelimit has not yet passed just assume the defending team will win
1789         if(assault_attacker_team == NUM_TEAM_1)
1790         {
1791                 SetWinners(team, NUM_TEAM_2);
1792         }
1793         else
1794         {
1795                 SetWinners(team, NUM_TEAM_1);
1796         }
1797
1798         entity ent;
1799         ent = find(world, classname, "target_assault_roundend");
1800         if(ent)
1801         {
1802                 if(ent.winning) // round end has been triggered by attacking team
1803                 {
1804                         bprint("ASSAULT: round completed...\n");
1805                         SetWinners(team, assault_attacker_team);
1806
1807                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1808
1809                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1810                         {
1811                                 status = WINNING_YES;
1812                         }
1813                         else
1814                         {
1815                                 entity oldself;
1816                                 oldself = self;
1817                                 self = ent;
1818                                 assault_new_round();
1819                                 self = oldself;
1820                         }
1821                 }
1822         }
1823
1824         return status;
1825 }
1826
1827 // LMS winning condition: game terminates if and only if there's at most one
1828 // one player who's living lives. Top two scores being equal cancels the time
1829 // limit.
1830 float WinningCondition_LMS()
1831 {
1832         entity head, head2;
1833         float have_player;
1834         float have_players;
1835         float l;
1836
1837         have_player = FALSE;
1838         have_players = FALSE;
1839         l = LMS_NewPlayerLives();
1840
1841         head = find(world, classname, "player");
1842         if(head)
1843                 have_player = TRUE;
1844         head2 = find(head, classname, "player");
1845         if(head2)
1846                 have_players = TRUE;
1847
1848         if(have_player)
1849         {
1850                 // we have at least one player
1851                 if(have_players)
1852                 {
1853                         // two or more active players - continue with the game
1854                 }
1855                 else
1856                 {
1857                         // exactly one player?
1858
1859                         ClearWinners();
1860                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1861
1862                         if(l)
1863                         {
1864                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1865                                 return WINNING_NO;
1866                         }
1867                         else
1868                         {
1869                                 // a winner!
1870                                 // and assign him his first place
1871                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1872                                 return WINNING_YES;
1873                         }
1874                 }
1875         }
1876         else
1877         {
1878                 // nobody is playing at all...
1879                 if(l)
1880                 {
1881                         // wait for players...
1882                 }
1883                 else
1884                 {
1885                         // SNAFU (maybe a draw game?)
1886                         ClearWinners();
1887                         dprint("No players, ending game.\n");
1888                         return WINNING_YES;
1889                 }
1890         }
1891
1892         // When we get here, we have at least two players who are actually LIVING,
1893         // now check if the top two players have equal score.
1894         WinningConditionHelper();
1895
1896         ClearWinners();
1897         if(WinningConditionHelper_winner)
1898                 WinningConditionHelper_winner.winning = TRUE;
1899         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1900                 return WINNING_NEVER;
1901
1902         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1903         return WINNING_NO;
1904 }
1905
1906 void ShuffleMaplist()
1907 {
1908         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1909 }
1910
1911 float leaderfrags;
1912 float WinningCondition_Scores(float limit, float leadlimit)
1913 {
1914         float limitreached;
1915
1916         // TODO make everything use THIS winning condition (except LMS)
1917         WinningConditionHelper();
1918
1919         if(teamplay)
1920         {
1921                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1922                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1923                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1924                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1925         }
1926
1927         ClearWinners();
1928         if(WinningConditionHelper_winner)
1929                 WinningConditionHelper_winner.winning = 1;
1930         if(WinningConditionHelper_winnerteam >= 0)
1931                 SetWinners(team, WinningConditionHelper_winnerteam);
1932
1933         if(WinningConditionHelper_lowerisbetter)
1934         {
1935                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1936                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1937                 limit = -limit;
1938         }
1939
1940         if(WinningConditionHelper_zeroisworst)
1941                 leadlimit = 0; // not supported in this mode
1942
1943         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1944         // these modes always score in increments of 1, thus this makes sense
1945         {
1946                 if(leaderfrags != WinningConditionHelper_topscore)
1947                 {
1948                         leaderfrags = WinningConditionHelper_topscore;
1949
1950                         if (limit)
1951                         if (leaderfrags == limit - 1)
1952                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1953                         else if (leaderfrags == limit - 2)
1954                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1955                         else if (leaderfrags == limit - 3)
1956                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1957                 }
1958         }
1959
1960         limitreached = FALSE;
1961         if(limit)
1962                 if(WinningConditionHelper_topscore >= limit)
1963                         limitreached = TRUE;
1964         if(leadlimit)
1965         {
1966                 float leadlimitreached;
1967                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1968                 if(autocvar_leadlimit_and_fraglimit)
1969                         limitreached = (limitreached && leadlimitreached);
1970                 else
1971                         limitreached = (limitreached || leadlimitreached);
1972         }
1973
1974         if(limit)
1975                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1976
1977         return GetWinningCode(
1978                 WinningConditionHelper_topscore && limitreached,
1979                 WinningConditionHelper_equality
1980         );
1981 }
1982
1983 float WinningCondition_Race(float fraglimit)
1984 {
1985         float wc;
1986         entity p;
1987         float n, c;
1988
1989         n = 0;
1990         c = 0;
1991         FOR_EACH_PLAYER(p)
1992         {
1993                 ++n;
1994                 if(p.race_completed)
1995                         ++c;
1996         }
1997         if(n && (n == c))
1998                 return WINNING_YES;
1999         wc = WinningCondition_Scores(fraglimit, 0);
2000
2001         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2002         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2003         // do NOT support equality when the laps are all raced!
2004                 return WINNING_STARTSUDDENDEATHOVERTIME;
2005         else
2006                 return WINNING_NEVER;
2007 }
2008
2009 float WinningCondition_QualifyingThenRace(float limit)
2010 {
2011         float wc;
2012         wc = WinningCondition_Scores(limit, 0);
2013
2014         // NEVER initiate overtime
2015         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2016         {
2017                 return WINNING_YES;
2018         }
2019
2020         return wc;
2021 }
2022
2023 float WinningCondition_RanOutOfSpawns()
2024 {
2025         entity head;
2026
2027         if(have_team_spawns <= 0)
2028                 return WINNING_NO;
2029
2030         if(autocvar_g_spawn_useallspawns <= 0)
2031                 return WINNING_NO;
2032
2033         if(!some_spawn_has_been_used)
2034                 return WINNING_NO;
2035
2036         team1_score = team2_score = team3_score = team4_score = 0;
2037
2038         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2039         {
2040                 if(head.team == NUM_TEAM_1)
2041                         team1_score = 1;
2042                 else if(head.team == NUM_TEAM_2)
2043                         team2_score = 1;
2044                 else if(head.team == NUM_TEAM_3)
2045                         team3_score = 1;
2046                 else if(head.team == NUM_TEAM_4)
2047                         team4_score = 1;
2048         }
2049
2050         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2051         {
2052                 if(head.team == NUM_TEAM_1)
2053                         team1_score = 1;
2054                 else if(head.team == NUM_TEAM_2)
2055                         team2_score = 1;
2056                 else if(head.team == NUM_TEAM_3)
2057                         team3_score = 1;
2058                 else if(head.team == NUM_TEAM_4)
2059                         team4_score = 1;
2060         }
2061
2062         ClearWinners();
2063         if(team1_score + team2_score + team3_score + team4_score == 0)
2064         {
2065                 checkrules_equality = TRUE;
2066                 return WINNING_YES;
2067         }
2068         else if(team1_score + team2_score + team3_score + team4_score == 1)
2069         {
2070                 float t, i;
2071                 if(team1_score)
2072                         t = NUM_TEAM_1;
2073                 else if(team2_score)
2074                         t = NUM_TEAM_2;
2075                 else if(team3_score)
2076                         t = NUM_TEAM_3;
2077                 else // if(team4_score)
2078                         t = NUM_TEAM_4;
2079                 CheckAllowedTeams(world);
2080                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2081                 {
2082                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
2083                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
2084                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
2085                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
2086                 }
2087
2088                 AddWinners(team, t);
2089                 return WINNING_YES;
2090         }
2091         else
2092                 return WINNING_NO;
2093 }
2094
2095 /*
2096 ============
2097 CheckRules_World
2098
2099 Exit deathmatch games upon conditions
2100 ============
2101 */
2102 void ReadyRestart();
2103 void CheckRules_World()
2104 {
2105         float timelimit;
2106         float fraglimit;
2107         float leadlimit;
2108
2109         VoteThink();
2110         MapVote_Think();
2111
2112         SetDefaultAlpha();
2113
2114         /*
2115         MapVote_Think should now do that part
2116         if (intermission_running)
2117                 if (time >= intermission_exittime + 60)
2118                 {
2119                         if(!DoNextMapOverride())
2120                                 GotoNextMap();
2121                         return;
2122                 }
2123         */
2124
2125         if (gameover)   // someone else quit the game already
2126         {
2127                 if(player_count == 0) // Nobody there? Then let's go to the next map
2128                         MapVote_Start();
2129                         // this will actually check the player count in the next frame
2130                         // again, but this shouldn't hurt
2131                 return;
2132         }
2133
2134         timelimit = autocvar_timelimit * 60;
2135         fraglimit = autocvar_fraglimit;
2136         leadlimit = autocvar_leadlimit;
2137
2138         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2139         {
2140                 if(timelimit > 0)
2141                         timelimit = 0; // timelimit is not made for warmup
2142                 if(fraglimit > 0)
2143                         fraglimit = 0; // no fraglimit for now
2144                 leadlimit = 0; // no leadlimit for now
2145         }
2146
2147         if(timelimit > 0)
2148         {
2149                 timelimit += game_starttime;
2150         }
2151         else if (timelimit < 0)
2152         {
2153                 // endmatch
2154                 NextLevel();
2155                 return;
2156         }
2157
2158         if(g_onslaught)
2159                 timelimit = 0; // ONS has its own overtime rule
2160
2161         float wantovertime;
2162         wantovertime = 0;
2163
2164         if(timelimit > game_starttime)
2165                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2166         else
2167                 game_completion_ratio = 0;
2168
2169         if(checkrules_suddendeathend)
2170         {
2171                 if(!checkrules_suddendeathwarning)
2172                 {
2173                         checkrules_suddendeathwarning = TRUE;
2174                         if(g_race && !g_race_qualifying)
2175                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2176                         else
2177                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2178                 }
2179         }
2180         else
2181         {
2182                 if (timelimit && time >= timelimit)
2183                 {
2184                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2185                         {
2186                                 float totalplayers;
2187                                 float playerswithlaps;
2188                                 float readyplayers;
2189                                 entity head;
2190                                 totalplayers = playerswithlaps = readyplayers = 0;
2191                                 FOR_EACH_PLAYER(head)
2192                                 {
2193                                         ++totalplayers;
2194                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2195                                                 ++playerswithlaps;
2196                                         if(head.ready)
2197                                                 ++readyplayers;
2198                                 }
2199
2200                                 // at least 2 of the players have completed a lap: start the RACE
2201                                 // otherwise, the players should end the qualifying on their own
2202                                 if(readyplayers || playerswithlaps >= 2)
2203                                 {
2204                                         checkrules_suddendeathend = 0;
2205                                         ReadyRestart(); // go to race
2206                                         return;
2207                                 }
2208                                 else
2209                                         wantovertime |= InitiateSuddenDeath();
2210                         }
2211                         else
2212                                 wantovertime |= InitiateSuddenDeath();
2213                 }
2214         }
2215
2216         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2217         {
2218                 NextLevel();
2219                 return;
2220         }
2221
2222         float checkrules_status;
2223         checkrules_status = WinningCondition_RanOutOfSpawns();
2224         if(checkrules_status == WINNING_YES)
2225         {
2226                 bprint("Hey! Someone ran out of spawns!\n");
2227         }
2228         else if(g_race && !g_race_qualifying && timelimit >= 0)
2229         {
2230                 checkrules_status = WinningCondition_Race(fraglimit);
2231                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2232         }
2233         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2234         {
2235                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2236                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2237         }
2238         else if(g_assault)
2239         {
2240                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2241         }
2242         else if(g_lms)
2243         {
2244                 checkrules_status = WinningCondition_LMS();
2245         }
2246         else if (g_onslaught)
2247         {
2248                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2249         }
2250         else
2251         {
2252                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2253                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2254         }
2255
2256         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2257         {
2258                 checkrules_status = WINNING_NEVER;
2259                 checkrules_overtimesadded = -1;
2260                 wantovertime |= InitiateSuddenDeath();
2261         }
2262
2263         if(checkrules_status == WINNING_NEVER)
2264                 // equality cases! Nobody wins if the overtime ends in a draw.
2265                 ClearWinners();
2266
2267         if(wantovertime)
2268         {
2269                 if(checkrules_status == WINNING_NEVER)
2270                         InitiateOvertime();
2271                 else
2272                         checkrules_status = WINNING_YES;
2273         }
2274
2275         if(checkrules_suddendeathend)
2276                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2277                         checkrules_status = WINNING_YES;
2278
2279         if(checkrules_status == WINNING_YES)
2280         {
2281                 //print("WINNING\n");
2282                 NextLevel();
2283         }
2284 }
2285
2286 float mapvote_nextthink;
2287 float mapvote_initialized;
2288 float mapvote_keeptwotime;
2289 float mapvote_timeout;
2290 string mapvote_message;
2291 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2292 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2293 float mapvote_screenshot_dirs_count;
2294
2295 float mapvote_count;
2296 float mapvote_count_real;
2297 string mapvote_maps[MAPVOTE_COUNT];
2298 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2299 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2300 float mapvote_maps_suggested[MAPVOTE_COUNT];
2301 string mapvote_suggestions[MAPVOTE_COUNT];
2302 float mapvote_suggestion_ptr;
2303 float mapvote_voters;
2304 float mapvote_selections[MAPVOTE_COUNT];
2305 float mapvote_run;
2306 float mapvote_detail;
2307 float mapvote_abstain;
2308 .float mapvote;
2309
2310 void MapVote_ClearAllVotes()
2311 {
2312         FOR_EACH_CLIENT(other)
2313                 other.mapvote = 0;
2314 }
2315
2316 string MapVote_Suggest(string m)
2317 {
2318         float i;
2319         if(m == "")
2320                 return "That's not how to use this command.";
2321         if(!autocvar_g_maplist_votable_suggestions)
2322                 return "Suggestions are not accepted on this server.";
2323         if(mapvote_initialized)
2324                 return "Can't suggest - voting is already in progress!";
2325         m = MapInfo_FixName(m);
2326         if not(m)
2327                 return "The map you suggested is not available on this server.";
2328         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2329                 if(Map_IsRecent(m))
2330                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2331
2332         if(!MapInfo_CheckMap(m))
2333                 return "The map you suggested does not support the current game mode.";
2334         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2335                 if(mapvote_suggestions[i] == m)
2336                         return "This map was already suggested.";
2337         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2338         {
2339                 i = floor(random() * mapvote_suggestion_ptr);
2340         }
2341         else
2342         {
2343                 i = mapvote_suggestion_ptr;
2344                 mapvote_suggestion_ptr += 1;
2345         }
2346         if(mapvote_suggestions[i] != "")
2347                 strunzone(mapvote_suggestions[i]);
2348         mapvote_suggestions[i] = strzone(m);
2349         if(autocvar_sv_eventlog)
2350                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2351         return strcat("Suggestion of ", m, " accepted.");
2352 }
2353
2354 void MapVote_AddVotable(string nextMap, float isSuggestion)
2355 {
2356         float j, i, o;
2357         string pakfile, mapfile;
2358
2359         if(nextMap == "")
2360                 return;
2361         for(j = 0; j < mapvote_count; ++j)
2362                 if(mapvote_maps[j] == nextMap)
2363                         return;
2364         // suggestions might be no longer valid/allowed after gametype switch!
2365         if(isSuggestion)
2366                 if(!MapInfo_CheckMap(nextMap))
2367                         return;
2368         mapvote_maps[mapvote_count] = strzone(nextMap);
2369         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2370
2371         pakfile = string_null;
2372         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2373         {
2374                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2375                 pakfile = whichpack(strcat(mapfile, ".tga"));
2376                 if(pakfile == "")
2377                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2378                 if(pakfile == "")
2379                         pakfile = whichpack(strcat(mapfile, ".png"));
2380                 if(pakfile != "")
2381                         break;
2382         }
2383         if(i >= mapvote_screenshot_dirs_count)
2384                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2385         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2386                 pakfile = substring(pakfile, o, -1);
2387
2388         mapvote_maps_screenshot_dir[mapvote_count] = i;
2389         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2390
2391         mapvote_count += 1;
2392 }
2393
2394 void MapVote_Spawn();
2395 void MapVote_Init()
2396 {
2397         float i;
2398         float nmax, smax;
2399
2400         MapVote_ClearAllVotes();
2401
2402         mapvote_count = 0;
2403         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2404         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2405
2406         if(mapvote_abstain)
2407                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2408         else
2409                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2410         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2411
2412         // we need this for AddVotable, as that cycles through the screenshot dirs
2413         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2414         if(mapvote_screenshot_dirs_count == 0)
2415                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2416         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2417         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2418                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2419
2420         if(mapvote_suggestion_ptr)
2421                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2422                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2423
2424         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2425                 MapVote_AddVotable(GetNextMap(), FALSE);
2426
2427         if(mapvote_count == 0)
2428         {
2429                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2430                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2431                 if(autocvar_g_maplist_shuffle)
2432                         ShuffleMaplist();
2433                 localcmd("\nmenu_cmd sync\n");
2434                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2435                         MapVote_AddVotable(GetNextMap(), FALSE);
2436         }
2437
2438         mapvote_count_real = mapvote_count;
2439         if(mapvote_abstain)
2440                 MapVote_AddVotable("don't care", 0);
2441
2442         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2443
2444         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2445         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2446         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2447                 mapvote_keeptwotime = 0;
2448         mapvote_message = "Choose a map and press its key!";
2449
2450         MapVote_Spawn();
2451 }
2452
2453 void MapVote_SendPicture(float id)
2454 {
2455         msg_entity = self;
2456         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2457         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2458         WriteByte(MSG_ONE, id);
2459         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2460 }
2461
2462 float MapVote_GetMapMask()
2463 {
2464         float mask, i, power;
2465         mask = 0;
2466         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2467                 if(mapvote_maps[i] != "")
2468                         mask |= power;
2469         return mask;
2470 }
2471
2472 entity mapvote_ent;
2473 float MapVote_SendEntity(entity to, float sf)
2474 {
2475         float i;
2476
2477         if(sf & 1)
2478                 sf &~= 2; // if we send 1, we don't need to also send 2
2479
2480         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2481         WriteByte(MSG_ENTITY, sf);
2482
2483         if(sf & 1)
2484         {
2485                 // flag 1 == initialization
2486                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2487                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2488                 WriteString(MSG_ENTITY, "");
2489                 WriteByte(MSG_ENTITY, mapvote_count);
2490                 WriteByte(MSG_ENTITY, mapvote_abstain);
2491                 WriteByte(MSG_ENTITY, mapvote_detail);
2492                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2493                 if(mapvote_count <= 8)
2494                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2495                 else
2496                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2497                 for(i = 0; i < mapvote_count; ++i)
2498                         if(mapvote_maps[i] != "")
2499                         {
2500                                 if(mapvote_abstain && i == mapvote_count - 1)
2501                                 {
2502                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2503                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2504                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2505                                 }
2506                                 else
2507                                 {
2508                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2509                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2510                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2511                                 }
2512                         }
2513         }
2514
2515         if(sf & 2)
2516         {
2517                 // flag 2 == update of mask
2518                 if(mapvote_count <= 8)
2519                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2520                 else
2521                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2522         }
2523
2524         if(sf & 4)
2525         {
2526                 if(mapvote_detail)
2527                         for(i = 0; i < mapvote_count; ++i)
2528                                 if(mapvote_maps[i] != "")
2529                                         WriteByte(MSG_ENTITY, mapvote_selections[i]);
2530
2531                 WriteByte(MSG_ENTITY, to.mapvote);
2532         }
2533
2534         return TRUE;
2535 }
2536
2537 void MapVote_Spawn()
2538 {
2539         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2540 }
2541
2542 void MapVote_TouchMask()
2543 {
2544         mapvote_ent.SendFlags |= 2;
2545 }
2546
2547 void MapVote_TouchVotes(entity voter)
2548 {
2549         mapvote_ent.SendFlags |= 4;
2550 }
2551
2552 float MapVote_Finished(float mappos)
2553 {
2554         string result;
2555         float i;
2556         float didntvote;
2557
2558         if(autocvar_sv_eventlog)
2559         {
2560                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2561                 result = strcat(result, ":", ftos(mapvote_selections[mappos]), "::");
2562                 didntvote = mapvote_voters;
2563                 for(i = 0; i < mapvote_count; ++i)
2564                         if(mapvote_maps[i] != "")
2565                         {
2566                                 didntvote -= mapvote_selections[i];
2567                                 if(i != mappos)
2568                                 {
2569                                         result = strcat(result, ":", mapvote_maps[i]);
2570                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2571                                 }
2572                         }
2573                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2574
2575                 GameLogEcho(result);
2576                 if(mapvote_maps_suggested[mappos])
2577                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2578         }
2579
2580         FOR_EACH_REALCLIENT(other)
2581                 FixClientCvars(other);
2582
2583         Map_Goto_SetStr(mapvote_maps[mappos]);
2584         Map_Goto(0);
2585         alreadychangedlevel = TRUE;
2586         return TRUE;
2587 }
2588 void MapVote_CheckRules_1()
2589 {
2590         float i;
2591
2592         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2593         {
2594                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2595                 mapvote_selections[i] = 0;
2596         }
2597
2598         mapvote_voters = 0;
2599         FOR_EACH_REALCLIENT(other)
2600         {
2601                 ++mapvote_voters;
2602                 if(other.mapvote)
2603                 {
2604                         i = other.mapvote - 1;
2605                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2606                         mapvote_selections[i] = mapvote_selections[i] + 1;
2607                 }
2608         }
2609 }
2610
2611 float MapVote_CheckRules_2()
2612 {
2613         float i;
2614         float firstPlace, secondPlace;
2615         float firstPlaceVotes, secondPlaceVotes;
2616         float mapvote_voters_real;
2617         string result;
2618
2619         if(mapvote_count_real == 1)
2620                 return MapVote_Finished(0);
2621
2622         mapvote_voters_real = mapvote_voters;
2623         if(mapvote_abstain)
2624                 mapvote_voters_real -= mapvote_selections[mapvote_count - 1];
2625
2626         RandomSelection_Init();
2627         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2628                 RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2629         firstPlace = RandomSelection_chosen_float;
2630         firstPlaceVotes = RandomSelection_best_priority;
2631         //dprint("First place: ", ftos(firstPlace), "\n");
2632         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2633
2634         RandomSelection_Init();
2635         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2636                 if(i != firstPlace)
2637                         RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2638         secondPlace = RandomSelection_chosen_float;
2639         secondPlaceVotes = RandomSelection_best_priority;
2640         //dprint("Second place: ", ftos(secondPlace), "\n");
2641         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2642
2643         if(firstPlace == -1)
2644                 error("No first place in map vote... WTF?");
2645
2646         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2647                 return MapVote_Finished(firstPlace);
2648
2649         if(mapvote_keeptwotime)
2650                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2651                 {
2652                         float didntvote;
2653                         MapVote_TouchMask();
2654                         mapvote_message = "Now decide between the TOP TWO!";
2655                         mapvote_keeptwotime = 0;
2656                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2657                         result = strcat(result, ":", ftos(firstPlaceVotes));
2658                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2659                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2660                         didntvote = mapvote_voters;
2661                         for(i = 0; i < mapvote_count; ++i)
2662                                 if(mapvote_maps[i] != "")
2663                                 {
2664                                         didntvote -= mapvote_selections[i];
2665                                         if(i != firstPlace)
2666                                                 if(i != secondPlace)
2667                                                 {
2668                                                         result = strcat(result, ":", mapvote_maps[i]);
2669                                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2670                                                         if(i < mapvote_count_real)
2671                                                         {
2672                                                                 strunzone(mapvote_maps[i]);
2673                                                                 mapvote_maps[i] = "";
2674                                                                 strunzone(mapvote_maps_pakfile[i]);
2675                                                                 mapvote_maps_pakfile[i] = "";
2676                                                         }
2677                                                 }
2678                                 }
2679                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2680                         if(autocvar_sv_eventlog)
2681                                 GameLogEcho(result);
2682                 }
2683
2684         return FALSE;
2685 }
2686 void MapVote_Tick()
2687 {
2688         float keeptwo;
2689         float totalvotes;
2690
2691         keeptwo = mapvote_keeptwotime;
2692         MapVote_CheckRules_1(); // count
2693         if(MapVote_CheckRules_2()) // decide
2694                 return;
2695
2696         totalvotes = 0;
2697         FOR_EACH_REALCLIENT(other)
2698         {
2699                 // hide scoreboard again
2700                 if(other.health != 2342)
2701                 {
2702                         other.health = 2342;
2703                         other.impulse = 0;
2704                         if(clienttype(other) == CLIENTTYPE_REAL)
2705                         {
2706                                 msg_entity = other;
2707                                 WriteByte(MSG_ONE, SVC_FINALE);
2708                                 WriteString(MSG_ONE, "");
2709                         }
2710                 }
2711
2712                 // clear possibly invalid votes
2713                 if(mapvote_maps[other.mapvote - 1] == "")
2714                         other.mapvote = 0;
2715                 // use impulses as new vote
2716                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2717                         if(mapvote_maps[other.impulse - 1] != "")
2718                         {
2719                                 other.mapvote = other.impulse;
2720                                 MapVote_TouchVotes(other);
2721                         }
2722                 other.impulse = 0;
2723
2724                 if(other.mapvote)
2725                         ++totalvotes;
2726         }
2727
2728         MapVote_CheckRules_1(); // just count
2729 }
2730 void MapVote_Start()
2731 {
2732         if(mapvote_run)
2733                 return;
2734
2735         // wait for stats to be sent first
2736         if(!playerstats_waitforme)
2737                 return;
2738
2739         MapInfo_Enumerate();
2740         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2741                 mapvote_run = TRUE;
2742 }
2743 void MapVote_Think()
2744 {
2745         if(!mapvote_run)
2746                 return;
2747
2748         if(alreadychangedlevel)
2749                 return;
2750
2751         if(time < mapvote_nextthink)
2752                 return;
2753         //dprint("tick\n");
2754
2755         mapvote_nextthink = time + 0.5;
2756
2757         if(!mapvote_initialized)
2758         {
2759                 if(autocvar_rescan_pending == 1)
2760                 {
2761                         cvar_set("rescan_pending", "2");
2762                         localcmd("fs_rescan\nrescan_pending 3\n");
2763                         return;
2764                 }
2765                 else if(autocvar_rescan_pending == 2)
2766                 {
2767                         return;
2768                 }
2769                 else if(autocvar_rescan_pending == 3)
2770                 {
2771                         // now build missing mapinfo files
2772                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2773                                 return;
2774
2775                         // we're done, start the timer
2776                         cvar_set("rescan_pending", "0");
2777                 }
2778
2779                 mapvote_initialized = TRUE;
2780                 if(DoNextMapOverride(0))
2781                         return;
2782                 if(!autocvar_g_maplist_votable || player_count <= 0)
2783                 {
2784                         GotoNextMap(0);
2785                         return;
2786                 }
2787                 MapVote_Init();
2788         }
2789
2790         MapVote_Tick();
2791 }
2792
2793 string GotoMap(string m)
2794 {
2795         if(!MapInfo_CheckMap(m))
2796                 return "The map you chose is not available on this server.";
2797         cvar_set("nextmap", m);
2798         cvar_set("timelimit", "-1");
2799         if(mapvote_initialized || alreadychangedlevel)
2800         {
2801                 if(DoNextMapOverride(0))
2802                         return "Map switch initiated.";
2803                 else
2804                         return "Hm... no. For some reason I like THIS map more.";
2805         }
2806         else
2807                 return "Map switch will happen after scoreboard.";
2808 }
2809
2810
2811 void EndFrame()
2812 {
2813         float altime;
2814         FOR_EACH_REALCLIENT(self)
2815         {
2816                 if(self.classname == "spectator")
2817                 {
2818                         if(self.enemy.typehitsound)
2819                                 self.typehit_time = time;
2820                         else if(self.enemy.hitsound)
2821                                 self.hit_time = time;
2822                 }
2823                 else
2824                 {
2825                         if(self.typehitsound)
2826                                 self.typehit_time = time;
2827                         else if(self.hitsound)
2828                                 self.hit_time = time;
2829                 }
2830         }
2831         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2832         // add 1 frametime because after this, engine SV_Physics
2833         // increases time by a frametime and then networks the frame
2834         // add another frametime because client shows everything with
2835         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2836         // needed!
2837         FOR_EACH_CLIENT(self)
2838         {
2839                 self.hitsound = FALSE;
2840                 self.typehitsound = FALSE;
2841                 antilag_record(self, altime);
2842         }
2843 }
2844
2845
2846 /*
2847  * RedirectionThink:
2848  * returns TRUE if redirecting
2849  */
2850 float redirection_timeout;
2851 float redirection_nextthink;
2852 float RedirectionThink()
2853 {
2854         float clients_found;
2855
2856         if(redirection_target == "")
2857                 return FALSE;
2858
2859         if(!redirection_timeout)
2860         {
2861                 cvar_set("sv_public", "-2");
2862                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2863                 if(redirection_target == "self")
2864                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2865                 else
2866                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2867         }
2868
2869         if(time < redirection_nextthink)
2870                 return TRUE;
2871
2872         redirection_nextthink = time + 1;
2873
2874         clients_found = 0;
2875         FOR_EACH_REALCLIENT(self)
2876         {
2877                 // TODO add timer
2878                 print("Redirecting: sending connect command to ", self.netname, "\n");
2879                 if(redirection_target == "self")
2880                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2881                 else
2882                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2883                 ++clients_found;
2884         }
2885
2886         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2887
2888         if(time > redirection_timeout || clients_found == 0)
2889                 localcmd("\nwait; wait; wait; quit\n");
2890
2891         return TRUE;
2892 }
2893
2894 void TargetMusic_RestoreGame();
2895 void RestoreGame()
2896 {
2897         // Loaded from a save game
2898         // some things then break, so let's work around them...
2899
2900         // Progs DB (capture records)
2901         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2902
2903         // Mapinfo
2904         MapInfo_Shutdown();
2905         MapInfo_Enumerate();
2906         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2907         WeaponStats_Init();
2908
2909         TargetMusic_RestoreGame();
2910 }
2911
2912 void Shutdown()
2913 {
2914         entity e;
2915
2916         gameover = 2;
2917
2918         if(world_initialized > 0)
2919         {
2920                 world_initialized = 0;
2921                 print("Saving persistent data...\n");
2922                 Ban_SaveBans();
2923
2924                 PlayerStats_EndMatch(0);
2925                 FOR_EACH_CLIENT(e)
2926                         PlayerStats_AddGlobalInfo(e);
2927                 PlayerStats_Shutdown();
2928
2929                 if(!cheatcount_total)
2930                 {
2931                         if(autocvar_sv_db_saveasdump)
2932                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2933                         else
2934                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2935                 }
2936                 if(autocvar_developer)
2937                 {
2938                         if(autocvar_sv_db_saveasdump)
2939                                 db_dump(TemporaryDB, "server-temp.db");
2940                         else
2941                                 db_save(TemporaryDB, "server-temp.db");
2942                 }
2943                 CheatShutdown(); // must be after cheatcount check
2944                 db_close(ServerProgsDB);
2945                 db_close(TemporaryDB);
2946                 print("done!\n");
2947                 // tell the bot system the game is ending now
2948                 bot_endgame();
2949
2950                 WeaponStats_Shutdown();
2951                 MapInfo_Shutdown();
2952         }
2953         else if(world_initialized == 0)
2954         {
2955                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2956         }
2957 }