qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2
   3 #include "anticheat.qh"
   4 #include "antilag.qh"
   5 #include "bot/bot.qh"
   6 #include "campaign.qh"
   7 #include "cheats.qh"
   8 #include "cl_client.qh"
   9 #include "command/common.qh"
  10 #include "command/getreplies.qh"
  11 #include "command/sv_cmd.qh"
  12 #include "command/vote.qh"
  13 #include "g_hook.qh"
  14 #include "ipban.qh"
  15 #include "mapvoting.qh"
  16 #include "mutators/all.qh"
  17 #include "race.qh"
  18 #include "scores.qh"
  19 #include "teamplay.qh"
  20 #include "weapons/weaponstats.qh"
  21 #include "../common/constants.qh"
  22 #include "../common/deathtypes/all.qh"
  23 #include "../common/mapinfo.qh"
  24 #include "../common/monsters/all.qh"
  25 #include "../common/monsters/sv_monsters.qh"
  26 #include "../common/vehicles/all.qh"
  27 #include "../common/notifications.qh"
  28 #include "../common/physics/player.qh"
  29 #include "../common/playerstats.qh"
  30 #include "../common/stats.qh"
  31 #include "../common/teams.qh"
  32 #include "../common/triggers/trigger/secret.qh"
  33 #include "../common/triggers/target/music.qh"
  34 #include "../common/util.qh"
  35 #include "../common/items/all.qh"
  36 #include "../common/weapons/all.qh"
  37
  38 const float LATENCY_THINKRATE = 10;
  39 .float latency_sum;
  40 .float latency_cnt;
  41 .float latency_time;
  42 entity pingplreport;
  43 void PingPLReport_Think()
  44 {SELFPARAM();
  45         float delta;
  46         entity e;
  47
  48         delta = 3 / maxclients;
  49         if(delta < sys_frametime)
  50                 delta = 0;
  51         self.nextthink = time + delta;
  52
  53         e = edict_num(self.cnt + 1);
  54         if(IS_REAL_CLIENT(e))
  55         {
  56                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  57                 WriteByte(MSG_BROADCAST, self.cnt);
  58                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  59                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  60                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  61
  62                 // record latency times for clients throughout the match so we can report it to playerstats
  63                 if(time > (e.latency_time + LATENCY_THINKRATE))
  64                 {
  65                         e.latency_sum += e.ping;
  66                         e.latency_cnt += 1;
  67                         e.latency_time = time;
  68                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  69                 }
  70         }
  71         else
  72         {
  73                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  74                 WriteByte(MSG_BROADCAST, self.cnt);
  75                 WriteShort(MSG_BROADCAST, 0);
  76                 WriteByte(MSG_BROADCAST, 0);
  77                 WriteByte(MSG_BROADCAST, 0);
  78         }
  79         self.cnt = (self.cnt + 1) % maxclients;
  80 }
  81 void PingPLReport_Spawn()
  82 {
  83         pingplreport = new(pingplreport);
  84         make_pure(pingplreport);
  85         pingplreport.think = PingPLReport_Think;
  86         pingplreport.nextthink = time;
  87 }
  88
  89 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  90 string redirection_target;
  91 float world_initialized;
  92
  93 string GetGametype();
  94 void ShuffleMaplist();
  95
  96 void SetDefaultAlpha()
  97 {
  98         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
  99         {
 100                 default_player_alpha = autocvar_g_player_alpha;
 101                 if(default_player_alpha == 0)
 102                         default_player_alpha = 1;
 103                 default_weapon_alpha = default_player_alpha;
 104         }
 105 }
 106
 107 void GotoFirstMap()
 108 {SELFPARAM();
 109         float n;
 110         if(autocvar__sv_init)
 111         {
 112                 // cvar_set("_sv_init", "0");
 113                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 114                 // to this "init" map on a dedicated server will cause no permanent
 115                 // harm
 116                 if(autocvar_g_maplist_shuffle)
 117                         ShuffleMaplist();
 118                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 119                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 120
 121                 MapInfo_Enumerate();
 122                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 123
 124                 if(!DoNextMapOverride(1))
 125                         GotoNextMap(1);
 126
 127                 return;
 128         }
 129
 130         if(time < 5)
 131         {
 132                 self.nextthink = time;
 133         }
 134         else
 135         {
 136                 self.nextthink = time + 1;
 137                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 138         }
 139 }
 140
 141 void cvar_changes_init()
 142 {
 143         float h;
 144         string k, v, d;
 145         float n, i, adding, pureadding;
 146
 147         if(cvar_changes)
 148                 strunzone(cvar_changes);
 149         cvar_changes = string_null;
 150         if(cvar_purechanges)
 151                 strunzone(cvar_purechanges);
 152         cvar_purechanges = string_null;
 153         cvar_purechanges_count = 0;
 154
 155         h = buf_create();
 156         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 157         n = buf_getsize(h);
 158
 159         adding = true;
 160         pureadding = true;
 161
 162         for(i = 0; i < n; ++i)
 163         {
 164                 k = bufstr_get(h, i);
 165
 166 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 167 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 168 #define BADCVAR(p) if(k == p) continue
 169
 170                 // general excludes and namespaces for server admin used cvars
 171                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 172
 173                 // internal
 174                 BADPREFIX("csqc_");
 175                 BADPREFIX("cvar_check_");
 176                 BADCVAR("gamecfg");
 177                 BADCVAR("g_configversion");
 178                 BADCVAR("g_maplist_index");
 179                 BADCVAR("halflifebsp");
 180                 BADCVAR("sv_mapformat_is_quake2");
 181                 BADCVAR("sv_mapformat_is_quake3");
 182                 BADPREFIX("sv_world");
 183
 184                 // client
 185                 BADPREFIX("chase_");
 186                 BADPREFIX("cl_");
 187                 BADPREFIX("con_");
 188                 BADPREFIX("scoreboard_");
 189                 BADPREFIX("g_campaign");
 190                 BADPREFIX("g_waypointsprite_");
 191                 BADPREFIX("gl_");
 192                 BADPREFIX("joy");
 193                 BADPREFIX("hud_");
 194                 BADPREFIX("m_");
 195                 BADPREFIX("menu_");
 196                 BADPREFIX("net_slist_");
 197                 BADPREFIX("r_");
 198                 BADPREFIX("sbar_");
 199                 BADPREFIX("scr_");
 200                 BADPREFIX("snd_");
 201                 BADPREFIX("show");
 202                 BADPREFIX("sensitivity");
 203                 BADPREFIX("userbind");
 204                 BADPREFIX("v_");
 205                 BADPREFIX("vid_");
 206                 BADPREFIX("crosshair");
 207                 BADCVAR("mod_q3bsp_lightmapmergepower");
 208                 BADCVAR("mod_q3bsp_nolightmaps");
 209                 BADCVAR("fov");
 210                 BADCVAR("mastervolume");
 211                 BADCVAR("volume");
 212                 BADCVAR("bgmvolume");
 213
 214                 // private
 215                 BADCVAR("developer");
 216                 BADCVAR("log_dest_udp");
 217                 BADCVAR("net_address");
 218                 BADCVAR("net_address_ipv6");
 219                 BADCVAR("port");
 220                 BADCVAR("savedgamecfg");
 221                 BADCVAR("serverconfig");
 222                 BADCVAR("sv_autoscreenshot");
 223                 BADCVAR("sv_heartbeatperiod");
 224                 BADCVAR("sv_vote_master_password");
 225                 BADCVAR("sys_colortranslation");
 226                 BADCVAR("sys_specialcharactertranslation");
 227                 BADCVAR("timeformat");
 228                 BADCVAR("timestamps");
 229                 BADPREFIX("developer_");
 230                 BADPREFIX("g_ban_");
 231                 BADPREFIX("g_banned_list");
 232                 BADPREFIX("g_chat_flood_");
 233                 BADPREFIX("g_ghost_items");
 234                 BADPREFIX("g_playerstats_");
 235                 BADPREFIX("g_respawn_ghosts");
 236                 BADPREFIX("g_voice_flood_");
 237                 BADPREFIX("log_file");
 238                 BADPREFIX("rcon_");
 239                 BADPREFIX("sv_allowdownloads");
 240                 BADPREFIX("sv_autodemo");
 241                 BADPREFIX("sv_curl_");
 242                 BADPREFIX("sv_eventlog");
 243                 BADPREFIX("sv_logscores_");
 244                 BADPREFIX("sv_master");
 245                 BADPREFIX("sv_weaponstats_");
 246                 BADPREFIX("sv_waypointsprite_");
 247                 BADCVAR("rescan_pending");
 248
 249                 // these can contain player IDs, so better hide
 250                 BADPREFIX("g_forced_team_");
 251
 252                 // mapinfo
 253                 BADCVAR("fraglimit");
 254                 BADCVAR("g_assault");
 255                 BADCVAR("g_ca");
 256                 BADCVAR("g_ca_teams");
 257                 BADCVAR("g_ctf");
 258                 BADCVAR("g_cts");
 259                 BADCVAR("g_dm");
 260                 BADCVAR("g_domination");
 261                 BADCVAR("g_domination_default_teams");
 262                 BADCVAR("g_freezetag");
 263                 BADCVAR("g_freezetag_teams");
 264                 BADCVAR("g_invasion_teams");
 265                 BADCVAR("g_keepaway");
 266                 BADCVAR("g_keyhunt");
 267                 BADCVAR("g_keyhunt_teams");
 268                 BADCVAR("g_lms");
 269                 BADCVAR("g_nexball");
 270                 BADCVAR("g_onslaught");
 271                 BADCVAR("g_race");
 272                 BADCVAR("g_race_qualifying_timelimit");
 273                 BADCVAR("g_tdm");
 274                 BADCVAR("g_tdm_teams");
 275                 BADCVAR("leadlimit");
 276                 BADCVAR("nextmap");
 277                 BADCVAR("teamplay");
 278                 BADCVAR("timelimit");
 279
 280                 // long
 281                 BADCVAR("hostname");
 282                 BADCVAR("g_maplist");
 283                 BADCVAR("g_maplist_mostrecent");
 284                 BADCVAR("sv_motd");
 285
 286                 v = cvar_string(k);
 287                 d = cvar_defstring(k);
 288                 if(v == d)
 289                         continue;
 290
 291                 if(adding)
 292                 {
 293                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 294                         if(strlen(cvar_changes) > 16384)
 295                         {
 296                                 cvar_changes = "// too many settings have been changed to show them here\n";
 297                                 adding = 0;
 298                         }
 299                 }
 300
 301                 // now check if the changes are actually gameplay relevant
 302
 303                 // does nothing visible
 304                 BADCVAR("captureleadlimit_override");
 305                 BADCVAR("g_balance_kill_delay");
 306                 BADCVAR("g_ca_point_limit");
 307                 BADCVAR("g_ca_point_leadlimit");
 308                 BADCVAR("g_ctf_captimerecord_always");
 309                 BADCVAR("g_ctf_flag_glowtrails");
 310                 BADCVAR("g_ctf_flag_pickup_verbosename");
 311                 BADCVAR("g_domination_point_leadlimit");
 312                 BADCVAR("g_forced_respawn");
 313                 BADCVAR("g_freezetag_point_limit");
 314                 BADCVAR("g_freezetag_point_leadlimit");
 315                 BADCVAR("g_keyhunt_point_leadlimit");
 316                 BADPREFIX("g_mod_");
 317                 BADCVAR("g_invasion_point_limit");
 318                 BADCVAR("g_nexball_goalleadlimit");
 319                 BADCVAR("g_tdm_point_limit");
 320                 BADCVAR("g_tdm_point_leadlimit");
 321                 BADCVAR("leadlimit_and_fraglimit");
 322                 BADCVAR("leadlimit_override");
 323                 BADCVAR("pausable");
 324                 BADCVAR("sv_allow_fullbright");
 325                 BADCVAR("sv_checkforpacketsduringsleep");
 326                 BADCVAR("sv_timeout");
 327                 BADPREFIX("sv_timeout_");
 328                 BADPREFIX("crypto_");
 329                 BADPREFIX("g_chat_");
 330                 BADPREFIX("g_ctf_captimerecord_");
 331                 BADPREFIX("g_maplist_votable_");
 332                 BADPREFIX("net_");
 333                 BADPREFIX("prvm_");
 334                 BADPREFIX("skill_");
 335                 BADPREFIX("sv_cullentities_");
 336                 BADPREFIX("sv_maxidle_");
 337                 BADPREFIX("sv_vote_");
 338                 BADPREFIX("timelimit_");
 339                 BADCVAR("gameversion");
 340                 BADPREFIX("gameversion_");
 341                 BADCVAR("sv_minigames");
 342                 BADPREFIX("sv_minigames_");
 343                 BADCVAR("sv_namechangetimer");
 344
 345                 // allowed changes to server admins (please sync this to server.cfg)
 346                 // vi commands:
 347                 //   :/"impure"/,$d
 348                 //   :g!,^\/\/[^ /],d
 349                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 350                 //   :%!sort
 351                 // yes, this does contain some redundant stuff, don't really care
 352                 BADCVAR("bot_config_file");
 353                 BADCVAR("bot_number");
 354                 BADCVAR("bot_prefix");
 355                 BADCVAR("bot_suffix");
 356                 BADCVAR("capturelimit_override");
 357                 BADCVAR("fraglimit_override");
 358                 BADCVAR("gametype");
 359                 BADCVAR("g_antilag");
 360                 BADCVAR("g_balance_teams");
 361                 BADCVAR("g_balance_teams_prevent_imbalance");
 362                 BADCVAR("g_balance_teams_scorefactor");
 363                 BADCVAR("g_ban_sync_trusted_servers");
 364                 BADCVAR("g_ban_sync_uri");
 365                 BADCVAR("g_ca_teams_override");
 366                 BADCVAR("g_ctf_ignore_frags");
 367                 BADCVAR("g_domination_point_limit");
 368                 BADCVAR("g_domination_teams_override");
 369                 BADCVAR("g_freezetag_teams_override");
 370                 BADCVAR("g_friendlyfire");
 371                 BADCVAR("g_fullbrightitems");
 372                 BADCVAR("g_fullbrightplayers");
 373                 BADCVAR("g_keyhunt_point_limit");
 374                 BADCVAR("g_keyhunt_teams_override");
 375                 BADCVAR("g_lms_lives_override");
 376                 BADCVAR("g_maplist");
 377                 BADCVAR("g_maplist_check_waypoints");
 378                 BADCVAR("g_maplist_mostrecent_count");
 379                 BADCVAR("g_maplist_shuffle");
 380                 BADCVAR("g_maplist_votable");
 381                 BADCVAR("g_maplist_votable_abstain");
 382                 BADCVAR("g_maplist_votable_nodetail");
 383                 BADCVAR("g_maplist_votable_suggestions");
 384                 BADCVAR("g_maxplayers");
 385                 BADCVAR("g_mirrordamage");
 386                 BADCVAR("g_nexball_goallimit");
 387                 BADCVAR("g_powerups");
 388                 BADCVAR("g_start_delay");
 389                 BADCVAR("g_tdm_teams_override");
 390                 BADCVAR("g_warmup");
 391                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 392                 BADCVAR("hostname");
 393                 BADCVAR("log_file");
 394                 BADCVAR("maxplayers");
 395                 BADCVAR("minplayers");
 396                 BADCVAR("net_address");
 397                 BADCVAR("port");
 398                 BADCVAR("rcon_password");
 399                 BADCVAR("rcon_restricted_commands");
 400                 BADCVAR("rcon_restricted_password");
 401                 BADCVAR("skill");
 402                 BADCVAR("sv_adminnick");
 403                 BADCVAR("sv_autoscreenshot");
 404                 BADCVAR("sv_autotaunt");
 405                 BADCVAR("sv_curl_defaulturl");
 406                 BADCVAR("sv_defaultcharacter");
 407                 BADCVAR("sv_defaultplayercolors");
 408                 BADCVAR("sv_defaultplayermodel");
 409                 BADCVAR("sv_defaultplayerskin");
 410                 BADCVAR("sv_maxidle");
 411                 BADCVAR("sv_maxrate");
 412                 BADCVAR("sv_motd");
 413                 BADCVAR("sv_public");
 414                 BADCVAR("sv_ready_restart");
 415                 BADCVAR("sv_status_privacy");
 416                 BADCVAR("sv_taunt");
 417                 BADCVAR("sv_vote_call");
 418                 BADCVAR("sv_vote_commands");
 419                 BADCVAR("sv_vote_majority_factor");
 420                 BADCVAR("sv_vote_master");
 421                 BADCVAR("sv_vote_master_commands");
 422                 BADCVAR("sv_vote_master_password");
 423                 BADCVAR("sv_vote_simple_majority_factor");
 424                 BADCVAR("teamplay_mode");
 425                 BADCVAR("timelimit_override");
 426                 BADCVAR("g_spawnshieldtime");
 427                 BADPREFIX("g_warmup_");
 428                 BADPREFIX("sv_ready_restart_");
 429
 430                 // mutators that announce themselves properly to the server browser
 431                 BADCVAR("g_instagib");
 432                 BADCVAR("g_new_toys");
 433                 BADCVAR("g_nix");
 434                 BADCVAR("g_grappling_hook");
 435                 BADCVAR("g_jetpack");
 436
 437 #undef BADPREFIX
 438 #undef BADCVAR
 439
 440                 if(pureadding)
 441                 {
 442                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 443                         if(strlen(cvar_purechanges) > 16384)
 444                         {
 445                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 446                                 pureadding = 0;
 447                         }
 448                 }
 449                 ++cvar_purechanges_count;
 450                 // WARNING: this variable is used for the server list
 451                 // NEVER dare to skip this code!
 452                 // Hacks to intentionally appearing as "pure server" even though you DO have
 453                 // modified settings may be punished by removal from the server list.
 454                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 455                 // though.
 456         }
 457         buf_del(h);
 458         if(cvar_changes == "")
 459                 cvar_changes = "// this server runs at default server settings\n";
 460         else
 461                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 462         cvar_changes = strzone(cvar_changes);
 463         if(cvar_purechanges == "")
 464                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 465         else
 466                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 467         cvar_purechanges = strzone(cvar_purechanges);
 468 }
 469
 470 void detect_maptype()
 471 {
 472 #if 0
 473         vector o, v;
 474         float i;
 475
 476         for (;;)
 477         {
 478                 o = world.mins;
 479                 o.x += random() * (world.maxs.x - world.mins.x);
 480                 o.y += random() * (world.maxs.y - world.mins.y);
 481                 o.z += random() * (world.maxs.z - world.mins.z);
 482
 483                 tracebox(o, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), o - '0 0 32768', MOVE_WORLDONLY, world);
 484                 if(trace_fraction == 1)
 485                         continue;
 486
 487                 v = trace_endpos;
 488
 489                 for(i = 0; i < 64; i += 4)
 490                 {
 491                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 492         if(trace_fraction == 1)
 493                 continue;
 494                         LOG_INFO(ftos(i), " -> ", vtos(trace_endpos), "\n");
 495                 }
 496
 497                 break;
 498         }
 499 #endif
 500 }
 501
 502 entity randomseed;
 503 bool RandomSeed_Send(entity this, entity to, int sf)
 504 {
 505         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 506         WriteShort(MSG_ENTITY, self.cnt);
 507         return true;
 508 }
 509 void RandomSeed_Think()
 510 {SELFPARAM();
 511         self.cnt = bound(0, floor(random() * 65536), 65535);
 512         self.nextthink = time + 5;
 513
 514         self.SendFlags |= 1;
 515 }
 516 void RandomSeed_Spawn()
 517 {SELFPARAM();
 518         randomseed = new(randomseed);
 519         make_pure(randomseed);
 520         randomseed.think = RandomSeed_Think;
 521         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 522
 523         WITH(entity, self, randomseed, randomseed.think()); // sets random seed and nextthink
 524 }
 525
 526 spawnfunc(__init_dedicated_server)
 527 {
 528         // handler for _init/_init map (only for dedicated server initialization)
 529
 530         world_initialized = -1; // don't complain
 531         cvar = cvar_normal;
 532         cvar_string = cvar_string_normal;
 533         cvar_set = cvar_set_normal;
 534
 535         remove = remove_unsafely;
 536
 537         entity e = spawn();
 538         e.think = GotoFirstMap;
 539         e.nextthink = time; // this is usually 1 at this point
 540
 541         e = new(info_player_deathmatch);  // safeguard against player joining
 542
 543         self.classname = "worldspawn"; // safeguard against various stuff ;)
 544
 545         // needs to be done so early because of the constants they create
 546         static_init();
 547         static_init_late();
 548         static_init_precache();
 549
 550         MapInfo_Enumerate();
 551         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 552 }
 553
 554 void __init_dedicated_server_shutdown() {
 555         MapInfo_Shutdown();
 556 }
 557
 558 void Map_MarkAsRecent(string m);
 559 float world_already_spawned;
 560 void Nagger_Init();
 561 void ClientInit_Spawn();
 562 void WeaponStats_Init();
 563 void WeaponStats_Shutdown();
 564 spawnfunc(worldspawn)
 565 {
 566         {
 567                 bool wantrestart = false;
 568                 // Try to use versioned csprogs from pk3
 569                 // Only ever use versioned csprogs.dat files on dedicated servers;
 570                 // we need to reset csqc_progname on clients ourselves, and it's easier if the client's release name is constant
 571                 string pk3csprogs = "csprogs-" WATERMARK ".dat";
 572                 if (cvar_string_normal("csqc_progname") != pk3csprogs && fexists(pk3csprogs))
 573                 {
 574                         cvar_set_normal("csqc_progname", pk3csprogs);
 575                         wantrestart = true;
 576                 }
 577                 // Check for updates on startup
 578                 // We do it this way for atomicity so that connecting clients still match the server progs and don't disconnect
 579                 int sentinel = fopen("progs.txt", FILE_READ);
 580                 if (sentinel >= 0)
 581                 {
 582                         string switchversion = fgets(sentinel);
 583                         fclose(sentinel);
 584                         if (switchversion != "" && switchversion != WATERMARK)
 585                         {
 586                                 LOG_INFOF("Switching progs: " WATERMARK " -> %s\n", switchversion);
 587                                 // if it doesn't exist, assume either:
 588                                 //   a) the current program was overwritten
 589                                 //   b) this is a client only update
 590                                 string newprogs = sprintf("progs-%s.dat", switchversion);
 591                                 if (fexists(newprogs))
 592                                 {
 593                                         cvar_set_normal("sv_progs", newprogs);
 594                                         wantrestart = true;
 595                                 }
 596                                 string newcsprogs = sprintf("csprogs-%s.dat", switchversion);
 597                                 if (fexists(newcsprogs))
 598                                 {
 599                                         cvar_set_normal("csqc_progname", newcsprogs);
 600                                         wantrestart = true;
 601                                 }
 602                         }
 603                 }
 604                 if (wantrestart) changelevel(mapname);
 605                 // let initialization continue, shutdown depends on it
 606         }
 607
 608         float fd, l;
 609         string s;
 610
 611         cvar = cvar_normal;
 612         cvar_string = cvar_string_normal;
 613         cvar_set = cvar_set_normal;
 614
 615         if(world_already_spawned)
 616                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 617         world_already_spawned = true;
 618
 619         remove = remove_safely; // during spawning, watch what you remove!
 620
 621         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 622
 623         compressShortVector_init();
 624
 625         maxclients = 0;
 626         for (entity head = nextent(world); head; head = nextent(head))
 627         {
 628                 ++maxclients;
 629         }
 630
 631         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? true : false);
 632
 633         // needs to be done so early because of the constants they create
 634         static_init();
 635
 636         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 637
 638         TemporaryDB = db_create();
 639
 640         // 0 normal
 641         lightstyle(0, "m");
 642
 643         // 1 FLICKER (first variety)
 644         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 645
 646         // 2 SLOW STRONG PULSE
 647         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 648
 649         // 3 CANDLE (first variety)
 650         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 651
 652         // 4 FAST STROBE
 653         lightstyle(4, "mamamamamama");
 654
 655         // 5 GENTLE PULSE 1
 656         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 657
 658         // 6 FLICKER (second variety)
 659         lightstyle(6, "nmonqnmomnmomomno");
 660
 661         // 7 CANDLE (second variety)
 662         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 663
 664         // 8 CANDLE (third variety)
 665         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 666
 667         // 9 SLOW STROBE (fourth variety)
 668         lightstyle(9, "aaaaaaaazzzzzzzz");
 669
 670         // 10 FLUORESCENT FLICKER
 671         lightstyle(10, "mmamammmmammamamaaamammma");
 672
 673         // 11 SLOW PULSE NOT FADE TO BLACK
 674         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 675
 676         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 677
 678         // 63 testing
 679         lightstyle(63, "a");
 680
 681         if(autocvar_g_campaign)
 682                 CampaignPreInit();
 683
 684         Map_MarkAsRecent(mapname);
 685
 686         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 687
 688         InitGameplayMode();
 689         static_init_late();
 690         static_init_precache();
 691         readlevelcvars();
 692         GrappleHookInit();
 693
 694         player_count = 0;
 695         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 696         if(bot_waypoints_for_items == 1)
 697                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 698                         bot_waypoints_for_items = 0;
 699
 700         precache();
 701
 702         WaypointSprite_Init();
 703
 704         GameLogInit(); // prepare everything
 705         // NOTE for matchid:
 706         // changing the logic generating it is okay. But:
 707         // it HAS to stay <= 64 chars
 708         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 709         if(autocvar_sv_eventlog)
 710         {
 711                 s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 712                 matchid = strzone(s);
 713
 714                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 715                 s = ":gameinfo:mutators:LIST";
 716
 717                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
 718                 s = ret_string;
 719
 720                 // initialiation stuff, not good in the mutator system
 721                 if(!autocvar_g_use_ammunition)
 722                         s = strcat(s, ":no_use_ammunition");
 723
 724                 // initialiation stuff, not good in the mutator system
 725                 if(autocvar_g_pickup_items == 0)
 726                         s = strcat(s, ":no_pickup_items");
 727                 if(autocvar_g_pickup_items > 0)
 728                         s = strcat(s, ":pickup_items");
 729
 730                 // initialiation stuff, not good in the mutator system
 731                 if(autocvar_g_weaponarena != "0")
 732                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 733
 734                 // TODO to mutator system
 735                 if(autocvar_g_norecoil)
 736                         s = strcat(s, ":norecoil");
 737
 738                 // TODO to mutator system
 739                 if(autocvar_g_powerups == 0)
 740                         s = strcat(s, ":no_powerups");
 741                 if(autocvar_g_powerups > 0)
 742                         s = strcat(s, ":powerups");
 743
 744                 GameLogEcho(s);
 745                 GameLogEcho(":gameinfo:end");
 746         }
 747         else
 748                 matchid = strzone(ftos(random()));
 749
 750         cvar_set("nextmap", "");
 751
 752         SetDefaultAlpha();
 753
 754         if(autocvar_g_campaign)
 755                 CampaignPostInit();
 756
 757         Ban_LoadBans();
 758
 759         MapInfo_Enumerate();
 760         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 761
 762         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 763         {
 764                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 765                 if(fd != -1)
 766                 {
 767                         while((s = fgets(fd)))
 768                         {
 769                                 l = tokenize_console(s);
 770                                 if(l < 2)
 771                                         continue;
 772                                 if(argv(0) == "cd")
 773                                 {
 774                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 775                                         LOG_INFO("  cdtrack ", argv(2), "\n");
 776                                 }
 777                                 else if(argv(0) == "fog")
 778                                 {
 779                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 780                                         LOG_INFO("  \"fog\" \"", s, "\"\n");
 781                                 }
 782                                 else if(argv(0) == "set")
 783                                 {
 784                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 785                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 786                                 }
 787                                 else if(argv(0) != "//")
 788                                 {
 789                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 790                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 791                                 }
 792                         }
 793                         fclose(fd);
 794                 }
 795         }
 796
 797         WeaponStats_Init();
 798
 799         Nagger_Init();
 800
 801         next_pingtime = time + 5;
 802
 803         detect_maptype();
 804
 805         // set up information replies for clients and server to use
 806         maplist_reply = strzone(getmaplist());
 807         lsmaps_reply = strzone(getlsmaps());
 808         monsterlist_reply = strzone(getmonsterlist());
 809         for(int i = 0; i < 10; ++i)
 810         {
 811                 s = getrecords(i);
 812                 if (s)
 813                         records_reply[i] = strzone(s);
 814         }
 815         ladder_reply = strzone(getladder());
 816         rankings_reply = strzone(getrankings());
 817
 818         // begin other init
 819         ClientInit_Spawn();
 820         RandomSeed_Spawn();
 821         PingPLReport_Spawn();
 822
 823         CheatInit();
 824
 825         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 826
 827         // force unloading of server pk3 files when starting a listen server
 828         if (!server_is_dedicated) localcmd("\nfs_rescan\n");
 829
 830         // fill sv_curl_serverpackages from .serverpackage files
 831         if (autocvar_sv_curl_serverpackages_auto)
 832         {
 833                 s = "csprogs-" WATERMARK ".txt";
 834                 // remove automatically managed files from the list to prevent duplicates
 835                 for (int i = 0, n = tokenize_console(cvar_string("sv_curl_serverpackages")); i < n; ++i)
 836                 {
 837                         string pkg = argv(i);
 838                         if (startsWith(pkg, "csprogs-")) continue;
 839                         if (endsWith(pkg, "-serverpackage.txt")) continue;
 840                         if (endsWith(pkg, ".serverpackage")) continue;  // OLD legacy
 841                         s = cons(s, pkg);
 842                 }
 843                 // add automatically managed files to the list
 844                 #define X(match) MACRO_BEGIN { \
 845                         fd = search_begin(match, true, false); \
 846                         if (fd >= 0) \
 847                         { \
 848                                 for (int i = 0, j = search_getsize(fd); i < j; ++i) \
 849                                 { \
 850                                         s = cons(s, search_getfilename(fd, i)); \
 851                                 } \
 852                                 search_end(fd); \
 853                         } \
 854                 } MACRO_END
 855                 X("*-serverpackage.txt");
 856                 X("*.serverpackage");
 857                 #undef X
 858                 cvar_set("sv_curl_serverpackages", s);
 859         }
 860
 861         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 862         modname = "Xonotic";
 863         // physics/balance/config changes that count as mod
 864         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 865                 modname = cvar_string("g_mod_physics");
 866         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 867                 modname = cvar_string("g_mod_balance");
 868         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 869                 modname = cvar_string("g_mod_config");
 870         // extra mutators that deserve to count as mod
 871         MUTATOR_CALLHOOK(SetModname);
 872
 873         // save it for later
 874         modname = strzone(modname);
 875
 876         WinningConditionHelper(); // set worldstatus
 877
 878         world_initialized = 1;
 879 }
 880
 881 spawnfunc(light)
 882 {
 883         //makestatic (self); // Who the f___ did that?
 884         remove(self);
 885 }
 886
 887 string GetGametype()
 888 {
 889         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 890 }
 891
 892 string GetMapname()
 893 {
 894         return mapname;
 895 }
 896
 897 float Map_Count, Map_Current;
 898 string Map_Current_Name;
 899
 900 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 901 float GetMaplistPosition()
 902 {
 903         float pos, idx;
 904         string map;
 905
 906         map = GetMapname();
 907         idx = autocvar_g_maplist_index;
 908
 909         if(idx >= 0)
 910                 if(idx < Map_Count)
 911                         if(map == argv(idx))
 912                                 return idx;
 913
 914         for(pos = 0; pos < Map_Count; ++pos)
 915                 if(map == argv(pos))
 916                         return pos;
 917
 918         // resume normal maplist rotation if current map is not in g_maplist
 919         return idx;
 920 }
 921
 922 float MapHasRightSize(string map)
 923 {
 924         float fh;
 925         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 926         if(autocvar_g_maplist_check_waypoints)
 927         {
 928                 LOG_TRACE("checkwp "); LOG_TRACE(map);
 929                 if(!fexists(strcat("maps/", map, ".waypoints")))
 930                 {
 931                         LOG_TRACE(": no waypoints\n");
 932                         return false;
 933                 }
 934                 LOG_TRACE(": has waypoints\n");
 935         }
 936
 937         // open map size restriction file
 938         LOG_TRACE("opensize "); LOG_TRACE(map);
 939         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 940         if(fh >= 0)
 941         {
 942                 float mapmin, mapmax;
 943                 LOG_TRACE(": ok, ");
 944                 mapmin = stof(fgets(fh));
 945                 mapmax = stof(fgets(fh));
 946                 fclose(fh);
 947                 if(player_count < mapmin)
 948                 {
 949                         LOG_TRACE("not enough\n");
 950                         return false;
 951                 }
 952                 if(player_count > mapmax)
 953                 {
 954                         LOG_TRACE("too many\n");
 955                         return false;
 956                 }
 957                 LOG_TRACE("right size\n");
 958                 return true;
 959         }
 960         LOG_TRACE(": not found\n");
 961         return true;
 962 }
 963
 964 string Map_Filename(float position)
 965 {
 966         return strcat("maps/", argv(position), ".bsp");
 967 }
 968
 969 void Map_MarkAsRecent(string m)
 970 {
 971         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
 972 }
 973
 974 float Map_IsRecent(string m)
 975 {
 976         return strhasword(autocvar_g_maplist_mostrecent, m);
 977 }
 978
 979 float Map_Check(float position, float pass)
 980 {
 981         string filename;
 982         string map_next;
 983         map_next = argv(position);
 984         if(pass <= 1)
 985         {
 986                 if(Map_IsRecent(map_next))
 987                         return 0;
 988         }
 989         filename = Map_Filename(position);
 990         if(MapInfo_CheckMap(map_next))
 991         {
 992                 if(pass == 2)
 993                         return 1;
 994                 if(MapHasRightSize(map_next))
 995                         return 1;
 996                 return 0;
 997         }
 998         else
 999                 LOG_TRACE( "Couldn't select '", filename, "'..\n" );
1000
1001         return 0;
1002 }
1003
1004 void Map_Goto_SetStr(string nextmapname)
1005 {
1006         if(getmapname_stored != "")
1007                 strunzone(getmapname_stored);
1008         if(nextmapname == "")
1009                 getmapname_stored = "";
1010         else
1011                 getmapname_stored = strzone(nextmapname);
1012 }
1013
1014 void Map_Goto_SetFloat(float position)
1015 {
1016         cvar_set("g_maplist_index", ftos(position));
1017         Map_Goto_SetStr(argv(position));
1018 }
1019
1020 void Map_Goto(float reinit)
1021 {
1022         MapInfo_LoadMap(getmapname_stored, reinit);
1023 }
1024
1025 // return codes of map selectors:
1026 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1027 //   -2 = permanent failure
1028 float() MaplistMethod_Iterate = // usual method
1029 {
1030         float pass, i;
1031
1032         LOG_TRACE("Trying MaplistMethod_Iterate\n");
1033
1034         for(pass = 1; pass <= 2; ++pass)
1035         {
1036                 for(i = 1; i < Map_Count; ++i)
1037                 {
1038                         float mapindex;
1039                         mapindex = (i + Map_Current) % Map_Count;
1040                         if(Map_Check(mapindex, pass))
1041                                 return mapindex;
1042                 }
1043         }
1044         return -1;
1045 }
1046
1047 float() MaplistMethod_Repeat = // fallback method
1048 {
1049         LOG_TRACE("Trying MaplistMethod_Repeat\n");
1050
1051         if(Map_Check(Map_Current, 2))
1052                 return Map_Current;
1053         return -2;
1054 }
1055
1056 float() MaplistMethod_Random = // random map selection
1057 {
1058         float i, imax;
1059
1060         LOG_TRACE("Trying MaplistMethod_Random\n");
1061
1062         imax = 42;
1063
1064         for(i = 0; i <= imax; ++i)
1065         {
1066                 float mapindex;
1067                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1068                 if(Map_Check(mapindex, 1))
1069                         return mapindex;
1070         }
1071         return -1;
1072 }
1073
1074 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1075 // the exponent sets a bias on the map selection:
1076 // the higher the exponent, the less likely "shortly repeated" same maps are
1077 {
1078         float i, j, imax, insertpos;
1079
1080         LOG_TRACE("Trying MaplistMethod_Shuffle\n");
1081
1082         imax = 42;
1083
1084         for(i = 0; i <= imax; ++i)
1085         {
1086                 string newlist;
1087
1088                 // now reinsert this at another position
1089                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1090                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1091                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1092                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1093
1094                 // insert the current map there
1095                 newlist = "";
1096                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1097                         newlist = strcat(newlist, " ", argv(j));
1098                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1099                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1100                         newlist = strcat(newlist, " ", argv(j));
1101                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1102                 cvar_set("g_maplist", newlist);
1103                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1104
1105                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1106                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1107                 if(Map_Check(Map_Current, 1))
1108                         return Map_Current;
1109         }
1110         return -1;
1111 }
1112
1113 void Maplist_Init()
1114 {
1115         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1116         float i;
1117         for (i = 0; i < Map_Count; ++i)
1118                 if (Map_Check(i, 2))
1119                         break;
1120         if (i == Map_Count)
1121         {
1122                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1123                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1124                 if(autocvar_g_maplist_shuffle)
1125                         ShuffleMaplist();
1126                 localcmd("\nmenu_cmd sync\n");
1127                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1128         }
1129         if(Map_Count == 0)
1130                 error("empty maplist, cannot select a new map");
1131         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1132
1133         if(Map_Current_Name)
1134                 strunzone(Map_Current_Name);
1135         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1136         // this may or may not be correct, but who cares, in the worst case a map
1137         // isn't chosen in the first pass that should have been
1138 }
1139
1140 string GetNextMap()
1141 {
1142         float nextMap;
1143
1144         Maplist_Init();
1145         nextMap = -1;
1146
1147         if(nextMap == -1)
1148                 if(autocvar_g_maplist_shuffle > 0)
1149                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1150
1151         if(nextMap == -1)
1152                 if(autocvar_g_maplist_selectrandom)
1153                         nextMap = MaplistMethod_Random();
1154
1155         if(nextMap == -1)
1156                 nextMap = MaplistMethod_Iterate();
1157
1158         if(nextMap == -1)
1159                 nextMap = MaplistMethod_Repeat();
1160
1161         if(nextMap >= 0)
1162         {
1163                 Map_Goto_SetFloat(nextMap);
1164                 return getmapname_stored;
1165         }
1166
1167         return "";
1168 }
1169
1170 float DoNextMapOverride(float reinit)
1171 {
1172         if(autocvar_g_campaign)
1173         {
1174                 CampaignPostIntermission();
1175                 alreadychangedlevel = true;
1176                 return true;
1177         }
1178         if(autocvar_quit_when_empty)
1179         {
1180                 if(player_count <= currentbots)
1181                 {
1182                         localcmd("quit\n");
1183                         alreadychangedlevel = true;
1184                         return true;
1185                 }
1186         }
1187         if(autocvar_quit_and_redirect != "")
1188         {
1189                 redirection_target = strzone(autocvar_quit_and_redirect);
1190                 alreadychangedlevel = true;
1191                 return true;
1192         }
1193         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1194         {
1195                 localcmd("restart\n");
1196                 alreadychangedlevel = true;
1197                 return true;
1198         }
1199         if(autocvar_nextmap != "")
1200         {
1201                 string m;
1202                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1203                 cvar_set("nextmap",m);
1204
1205                 if(!m || gametypevote)
1206                         return false;
1207                 if(autocvar_sv_vote_gametype)
1208                 {
1209                         Map_Goto_SetStr(m);
1210                         return false;
1211                 }
1212
1213                 if(MapInfo_CheckMap(m))
1214                 {
1215                         Map_Goto_SetStr(m);
1216                         Map_Goto(reinit);
1217                         alreadychangedlevel = true;
1218                         return true;
1219                 }
1220         }
1221         if(!reinit && autocvar_lastlevel)
1222         {
1223                 cvar_settemp_restore();
1224                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1225                 alreadychangedlevel = true;
1226                 return true;
1227         }
1228         return false;
1229 }
1230
1231 void GotoNextMap(float reinit)
1232 {
1233         //string nextmap;
1234         //float n, nummaps;
1235         //string s;
1236         if (alreadychangedlevel)
1237                 return;
1238         alreadychangedlevel = true;
1239
1240         string nextMap;
1241
1242         nextMap = GetNextMap();
1243         if(nextMap == "")
1244                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1245         Map_Goto(reinit);
1246 }
1247
1248
1249 /*
1250 ============
1251 IntermissionThink
1252
1253 When the player presses attack or jump, change to the next level
1254 ============
1255 */
1256 .float autoscreenshot;
1257 void IntermissionThink()
1258 {SELFPARAM();
1259         FixIntermissionClient(self);
1260
1261         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1262         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1263
1264         if( (server_screenshot || client_screenshot)
1265                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1266         {
1267                 self.autoscreenshot = -1;
1268                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1269                 return;
1270         }
1271
1272         if (time < intermission_exittime)
1273                 return;
1274
1275         if(!mapvote_initialized)
1276                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1277                         return;
1278
1279         MapVote_Start();
1280 }
1281
1282 /*
1283 ============
1284 FindIntermission
1285
1286 Returns the entity to view from
1287 ============
1288 */
1289 /*
1290 entity FindIntermission()
1291 {
1292         local   entity spot;
1293         local   float cyc;
1294
1295 // look for info_intermission first
1296         spot = find (world, classname, "info_intermission");
1297         if (spot)
1298         {       // pick a random one
1299                 cyc = random() * 4;
1300                 while (cyc > 1)
1301                 {
1302                         spot = find (spot, classname, "info_intermission");
1303                         if (!spot)
1304                                 spot = find (spot, classname, "info_intermission");
1305                         cyc = cyc - 1;
1306                 }
1307                 return spot;
1308         }
1309
1310 // then look for the start position
1311         spot = find (world, classname, "info_player_start");
1312         if (spot)
1313                 return spot;
1314
1315 // testinfo_player_start is only found in regioned levels
1316         spot = find (world, classname, "testplayerstart");
1317         if (spot)
1318                 return spot;
1319
1320 // then look for the start position
1321         spot = find (world, classname, "info_player_deathmatch");
1322         if (spot)
1323                 return spot;
1324
1325         //objerror ("FindIntermission: no spot");
1326         return world;
1327 }
1328 */
1329
1330 /*
1331 ===============================================================================
1332
1333 RULES
1334
1335 ===============================================================================
1336 */
1337
1338 void DumpStats(float final)
1339 {
1340         float file;
1341         string s;
1342         float to_console;
1343         float to_eventlog;
1344         float to_file;
1345         float i;
1346
1347         to_console = autocvar_sv_logscores_console;
1348         to_eventlog = autocvar_sv_eventlog;
1349         to_file = autocvar_sv_logscores_file;
1350
1351         if(!final)
1352         {
1353                 to_console = true; // always print printstats replies
1354                 to_eventlog = false; // but never print them to the event log
1355         }
1356
1357         if(to_eventlog)
1358                 if(autocvar_sv_eventlog_console)
1359                         to_console = false; // otherwise we get the output twice
1360
1361         if(final)
1362                 s = ":scores:";
1363         else
1364                 s = ":status:";
1365         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1366
1367         if(to_console)
1368                 LOG_INFO(s, "\n");
1369         if(to_eventlog)
1370                 GameLogEcho(s);
1371
1372         file = -1;
1373         if(to_file)
1374         {
1375                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1376                 if(file == -1)
1377                         to_file = false;
1378                 else
1379                         fputs(file, strcat(s, "\n"));
1380         }
1381
1382         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1383         if(to_console)
1384                 LOG_INFO(s, "\n");
1385         if(to_eventlog)
1386                 GameLogEcho(s);
1387         if(to_file)
1388                 fputs(file, strcat(s, "\n"));
1389
1390         FOREACH_CLIENT(IS_REAL_CLIENT(it) || (IS_BOT_CLIENT(it) && autocvar_sv_logscores_bots), LAMBDA(
1391                 s = strcat(":player:see-labels:", GetPlayerScoreString(it, 0), ":");
1392                 s = strcat(s, ftos(rint(time - it.jointime)), ":");
1393                 if(IS_PLAYER(it) || MUTATOR_CALLHOOK(GetPlayerStatus, it, s))
1394                         s = strcat(s, ftos(it.team), ":");
1395                 else
1396                         s = strcat(s, "spectator:");
1397
1398                 if(to_console)
1399                         LOG_INFO(s, it.netname, "\n");
1400                 if(to_eventlog)
1401                         GameLogEcho(strcat(s, ftos(it.playerid), ":", it.netname));
1402                 if(to_file)
1403                         fputs(file, strcat(s, it.netname, "\n"));
1404         ));
1405
1406         if(teamplay)
1407         {
1408                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1409                 if(to_console)
1410                         LOG_INFO(s, "\n");
1411                 if(to_eventlog)
1412                         GameLogEcho(s);
1413                 if(to_file)
1414                         fputs(file, strcat(s, "\n"));
1415
1416                 for(i = 1; i < 16; ++i)
1417                 {
1418                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1419                         s = strcat(s, ":", ftos(i));
1420                         if(to_console)
1421                                 LOG_INFO(s, "\n");
1422                         if(to_eventlog)
1423                                 GameLogEcho(s);
1424                         if(to_file)
1425                                 fputs(file, strcat(s, "\n"));
1426                 }
1427         }
1428
1429         if(to_console)
1430                 LOG_INFO(":end\n");
1431         if(to_eventlog)
1432                 GameLogEcho(":end");
1433         if(to_file)
1434         {
1435                 fputs(file, ":end\n");
1436                 fclose(file);
1437         }
1438 }
1439
1440 void FixIntermissionClient(entity e)
1441 {
1442         if(!e.autoscreenshot) // initial call
1443         {
1444                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1445                 e.health = -2342;
1446                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1447                 e.solid = SOLID_NOT;
1448                 e.movetype = MOVETYPE_NONE;
1449                 e.takedamage = DAMAGE_NO;
1450                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1451                 {
1452                     .entity weaponentity = weaponentities[slot];
1453                         if(e.(weaponentity))
1454                         {
1455                                 e.(weaponentity).effects = EF_NODRAW;
1456                                 if (e.(weaponentity).weaponchild)
1457                                         e.(weaponentity).weaponchild.effects = EF_NODRAW;
1458                         }
1459                 }
1460                 if(IS_REAL_CLIENT(e))
1461                 {
1462                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1463                         RandomSelection_Init();
1464                         FOREACH_WORD(autocvar_sv_intermission_cdtrack, true, LAMBDA(
1465                                 RandomSelection_Add(NULL, 0, it, 1, 1);
1466                         ));
1467                         if (RandomSelection_chosen_string != "")
1468                         {
1469                                 stuffcmd(e, sprintf("\ncd loop %s\n", RandomSelection_chosen_string));
1470                         }
1471                         msg_entity = e;
1472                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1473                 }
1474         }
1475 }
1476
1477 /*
1478 go to the next level for deathmatch
1479 only called if a time or frag limit has expired
1480 */
1481 void NextLevel()
1482 {
1483         gameover = true;
1484
1485         intermission_running = 1;
1486
1487 // enforce a wait time before allowing changelevel
1488         if(player_count > 0)
1489                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1490         else
1491                 intermission_exittime = -1;
1492
1493         /*
1494         WriteByte (MSG_ALL, SVC_CDTRACK);
1495         WriteByte (MSG_ALL, 3);
1496         WriteByte (MSG_ALL, 3);
1497         // done in FixIntermission
1498         */
1499
1500         //pos = FindIntermission ();
1501
1502         VoteReset();
1503
1504         DumpStats(true);
1505
1506         // send statistics
1507         PlayerStats_GameReport(true);
1508         WeaponStats_Shutdown();
1509
1510         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1511
1512         if(autocvar_sv_eventlog)
1513                 GameLogEcho(":gameover");
1514
1515         GameLogClose();
1516
1517         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
1518                 FixIntermissionClient(it);
1519                 if(it.winning)
1520                         bprint(it.netname, " ^7wins.\n");
1521         ));
1522
1523         entity oldself = self;
1524         target_music_kill();
1525         self = oldself;
1526
1527         if(autocvar_g_campaign)
1528                 CampaignPreIntermission();
1529
1530         MUTATOR_CALLHOOK(MatchEnd);
1531
1532         localcmd("\nsv_hook_gameend\n");
1533 }
1534
1535 /*
1536 ============
1537 CheckRules_Player
1538
1539 Exit deathmatch games upon conditions
1540 ============
1541 */
1542 void CheckRules_Player()
1543 {SELFPARAM();
1544         if (gameover)   // someone else quit the game already
1545                 return;
1546
1547         if(!IS_DEAD(self))
1548                 self.play_time += frametime;
1549
1550         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1551         //   (div0: and that in CheckRules_World please)
1552 }
1553
1554
1555 float InitiateSuddenDeath()
1556 {
1557         // Check first whether normal overtimes could be added before initiating suddendeath mode
1558         // - for this timelimit_overtime needs to be >0 of course
1559         // - also check the winning condition calculated in the previous frame and only add normal overtime
1560         //   again, if at the point at which timelimit would be extended again, still no winner was found
1561         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1562         {
1563                 return 1; // need to call InitiateOvertime later
1564         }
1565         else
1566         {
1567                 if(!checkrules_suddendeathend)
1568                 {
1569                         if(autocvar_g_campaign)
1570                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1571                         else
1572                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1573                         if(g_race && !g_race_qualifying)
1574                                 race_StartCompleting();
1575                 }
1576                 return 0;
1577         }
1578 }
1579
1580 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1581 {
1582         ++checkrules_overtimesadded;
1583         //add one more overtime by simply extending the timelimit
1584         float tl;
1585         tl = autocvar_timelimit;
1586         tl += autocvar_timelimit_overtime;
1587         cvar_set("timelimit", ftos(tl));
1588
1589         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1590 }
1591
1592 float GetWinningCode(float fraglimitreached, float equality)
1593 {
1594         if(autocvar_g_campaign == 1)
1595                 if(fraglimitreached)
1596                         return WINNING_YES;
1597                 else
1598                         return WINNING_NO;
1599
1600         else
1601                 if(equality)
1602                         if(fraglimitreached)
1603                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1604                         else
1605                                 return WINNING_NEVER;
1606                 else
1607                         if(fraglimitreached)
1608                                 return WINNING_YES;
1609                         else
1610                                 return WINNING_NO;
1611 }
1612
1613 // set the .winning flag for exactly those players with a given field value
1614 void SetWinners(.float field, float value)
1615 {
1616         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(it.winning = (it.(field) == value)));
1617 }
1618
1619 // set the .winning flag for those players with a given field value
1620 void AddWinners(.float field, float value)
1621 {
1622         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
1623                 if(it.(field) == value)
1624                         it.winning = 1;
1625         ));
1626 }
1627
1628 // clear the .winning flags
1629 void ClearWinners()
1630 {
1631         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(it.winning = 0));
1632 }
1633
1634 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1635 // they win. Otherwise the defending team wins once the timelimit passes.
1636 void assault_new_round();
1637 float WinningCondition_Assault()
1638 {SELFPARAM();
1639         float status;
1640
1641         WinningConditionHelper(); // set worldstatus
1642
1643         status = WINNING_NO;
1644         // as the timelimit has not yet passed just assume the defending team will win
1645         if(assault_attacker_team == NUM_TEAM_1)
1646         {
1647                 SetWinners(team, NUM_TEAM_2);
1648         }
1649         else
1650         {
1651                 SetWinners(team, NUM_TEAM_1);
1652         }
1653
1654         entity ent;
1655         ent = find(world, classname, "target_assault_roundend");
1656         if(ent)
1657         {
1658                 if(ent.winning) // round end has been triggered by attacking team
1659                 {
1660                         bprint("ASSAULT: round completed...\n");
1661                         SetWinners(team, assault_attacker_team);
1662
1663                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1664
1665                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1666                         {
1667                                 status = WINNING_YES;
1668                         }
1669                         else
1670                         {
1671                                 WITH(entity, self, ent, assault_new_round());
1672                         }
1673                 }
1674         }
1675
1676         return status;
1677 }
1678
1679 void ShuffleMaplist()
1680 {
1681         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1682 }
1683
1684 float leaderfrags;
1685 float WinningCondition_Scores(float limit, float leadlimit)
1686 {
1687         float limitreached;
1688
1689         // TODO make everything use THIS winning condition (except LMS)
1690         WinningConditionHelper();
1691
1692         if(teamplay)
1693         {
1694                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1695                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1696                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1697                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1698         }
1699
1700         ClearWinners();
1701         if(WinningConditionHelper_winner)
1702                 WinningConditionHelper_winner.winning = 1;
1703         if(WinningConditionHelper_winnerteam >= 0)
1704                 SetWinners(team, WinningConditionHelper_winnerteam);
1705
1706         if(WinningConditionHelper_lowerisbetter)
1707         {
1708                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1709                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1710                 limit = -limit;
1711         }
1712
1713         if(WinningConditionHelper_zeroisworst)
1714                 leadlimit = 0; // not supported in this mode
1715
1716         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1717         // these modes always score in increments of 1, thus this makes sense
1718         {
1719                 if(leaderfrags != WinningConditionHelper_topscore)
1720                 {
1721                         leaderfrags = WinningConditionHelper_topscore;
1722
1723                         if (limit)
1724                         if (leaderfrags == limit - 1)
1725                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1726                         else if (leaderfrags == limit - 2)
1727                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1728                         else if (leaderfrags == limit - 3)
1729                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1730                 }
1731         }
1732
1733         limitreached = false;
1734         if(limit)
1735                 if(WinningConditionHelper_topscore >= limit)
1736                         limitreached = true;
1737         if(leadlimit)
1738         {
1739                 float leadlimitreached;
1740                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1741                 if(autocvar_leadlimit_and_fraglimit)
1742                         limitreached = (limitreached && leadlimitreached);
1743                 else
1744                         limitreached = (limitreached || leadlimitreached);
1745         }
1746
1747         if(limit)
1748                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1749
1750         return GetWinningCode(
1751                 WinningConditionHelper_topscore && limitreached,
1752                 WinningConditionHelper_equality
1753         );
1754 }
1755
1756 float WinningCondition_RanOutOfSpawns()
1757 {
1758         if(have_team_spawns <= 0)
1759                 return WINNING_NO;
1760
1761         if(!autocvar_g_spawn_useallspawns)
1762                 return WINNING_NO;
1763
1764         if(!some_spawn_has_been_used)
1765                 return WINNING_NO;
1766
1767         team1_score = team2_score = team3_score = team4_score = 0;
1768
1769         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it), LAMBDA(
1770                 switch(it.team)
1771                 {
1772                         case NUM_TEAM_1: team1_score = 1; break;
1773                         case NUM_TEAM_2: team2_score = 1; break;
1774                         case NUM_TEAM_3: team3_score = 1; break;
1775                         case NUM_TEAM_4: team4_score = 1; break;
1776                 }
1777         ));
1778
1779         FOREACH_ENTITY_CLASS("info_player_deathmatch", true, LAMBDA(
1780                 switch(it.team)
1781                 {
1782                         case NUM_TEAM_1: team1_score = 1; break;
1783                         case NUM_TEAM_2: team2_score = 1; break;
1784                         case NUM_TEAM_3: team3_score = 1; break;
1785                         case NUM_TEAM_4: team4_score = 1; break;
1786                 }
1787         ));
1788
1789         ClearWinners();
1790         if(team1_score + team2_score + team3_score + team4_score == 0)
1791         {
1792                 checkrules_equality = true;
1793                 return WINNING_YES;
1794         }
1795         else if(team1_score + team2_score + team3_score + team4_score == 1)
1796         {
1797                 float t, i;
1798                 if(team1_score)
1799                         t = NUM_TEAM_1;
1800                 else if(team2_score)
1801                         t = NUM_TEAM_2;
1802                 else if(team3_score)
1803                         t = NUM_TEAM_3;
1804                 else // if(team4_score)
1805                         t = NUM_TEAM_4;
1806                 CheckAllowedTeams(world);
1807                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1808                 {
1809                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
1810                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
1811                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
1812                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
1813                 }
1814
1815                 AddWinners(team, t);
1816                 return WINNING_YES;
1817         }
1818         else
1819                 return WINNING_NO;
1820 }
1821
1822 /*
1823 ============
1824 CheckRules_World
1825
1826 Exit deathmatch games upon conditions
1827 ============
1828 */
1829 void CheckRules_World()
1830 {
1831         float timelimit;
1832         float fraglimit;
1833         float leadlimit;
1834
1835         VoteThink();
1836         MapVote_Think();
1837
1838         SetDefaultAlpha();
1839
1840         if (gameover)   // someone else quit the game already
1841         {
1842                 if(player_count == 0) // Nobody there? Then let's go to the next map
1843                         MapVote_Start();
1844                         // this will actually check the player count in the next frame
1845                         // again, but this shouldn't hurt
1846                 return;
1847         }
1848
1849         timelimit = autocvar_timelimit * 60;
1850         fraglimit = autocvar_fraglimit;
1851         leadlimit = autocvar_leadlimit;
1852
1853         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1854         {
1855                 if(timelimit > 0)
1856                         timelimit = 0; // timelimit is not made for warmup
1857                 if(fraglimit > 0)
1858                         fraglimit = 0; // no fraglimit for now
1859                 leadlimit = 0; // no leadlimit for now
1860         }
1861
1862         if(timelimit > 0)
1863         {
1864                 timelimit += game_starttime;
1865         }
1866         else if (timelimit < 0)
1867         {
1868                 // endmatch
1869                 NextLevel();
1870                 return;
1871         }
1872
1873         float wantovertime;
1874         wantovertime = 0;
1875
1876         if(timelimit > game_starttime)
1877                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
1878         else
1879                 game_completion_ratio = 0;
1880
1881         if(checkrules_suddendeathend)
1882         {
1883                 if(!checkrules_suddendeathwarning)
1884                 {
1885                         checkrules_suddendeathwarning = true;
1886                         if(g_race && !g_race_qualifying)
1887                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
1888                         else
1889                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
1890                 }
1891         }
1892         else
1893         {
1894                 if (timelimit && time >= timelimit)
1895                 {
1896                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1897                         {
1898                                 float totalplayers;
1899                                 float playerswithlaps;
1900                                 float readyplayers;
1901                                 totalplayers = playerswithlaps = readyplayers = 0;
1902                                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
1903                                         ++totalplayers;
1904                                         if(PlayerScore_Add(it, SP_RACE_FASTEST, 0))
1905                                                 ++playerswithlaps;
1906                                         if(it.ready)
1907                                                 ++readyplayers;
1908                                 ));
1909
1910                                 // at least 2 of the players have completed a lap: start the RACE
1911                                 // otherwise, the players should end the qualifying on their own
1912                                 if(readyplayers || playerswithlaps >= 2)
1913                                 {
1914                                         checkrules_suddendeathend = 0;
1915                                         ReadyRestart(); // go to race
1916                                         return;
1917                                 }
1918                                 else
1919                                         wantovertime |= InitiateSuddenDeath();
1920                         }
1921                         else
1922                                 wantovertime |= InitiateSuddenDeath();
1923                 }
1924         }
1925
1926         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1927         {
1928                 NextLevel();
1929                 return;
1930         }
1931
1932         int checkrules_status = WinningCondition_RanOutOfSpawns();
1933         if(checkrules_status == WINNING_YES)
1934                 bprint("Hey! Someone ran out of spawns!\n");
1935         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
1936                 checkrules_status = ret_float;
1937         else
1938                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1939
1940         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1941         {
1942                 checkrules_status = WINNING_NEVER;
1943                 checkrules_overtimesadded = -1;
1944                 wantovertime |= InitiateSuddenDeath();
1945         }
1946
1947         if(checkrules_status == WINNING_NEVER)
1948                 // equality cases! Nobody wins if the overtime ends in a draw.
1949                 ClearWinners();
1950
1951         if(wantovertime)
1952         {
1953                 if(checkrules_status == WINNING_NEVER)
1954                         InitiateOvertime();
1955                 else
1956                         checkrules_status = WINNING_YES;
1957         }
1958
1959         if(checkrules_suddendeathend)
1960                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1961                         checkrules_status = WINNING_YES;
1962
1963         if(checkrules_status == WINNING_YES)
1964         {
1965                 //print("WINNING\n");
1966                 NextLevel();
1967         }
1968 }
1969
1970 string GotoMap(string m)
1971 {
1972         m = GameTypeVote_MapInfo_FixName(m);
1973         if (!m)
1974                 return "The map you suggested is not available on this server.";
1975         if (!autocvar_sv_vote_gametype)
1976         if(!MapInfo_CheckMap(m))
1977                 return "The map you suggested does not support the current game mode.";
1978         cvar_set("nextmap", m);
1979         cvar_set("timelimit", "-1");
1980         if(mapvote_initialized || alreadychangedlevel)
1981         {
1982                 if(DoNextMapOverride(0))
1983                         return "Map switch initiated.";
1984                 else
1985                         return "Hm... no. For some reason I like THIS map more.";
1986         }
1987         else
1988                 return "Map switch will happen after scoreboard.";
1989 }
1990
1991
1992 void EndFrame()
1993 {SELFPARAM();
1994         anticheat_endframe();
1995
1996         float altime;
1997         FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(
1998                 entity e = IS_SPEC(it) ? it.enemy : it;
1999                 if(e.typehitsound)
2000                         it.typehit_time = time;
2001                 else if(e.damage_dealt)
2002                 {
2003                         it.hit_time = time;
2004                         it.damage_dealt_total += ceil(e.damage_dealt);
2005                 }
2006         ));
2007         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2008         // add 1 frametime because after this, engine SV_Physics
2009         // increases time by a frametime and then networks the frame
2010         // add another frametime because client shows everything with
2011         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2012         // needed!
2013         FOREACH_CLIENT(true, LAMBDA(
2014                 it.typehitsound = false;
2015                 it.damage_dealt = 0;
2016                 setself(it);
2017                 antilag_record(it, altime);
2018         ));
2019         FOREACH_ENTITY_FLAGS(flags, FL_MONSTER, LAMBDA(
2020                 setself(it);
2021                 antilag_record(it, altime);
2022         ));
2023         FOREACH_CLIENT(PS(it), LAMBDA(
2024                 PlayerState s = PS(it);
2025                 s.ps_push(s, it);
2026         ));
2027 }
2028
2029
2030 /*
2031  * RedirectionThink:
2032  * returns true if redirecting
2033  */
2034 float redirection_timeout;
2035 float redirection_nextthink;
2036 float RedirectionThink()
2037 {SELFPARAM();
2038         float clients_found;
2039
2040         if(redirection_target == "")
2041                 return false;
2042
2043         if(!redirection_timeout)
2044         {
2045                 cvar_set("sv_public", "-2");
2046                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2047                 if(redirection_target == "self")
2048                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2049                 else
2050                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2051         }
2052
2053         if(time < redirection_nextthink)
2054                 return true;
2055
2056         redirection_nextthink = time + 1;
2057
2058         clients_found = 0;
2059         FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(
2060                 setself(it);
2061                 // TODO add timer
2062                 LOG_INFO("Redirecting: sending connect command to ", self.netname, "\n");
2063                 if(redirection_target == "self")
2064                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2065                 else
2066                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2067                 ++clients_found;
2068         ));
2069
2070         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.\n");
2071
2072         if(time > redirection_timeout || clients_found == 0)
2073                 localcmd("\nwait; wait; wait; quit\n");
2074
2075         return true;
2076 }
2077
2078 void TargetMusic_RestoreGame();
2079 void RestoreGame()
2080 {
2081         // Loaded from a save game
2082         // some things then break, so let's work around them...
2083
2084         // Progs DB (capture records)
2085         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2086
2087         // Mapinfo
2088         MapInfo_Shutdown();
2089         MapInfo_Enumerate();
2090         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2091         WeaponStats_Init();
2092
2093         TargetMusic_RestoreGame();
2094 }
2095
2096 void Shutdown()
2097 {
2098         gameover = 2;
2099
2100         if(world_initialized > 0)
2101         {
2102                 world_initialized = 0;
2103                 LOG_TRACE("Saving persistent data...\n");
2104                 Ban_SaveBans();
2105
2106                 // playerstats with unfinished match
2107                 PlayerStats_GameReport(false);
2108
2109                 if(!cheatcount_total)
2110                 {
2111                         if(autocvar_sv_db_saveasdump)
2112                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2113                         else
2114                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2115                 }
2116                 if(autocvar_developer)
2117                 {
2118                         if(autocvar_sv_db_saveasdump)
2119                                 db_dump(TemporaryDB, "server-temp.db");
2120                         else
2121                                 db_save(TemporaryDB, "server-temp.db");
2122                 }
2123                 CheatShutdown(); // must be after cheatcount check
2124                 db_close(ServerProgsDB);
2125                 db_close(TemporaryDB);
2126                 LOG_TRACE("Saving persistent data... done!\n");
2127                 // tell the bot system the game is ending now
2128                 bot_endgame();
2129
2130                 WeaponStats_Shutdown();
2131                 MapInfo_Shutdown();
2132         }
2133         else if(world_initialized == 0)
2134         {
2135                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data\n");
2136         }
2137         else
2138         {
2139                 __init_dedicated_server_shutdown();
2140         }
2141 }