qcsrc/server/w_crylink.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(CRYLINK, w_crylink, IT_CELLS, 6, WEP_FLAG_NORMAL | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_MID, "crylink", "crylink", "Crylink");
   3 #else
   4 #ifdef SVQC
   5 .float gravity;
   6 .float crylink_waitrelease;
   7 .entity crylink_lastgroup;
   8
   9 .entity queuenext;
  10 .entity queueprev;
  11
  12 void W_Crylink_Dequeue_Raw(entity own, entity prev, entity me, entity next)
  13 {
  14         if(me == own.crylink_lastgroup)
  15                 own.crylink_lastgroup = ((me == next) ? world : next);
  16         prev.queuenext = next;
  17         next.queueprev = prev;
  18 }
  19
  20 void W_Crylink_Dequeue(entity e)
  21 {
  22         W_Crylink_Dequeue_Raw(e.realowner, e.queueprev, e, e.queuenext);
  23 }
  24
  25 // force projectile to explode
  26 void W_Crylink_LinkExplode (entity e, entity e2)
  27 {
  28         float a;
  29         a = bound(0, 1 - (time - e.fade_time) * e.fade_rate, 1);
  30
  31         if(e == e.realowner.crylink_lastgroup)
  32                 e.realowner.crylink_lastgroup = world;
  33
  34         RadiusDamage (e, e.realowner, cvar("g_balance_crylink_primary_damage") * a, cvar("g_balance_crylink_primary_edgedamage") * a, cvar("g_balance_crylink_primary_radius"), world, cvar("g_balance_crylink_primary_force") * a, e.projectiledeathtype, other);
  35
  36         if(e.queuenext != e2)
  37                 W_Crylink_LinkExplode(e.queuenext, e2);
  38
  39         remove (e);
  40 }
  41
  42 // adjust towards center
  43 // returns the origin where they will meet... and the time till the meeting is
  44 // stored in w_crylink_linkjoin_time.
  45 // could possibly network this origin and time, and display a special particle
  46 // effect when projectiles meet there :P
  47 // jspeed: MINIMUM jing speed
  48 // jtime: MAXIMUM jing time (0: none)
  49 float w_crylink_linkjoin_time;
  50 vector W_Crylink_LinkJoin(entity e, float jspeed, float jtime)
  51 {
  52         vector avg_origin, avg_velocity;
  53         vector targ_origin;
  54         float avg_dist, n;
  55         entity p;
  56
  57         w_crylink_linkjoin_time = 0;
  58
  59         avg_origin = e.origin;
  60         avg_velocity = e.velocity;
  61         n = 1;
  62         for(p = e; (p = p.queuenext) != e; )
  63         {
  64                 avg_origin += WarpZone_RefSys_TransformOrigin(p, e, p.origin);
  65                 avg_velocity += WarpZone_RefSys_TransformVelocity(p, e, p.velocity);
  66                 ++n;
  67         }
  68         avg_origin *= (1.0 / n);
  69         avg_velocity *= (1.0 / n);
  70
  71         if(n < 2)
  72                 return avg_origin; // nothing to do
  73
  74         // yes, mathematically we can do this in ONE step, but beware of 32bit floats...
  75         avg_dist = pow(vlen(e.origin - avg_origin), 2);
  76         for(p = e; (p = p.queuenext) != e; )
  77                 avg_dist += pow(vlen(WarpZone_RefSys_TransformOrigin(p, e, p.origin) - avg_origin), 2);
  78         avg_dist *= (1.0 / n);
  79         avg_dist = sqrt(avg_dist);
  80
  81         if(avg_dist == 0)
  82                 return avg_origin; // no change needed
  83
  84         if(jspeed == 0 && jtime == 0)
  85         {
  86                 e.velocity = avg_velocity;
  87                 UpdateCSQCProjectile(e);
  88                 for(p = e; (p = p.queuenext) != e; )
  89                 {
  90                         p.velocity = WarpZone_RefSys_TransformVelocity(e, p, avg_velocity);
  91                         UpdateCSQCProjectile(p);
  92                 }
  93         }
  94         else
  95         {
  96                 if(jtime)
  97                 {
  98                         if(jspeed)
  99                                 w_crylink_linkjoin_time = min(jtime, avg_dist / jspeed);
 100                         else
 101                                 w_crylink_linkjoin_time = jtime;
 102                 }
 103                 else
 104                         w_crylink_linkjoin_time = avg_dist / jspeed;
 105                 targ_origin = avg_origin + w_crylink_linkjoin_time * avg_velocity;
 106
 107                 e.velocity = (targ_origin - e.origin) * (1.0 / w_crylink_linkjoin_time);
 108                 UpdateCSQCProjectile(e);
 109                 for(p = e; (p = p.queuenext) != e; )
 110                 {
 111                         p.velocity = WarpZone_RefSys_TransformVelocity(e, p, (targ_origin - WarpZone_RefSys_TransformOrigin(p, e, p.origin)) * (1.0 / w_crylink_linkjoin_time));
 112                         UpdateCSQCProjectile(p);
 113                 }
 114
 115                 // analysis:
 116                 //   jspeed -> +infinity:
 117                 //      w_crylink_linkjoin_time -> +0
 118                 //      targ_origin -> avg_origin
 119                 //      p->velocity -> HUEG towards center
 120                 //   jspeed -> 0:
 121                 //      w_crylink_linkjoin_time -> +/- infinity
 122                 //      targ_origin -> avg_velocity * +/- infinity
 123                 //      p->velocity -> avg_velocity
 124                 //   jspeed -> -infinity:
 125                 //      w_crylink_linkjoin_time -> -0
 126                 //      targ_origin -> avg_origin
 127                 //      p->velocity -> HUEG away from center
 128         }
 129
 130         return targ_origin;
 131 }
 132
 133 void W_Crylink_LinkJoinEffect_Think()
 134 {
 135         // is there at least 2 projectiles very close?
 136         entity e, p;
 137         float n;
 138         e = self.owner.crylink_lastgroup;
 139         n = 0;
 140         if(e)
 141         {
 142                 if(vlen(e.origin - self.origin) < vlen(e.velocity) * frametime)
 143                         ++n;
 144                 for(p = e; (p = p.queuenext) != e; )
 145                 {
 146                         if(vlen(p.origin - self.origin) < vlen(p.velocity) * frametime)
 147                                 ++n;
 148                 }
 149                 if(n >= 2)
 150                 {
 151
 152
 153                         if(e.projectiledeathtype & HITTYPE_SECONDARY)
 154                         {
 155                                 if(cvar("g_balance_crylink_secondary_joinexplode"))
 156                                 {
 157                                         n = n / cvar("g_balance_crylink_secondary_shots");
 158                                         RadiusDamage (e, e.realowner, cvar("g_balance_crylink_secondary_joinexplode_damage") * n,
 159                                                                         cvar("g_balance_crylink_secondary_joinexplode_edgedamage") * n,
 160                                                                         cvar("g_balance_crylink_secondary_joinexplode_radius") * n, world,
 161                                                                         cvar("g_balance_crylink_secondary_joinexplode_force") * n, e.projectiledeathtype, other);
 162                                 }
 163                         }
 164                         else
 165                         {
 166                                 if(cvar("g_balance_crylink_primary_joinexplode"))
 167                                 {
 168                                         n = n / cvar("g_balance_crylink_primary_shots");
 169                                         RadiusDamage (e, e.realowner, cvar("g_balance_crylink_primary_joinexplode_damage") * n,
 170                                                                         cvar("g_balance_crylink_primary_joinexplode_edgedamage") * n,
 171                                                                         cvar("g_balance_crylink_primary_joinexplode_radius") * n, world,
 172                                                                         cvar("g_balance_crylink_primary_joinexplode_force") * n, e.projectiledeathtype, other);
 173                                 }
 174                         }
 175
 176                         // they seem to touch...
 177                         // TODO make a specific particle effect for this
 178                         pointparticles(particleeffectnum("crylink_linkjoin"), self.origin, '0 0 0', 1);
 179                 }
 180         }
 181         remove(self);
 182 }
 183
 184
 185 // NO bounce protection, as bounces are limited!
 186 void W_Crylink_Touch (void)
 187 {
 188         float finalhit;
 189         float f;
 190         //PROJECTILE_TOUCH;
 191         local entity savenext, saveprev, saveown;
 192         saveown = self.realowner;
 193         savenext = self.queuenext;
 194         saveprev = self.queueprev;
 195         if(WarpZone_Projectile_Touch())
 196         {
 197                 if(wasfreed(self))
 198                         W_Crylink_Dequeue_Raw(saveown, saveprev, self, savenext);
 199                 return;
 200         }
 201
 202         float a;
 203         a = bound(0, 1 - (time - self.fade_time) * self.fade_rate, 1);
 204
 205         finalhit = ((self.cnt <= 0) || (other.takedamage != DAMAGE_NO));
 206         if(finalhit)
 207                 f = 1;
 208         else
 209                 f = cvar("g_balance_crylink_primary_bouncedamagefactor");
 210         if(a)
 211                 f *= a;
 212         if (RadiusDamage (self, self.realowner, cvar("g_balance_crylink_primary_damage") * f, cvar("g_balance_crylink_primary_edgedamage") * f, cvar("g_balance_crylink_primary_radius"), world, cvar("g_balance_crylink_primary_force") * f, self.projectiledeathtype, other) && cvar("g_balance_crylink_primary_linkexplode"))
 213         {
 214                 W_Crylink_LinkExplode(self.queuenext, self);
 215                 remove (self);
 216                 return;
 217         }
 218         else if(finalhit)
 219         {
 220                 // just unlink
 221                 W_Crylink_Dequeue(self);
 222                 remove(self);
 223                 return;
 224         }
 225         self.cnt = self.cnt - 1;
 226         self.angles = vectoangles(self.velocity);
 227         self.owner = world;
 228         self.projectiledeathtype |= HITTYPE_BOUNCE;
 229         // commented out as it causes a little hitch...
 230         //if(proj.cnt == 0)
 231         //      CSQCProjectile(proj, TRUE, PROJECTILE_CRYLINK, TRUE);
 232 }
 233
 234 void W_Crylink_Touch2 (void)
 235 {
 236         float finalhit;
 237         float f;
 238         //PROJECTILE_TOUCH;
 239         local entity savenext, saveprev, saveown;
 240         savenext = self.queuenext;
 241         saveprev = self.queueprev;
 242         saveown = self.realowner;
 243         if(WarpZone_Projectile_Touch())
 244         {
 245                 if(wasfreed(self))
 246                         W_Crylink_Dequeue_Raw(saveown, saveprev, self, savenext);
 247                 return;
 248         }
 249
 250         float a;
 251         a = 1 - (time - self.fade_time) * self.fade_rate;
 252
 253         finalhit = ((self.cnt <= 0) || (other.takedamage != DAMAGE_NO));
 254         if(finalhit)
 255                 f = 1;
 256         else
 257                 f = cvar("g_balance_crylink_secondary_bouncedamagefactor");
 258         if(a)
 259                 f *= a;
 260         if (RadiusDamage (self, self.realowner, cvar("g_balance_crylink_secondary_damage") * f, cvar("g_balance_crylink_secondary_edgedamage") * f, cvar("g_balance_crylink_secondary_radius"), world, cvar("g_balance_crylink_secondary_force") * f, self.projectiledeathtype, other) && cvar("g_balance_crylink_secondary_linkexplode"))
 261         {
 262                 W_Crylink_LinkExplode(self.queuenext, self);
 263                 remove (self);
 264                 return;
 265         }
 266         else if(finalhit)
 267         {
 268                 // just unlink
 269                 W_Crylink_Dequeue(self);
 270                 remove(self);
 271                 return;
 272         }
 273         self.cnt = self.cnt - 1;
 274         self.angles = vectoangles(self.velocity);
 275         self.owner = world;
 276         self.projectiledeathtype |= HITTYPE_BOUNCE;
 277         // commented out as it causes a little hitch...
 278         //if(proj.cnt == 0)
 279         //      CSQCProjectile(proj, TRUE, PROJECTILE_CRYLINK, TRUE);
 280 }
 281
 282 void W_Crylink_Fadethink (void)
 283 {
 284         W_Crylink_Dequeue(self);
 285         remove(self);
 286 }
 287
 288 void W_Crylink_Attack (void)
 289 {
 290         local float counter, shots;
 291         local entity proj, prevproj, firstproj;
 292         local vector s;
 293         vector forward, right, up;
 294
 295         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 296                 self.ammo_cells = self.ammo_cells - cvar("g_balance_crylink_primary_ammo");
 297
 298         W_SetupShot (self, FALSE, 2, "weapons/crylink_fire.wav", (cvar("g_balance_crylink_primary_damage")*cvar("g_balance_crylink_primary_shots")));
 299         forward = v_forward;
 300         right = v_right;
 301         up = v_up;
 302
 303         shots = cvar("g_balance_crylink_primary_shots");
 304         pointparticles(particleeffectnum("crylink_muzzleflash"), w_shotorg, w_shotdir * 1000, shots);
 305         proj = world;
 306         while (counter < shots)
 307         {
 308                 proj = spawn ();
 309                 proj.realowner = proj.owner = self;
 310                 proj.classname = "spike";
 311                 proj.bot_dodge = TRUE;
 312                 proj.bot_dodgerating = cvar("g_balance_crylink_primary_damage");
 313                 if(counter == 0) { // first projectile, store in firstproj for now
 314                         firstproj = proj;
 315                 }
 316                 else if(counter == shots - 1) { // last projectile, link up with first projectile
 317                         prevproj.queuenext = proj;
 318                         firstproj.queueprev = proj;
 319                         proj.queuenext = firstproj;
 320                         proj.queueprev = prevproj;
 321                 }
 322                 else { // else link up with previous projectile
 323                         prevproj.queuenext = proj;
 324                         proj.queueprev = prevproj;
 325                 }
 326
 327                 prevproj = proj;
 328
 329                 proj.movetype = MOVETYPE_BOUNCEMISSILE;
 330                 PROJECTILE_MAKETRIGGER(proj);
 331                 proj.projectiledeathtype = WEP_CRYLINK;
 332                 //proj.gravity = 0.001;
 333
 334                 setorigin (proj, w_shotorg);
 335                 setsize(proj, '0 0 0', '0 0 0');
 336
 337
 338                 s = '0 0 0';
 339                 if (counter == 0)
 340                         s = '0 0 0';
 341                 else
 342                 {
 343                         makevectors('0 360 0' * (0.75 + (counter - 0.5) / (shots - 1)));
 344                         s_y = v_forward_x;
 345                         s_z = v_forward_y;
 346                 }
 347                 s = s * cvar("g_balance_crylink_primary_spread") * g_weaponspreadfactor;
 348                 W_SetupProjectileVelocityEx(proj, w_shotdir + right * s_y + up * s_z, v_up, cvar("g_balance_crylink_primary_speed"), 0, 0, 0);
 349                 proj.touch = W_Crylink_Touch;
 350
 351                 proj.think = W_Crylink_Fadethink;
 352                 if(counter == 0)
 353                 {
 354                         proj.fade_time = time + cvar("g_balance_crylink_primary_middle_lifetime");
 355                         self.fade_rate = 1 / cvar("g_balance_crylink_primary_middle_fadetime");
 356                         proj.nextthink = time + cvar("g_balance_crylink_primary_middle_lifetime") + cvar("g_balance_crylink_primary_middle_fadetime");
 357                 }
 358                 else
 359                 {
 360                         proj.fade_time = time + cvar("g_balance_crylink_primary_other_lifetime");
 361                         self.fade_rate = 1 / cvar("g_balance_crylink_primary_other_fadetime");
 362                         proj.nextthink = time + cvar("g_balance_crylink_primary_other_lifetime") + cvar("g_balance_crylink_primary_other_fadetime");
 363                 }
 364                 proj.cnt = cvar("g_balance_crylink_primary_bounces");
 365                 //proj.scale = 1 + 1 * proj.cnt;
 366
 367                 proj.angles = vectoangles (proj.velocity);
 368
 369                 //proj.glow_size = 20;
 370
 371                 proj.flags = FL_PROJECTILE;
 372
 373                 CSQCProjectile(proj, TRUE, (proj.cnt ? PROJECTILE_CRYLINK_BOUNCING : PROJECTILE_CRYLINK), TRUE);
 374
 375                 other = proj; MUTATOR_CALLHOOK(EditProjectile);
 376
 377                 counter = counter + 1;
 378         }
 379         self.crylink_lastgroup = proj;
 380 }
 381
 382 void W_Crylink_Attack2 (void)
 383 {
 384         local float counter, shots;
 385         local entity proj, prevproj, firstproj;
 386
 387         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 388                 self.ammo_cells = self.ammo_cells - cvar("g_balance_crylink_secondary_ammo");
 389
 390         W_SetupShot (self, FALSE, 2, "weapons/crylink_fire2.wav", (cvar("g_balance_crylink_secondary_damage")*cvar("g_balance_crylink_secondary_shots")));
 391
 392         shots = cvar("g_balance_crylink_secondary_shots");
 393         pointparticles(particleeffectnum("crylink_muzzleflash"), w_shotorg, w_shotdir * 1000, shots);
 394         proj = world;
 395         while (counter < shots)
 396         {
 397                 proj = spawn ();
 398                 proj.realowner = proj.owner = self;
 399                 proj.classname = "spike";
 400                 proj.bot_dodge = TRUE;
 401                 proj.bot_dodgerating = cvar("g_balance_crylink_secondary_damage");
 402                 if(counter == 0) { // first projectile, store in firstproj for now
 403                         firstproj = proj;
 404                 }
 405                 else if(counter == shots - 1) { // last projectile, link up with first projectile
 406                         prevproj.queuenext = proj;
 407                         firstproj.queueprev = proj;
 408                         proj.queuenext = firstproj;
 409                         proj.queueprev = prevproj;
 410                 }
 411                 else { // else link up with previous projectile
 412                         prevproj.queuenext = proj;
 413                         proj.queueprev = prevproj;
 414                 }
 415
 416                 prevproj = proj;
 417
 418                 proj.movetype = MOVETYPE_BOUNCEMISSILE;
 419                 PROJECTILE_MAKETRIGGER(proj);
 420                 proj.projectiledeathtype = WEP_CRYLINK | HITTYPE_SECONDARY;
 421                 //proj.gravity = 0.001;
 422
 423                 setorigin (proj, w_shotorg);
 424                 setsize(proj, '0 0 0', '0 0 0');
 425
 426                 W_SetupProjectileVelocityEx(proj, (w_shotdir + (((counter + 0.5) / shots) * 2 - 1) * v_right * cvar("g_balance_crylink_secondary_spread") * g_weaponspreadfactor), v_up, cvar("g_balance_crylink_secondary_speed"), 0, 0, 0);
 427                 proj.touch = W_Crylink_Touch2;
 428                 proj.think = W_Crylink_Fadethink;
 429                 if(counter == (shots - 1) / 2)
 430                 {
 431                         proj.fade_time = time + cvar("g_balance_crylink_secondary_middle_lifetime");
 432                         self.fade_rate = 1 / cvar("g_balance_crylink_secondary_middle_fadetime");
 433                         proj.nextthink = time + cvar("g_balance_crylink_secondary_middle_lifetime") + cvar("g_balance_crylink_secondary_middle_fadetime");
 434                 }
 435                 else
 436                 {
 437                         proj.fade_time = time + cvar("g_balance_crylink_secondary_line_lifetime");
 438                         self.fade_rate = 1 / cvar("g_balance_crylink_secondary_line_fadetime");
 439                         proj.nextthink = time + cvar("g_balance_crylink_secondary_line_lifetime") + cvar("g_balance_crylink_secondary_line_fadetime");
 440                 }
 441                 proj.cnt = cvar("g_balance_crylink_secondary_bounces");
 442                 //proj.scale = 1 + 1 * proj.cnt;
 443
 444                 proj.angles = vectoangles (proj.velocity);
 445
 446                 //proj.glow_size = 20;
 447
 448                 proj.flags = FL_PROJECTILE;
 449
 450                 CSQCProjectile(proj, TRUE, (proj.cnt ? PROJECTILE_CRYLINK_BOUNCING : PROJECTILE_CRYLINK), TRUE);
 451
 452                 other = proj; MUTATOR_CALLHOOK(EditProjectile);
 453
 454                 counter = counter + 1;
 455         }
 456         self.crylink_lastgroup = proj;
 457 }
 458
 459 void spawnfunc_weapon_crylink (void)
 460 {
 461         weapon_defaultspawnfunc(WEP_CRYLINK);
 462 }
 463
 464 float w_crylink(float req)
 465 {
 466         if (req == WR_AIM)
 467         {
 468                 if (random() > 0.15)
 469                         self.BUTTON_ATCK = bot_aim(cvar("g_balance_crylink_primary_speed"), 0, cvar("g_balance_crylink_primary_middle_lifetime"), FALSE);
 470                 else
 471                         self.BUTTON_ATCK2 = bot_aim(cvar("g_balance_crylink_secondary_speed"), 0, cvar("g_balance_crylink_secondary_middle_lifetime"), FALSE);
 472         }
 473         else if (req == WR_THINK)
 474         {
 475                 if (self.BUTTON_ATCK)
 476                 {
 477                         if (!self.crylink_waitrelease)
 478                         if (weapon_prepareattack(0, cvar("g_balance_crylink_primary_refire")))
 479                         {
 480                                 W_Crylink_Attack();
 481                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_crylink_primary_animtime"), w_ready);
 482                                 if(cvar("g_balance_crylink_primary_joinspeed") != 0 || cvar("g_balance_crylink_primary_jointime") != 0)
 483                                         self.crylink_waitrelease = 1;
 484                         }
 485                 }
 486                 else if(self.BUTTON_ATCK2 && cvar("g_balance_crylink_secondary"))
 487                 {
 488                         if (!self.crylink_waitrelease)
 489                         if (weapon_prepareattack(1, cvar("g_balance_crylink_secondary_refire")))
 490                         {
 491                                 W_Crylink_Attack2();
 492                                 weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_crylink_secondary_animtime"), w_ready);
 493                                 if(cvar("g_balance_crylink_secondary_joinspeed") != 0 || cvar("g_balance_crylink_secondary_jointime") != 0)
 494                                         self.crylink_waitrelease = 2;
 495                         }
 496                 }
 497                 else
 498                 {
 499                         if (self.crylink_waitrelease)
 500                         {
 501                                 // fired and released now!
 502                                 if(self.crylink_lastgroup)
 503                                 {
 504                                         vector pos;
 505                                         entity linkjoineffect;
 506
 507
 508                                         if(self.crylink_waitrelease == 1)
 509                                         {
 510                                                 pos = W_Crylink_LinkJoin(self.crylink_lastgroup, cvar("g_balance_crylink_primary_joinspeed"), cvar("g_balance_crylink_primary_jointime"));
 511
 512                                         }
 513                                         else
 514                                         {
 515                                                 pos = W_Crylink_LinkJoin(self.crylink_lastgroup, cvar("g_balance_crylink_secondary_joinspeed"), cvar("g_balance_crylink_secondary_jointime"));
 516                                         }
 517
 518                                         linkjoineffect = spawn();
 519                                         linkjoineffect.think = W_Crylink_LinkJoinEffect_Think;
 520                                         linkjoineffect.classname = "linkjoineffect";
 521                                         linkjoineffect.nextthink = time + w_crylink_linkjoin_time;
 522                                         linkjoineffect.owner = self;
 523                                         setorigin(linkjoineffect, pos);
 524
 525
 526                                 }
 527                                 self.crylink_waitrelease = 0;
 528                                 if(!w_crylink(WR_CHECKAMMO1) && !w_crylink(WR_CHECKAMMO2))
 529                                 {
 530                                         // ran out of ammo!
 531                                         self.cnt = WEP_CRYLINK;
 532                                         self.switchweapon = w_getbestweapon(self);
 533                                 }
 534                         }
 535                 }
 536         }
 537         else if (req == WR_PRECACHE)
 538         {
 539                 precache_model ("models/weapons/g_crylink.md3");
 540                 precache_model ("models/weapons/v_crylink.md3");
 541                 precache_model ("models/weapons/h_crylink.iqm");
 542                 precache_sound ("weapons/crylink_fire.wav");
 543                 precache_sound ("weapons/crylink_fire2.wav");
 544                 precache_sound ("weapons/crylink_linkjoin.wav");
 545         }
 546         else if (req == WR_SETUP)
 547                 weapon_setup(WEP_CRYLINK);
 548         else if (req == WR_CHECKAMMO1)
 549         {
 550                 // don't "run out of ammo" and switch weapons while waiting for release
 551                 if(self.crylink_lastgroup && self.crylink_waitrelease)
 552                         return TRUE;
 553                 return self.ammo_cells >= cvar("g_balance_crylink_primary_ammo");
 554         }
 555         else if (req == WR_CHECKAMMO2)
 556         {
 557                 // don't "run out of ammo" and switch weapons while waiting for release
 558                 if(self.crylink_lastgroup && self.crylink_waitrelease)
 559                         return TRUE;
 560                 return self.ammo_cells >= cvar("g_balance_crylink_secondary_ammo");
 561         }
 562         return TRUE;
 563 };
 564 #endif
 565 #ifdef CSQC
 566 float w_crylink(float req)
 567 {
 568         if(req == WR_IMPACTEFFECT)
 569         {
 570                 vector org2;
 571                 org2 = w_org + w_backoff * 2;
 572                 if(w_deathtype & HITTYPE_SECONDARY)
 573                 {
 574                         pointparticles(particleeffectnum("crylink_impact"), org2, '0 0 0', 1);
 575                         if(!w_issilent)
 576                                 sound(self, CHAN_PROJECTILE, "weapons/crylink_impact2.wav", VOL_BASE, ATTN_NORM);
 577                 }
 578                 else
 579                 {
 580                         pointparticles(particleeffectnum("crylink_impactbig"), org2, '0 0 0', 1);
 581                         if(!w_issilent)
 582                                 sound(self, CHAN_PROJECTILE, "weapons/crylink_impact.wav", VOL_BASE, ATTN_NORM);
 583                 }
 584         }
 585         else if(req == WR_PRECACHE)
 586         {
 587                 precache_sound("weapons/crylink_impact2.wav");
 588                 precache_sound("weapons/crylink_impact.wav");
 589         }
 590         else if (req == WR_SUICIDEMESSAGE)
 591         {
 592                 w_deathtypestring = "%s succeeded at self-destructing themself with the Crylink";
 593         }
 594         else if (req == WR_KILLMESSAGE)
 595         {
 596                 if(w_deathtype & HITTYPE_BOUNCE)
 597                         w_deathtypestring = "%s could not hide from %s's Crylink"; // unchecked: SPLASH (SECONDARY can't be)
 598                 else if(w_deathtype & HITTYPE_SPLASH)
 599                         w_deathtypestring = "%s was too close to %s's Crylink"; // unchecked: SECONDARY
 600                 else
 601                         w_deathtypestring = "%s took a close look at %s's Crylink"; // unchecked: SECONDARY
 602         }
 603         return TRUE;
 604 }
 605 #endif
 606 #endif