qcsrc/common/notifications/all.qh

   1 #pragma once
   2
   3 #include <common/command/_mod.qh>
   4
   5 #include <common/constants.qh>
   6 #include <common/teams.qh>
   7 #include <common/util.qh>
   8 #include <common/sounds/sound.qh>
   9 #include <common/weapons/all.qh>
  10
  11 // Operator for bold notifications
  12 #define BOLD_OPERATOR "^BOLD"
  13
  14 /** main types/groups of notifications */
  15 ENUMCLASS(MSG)
  16         /** "Global" AND "personal" announcer messages */
  17         CASE(MSG, ANNCE)
  18         /** "Global" information messages */
  19         CASE(MSG, INFO)
  20         /** "Personal" centerprint messages */
  21         CASE(MSG, CENTER)
  22         /** Subcall MSG_INFO and/or MSG_CENTER notifications */
  23         CASE(MSG, MULTI)
  24         /** Choose which subcall wrapper to activate */
  25         CASE(MSG, CHOICE)
  26         /** Kill centerprint message @deprecated */
  27         CASE(MSG, CENTER_KILL)
  28 ENUMCLASS_END(MSG)
  29
  30 string Get_Notif_TypeName(MSG net_type)
  31 {
  32         switch (net_type)
  33         {
  34                 case MSG_ANNCE: return "MSG_ANNCE";
  35                 case MSG_INFO: return "MSG_INFO";
  36                 case MSG_CENTER: return "MSG_CENTER";
  37                 case MSG_MULTI: return "MSG_MULTI";
  38                 case MSG_CHOICE: return "MSG_CHOICE";
  39                 case MSG_CENTER_KILL: return "MSG_CENTER_KILL";
  40         }
  41         LOG_WARNF("Get_Notif_TypeName(%d): Improper net type!", ORDINAL(net_type));
  42         return "";
  43 }
  44
  45 ENUMCLASS(CPID)
  46         CASE(CPID, ASSAULT_ROLE)
  47         CASE(CPID, ROUND)
  48         CASE(CPID, CAMPCHECK)
  49         CASE(CPID, CTF_CAPSHIELD)
  50         CASE(CPID, CTF_LOWPRIO)
  51         CASE(CPID, CTF_PASS)
  52         CASE(CPID, STALEMATE)
  53         CASE(CPID, NADES)
  54         CASE(CPID, IDLING)
  55         CASE(CPID, REMOVE)
  56         CASE(CPID, ITEM)
  57         CASE(CPID, PREVENT_JOIN)
  58         CASE(CPID, KEEPAWAY)
  59         CASE(CPID, KEEPAWAY_WARN)
  60         CASE(CPID, KEYHUNT)
  61         CASE(CPID, KEYHUNT_OTHER)
  62         CASE(CPID, LMS)
  63         CASE(CPID, MISSING_TEAMS)
  64         CASE(CPID, MISSING_PLAYERS)
  65         CASE(CPID, INSTAGIB_FINDAMMO)
  66         CASE(CPID, NIX)
  67         CASE(CPID, ONSLAUGHT)
  68         CASE(CPID, ONS_CAPSHIELD)
  69         CASE(CPID, OVERTIME)
  70         CASE(CPID, POWERUP)
  71         CASE(CPID, RACE_FINISHLAP)
  72         CASE(CPID, SURVIVAL)
  73         CASE(CPID, TEAMCHANGE)
  74         CASE(CPID, TIMEOUT)
  75         CASE(CPID, TIMEIN)
  76         CASE(CPID, VEHICLES)
  77         CASE(CPID, VEHICLES_OTHER)
  78         /** always last */
  79         CASE(CPID, LAST)
  80 ENUMCLASS_END(CPID)
  81
  82 USING(Notification, entity);
  83
  84 // used for notification system multi-team identifiers
  85 #define APP_TEAM_NUM(num, prefix) ((num == NUM_TEAM_1) ? prefix##_RED : ((num == NUM_TEAM_2) ? prefix##_BLUE : ((num == NUM_TEAM_3) ? prefix##_YELLOW : prefix##_PINK)))
  86 #define APP_NUM(num, prefix) ((num) ? APP_TEAM_NUM(num, prefix) : prefix##_NEUTRAL)
  87
  88 #define EIGHT_VARS_TO_VARARGS_VARLIST \
  89         VARITEM(1, 0, s1) \
  90         VARITEM(2, 0, XPD(s1, s2)) \
  91         VARITEM(3, 0, XPD(s1, s2, s3)) \
  92         VARITEM(4, 0, XPD(s1, s2, s3, s4)) \
  93         VARITEM(0, 1, f1) \
  94         VARITEM(1, 1, XPD(s1, f1)) \
  95         VARITEM(2, 1, XPD(s1, s2, f1)) \
  96         VARITEM(3, 1, XPD(s1, s2, s3, f1)) \
  97         VARITEM(4, 1, XPD(s1, s2, s3, s4, f1)) \
  98         VARITEM(0, 2, XPD(f1, f2)) \
  99         VARITEM(1, 2, XPD(s1, f1, f2)) \
 100         VARITEM(2, 2, XPD(s1, s2, f1, f2)) \
 101         VARITEM(3, 2, XPD(s1, s2, s3, f1, f2)) \
 102         VARITEM(4, 2, XPD(s1, s2, s3, s4, f1, f2)) \
 103         VARITEM(0, 3, XPD(f1, f2, f3)) \
 104         VARITEM(1, 3, XPD(s1, f1, f2, f3)) \
 105         VARITEM(2, 3, XPD(s1, s2, f1, f2, f3)) \
 106         VARITEM(3, 3, XPD(s1, s2, s3, f1, f2, f3)) \
 107         VARITEM(4, 3, XPD(s1, s2, s3, s4, f1, f2, f3)) \
 108         VARITEM(0, 4, XPD(f1, f2, f3, f4)) \
 109         VARITEM(1, 4, XPD(s1, f1, f2, f3, f4)) \
 110         VARITEM(2, 4, XPD(s1, s2, f1, f2, f3, f4)) \
 111         VARITEM(3, 4, XPD(s1, s2, s3, f1, f2, f3, f4)) \
 112         VARITEM(4, 4, XPD(s1, s2, s3, s4, f1, f2, f3, f4))
 113
 114 void Destroy_All_Notifications();
 115 void Create_Notification_Entity(entity notif,
 116         float var_default,
 117         float var_cvar,
 118         MSG typeId,
 119         string namestring,
 120         int teamnum);
 121 void Create_Notification_Entity_Annce(entity notif,
 122                                                                                 float var_cvar,
 123                                                                                 string namestring,
 124                                                                                 /* MSG_ANNCE */
 125                                                                                 float channel,
 126                                                                                 string snd,
 127                                                                                 float vol,
 128                                                                                 float position,
 129                                                                                 float queuetime);
 130
 131 void Create_Notification_Entity_InfoCenter(entity notif,
 132                                                                                         float var_cvar,
 133                                                                                         string namestring,
 134                                                                                         int strnum,
 135                                                                                         int flnum,
 136                                                                                         /* MSG_INFO & MSG_CENTER */
 137                                                                                         string args,
 138                                                                                         string hudargs,
 139                                                                                         string icon,
 140                                                                                         CPID cpid,
 141                                                                                         string durcnt,
 142                                                                                         string normal,
 143                                                                                         string gentle);
 144
 145 void Create_Notification_Entity_Multi(entity notif,
 146                                                                                 float var_cvar,
 147                                                                                 string namestring,
 148                                                                                 /* MSG_MULTI */
 149                                                                                 Notification anncename,
 150                                                                                 Notification infoname,
 151                                                                                 Notification centername);
 152
 153 void Create_Notification_Entity_Choice(entity notif,
 154                                                                                 float var_cvar,
 155                                                                                 string namestring,
 156                                                                                 /* MSG_CHOICE */
 157                                                                                 float challow_def,
 158                                                                                 float challow_var,
 159                                                                                 MSG chtype,
 160                                                                                 Notification optiona,
 161                                                                                 Notification optionb);
 162
 163 void Dump_Notifications(int fh, bool alsoprint);
 164
 165 #define DEFAULT_FILENAME "notifications_dump.cfg"
 166 // NOTE: dumpeffectinfo, dumpnotifs, dumpturrets and dumpweapons use similar code
 167 GENERIC_COMMAND(dumpnotifs, "Dump all notifications into " DEFAULT_FILENAME, false)
 168 {
 169         switch (request)
 170         {
 171                 case CMD_REQUEST_COMMAND:
 172                 {
 173                         #ifdef GAMEQC
 174                         string filename = argv(1);
 175                         bool alsoprint = false;
 176                         if (filename == "")
 177                         {
 178                                 filename = DEFAULT_FILENAME;
 179                                 alsoprint = false;
 180                         }
 181                         else if (filename == "-")
 182                         {
 183                                 filename = DEFAULT_FILENAME;
 184                                 alsoprint = true;
 185                         }
 186                         int fh = fopen(filename, FILE_WRITE);
 187                         if (fh >= 0)
 188                         {
 189                                 Dump_Notifications(fh, alsoprint);
 190                                 LOG_INFOF("Dumping notifications... File located in ^2data/data/%s^7.", filename);
 191                                 fclose(fh);
 192                         }
 193                         else
 194                         {
 195                                 LOG_INFOF("^1Error: ^7Could not open file '%s'!", filename);
 196                         }
 197                         #else
 198                         LOG_INFO("Notification dump command only works with cl_cmd and sv_cmd.");
 199                         #endif
 200                         return;
 201                 }
 202                 default:
 203                 case CMD_REQUEST_USAGE:
 204                 {
 205                         LOG_HELP("Usage:^3 ", GetProgramCommandPrefix(), " dumpnotifs [<filename>]");
 206                         LOG_HELPF("  Where <filename> is the file to write (default is %s),", DEFAULT_FILENAME);
 207                         LOG_HELP("  if supplied with '-' output to console as well as default,");
 208                         LOG_HELP("  if left blank, it will only write to default.");
 209                         return;
 210                 }
 211         }
 212 }
 213 #undef DEFAULT_FILENAME
 214
 215 #ifdef NOTIFICATIONS_DEBUG
 216 bool autocvar_notification_debug = false;
 217 void Debug_Notification(string input)
 218 {
 219         switch (autocvar_notification_debug)
 220         {
 221                 case 1: { LOG_TRACE(input); break; }
 222                 case 2: { LOG_INFO(input); break; }
 223         }
 224 }
 225 #endif
 226
 227 void Local_Notification(MSG net_type, Notification net_name, ...count);
 228 /** glue for networking, forwards to `Local_Notification` */
 229 void Local_Notification_WOVA(
 230         MSG net_type, Notification net_name,
 231         float stringcount, float floatcount,
 232         string s1, string s2, string s3, string s4,
 233         float f1, float f2, float f3, float f4);
 234
 235 #ifdef CSQC
 236 string prev_soundfile;
 237 float prev_soundtime;
 238 #endif
 239
 240 #ifdef SVQC
 241 IntrusiveList g_notifications;
 242 STATIC_INIT(g_notifications) { g_notifications = IL_NEW(); }
 243 #endif
 244
 245 #ifdef SVQC
 246 ENUMCLASS(NOTIF)
 247         /** send to one client and their spectators */
 248         CASE(NOTIF, ONE)
 249         /** send ONLY to one client */
 250         CASE(NOTIF, ONE_ONLY)
 251         /** send only to X team and their spectators */
 252         CASE(NOTIF, TEAM)
 253         /** send only to X team and their spectators, except for Y person and their spectators */
 254         CASE(NOTIF, TEAM_EXCEPT)
 255         /** send to everyone */
 256         CASE(NOTIF, ALL)
 257         /** send to everyone except X person and their spectators */
 258         CASE(NOTIF, ALL_EXCEPT)
 259 ENUMCLASS_END(NOTIF)
 260
 261 string Get_Notif_BroadcastName(NOTIF broadcast)
 262 {
 263         switch (broadcast)
 264         {
 265                 case NOTIF_ONE: return "NOTIF_ONE";
 266                 case NOTIF_ONE_ONLY: return "NOTIF_ONE_ONLY";
 267                 case NOTIF_ALL_EXCEPT: return "NOTIF_ALL_EXCEPT";
 268                 case NOTIF_ALL: return "NOTIF_ALL";
 269                 case NOTIF_TEAM: return "NOTIF_TEAM";
 270                 case NOTIF_TEAM_EXCEPT: return "NOTIF_TEAM_EXCEPT";
 271         }
 272         LOG_WARNF("Get_Notif_BroadcastName(%d): Improper broadcast!", broadcast);
 273         return "";
 274 }
 275
 276 void Kill_Notification(
 277         NOTIF broadcast, entity client,
 278         MSG net_type, CPID net_name);
 279 void Send_Notification(
 280         NOTIF broadcast, entity client,
 281         MSG net_type, Notification net_name,
 282         ...count);
 283 void Send_Notification_WOVA(
 284         NOTIF broadcast, entity client,
 285         MSG net_type, Notification net_name,
 286         float stringcount, float floatcount,
 287         string s1, string s2, string s3, string s4,
 288         float f1, float f2, float f3, float f4);
 289 void Send_Notification_WOCOVA(
 290         NOTIF broadcast, entity client,
 291         MSG net_type, Notification net_name,
 292         string s1, string s2, string s3, string s4,
 293         float f1, float f2, float f3, float f4);
 294 #endif
 295
 296 // ===========================
 297 //  Special CVAR Declarations
 298 // ===========================
 299
 300 // MAKE SURE THIS IS ALWAYS SYNCHRONIZED WITH THE DUMP
 301 // NOTIFICATIONS FUNCTION IN THE .QC FILE!
 302
 303 #define NOTIF_ADD_AUTOCVAR(name,defaultvalue) float autocvar_notification_##name = defaultvalue;
 304
 305 float autocvar_notification_show_location = false;
 306 string autocvar_notification_show_location_string = ""; //_(" at the %s");
 307 float autocvar_notification_show_sprees = true;
 308 float autocvar_notification_show_sprees_info = 3; // 0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker
 309 float autocvar_notification_show_sprees_info_newline = true;
 310 float autocvar_notification_show_sprees_info_specialonly = true;
 311 float autocvar_notification_errors_are_fatal = true;
 312 #ifdef SVQC
 313 float autocvar_notification_lifetime_runtime = 0.5;
 314 float autocvar_notification_lifetime_mapload = 10;
 315 #endif
 316
 317 #ifdef SVQC
 318 void Notification_GetCvars(entity this, entity store);
 319 float autocvar_notification_server_allows_location = 1; // 0 = no, 1 = yes
 320 #else
 321 float autocvar_notification_item_centerprinttime = 1.5;
 322
 323 // 0 = no, 1 = yes, 2 = forced on for all MSG_INFO notifs
 324 // DISABLED IN CODE, BUT ENABLED IN CONFIG FOR COMPATIBILITY WITH OLD CLIENTS
 325 float autocvar_notification_allow_chatboxprint = 0;
 326
 327 float autocvar_notification_show_sprees_center = true;
 328 float autocvar_notification_show_sprees_center_specialonly = true;
 329 #endif
 330
 331
 332 // ============================
 333 //  Notification Argument List
 334 // ============================
 335 /*
 336  These arguments get replaced with the Local_Notification_sprintf
 337  and other such functions found in all.qc to supply data
 338  from networked notifications to their usage in sprintf... It
 339  allows for more dynamic data to be inferred by the local
 340  notification parser, so that the server does not have to network
 341  anything too crazy on a per-client/per-situation basis.
 342
 343  Pay attention to the CSQC/SVQC relations, some of these are redefined
 344  in slightly different ways for different programs, this is because the
 345  server does a more conservative approach to the notifs than the client.
 346
 347  All arguments are swapped into strings, so be sure that your
 348  sprintf usage matches with proper %s placement.
 349
 350  Argument descriptions:
 351         s1-s4: string arguments to be literally swapped into sprintf
 352         s2loc: s2 string of locations of deaths or other events
 353         s3loc: s3 string of locations of deaths or other events
 354         f1-f4: float arguments expanded into strings to be swapped into sprintf
 355         f1p2dec: f1 float to string with 2 decimal places
 356         f2p2dec: f2 float to string with 2 decimal places
 357         f2primsec: f2 float primary or secondary selection for weapons
 358         f3primsec: f3 float primary or secondary selection for weapons
 359         f1secs: count_seconds of f1
 360         f1points: point or points depending on f1
 361         f1ord: count_ordinal of f1
 362         f1time: process_time of f1
 363         f1race_time: TIME_ENCODED_TOSTRING of f1
 364         f2race_time: TIME_ENCODED_TOSTRING of f2
 365         race_col: color of race time/position (i.e. good or bad)
 366         race_diff: show time difference between f2 and f3
 367         missing_teams: show which teams still need players
 368         pass_key: find the keybind for "passing" or "dropping" in CTF game mode
 369         nade_key: find the keybind for nade throwing
 370         frag_ping: show the ping of a player
 371         frag_stats: show health/armor/ping of a player
 372         frag_pos: show score status and position in the match of a player
 373         spree_cen: centerprint notif for kill spree/how many kills they have
 374         spree_inf: info notif for kill spree/how many kills they have
 375         spree_end: placed at the end of murder messages to show ending of sprees
 376         spree_lost: placed at the end of suicide messages to show losing of sprees
 377         item_wepname: return full name of a weapon from weaponid
 378         item_wepammo: ammo display for weapon from f1 and f2
 379         item_centime: amount of time to display weapon message in centerprint
 380         item_buffname: return full name of a buff from buffid
 381         death_team: show the full name of the team a player is switching from
 382         minigame1_name: return human readable name of a minigame from its id(s1)
 383         minigame1_d: return descriptor name of a minigame from its id(s1)
 384 */
 385
 386 const float NOTIF_MAX_ARGS = 7;
 387 const float NOTIF_MAX_HUDARGS = 2;
 388 const float NOTIF_MAX_DURCNT = 2;
 389
 390 #ifdef CSQC
 391 const int NOTIF_QUEUE_MAX = 10;
 392 entity notif_queue_entity[NOTIF_QUEUE_MAX];
 393 MSG notif_queue_type[NOTIF_QUEUE_MAX];
 394 float notif_queue_time[NOTIF_QUEUE_MAX];
 395
 396 float notif_queue_next_time;
 397 int notif_queue_length;
 398
 399 void Local_Notification_Queue_Process();
 400 #endif
 401
 402 string arg_slot[NOTIF_MAX_ARGS];
 403
 404 const float ARG_CS_SV_HA = 1; // enabled on CSQC, SVQC, and Hudargs
 405 const float ARG_CS_SV_DC = 2; // enabled on CSQC, SVQC, and durcnt centerprint
 406 const float ARG_CS_SV = 3; // enabled on CSQC and SVQC
 407 const float ARG_CS = 4; // unique result to CSQC
 408 const float ARG_SV = 5; // unique result to SVQC
 409 const float ARG_DC = 6; // unique result to durcnt/centerprint
 410
 411 // todo possible idea.... declare how many floats/strings each arg needs, and then dynamically increment the input
 412 // this way, we don't need to have duplicates like i.e. s2loc and s3loc?
 413
 414 string BUFF_NAME(int i);
 415
 416 #define NOTIF_ARGUMENT_LIST \
 417         ARG_CASE(ARG_CS_SV_HA,  "s1",            s1) \
 418         ARG_CASE(ARG_CS_SV_HA,  "s2",            s2) \
 419         ARG_CASE(ARG_CS_SV_HA,  "s3",            s3) \
 420         ARG_CASE(ARG_CS_SV_HA,  "s4",            s4) \
 421         ARG_CASE(ARG_CS_SV,     "s2loc",         ((autocvar_notification_show_location && (s2 != "")) ? sprintf(( ((tmp_s = autocvar_notification_show_location_string) != "") ? tmp_s : _(" (near %s)") ), s2) : "")) \
 422         ARG_CASE(ARG_CS_SV,     "s3loc",         ((autocvar_notification_show_location && (s3 != "")) ? sprintf(( ((tmp_s = autocvar_notification_show_location_string) != "") ? tmp_s : _(" (near %s)") ), s3) : "")) \
 423         ARG_CASE(ARG_CS_SV_DC,  "f1",            ftos(f1)) \
 424         ARG_CASE(ARG_CS_SV_DC,  "f2",            ftos(f2)) \
 425         ARG_CASE(ARG_CS_SV,     "f3",            ftos(f3)) \
 426         ARG_CASE(ARG_CS_SV,     "f4",            ftos(f4)) \
 427         ARG_CASE(ARG_CS_SV,     "f1dtime",       ftos_decimals(TIME_DECODE(f1), 2)) \
 428         ARG_CASE(ARG_CS_SV,     "f2dtime",       ftos_decimals(TIME_DECODE(f2), 2)) \
 429         ARG_CASE(ARG_CS,        "f2primsec",     (f2 ? _("secondary") : _("primary"))) \
 430         ARG_CASE(ARG_CS,        "f3primsec",     (f3 ? _("secondary") : _("primary"))) \
 431         ARG_CASE(ARG_CS,        "f1secs",        count_seconds(f1)) \
 432         ARG_CASE(ARG_CS,        "f1points",      (f1 == 1 ? _("point") : _("points"))) \
 433         ARG_CASE(ARG_CS_SV,     "f1ord",         count_ordinal(f1)) \
 434         ARG_CASE(ARG_CS_SV,     "f1time",        process_time(2, f1)) \
 435         ARG_CASE(ARG_CS_SV_HA,  "f1race_time",   TIME_ENCODED_TOSTRING(f1, true)) \
 436         ARG_CASE(ARG_CS_SV_HA,  "f2race_time",   TIME_ENCODED_TOSTRING(f2, true)) \
 437         ARG_CASE(ARG_CS_SV_HA,  "f3race_time",   TIME_ENCODED_TOSTRING(f3, true)) \
 438         ARG_CASE(ARG_CS_SV,     "race_col",      CCR(((f1 == 1) ? "^F1" : "^F2"))) \
 439         ARG_CASE(ARG_CS_SV,     "race_diff",     ((f2 > f3) ? sprintf(CCR("^1[+%s]"), TIME_ENCODED_TOSTRING(f2 - f3, true)) : sprintf(CCR("^2[-%s]"), TIME_ENCODED_TOSTRING(f3 - f2, true)))) \
 440         ARG_CASE(ARG_CS,        "missing_teams", notif_arg_missing_teams(f1)) \
 441         ARG_CASE(ARG_CS,        "pass_key",      getcommandkey(_("drop flag"), "+use")) \
 442         ARG_CASE(ARG_CS,        "nade_key",      getcommandkey(_("throw nade"), "dropweapon")) \
 443         ARG_CASE(ARG_CS,        "join_key",      getcommandkey(_("jump"), "+jump")) \
 444         ARG_CASE(ARG_CS,        "frag_ping",     notif_arg_frag_ping(true, f2)) \
 445         ARG_CASE(ARG_CS,        "frag_stats",    notif_arg_frag_stats(f2, f3, f4)) \
 446         /*ARG_CASE(ARG_CS,      "frag_pos",      ((Should_Print_Score_Pos(f1)) ? sprintf("\n^BG%s", Read_Score_Pos(f1)) : ""))*/ \
 447         ARG_CASE(ARG_CS,        "spree_cen",     (autocvar_notification_show_sprees ? notif_arg_spree_cen(f1) : "")) \
 448         ARG_CASE(ARG_CS_SV,     "spree_inf",     (autocvar_notification_show_sprees ? notif_arg_spree_inf(1, input, s2, f2) : "")) \
 449         ARG_CASE(ARG_CS_SV,     "spree_end",     (autocvar_notification_show_sprees ? notif_arg_spree_inf(-1, "", "", f1) : "")) \
 450         ARG_CASE(ARG_CS_SV,     "spree_lost",    (autocvar_notification_show_sprees ? notif_arg_spree_inf(-2, "", "", f1) : "")) \
 451         ARG_CASE(ARG_CS_SV,     "item_wepname",  REGISTRY_GET(Weapons, f1).m_name) \
 452         ARG_CASE(ARG_CS_SV,     "item_buffname", BUFF_NAME(f1)) \
 453         ARG_CASE(ARG_CS_SV,     "f3buffname",    BUFF_NAME(f3)) \
 454         ARG_CASE(ARG_CS_SV,     "item_wepammo",  (f2 > 0 ? notif_arg_item_wepammo(f1, f2) : "")) \
 455         ARG_CASE(ARG_DC,        "item_centime",  ftos(autocvar_notification_item_centerprinttime)) \
 456         ARG_CASE(ARG_SV,        "death_team",    Team_ColoredFullName(f1)) \
 457         ARG_CASE(ARG_CS,        "death_team",    Team_ColoredFullName(f1 - 1)) \
 458         ARG_CASE(ARG_CS_SV_HA,  "minigame1_name",find(NULL,netname,s1).descriptor.message) \
 459         ARG_CASE(ARG_CS_SV_HA,  "minigame1_d",   find(NULL,netname,s1).descriptor.netname)
 460
 461 #define NOTIF_HIT_MAX(count,funcname) MACRO_BEGIN \
 462         if(sel_num == count) { backtrace(sprintf("%s: Hit maximum arguments!\n", funcname)); break; } \
 463 MACRO_END
 464
 465 #define NOTIF_HIT_UNKNOWN(token,funcname) { backtrace(sprintf("%s: Hit unknown token in selected string! '%s'\n", funcname, selected)); break; }
 466
 467 #define KILL_SPREE_LIST \
 468         SPREE_ITEM(3, 03, _("TRIPLE FRAG! "), _("%s^K1 made a TRIPLE FRAG! %s^BG"), _("%s^K1 made a TRIPLE SCORE! %s^BG")) \
 469         SPREE_ITEM(5, 05, _("RAGE! "), _("%s^K1 unlocked RAGE! %s^BG"), _("%s^K1 made FIVE SCORES IN A ROW! %s^BG")) \
 470         SPREE_ITEM(10, 10, _("MASSACRE! "), _("%s^K1 started a MASSACRE! %s^BG"), _("%s^K1 made TEN SCORES IN A ROW! %s^BG")) \
 471         SPREE_ITEM(15, 15, _("MAYHEM! "), _("%s^K1 executed MAYHEM! %s^BG"), _("%s^K1 made FIFTEEN SCORES IN A ROW! %s^BG")) \
 472         SPREE_ITEM(20, 20, _("BERSERKER! "), _("%s^K1 is a BERSERKER! %s^BG"), _("%s^K1 made TWENTY SCORES IN A ROW! %s^BG")) \
 473         SPREE_ITEM(25, 25, _("CARNAGE! "), _("%s^K1 inflicts CARNAGE! %s^BG"), _("%s^K1 made TWENTY FIVE SCORES IN A ROW! %s^BG")) \
 474         SPREE_ITEM(30, 30, _("ARMAGEDDON! "), _("%s^K1 unleashes ARMAGEDDON! %s^BG"), _("%s^K1 made THIRTY SCORES IN A ROW! %s^BG"))
 475
 476 #ifdef CSQC
 477 string notif_arg_frag_ping(bool newline, float fping)
 478 {
 479         string s = newline ? "\n" : " ";
 480         if (fping < 0)
 481                 return sprintf(CCR(_("%s(^F1Bot^BG)")), s);
 482         else
 483                 return sprintf(CCR(_("%s(Ping ^F1%d^BG)")), s, fping);
 484 }
 485
 486 string notif_arg_frag_stats(float fhealth, float farmor, float fping)
 487 {
 488         string s = notif_arg_frag_ping(false, fping);
 489         if (fhealth > 1)
 490                 return sprintf(CCR(_("\n(Health ^1%d^BG / Armor ^2%d^BG)%s")), fhealth, farmor, s);
 491         else
 492                 return sprintf(CCR(_("\n(^F4Dead^BG)%s")), s);
 493 }
 494
 495 string notif_arg_missing_teams(float f1)
 496 {
 497         return strcat(
 498                 ((f1 & BIT(0)) ? strcat(Team_ColoredFullName(NUM_TEAM_1), (f1 >> 1) ? ", " : "") : ""),
 499                 ((f1 & BIT(1)) ? strcat(Team_ColoredFullName(NUM_TEAM_2), (f1 >> 2) ? ", " : "") : ""),
 500                 ((f1 & BIT(2)) ? strcat(Team_ColoredFullName(NUM_TEAM_3), (f1 >> 3) ? ", " : "") : ""),
 501                 ((f1 & BIT(3)) ?        Team_ColoredFullName(NUM_TEAM_4)                         : "")
 502         );
 503 }
 504
 505 string notif_arg_spree_cen(float spree)
 506 {
 507         // 0 = off, 1 = target (but only for first victim) and attacker
 508         if(autocvar_notification_show_sprees_center)
 509         {
 510                 if(spree > 1)
 511                 {
 512                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 513                                 case counta: { return normal_or_gentle(center, sprintf(_("%d score spree! "), spree)); }
 514
 515                         switch(spree)
 516                         {
 517                                 KILL_SPREE_LIST
 518                                 default:
 519                                 {
 520                                         if (!autocvar_notification_show_sprees_center_specialonly)
 521                                         {
 522                                                 return
 523                                                         sprintf(
 524                                                                 normal_or_gentle(
 525                                                                         _("%d frag spree! "),
 526                                                                         _("%d score spree! ")
 527                                                                 ),
 528                                                                 spree);
 529                                         }
 530                                         else { return ""; } // don't show spree information if it isn't an achievement
 531                                 }
 532                         }
 533
 534                         #undef SPREE_ITEM
 535                 }
 536                 else if(spree == -1) // first blood
 537                 {
 538                         return normal_or_gentle(_("First blood! "), _("First score! "));
 539                 }
 540                 else if(spree == -2) // first victim
 541                 {
 542                         return normal_or_gentle(_("First victim! "), _("First casualty! "));
 543                 }
 544         }
 545         return "";
 546 }
 547 #endif
 548
 549 string notif_arg_spree_inf(float type, string input, string player, float spree)
 550 {
 551         switch(type)
 552         {
 553                 case 1: // attacker kill spree
 554                 {
 555                         // 0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker
 556                         // this conditional (& 2) is true for 2 and 3
 557                         if(autocvar_notification_show_sprees_info & 2)
 558                         {
 559                                 #ifdef CSQC
 560                                 string spree_newline =
 561                                         ( autocvar_notification_show_sprees_info_newline ?
 562                                                 ((substring(input, 0, 1) == "\{3}") ? "\n\{3}" : "\n") : "" );
 563                                 #else
 564                                 string spree_newline =
 565                                         (autocvar_notification_show_sprees_info_newline ? "\n" : "");
 566                                 #endif
 567
 568                                 if(spree > 1)
 569                                 {
 570                                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 571                                                 case counta: { return sprintf(CCR(normal_or_gentle(normal, gentle)), player, spree_newline); }
 572
 573                                         switch(spree)
 574                                         {
 575                                                 KILL_SPREE_LIST
 576                                                 default:
 577                                                 {
 578                                                         if (!autocvar_notification_show_sprees_info_specialonly)
 579                                                         {
 580                                                                 return
 581                                                                         sprintf(
 582                                                                                 CCR(normal_or_gentle(
 583                                                                                         _("%s^K1 has %d frags in a row! %s^BG"),
 584                                                                                         _("%s^K1 made %d scores in a row! %s^BG")
 585                                                                                 )),
 586                                                                                 player,
 587                                                                                 spree,
 588                                                                                 spree_newline
 589                                                                         );
 590                                                         }
 591                                                         else { return ""; } // don't show spree information if it isn't an achievement
 592                                                 }
 593                                         }
 594
 595                                         #undef SPREE_ITEM
 596                                 }
 597                                 else if(spree == -1) // firstblood
 598                                 {
 599                                         return
 600                                                 sprintf(
 601                                                         CCR(normal_or_gentle(
 602                                                                 _("%s^K1 drew first blood! %s^BG"),
 603                                                                 _("%s^K1 got the first score! %s^BG")
 604                                                         )),
 605                                                         player,
 606                                                         spree_newline
 607                                                 );
 608                                 }
 609                         }
 610                         break;
 611                 }
 612
 613                 case -1: // kill spree ended
 614                 {
 615                         if((spree > 1) && (autocvar_notification_show_sprees_info & 1))
 616                         {
 617                                 return
 618                                         sprintf(normal_or_gentle(
 619                                                 _(", ending their %d frag spree"),
 620                                                 _(", ending their %d score spree")
 621                                                 ),
 622                                                 spree
 623                                         );
 624                         }
 625                         break;
 626                 }
 627
 628                 case -2: // kill spree lost
 629                 {
 630                         if((spree > 1) && (autocvar_notification_show_sprees_info & 1))
 631                         {
 632                                 return
 633                                         sprintf(normal_or_gentle(
 634                                                 _(", losing their %d frag spree"),
 635                                                 _(", losing their %d score spree")
 636                                                 ),
 637                                                 spree
 638                                         );
 639                         }
 640                         break;
 641                 }
 642         }
 643         return "";
 644 }
 645
 646 string notif_arg_item_wepammo(float f1, float f2)
 647 {
 648         string ammoitems = "";
 649         Weapon wep = REGISTRY_GET(Weapons, f1);
 650         // TODO: registry handles
 651         switch (wep.ammo_type)
 652         {
 653                 case RES_SHELLS:  ammoitems = ITEM_Shells.m_name;      break;
 654                 case RES_BULLETS: ammoitems = ITEM_Bullets.m_name;     break;
 655                 case RES_ROCKETS: ammoitems = ITEM_Rockets.m_name;     break;
 656                 case RES_CELLS:   ammoitems = ITEM_Cells.m_name;       break;
 657                 case RES_PLASMA:  ammoitems = ITEM_Plasma.m_name;      break;
 658                 case RES_FUEL:    ammoitems = ITEM_JetpackFuel.m_name; break;
 659                 default: return ""; // doesn't use ammo
 660         }
 661         return sprintf(_(" with %d %s"), f2, strtolower(ammoitems));
 662 }
 663
 664
 665 // ====================================
 666 //  Initialization/Create Declarations
 667 // ====================================
 668
 669 // common notification entity values
 670 .int nent_default;
 671 .bool nent_enabled;
 672 .MSG nent_type;
 673 .string nent_name;
 674 .int nent_stringcount;
 675 .int nent_floatcount;
 676 .int nent_teamnum;
 677
 678 // MSG_ANNCE entity values
 679 .int nent_channel;
 680 .string nent_snd;
 681 .float nent_vol;
 682 .float nent_position;
 683 .float nent_queuetime;
 684
 685 // MSG_INFO and MSG_CENTER entity values
 686 .string nent_args; // used by both
 687 .string nent_hudargs; // used by info
 688 .string nent_icon; // used by info
 689 .CPID nent_cpid; // used by center
 690 .string nent_durcnt; // used by center
 691 .string nent_string; // used by both
 692
 693 // MSG_MULTI entity values
 694 .entity nent_msgannce;
 695 .entity nent_msginfo;
 696 .entity nent_msgcenter;
 697
 698 // MSG_CHOICE entity values
 699 .float nent_challow_def;
 700 .float nent_challow_var;
 701 .entity nent_optiona;
 702 .entity nent_optionb;
 703
 704 // networked notification entity values
 705 #ifdef SVQC
 706 .NOTIF nent_broadcast;
 707 #endif
 708 .entity nent_client;
 709 .MSG nent_net_type;
 710 .float nent_net_name;
 711 .string nent_strings[4];
 712 .float nent_floats[4];
 713
 714 #define ACVNN(name) autocvar_notification_##name
 715
 716 REGISTRY(Notifications, BITS(11))
 717 REGISTER_REGISTRY(Notifications)
 718 REGISTRY_SORT(Notifications)
 719
 720 REGISTRY_DEFINE_GET(Notifications, NULL)
 721 STATIC_INIT(Notifications) { FOREACH(Notifications, true, it.m_id = i); }
 722 REGISTRY_CHECK(Notifications)
 723
 724 const int NOTIF_CHOICE_MAX = 20;
 725 // NOTE: a team choice is actually made of 4 choices (one per team) with the same nent_choice_idx
 726 // thus they are counted as 1 in nent_choice_count
 727 int nent_choice_count = 0;
 728 .int nent_choice_idx;
 729 .int msg_choice_choices[NOTIF_CHOICE_MAX]; // set on each player containing MSG_CHOICE choices
 730 // initialization error detection
 731 bool notif_error;
 732 bool notif_global_error;
 733
 734 STATIC_INIT_LATE(Notif_Choices)
 735 {
 736         if (nent_choice_count > NOTIF_CHOICE_MAX)
 737                 LOG_FATALF("Too many MSG_CHOICE notifications (%d), hit NOTIF_CHOICE_MAX (%d) limit",
 738                         nent_choice_count, NOTIF_CHOICE_MAX);
 739 }
 740
 741 string Get_Notif_CvarName(Notification notif)
 742 {
 743         if(!notif.nent_teamnum)
 744                 return notif.nent_name;
 745         return substring(notif.nent_name, 0, -strlen(Static_Team_ColorName(notif.nent_teamnum)) - 2);
 746 }
 747
 748 Notification Get_Notif_Ent(MSG net_type, int net_name)
 749 {
 750         Notification it = REGISTRY_GET(Notifications, net_name);
 751         if (it.nent_type != net_type) {
 752                 LOG_WARNF("Get_Notif_Ent(%s (%d), %s (%d)): Improper net type '%s'!",
 753                         Get_Notif_TypeName(net_type), net_type,
 754                         it.registered_id, net_name,
 755                         Get_Notif_TypeName(it.nent_type)
 756                 );
 757                 return NULL;
 758         }
 759         return it;
 760 }
 761
 762 #define MSG_ANNCE_NOTIF_TEAM(teamnum, name, cvarname, defaultvalue, sound, channel, volume, position, queuetime) \
 763         MSG_ANNCE_NOTIF_(teamnum, ANNCE_##name, ANNCE_##cvarname, defaultvalue, sound, channel, volume, position, queuetime)
 764
 765 #define MSG_ANNCE_NOTIF(name, defaultvalue, sound, channel, volume, position, queuetime) \
 766         NOTIF_ADD_AUTOCVAR(ANNCE_##name, defaultvalue) \
 767         MSG_ANNCE_NOTIF_(0, ANNCE_##name, ANNCE_##name, defaultvalue, sound, channel, volume, position, queuetime)
 768
 769 #define MSG_ANNCE_NOTIF_(teamnum, name, cvarname, defaultvalue, sound, channel, volume, position, queuetime) \
 770         REGISTER(Notifications, name, m_id, new_pure(msg_annce_notification)) { \
 771                 Create_Notification_Entity      (this, defaultvalue, ACVNN(cvarname), MSG_ANNCE, strtoupper(#name), teamnum); \
 772                 Create_Notification_Entity_Annce(this, ACVNN(cvarname), strtoupper(#name), \
 773                         channel,    /* channel   */ \
 774                         sound,      /* snd       */ \
 775                         volume,     /* vol       */ \
 776                         position,   /* position  */ \
 777                         queuetime); /* queuetime */ \
 778         }
 779
 780 #define MSG_INFO_NOTIF_TEAM(teamnum, name, cvarname, defaultvalue, strnum, flnum, args, hudargs, icon, normal, gentle) \
 781         MSG_INFO_NOTIF_(teamnum, INFO_##name, INFO_##cvarname, defaultvalue, strnum, flnum, args, hudargs, icon, normal, gentle)
 782
 783 #define MSG_INFO_NOTIF(name, defaultvalue, strnum, flnum, args, hudargs, icon, normal, gentle) \
 784         NOTIF_ADD_AUTOCVAR(INFO_##name, defaultvalue) \
 785         MSG_INFO_NOTIF_(0, INFO_##name, INFO_##name, defaultvalue, strnum, flnum, args, hudargs, icon, normal, gentle)
 786
 787 #define MSG_INFO_NOTIF_(teamnum, name, cvarname, defaultvalue, strnum, flnum, args, hudargs, icon, normal, gentle) \
 788         REGISTER(Notifications, name, m_id, new_pure(msg_info_notification)) { \
 789                 Create_Notification_Entity           (this, defaultvalue, ACVNN(cvarname), MSG_INFO, strtoupper(#name), teamnum); \
 790                 Create_Notification_Entity_InfoCenter(this, ACVNN(cvarname), strtoupper(#name), strnum, flnum, \
 791                         args,     /* args    */ \
 792                         hudargs,  /* hudargs */ \
 793                         icon,     /* icon    */ \
 794                         CPID_Null,/* cpid    */ \
 795                         "",       /* durcnt  */ \
 796                         normal,   /* normal  */ \
 797                         gentle);  /* gentle  */ \
 798         }
 799
 800 .string nent_iconargs;
 801 #define MULTIICON_INFO(name, defaultvalue, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle) \
 802         MULTIICON_INFO_(INFO_##name, defaultvalue, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle)
 803 #define MULTIICON_INFO_(name, defaultvalue, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle) \
 804         NOTIF_ADD_AUTOCVAR(name, defaultvalue) \
 805         REGISTER(Notifications, name, m_id, new_pure(msg_info_notification)) { \
 806                 Create_Notification_Entity           (this, defaultvalue, ACVNN(name), MSG_INFO, strtoupper(#name), 0); \
 807                 Create_Notification_Entity_InfoCenter(this, ACVNN(name), strtoupper(#name), strnum, flnum, \
 808                         args,     /* args    */ \
 809                         hudargs,  /* hudargs */ \
 810                         icon,     /* icon    */ \
 811                         CPID_Null,/* cpid    */ \
 812                         "",       /* durcnt  */ \
 813                         normal,   /* normal  */ \
 814                         gentle);  /* gentle  */ \
 815                 this.nent_iconargs = iconargs; \
 816         }
 817
 818 #define MSG_CENTER_NOTIF_TEAM(teamnum, name, cvarname, defaultvalue, strnum, flnum, args, cpid, durcnt, normal, gentle) \
 819         MSG_CENTER_NOTIF_(teamnum, CENTER_##name, CENTER_##cvarname, defaultvalue, strnum, flnum, args, cpid, durcnt, normal, gentle)
 820
 821 #define MSG_CENTER_NOTIF(name, defaultvalue, strnum, flnum, args, cpid, durcnt, normal, gentle) \
 822         NOTIF_ADD_AUTOCVAR(CENTER_##name, defaultvalue) \
 823         MSG_CENTER_NOTIF_(0, CENTER_##name, CENTER_##name, defaultvalue, strnum, flnum, args, cpid, durcnt, normal, gentle)
 824
 825 #define MSG_CENTER_NOTIF_(teamnum, name, cvarname, defaultvalue, strnum, flnum, args, cpid, durcnt, normal, gentle) \
 826         REGISTER(Notifications, name, m_id, new_pure(msg_center_notification)) { \
 827                 Create_Notification_Entity           (this, defaultvalue, ACVNN(cvarname), MSG_CENTER, strtoupper(#name), teamnum); \
 828                 Create_Notification_Entity_InfoCenter(this, ACVNN(cvarname), strtoupper(#name), strnum, flnum, \
 829                         args,    /* args    */ \
 830                         "",      /* hudargs */ \
 831                         "",      /* icon    */ \
 832                         cpid,    /* cpid    */ \
 833                         durcnt,  /* durcnt  */ \
 834                         normal,  /* normal  */ \
 835                         gentle); /* gentle  */ \
 836         }
 837
 838 #define MSG_MULTI_NOTIF(name, defaultvalue, anncename, infoname, centername) \
 839         NOTIF_ADD_AUTOCVAR(name, defaultvalue) \
 840         REGISTER(Notifications, name, m_id, new_pure(msg_multi_notification)) { \
 841                 Create_Notification_Entity      (this, defaultvalue, ACVNN(name), MSG_MULTI, strtoupper(#name), 0); \
 842                 Create_Notification_Entity_Multi(this, ACVNN(name), strtoupper(#name), \
 843                         anncename,   /* anncename  */ \
 844                         infoname,    /* infoname   */ \
 845                         centername); /* centername */ \
 846         }
 847
 848 #define MSG_CHOICE_NOTIF_TEAM(teamnum, name, cvarname, defaultvalue, challow, chtype, optiona, optionb) \
 849         MSG_CHOICE_NOTIF_(teamnum, CHOICE_##name, CHOICE_##cvarname, defaultvalue, challow, chtype, optiona, optionb)
 850
 851 #define MSG_CHOICE_NOTIF(name, defaultvalue, challow, chtype, optiona, optionb) \
 852         NOTIF_ADD_AUTOCVAR(CHOICE_##name, defaultvalue) \
 853         NOTIF_ADD_AUTOCVAR(CHOICE_##name##_ALLOWED, challow) \
 854         MSG_CHOICE_NOTIF_(0, CHOICE_##name, CHOICE_##name, defaultvalue, challow, chtype, optiona, optionb)
 855
 856 #define MSG_CHOICE_NOTIF_(teamnum, name, cvarname, defaultvalue, challow, chtype, optiona, optionb) \
 857         REGISTER(Notifications, name, m_id, new_pure(msg_choice_notification)) { \
 858                 this.nent_choice_idx = nent_choice_count; \
 859                 if (!teamnum || teamnum == NUM_TEAM_4) \
 860                         nent_choice_count++; \
 861                 Create_Notification_Entity       (this, defaultvalue, ACVNN(cvarname), MSG_CHOICE, strtoupper(#name), teamnum); \
 862                 Create_Notification_Entity_Choice(this, ACVNN(cvarname), strtoupper(#name), \
 863                         challow,                                 /* challow_def */ \
 864                         autocvar_notification_##cvarname##_ALLOWED,  /* challow_var */ \
 865                         chtype,                                  /* chtype      */ \
 866                         optiona,                                 /* optiona     */ \
 867                         optionb);                                /* optionb     */ \
 868         }
 869
 870 REGISTRY_BEGIN(Notifications)
 871 {
 872         notif_global_error = false;
 873 }
 874
 875 REGISTRY_END(Notifications)
 876 {
 877         if (!notif_global_error) return;
 878         // shit happened... stop the loading of the program now if this is unacceptable
 879         if (autocvar_notification_errors_are_fatal)
 880                 LOG_FATAL("Notification initialization failed! Read above and fix the errors!");
 881         else
 882                 LOG_SEVERE("Notification initialization failed! Read above and fix the errors!");
 883 }
 884
 885 #ifdef CSQC
 886 .int cvar_value;
 887 void ReplicateVars(bool would_destroy)
 888 {
 889         if (!would_destroy)
 890                 FOREACH(Notifications, it.nent_type == MSG_CHOICE && (!it.nent_teamnum || it.nent_teamnum == NUM_TEAM_1), {
 891                         string cvarname = strcat("notification_", Get_Notif_CvarName(it));
 892                         // NOTE: REPLICATE_SIMPLE can return;
 893                         REPLICATE_SIMPLE(it.cvar_value, cvarname);
 894                 });
 895 }
 896 #endif
 897
 898 #include "all.inc"