qcsrc/common/notifications/all.qh

   1 #pragma once
   2
   3 #include <common/command/_mod.qh>
   4
   5 #include <common/constants.qh>
   6 #include <common/teams.qh>
   7 #include <common/util.qh>
   8 #include <common/sounds/sound.qh>
   9 #include <common/weapons/all.qh>
  10
  11 // Operator for bold notifications
  12 #define BOLD_OPERATOR "^BOLD"
  13
  14 /** main types/groups of notifications */
  15 ENUMCLASS(MSG)
  16         /** "Global" AND "personal" announcer messages */
  17         CASE(MSG, ANNCE)
  18         /** "Global" information messages */
  19         CASE(MSG, INFO)
  20         /** "Personal" centerprint messages */
  21         CASE(MSG, CENTER)
  22         /** Subcall MSG_INFO and/or MSG_CENTER notifications */
  23         CASE(MSG, MULTI)
  24         /** Choose which subcall wrapper to activate */
  25         CASE(MSG, CHOICE)
  26         /** Kill centerprint message @deprecated */
  27         CASE(MSG, CENTER_KILL)
  28 ENUMCLASS_END(MSG)
  29
  30 string Get_Notif_TypeName(MSG net_type)
  31 {
  32         switch (net_type)
  33         {
  34                 case MSG_ANNCE: return "MSG_ANNCE";
  35                 case MSG_INFO: return "MSG_INFO";
  36                 case MSG_CENTER: return "MSG_CENTER";
  37                 case MSG_MULTI: return "MSG_MULTI";
  38                 case MSG_CHOICE: return "MSG_CHOICE";
  39                 case MSG_CENTER_KILL: return "MSG_CENTER_KILL";
  40         }
  41         LOG_WARNF("Get_Notif_TypeName(%d): Improper net type!", ORDINAL(net_type));
  42         return "";
  43 }
  44
  45 ENUMCLASS(CPID)
  46         CASE(CPID, ASSAULT_ROLE)
  47         CASE(CPID, ROUND)
  48         CASE(CPID, CAMPCHECK)
  49         CASE(CPID, CTF_CAPSHIELD)
  50         CASE(CPID, CTF_LOWPRIO)
  51         CASE(CPID, CTF_PASS)
  52         CASE(CPID, STALEMATE)
  53         CASE(CPID, NADES)
  54         CASE(CPID, IDLING)
  55         CASE(CPID, ITEM)
  56         CASE(CPID, PREVENT_JOIN)
  57         CASE(CPID, KEEPAWAY)
  58         CASE(CPID, KEEPAWAY_WARN)
  59         CASE(CPID, KEYHUNT)
  60         CASE(CPID, KEYHUNT_OTHER)
  61         CASE(CPID, LMS)
  62         CASE(CPID, MISSING_TEAMS)
  63         CASE(CPID, MISSING_PLAYERS)
  64         CASE(CPID, INSTAGIB_FINDAMMO)
  65         CASE(CPID, NIX)
  66         CASE(CPID, ONSLAUGHT)
  67         CASE(CPID, ONS_CAPSHIELD)
  68         CASE(CPID, OVERTIME)
  69         CASE(CPID, POWERUP)
  70         CASE(CPID, RACE_FINISHLAP)
  71         CASE(CPID, SURVIVAL)
  72         CASE(CPID, TEAMCHANGE)
  73         CASE(CPID, TIMEOUT)
  74         CASE(CPID, TIMEIN)
  75         CASE(CPID, VEHICLES)
  76         CASE(CPID, VEHICLES_OTHER)
  77         /** always last */
  78         CASE(CPID, LAST)
  79 ENUMCLASS_END(CPID)
  80
  81 USING(Notification, entity);
  82
  83 // used for notification system multi-team identifiers
  84 #define APP_TEAM_NUM(num, prefix) ((num == NUM_TEAM_1) ? prefix##_RED : ((num == NUM_TEAM_2) ? prefix##_BLUE : ((num == NUM_TEAM_3) ? prefix##_YELLOW : prefix##_PINK)))
  85 #define APP_NUM(num, prefix) ((num) ? APP_TEAM_NUM(num, prefix) : prefix##_NEUTRAL)
  86
  87 #define EIGHT_VARS_TO_VARARGS_VARLIST \
  88         VARITEM(1, 0, s1) \
  89         VARITEM(2, 0, XPD(s1, s2)) \
  90         VARITEM(3, 0, XPD(s1, s2, s3)) \
  91         VARITEM(4, 0, XPD(s1, s2, s3, s4)) \
  92         VARITEM(0, 1, f1) \
  93         VARITEM(1, 1, XPD(s1, f1)) \
  94         VARITEM(2, 1, XPD(s1, s2, f1)) \
  95         VARITEM(3, 1, XPD(s1, s2, s3, f1)) \
  96         VARITEM(4, 1, XPD(s1, s2, s3, s4, f1)) \
  97         VARITEM(0, 2, XPD(f1, f2)) \
  98         VARITEM(1, 2, XPD(s1, f1, f2)) \
  99         VARITEM(2, 2, XPD(s1, s2, f1, f2)) \
 100         VARITEM(3, 2, XPD(s1, s2, s3, f1, f2)) \
 101         VARITEM(4, 2, XPD(s1, s2, s3, s4, f1, f2)) \
 102         VARITEM(0, 3, XPD(f1, f2, f3)) \
 103         VARITEM(1, 3, XPD(s1, f1, f2, f3)) \
 104         VARITEM(2, 3, XPD(s1, s2, f1, f2, f3)) \
 105         VARITEM(3, 3, XPD(s1, s2, s3, f1, f2, f3)) \
 106         VARITEM(4, 3, XPD(s1, s2, s3, s4, f1, f2, f3)) \
 107         VARITEM(0, 4, XPD(f1, f2, f3, f4)) \
 108         VARITEM(1, 4, XPD(s1, f1, f2, f3, f4)) \
 109         VARITEM(2, 4, XPD(s1, s2, f1, f2, f3, f4)) \
 110         VARITEM(3, 4, XPD(s1, s2, s3, f1, f2, f3, f4)) \
 111         VARITEM(4, 4, XPD(s1, s2, s3, s4, f1, f2, f3, f4))
 112
 113 void Destroy_All_Notifications();
 114 void Create_Notification_Entity(entity notif,
 115         float var_default,
 116         float var_cvar,
 117         MSG typeId,
 118         string namestring,
 119         int teamnum);
 120 void Create_Notification_Entity_Annce(entity notif,
 121                                                                                 float var_cvar,
 122                                                                                 string namestring,
 123                                                                                 /* MSG_ANNCE */
 124                                                                                 float channel,
 125                                                                                 string snd,
 126                                                                                 float vol,
 127                                                                                 float position,
 128                                                                                 float queuetime);
 129
 130 void Create_Notification_Entity_InfoCenter(entity notif,
 131                                                                                         float var_cvar,
 132                                                                                         string namestring,
 133                                                                                         int strnum,
 134                                                                                         int flnum,
 135                                                                                         /* MSG_INFO & MSG_CENTER */
 136                                                                                         string args,
 137                                                                                         string hudargs,
 138                                                                                         string icon,
 139                                                                                         CPID cpid,
 140                                                                                         string durcnt,
 141                                                                                         string normal,
 142                                                                                         string gentle);
 143
 144 void Create_Notification_Entity_Multi(entity notif,
 145                                                                                 float var_cvar,
 146                                                                                 string namestring,
 147                                                                                 /* MSG_MULTI */
 148                                                                                 Notification anncename,
 149                                                                                 Notification infoname,
 150                                                                                 Notification centername);
 151
 152 void Create_Notification_Entity_Choice(entity notif,
 153                                                                                 float var_cvar,
 154                                                                                 string namestring,
 155                                                                                 /* MSG_CHOICE */
 156                                                                                 float challow_def,
 157                                                                                 float challow_var,
 158                                                                                 MSG chtype,
 159                                                                                 Notification optiona,
 160                                                                                 Notification optionb);
 161
 162 void Dump_Notifications(int fh, bool alsoprint);
 163
 164 #define DEFAULT_FILENAME "notifications_dump.cfg"
 165 // NOTE: dumpeffectinfo, dumpnotifs, dumpturrets and dumpweapons use similar code
 166 GENERIC_COMMAND(dumpnotifs, "Dump all notifications into " DEFAULT_FILENAME, false)
 167 {
 168         switch (request)
 169         {
 170                 case CMD_REQUEST_COMMAND:
 171                 {
 172                         #ifdef GAMEQC
 173                         string filename = argv(1);
 174                         bool alsoprint = false;
 175                         if (filename == "")
 176                         {
 177                                 filename = DEFAULT_FILENAME;
 178                                 alsoprint = false;
 179                         }
 180                         else if (filename == "-")
 181                         {
 182                                 filename = DEFAULT_FILENAME;
 183                                 alsoprint = true;
 184                         }
 185                         int fh = fopen(filename, FILE_WRITE);
 186                         if (fh >= 0)
 187                         {
 188                                 Dump_Notifications(fh, alsoprint);
 189                                 LOG_INFOF("Dumping notifications... File located in ^2data/data/%s^7.", filename);
 190                                 fclose(fh);
 191                         }
 192                         else
 193                         {
 194                                 LOG_INFOF("^1Error: ^7Could not open file '%s'!", filename);
 195                         }
 196                         #else
 197                         LOG_INFO("Notification dump command only works with cl_cmd and sv_cmd.");
 198                         #endif
 199                         return;
 200                 }
 201                 default:
 202                 case CMD_REQUEST_USAGE:
 203                 {
 204                         LOG_HELP("Usage:^3 ", GetProgramCommandPrefix(), " dumpnotifs [<filename>]");
 205                         LOG_HELPF("  Where <filename> is the file to write (default is %s),", DEFAULT_FILENAME);
 206                         LOG_HELP("  if supplied with '-' output to console as well as default,");
 207                         LOG_HELP("  if left blank, it will only write to default.");
 208                         return;
 209                 }
 210         }
 211 }
 212 #undef DEFAULT_FILENAME
 213
 214 #ifdef NOTIFICATIONS_DEBUG
 215 bool autocvar_notification_debug = false;
 216 void Debug_Notification(string input)
 217 {
 218         switch (autocvar_notification_debug)
 219         {
 220                 case 1: { LOG_TRACE(input); break; }
 221                 case 2: { LOG_INFO(input); break; }
 222         }
 223 }
 224 #endif
 225
 226 void Local_Notification(MSG net_type, Notification net_name, ...count);
 227 /** glue for networking, forwards to `Local_Notification` */
 228 void Local_Notification_WOVA(
 229         MSG net_type, Notification net_name,
 230         float stringcount, float floatcount,
 231         string s1, string s2, string s3, string s4,
 232         float f1, float f2, float f3, float f4);
 233
 234 #ifdef CSQC
 235 string prev_soundfile;
 236 float prev_soundtime;
 237 #endif
 238
 239 #ifdef SVQC
 240 IntrusiveList g_notifications;
 241 STATIC_INIT(g_notifications) { g_notifications = IL_NEW(); }
 242 #endif
 243
 244 #ifdef SVQC
 245 ENUMCLASS(NOTIF)
 246         /** send to one client and their spectators */
 247         CASE(NOTIF, ONE)
 248         /** send ONLY to one client */
 249         CASE(NOTIF, ONE_ONLY)
 250         /** send only to X team and their spectators */
 251         CASE(NOTIF, TEAM)
 252         /** send only to X team and their spectators, except for Y person and their spectators */
 253         CASE(NOTIF, TEAM_EXCEPT)
 254         /** send to everyone */
 255         CASE(NOTIF, ALL)
 256         /** send to everyone except X person and their spectators */
 257         CASE(NOTIF, ALL_EXCEPT)
 258 ENUMCLASS_END(NOTIF)
 259
 260 string Get_Notif_BroadcastName(NOTIF broadcast)
 261 {
 262         switch (broadcast)
 263         {
 264                 case NOTIF_ONE: return "NOTIF_ONE";
 265                 case NOTIF_ONE_ONLY: return "NOTIF_ONE_ONLY";
 266                 case NOTIF_ALL_EXCEPT: return "NOTIF_ALL_EXCEPT";
 267                 case NOTIF_ALL: return "NOTIF_ALL";
 268                 case NOTIF_TEAM: return "NOTIF_TEAM";
 269                 case NOTIF_TEAM_EXCEPT: return "NOTIF_TEAM_EXCEPT";
 270         }
 271         LOG_WARNF("Get_Notif_BroadcastName(%d): Improper broadcast!", broadcast);
 272         return "";
 273 }
 274
 275 void Kill_Notification(
 276         NOTIF broadcast, entity client,
 277         MSG net_type, CPID net_name);
 278 void Send_Notification(
 279         NOTIF broadcast, entity client,
 280         MSG net_type, Notification net_name,
 281         ...count);
 282 void Send_Notification_WOVA(
 283         NOTIF broadcast, entity client,
 284         MSG net_type, Notification net_name,
 285         float stringcount, float floatcount,
 286         string s1, string s2, string s3, string s4,
 287         float f1, float f2, float f3, float f4);
 288 void Send_Notification_WOCOVA(
 289         NOTIF broadcast, entity client,
 290         MSG net_type, Notification net_name,
 291         string s1, string s2, string s3, string s4,
 292         float f1, float f2, float f3, float f4);
 293 #endif
 294
 295 // ===========================
 296 //  Special CVAR Declarations
 297 // ===========================
 298
 299 // MAKE SURE THIS IS ALWAYS SYNCHRONIZED WITH THE DUMP
 300 // NOTIFICATIONS FUNCTION IN THE .QC FILE!
 301
 302 #define NOTIF_ADD_AUTOCVAR(name,defaultvalue) float autocvar_notification_##name = defaultvalue;
 303
 304 float autocvar_notification_show_location = false;
 305 string autocvar_notification_show_location_string = ""; //_(" at the %s");
 306 float autocvar_notification_show_sprees = true;
 307 float autocvar_notification_show_sprees_info = 3; // 0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker
 308 float autocvar_notification_show_sprees_info_newline = true;
 309 float autocvar_notification_show_sprees_info_specialonly = true;
 310 float autocvar_notification_errors_are_fatal = true;
 311 #ifdef SVQC
 312 float autocvar_notification_lifetime_runtime = 0.5;
 313 float autocvar_notification_lifetime_mapload = 10;
 314 #endif
 315
 316 #ifdef SVQC
 317 void Notification_GetCvars(entity this, entity store);
 318 float autocvar_notification_server_allows_location = 1; // 0 = no, 1 = yes
 319 #else
 320 float autocvar_notification_item_centerprinttime = 1.5;
 321
 322 // 0 = no, 1 = yes, 2 = forced on for all MSG_INFO notifs
 323 // DISABLED IN CODE, BUT ENABLED IN CONFIG FOR COMPATIBILITY WITH OLD CLIENTS
 324 float autocvar_notification_allow_chatboxprint = 0;
 325
 326 float autocvar_notification_show_sprees_center = true;
 327 float autocvar_notification_show_sprees_center_specialonly = true;
 328 #endif
 329
 330
 331 // ============================
 332 //  Notification Argument List
 333 // ============================
 334 /*
 335  These arguments get replaced with the Local_Notification_sprintf
 336  and other such functions found in all.qc to supply data
 337  from networked notifications to their usage in sprintf... It
 338  allows for more dynamic data to be inferred by the local
 339  notification parser, so that the server does not have to network
 340  anything too crazy on a per-client/per-situation basis.
 341
 342  Pay attention to the CSQC/SVQC relations, some of these are redefined
 343  in slightly different ways for different programs, this is because the
 344  server does a more conservative approach to the notifs than the client.
 345
 346  All arguments are swapped into strings, so be sure that your
 347  sprintf usage matches with proper %s placement.
 348
 349  Argument descriptions:
 350         s1-s4: string arguments to be literally swapped into sprintf
 351         s2loc: s2 string of locations of deaths or other events
 352         s3loc: s3 string of locations of deaths or other events
 353         f1-f4: float arguments expanded into strings to be swapped into sprintf
 354         f1p2dec: f1 float to string with 2 decimal places
 355         f2p2dec: f2 float to string with 2 decimal places
 356         f2primsec: f2 float primary or secondary selection for weapons
 357         f3primsec: f3 float primary or secondary selection for weapons
 358         f1secs: count_seconds of f1
 359         f1points: point or points depending on f1
 360         f1ord: count_ordinal of f1
 361         f1time: process_time of f1
 362         f1race_time: TIME_ENCODED_TOSTRING of f1
 363         f2race_time: TIME_ENCODED_TOSTRING of f2
 364         race_col: color of race time/position (i.e. good or bad)
 365         race_diff: show time difference between f2 and f3
 366         missing_teams: show which teams still need players
 367         pass_key: find the keybind for "passing" or "dropping" in CTF game mode
 368         nade_key: find the keybind for nade throwing
 369         frag_ping: show the ping of a player
 370         frag_stats: show health/armor/ping of a player
 371         frag_pos: show score status and position in the match of a player
 372         spree_cen: centerprint notif for kill spree/how many kills they have
 373         spree_inf: info notif for kill spree/how many kills they have
 374         spree_end: placed at the end of murder messages to show ending of sprees
 375         spree_lost: placed at the end of suicide messages to show losing of sprees
 376         item_wepname: return full name of a weapon from weaponid
 377         item_wepammo: ammo display for weapon from f1 and f2
 378         item_centime: amount of time to display weapon message in centerprint
 379         item_buffname: return full name of a buff from buffid
 380         death_team: show the full name of the team a player is switching from
 381         minigame1_name: return human readable name of a minigame from its id(s1)
 382         minigame1_d: return descriptor name of a minigame from its id(s1)
 383 */
 384
 385 const float NOTIF_MAX_ARGS = 7;
 386 const float NOTIF_MAX_HUDARGS = 2;
 387 const float NOTIF_MAX_DURCNT = 2;
 388
 389 #ifdef CSQC
 390 const int NOTIF_QUEUE_MAX = 10;
 391 entity notif_queue_entity[NOTIF_QUEUE_MAX];
 392 MSG notif_queue_type[NOTIF_QUEUE_MAX];
 393 float notif_queue_time[NOTIF_QUEUE_MAX];
 394
 395 float notif_queue_next_time;
 396 int notif_queue_length;
 397
 398 void Local_Notification_Queue_Process();
 399 #endif
 400
 401 string arg_slot[NOTIF_MAX_ARGS];
 402
 403 const float ARG_CS_SV_HA = 1; // enabled on CSQC, SVQC, and Hudargs
 404 const float ARG_CS_SV_DC = 2; // enabled on CSQC, SVQC, and durcnt centerprint
 405 const float ARG_CS_SV = 3; // enabled on CSQC and SVQC
 406 const float ARG_CS = 4; // unique result to CSQC
 407 const float ARG_SV = 5; // unique result to SVQC
 408 const float ARG_DC = 6; // unique result to durcnt/centerprint
 409
 410 // todo possible idea.... declare how many floats/strings each arg needs, and then dynamically increment the input
 411 // this way, we don't need to have duplicates like i.e. s2loc and s3loc?
 412
 413 string BUFF_NAME(int i);
 414
 415 #define NOTIF_ARGUMENT_LIST \
 416         ARG_CASE(ARG_CS_SV_HA,  "s1",            s1) \
 417         ARG_CASE(ARG_CS_SV_HA,  "s2",            s2) \
 418         ARG_CASE(ARG_CS_SV_HA,  "s3",            s3) \
 419         ARG_CASE(ARG_CS_SV_HA,  "s4",            s4) \
 420         ARG_CASE(ARG_CS_SV,     "s2loc",         ((autocvar_notification_show_location && (s2 != "")) ? sprintf(( ((tmp_s = autocvar_notification_show_location_string) != "") ? tmp_s : _(" (near %s)") ), s2) : "")) \
 421         ARG_CASE(ARG_CS_SV,     "s3loc",         ((autocvar_notification_show_location && (s3 != "")) ? sprintf(( ((tmp_s = autocvar_notification_show_location_string) != "") ? tmp_s : _(" (near %s)") ), s3) : "")) \
 422         ARG_CASE(ARG_CS_SV_DC,  "f1",            ftos(f1)) \
 423         ARG_CASE(ARG_CS_SV_DC,  "f2",            ftos(f2)) \
 424         ARG_CASE(ARG_CS_SV,     "f3",            ftos(f3)) \
 425         ARG_CASE(ARG_CS_SV,     "f4",            ftos(f4)) \
 426         ARG_CASE(ARG_CS_SV,     "f1dtime",       ftos_decimals(TIME_DECODE(f1), 2)) \
 427         ARG_CASE(ARG_CS_SV,     "f2dtime",       ftos_decimals(TIME_DECODE(f2), 2)) \
 428         ARG_CASE(ARG_CS,        "f2primsec",     (f2 ? _("secondary") : _("primary"))) \
 429         ARG_CASE(ARG_CS,        "f3primsec",     (f3 ? _("secondary") : _("primary"))) \
 430         ARG_CASE(ARG_CS,        "f1secs",        count_seconds(f1)) \
 431         ARG_CASE(ARG_CS,        "f1points",      (f1 == 1 ? _("point") : _("points"))) \
 432         ARG_CASE(ARG_CS_SV,     "f1ord",         count_ordinal(f1)) \
 433         ARG_CASE(ARG_CS_SV,     "f1time",        process_time(2, f1)) \
 434         ARG_CASE(ARG_CS_SV_HA,  "f1race_time",   TIME_ENCODED_TOSTRING(f1, true)) \
 435         ARG_CASE(ARG_CS_SV_HA,  "f2race_time",   TIME_ENCODED_TOSTRING(f2, true)) \
 436         ARG_CASE(ARG_CS_SV_HA,  "f3race_time",   TIME_ENCODED_TOSTRING(f3, true)) \
 437         ARG_CASE(ARG_CS_SV,     "race_col",      CCR(((f1 == 1) ? "^F1" : "^F2"))) \
 438         ARG_CASE(ARG_CS_SV,     "race_diff",     ((f2 > f3) ? sprintf(CCR("^1[+%s]"), TIME_ENCODED_TOSTRING(f2 - f3, true)) : sprintf(CCR("^2[-%s]"), TIME_ENCODED_TOSTRING(f3 - f2, true)))) \
 439         ARG_CASE(ARG_CS,        "missing_teams", notif_arg_missing_teams(f1)) \
 440         ARG_CASE(ARG_CS,        "pass_key",      getcommandkey(_("drop flag"), "+use")) \
 441         ARG_CASE(ARG_CS,        "nade_key",      getcommandkey(_("throw nade"), "dropweapon")) \
 442         ARG_CASE(ARG_CS,        "join_key",      getcommandkey(_("jump"), "+jump")) \
 443         ARG_CASE(ARG_CS,        "frag_ping",     notif_arg_frag_ping(true, f2)) \
 444         ARG_CASE(ARG_CS,        "frag_stats",    notif_arg_frag_stats(f2, f3, f4)) \
 445         /*ARG_CASE(ARG_CS,      "frag_pos",      ((Should_Print_Score_Pos(f1)) ? sprintf("\n^BG%s", Read_Score_Pos(f1)) : ""))*/ \
 446         ARG_CASE(ARG_CS,        "spree_cen",     (autocvar_notification_show_sprees ? notif_arg_spree_cen(f1) : "")) \
 447         ARG_CASE(ARG_CS_SV,     "spree_inf",     (autocvar_notification_show_sprees ? notif_arg_spree_inf(1, input, s2, f2) : "")) \
 448         ARG_CASE(ARG_CS_SV,     "spree_end",     (autocvar_notification_show_sprees ? notif_arg_spree_inf(-1, "", "", f1) : "")) \
 449         ARG_CASE(ARG_CS_SV,     "spree_lost",    (autocvar_notification_show_sprees ? notif_arg_spree_inf(-2, "", "", f1) : "")) \
 450         ARG_CASE(ARG_CS_SV,     "item_wepname",  REGISTRY_GET(Weapons, f1).m_name) \
 451         ARG_CASE(ARG_CS_SV,     "item_buffname", BUFF_NAME(f1)) \
 452         ARG_CASE(ARG_CS_SV,     "f3buffname",    BUFF_NAME(f3)) \
 453         ARG_CASE(ARG_CS_SV,     "item_wepammo",  (f2 > 0 ? notif_arg_item_wepammo(f1, f2) : "")) \
 454         ARG_CASE(ARG_DC,        "item_centime",  ftos(autocvar_notification_item_centerprinttime)) \
 455         ARG_CASE(ARG_SV,        "death_team",    Team_ColoredFullName(f1)) \
 456         ARG_CASE(ARG_CS,        "death_team",    Team_ColoredFullName(f1 - 1)) \
 457         ARG_CASE(ARG_CS_SV_HA,  "minigame1_name",find(NULL,netname,s1).descriptor.message) \
 458         ARG_CASE(ARG_CS_SV_HA,  "minigame1_d",   find(NULL,netname,s1).descriptor.netname)
 459
 460 #define NOTIF_HIT_MAX(count,funcname) MACRO_BEGIN \
 461         if(sel_num == count) { backtrace(sprintf("%s: Hit maximum arguments!\n", funcname)); break; } \
 462 MACRO_END
 463
 464 #define NOTIF_HIT_UNKNOWN(token,funcname) { backtrace(sprintf("%s: Hit unknown token in selected string! '%s'\n", funcname, selected)); break; }
 465
 466 #define KILL_SPREE_LIST \
 467         SPREE_ITEM(3, 03, _("TRIPLE FRAG! "), _("%s^K1 made a TRIPLE FRAG! %s^BG"), _("%s^K1 made a TRIPLE SCORE! %s^BG")) \
 468         SPREE_ITEM(5, 05, _("RAGE! "), _("%s^K1 unlocked RAGE! %s^BG"), _("%s^K1 made FIVE SCORES IN A ROW! %s^BG")) \
 469         SPREE_ITEM(10, 10, _("MASSACRE! "), _("%s^K1 started a MASSACRE! %s^BG"), _("%s^K1 made TEN SCORES IN A ROW! %s^BG")) \
 470         SPREE_ITEM(15, 15, _("MAYHEM! "), _("%s^K1 executed MAYHEM! %s^BG"), _("%s^K1 made FIFTEEN SCORES IN A ROW! %s^BG")) \
 471         SPREE_ITEM(20, 20, _("BERSERKER! "), _("%s^K1 is a BERSERKER! %s^BG"), _("%s^K1 made TWENTY SCORES IN A ROW! %s^BG")) \
 472         SPREE_ITEM(25, 25, _("CARNAGE! "), _("%s^K1 inflicts CARNAGE! %s^BG"), _("%s^K1 made TWENTY FIVE SCORES IN A ROW! %s^BG")) \
 473         SPREE_ITEM(30, 30, _("ARMAGEDDON! "), _("%s^K1 unleashes ARMAGEDDON! %s^BG"), _("%s^K1 made THIRTY SCORES IN A ROW! %s^BG"))
 474
 475 #ifdef CSQC
 476 string notif_arg_frag_ping(bool newline, float fping)
 477 {
 478         string s = newline ? "\n" : " ";
 479         if (fping < 0)
 480                 return sprintf(CCR(_("%s(^F1Bot^BG)")), s);
 481         else
 482                 return sprintf(CCR(_("%s(Ping ^F1%d^BG)")), s, fping);
 483 }
 484
 485 string notif_arg_frag_stats(float fhealth, float farmor, float fping)
 486 {
 487         string s = notif_arg_frag_ping(false, fping);
 488         if (fhealth > 1)
 489                 return sprintf(CCR(_("\n(Health ^1%d^BG / Armor ^2%d^BG)%s")), fhealth, farmor, s);
 490         else
 491                 return sprintf(CCR(_("\n(^F4Dead^BG)%s")), s);
 492 }
 493
 494 string notif_arg_missing_teams(float f1)
 495 {
 496         return strcat(
 497                 ((f1 & BIT(0)) ? strcat(Team_ColoredFullName(NUM_TEAM_1), (f1 >> 1) ? ", " : "") : ""),
 498                 ((f1 & BIT(1)) ? strcat(Team_ColoredFullName(NUM_TEAM_2), (f1 >> 2) ? ", " : "") : ""),
 499                 ((f1 & BIT(2)) ? strcat(Team_ColoredFullName(NUM_TEAM_3), (f1 >> 3) ? ", " : "") : ""),
 500                 ((f1 & BIT(3)) ?        Team_ColoredFullName(NUM_TEAM_4)                         : "")
 501         );
 502 }
 503
 504 string notif_arg_spree_cen(float spree)
 505 {
 506         // 0 = off, 1 = target (but only for first victim) and attacker
 507         if(autocvar_notification_show_sprees_center)
 508         {
 509                 if(spree > 1)
 510                 {
 511                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 512                                 case counta: { return normal_or_gentle(center, sprintf(_("%d score spree! "), spree)); }
 513
 514                         switch(spree)
 515                         {
 516                                 KILL_SPREE_LIST
 517                                 default:
 518                                 {
 519                                         if (!autocvar_notification_show_sprees_center_specialonly)
 520                                         {
 521                                                 return
 522                                                         sprintf(
 523                                                                 normal_or_gentle(
 524                                                                         _("%d frag spree! "),
 525                                                                         _("%d score spree! ")
 526                                                                 ),
 527                                                                 spree);
 528                                         }
 529                                         else { return ""; } // don't show spree information if it isn't an achievement
 530                                 }
 531                         }
 532
 533                         #undef SPREE_ITEM
 534                 }
 535                 else if(spree == -1) // first blood
 536                 {
 537                         return normal_or_gentle(_("First blood! "), _("First score! "));
 538                 }
 539                 else if(spree == -2) // first victim
 540                 {
 541                         return normal_or_gentle(_("First victim! "), _("First casualty! "));
 542                 }
 543         }
 544         return "";
 545 }
 546 #endif
 547
 548 string notif_arg_spree_inf(float type, string input, string player, float spree)
 549 {
 550         switch(type)
 551         {
 552                 case 1: // attacker kill spree
 553                 {
 554                         // 0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker
 555                         // this conditional (& 2) is true for 2 and 3
 556                         if(autocvar_notification_show_sprees_info & 2)
 557                         {
 558                                 #ifdef CSQC
 559                                 string spree_newline =
 560                                         ( autocvar_notification_show_sprees_info_newline ?
 561                                                 ((substring(input, 0, 1) == "\{3}") ? "\n\{3}" : "\n") : "" );
 562                                 #else
 563                                 string spree_newline =
 564                                         (autocvar_notification_show_sprees_info_newline ? "\n" : "");
 565                                 #endif
 566
 567                                 if(spree > 1)
 568                                 {
 569                                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 570                                                 case counta: { return sprintf(CCR(normal_or_gentle(normal, gentle)), player, spree_newline); }
 571
 572                                         switch(spree)
 573                                         {
 574                                                 KILL_SPREE_LIST
 575                                                 default:
 576                                                 {
 577                                                         if (!autocvar_notification_show_sprees_info_specialonly)
 578                                                         {
 579                                                                 return
 580                                                                         sprintf(
 581                                                                                 CCR(normal_or_gentle(
 582                                                                                         _("%s^K1 has %d frags in a row! %s^BG"),
 583                                                                                         _("%s^K1 made %d scores in a row! %s^BG")
 584                                                                                 )),
 585                                                                                 player,
 586                                                                                 spree,
 587                                                                                 spree_newline
 588                                                                         );
 589                                                         }
 590                                                         else { return ""; } // don't show spree information if it isn't an achievement
 591                                                 }
 592                                         }
 593
 594                                         #undef SPREE_ITEM
 595                                 }
 596                                 else if(spree == -1) // firstblood
 597                                 {
 598                                         return
 599                                                 sprintf(
 600                                                         CCR(normal_or_gentle(
 601                                                                 _("%s^K1 drew first blood! %s^BG"),
 602                                                                 _("%s^K1 got the first score! %s^BG")
 603                                                         )),
 604                                                         player,
 605                                                         spree_newline
 606                                                 );
 607                                 }
 608                         }
 609                         break;
 610                 }
 611
 612                 case -1: // kill spree ended
 613                 {
 614                         if((spree > 1) && (autocvar_notification_show_sprees_info & 1))
 615                         {
 616                                 return
 617                                         sprintf(normal_or_gentle(
 618                                                 _(", ending their %d frag spree"),
 619                                                 _(", ending their %d score spree")
 620                                                 ),
 621                                                 spree
 622                                         );
 623                         }
 624                         break;
 625                 }
 626
 627                 case -2: // kill spree lost
 628                 {
 629                         if((spree > 1) && (autocvar_notification_show_sprees_info & 1))
 630                         {
 631                                 return
 632                                         sprintf(normal_or_gentle(
 633                                                 _(", losing their %d frag spree"),
 634                                                 _(", losing their %d score spree")
 635                                                 ),
 636                                                 spree
 637                                         );
 638                         }
 639                         break;
 640                 }
 641         }
 642         return "";
 643 }
 644
 645 string notif_arg_item_wepammo(float f1, float f2)
 646 {
 647         string ammoitems = "";
 648         Weapon wep = REGISTRY_GET(Weapons, f1);
 649         // TODO: registry handles
 650         switch (wep.ammo_type)
 651         {
 652                 case RES_SHELLS:  ammoitems = ITEM_Shells.m_name;      break;
 653                 case RES_BULLETS: ammoitems = ITEM_Bullets.m_name;     break;
 654                 case RES_ROCKETS: ammoitems = ITEM_Rockets.m_name;     break;
 655                 case RES_CELLS:   ammoitems = ITEM_Cells.m_name;       break;
 656                 case RES_PLASMA:  ammoitems = ITEM_Plasma.m_name;      break;
 657                 case RES_FUEL:    ammoitems = ITEM_JetpackFuel.m_name; break;
 658                 default: return ""; // doesn't use ammo
 659         }
 660         return sprintf(_(" with %d %s"), f2, strtolower(ammoitems));
 661 }
 662
 663
 664 // ====================================
 665 //  Initialization/Create Declarations
 666 // ====================================
 667
 668 // common notification entity values
 669 .int nent_default;
 670 .bool nent_enabled;
 671 .MSG nent_type;
 672 .string nent_name;
 673 .int nent_stringcount;
 674 .int nent_floatcount;
 675 .int nent_teamnum;
 676
 677 // MSG_ANNCE entity values
 678 .int nent_channel;
 679 .string nent_snd;
 680 .float nent_vol;
 681 .float nent_position;
 682 .float nent_queuetime;
 683
 684 // MSG_INFO and MSG_CENTER entity values
 685 .string nent_args; // used by both
 686 .string nent_hudargs; // used by info
 687 .string nent_icon; // used by info
 688 .CPID nent_cpid; // used by center
 689 .string nent_durcnt; // used by center
 690 .string nent_string; // used by both
 691
 692 // MSG_MULTI entity values
 693 .entity nent_msgannce;
 694 .entity nent_msginfo;
 695 .entity nent_msgcenter;
 696
 697 // MSG_CHOICE entity values
 698 .float nent_challow_def;
 699 .float nent_challow_var;
 700 .entity nent_optiona;
 701 .entity nent_optionb;
 702
 703 // networked notification entity values
 704 #ifdef SVQC
 705 .NOTIF nent_broadcast;
 706 #endif
 707 .entity nent_client;
 708 .MSG nent_net_type;
 709 .float nent_net_name;
 710 .string nent_strings[4];
 711 .float nent_floats[4];
 712
 713 #define ACVNN(name) autocvar_notification_##name
 714
 715 REGISTRY(Notifications, BITS(11))
 716 REGISTER_REGISTRY(Notifications)
 717 REGISTRY_SORT(Notifications)
 718
 719 REGISTRY_DEFINE_GET(Notifications, NULL)
 720 STATIC_INIT(Notifications) { FOREACH(Notifications, true, it.m_id = i); }
 721 REGISTRY_CHECK(Notifications)
 722
 723 const int NOTIF_CHOICE_MAX = 20;
 724 // NOTE: a team choice is actually made of 4 choices (one per team) with the same nent_choice_idx
 725 // thus they are counted as 1 in nent_choice_count
 726 int nent_choice_count = 0;
 727 .int nent_choice_idx;
 728 .int msg_choice_choices[NOTIF_CHOICE_MAX]; // set on each player containing MSG_CHOICE choices
 729 // initialization error detection
 730 bool notif_error;
 731 bool notif_global_error;
 732
 733 STATIC_INIT_LATE(Notif_Choices)
 734 {
 735         if (nent_choice_count > NOTIF_CHOICE_MAX)
 736                 LOG_FATALF("Too many MSG_CHOICE notifications (%d), hit NOTIF_CHOICE_MAX (%d) limit",
 737                         nent_choice_count, NOTIF_CHOICE_MAX);
 738 }
 739
 740 string Get_Notif_CvarName(Notification notif)
 741 {
 742         if(!notif.nent_teamnum)
 743                 return notif.nent_name;
 744         return substring(notif.nent_name, 0, -strlen(Static_Team_ColorName(notif.nent_teamnum)) - 2);
 745 }
 746
 747 Notification Get_Notif_Ent(MSG net_type, int net_name)
 748 {
 749         Notification it = REGISTRY_GET(Notifications, net_name);
 750         if (it.nent_type != net_type) {
 751                 LOG_WARNF("Get_Notif_Ent(%s (%d), %s (%d)): Improper net type '%s'!",
 752                         Get_Notif_TypeName(net_type), net_type,
 753                         it.registered_id, net_name,
 754                         Get_Notif_TypeName(it.nent_type)
 755                 );
 756                 return NULL;
 757         }
 758         return it;
 759 }
 760
 761 #define MSG_ANNCE_NOTIF_TEAM(teamnum, name, cvarname, defaultvalue, sound, channel, volume, position, queuetime) \
 762         MSG_ANNCE_NOTIF_(teamnum, ANNCE_##name, ANNCE_##cvarname, defaultvalue, sound, channel, volume, position, queuetime)
 763
 764 #define MSG_ANNCE_NOTIF(name, defaultvalue, sound, channel, volume, position, queuetime) \
 765         NOTIF_ADD_AUTOCVAR(ANNCE_##name, defaultvalue) \
 766         MSG_ANNCE_NOTIF_(0, ANNCE_##name, ANNCE_##name, defaultvalue, sound, channel, volume, position, queuetime)
 767
 768 #define MSG_ANNCE_NOTIF_(teamnum, name, cvarname, defaultvalue, sound, channel, volume, position, queuetime) \
 769         REGISTER(Notifications, name, m_id, new_pure(msg_annce_notification)) { \
 770                 Create_Notification_Entity      (this, defaultvalue, ACVNN(cvarname), MSG_ANNCE, strtoupper(#name), teamnum); \
 771                 Create_Notification_Entity_Annce(this, ACVNN(cvarname), strtoupper(#name), \
 772                         channel,    /* channel   */ \
 773                         sound,      /* snd       */ \
 774                         volume,     /* vol       */ \
 775                         position,   /* position  */ \
 776                         queuetime); /* queuetime */ \
 777         }
 778
 779 #define MSG_INFO_NOTIF_TEAM(teamnum, name, cvarname, defaultvalue, strnum, flnum, args, hudargs, icon, normal, gentle) \
 780         MSG_INFO_NOTIF_(teamnum, INFO_##name, INFO_##cvarname, defaultvalue, strnum, flnum, args, hudargs, icon, normal, gentle)
 781
 782 #define MSG_INFO_NOTIF(name, defaultvalue, strnum, flnum, args, hudargs, icon, normal, gentle) \
 783         NOTIF_ADD_AUTOCVAR(INFO_##name, defaultvalue) \
 784         MSG_INFO_NOTIF_(0, INFO_##name, INFO_##name, defaultvalue, strnum, flnum, args, hudargs, icon, normal, gentle)
 785
 786 #define MSG_INFO_NOTIF_(teamnum, name, cvarname, defaultvalue, strnum, flnum, args, hudargs, icon, normal, gentle) \
 787         REGISTER(Notifications, name, m_id, new_pure(msg_info_notification)) { \
 788                 Create_Notification_Entity           (this, defaultvalue, ACVNN(cvarname), MSG_INFO, strtoupper(#name), teamnum); \
 789                 Create_Notification_Entity_InfoCenter(this, ACVNN(cvarname), strtoupper(#name), strnum, flnum, \
 790                         args,     /* args    */ \
 791                         hudargs,  /* hudargs */ \
 792                         icon,     /* icon    */ \
 793                         CPID_Null,/* cpid    */ \
 794                         "",       /* durcnt  */ \
 795                         normal,   /* normal  */ \
 796                         gentle);  /* gentle  */ \
 797         }
 798
 799 .string nent_iconargs;
 800 #define MULTIICON_INFO(name, defaultvalue, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle) \
 801         MULTIICON_INFO_(INFO_##name, defaultvalue, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle)
 802 #define MULTIICON_INFO_(name, defaultvalue, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle) \
 803         NOTIF_ADD_AUTOCVAR(name, defaultvalue) \
 804         REGISTER(Notifications, name, m_id, new_pure(msg_info_notification)) { \
 805                 Create_Notification_Entity           (this, defaultvalue, ACVNN(name), MSG_INFO, strtoupper(#name), 0); \
 806                 Create_Notification_Entity_InfoCenter(this, ACVNN(name), strtoupper(#name), strnum, flnum, \
 807                         args,     /* args    */ \
 808                         hudargs,  /* hudargs */ \
 809                         icon,     /* icon    */ \
 810                         CPID_Null,/* cpid    */ \
 811                         "",       /* durcnt  */ \
 812                         normal,   /* normal  */ \
 813                         gentle);  /* gentle  */ \
 814                 this.nent_iconargs = iconargs; \
 815         }
 816
 817 #define MSG_CENTER_NOTIF_TEAM(teamnum, name, cvarname, defaultvalue, strnum, flnum, args, cpid, durcnt, normal, gentle) \
 818         MSG_CENTER_NOTIF_(teamnum, CENTER_##name, CENTER_##cvarname, defaultvalue, strnum, flnum, args, cpid, durcnt, normal, gentle)
 819
 820 #define MSG_CENTER_NOTIF(name, defaultvalue, strnum, flnum, args, cpid, durcnt, normal, gentle) \
 821         NOTIF_ADD_AUTOCVAR(CENTER_##name, defaultvalue) \
 822         MSG_CENTER_NOTIF_(0, CENTER_##name, CENTER_##name, defaultvalue, strnum, flnum, args, cpid, durcnt, normal, gentle)
 823
 824 #define MSG_CENTER_NOTIF_(teamnum, name, cvarname, defaultvalue, strnum, flnum, args, cpid, durcnt, normal, gentle) \
 825         REGISTER(Notifications, name, m_id, new_pure(msg_center_notification)) { \
 826                 Create_Notification_Entity           (this, defaultvalue, ACVNN(cvarname), MSG_CENTER, strtoupper(#name), teamnum); \
 827                 Create_Notification_Entity_InfoCenter(this, ACVNN(cvarname), strtoupper(#name), strnum, flnum, \
 828                         args,    /* args    */ \
 829                         "",      /* hudargs */ \
 830                         "",      /* icon    */ \
 831                         cpid,    /* cpid    */ \
 832                         durcnt,  /* durcnt  */ \
 833                         normal,  /* normal  */ \
 834                         gentle); /* gentle  */ \
 835         }
 836
 837 #define MSG_MULTI_NOTIF(name, defaultvalue, anncename, infoname, centername) \
 838         NOTIF_ADD_AUTOCVAR(name, defaultvalue) \
 839         REGISTER(Notifications, name, m_id, new_pure(msg_multi_notification)) { \
 840                 Create_Notification_Entity      (this, defaultvalue, ACVNN(name), MSG_MULTI, strtoupper(#name), 0); \
 841                 Create_Notification_Entity_Multi(this, ACVNN(name), strtoupper(#name), \
 842                         anncename,   /* anncename  */ \
 843                         infoname,    /* infoname   */ \
 844                         centername); /* centername */ \
 845         }
 846
 847 #define MSG_CHOICE_NOTIF_TEAM(teamnum, name, cvarname, defaultvalue, challow, chtype, optiona, optionb) \
 848         MSG_CHOICE_NOTIF_(teamnum, CHOICE_##name, CHOICE_##cvarname, defaultvalue, challow, chtype, optiona, optionb)
 849
 850 #define MSG_CHOICE_NOTIF(name, defaultvalue, challow, chtype, optiona, optionb) \
 851         NOTIF_ADD_AUTOCVAR(CHOICE_##name, defaultvalue) \
 852         NOTIF_ADD_AUTOCVAR(CHOICE_##name##_ALLOWED, challow) \
 853         MSG_CHOICE_NOTIF_(0, CHOICE_##name, CHOICE_##name, defaultvalue, challow, chtype, optiona, optionb)
 854
 855 #define MSG_CHOICE_NOTIF_(teamnum, name, cvarname, defaultvalue, challow, chtype, optiona, optionb) \
 856         REGISTER(Notifications, name, m_id, new_pure(msg_choice_notification)) { \
 857                 this.nent_choice_idx = nent_choice_count; \
 858                 if (!teamnum || teamnum == NUM_TEAM_4) \
 859                         nent_choice_count++; \
 860                 Create_Notification_Entity       (this, defaultvalue, ACVNN(cvarname), MSG_CHOICE, strtoupper(#name), teamnum); \
 861                 Create_Notification_Entity_Choice(this, ACVNN(cvarname), strtoupper(#name), \
 862                         challow,                                 /* challow_def */ \
 863                         autocvar_notification_##cvarname##_ALLOWED,  /* challow_var */ \
 864                         chtype,                                  /* chtype      */ \
 865                         optiona,                                 /* optiona     */ \
 866                         optionb);                                /* optionb     */ \
 867         }
 868
 869 REGISTRY_BEGIN(Notifications)
 870 {
 871         notif_global_error = false;
 872 }
 873
 874 REGISTRY_END(Notifications)
 875 {
 876         if (!notif_global_error) return;
 877         // shit happened... stop the loading of the program now if this is unacceptable
 878         if (autocvar_notification_errors_are_fatal)
 879                 LOG_FATAL("Notification initialization failed! Read above and fix the errors!");
 880         else
 881                 LOG_SEVERE("Notification initialization failed! Read above and fix the errors!");
 882 }
 883
 884 #ifdef CSQC
 885 .int cvar_value;
 886 void ReplicateVars(bool would_destroy)
 887 {
 888         if (!would_destroy)
 889                 FOREACH(Notifications, it.nent_type == MSG_CHOICE && (!it.nent_teamnum || it.nent_teamnum == NUM_TEAM_1), {
 890                         string cvarname = strcat("notification_", Get_Notif_CvarName(it));
 891                         // NOTE: REPLICATE_SIMPLE can return;
 892                         REPLICATE_SIMPLE(it.cvar_value, cvarname);
 893                 });
 894 }
 895 #endif
 896
 897 #include "all.inc"