qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 entity clearentity_ent;
   6 void clearentity(entity e)
   7 {
   8         if (!clearentity_ent)
   9         {
  10                 clearentity_ent = spawn();
  11                 clearentity_ent.classname = "clearentity";
  12         }
  13         float n = e.entnum;
  14         copyentity(clearentity_ent, e);
  15         e.entnum = n;
  16 }
  17
  18 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  19 void menu_show_error()
  20 {
  21         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  22 }
  23
  24 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  25 // Useful for precaching things
  26
  27 void menu_sub_null()
  28 {
  29 }
  30
  31 string forcefog;
  32 void WaypointSprite_Load();
  33 void ConsoleCommand_macro_init();
  34 void CSQC_Init(void)
  35 {
  36         prvm_language = cvar_string("prvm_language");
  37
  38 #ifdef WATERMARK
  39         dprintf("^4CSQC Build information: ^1%s\n", WATERMARK);
  40 #endif
  41
  42         float i;
  43
  44         binddb = db_create();
  45         tempdb = db_create();
  46         ClientProgsDB = db_load("client.db");
  47         compressShortVector_init();
  48
  49         draw_endBoldFont();
  50         menu_visible = FALSE;
  51         menu_show = menu_show_error;
  52         menu_action = func_null;
  53
  54         for(i = 0; i < 255; ++i)
  55                 if(getplayerkeyvalue(i, "viewentity") == "")
  56                         break;
  57         maxclients = i;
  58
  59         //registercommand("hud_configure");
  60         //registercommand("hud_save");
  61         //registercommand("menu_action");
  62
  63         ConsoleCommand_macro_init();
  64
  65         registercvar("hud_usecsqc", "1");
  66         registercvar("scoreboard_columns", "default");
  67
  68         registercvar("cl_nade_type", "3");
  69         registercvar("cl_pokenade_type", "zombie");
  70
  71         gametype = 0;
  72
  73         // hud_fields uses strunzone on the titles!
  74         for(i = 0; i < MAX_HUD_FIELDS; ++i)
  75                 hud_title[i] = strzone("(null)");
  76
  77         Cmd_HUD_SetFields(0);
  78
  79         postinit = false;
  80
  81         calledhooks = 0;
  82
  83         teams = Sort_Spawn();
  84         players = Sort_Spawn();
  85
  86         GetTeam(NUM_SPECTATOR, true); // add specs first
  87
  88         // needs to be done so early because of the constants they create
  89         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
  90         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
  91         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
  92         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
  93         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
  94         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
  95         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
  96
  97         WaypointSprite_Load();
  98
  99         // precaches
 100         precache_model("null");
 101         precache_sound("misc/hit.wav");
 102         precache_sound("misc/typehit.wav");
 103
 104         Projectile_Precache();
 105         Hook_Precache();
 106         GibSplash_Precache();
 107         Casings_Precache();
 108         Vehicles_Precache();
 109         turrets_precache();
 110         Tuba_Precache();
 111         CSQCPlayer_Precache();
 112
 113         if(autocvar_cl_reticle)
 114         {
 115                 precache_pic("gfx/reticle_normal");
 116                 // weapon reticles are precached in weapon files
 117         }
 118
 119         get_mi_min_max_texcoords(1); // try the CLEVER way first
 120         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 121         shortmapname = mi_shortname;
 122
 123         if(precache_pic(minimapname) == "")
 124         {
 125                 // but maybe we have a non-clever minimap
 126                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 127                 if(precache_pic(minimapname) == "")
 128                         minimapname = ""; // FAIL
 129                 else
 130                         get_mi_min_max_texcoords(0); // load new texcoords
 131         }
 132
 133         mi_center = (mi_min + mi_max) * 0.5;
 134         mi_scale = mi_max - mi_min;
 135         minimapname = strzone(minimapname);
 136
 137         WarpZone_Init();
 138
 139         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 140         hud_configure_prev = -1;
 141
 142         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 143 }
 144
 145 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 146 void Shutdown(void)
 147 {
 148         WarpZone_Shutdown();
 149
 150         remove(teams);
 151         remove(players);
 152         db_close(binddb);
 153         db_close(tempdb);
 154         if(autocvar_cl_db_saveasdump)
 155                 db_dump(ClientProgsDB, "client.db");
 156         else
 157                 db_save(ClientProgsDB, "client.db");
 158         db_close(ClientProgsDB);
 159
 160         if(camera_active)
 161                 cvar_set("chase_active",ftos(chase_active_backup));
 162
 163         // unset the event chasecam's chase_active
 164         if(autocvar_chase_active < 0)
 165                 cvar_set("chase_active", "0");
 166
 167         if (!isdemo())
 168         {
 169                 if (!(calledhooks & HOOK_START))
 170                         localcmd("\n_cl_hook_gamestart nop\n");
 171                 if (!(calledhooks & HOOK_END))
 172                         localcmd("\ncl_hook_gameend\n");
 173         }
 174 }
 175
 176 .float has_team;
 177 float SetTeam(entity o, float Team)
 178 {
 179         entity tm;
 180         if(teamplay)
 181         {
 182                 switch(Team)
 183                 {
 184                         case -1:
 185                         case NUM_TEAM_1:
 186                         case NUM_TEAM_2:
 187                         case NUM_TEAM_3:
 188                         case NUM_TEAM_4:
 189                                 break;
 190                         default:
 191                                 if(GetTeam(Team, false) == world)
 192                                 {
 193                                         dprintf("trying to switch to unsupported team %d\n", Team);
 194                                         Team = NUM_SPECTATOR;
 195                                 }
 196                                 break;
 197                 }
 198         }
 199         else
 200         {
 201                 switch(Team)
 202                 {
 203                         case -1:
 204                         case 0:
 205                                 break;
 206                         default:
 207                                 if(GetTeam(Team, false) == world)
 208                                 {
 209                                         dprintf("trying to switch to unsupported team %d\n", Team);
 210                                         Team = NUM_SPECTATOR;
 211                                 }
 212                                 break;
 213                 }
 214         }
 215         if(Team == -1) // leave
 216         {
 217                 if(o.has_team)
 218                 {
 219                         tm = GetTeam(o.team, false);
 220                         tm.team_size -= 1;
 221                         o.has_team = 0;
 222                         return TRUE;
 223                 }
 224         }
 225         else
 226         {
 227                 if (!o.has_team)
 228                 {
 229                         o.team = Team;
 230                         tm = GetTeam(Team, true);
 231                         tm.team_size += 1;
 232                         o.has_team = 1;
 233                         return TRUE;
 234                 }
 235                 else if(Team != o.team)
 236                 {
 237                         tm = GetTeam(o.team, false);
 238                         tm.team_size -= 1;
 239                         o.team = Team;
 240                         tm = GetTeam(Team, true);
 241                         tm.team_size += 1;
 242                         return TRUE;
 243                 }
 244         }
 245         return FALSE;
 246 }
 247
 248 void Playerchecker_Think()
 249 {
 250         float i;
 251         entity e;
 252         for(i = 0; i < maxclients; ++i)
 253         {
 254                 e = playerslots[i];
 255                 if(GetPlayerName(i) == "")
 256                 {
 257                         if(e.sort_prev)
 258                         {
 259                                 // player disconnected
 260                                 SetTeam(e, -1);
 261                                 RemovePlayer(e);
 262                                 e.sort_prev = world;
 263                                 //e.gotscores = 0;
 264                         }
 265                 }
 266                 else
 267                 {
 268                         if (!e.sort_prev)
 269                         {
 270                                 // player connected
 271                                 if (!e)
 272                                         playerslots[i] = e = spawn();
 273                                 e.sv_entnum = i;
 274                                 e.ping = 0;
 275                                 e.ping_packetloss = 0;
 276                                 e.ping_movementloss = 0;
 277                                 //e.gotscores = 0; // we might already have the scores...
 278                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 279                                 RegisterPlayer(e);
 280                                 HUD_UpdatePlayerPos(e);
 281                         }
 282                 }
 283         }
 284         self.nextthink = time + 0.2;
 285 }
 286
 287 void Porto_Init();
 288 void TrueAim_Init();
 289 void PostInit(void)
 290 {
 291         entity playerchecker;
 292         playerchecker = spawn();
 293         playerchecker.think = Playerchecker_Think;
 294         playerchecker.nextthink = time + 0.2;
 295
 296         Porto_Init();
 297         TrueAim_Init();
 298
 299         postinit = true;
 300 }
 301
 302 float button_zoom;
 303
 304 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 305 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 306 // All keys are in ascii.
 307 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 308 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 309 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 310 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 311 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 312 {
 313         float bSkipKey;
 314         bSkipKey = false;
 315
 316         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 317                 return true;
 318
 319         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 320                 return true;
 321
 322         if(menu_visible && menu_action)
 323                 if(menu_action(bInputType, nPrimary, nSecondary))
 324                         return TRUE;
 325
 326         return bSkipKey;
 327 }
 328
 329 // END REQUIRED CSQC FUNCTIONS
 330 // --------------------------------------------------------------------------
 331
 332 // --------------------------------------------------------------------------
 333 // BEGIN OPTIONAL CSQC FUNCTIONS
 334
 335 void Ent_RemoveEntCS()
 336 {
 337         entcs_receiver[self.sv_entnum] = world;
 338 }
 339 void Ent_ReadEntCS()
 340 {
 341         float sf;
 342         InterpolateOrigin_Undo();
 343
 344         self.classname = "entcs_receiver";
 345         sf = ReadByte();
 346
 347         if(sf & 1)
 348                 self.sv_entnum = ReadByte();
 349         if(sf & 2)
 350         {
 351                 self.origin_x = ReadShort();
 352                 self.origin_y = ReadShort();
 353                 self.origin_z = ReadShort();
 354                 setorigin(self, self.origin);
 355         }
 356         if(sf & 4)
 357         {
 358                 self.angles_y = ReadByte() * 360.0 / 256;
 359                 self.angles_x = self.angles_z = 0;
 360         }
 361         if(sf & 8)
 362                 self.healthvalue = ReadByte() * 10;
 363         if(sf & 16)
 364                 self.armorvalue = ReadByte() * 10;
 365
 366         entcs_receiver[self.sv_entnum] = self;
 367         self.entremove = Ent_RemoveEntCS;
 368         self.iflags |= IFLAG_ORIGIN;
 369
 370         InterpolateOrigin_Note();
 371 }
 372
 373 void Ent_Remove();
 374
 375 void Ent_RemovePlayerScore()
 376 {
 377         float i;
 378
 379         if(self.owner)
 380         {
 381                 SetTeam(self.owner, -1);
 382                 self.owner.gotscores = 0;
 383                 for(i = 0; i < MAX_SCORE; ++i)
 384                         self.owner.(scores[i]) = 0; // clear all scores
 385         }
 386 }
 387
 388 void Ent_ReadPlayerScore()
 389 {
 390         float i, n;
 391         float isNew;
 392         entity o;
 393
 394         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 395         // (no I've never heard of M-x replace-string, sed, or anything like that)
 396         isNew = !self.owner; // workaround for DP bug
 397         n = ReadByte()-1;
 398
 399 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 400         if(!isNew && n != self.sv_entnum)
 401         {
 402                 //print("A CSQC entity changed its owner!\n");
 403                 printf("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname);
 404                 isNew = true;
 405                 Ent_Remove();
 406                 self.enttype = ENT_CLIENT_SCORES;
 407         }
 408 #endif
 409
 410         self.sv_entnum = n;
 411
 412         if (!(playerslots[self.sv_entnum]))
 413                 playerslots[self.sv_entnum] = spawn();
 414         o = self.owner = playerslots[self.sv_entnum];
 415         o.sv_entnum = self.sv_entnum;
 416         o.gotscores = 1;
 417
 418         //if (!o.sort_prev)
 419         //      RegisterPlayer(o);
 420         //playerchecker will do this for us later, if it has not already done so
 421
 422         float sf, lf;
 423 #if MAX_SCORE <= 8
 424         sf = ReadByte();
 425         lf = ReadByte();
 426 #else
 427         sf = ReadShort();
 428         lf = ReadShort();
 429 #endif
 430         float p;
 431         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 432                 if(sf & p)
 433                 {
 434                         if(lf & p)
 435                                 o.(scores[i]) = ReadInt24_t();
 436                         else
 437                                 o.(scores[i]) = ReadChar();
 438                 }
 439
 440         if(o.sort_prev)
 441                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 442
 443         self.entremove = Ent_RemovePlayerScore;
 444 }
 445
 446 void Ent_ReadTeamScore()
 447 {
 448         float i;
 449         entity o;
 450
 451         self.team = ReadByte();
 452         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 453
 454         float sf, lf;
 455 #if MAX_TEAMSCORE <= 8
 456         sf = ReadByte();
 457         lf = ReadByte();
 458 #else
 459         sf = ReadShort();
 460         lf = ReadShort();
 461 #endif
 462         float p;
 463         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 464                 if(sf & p)
 465                 {
 466                         if(lf & p)
 467                                 o.(teamscores[i]) = ReadInt24_t();
 468                         else
 469                                 o.(teamscores[i]) = ReadChar();
 470                 }
 471
 472         HUD_UpdateTeamPos(o);
 473 }
 474
 475 void Ent_ClientData()
 476 {
 477         float f;
 478         float newspectatee_status;
 479
 480         f = ReadByte();
 481
 482         scoreboard_showscores_force = (f & 1);
 483
 484         if(f & 2)
 485         {
 486                 newspectatee_status = ReadByte();
 487                 if(newspectatee_status == player_localnum + 1)
 488                         newspectatee_status = -1; // observing
 489         }
 490         else
 491                 newspectatee_status = 0;
 492
 493         spectatorbutton_zoom = (f & 4);
 494
 495         if(f & 8)
 496         {
 497                 angles_held_status = 1;
 498                 angles_held_x = ReadAngle();
 499                 angles_held_y = ReadAngle();
 500                 angles_held_z = 0;
 501         }
 502         else
 503                 angles_held_status = 0;
 504
 505         if(newspectatee_status != spectatee_status)
 506         {
 507                 // clear race stuff
 508                 race_laptime = 0;
 509                 race_checkpointtime = 0;
 510         }
 511         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 512         {
 513                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 514                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 515                 )
 516                         prev_p_health = -1;
 517                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 518                         prev_health = -1;
 519         }
 520         spectatee_status = newspectatee_status;
 521
 522         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 523 }
 524
 525 void Ent_Nagger()
 526 {
 527         float nags, i, j, b, f;
 528
 529         nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 530
 531         if(!(nags & 4))
 532         {
 533                 if(vote_called_vote)
 534                         strunzone(vote_called_vote);
 535                 vote_called_vote = string_null;
 536                 vote_active = 0;
 537         }
 538         else
 539         {
 540                 vote_active = 1;
 541         }
 542
 543         if(nags & 64)
 544         {
 545                 vote_yescount = ReadByte();
 546                 vote_nocount = ReadByte();
 547                 vote_needed = ReadByte();
 548                 vote_highlighted = ReadChar();
 549         }
 550
 551         if(nags & 128)
 552         {
 553                 if(vote_called_vote)
 554                         strunzone(vote_called_vote);
 555                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 556         }
 557
 558         if(nags & 1)
 559         {
 560                 for(j = 0; j < maxclients; ++j)
 561                         if(playerslots[j])
 562                                 playerslots[j].ready = 1;
 563                 for(i = 1; i <= maxclients; i += 8)
 564                 {
 565                         f = ReadByte();
 566                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 567                                 if (!(f & b))
 568                                         if(playerslots[j])
 569                                                 playerslots[j].ready = 0;
 570                 }
 571         }
 572
 573         ready_waiting = (nags & 1);
 574         ready_waiting_for_me = (nags & 2);
 575         vote_waiting = (nags & 4);
 576         vote_waiting_for_me = (nags & 8);
 577         warmup_stage = (nags & 16);
 578 }
 579
 580 void Ent_EliminatedPlayers()
 581 {
 582         float sf, i, j, b, f;
 583
 584         sf = ReadByte();
 585         if(sf & 1)
 586         {
 587                 for(j = 0; j < maxclients; ++j)
 588                         if(playerslots[j])
 589                                 playerslots[j].eliminated = 1;
 590                 for(i = 1; i <= maxclients; i += 8)
 591                 {
 592                         f = ReadByte();
 593                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 594                                 if (!(f & b))
 595                                         if(playerslots[j])
 596                                                 playerslots[j].eliminated = 0;
 597                 }
 598         }
 599 }
 600
 601 void Ent_RandomSeed()
 602 {
 603         float s;
 604         prandom_debug();
 605         s = ReadShort();
 606         psrandom(s);
 607 }
 608
 609 void Ent_ReadAccuracy(void)
 610 {
 611         float sf, f, w, b;
 612         sf = ReadInt24_t();
 613         if(sf == 0)
 614         {
 615                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 616                         weapon_accuracy[w] = -1;
 617                 return;
 618         }
 619
 620         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 621         {
 622                 if(sf & f)
 623                 {
 624                         b = ReadByte();
 625                         if(b == 0)
 626                                 weapon_accuracy[w] = -1;
 627                         else if(b == 255)
 628                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 629                         else
 630                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 631                 }
 632                 if(f == 0x800000)
 633                         f = 1;
 634                 else
 635                         f *= 2;
 636         }
 637 }
 638
 639 void Spawn_Draw(void)
 640 {
 641         pointparticles(self.cnt, self.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 642 }
 643
 644 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
 645 {
 646         float teamnum = (ReadByte() - 1);
 647         vector spn_origin;
 648         spn_origin_x = ReadShort();
 649         spn_origin_y = ReadShort();
 650         spn_origin_z = ReadShort();
 651
 652         if(is_new)
 653         {
 654                 self.origin = spn_origin;
 655                 setsize(self, PL_MIN, PL_MAX);
 656                 droptofloor();
 657
 658                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 659                 {
 660                         self.mdl = "models/spawnpoint.md3";
 661                         self.colormod = Team_ColorRGB(teamnum);
 662                         precache_model(self.mdl);
 663                         setmodel(self, self.mdl);
 664                         self.drawmask = MASK_NORMAL;
 665                         //self.movetype = MOVETYPE_NOCLIP;
 666                         //self.draw = Spawn_Draw;
 667                 }*/
 668                 if(autocvar_cl_spawn_point_particles)
 669                 {
 670                         if((serverflags & SERVERFLAG_TEAMPLAY))
 671                         {
 672                                 switch(teamnum)
 673                                 {
 674                                         case NUM_TEAM_1: self.cnt = particleeffectnum("spawn_point_red"); break;
 675                                         case NUM_TEAM_2: self.cnt = particleeffectnum("spawn_point_blue"); break;
 676                                         case NUM_TEAM_3: self.cnt = particleeffectnum("spawn_point_yellow"); break;
 677                                         case NUM_TEAM_4: self.cnt = particleeffectnum("spawn_point_pink"); break;
 678                                         default: self.cnt = particleeffectnum("spawn_point_neutral"); break;
 679                                 }
 680                         }
 681                         else { self.cnt = particleeffectnum("spawn_point_neutral"); }
 682
 683                         self.draw = Spawn_Draw;
 684                 }
 685         }
 686
 687         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt);
 688 }
 689
 690 void Ent_ReadSpawnEvent(float is_new)
 691 {
 692         // If entnum is 0, ONLY do the local spawn actions
 693         // this way the server can disable the sending of
 694         // spawn origin or such to clients if wanted.
 695         float entnum = ReadByte();
 696
 697         if(entnum)
 698         {
 699                 self.origin_x = ReadShort();
 700                 self.origin_y = ReadShort();
 701                 self.origin_z = ReadShort();
 702
 703                 if(is_new)
 704                 {
 705                         float teamnum = GetPlayerColor(entnum - 1);
 706
 707                         if(autocvar_cl_spawn_event_particles)
 708                         {
 709                                 switch(teamnum)
 710                                 {
 711                                         case NUM_TEAM_1: pointparticles(particleeffectnum("spawn_event_red"), self.origin, '0 0 0', 1); break;
 712                                         case NUM_TEAM_2: pointparticles(particleeffectnum("spawn_event_blue"), self.origin, '0 0 0', 1); break;
 713                                         case NUM_TEAM_3: pointparticles(particleeffectnum("spawn_event_yellow"), self.origin, '0 0 0', 1); break;
 714                                         case NUM_TEAM_4: pointparticles(particleeffectnum("spawn_event_pink"), self.origin, '0 0 0', 1); break;
 715                                         default: pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); break;
 716                                 }
 717                         }
 718                         if(autocvar_cl_spawn_event_sound)
 719                         {
 720                                 sound(self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTEN_NORM);
 721                         }
 722                 }
 723         }
 724
 725         // local spawn actions
 726         if(is_new && (!entnum || (entnum == player_localentnum)))
 727         {
 728                 zoomin_effect = 1;
 729                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 730
 731                 if(autocvar_cl_unpress_zoom_on_spawn)
 732                 {
 733                         localcmd("-zoom\n");
 734                         button_zoom = FALSE;
 735                 }
 736         }
 737
 738         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum);
 739 }
 740
 741 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 742 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 743 void Ent_RadarLink();
 744 void Ent_Init();
 745 void Ent_ScoresInfo();
 746 void CSQC_Ent_Update(float bIsNewEntity)
 747 {
 748         float t;
 749         float savetime;
 750         t = ReadByte();
 751
 752         if(autocvar_developer_csqcentities)
 753                 printf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t);
 754
 755         // set up the "time" global for received entities to be correct for interpolation purposes
 756         savetime = time;
 757         if(servertime)
 758         {
 759                 time = servertime;
 760         }
 761         else
 762         {
 763                 serverprevtime = time;
 764                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 765                 time = serverprevtime + serverdeltatime;
 766         }
 767
 768 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 769         if(self.enttype)
 770         {
 771                 if(t != self.enttype || bIsNewEntity)
 772                 {
 773                         //print("A CSQC entity changed its type!\n");
 774                         printf("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t);
 775                         Ent_Remove();
 776                         clearentity(self);
 777                         bIsNewEntity = 1;
 778                 }
 779         }
 780         else
 781         {
 782                 if(!bIsNewEntity)
 783                 {
 784                         printf("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t);
 785                         bIsNewEntity = 1;
 786                 }
 787         }
 788 #endif
 789         self.enttype = t;
 790         switch(t)
 791         {
 792                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 793                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 794                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 795                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 796                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 797                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 798                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 799                 case ENT_CLIENT_ELIMINATEDPLAYERS: Ent_EliminatedPlayers(); break;
 800                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 801                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 802                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 803                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 804                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 805                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 806                 case ENT_CLIENT_INIT: Ent_Init(); break;
 807                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 808                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 809                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 810                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 811                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 812                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 813                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 814                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 815                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 816                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 817                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 818                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 819                 case ENT_CLIENT_ARC_BEAM: Ent_ReadArcBeam(bIsNewEntity); break;
 820                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 821                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 822                 case ENT_CLIENT_TURRET: ent_turret(); break;
 823                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 824                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 825                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 826                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
 827                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
 828                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
 829                 case ENT_CLIENT_HEALING_ORB: ent_healer(); break;
 830                 case ENT_CLIENT_LADDER: ent_func_ladder(); break;
 831                 case ENT_CLIENT_TRIGGER_PUSH: ent_trigger_push(); break;
 832                 case ENT_CLIENT_TARGET_PUSH: ent_target_push(); break;
 833                 case ENT_CLIENT_CONVEYOR: ent_conveyor(); break;
 834                 case ENT_CLIENT_DOOR: ent_door(); break;
 835                 case ENT_CLIENT_DOOR_TRIGGER: ent_door_trigger(); break;
 836                 case ENT_CLIENT_PLAT: ent_plat(); break;
 837                 case ENT_CLIENT_PLAT_TRIGGER: ent_plat_trigger(); break;
 838                 case ENT_CLIENT_SWAMP: ent_swamp(); break;
 839
 840                 default:
 841                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 842                         error(sprintf("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n", self.enttype, num_for_edict(self), self.classname));
 843                         break;
 844         }
 845
 846         time = savetime;
 847 }
 848 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 849 // used when an entity changes its type. For an entity that someone interacts
 850 // with others, make sure it can no longer do so.
 851 void Ent_Remove()
 852 {
 853         if(self.entremove)
 854                 self.entremove();
 855
 856         if(self.skeletonindex)
 857         {
 858                 skel_delete(self.skeletonindex);
 859                 self.skeletonindex = 0;
 860         }
 861
 862         if(self.snd_looping > 0)
 863         {
 864                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 865                 self.snd_looping = 0;
 866         }
 867
 868         self.enttype = 0;
 869         self.classname = "";
 870         self.draw = menu_sub_null;
 871         self.entremove = menu_sub_null;
 872         // TODO possibly set more stuff to defaults
 873 }
 874 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 875 void CSQC_Ent_Remove()
 876 {
 877         if(autocvar_developer_csqcentities)
 878                 printf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype);
 879
 880         if(wasfreed(self))
 881         {
 882                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 883                 return;
 884         }
 885         if(self.enttype)
 886                 Ent_Remove();
 887         remove(self);
 888 }
 889
 890 void Gamemode_Init()
 891 {
 892         if (!isdemo())
 893         {
 894                 if(!(calledhooks & HOOK_START))
 895                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 896                 calledhooks |= HOOK_START;
 897         }
 898 }
 899 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 900 void CSQC_Parse_StuffCmd(string strMessage)
 901 {
 902         if(autocvar_developer_csqcentities)
 903                 printf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 904
 905         localcmd(strMessage);
 906 }
 907 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 908 void CSQC_Parse_Print(string strMessage)
 909 {
 910         if(autocvar_developer_csqcentities)
 911                 printf("CSQC_Parse_Print(\"%s\")\n", strMessage);
 912
 913         print(ColorTranslateRGB(strMessage));
 914 }
 915
 916 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 917 void CSQC_Parse_CenterPrint(string strMessage)
 918 {
 919         if(autocvar_developer_csqcentities)
 920                 printf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 921
 922         centerprint_hud(strMessage);
 923 }
 924
 925 string notranslate_fogcmd1 = "\nfog ";
 926 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 927 void Fog_Force()
 928 {
 929         // TODO somehow thwart prvm_globalset client ...
 930
 931         if(autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 932                 { localcmd("\nr_drawfog 0\n"); }
 933         else if(forcefog != "")
 934                 { localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2)); }
 935 }
 936
 937 void Gamemode_Init();
 938 void Ent_ScoresInfo()
 939 {
 940         float i;
 941         self.classname = "ent_client_scores_info";
 942         gametype = ReadInt24_t();
 943         HUD_ModIcons_SetFunc();
 944         for(i = 0; i < MAX_SCORE; ++i)
 945         {
 946                 if(scores_label[i])
 947                         strunzone(scores_label[i]);
 948                 scores_label[i] = strzone(ReadString());
 949                 scores_flags[i] = ReadByte();
 950         }
 951         for(i = 0; i < MAX_TEAMSCORE; ++i)
 952         {
 953                 if(teamscores_label[i])
 954                         strunzone(teamscores_label[i]);
 955                 teamscores_label[i] = strzone(ReadString());
 956                 teamscores_flags[i] = ReadByte();
 957         }
 958         HUD_InitScores();
 959         Gamemode_Init();
 960 }
 961
 962 void Ent_Init()
 963 {
 964         self.classname = "ent_client_init";
 965
 966         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 967
 968         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 969         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 970         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 971         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 972         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 973         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 974         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 975         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 976
 977         if(forcefog)
 978                 strunzone(forcefog);
 979         forcefog = strzone(ReadString());
 980
 981         armorblockpercent = ReadByte() / 255.0;
 982
 983         g_balance_mortar_bouncefactor = ReadCoord();
 984         g_balance_mortar_bouncestop = ReadCoord();
 985         g_balance_electro_secondary_bouncefactor = ReadCoord();
 986         g_balance_electro_secondary_bouncestop = ReadCoord();
 987
 988         vortex_scope = !ReadByte();
 989         rifle_scope = !ReadByte();
 990
 991         serverflags = ReadByte();
 992
 993         minelayer_maxmines = ReadByte();
 994
 995         hagar_maxrockets = ReadByte();
 996
 997         g_trueaim_minrange = ReadCoord();
 998         g_balance_porto_secondary = ReadByte();
 999
1000         if(!postinit)
1001                 PostInit();
1002 }
1003
1004 void Net_ReadRace()
1005 {
1006         float b;
1007
1008         b = ReadByte();
1009
1010         switch(b)
1011         {
1012                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1013                         race_checkpoint = ReadByte();
1014                         race_time = ReadInt24_t();
1015                         race_previousbesttime = ReadInt24_t();
1016                         if(race_previousbestname)
1017                                 strunzone(race_previousbestname);
1018                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1019
1020                         race_checkpointtime = time;
1021
1022                         if(race_checkpoint == 0 || race_checkpoint == 254)
1023                         {
1024                                 race_penaltyaccumulator = 0;
1025                                 race_laptime = time; // valid
1026                         }
1027
1028                         break;
1029
1030                 case RACE_NET_CHECKPOINT_CLEAR:
1031                         race_laptime = 0;
1032                         race_checkpointtime = 0;
1033                         break;
1034
1035                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1036                         race_laptime = ReadCoord();
1037                         race_checkpointtime = -99999;
1038                         // fall through
1039                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1040                         race_nextcheckpoint = ReadByte();
1041
1042                         race_nextbesttime = ReadInt24_t();
1043                         if(race_nextbestname)
1044                                 strunzone(race_nextbestname);
1045                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1046                         break;
1047
1048                 case RACE_NET_CHECKPOINT_HIT_RACE:
1049                         race_mycheckpoint = ReadByte();
1050                         race_mycheckpointtime = time;
1051                         race_mycheckpointdelta = ReadInt24_t();
1052                         race_mycheckpointlapsdelta = ReadByte();
1053                         if(race_mycheckpointlapsdelta >= 128)
1054                                 race_mycheckpointlapsdelta -= 256;
1055                         if(race_mycheckpointenemy)
1056                                 strunzone(race_mycheckpointenemy);
1057                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1058                         break;
1059
1060                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1061                         race_othercheckpoint = ReadByte();
1062                         race_othercheckpointtime = time;
1063                         race_othercheckpointdelta = ReadInt24_t();
1064                         race_othercheckpointlapsdelta = ReadByte();
1065                         if(race_othercheckpointlapsdelta >= 128)
1066                                 race_othercheckpointlapsdelta -= 256;
1067                         if(race_othercheckpointenemy)
1068                                 strunzone(race_othercheckpointenemy);
1069                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1070                         break;
1071
1072                 case RACE_NET_PENALTY_RACE:
1073                         race_penaltyeventtime = time;
1074                         race_penaltytime = ReadShort();
1075                         //race_penaltyaccumulator += race_penaltytime;
1076                         if(race_penaltyreason)
1077                                 strunzone(race_penaltyreason);
1078                         race_penaltyreason = strzone(ReadString());
1079                         break;
1080
1081                 case RACE_NET_PENALTY_QUALIFYING:
1082                         race_penaltyeventtime = time;
1083                         race_penaltytime = ReadShort();
1084                         race_penaltyaccumulator += race_penaltytime;
1085                         if(race_penaltyreason)
1086                                 strunzone(race_penaltyreason);
1087                         race_penaltyreason = strzone(ReadString());
1088                         break;
1089
1090                 case RACE_NET_SERVER_RECORD:
1091                         race_server_record = ReadInt24_t();
1092                         break;
1093                 case RACE_NET_SPEED_AWARD:
1094                         race_speedaward = ReadInt24_t();
1095                         if(race_speedaward_holder)
1096                                 strunzone(race_speedaward_holder);
1097                         race_speedaward_holder = strzone(ReadString());
1098                         break;
1099                 case RACE_NET_SPEED_AWARD_BEST:
1100                         race_speedaward_alltimebest = ReadInt24_t();
1101                         if(race_speedaward_alltimebest_holder)
1102                                 strunzone(race_speedaward_alltimebest_holder);
1103                         race_speedaward_alltimebest_holder = strzone(ReadString());
1104                         break;
1105                 case RACE_NET_SERVER_RANKINGS:
1106                         float pos, prevpos, del;
1107                         pos = ReadShort();
1108                         prevpos = ReadShort();
1109                         del = ReadShort();
1110
1111                         // move other rankings out of the way
1112                         float i;
1113                         if (prevpos) {
1114                                 for (i=prevpos-1;i>pos-1;--i) {
1115                                         grecordtime[i] = grecordtime[i-1];
1116                                         if(grecordholder[i])
1117                                                 strunzone(grecordholder[i]);
1118                                         grecordholder[i] = strzone(grecordholder[i-1]);
1119                                 }
1120                         } else if (del) { // a record has been deleted by the admin
1121                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1122                                         if (i == RANKINGS_CNT-1) { // clear out last record
1123                                                 grecordtime[i] = 0;
1124                                                 if (grecordholder[i])
1125                                                         strunzone(grecordholder[i]);
1126                                                 grecordholder[i] = string_null;
1127                                         }
1128                                         else {
1129                                                 grecordtime[i] = grecordtime[i+1];
1130                                                 if (grecordholder[i])
1131                                                         strunzone(grecordholder[i]);
1132                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1133                                         }
1134                                 }
1135                         } else { // player has no ranked record yet
1136                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1137                                         grecordtime[i] = grecordtime[i-1];
1138                                         if(grecordholder[i])
1139                                                 strunzone(grecordholder[i]);
1140                                         grecordholder[i] = strzone(grecordholder[i-1]);
1141                                 }
1142                         }
1143
1144                         // store new ranking
1145                         if(grecordholder[pos-1] != "")
1146                                 strunzone(grecordholder[pos-1]);
1147                         grecordholder[pos-1] = strzone(ReadString());
1148                         grecordtime[pos-1] = ReadInt24_t();
1149                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1150                                 race_myrank = pos;
1151                         break;
1152                 case RACE_NET_SERVER_STATUS:
1153                         race_status = ReadShort();
1154                         if(race_status_name)
1155                                 strunzone(race_status_name);
1156                         race_status_name = strzone(ReadString());
1157         }
1158 }
1159
1160 void Net_TeamNagger()
1161 {
1162         teamnagger = 1;
1163 }
1164
1165 void Net_ReadPingPLReport()
1166 {
1167         float e, pi, pl, ml;
1168         e = ReadByte();
1169         pi = ReadShort();
1170         pl = ReadByte();
1171         ml = ReadByte();
1172         if (!(playerslots[e]))
1173                 return;
1174         playerslots[e].ping = pi;
1175         playerslots[e].ping_packetloss = pl / 255.0;
1176         playerslots[e].ping_movementloss = ml / 255.0;
1177 }
1178
1179 void Net_WeaponComplain()
1180 {
1181         complain_weapon = ReadByte();
1182
1183         if(complain_weapon_name)
1184                 strunzone(complain_weapon_name);
1185         complain_weapon_name = strzone(WEP_NAME(complain_weapon));
1186
1187         complain_weapon_type = ReadByte();
1188
1189         complain_weapon_time = time;
1190         weapontime = time; // ping the weapon panel
1191
1192         switch(complain_weapon_type)
1193         {
1194                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1195                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1196                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1197         }
1198 }
1199
1200 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1201 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1202 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1203 float CSQC_Parse_TempEntity()
1204 {
1205         float bHandled;
1206                 bHandled  = true;
1207         // Acquire TE ID
1208         float nTEID;
1209                 nTEID = ReadByte();
1210
1211         if(autocvar_developer_csqcentities)
1212                 printf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
1213
1214                 // NOTE: Could just do return instead of break...
1215         switch(nTEID)
1216         {
1217                 case TE_CSQC_TARGET_MUSIC:
1218                         Net_TargetMusic();
1219                         bHandled = true;
1220                         break;
1221                 case TE_CSQC_PICTURE:
1222                         Net_MapVote_Picture();
1223                         bHandled = true;
1224                         break;
1225                 case TE_CSQC_RACE:
1226                         Net_ReadRace();
1227                         bHandled = true;
1228                         break;
1229                 case TE_CSQC_VORTEXBEAMPARTICLE:
1230                         Net_ReadVortexBeamParticle();
1231                         bHandled = true;
1232                         break;
1233                 case TE_CSQC_TEAMNAGGER:
1234                         Net_TeamNagger();
1235                         bHandled = true;
1236                         break;
1237                 case TE_CSQC_ARC:
1238                         Net_ReadArc();
1239                         bHandled = true;
1240                         break;
1241                 case TE_CSQC_PINGPLREPORT:
1242                         Net_ReadPingPLReport();
1243                         bHandled = true;
1244                         break;
1245                 case TE_CSQC_WEAPONCOMPLAIN:
1246                         Net_WeaponComplain();
1247                         bHandled = true;
1248                         break;
1249                 case TE_CSQC_VEHICLESETUP:
1250                         Net_VehicleSetup();
1251                         bHandled = true;
1252                         break;
1253                 case TE_CSQC_SVNOTICE:
1254                         cl_notice_read();
1255                         bHandled = true;
1256                         break;
1257                 case TE_CSQC_SHOCKWAVEPARTICLE:
1258                         Net_ReadShockwaveParticle();
1259                         bHandled = true;
1260                         break;
1261                 default:
1262                         // No special logic for this temporary entity; return 0 so the engine can handle it
1263                         bHandled = false;
1264                         break;
1265         }
1266
1267         return bHandled;
1268 }
1269
1270 string getcommandkey(string text, string command)
1271 {
1272         string keys;
1273         float n, j, k, l = 0;
1274
1275         if (!autocvar_hud_showbinds)
1276                 return text;
1277
1278         keys = db_get(binddb, command);
1279         if (keys == "")
1280         {
1281                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1282                 for(j = 0; j < n; ++j)
1283                 {
1284                         k = stof(argv(j));
1285                         if(k != -1)
1286                         {
1287                                 if ("" == keys)
1288                                         keys = keynumtostring(k);
1289                                 else
1290                                         keys = strcat(keys, ", ", keynumtostring(k));
1291
1292                                 ++l;
1293                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1294                                         break;
1295                         }
1296
1297                 }
1298                 if (keys == "")
1299                         keys = "NO_KEY";
1300                 db_put(binddb, command, keys);
1301         }
1302
1303         if (keys == "NO_KEY") {
1304                 if (autocvar_hud_showbinds > 1)
1305                         return sprintf(_("%s (not bound)"), text);
1306                 else
1307                         return text;
1308         }
1309         else if (autocvar_hud_showbinds > 1)
1310                 return sprintf("%s (%s)", text, keys);
1311         else
1312                 return keys;
1313 }