qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
   6
   7 void cvar_clientsettemp(string cv, string val)
   8 {
   9         entity e;
  10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  11                 if(e.netname == cv)
  12                         goto saved;
  13         e = spawn();
  14         e.classname = "saved_cvar_value";
  15         e.netname = strzone(cv);
  16         e.message = strzone(cvar_string(cv));
  17 :saved
  18         cvar_set(cv, val);
  19 }
  20
  21 void cvar_clientsettemp_restore()
  22 {
  23         entity e;
  24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  25                         cvar_set(e.netname, e.message);
  26 }
  27
  28 void() menu_show_error =
  29 {
  30         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  31 };
  32
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  34 // Useful for precaching things
  35
  36 void() menu_sub_null =
  37 {
  38 };
  39
  40 #ifdef USE_FTE
  41 float __engine_check;
  42 #endif
  43
  44 string forcefog;
  45 string cl_announcer_prev;
  46 void WaypointSprite_Load();
  47 void CSQC_Init(void)
  48 {
  49         prvm_language = cvar_string("prvm_language");
  50
  51 #ifdef USE_FTE
  52 #pragma target ID
  53         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  54         if(!__engine_check)
  55         {
  56                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
  57                 localcmd("\ndisconnect\n");
  58                 return;
  59         }
  60 #pragma target FTE
  61 #endif
  62
  63         check_unacceptable_compiler_bugs();
  64
  65 #ifdef WATERMARK
  66         print(sprintf(_("^4CSQC Build information: ^1%s\n"), WATERMARK()));
  67 #endif
  68
  69         float i;
  70
  71         binddb = db_create();
  72         tempdb = db_create();
  73         ClientProgsDB = db_load("client.db");
  74         compressShortVector_init();
  75
  76         drawfont = FONT_USER+1;
  77         menu_visible = FALSE;
  78         menu_show = menu_show_error;
  79         menu_action = menu_sub_null;
  80
  81         for(i = 0; i < 255; ++i)
  82                 if(getplayerkey(i, "viewentity") == "")
  83                         break;
  84         maxclients = i;
  85
  86         //ctf_temp_1 = "";
  87         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used
  88         //registercmd("ctf_menu");
  89         registercmd("ons_map");
  90         registercmd("hud_configure");
  91         registercmd("hud_save");
  92         //registercmd("menu_action");
  93
  94         registercmd("+showscores");registercmd("-showscores");
  95         registercmd("+showaccuracy");registercmd("-showaccuracy");
  96
  97 #ifndef CAMERATEST
  98         if(isdemo())
  99         {
 100 #endif
 101                 registercmd("+forward");registercmd("-forward");
 102                 registercmd("+back");registercmd("-back");
 103                 registercmd("+moveup");registercmd("-moveup");
 104                 registercmd("+movedown");registercmd("-movedown");
 105                 registercmd("+moveright");registercmd("-moveright");
 106                 registercmd("+moveleft");registercmd("-moveleft");
 107                 registercmd("+roll_right");registercmd("-roll_right");
 108                 registercmd("+roll_left");registercmd("-roll_left");
 109 #ifndef CAMERATEST
 110         }
 111 #endif
 112         registercvar("hud_usecsqc", "1");
 113         registercvar("scoreboard_columns", "default", CVAR_SAVE);
 114
 115         gametype = 0;
 116
 117         // hud_fields uses strunzone on the titles!
 118         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 119                 hud_title[i] = strzone("(null)");
 120
 121         postinit = false;
 122
 123         calledhooks = 0;
 124
 125         teams = Sort_Spawn();
 126         players = Sort_Spawn();
 127
 128         GetTeam(COLOR_SPECTATOR, true); // add specs first
 129
 130         RegisterWeapons();
 131
 132         WaypointSprite_Load();
 133
 134         // precaches
 135         precache_sound("misc/hit.wav");
 136         precache_sound("misc/typehit.wav");
 137         Projectile_Precache();
 138         Hook_Precache();
 139         GibSplash_Precache();
 140         Casings_Precache();
 141         DamageInfo_Precache();
 142         if(autocvar_cl_announcer != cl_announcer_prev) {
 143                 Announcer_Precache();
 144                 if(cl_announcer_prev)
 145                         strunzone(cl_announcer_prev);
 146                 cl_announcer_prev = strzone(autocvar_cl_announcer);
 147         }
 148         Tuba_Precache();
 149
 150         if(autocvar_cl_reticle_item_normal) precache_pic("gfx/reticle_normal");
 151         if(autocvar_cl_reticle_item_nex) precache_pic("gfx/reticle_nex");
 152
 153         get_mi_min_max_texcoords(1); // try the CLEVER way first
 154         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 155         shortmapname = mi_shortname;
 156
 157         if(precache_pic(minimapname) == "")
 158         {
 159                 // but maybe we have a non-clever minimap
 160                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 161                 if(precache_pic(minimapname) == "")
 162                         minimapname = ""; // FAIL
 163                 else
 164                         get_mi_min_max_texcoords(0); // load new texcoords
 165         }
 166
 167         mi_center = (mi_min + mi_max) * 0.5;
 168         mi_scale = mi_max - mi_min;
 169         minimapname = strzone(minimapname);
 170
 171         WarpZone_Init();
 172
 173         hud_configure_prev = -1;
 174         tab_panel = -1;
 175 }
 176
 177 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 178 void CSQC_Shutdown(void)
 179 {
 180 #ifdef USE_FTE
 181 #pragma TARGET id
 182         if(!__engine_check)
 183                 return 0;
 184 #pragma TARGET fte
 185 #endif
 186
 187         WarpZone_Shutdown();
 188
 189         remove(teams);
 190         remove(players);
 191         db_close(binddb);
 192         db_close(tempdb);
 193         if(autocvar_cl_db_saveasdump)
 194                 db_dump(ClientProgsDB, "client.db");
 195         else
 196                 db_save(ClientProgsDB, "client.db");
 197         db_close(ClientProgsDB);
 198
 199         cvar_clientsettemp_restore();
 200
 201         if(camera_active)
 202                 cvar_set("chase_active",ftos(chase_active_backup));
 203
 204         // unset the event chasecam's chase_active
 205         if(autocvar_chase_active < 0)
 206                 cvar_set("chase_active", "0");
 207
 208         if not(isdemo())
 209         {
 210                 if not(calledhooks & HOOK_START)
 211                         localcmd("\n_cl_hook_gamestart nop\n");
 212                 if not(calledhooks & HOOK_END)
 213                         localcmd("\ncl_hook_gameend\n");
 214         }
 215 }
 216
 217 .float has_team;
 218 float SetTeam(entity o, float Team)
 219 {
 220         entity tm;
 221         if(teamplay)
 222         {
 223                 switch(Team)
 224                 {
 225                         case -1:
 226                         case COLOR_TEAM1:
 227                         case COLOR_TEAM2:
 228                         case COLOR_TEAM3:
 229                         case COLOR_TEAM4:
 230                                 break;
 231                         default:
 232                                 if(GetTeam(Team, false) == NULL)
 233                                 {
 234                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 235                                         Team = COLOR_SPECTATOR;
 236                                 }
 237                                 break;
 238                 }
 239         }
 240         else
 241         {
 242                 switch(Team)
 243                 {
 244                         case -1:
 245                         case 0:
 246                                 break;
 247                         default:
 248                                 if(GetTeam(Team, false) == NULL)
 249                                 {
 250                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 251                                         Team = COLOR_SPECTATOR;
 252                                 }
 253                                 break;
 254                 }
 255         }
 256         if(Team == -1) // leave
 257         {
 258                 if(o.has_team)
 259                 {
 260                         tm = GetTeam(o.team, false);
 261                         tm.team_size -= 1;
 262                         o.has_team = 0;
 263                         return TRUE;
 264                 }
 265         }
 266         else
 267         {
 268                 if not(o.has_team)
 269                 {
 270                         o.team = Team;
 271                         tm = GetTeam(Team, true);
 272                         tm.team_size += 1;
 273                         o.has_team = 1;
 274                         return TRUE;
 275                 }
 276                 else if(Team != o.team)
 277                 {
 278                         tm = GetTeam(o.team, false);
 279                         tm.team_size -= 1;
 280                         o.team = Team;
 281                         tm = GetTeam(Team, true);
 282                         tm.team_size += 1;
 283                         return TRUE;
 284                 }
 285         }
 286         return FALSE;
 287 }
 288
 289 void Playerchecker_Think()
 290 {
 291         float i;
 292         entity e;
 293         for(i = 0; i < maxclients; ++i)
 294         {
 295                 e = playerslots[i];
 296                 if(GetPlayerName(i) == "")
 297                 {
 298                         if(e.sort_prev)
 299                         {
 300                                 // player disconnected
 301                                 SetTeam(e, -1);
 302                                 RemovePlayer(e);
 303                                 e.sort_prev = world;
 304                                 //e.gotscores = 0;
 305                         }
 306                 }
 307                 else
 308                 {
 309                         if not(e.sort_prev)
 310                         {
 311                                 // player connected
 312                                 if not(e)
 313                                         playerslots[i] = e = spawn();
 314                                 e.sv_entnum = i;
 315                                 e.ping = 0;
 316                                 e.ping_packetloss = 0;
 317                                 e.ping_movementloss = 0;
 318                                 //e.gotscores = 0; // we might already have the scores...
 319                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 320                                 RegisterPlayer(e);
 321                                 HUD_UpdatePlayerPos(e);
 322                         }
 323                 }
 324         }
 325         self.nextthink = time + 0.2;
 326 }
 327
 328 void Porto_Init();
 329 void TrueAim_Init();
 330 void PostInit(void)
 331 {
 332         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
 333
 334         entity playerchecker;
 335         playerchecker = spawn();
 336         playerchecker.think = Playerchecker_Think;
 337         playerchecker.nextthink = time + 0.2;
 338
 339         Porto_Init();
 340         TrueAim_Init();
 341
 342         postinit = true;
 343 }
 344
 345 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function
 346 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.
 347 float button_zoom;
 348 void Cmd_HUD_SetFields(float);
 349 void Cmd_HUD_Help(float);
 350 float CSQC_ConsoleCommand(string strMessage)
 351 {
 352         float argc;
 353         // Tokenize String
 354         //argc = tokenize(strMessage);
 355         argc = tokenize_console(strMessage);
 356
 357         // Acquire Command
 358         local string strCmd;
 359         strCmd = argv(0);
 360
 361         if(strCmd == "hud_configure") { // config hud
 362                 cvar_set("_hud_configure", ftos(!autocvar__hud_configure));
 363                 return true;
 364         } else if(strCmd == "hud_save") { // save hud config
 365                 if(argv(1) == "" || argv(2)) {
 366                         print(_("Usage:\n"));
 367                         print(_("hud_save configname   (saves to hud_skinname_configname.cfg)\n"));
 368                 }
 369                 else
 370                         HUD_Panel_ExportCfg(argv(1));
 371                 return true;
 372         } else if(strCmd == "+showscores") {
 373                 scoreboard_showscores = true;
 374                 return true;
 375         } else if(strCmd == "-showscores") {
 376                 scoreboard_showscores = false;
 377                 return true;
 378         } else if(strCmd == "+showaccuracy") {
 379                 scoreboard_showaccuracy = true;
 380                 return true;
 381         } else if(strCmd == "-showaccuracy") {
 382                 scoreboard_showaccuracy = false;
 383                 return true;
 384         }
 385
 386         if(camera_active)
 387         if(strCmd == "+forward" || strCmd == "-back") {
 388                 ++camera_direction_x;
 389                 return true;
 390         } else if(strCmd == "-forward" || strCmd == "+back") {
 391                 --camera_direction_x;
 392                 return true;
 393         } else if(strCmd == "+moveright" || strCmd == "-moveleft") {
 394                 --camera_direction_y;
 395                 return true;
 396         } else if(strCmd == "-moveright" || strCmd == "+moveleft") {
 397                 ++camera_direction_y;
 398                 return true;
 399         } else if(strCmd == "+moveup" || strCmd == "-movedown") {
 400                 ++camera_direction_z;
 401                 return true;
 402         } else if(strCmd == "-moveup" || strCmd == "+movedown") {
 403                 --camera_direction_z;
 404                 return true;
 405         } else if(strCmd == "+roll_right" || strCmd == "-roll_left") {
 406                 ++camera_roll;
 407                 return true;
 408         } else if(strCmd == "+roll_left" || strCmd == "-roll_right") {
 409                 --camera_roll;
 410                 return true;
 411         }
 412
 413         return false;
 414 }
 415
 416 .vector view_ofs;
 417 entity debug_shotorg;
 418 void ShotOrg_Draw()
 419 {
 420         self.origin = view_origin + view_forward * self.view_ofs_x + view_right * self.view_ofs_y + view_up * self.view_ofs_z;
 421         self.angles = view_angles;
 422         self.angles_x = -self.angles_x;
 423         if not(self.cnt)
 424                 self.drawmask = MASK_NORMAL;
 425         else
 426                 self.drawmask = 0;
 427 }
 428 void ShotOrg_Draw2D()
 429 {
 430         vector coord2d_topleft, coord2d_topright, coord2d;
 431         string s;
 432         vector fs;
 433
 434         s = vtos(self.view_ofs);
 435         s = substring(s, 1, strlen(s) - 2);
 436         if(tokenize_console(s) == 3)
 437                 s = strcat(argv(0), " ", argv(1), " ", argv(2));
 438
 439         coord2d_topleft = project_3d_to_2d(self.origin + view_up * 4 - view_right * 4);
 440         coord2d_topright = project_3d_to_2d(self.origin + view_up * 4 + view_right * 4);
 441
 442         fs = '1 1 0' * ((coord2d_topright_x - coord2d_topleft_x) / stringwidth(s, FALSE, '8 8 0'));
 443
 444         coord2d = coord2d_topleft;
 445         if(fs_x < 8)
 446         {
 447                 coord2d_x += (coord2d_topright_x - coord2d_topleft_x) * (1 - 8 / fs_x) * 0.5;
 448                 fs = '8 8 0';
 449         }
 450         coord2d_y -= fs_y;
 451         coord2d_z = 0;
 452         drawstring(coord2d, s, fs, '1 1 1', 1, 0);
 453 }
 454
 455 void ShotOrg_Spawn()
 456 {
 457         debug_shotorg = spawn();
 458         debug_shotorg.draw = ShotOrg_Draw;
 459         debug_shotorg.draw2d = ShotOrg_Draw2D;
 460         debug_shotorg.renderflags = RF_VIEWMODEL;
 461         debug_shotorg.effects = EF_FULLBRIGHT;
 462         precache_model("models/shotorg_adjuster.md3");
 463         setmodel(debug_shotorg, "models/shotorg_adjuster.md3");
 464         debug_shotorg.scale = 2;
 465         debug_shotorg.view_ofs = '25 8 -8';
 466 }
 467
 468 void DrawDebugModel()
 469 {
 470         if(time - floor(time) > 0.5)
 471         {
 472                 PolyDrawModel(self);
 473                 self.drawmask = 0;
 474         }
 475         else
 476         {
 477                 self.renderflags = 0;
 478                 self.drawmask = MASK_NORMAL;
 479         }
 480 }
 481
 482 void GameCommand(string msg)
 483 {
 484         string s;
 485         float argc;
 486         entity e;
 487         argc = tokenize_console(msg);
 488
 489         if(argv(0) == "help" || argc == 0)
 490         {
 491                 print(_("Usage: cl_cmd COMMAND..., where possible commands are:\n"));
 492                 print(_("  settemp cvar value\n"));
 493                 print(_("  scoreboard_columns_set ...\n"));
 494                 print(_("  scoreboard_columns_help\n"));
 495                 GameCommand_Generic("help");
 496                 return;
 497         }
 498
 499         if(GameCommand_Generic(msg))
 500                 return;
 501
 502         string cmd;
 503         cmd = argv(0);
 504         if(cmd == "mv_download") {
 505                 Cmd_MapVote_MapDownload(argc);
 506         }
 507         else if(cmd == "settemp") {
 508                 cvar_clientsettemp(argv(1), argv(2));
 509         }
 510         else if(cmd == "scoreboard_columns_set") {
 511                 Cmd_HUD_SetFields(argc);
 512         }
 513         else if(cmd == "scoreboard_columns_help") {
 514                 Cmd_HUD_Help(argc);
 515         }
 516 #ifdef BLURTEST
 517         else if(cmd == "blurtest") {
 518                 blurtest_time0 = time;
 519                 blurtest_time1 = time + stof(argv(1));
 520                 blurtest_radius = stof(argv(2));
 521                 blurtest_power = stof(argv(3));
 522         }
 523 #endif
 524         else if(cmd == "shotorg_move") {
 525                 if(!debug_shotorg)
 526                         ShotOrg_Spawn();
 527                 else
 528                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stov(argv(1));
 529                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 530         }
 531         else if(cmd == "shotorg_movez") {
 532                 if(!debug_shotorg)
 533                         ShotOrg_Spawn();
 534                 else
 535                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stof(argv(1)) * (debug_shotorg.view_ofs * (1 / debug_shotorg.view_ofs_x)); // closer/farther, same xy pos
 536                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 537         }
 538         else if(cmd == "shotorg_set") {
 539                 if(!debug_shotorg)
 540                         ShotOrg_Spawn();
 541                 else
 542                         debug_shotorg.view_ofs = stov(argv(1));
 543                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 544         }
 545         else if(cmd == "shotorg_setz") {
 546                 if(!debug_shotorg)
 547                         ShotOrg_Spawn();
 548                 else
 549                         debug_shotorg.view_ofs = debug_shotorg.view_ofs * (stof(argv(1)) / debug_shotorg.view_ofs_x); // closer/farther, same xy pos
 550                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 551         }
 552         else if(cmd == "shotorg_toggle_hide") {
 553                 if(debug_shotorg)
 554                 {
 555                         debug_shotorg.cnt = !debug_shotorg.cnt;
 556                 }
 557         }
 558         else if(cmd == "shotorg_end") {
 559                 if(debug_shotorg)
 560                 {
 561                         print(vtos(debug_shotorg.view_ofs), "\n");
 562                         remove(debug_shotorg);
 563                         debug_shotorg = world;
 564                 }
 565                 localcmd("sv_cmd debug_shotorg\n");
 566         }
 567         else if(cmd == "sendcvar") {
 568                 // W_FixWeaponOrder will trash argv, so save what we need.
 569                 string thiscvar;
 570                 thiscvar = strzone(argv(1));
 571                 s = cvar_string(thiscvar);
 572                 if(thiscvar == "cl_weaponpriority")
 573                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
 574                 else if(substring(thiscvar, 0, 17) == "cl_weaponpriority" && strlen(thiscvar) == 18)
 575                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
 576                 localcmd("cmd sentcvar ", thiscvar, " \"", s, "\"\n");
 577                 strunzone(thiscvar);
 578         }
 579         else if(cmd == "spawn") {
 580                 s = argv(1);
 581                 e = spawn();
 582                 precache_model(s);
 583                 setmodel(e, s);
 584                 setorigin(e, view_origin);
 585                 e.angles = view_angles;
 586                 e.draw = DrawDebugModel;
 587                 e.classname = "debugmodel";
 588         }
 589     else if(cmd == "vyes")
 590     {
 591         if(uid2name_dialog)
 592         {
 593             vote_active = 0; // force the panel to disappear right as we have selected the value (to prevent it from fading out in the normal vote panel pos)
 594             vote_prev = 0;
 595             cvar_set("cl_allow_uid2name", "1");
 596             vote_change = -9999;
 597                         uid2name_dialog = 0;
 598         }
 599         else
 600         {
 601             localcmd("cmd vote yes\n");
 602         }
 603     }
 604     else if(cmd == "vno")
 605     {
 606         if(uid2name_dialog)
 607         {
 608             vote_active = 0;
 609             vote_prev = 0;
 610             cvar_set("cl_allow_uid2name", "0");
 611             vote_change = -9999;
 612                         uid2name_dialog = 0;
 613         }
 614         else
 615         {
 616             localcmd("cmd vote no\n");
 617         }
 618     }
 619
 620         else
 621         {
 622                 print("Invalid command. For a list of supported commands, try cl_cmd help.\n");
 623         }
 624
 625         return;
 626 }
 627
 628 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 629 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 630 // All keys are in ascii.
 631 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.
 632 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 633 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 634 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 635 {
 636         local float bSkipKey;
 637         bSkipKey = false;
 638
 639         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 640                 return true;
 641
 642         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 643                 return true;
 644
 645         if(menu_visible)
 646                 if(menu_action(bInputType, nPrimary, nSecondary))
 647                         return TRUE;
 648
 649         return bSkipKey;
 650 }
 651
 652 // END REQUIRED CSQC FUNCTIONS
 653 // --------------------------------------------------------------------------
 654
 655 // --------------------------------------------------------------------------
 656 // BEGIN OPTIONAL CSQC FUNCTIONS
 657 void Ent_RemoveEntCS()
 658 {
 659         entcs_receiver[self.sv_entnum] = world;
 660 }
 661 void Ent_ReadEntCS()
 662 {
 663         InterpolateOrigin_Undo();
 664
 665         self.classname = "entcs_receiver";
 666         self.sv_entnum = ReadByte() - 1;
 667         self.origin_x = ReadShort();
 668         self.origin_y = ReadShort();
 669         self.origin_z = ReadShort();
 670         self.angles_y = ReadByte() * 360.0 / 256;
 671         self.angles_x = self.angles_z = 0;
 672         entcs_receiver[self.sv_entnum] = self;
 673         self.entremove = Ent_RemoveEntCS;
 674
 675         InterpolateOrigin_Note();
 676 }
 677
 678 void Ent_Remove();
 679
 680 void Ent_RemovePlayerScore()
 681 {
 682         float i;
 683
 684         if(self.owner)
 685         {
 686                 SetTeam(self.owner, -1);
 687                 self.owner.gotscores = 0;
 688                 for(i = 0; i < MAX_SCORE; ++i)
 689                         self.owner.(scores[i]) = 0; // clear all scores
 690         }
 691 }
 692
 693 void Ent_ReadPlayerScore()
 694 {
 695         float i, n;
 696         float isNew;
 697         entity o;
 698
 699         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 700         // (no I've never heard of M-x replace-string, sed, or anything like that)
 701         isNew = !self.owner; // workaround for DP bug
 702         n = ReadByte()-1;
 703
 704 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 705         if(!isNew && n != self.sv_entnum)
 706         {
 707                 //print(_("A CSQC entity changed its owner!\n"));
 708                 print(sprintf(_("A CSQC entity changed its owner! (edict: %d, classname: %s)\n"), num_for_edict(self), self.classname));
 709                 isNew = true;
 710                 Ent_Remove();
 711                 self.enttype = ENT_CLIENT_SCORES;
 712         }
 713 #endif
 714
 715         self.sv_entnum = n;
 716
 717         if not(playerslots[self.sv_entnum])
 718                 playerslots[self.sv_entnum] = spawn();
 719         o = self.owner = playerslots[self.sv_entnum];
 720         o.sv_entnum = self.sv_entnum;
 721         o.gotscores = 1;
 722
 723         //if not(o.sort_prev)
 724         //      RegisterPlayer(o);
 725         //playerchecker will do this for us later, if it has not already done so
 726
 727         float sf, lf;
 728 #if MAX_SCORE <= 8
 729         sf = ReadByte();
 730         lf = ReadByte();
 731 #else
 732         sf = ReadShort();
 733         lf = ReadShort();
 734 #endif
 735         float p;
 736         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 737                 if(sf & p)
 738                 {
 739                         if(lf & p)
 740                                 o.(scores[i]) = ReadInt24_t();
 741                         else
 742                                 o.(scores[i]) = ReadChar();
 743                 }
 744
 745         if(o.sort_prev)
 746                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 747
 748         self.entremove = Ent_RemovePlayerScore;
 749 }
 750
 751 void Ent_ReadTeamScore()
 752 {
 753         float i;
 754         entity o;
 755
 756         self.team = ReadByte();
 757         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 758
 759         float sf, lf;
 760 #if MAX_TEAMSCORE <= 8
 761         sf = ReadByte();
 762         lf = ReadByte();
 763 #else
 764         sf = ReadShort();
 765         lf = ReadShort();
 766 #endif
 767         float p;
 768         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 769                 if(sf & p)
 770                 {
 771                         if(lf & p)
 772                                 o.(teamscores[i]) = ReadInt24_t();
 773                         else
 774                                 o.(teamscores[i]) = ReadChar();
 775                 }
 776
 777         HUD_UpdateTeamPos(o);
 778 }
 779
 780 void Ent_ClientData()
 781 {
 782         float f;
 783         float newspectatee_status;
 784
 785         f = ReadByte();
 786
 787         scoreboard_showscores_force = (f & 1);
 788
 789         if(f & 2)
 790         {
 791                 newspectatee_status = ReadByte();
 792                 if(newspectatee_status == player_localentnum)
 793                         newspectatee_status = -1; // observing
 794         }
 795         else
 796                 newspectatee_status = 0;
 797
 798         spectatorbutton_zoom = (f & 4);
 799
 800         if(f & 8)
 801         {
 802                 angles_held_status = 1;
 803                 angles_held_x = ReadAngle();
 804                 angles_held_y = ReadAngle();
 805                 angles_held_z = 0;
 806         }
 807         else
 808                 angles_held_status = 0;
 809
 810         if(newspectatee_status != spectatee_status)
 811         {
 812                 float i;
 813
 814                 // clear race stuff
 815                 race_laptime = 0;
 816                 race_checkpointtime = 0;
 817         }
 818         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 819         {
 820                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 821                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 822                 )
 823                         prev_p_health = -1;
 824                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 825                         prev_health = -1;
 826         }
 827         spectatee_status = newspectatee_status;
 828 }
 829
 830 void Ent_Nagger()
 831 {
 832         float nags, i, j, b, f;
 833
 834         nags = ReadByte();
 835
 836         if(nags & 128)
 837         {
 838                 if(vote_called_vote)
 839                         strunzone(vote_called_vote);
 840                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 841         }
 842
 843         if(nags & 1)
 844         {
 845                 for(j = 0; j < maxclients; ++j)
 846                         if(playerslots[j])
 847                                 playerslots[j].ready = 1;
 848                 for(i = 1; i <= maxclients; i += 8)
 849                 {
 850                         f = ReadByte();
 851                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 852                                 if not(f & b)
 853                                         if(playerslots[j])
 854                                                 playerslots[j].ready = 0;
 855                 }
 856         }
 857
 858         ready_waiting = (nags & 1);
 859         ready_waiting_for_me = (nags & 2);
 860         vote_waiting = (nags & 4);
 861         vote_waiting_for_me = (nags & 8);
 862         warmup_stage = (nags & 16);
 863 }
 864
 865 void Ent_RandomSeed()
 866 {
 867         float s;
 868         prandom_debug();
 869         s = ReadShort();
 870         psrandom(s);
 871 }
 872
 873 void Ent_ReadAccuracy(void)
 874 {
 875         float sf, f, w, b;
 876         sf = ReadInt24_t();
 877         if(sf == 0)
 878         {
 879                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 880                         weapon_accuracy[w] = -1;
 881                 return;
 882         }
 883
 884         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w, f *= 2)
 885         {
 886                 if(sf & f)
 887                 {
 888                         b = ReadByte();
 889                         if(b == 0)
 890                                 weapon_accuracy[w] = -1;
 891                         else if(b == 255)
 892                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 893                         else
 894                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 895                 }
 896         }
 897 }
 898
 899 void Ent_ShowNames()
 900 {
 901     float sf;
 902
 903     // entity init, TODO can this be done only once somehow?
 904     self.the_entnum = ReadByte(); // TODO: fixme to only send once somehow
 905     self.draw2d = Draw_ShowNames;
 906
 907     //self.movetype = MOVETYPE_FLY; // movetype needed so we can traceline?
 908     //self.mins = '-20 -20 -24';
 909     //self.maxs = '20 20 45';
 910     self.classname = "shownames_tag";
 911
 912     sf = ReadByte();
 913
 914     if(sf & 1)
 915     {
 916         self.healthvalue = ReadByte() * 10;
 917     }
 918     if(sf & 2)
 919     {
 920         self.armorvalue = ReadByte() * 10;
 921     }
 922
 923     if(sf & 128) // same team
 924         self.sameteam = TRUE;
 925     else
 926         self.sameteam = FALSE;
 927 }
 928
 929 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 930 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 931 void Ent_RadarLink();
 932 void Ent_Init();
 933 void Ent_ScoresInfo();
 934 void(float bIsNewEntity) CSQC_Ent_Update =
 935 {
 936         float t;
 937         float savetime;
 938         t = ReadByte();
 939
 940         // set up the "time" global for received entities to be correct for interpolation purposes
 941         savetime = time;
 942         if(servertime)
 943         {
 944                 time = servertime;
 945         }
 946         else
 947         {
 948                 serverprevtime = time;
 949                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 950                 time = serverprevtime + serverdeltatime;
 951         }
 952
 953 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 954         if(self.enttype)
 955                 if(t != self.enttype)
 956                 {
 957                         //print(_("A CSQC entity changed its type!\n"));
 958                         print(sprintf(_("A CSQC entity changed its type! (edict: %d, classname: %s)\n"), num_for_edict(self), self.classname));
 959                         Ent_Remove();
 960                         bIsNewEntity = 1;
 961                 }
 962 #endif
 963         self.enttype = t;
 964         switch(t)
 965         {
 966                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 967                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 968                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 969                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 970                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 971                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 972                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 973                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 974                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 975                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 976                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 977                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 978                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 979                 case ENT_CLIENT_INIT: Ent_Init(); break;
 980                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 981                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 982                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 983                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 984                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 985                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 986                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 987                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 988                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 989                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 990                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 991                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 992                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
 993                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
 994                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 995                 case ENT_CLIENT_SHOWNAMES: Ent_ShowNames(); break;
 996                 default:
 997                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 998                         error(sprintf(_("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n"), self.enttype, num_for_edict(self), self.classname));
 999                         break;
1000         }
1001
1002         time = savetime;
1003 };
1004 // Destructor, but does NOT deallocate the entity by calling remove(). Also
1005 // used when an entity changes its type. For an entity that someone interacts
1006 // with others, make sure it can no longer do so.
1007 void Ent_Remove()
1008 {
1009         if(self.entremove)
1010                 self.entremove();
1011
1012         self.enttype = 0;
1013         self.classname = "";
1014         self.draw = menu_sub_null;
1015         self.entremove = menu_sub_null;
1016         // TODO possibly set more stuff to defaults
1017 }
1018 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
1019 void CSQC_Ent_Remove()
1020 {
1021         if(self.enttype)
1022                 Ent_Remove();
1023         remove(self);
1024 }
1025
1026 void Gamemode_Init()
1027 {
1028         if not(isdemo())
1029         {
1030                 localcmd("\n_cl_hook_gamestart ", GametypeNameFromType(gametype), "\n");
1031                 calledhooks |= HOOK_START;
1032         }
1033 }
1034 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
1035 void CSQC_Parse_StuffCmd(string strMessage)
1036 {
1037         localcmd(strMessage);
1038 }
1039 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
1040 void CSQC_Parse_Print(string strMessage)
1041 {
1042         print(ColorTranslateRGB(strMessage));
1043 }
1044
1045 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.
1046 void CSQC_Parse_CenterPrint(string strMessage)
1047 {
1048         centerprint(strMessage);
1049 }
1050
1051 string notranslate_fogcmd1 = "\nfog ";
1052 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
1053 void Fog_Force()
1054 {
1055         // TODO somehow thwart prvm_globalset client ...
1056
1057         if(forcefog != "")
1058                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
1059 }
1060
1061 void Gamemode_Init();
1062 void Ent_ScoresInfo()
1063 {
1064         float i;
1065         self.classname = "ent_client_scores_info";
1066         gametype = ReadByte();
1067         for(i = 0; i < MAX_SCORE; ++i)
1068         {
1069                 scores_label[i] = strzone(ReadString());
1070                 scores_flags[i] = ReadByte();
1071         }
1072         for(i = 0; i < MAX_TEAMSCORE; ++i)
1073         {
1074                 teamscores_label[i] = strzone(ReadString());
1075                 teamscores_flags[i] = ReadByte();
1076         }
1077         HUD_InitScores();
1078         Gamemode_Init();
1079 }
1080
1081 void Ent_Init()
1082 {
1083         self.classname = "ent_client_init";
1084
1085         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1086
1087         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1088         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1089         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1090         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1091         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1092         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1093         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1094         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1095         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1096         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1097         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1098         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1099
1100         if(forcefog)
1101                 strunzone(forcefog);
1102         forcefog = strzone(ReadString());
1103
1104         armorblockpercent = ReadByte() / 255.0;
1105
1106         g_weaponswitchdelay = ReadByte() / 255.0;
1107
1108         g_balance_grenadelauncher_bouncefactor = ReadCoord();
1109         g_balance_grenadelauncher_bouncestop = ReadCoord();
1110         g_balance_electro_secondary_bouncefactor = ReadCoord();
1111         g_balance_electro_secondary_bouncestop = ReadCoord();
1112
1113         nex_scope = !ReadByte();
1114         sniperrifle_scope = !ReadByte();
1115
1116         serverflags = ReadByte();
1117
1118         minelayer_maxmines = ReadByte();
1119
1120         hagar_maxrockets = ReadByte();
1121
1122         g_trueaim_minrange = ReadCoord();
1123
1124         if(!postinit)
1125                 PostInit();
1126 }
1127
1128 void Net_ReadRace()
1129 {
1130         float b;
1131
1132         b = ReadByte();
1133
1134         switch(b)
1135         {
1136                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1137                         race_checkpoint = ReadByte();
1138                         race_time = ReadInt24_t();
1139                         race_previousbesttime = ReadInt24_t();
1140                         if(race_previousbestname)
1141                                 strunzone(race_previousbestname);
1142                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1143
1144                         race_checkpointtime = time;
1145
1146                         if(race_checkpoint == 0 || race_checkpoint == 254)
1147                         {
1148                                 race_penaltyaccumulator = 0;
1149                                 race_laptime = time; // valid
1150                         }
1151
1152                         break;
1153
1154                 case RACE_NET_CHECKPOINT_CLEAR:
1155                         race_laptime = 0;
1156                         race_checkpointtime = 0;
1157                         break;
1158
1159                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1160                         race_laptime = ReadCoord();
1161                         race_checkpointtime = -99999;
1162                         // fall through
1163                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1164                         race_nextcheckpoint = ReadByte();
1165
1166                         race_nextbesttime = ReadInt24_t();
1167                         if(race_nextbestname)
1168                                 strunzone(race_nextbestname);
1169                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1170                         break;
1171
1172                 case RACE_NET_CHECKPOINT_HIT_RACE:
1173                         race_mycheckpoint = ReadByte();
1174                         race_mycheckpointtime = time;
1175                         race_mycheckpointdelta = ReadInt24_t();
1176                         race_mycheckpointlapsdelta = ReadByte();
1177                         if(race_mycheckpointlapsdelta >= 128)
1178                                 race_mycheckpointlapsdelta -= 256;
1179                         if(race_mycheckpointenemy)
1180                                 strunzone(race_mycheckpointenemy);
1181                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1182                         break;
1183
1184                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1185                         race_othercheckpoint = ReadByte();
1186                         race_othercheckpointtime = time;
1187                         race_othercheckpointdelta = ReadInt24_t();
1188                         race_othercheckpointlapsdelta = ReadByte();
1189                         if(race_othercheckpointlapsdelta >= 128)
1190                                 race_othercheckpointlapsdelta -= 256;
1191                         if(race_othercheckpointenemy)
1192                                 strunzone(race_othercheckpointenemy);
1193                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1194                         break;
1195
1196                 case RACE_NET_PENALTY_RACE:
1197                         race_penaltyeventtime = time;
1198                         race_penaltytime = ReadShort();
1199                         //race_penaltyaccumulator += race_penaltytime;
1200                         if(race_penaltyreason)
1201                                 strunzone(race_penaltyreason);
1202                         race_penaltyreason = strzone(ReadString());
1203                         break;
1204
1205                 case RACE_NET_PENALTY_QUALIFYING:
1206                         race_penaltyeventtime = time;
1207                         race_penaltytime = ReadShort();
1208                         race_penaltyaccumulator += race_penaltytime;
1209                         if(race_penaltyreason)
1210                                 strunzone(race_penaltyreason);
1211                         race_penaltyreason = strzone(ReadString());
1212                         break;
1213
1214                 case RACE_NET_SERVER_RECORD:
1215                         race_server_record = ReadInt24_t();
1216                         break;
1217                 case RACE_NET_SPEED_AWARD:
1218                         race_speedaward = ReadInt24_t();
1219                         if(race_speedaward_holder)
1220                                 strunzone(race_speedaward_holder);
1221                         race_speedaward_holder = strzone(ReadString());
1222                         break;
1223                 case RACE_NET_SPEED_AWARD_BEST:
1224                         race_speedaward_alltimebest = ReadInt24_t();
1225                         if(race_speedaward_alltimebest_holder)
1226                                 strunzone(race_speedaward_alltimebest_holder);
1227                         race_speedaward_alltimebest_holder = strzone(ReadString());
1228                         break;
1229                 case RACE_NET_SERVER_RANKINGS:
1230                         float pos, prevpos, del;
1231                         pos = ReadShort();
1232                         prevpos = ReadShort();
1233                         del = ReadShort();
1234
1235                         // move other rankings out of the way
1236                         float i;
1237                         if (prevpos) {
1238                                 for (i=prevpos-1;i>pos-1;--i) {
1239                                         grecordtime[i] = grecordtime[i-1];
1240                                         if(grecordholder[i])
1241                                                 strunzone(grecordholder[i]);
1242                                         grecordholder[i] = strzone(grecordholder[i-1]);
1243                                 }
1244                         } else if (del) { // a record has been deleted by the admin
1245                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1246                                         if (i == RANKINGS_CNT-1) { // clear out last record
1247                                                 grecordtime[i] = 0;
1248                                                 if (grecordholder[i])
1249                                                         strunzone(grecordholder[i]);
1250                                                 grecordholder[i] = string_null;
1251                                         }
1252                                         else {
1253                                                 grecordtime[i] = grecordtime[i+1];
1254                                                 if (grecordholder[i])
1255                                                         strunzone(grecordholder[i]);
1256                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1257                                         }
1258                                 }
1259                         } else { // player has no ranked record yet
1260                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1261                                         grecordtime[i] = grecordtime[i-1];
1262                                         if(grecordholder[i])
1263                                                 strunzone(grecordholder[i]);
1264                                         grecordholder[i] = strzone(grecordholder[i-1]);
1265                                 }
1266                         }
1267
1268                         // store new ranking
1269                         if(grecordholder[pos-1] != "")
1270                                 strunzone(grecordholder[pos-1]);
1271                         grecordholder[pos-1] = strzone(ReadString());
1272                         grecordtime[pos-1] = ReadInt24_t();
1273                         if(grecordholder[pos-1] == GetPlayerName(player_localentnum -1))
1274                                 race_myrank = pos;
1275                         break;
1276                 case RACE_NET_SERVER_STATUS:
1277                         race_status = ReadShort();
1278                         if(race_status_name)
1279                                 strunzone(race_status_name);
1280                         race_status_name = strzone(ReadString());
1281         }
1282 }
1283
1284 void Net_ReadSpawn()
1285 {
1286         zoomin_effect = 1;
1287         current_viewzoom = 0.6;
1288 }
1289
1290 void Net_TeamNagger()
1291 {
1292         teamnagger = 1;
1293 }
1294
1295 void Net_ReadPingPLReport()
1296 {
1297         float e, pi, pl, ml;
1298         e = ReadByte();
1299         pi = ReadShort();
1300         pl = ReadByte();
1301         ml = ReadByte();
1302         if not(playerslots[e])
1303                 return;
1304         playerslots[e].ping = pi;
1305         playerslots[e].ping_packetloss = pl / 255.0;
1306         playerslots[e].ping_movementloss = ml / 255.0;
1307 }
1308
1309 void Net_VoteDialog(float highlight) {
1310         if(highlight) {
1311                 vote_highlighted = ReadByte();
1312                 return;
1313         }
1314
1315         vote_yescount = ReadByte();
1316         vote_nocount = ReadByte();
1317         vote_needed = ReadByte();
1318         vote_active = 1;
1319 }
1320
1321 void Net_VoteDialogReset() {
1322         vote_active = 0;
1323 }
1324
1325 void Net_Notify() {
1326         float type;
1327         type = ReadByte();
1328
1329         if(type == CSQC_KILLNOTIFY)
1330         {
1331                 HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1332         }
1333         else if(type == CSQC_CENTERPRINT)
1334         {
1335                 HUD_Centerprint(ReadString(), ReadString(), ReadShort(), ReadByte());
1336         }
1337 }
1338
1339 void Net_WeaponComplain() {
1340         complain_weapon = ReadByte();
1341
1342         if(complain_weapon_name)
1343                 strunzone(complain_weapon_name);
1344         complain_weapon_name = strzone(ReadString());
1345
1346         complain_weapon_type = ReadByte();
1347
1348         complain_weapon_time = time;
1349         weapontime = time; // ping the weapon panel
1350 }
1351
1352 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1353 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1354 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1355 float CSQC_Parse_TempEntity()
1356 {
1357         local float bHandled;
1358                 bHandled  = true;
1359         // Acquire TE ID
1360         local float nTEID;
1361                 nTEID = ReadByte();
1362
1363                 // NOTE: Could just do return instead of break...
1364         switch(nTEID)
1365         {
1366                 case TE_CSQC_TARGET_MUSIC:
1367                         Net_TargetMusic();
1368                         bHandled = true;
1369                         break;
1370                 case TE_CSQC_PICTURE:
1371                         Net_MapVote_Picture();
1372                         bHandled = true;
1373                         break;
1374                 case TE_CSQC_RACE:
1375                         Net_ReadRace();
1376                         bHandled = true;
1377                         break;
1378                 case TE_CSQC_SPAWN:
1379                         Net_ReadSpawn();
1380                         bHandled = true;
1381                         break;
1382                 case TE_CSQC_ZCURVEPARTICLES:
1383                         Net_ReadZCurveParticles();
1384                         bHandled = true;
1385                         break;
1386                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1387                         Net_ReadNexgunBeamParticle();
1388                         bHandled = true;
1389                         break;
1390                 case TE_CSQC_TEAMNAGGER:
1391                         Net_TeamNagger();
1392                         bHandled = true;
1393                         break;
1394                 case TE_CSQC_VOTE:
1395                         Net_VoteDialog(ReadByte());
1396                         bHandled = true;
1397                         break;
1398                 case TE_CSQC_VOTERESET:
1399                         Net_VoteDialogReset();
1400                         bHandled = true;
1401                         break;
1402                 case TE_CSQC_LIGHTNINGARC:
1403                         Net_ReadLightningarc();
1404                         bHandled = true;
1405                         break;
1406                 case TE_CSQC_PINGPLREPORT:
1407                         Net_ReadPingPLReport();
1408                         bHandled = true;
1409                         break;
1410                 case TE_CSQC_ANNOUNCE:
1411                         announce_snd = strzone(ReadString());
1412                         bHandled = true;
1413                         break;
1414                 case TE_CSQC_NOTIFY:
1415                         Net_Notify();
1416                         bHandled = true;
1417                         break;
1418                 case TE_CSQC_WEAPONCOMPLAIN:
1419                         Net_WeaponComplain();
1420                         bHandled = true;
1421                         break;
1422                 default:
1423                         // No special logic for this temporary entity; return 0 so the engine can handle it
1424                         bHandled = false;
1425                         break;
1426         }
1427
1428         return bHandled;
1429 }
1430
1431 string getcommandkey(string text, string command)
1432 {
1433         string keys;
1434         float n, j, k, l;
1435
1436         if (!autocvar_hud_showbinds)
1437                 return text;
1438
1439         keys = db_get(binddb, command);
1440         if (!keys)
1441         {
1442                 n = tokenize(findkeysforcommand(command)); // uses '...' strings
1443                 for(j = 0; j < n; ++j)
1444                 {
1445                         k = stof(argv(j));
1446                         if(k != -1)
1447                         {
1448                                 if ("" == keys)
1449                                         keys = keynumtostring(k);
1450                                 else
1451                                         keys = strcat(keys, ", ", keynumtostring(k));
1452
1453                                 ++l;
1454                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit >= l) break;
1455                         }
1456
1457                 }
1458                 db_put(binddb, command, keys);
1459         }
1460
1461         if ("" == keys) {
1462                 if (autocvar_hud_showbinds > 1)
1463                         return sprintf(_("%s (not bound)"), text);
1464                 else
1465                         return text;
1466         }
1467         else if (autocvar_hud_showbinds > 1)
1468                 return sprintf(_("%s (%s)"), text, keys);
1469         else
1470                 return keys;
1471 }