qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 entity clearentity_ent;
   6 void clearentity(entity e)
   7 {
   8         if not(clearentity_ent)
   9         {
  10                 clearentity_ent = spawn();
  11                 clearentity_ent.classname = "clearentity";
  12         }
  13         float n = e.entnum;
  14         copyentity(clearentity_ent, e);
  15         e.entnum = n;
  16 }
  17
  18 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  19 void menu_show_error()
  20 {
  21         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  22 }
  23
  24 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  25 // Useful for precaching things
  26
  27 void menu_sub_null()
  28 {
  29 }
  30
  31 #ifdef USE_FTE
  32 float __engine_check;
  33 #endif
  34
  35 void precache_playermodel(string m)
  36 {
  37         string f;
  38
  39         if(substring(m, -9,5) == "_lod1")
  40                 return;
  41         if(substring(m, -9,5) == "_lod2")
  42                 return;
  43         precache_model(m);
  44         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
  45         if(fexists(f))
  46                 precache_model(f);
  47         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
  48         if(fexists(f))
  49                 precache_model(f);
  50
  51         /*
  52         float globhandle, i, n;
  53         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
  54         if (globhandle < 0)
  55                 return;
  56         n = search_getsize(globhandle);
  57         for (i = 0; i < n; ++i)
  58         {
  59                 //print(search_getfilename(globhandle, i), "\n");
  60                 f = search_getfilename(globhandle, i);
  61                 PrecachePlayerSounds(f);
  62         }
  63         search_end(globhandle);
  64         */
  65 }
  66 void precache_all_playermodels(string pattern)
  67 {
  68         float globhandle, i, n;
  69         string f;
  70
  71         globhandle = search_begin(pattern, TRUE, FALSE);
  72         if (globhandle < 0)
  73                 return;
  74         n = search_getsize(globhandle);
  75         for (i = 0; i < n; ++i)
  76         {
  77                 //print(search_getfilename(globhandle, i), "\n");
  78                 f = search_getfilename(globhandle, i);
  79                 precache_playermodel(f);
  80         }
  81         search_end(globhandle);
  82 }
  83
  84 string forcefog;
  85 void WaypointSprite_Load();
  86 void ConsoleCommand_macro_init();
  87 void CSQC_Init(void)
  88 {
  89         prvm_language = cvar_string("prvm_language");
  90 #ifdef USE_FTE
  91 #pragma target ID
  92         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  93         if(!__engine_check)
  94         {
  95                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
  96                 localcmd("\ndisconnect\n");
  97                 return;
  98         }
  99 #pragma target FTE
 100 #endif
 101
 102         check_unacceptable_compiler_bugs();
 103
 104 #ifdef WATERMARK
 105         print(sprintf(_("^4CSQC Build information: ^1%s\n"), WATERMARK));
 106 #endif
 107
 108         float i;
 109
 110 #ifdef COMPAT_XON050_ENGINE
 111         // old engine lacks implementation of player_localnum
 112         player_localnum = player_localentnum - 1;
 113 #endif
 114
 115         binddb = db_create();
 116         tempdb = db_create();
 117         ClientProgsDB = db_load("client.db");
 118         compressShortVector_init();
 119
 120         draw_endBoldFont();
 121         menu_visible = FALSE;
 122         menu_show = menu_show_error;
 123         menu_action = func_null;
 124
 125         for(i = 0; i < 255; ++i)
 126                 if(getplayerkeyvalue(i, "viewentity") == "")
 127                         break;
 128         maxclients = i;
 129
 130         //registercommand("hud_configure");
 131         //registercommand("hud_save");
 132         //registercommand("menu_action");
 133
 134         ConsoleCommand_macro_init();
 135
 136         registercvar("hud_usecsqc", "1");
 137         registercvar("scoreboard_columns", "default");
 138
 139         gametype = 0;
 140
 141         // hud_fields uses strunzone on the titles!
 142         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 143                 hud_title[i] = strzone("(null)");
 144
 145         postinit = false;
 146
 147         calledhooks = 0;
 148
 149         teams = Sort_Spawn();
 150         players = Sort_Spawn();
 151
 152         GetTeam(NUM_SPECTATOR, true); // add specs first
 153
 154         // needs to be done so early because of the constants they create
 155         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 156         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 157         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 158         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 159
 160         WaypointSprite_Load();
 161
 162         // precaches
 163         precache_model("null");
 164         precache_sound("misc/hit.wav");
 165         precache_sound("misc/typehit.wav");
 166         if (autocvar_cl_precacheplayermodels)
 167         {
 168                 precache_all_playermodels("models/player/*.zym");
 169                 precache_all_playermodels("models/player/*.dpm");
 170                 precache_all_playermodels("models/player/*.md3");
 171                 precache_all_playermodels("models/player/*.psk");
 172                 precache_all_playermodels("models/player/*.iqm");
 173         }
 174
 175         Projectile_Precache();
 176         Hook_Precache();
 177         GibSplash_Precache();
 178         Casings_Precache();
 179         DamageInfo_Precache();
 180         Vehicles_Precache();
 181         turrets_precache();
 182         Tuba_Precache();
 183         CSQCPlayer_Precache();
 184
 185         if(autocvar_cl_reticle)
 186         {
 187                 if(autocvar_cl_reticle_item_normal) { precache_pic("gfx/reticle_normal"); }
 188                 if(autocvar_cl_reticle_item_nex) { precache_pic("gfx/reticle_nex"); }
 189         }
 190
 191         get_mi_min_max_texcoords(1); // try the CLEVER way first
 192         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 193         shortmapname = mi_shortname;
 194
 195         if(precache_pic(minimapname) == "")
 196         {
 197                 // but maybe we have a non-clever minimap
 198                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 199                 if(precache_pic(minimapname) == "")
 200                         minimapname = ""; // FAIL
 201                 else
 202                         get_mi_min_max_texcoords(0); // load new texcoords
 203         }
 204
 205         mi_center = (mi_min + mi_max) * 0.5;
 206         mi_scale = mi_max - mi_min;
 207         minimapname = strzone(minimapname);
 208
 209         WarpZone_Init();
 210
 211         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 212         hud_configure_prev = -1;
 213         tab_panel = -1;
 214
 215         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 216 }
 217
 218 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 219 void Shutdown(void)
 220 {
 221 #ifdef USE_FTE
 222 #pragma TARGET id
 223         if(!__engine_check)
 224                 return 0;
 225 #pragma TARGET fte
 226 #endif
 227
 228         WarpZone_Shutdown();
 229
 230         remove(teams);
 231         remove(players);
 232         db_close(binddb);
 233         db_close(tempdb);
 234         if(autocvar_cl_db_saveasdump)
 235                 db_dump(ClientProgsDB, "client.db");
 236         else
 237                 db_save(ClientProgsDB, "client.db");
 238         db_close(ClientProgsDB);
 239
 240         if(camera_active)
 241                 cvar_set("chase_active",ftos(chase_active_backup));
 242
 243         // unset the event chasecam's chase_active
 244         if(autocvar_chase_active < 0)
 245                 cvar_set("chase_active", "0");
 246
 247         if not(isdemo())
 248         {
 249                 if not(calledhooks & HOOK_START)
 250                         localcmd("\n_cl_hook_gamestart nop\n");
 251                 if not(calledhooks & HOOK_END)
 252                         localcmd("\ncl_hook_gameend\n");
 253         }
 254 }
 255
 256 .float has_team;
 257 float SetTeam(entity o, float Team)
 258 {
 259         entity tm;
 260         if(teamplay)
 261         {
 262                 switch(Team)
 263                 {
 264                         case -1:
 265                         case NUM_TEAM_1:
 266                         case NUM_TEAM_2:
 267                         case NUM_TEAM_3:
 268                         case NUM_TEAM_4:
 269                                 break;
 270                         default:
 271                                 if(GetTeam(Team, false) == world)
 272                                 {
 273                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 274                                         Team = NUM_SPECTATOR;
 275                                 }
 276                                 break;
 277                 }
 278         }
 279         else
 280         {
 281                 switch(Team)
 282                 {
 283                         case -1:
 284                         case 0:
 285                                 break;
 286                         default:
 287                                 if(GetTeam(Team, false) == world)
 288                                 {
 289                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 290                                         Team = NUM_SPECTATOR;
 291                                 }
 292                                 break;
 293                 }
 294         }
 295         if(Team == -1) // leave
 296         {
 297                 if(o.has_team)
 298                 {
 299                         tm = GetTeam(o.team, false);
 300                         tm.team_size -= 1;
 301                         o.has_team = 0;
 302                         return TRUE;
 303                 }
 304         }
 305         else
 306         {
 307                 if not(o.has_team)
 308                 {
 309                         o.team = Team;
 310                         tm = GetTeam(Team, true);
 311                         tm.team_size += 1;
 312                         o.has_team = 1;
 313                         return TRUE;
 314                 }
 315                 else if(Team != o.team)
 316                 {
 317                         tm = GetTeam(o.team, false);
 318                         tm.team_size -= 1;
 319                         o.team = Team;
 320                         tm = GetTeam(Team, true);
 321                         tm.team_size += 1;
 322                         return TRUE;
 323                 }
 324         }
 325         return FALSE;
 326 }
 327
 328 void Playerchecker_Think()
 329 {
 330         float i;
 331         entity e;
 332         for(i = 0; i < maxclients; ++i)
 333         {
 334                 e = playerslots[i];
 335                 if(GetPlayerName(i) == "")
 336                 {
 337                         if(e.sort_prev)
 338                         {
 339                                 // player disconnected
 340                                 SetTeam(e, -1);
 341                                 RemovePlayer(e);
 342                                 e.sort_prev = world;
 343                                 //e.gotscores = 0;
 344                         }
 345                 }
 346                 else
 347                 {
 348                         if not(e.sort_prev)
 349                         {
 350                                 // player connected
 351                                 if not(e)
 352                                         playerslots[i] = e = spawn();
 353                                 e.sv_entnum = i;
 354                                 e.ping = 0;
 355                                 e.ping_packetloss = 0;
 356                                 e.ping_movementloss = 0;
 357                                 //e.gotscores = 0; // we might already have the scores...
 358                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 359                                 RegisterPlayer(e);
 360                                 HUD_UpdatePlayerPos(e);
 361                         }
 362                 }
 363         }
 364         self.nextthink = time + 0.2;
 365 }
 366
 367 void Porto_Init();
 368 void TrueAim_Init();
 369 void PostInit(void)
 370 {
 371         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
 372
 373         entity playerchecker;
 374         playerchecker = spawn();
 375         playerchecker.think = Playerchecker_Think;
 376         playerchecker.nextthink = time + 0.2;
 377
 378         Porto_Init();
 379         TrueAim_Init();
 380
 381         postinit = true;
 382 }
 383
 384 float button_zoom;
 385
 386 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 387 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 388 // All keys are in ascii.
 389 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 390 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 391 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 392 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 393 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 394 {
 395         float bSkipKey;
 396         bSkipKey = false;
 397
 398         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 399                 return true;
 400
 401         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 402                 return true;
 403
 404         if(menu_visible && menu_action)
 405                 if(menu_action(bInputType, nPrimary, nSecondary))
 406                         return TRUE;
 407
 408         return bSkipKey;
 409 }
 410
 411 // END REQUIRED CSQC FUNCTIONS
 412 // --------------------------------------------------------------------------
 413
 414 // --------------------------------------------------------------------------
 415 // BEGIN OPTIONAL CSQC FUNCTIONS
 416 void Ent_RemoveEntCS()
 417 {
 418         entcs_receiver[self.sv_entnum] = world;
 419 }
 420 void Ent_ReadEntCS()
 421 {
 422         float sf;
 423         InterpolateOrigin_Undo();
 424
 425         self.classname = "entcs_receiver";
 426         sf = ReadByte();
 427
 428         if(sf & 1)
 429                 self.sv_entnum = ReadByte();
 430         if(sf & 2)
 431         {
 432                 self.origin_x = ReadShort();
 433                 self.origin_y = ReadShort();
 434                 self.origin_z = ReadShort();
 435                 setorigin(self, self.origin);
 436         }
 437         if(sf & 4)
 438         {
 439                 self.angles_y = ReadByte() * 360.0 / 256;
 440                 self.angles_x = self.angles_z = 0;
 441         }
 442         if(sf & 8)
 443                 self.healthvalue = ReadByte() * 10;
 444         if(sf & 16)
 445                 self.armorvalue = ReadByte() * 10;
 446
 447         entcs_receiver[self.sv_entnum] = self;
 448         self.entremove = Ent_RemoveEntCS;
 449         self.iflags |= IFLAG_ORIGIN;
 450
 451         InterpolateOrigin_Note();
 452 }
 453
 454 void Ent_Remove();
 455
 456 void Ent_RemovePlayerScore()
 457 {
 458         float i;
 459
 460         if(self.owner)
 461         {
 462                 SetTeam(self.owner, -1);
 463                 self.owner.gotscores = 0;
 464                 for(i = 0; i < MAX_SCORE; ++i)
 465                         self.owner.(scores[i]) = 0; // clear all scores
 466         }
 467 }
 468
 469 void Ent_ReadPlayerScore()
 470 {
 471         float i, n;
 472         float isNew;
 473         entity o;
 474
 475         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 476         // (no I've never heard of M-x replace-string, sed, or anything like that)
 477         isNew = !self.owner; // workaround for DP bug
 478         n = ReadByte()-1;
 479
 480 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 481         if(!isNew && n != self.sv_entnum)
 482         {
 483                 //print(_("A CSQC entity changed its owner!\n"));
 484                 print(sprintf(_("A CSQC entity changed its owner! (edict: %d, classname: %s)\n"), num_for_edict(self), self.classname));
 485                 isNew = true;
 486                 Ent_Remove();
 487                 self.enttype = ENT_CLIENT_SCORES;
 488         }
 489 #endif
 490
 491         self.sv_entnum = n;
 492
 493         if not(playerslots[self.sv_entnum])
 494                 playerslots[self.sv_entnum] = spawn();
 495         o = self.owner = playerslots[self.sv_entnum];
 496         o.sv_entnum = self.sv_entnum;
 497         o.gotscores = 1;
 498
 499         //if not(o.sort_prev)
 500         //      RegisterPlayer(o);
 501         //playerchecker will do this for us later, if it has not already done so
 502
 503         float sf, lf;
 504 #if MAX_SCORE <= 8
 505         sf = ReadByte();
 506         lf = ReadByte();
 507 #else
 508         sf = ReadShort();
 509         lf = ReadShort();
 510 #endif
 511         float p;
 512         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 513                 if(sf & p)
 514                 {
 515                         if(lf & p)
 516                                 o.(scores[i]) = ReadInt24_t();
 517                         else
 518                                 o.(scores[i]) = ReadChar();
 519                 }
 520
 521         if(o.sort_prev)
 522                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 523
 524         self.entremove = Ent_RemovePlayerScore;
 525 }
 526
 527 void Ent_ReadTeamScore()
 528 {
 529         float i;
 530         entity o;
 531
 532         self.team = ReadByte();
 533         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 534
 535         float sf, lf;
 536 #if MAX_TEAMSCORE <= 8
 537         sf = ReadByte();
 538         lf = ReadByte();
 539 #else
 540         sf = ReadShort();
 541         lf = ReadShort();
 542 #endif
 543         float p;
 544         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 545                 if(sf & p)
 546                 {
 547                         if(lf & p)
 548                                 o.(teamscores[i]) = ReadInt24_t();
 549                         else
 550                                 o.(teamscores[i]) = ReadChar();
 551                 }
 552
 553         HUD_UpdateTeamPos(o);
 554 }
 555
 556 void Ent_ClientData()
 557 {
 558         float f;
 559         float newspectatee_status;
 560
 561         f = ReadByte();
 562
 563         scoreboard_showscores_force = (f & 1);
 564
 565         if(f & 2)
 566         {
 567                 newspectatee_status = ReadByte();
 568                 if(newspectatee_status == player_localnum + 1)
 569                         newspectatee_status = -1; // observing
 570         }
 571         else
 572                 newspectatee_status = 0;
 573
 574         spectatorbutton_zoom = (f & 4);
 575
 576         if(f & 8)
 577         {
 578                 angles_held_status = 1;
 579                 angles_held_x = ReadAngle();
 580                 angles_held_y = ReadAngle();
 581                 angles_held_z = 0;
 582         }
 583         else
 584                 angles_held_status = 0;
 585
 586         if(newspectatee_status != spectatee_status)
 587         {
 588                 // clear race stuff
 589                 race_laptime = 0;
 590                 race_checkpointtime = 0;
 591         }
 592         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 593         {
 594                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 595                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 596                 )
 597                         prev_p_health = -1;
 598                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 599                         prev_health = -1;
 600         }
 601         spectatee_status = newspectatee_status;
 602
 603         // non-COMPAT_XON050_ENGINE: we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 604 }
 605
 606 void Ent_Nagger()
 607 {
 608         float nags, i, j, b, f;
 609
 610         nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 611
 612         if(!(nags & 4))
 613         {
 614                 if(vote_called_vote)
 615                         strunzone(vote_called_vote);
 616                 vote_called_vote = string_null;
 617                 vote_active = 0;
 618         }
 619         else
 620         {
 621                 vote_active = 1;
 622         }
 623
 624         if(nags & 64)
 625         {
 626                 vote_yescount = ReadByte();
 627                 vote_nocount = ReadByte();
 628                 vote_needed = ReadByte();
 629                 vote_highlighted = ReadChar();
 630         }
 631
 632         if(nags & 128)
 633         {
 634                 if(vote_called_vote)
 635                         strunzone(vote_called_vote);
 636                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 637         }
 638
 639         if(nags & 1)
 640         {
 641                 for(j = 0; j < maxclients; ++j)
 642                         if(playerslots[j])
 643                                 playerslots[j].ready = 1;
 644                 for(i = 1; i <= maxclients; i += 8)
 645                 {
 646                         f = ReadByte();
 647                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 648                                 if not(f & b)
 649                                         if(playerslots[j])
 650                                                 playerslots[j].ready = 0;
 651                 }
 652         }
 653
 654         ready_waiting = (nags & 1);
 655         ready_waiting_for_me = (nags & 2);
 656         vote_waiting = (nags & 4);
 657         vote_waiting_for_me = (nags & 8);
 658         warmup_stage = (nags & 16);
 659 }
 660
 661 void Ent_RandomSeed()
 662 {
 663         float s;
 664         prandom_debug();
 665         s = ReadShort();
 666         psrandom(s);
 667 }
 668
 669 void Ent_ReadAccuracy(void)
 670 {
 671         float sf, f, w, b;
 672         sf = ReadInt24_t();
 673         if(sf == 0)
 674         {
 675                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 676                         weapon_accuracy[w] = -1;
 677                 return;
 678         }
 679
 680         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 681         {
 682                 if(sf & f)
 683                 {
 684                         b = ReadByte();
 685                         if(b == 0)
 686                                 weapon_accuracy[w] = -1;
 687                         else if(b == 255)
 688                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 689                         else
 690                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 691                 }
 692                 if(f == 0x800000)
 693                         f = 1;
 694                 else
 695                         f *= 2;
 696         }
 697 }
 698
 699 void Spawn_Draw(void)
 700 {
 701         pointparticles(particleeffectnum("EF_STARDUST"), self.origin, '0 0 2', bound(0, frametime, 0.1));
 702 }
 703
 704 void Ent_ReadSpawnPoint(float is_new)
 705 {
 706         self.team = ReadByte();
 707         self.origin_x = ReadShort();
 708         self.origin_y = ReadShort();
 709         self.origin_z = ReadShort();
 710
 711         //self.colormod = colormapPaletteColor(self.team - 1, FALSE);
 712
 713         //setsize(self, PL_MIN, PL_MAX);
 714
 715         //droptofloor();
 716
 717         //self.mdl = "models/domination/dom_unclaimed.md3";
 718         //precache_model(self.mdl);
 719         //setmodel(self, self.mdl);
 720         self.drawmask = MASK_NORMAL;
 721         self.movetype = MOVETYPE_NOCLIP;
 722         self.draw = Spawn_Draw;
 723
 724         print(ftos(is_new), " - read a spawnpoint at ", vtos(self.origin), ", bitches.\n");
 725 }
 726
 727 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 728 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 729 void Ent_RadarLink();
 730 void Ent_Init();
 731 void Ent_ScoresInfo();
 732 void CSQC_Ent_Update(float bIsNewEntity)
 733 {
 734         float t;
 735         float savetime;
 736         t = ReadByte();
 737
 738         if(autocvar_developer_csqcentities)
 739                 print(sprintf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t));
 740
 741         // set up the "time" global for received entities to be correct for interpolation purposes
 742         savetime = time;
 743         if(servertime)
 744         {
 745                 time = servertime;
 746         }
 747         else
 748         {
 749                 serverprevtime = time;
 750                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 751                 time = serverprevtime + serverdeltatime;
 752         }
 753
 754 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 755         if(self.enttype)
 756         {
 757                 if(t != self.enttype || bIsNewEntity)
 758                 {
 759                         //print(_("A CSQC entity changed its type!\n"));
 760                         print(sprintf(_("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n"), num_for_edict(self), self.entnum, self.enttype, t));
 761                         Ent_Remove();
 762                         clearentity(self);
 763                         bIsNewEntity = 1;
 764                 }
 765         }
 766         else
 767         {
 768                 if(!bIsNewEntity)
 769                 {
 770                         print(sprintf(_("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n"), num_for_edict(self), self.entnum, t));
 771                         bIsNewEntity = 1;
 772                 }
 773         }
 774 #endif
 775         self.enttype = t;
 776         switch(t)
 777         {
 778                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 779                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 780                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 781                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 782                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 783                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 784                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 785                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 786                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 787                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 788                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 789                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 790                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 791                 case ENT_CLIENT_INIT: Ent_Init(); break;
 792                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 793                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 794                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 795                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 796                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 797                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 798                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 799                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 800                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 801                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 802                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 803                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 804                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
 805                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
 806                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 807                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 808                 case ENT_CLIENT_TURRET: ent_turret(); break;
 809                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 810                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 811                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 812                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
 813                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
 814
 815                 default:
 816                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 817                         error(sprintf(_("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n"), self.enttype, num_for_edict(self), self.classname));
 818                         break;
 819         }
 820
 821         time = savetime;
 822 }
 823 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 824 // used when an entity changes its type. For an entity that someone interacts
 825 // with others, make sure it can no longer do so.
 826 void Ent_Remove()
 827 {
 828         if(self.entremove)
 829                 self.entremove();
 830
 831         if(self.skeletonindex)
 832         {
 833                 skel_delete(self.skeletonindex);
 834                 self.skeletonindex = 0;
 835         }
 836
 837         if(self.snd_looping > 0)
 838         {
 839                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 840                 self.snd_looping = 0;
 841         }
 842
 843         self.enttype = 0;
 844         self.classname = "";
 845         self.draw = menu_sub_null;
 846         self.entremove = menu_sub_null;
 847         // TODO possibly set more stuff to defaults
 848 }
 849 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 850 void CSQC_Ent_Remove()
 851 {
 852         if(autocvar_developer_csqcentities)
 853                 print(sprintf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype));
 854
 855         if(wasfreed(self))
 856         {
 857                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 858                 return;
 859         }
 860         if(self.enttype)
 861                 Ent_Remove();
 862         remove(self);
 863 }
 864
 865 void Gamemode_Init()
 866 {
 867         if not(isdemo())
 868         {
 869                 if(!(calledhooks & HOOK_START))
 870                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 871                 calledhooks |= HOOK_START;
 872         }
 873 }
 874 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 875 void CSQC_Parse_StuffCmd(string strMessage)
 876 {
 877         if(autocvar_developer_csqcentities)
 878                 print(sprintf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage));
 879
 880         localcmd(strMessage);
 881 }
 882 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 883 void CSQC_Parse_Print(string strMessage)
 884 {
 885         if(autocvar_developer_csqcentities)
 886                 print(sprintf("CSQC_Parse_Print(\"%s\")\n", strMessage));
 887
 888         print(ColorTranslateRGB(strMessage));
 889 }
 890
 891 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 892 void CSQC_Parse_CenterPrint(string strMessage)
 893 {
 894         if(autocvar_developer_csqcentities)
 895                 print(sprintf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage));
 896
 897         centerprint_hud(strMessage);
 898 }
 899
 900 string notranslate_fogcmd1 = "\nfog ";
 901 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 902 void Fog_Force()
 903 {
 904         // TODO somehow thwart prvm_globalset client ...
 905
 906         if(forcefog != "")
 907                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
 908 }
 909
 910 void Gamemode_Init();
 911 void Ent_ScoresInfo()
 912 {
 913         float i;
 914         self.classname = "ent_client_scores_info";
 915         gametype = ReadInt24_t();
 916         for(i = 0; i < MAX_SCORE; ++i)
 917         {
 918                 scores_label[i] = strzone(ReadString());
 919                 scores_flags[i] = ReadByte();
 920         }
 921         for(i = 0; i < MAX_TEAMSCORE; ++i)
 922         {
 923                 teamscores_label[i] = strzone(ReadString());
 924                 teamscores_flags[i] = ReadByte();
 925         }
 926         HUD_InitScores();
 927         Gamemode_Init();
 928 }
 929
 930 void Ent_Init()
 931 {
 932         self.classname = "ent_client_init";
 933
 934         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 935
 936         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 937         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 938         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 939         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 940         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 941         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 942         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 943         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 944         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 945         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 946         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 947         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 948
 949         if(forcefog)
 950                 strunzone(forcefog);
 951         forcefog = strzone(ReadString());
 952
 953         armorblockpercent = ReadByte() / 255.0;
 954
 955         g_weaponswitchdelay = ReadByte() / 255.0;
 956
 957         g_balance_grenadelauncher_bouncefactor = ReadCoord();
 958         g_balance_grenadelauncher_bouncestop = ReadCoord();
 959         g_balance_electro_secondary_bouncefactor = ReadCoord();
 960         g_balance_electro_secondary_bouncestop = ReadCoord();
 961
 962         nex_scope = !ReadByte();
 963         rifle_scope = !ReadByte();
 964
 965         serverflags = ReadByte();
 966
 967         minelayer_maxmines = ReadByte();
 968
 969         hagar_maxrockets = ReadByte();
 970
 971         g_trueaim_minrange = ReadCoord();
 972         g_balance_porto_secondary = ReadByte();
 973
 974         if(!postinit)
 975                 PostInit();
 976 }
 977
 978 void Net_ReadRace()
 979 {
 980         float b;
 981
 982         b = ReadByte();
 983
 984         switch(b)
 985         {
 986                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
 987                         race_checkpoint = ReadByte();
 988                         race_time = ReadInt24_t();
 989                         race_previousbesttime = ReadInt24_t();
 990                         if(race_previousbestname)
 991                                 strunzone(race_previousbestname);
 992                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
 993
 994                         race_checkpointtime = time;
 995
 996                         if(race_checkpoint == 0 || race_checkpoint == 254)
 997                         {
 998                                 race_penaltyaccumulator = 0;
 999                                 race_laptime = time; // valid
1000                         }
1001
1002                         break;
1003
1004                 case RACE_NET_CHECKPOINT_CLEAR:
1005                         race_laptime = 0;
1006                         race_checkpointtime = 0;
1007                         break;
1008
1009                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1010                         race_laptime = ReadCoord();
1011                         race_checkpointtime = -99999;
1012                         // fall through
1013                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1014                         race_nextcheckpoint = ReadByte();
1015
1016                         race_nextbesttime = ReadInt24_t();
1017                         if(race_nextbestname)
1018                                 strunzone(race_nextbestname);
1019                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1020                         break;
1021
1022                 case RACE_NET_CHECKPOINT_HIT_RACE:
1023                         race_mycheckpoint = ReadByte();
1024                         race_mycheckpointtime = time;
1025                         race_mycheckpointdelta = ReadInt24_t();
1026                         race_mycheckpointlapsdelta = ReadByte();
1027                         if(race_mycheckpointlapsdelta >= 128)
1028                                 race_mycheckpointlapsdelta -= 256;
1029                         if(race_mycheckpointenemy)
1030                                 strunzone(race_mycheckpointenemy);
1031                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1032                         break;
1033
1034                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1035                         race_othercheckpoint = ReadByte();
1036                         race_othercheckpointtime = time;
1037                         race_othercheckpointdelta = ReadInt24_t();
1038                         race_othercheckpointlapsdelta = ReadByte();
1039                         if(race_othercheckpointlapsdelta >= 128)
1040                                 race_othercheckpointlapsdelta -= 256;
1041                         if(race_othercheckpointenemy)
1042                                 strunzone(race_othercheckpointenemy);
1043                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1044                         break;
1045
1046                 case RACE_NET_PENALTY_RACE:
1047                         race_penaltyeventtime = time;
1048                         race_penaltytime = ReadShort();
1049                         //race_penaltyaccumulator += race_penaltytime;
1050                         if(race_penaltyreason)
1051                                 strunzone(race_penaltyreason);
1052                         race_penaltyreason = strzone(ReadString());
1053                         break;
1054
1055                 case RACE_NET_PENALTY_QUALIFYING:
1056                         race_penaltyeventtime = time;
1057                         race_penaltytime = ReadShort();
1058                         race_penaltyaccumulator += race_penaltytime;
1059                         if(race_penaltyreason)
1060                                 strunzone(race_penaltyreason);
1061                         race_penaltyreason = strzone(ReadString());
1062                         break;
1063
1064                 case RACE_NET_SERVER_RECORD:
1065                         race_server_record = ReadInt24_t();
1066                         break;
1067                 case RACE_NET_SPEED_AWARD:
1068                         race_speedaward = ReadInt24_t();
1069                         if(race_speedaward_holder)
1070                                 strunzone(race_speedaward_holder);
1071                         race_speedaward_holder = strzone(ReadString());
1072                         break;
1073                 case RACE_NET_SPEED_AWARD_BEST:
1074                         race_speedaward_alltimebest = ReadInt24_t();
1075                         if(race_speedaward_alltimebest_holder)
1076                                 strunzone(race_speedaward_alltimebest_holder);
1077                         race_speedaward_alltimebest_holder = strzone(ReadString());
1078                         break;
1079                 case RACE_NET_SERVER_RANKINGS:
1080                         float pos, prevpos, del;
1081                         pos = ReadShort();
1082                         prevpos = ReadShort();
1083                         del = ReadShort();
1084
1085                         // move other rankings out of the way
1086                         float i;
1087                         if (prevpos) {
1088                                 for (i=prevpos-1;i>pos-1;--i) {
1089                                         grecordtime[i] = grecordtime[i-1];
1090                                         if(grecordholder[i])
1091                                                 strunzone(grecordholder[i]);
1092                                         grecordholder[i] = strzone(grecordholder[i-1]);
1093                                 }
1094                         } else if (del) { // a record has been deleted by the admin
1095                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1096                                         if (i == RANKINGS_CNT-1) { // clear out last record
1097                                                 grecordtime[i] = 0;
1098                                                 if (grecordholder[i])
1099                                                         strunzone(grecordholder[i]);
1100                                                 grecordholder[i] = string_null;
1101                                         }
1102                                         else {
1103                                                 grecordtime[i] = grecordtime[i+1];
1104                                                 if (grecordholder[i])
1105                                                         strunzone(grecordholder[i]);
1106                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1107                                         }
1108                                 }
1109                         } else { // player has no ranked record yet
1110                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1111                                         grecordtime[i] = grecordtime[i-1];
1112                                         if(grecordholder[i])
1113                                                 strunzone(grecordholder[i]);
1114                                         grecordholder[i] = strzone(grecordholder[i-1]);
1115                                 }
1116                         }
1117
1118                         // store new ranking
1119                         if(grecordholder[pos-1] != "")
1120                                 strunzone(grecordholder[pos-1]);
1121                         grecordholder[pos-1] = strzone(ReadString());
1122                         grecordtime[pos-1] = ReadInt24_t();
1123                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1124                                 race_myrank = pos;
1125                         break;
1126                 case RACE_NET_SERVER_STATUS:
1127                         race_status = ReadShort();
1128                         if(race_status_name)
1129                                 strunzone(race_status_name);
1130                         race_status_name = strzone(ReadString());
1131         }
1132 }
1133
1134 void Net_ReadSpawn()
1135 {
1136         zoomin_effect = 1;
1137         current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
1138
1139         if(autocvar_cl_unpress_zoom_on_spawn)
1140         {
1141                 localcmd("-zoom\n");
1142                 button_zoom = FALSE;
1143         }
1144 }
1145
1146 void Net_TeamNagger()
1147 {
1148         teamnagger = 1;
1149 }
1150
1151 void Net_ReadPingPLReport()
1152 {
1153         float e, pi, pl, ml;
1154         e = ReadByte();
1155         pi = ReadShort();
1156         pl = ReadByte();
1157         ml = ReadByte();
1158         if not(playerslots[e])
1159                 return;
1160         playerslots[e].ping = pi;
1161         playerslots[e].ping_packetloss = pl / 255.0;
1162         playerslots[e].ping_movementloss = ml / 255.0;
1163 }
1164
1165 void Net_WeaponComplain()
1166 {
1167         complain_weapon = ReadByte();
1168
1169         if(complain_weapon_name)
1170                 strunzone(complain_weapon_name);
1171         complain_weapon_name = strzone(ReadString());
1172
1173         complain_weapon_type = ReadByte();
1174
1175         complain_weapon_time = time;
1176         weapontime = time; // ping the weapon panel
1177
1178         switch(complain_weapon_type)
1179         {
1180                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1181                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1182                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1183         }
1184 }
1185
1186 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1187 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1188 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1189 float CSQC_Parse_TempEntity()
1190 {
1191         float bHandled;
1192                 bHandled  = true;
1193         // Acquire TE ID
1194         float nTEID;
1195                 nTEID = ReadByte();
1196
1197         if(autocvar_developer_csqcentities)
1198                 print(sprintf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID));
1199
1200                 // NOTE: Could just do return instead of break...
1201         switch(nTEID)
1202         {
1203                 case TE_CSQC_TARGET_MUSIC:
1204                         Net_TargetMusic();
1205                         bHandled = true;
1206                         break;
1207                 case TE_CSQC_PICTURE:
1208                         Net_MapVote_Picture();
1209                         bHandled = true;
1210                         break;
1211                 case TE_CSQC_RACE:
1212                         Net_ReadRace();
1213                         bHandled = true;
1214                         break;
1215                 case TE_CSQC_SPAWN:
1216                         Net_ReadSpawn();
1217                         bHandled = true;
1218                         break;
1219                 case TE_CSQC_ZCURVEPARTICLES:
1220                         Net_ReadZCurveParticles();
1221                         bHandled = true;
1222                         break;
1223                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1224                         Net_ReadNexgunBeamParticle();
1225                         bHandled = true;
1226                         break;
1227                 case TE_CSQC_TEAMNAGGER:
1228                         Net_TeamNagger();
1229                         bHandled = true;
1230                         break;
1231                 case TE_CSQC_LIGHTNINGARC:
1232                         Net_ReadLightningarc();
1233                         bHandled = true;
1234                         break;
1235                 case TE_CSQC_PINGPLREPORT:
1236                         Net_ReadPingPLReport();
1237                         bHandled = true;
1238                         break;
1239                 case TE_CSQC_WEAPONCOMPLAIN:
1240                         Net_WeaponComplain();
1241                         bHandled = true;
1242                         break;
1243                 case TE_CSQC_VEHICLESETUP:
1244                         Net_VehicleSetup();
1245                         bHandled = true;
1246                         break;
1247                 case TE_CSQC_SVNOTICE:
1248                         cl_notice_read();
1249                         bHandled = true;
1250                         break;
1251                 default:
1252                         // No special logic for this temporary entity; return 0 so the engine can handle it
1253                         bHandled = false;
1254                         break;
1255         }
1256
1257         return bHandled;
1258 }
1259
1260 string getcommandkey(string text, string command)
1261 {
1262         string keys;
1263         float n, j, k, l = 0;
1264
1265         if (!autocvar_hud_showbinds)
1266                 return text;
1267
1268         keys = db_get(binddb, command);
1269         if (keys == "")
1270         {
1271                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1272                 for(j = 0; j < n; ++j)
1273                 {
1274                         k = stof(argv(j));
1275                         if(k != -1)
1276                         {
1277                                 if ("" == keys)
1278                                         keys = keynumtostring(k);
1279                                 else
1280                                         keys = strcat(keys, ", ", keynumtostring(k));
1281
1282                                 ++l;
1283                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1284                                         break;
1285                         }
1286
1287                 }
1288                 if (keys == "")
1289                         keys = "NO_KEY";
1290                 db_put(binddb, command, keys);
1291         }
1292
1293         if (keys == "NO_KEY") {
1294                 if (autocvar_hud_showbinds > 1)
1295                         return sprintf(_("%s (not bound)"), text);
1296                 else
1297                         return text;
1298         }
1299         else if (autocvar_hud_showbinds > 1)
1300                 return sprintf(_("%s (%s)"), text, keys);
1301         else
1302                 return keys;
1303 }