qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
   6
   7 void cvar_clientsettemp(string cv, string val)
   8 {
   9         entity e;
  10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  11                 if(e.netname == cv)
  12                         goto saved;
  13         e = spawn();
  14         e.classname = "saved_cvar_value";
  15         e.netname = strzone(cv);
  16         e.message = strzone(cvar_string(cv));
  17 :saved
  18         cvar_set(cv, val);
  19 }
  20
  21 void cvar_clientsettemp_restore()
  22 {
  23         entity e;
  24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  25                         cvar_set(e.netname, e.message);
  26 }
  27
  28 void() menu_show_error =
  29 {
  30         drawstring('0 200 0', "ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!", '8 8 0', '1 0 0', 1, 0);
  31 };
  32
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  34 // Useful for precaching things
  35
  36 void() menu_sub_null =
  37 {
  38 };
  39
  40 #ifdef USE_FTE
  41 float __engine_check;
  42 #endif
  43
  44 string forcefog;
  45 string cl_announcer_prev;
  46 void WaypointSprite_Load();
  47 void CSQC_Init(void)
  48 {
  49 #ifdef USE_FTE
  50 #pragma target ID
  51         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  52         if(!__engine_check)
  53         {
  54                 print("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n");
  55                 localcmd("\ndisconnect\n");
  56                 return;
  57         }
  58 #pragma target FTE
  59 #endif
  60
  61         check_unacceptable_compiler_bugs();
  62
  63 #ifdef WATERMARK
  64         print("^4CSQC Build information: ", WATERMARK(), "\n");
  65 #endif
  66
  67         float i;
  68         CSQC_CheckEngine();
  69
  70         binddb = db_create();
  71         tempdb = db_create();
  72         ClientProgsDB = db_load("client.db");
  73         compressShortVector_init();
  74
  75         drawfont = 0;
  76         menu_visible = FALSE;
  77         menu_show = menu_show_error;
  78         menu_action = menu_sub_null;
  79
  80         for(i = 0; i < 255; ++i)
  81                 if(getplayerkey(i, "viewentity") == "")
  82                         break;
  83         maxclients = i;
  84
  85         //ctf_temp_1 = "";
  86         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used
  87         //registercmd("ctf_menu");
  88         registercmd("ons_map");
  89         registercmd("hud_configure");
  90         registercmd("hud_save");
  91         //registercmd("menu_action");
  92
  93         registercmd("+button3");
  94         registercmd("-button3");
  95         registercmd("+button4");
  96         registercmd("-button4");
  97         registercmd("+showscores");registercmd("-showscores");
  98         registercmd("+showaccuracy");registercmd("-showaccuracy");
  99
 100 #ifndef CAMERATEST
 101         if(isdemo())
 102         {
 103 #endif
 104                 registercmd("+forward");registercmd("-forward");
 105                 registercmd("+back");registercmd("-back");
 106                 registercmd("+moveup");registercmd("-moveup");
 107                 registercmd("+movedown");registercmd("-movedown");
 108                 registercmd("+moveright");registercmd("-moveright");
 109                 registercmd("+moveleft");registercmd("-moveleft");
 110                 registercmd("+roll_right");registercmd("-roll_right");
 111                 registercmd("+roll_left");registercmd("-roll_left");
 112 #ifndef CAMERATEST
 113         }
 114 #endif
 115         registercvar("hud_usecsqc", "1");
 116         registercvar("scoreboard_columns", "default", CVAR_SAVE);
 117
 118         gametype = 0;
 119
 120         // hud_fields uses strunzone on the titles!
 121         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 122                 hud_title[i] = strzone("(null)");
 123
 124         postinit = false;
 125
 126         calledhooks = 0;
 127
 128         teams = Sort_Spawn();
 129         players = Sort_Spawn();
 130
 131         GetTeam(COLOR_SPECTATOR, true); // add specs first
 132
 133         RegisterWeapons();
 134
 135         WaypointSprite_Load();
 136
 137         // precaches
 138         Projectile_Precache();
 139         Hook_Precache();
 140         GibSplash_Precache();
 141         Casings_Precache();
 142         DamageInfo_Precache();
 143         if(autocvar_cl_announcer != cl_announcer_prev) {
 144                 Announcer_Precache();
 145                 if(cl_announcer_prev)
 146                         strunzone(cl_announcer_prev);
 147                 cl_announcer_prev = strzone(autocvar_cl_announcer);
 148         }
 149         Tuba_Precache();
 150
 151         get_mi_min_max_texcoords(1); // try the CLEVER way first
 152         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 153         shortmapname = mi_shortname;
 154
 155         if(precache_pic(minimapname) == "")
 156         {
 157                 // but maybe we have a non-clever minimap
 158                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 159                 if(precache_pic(minimapname) == "")
 160                         minimapname = ""; // FAIL
 161                 else
 162                         get_mi_min_max_texcoords(0); // load new texcoords
 163         }
 164
 165         mi_center = (mi_min + mi_max) * 0.5;
 166         mi_scale = mi_max - mi_min;
 167         minimapname = strzone(minimapname);
 168
 169         WarpZone_Init();
 170
 171         hud_configure_prev = -1;
 172         tab_panel = -1;
 173 }
 174
 175 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 176 void CSQC_Shutdown(void)
 177 {
 178 #ifdef USE_FTE
 179 #pragma TARGET id
 180         if(!__engine_check)
 181                 return 0;
 182 #pragma TARGET fte
 183 #endif
 184
 185         WarpZone_Shutdown();
 186
 187         remove(teams);
 188         remove(players);
 189         db_close(binddb);
 190         db_close(tempdb);
 191         if(autocvar_cl_db_saveasdump)
 192                 db_dump(ClientProgsDB, "client.db");
 193         else
 194                 db_save(ClientProgsDB, "client.db");
 195         db_close(ClientProgsDB);
 196
 197         cvar_clientsettemp_restore();
 198
 199         if(camera_active)
 200                 cvar_set("chase_active",ftos(chase_active_backup));
 201
 202         if not(isdemo())
 203         {
 204                 if not(calledhooks & HOOK_START)
 205                         localcmd("\n_cl_hook_gamestart nop\n");
 206                 if not(calledhooks & HOOK_END)
 207                         localcmd("\ncl_hook_gameend\n");
 208         }
 209 }
 210
 211 .float has_team;
 212 float SetTeam(entity o, float Team)
 213 {
 214         entity tm;
 215         if(teamplay)
 216         {
 217                 switch(Team)
 218                 {
 219                         case -1:
 220                         case COLOR_TEAM1:
 221                         case COLOR_TEAM2:
 222                         case COLOR_TEAM3:
 223                         case COLOR_TEAM4:
 224                                 break;
 225                         default:
 226                                 if(GetTeam(Team, false) == NULL)
 227                                 {
 228                                         print("trying to switch to unsupported team ", ftos(Team), "\n");
 229                                         Team = COLOR_SPECTATOR;
 230                                 }
 231                                 break;
 232                 }
 233         }
 234         else
 235         {
 236                 switch(Team)
 237                 {
 238                         case -1:
 239                         case 0:
 240                                 break;
 241                         default:
 242                                 if(GetTeam(Team, false) == NULL)
 243                                 {
 244                                         print("trying to switch to unsupported team ", ftos(Team), "\n");
 245                                         Team = COLOR_SPECTATOR;
 246                                 }
 247                                 break;
 248                 }
 249         }
 250         if(Team == -1) // leave
 251         {
 252                 if(o.has_team)
 253                 {
 254                         //print("(DISCONNECT) leave team ", ftos(o.team), "\n");
 255                         tm = GetTeam(o.team, false);
 256                         tm.team_size -= 1;
 257                         o.has_team = 0;
 258                         return TRUE;
 259                 }
 260         }
 261         else
 262         {
 263                 if not(o.has_team)
 264                 {
 265                         //print("(CONNECT) enter team ", ftos(o.team), "\n");
 266                         o.team = Team;
 267                         tm = GetTeam(Team, true);
 268                         tm.team_size += 1;
 269                         o.has_team = 1;
 270                         return TRUE;
 271                 }
 272                 else if(Team != o.team)
 273                 {
 274                         //print("(CHANGE) leave team ", ftos(o.team), "\n");
 275                         tm = GetTeam(o.team, false);
 276                         tm.team_size -= 1;
 277                         o.team = Team;
 278                         //print("(CHANGE) enter team ", ftos(o.team), "\n");
 279                         tm = GetTeam(Team, true);
 280                         tm.team_size += 1;
 281                         return TRUE;
 282                 }
 283         }
 284         return FALSE;
 285 }
 286
 287 void Playerchecker_Think()
 288 {
 289         float i;
 290         entity e;
 291         for(i = 0; i < maxclients; ++i)
 292         {
 293                 e = playerslots[i];
 294                 if(GetPlayerName(i) == "")
 295                 {
 296                         if(e.sort_prev)
 297                         {
 298                                 //print("playerchecker: KILL KILL KILL\n");
 299                                 // player disconnected
 300                                 SetTeam(e, -1);
 301                                 RemovePlayer(e);
 302                                 e.sort_prev = world;
 303                                 //e.gotscores = 0;
 304                         }
 305                 }
 306                 else
 307                 {
 308                         if not(e.sort_prev)
 309                         {
 310                                 //print("playerchecker: SPAWN SPAWN SPAWN\n");
 311                                 // player connected
 312                                 if not(e)
 313                                         playerslots[i] = e = spawn();
 314                                 e.sv_entnum = i;
 315                                 e.ping = 0;
 316                                 e.ping_packetloss = 0;
 317                                 e.ping_movementloss = 0;
 318                                 //e.gotscores = 0; // we might already have the scores...
 319                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 320                                 RegisterPlayer(e);
 321                                 HUD_UpdatePlayerPos(e);
 322                         }
 323                 }
 324         }
 325         self.nextthink = time + 0.2;
 326 }
 327
 328 void Porto_Init();
 329 void TrueAim_Init();
 330 void PostInit(void)
 331 {
 332         print(strcat("PostInit\n    maxclients = ", ftos(maxclients), "\n"));
 333         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
 334
 335         entity playerchecker;
 336         playerchecker = spawn();
 337         playerchecker.think = Playerchecker_Think;
 338         playerchecker.nextthink = time + 0.2;
 339
 340         Porto_Init();
 341         TrueAim_Init();
 342
 343         postinit = true;
 344 }
 345
 346 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function
 347 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.
 348 float button_zoom;
 349 void Cmd_HUD_SetFields(float);
 350 void Cmd_HUD_Help(float);
 351 float CSQC_ConsoleCommand(string strMessage)
 352 {
 353         float argc;
 354         // Tokenize String
 355         //argc = tokenize(strMessage);
 356         argc = tokenize_console(strMessage);
 357
 358         // Acquire Command
 359         local string strCmd;
 360         strCmd = argv(0);
 361
 362         if(strCmd == "hud_configure") { // config hud
 363                 cvar_set("_hud_configure", ftos(!autocvar__hud_configure));
 364                 return true;
 365         } else if(strCmd == "hud_save") { // save hud config
 366                 if(argv(1) == "" || argv(2)) {
 367                         print("Usage:\n");
 368                         print("hud_save configname   (saves to hud_skinname_configname.cfg)\n");
 369                 }
 370                 else
 371                         HUD_Panel_ExportCfg(argv(1));
 372                 return true;
 373         } else if(strCmd == "+button4") { // zoom
 374                 // return false, because the message shall be sent to the server anyway (for demos/speccing)
 375                 if(ignore_plus_zoom)
 376                 {
 377                         --ignore_plus_zoom;
 378                         return false;
 379                 }
 380                 button_zoom = 1;
 381                 return true;
 382         } else if(strCmd == "-button4") { // zoom
 383                 if(ignore_minus_zoom)
 384                 {
 385                         --ignore_minus_zoom;
 386                         return false;
 387                 }
 388                 button_zoom = 0;
 389                 return true;
 390         } else if(strCmd == "+button3") { // secondary
 391                 button_attack2 = 1;
 392                 return false;
 393         } else if(strCmd == "-button3") { // secondary
 394                 button_attack2 = 0;
 395                 return false;
 396         } else if(strCmd == "+showscores") {
 397                 scoreboard_showscores = true;
 398                 return true;
 399         } else if(strCmd == "-showscores") {
 400                 scoreboard_showscores = false;
 401                 return true;
 402         } else if(strCmd == "+showaccuracy") {
 403                 scoreboard_showaccuracy = true;
 404                 return true;
 405         } else if(strCmd == "-showaccuracy") {
 406                 scoreboard_showaccuracy = false;
 407                 return true;
 408         }
 409
 410         if(camera_active)
 411         if(strCmd == "+forward" || strCmd == "-back") {
 412                 ++camera_direction_x;
 413                 return true;
 414         } else if(strCmd == "-forward" || strCmd == "+back") {
 415                 --camera_direction_x;
 416                 return true;
 417         } else if(strCmd == "+moveright" || strCmd == "-moveleft") {
 418                 --camera_direction_y;
 419                 return true;
 420         } else if(strCmd == "-moveright" || strCmd == "+moveleft") {
 421                 ++camera_direction_y;
 422                 return true;
 423         } else if(strCmd == "+moveup" || strCmd == "-movedown") {
 424                 ++camera_direction_z;
 425                 return true;
 426         } else if(strCmd == "-moveup" || strCmd == "+movedown") {
 427                 --camera_direction_z;
 428                 return true;
 429         } else if(strCmd == "+roll_right" || strCmd == "-roll_left") {
 430                 ++camera_roll;
 431                 return true;
 432         } else if(strCmd == "+roll_left" || strCmd == "-roll_right") {
 433                 --camera_roll;
 434                 return true;
 435         }
 436
 437         return false;
 438 }
 439
 440 .vector view_ofs;
 441 entity debug_shotorg;
 442 void ShotOrg_Draw()
 443 {
 444         self.origin = view_origin + view_forward * self.view_ofs_x + view_right * self.view_ofs_y + view_up * self.view_ofs_z;
 445         self.angles = view_angles;
 446         self.angles_x = -self.angles_x;
 447         if not(self.cnt)
 448                 self.drawmask = MASK_NORMAL;
 449         else
 450                 self.drawmask = 0;
 451 }
 452 void ShotOrg_Draw2D()
 453 {
 454         vector coord2d_topleft, coord2d_topright, coord2d;
 455         string s;
 456         vector fs;
 457
 458         s = vtos(self.view_ofs);
 459         s = substring(s, 1, strlen(s) - 2);
 460         if(tokenize_console(s) == 3)
 461                 s = strcat(argv(0), " ", argv(1), " ", argv(2));
 462
 463         coord2d_topleft = project_3d_to_2d(self.origin + view_up * 4 - view_right * 4);
 464         coord2d_topright = project_3d_to_2d(self.origin + view_up * 4 + view_right * 4);
 465
 466         fs = '1 1 0' * ((coord2d_topright_x - coord2d_topleft_x) / stringwidth(s, FALSE, '8 8 0'));
 467
 468         coord2d = coord2d_topleft;
 469         if(fs_x < 8)
 470         {
 471                 coord2d_x += (coord2d_topright_x - coord2d_topleft_x) * (1 - 8 / fs_x) * 0.5;
 472                 fs = '8 8 0';
 473         }
 474         coord2d_y -= fs_y;
 475         coord2d_z = 0;
 476         drawstring(coord2d, s, fs, '1 1 1', 1, 0);
 477 }
 478
 479 void ShotOrg_Spawn()
 480 {
 481         debug_shotorg = spawn();
 482         debug_shotorg.draw = ShotOrg_Draw;
 483         debug_shotorg.draw2d = ShotOrg_Draw2D;
 484         debug_shotorg.renderflags = RF_VIEWMODEL;
 485         debug_shotorg.effects = EF_FULLBRIGHT;
 486         precache_model("models/shotorg_adjuster.md3");
 487         setmodel(debug_shotorg, "models/shotorg_adjuster.md3");
 488         debug_shotorg.scale = 2;
 489         debug_shotorg.view_ofs = '25 8 -8';
 490 }
 491
 492 void DrawDebugModel()
 493 {
 494         if(time - floor(time) > 0.5)
 495         {
 496                 PolyDrawModel(self);
 497                 self.drawmask = 0;
 498         }
 499         else
 500         {
 501                 self.renderflags = 0;
 502                 self.drawmask = MASK_NORMAL;
 503         }
 504 }
 505
 506 void GameCommand(string msg)
 507 {
 508         string s;
 509         float argc;
 510         entity e;
 511         argc = tokenize_console(msg);
 512
 513         if(argv(0) == "help" || argc == 0)
 514         {
 515                 print("Usage: cl_cmd COMMAND..., where possible commands are:\n");
 516                 print("  settemp cvar value\n");
 517                 print("  scoreboard_columns_set ...\n");
 518                 print("  scoreboard_columns_help\n");
 519                 GameCommand_Generic("help");
 520                 return;
 521         }
 522
 523         if(GameCommand_Generic(msg))
 524                 return;
 525
 526         string cmd;
 527         cmd = argv(0);
 528         if(cmd == "mv_download") {
 529                 Cmd_MapVote_MapDownload(argc);
 530         }
 531         else if(cmd == "settemp") {
 532                 cvar_clientsettemp(argv(1), argv(2));
 533         }
 534         else if(cmd == "scoreboard_columns_set") {
 535                 Cmd_HUD_SetFields(argc);
 536         }
 537         else if(cmd == "scoreboard_columns_help") {
 538                 Cmd_HUD_Help(argc);
 539         }
 540 #ifdef BLURTEST
 541         else if(cmd == "blurtest") {
 542                 blurtest_time0 = time;
 543                 blurtest_time1 = time + stof(argv(1));
 544                 blurtest_radius = stof(argv(2));
 545                 blurtest_power = stof(argv(3));
 546         }
 547 #endif
 548         else if(cmd == "shotorg_move") {
 549                 if(!debug_shotorg)
 550                         ShotOrg_Spawn();
 551                 else
 552                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stov(argv(1));
 553                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 554         }
 555         else if(cmd == "shotorg_movez") {
 556                 if(!debug_shotorg)
 557                         ShotOrg_Spawn();
 558                 else
 559                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stof(argv(1)) * (debug_shotorg.view_ofs * (1 / debug_shotorg.view_ofs_x)); // closer/farther, same xy pos
 560                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 561         }
 562         else if(cmd == "shotorg_set") {
 563                 if(!debug_shotorg)
 564                         ShotOrg_Spawn();
 565                 else
 566                         debug_shotorg.view_ofs = stov(argv(1));
 567                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 568         }
 569         else if(cmd == "shotorg_setz") {
 570                 if(!debug_shotorg)
 571                         ShotOrg_Spawn();
 572                 else
 573                         debug_shotorg.view_ofs = debug_shotorg.view_ofs * (stof(argv(1)) / debug_shotorg.view_ofs_x); // closer/farther, same xy pos
 574                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 575         }
 576         else if(cmd == "shotorg_toggle_hide") {
 577                 if(debug_shotorg)
 578                 {
 579                         debug_shotorg.cnt = !debug_shotorg.cnt;
 580                 }
 581         }
 582         else if(cmd == "shotorg_end") {
 583                 if(debug_shotorg)
 584                 {
 585                         print(vtos(debug_shotorg.view_ofs), "\n");
 586                         remove(debug_shotorg);
 587                         debug_shotorg = world;
 588                 }
 589                 localcmd("sv_cmd debug_shotorg\n");
 590         }
 591         else if(cmd == "sendcvar") {
 592                 // W_FixWeaponOrder will trash argv, so save what we need.
 593                 string thiscvar;
 594                 thiscvar = strzone(argv(1));
 595                 s = cvar_string(thiscvar);
 596                 if(thiscvar == "cl_weaponpriority")
 597                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
 598                 else if(substring(thiscvar, 0, 17) == "cl_weaponpriority" && strlen(thiscvar) == 18)
 599                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
 600                 localcmd("cmd sentcvar ", thiscvar, " \"", s, "\"\n");
 601                 strunzone(thiscvar);
 602         }
 603         else if(cmd == "spawn") {
 604                 s = argv(1);
 605                 e = spawn();
 606                 precache_model(s);
 607                 setmodel(e, s);
 608                 setorigin(e, view_origin);
 609                 e.angles = view_angles;
 610                 e.draw = DrawDebugModel;
 611                 e.classname = "debugmodel";
 612         }
 613     else if(cmd == "vyes")
 614     {
 615         if(uid2name_dialog)
 616         {
 617             vote_active = 0; // force the panel to disappear right as we have selected the value (to prevent it from fading out in the normal vote panel pos)
 618             vote_prev = 0;
 619             cvar_set("cl_allow_uid2name", "1");
 620             vote_change = -9999;
 621                         uid2name_dialog = 0;
 622         }
 623         else
 624         {
 625             localcmd("cmd vote yes\n");
 626         }
 627     }
 628     else if(cmd == "vno")
 629     {
 630         if(uid2name_dialog)
 631         {
 632             vote_active = 0;
 633             vote_prev = 0;
 634             cvar_set("cl_allow_uid2name", "0");
 635             vote_change = -9999;
 636                         uid2name_dialog = 0;
 637         }
 638         else
 639         {
 640             localcmd("cmd vote no\n");
 641         }
 642     }
 643
 644         else
 645         {
 646                 print("Invalid command. For a list of supported commands, try cl_cmd help.\n");
 647         }
 648
 649         return;
 650 }
 651
 652 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 653 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 654 // All keys are in ascii.
 655 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.
 656 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 657 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 658 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 659 {
 660         local float bSkipKey;
 661         bSkipKey = false;
 662
 663         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 664                 return true;
 665
 666         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 667                 return true;
 668
 669         if(menu_visible)
 670                 if(menu_action(bInputType, nPrimary, nSecondary))
 671                         return TRUE;
 672
 673         return bSkipKey;
 674 }
 675
 676 // END REQUIRED CSQC FUNCTIONS
 677 // --------------------------------------------------------------------------
 678
 679 // --------------------------------------------------------------------------
 680 // BEGIN OPTIONAL CSQC FUNCTIONS
 681 void Ent_ReadEntCS()
 682 {
 683         InterpolateOrigin_Undo();
 684
 685         self.classname = "entcs_receiver";
 686         self.sv_entnum = ReadByte() - 1;
 687         self.origin_x = ReadShort();
 688         self.origin_y = ReadShort();
 689         self.origin_z = ReadShort();
 690         self.angles_y = ReadByte() * 360.0 / 256;
 691         self.origin_z = self.angles_x = self.angles_z = 0;
 692
 693         InterpolateOrigin_Note();
 694 }
 695
 696 void Ent_Remove();
 697
 698 void Ent_RemovePlayerScore()
 699 {
 700         float i;
 701
 702         if(self.owner)
 703         {
 704                 SetTeam(self.owner, -1);
 705                 self.owner.gotscores = 0;
 706                 for(i = 0; i < MAX_SCORE; ++i)
 707                         self.owner.(scores[i]) = 0; // clear all scores
 708         }
 709 }
 710
 711 void Ent_ReadPlayerScore()
 712 {
 713         float i, n;
 714         float isNew;
 715         entity o;
 716
 717         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 718         // (no I've never heard of M-x replace-string, sed, or anything like that)
 719         isNew = !self.owner; // workaround for DP bug
 720         n = ReadByte()-1;
 721
 722 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 723         if(!isNew && n != self.sv_entnum)
 724         {
 725                 print("A CSQC entity changed its owner!\n");
 726                 isNew = true;
 727                 Ent_Remove();
 728                 self.enttype = ENT_CLIENT_SCORES;
 729         }
 730 #endif
 731
 732         self.sv_entnum = n;
 733
 734         if not(playerslots[self.sv_entnum])
 735                 playerslots[self.sv_entnum] = spawn();
 736         o = self.owner = playerslots[self.sv_entnum];
 737         o.sv_entnum = self.sv_entnum;
 738         o.gotscores = 1;
 739
 740         //if not(o.sort_prev)
 741         //      RegisterPlayer(o);
 742         //playerchecker will do this for us later, if it has not already done so
 743
 744         float sf, lf;
 745 #if MAX_SCORE <= 8
 746         sf = ReadByte();
 747         lf = ReadByte();
 748 #else
 749         sf = ReadShort();
 750         lf = ReadShort();
 751 #endif
 752         float p;
 753         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 754                 if(sf & p)
 755                 {
 756                         if(lf & p)
 757                                 o.(scores[i]) = ReadInt24_t();
 758                         else
 759                                 o.(scores[i]) = ReadChar();
 760                 }
 761
 762         if(o.sort_prev)
 763                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 764
 765         self.entremove = Ent_RemovePlayerScore;
 766 }
 767
 768 void Ent_ReadTeamScore()
 769 {
 770         float i;
 771         entity o;
 772
 773         self.team = ReadByte();
 774         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 775
 776         float sf, lf;
 777 #if MAX_TEAMSCORE <= 8
 778         sf = ReadByte();
 779         lf = ReadByte();
 780 #else
 781         sf = ReadShort();
 782         lf = ReadShort();
 783 #endif
 784         float p;
 785         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 786                 if(sf & p)
 787                 {
 788                         if(lf & p)
 789                                 o.(teamscores[i]) = ReadInt24_t();
 790                         else
 791                                 o.(teamscores[i]) = ReadChar();
 792                 }
 793
 794         HUD_UpdateTeamPos(o);
 795 }
 796
 797 void Net_Reset()
 798 {
 799 }
 800
 801 void Ent_ClientData()
 802 {
 803         float f;
 804         float newspectatee_status;
 805
 806         f = ReadByte();
 807
 808         scoreboard_showscores_force = (f & 1);
 809
 810         if(f & 2)
 811         {
 812                 newspectatee_status = ReadByte();
 813                 if(newspectatee_status == player_localentnum)
 814                         newspectatee_status = -1; // observing
 815         }
 816         else
 817                 newspectatee_status = 0;
 818
 819         spectatorbutton_zoom = (f & 4);
 820
 821         if(f & 8)
 822         {
 823                 angles_held_status = 1;
 824                 angles_held_x = ReadAngle();
 825                 angles_held_y = ReadAngle();
 826                 angles_held_z = 0;
 827         }
 828         else
 829                 angles_held_status = 0;
 830
 831         if(newspectatee_status != spectatee_status)
 832         {
 833                 float i;
 834
 835                 // clear race stuff
 836                 race_laptime = 0;
 837                 race_checkpointtime = 0;
 838         }
 839         spectatee_status = newspectatee_status;
 840 }
 841
 842 void Ent_Nagger()
 843 {
 844         float nags, i, j, b, f;
 845
 846         nags = ReadByte();
 847
 848         if(nags & 128)
 849         {
 850                 if(vote_called_vote)
 851                         strunzone(vote_called_vote);
 852                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 853         }
 854
 855         if(nags & 1)
 856         {
 857                 for(j = 0; j < maxclients; ++j)
 858                         if(playerslots[j])
 859                                 playerslots[j].ready = 1;
 860                 for(i = 1; i <= maxclients; i += 8)
 861                 {
 862                         f = ReadByte();
 863                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 864                                 if not(f & b)
 865                                         if(playerslots[j])
 866                                                 playerslots[j].ready = 0;
 867                 }
 868         }
 869
 870         ready_waiting = (nags & 1);
 871         ready_waiting_for_me = (nags & 2);
 872         vote_waiting = (nags & 4);
 873         vote_waiting_for_me = (nags & 8);
 874         warmup_stage = (nags & 16);
 875 }
 876
 877 void Ent_RandomSeed()
 878 {
 879         float s;
 880         prandom_debug();
 881         s = ReadShort();
 882         psrandom(s);
 883 }
 884
 885 void Ent_ReadAccuracy(void)
 886 {
 887         float sf, f, w, b;
 888         sf = ReadInt24_t();
 889         if(sf == 0)
 890         {
 891                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 892                         weapon_accuracy[w] = -1;
 893                 return;
 894         }
 895
 896         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w, f *= 2)
 897         {
 898                 if(sf & f)
 899                 {
 900                         b = ReadByte();
 901                         if(b == 0)
 902                                 weapon_accuracy[w] = -1;
 903                         else if(b == 255)
 904                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 905                         else
 906                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 907                 }
 908         }
 909 }
 910
 911 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 912 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 913 void Ent_RadarLink();
 914 void Ent_Init();
 915 void Ent_ScoresInfo();
 916 void(float bIsNewEntity) CSQC_Ent_Update =
 917 {
 918         float t;
 919         float savetime;
 920         t = ReadByte();
 921
 922         // set up the "time" global for received entities to be correct for interpolation purposes
 923         savetime = time;
 924         if(servertime)
 925         {
 926                 time = servertime;
 927         }
 928         else
 929         {
 930                 serverprevtime = time;
 931                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 932                 time = serverprevtime + serverdeltatime;
 933         }
 934
 935 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 936         if(self.enttype)
 937                 if(t != self.enttype)
 938                 {
 939                         print("A CSQC entity changed its type!\n");
 940                         Ent_Remove();
 941                         bIsNewEntity = 1;
 942                 }
 943 #endif
 944         self.enttype = t;
 945         switch(t)
 946         {
 947                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 948                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 949                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 950                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 951                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 952                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 953                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 954                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 955                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 956                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 957                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 958                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 959                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 960                 case ENT_CLIENT_INIT: Ent_Init(); break;
 961                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 962                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 963                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 964                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 965                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 966                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 967                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 968                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 969                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 970                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 971                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 972                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
 973                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
 974                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 975                 default:
 976                         error(strcat("unknown entity type in CSQC_Ent_Update: ", ftos(self.enttype), "\n"));
 977                         break;
 978         }
 979
 980         time = savetime;
 981 };
 982 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 983 // used when an entity changes its type. For an entity that someone interacts
 984 // with others, make sure it can no longer do so.
 985 void Ent_Remove()
 986 {
 987         if(self.entremove)
 988                 self.entremove();
 989
 990         self.enttype = 0;
 991         self.classname = "";
 992         self.draw = menu_sub_null;
 993         self.entremove = menu_sub_null;
 994         // TODO possibly set more stuff to defaults
 995 }
 996 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 997 void CSQC_Ent_Remove()
 998 {
 999         if(self.enttype)
1000                 Ent_Remove();
1001         remove(self);
1002 }
1003
1004 void Gamemode_Init()
1005 {
1006         if not(isdemo())
1007         {
1008                 localcmd("\n_cl_hook_gamestart ", GametypeNameFromType(gametype), "\n");
1009                 calledhooks |= HOOK_START;
1010         }
1011 }
1012 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
1013 void CSQC_Parse_StuffCmd(string strMessage)
1014 {
1015         localcmd(strMessage);
1016 }
1017 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
1018 void CSQC_Parse_Print(string strMessage)
1019 {
1020         print(ColorTranslateRGB(strMessage));
1021 }
1022
1023 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.
1024 void CSQC_Parse_CenterPrint(string strMessage)
1025 {
1026         centerprint(strMessage);
1027 }
1028
1029 string notranslate_fogcmd1 = "\nfog ";
1030 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
1031 void Fog_Force()
1032 {
1033         // TODO somehow thwart prvm_globalset client ...
1034
1035         if(forcefog != "")
1036                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
1037 }
1038
1039 void Gamemode_Init();
1040 void Ent_ScoresInfo()
1041 {
1042         float i;
1043         self.classname = "ent_client_scores_info";
1044         gametype = ReadByte();
1045         for(i = 0; i < MAX_SCORE; ++i)
1046         {
1047                 scores_label[i] = strzone(ReadString());
1048                 scores_flags[i] = ReadByte();
1049         }
1050         for(i = 0; i < MAX_TEAMSCORE; ++i)
1051         {
1052                 teamscores_label[i] = strzone(ReadString());
1053                 teamscores_flags[i] = ReadByte();
1054         }
1055         HUD_InitScores();
1056         Gamemode_Init();
1057 }
1058
1059 void Ent_Init()
1060 {
1061         self.classname = "ent_client_init";
1062
1063         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1064
1065         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1066         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1067         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1068         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1069         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1070         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1071         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1072         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1073         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1074         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1075         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1076         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1077
1078         if(forcefog)
1079                 strunzone(forcefog);
1080         forcefog = strzone(ReadString());
1081
1082         armorblockpercent = ReadByte() / 255.0;
1083
1084         g_weaponswitchdelay = ReadByte() / 255.0;
1085
1086         g_balance_grenadelauncher_bouncefactor = ReadCoord();
1087         g_balance_grenadelauncher_bouncestop = ReadCoord();
1088         g_balance_electro_secondary_bouncefactor = ReadCoord();
1089         g_balance_electro_secondary_bouncestop = ReadCoord();
1090
1091         nex_scope = !ReadByte();
1092         campingrifle_scope = !ReadByte();
1093
1094         serverflags = ReadByte();
1095
1096         if(!postinit)
1097                 PostInit();
1098 }
1099
1100 void Net_ReadRace()
1101 {
1102         float b;
1103
1104         b = ReadByte();
1105
1106         switch(b)
1107         {
1108                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1109                         race_checkpoint = ReadByte();
1110                         race_time = ReadInt24_t();
1111                         race_previousbesttime = ReadInt24_t();
1112                         if(race_previousbestname)
1113                                 strunzone(race_previousbestname);
1114                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1115
1116                         race_checkpointtime = time;
1117
1118                         if(race_checkpoint == 0 || race_checkpoint == 254)
1119                         {
1120                                 race_penaltyaccumulator = 0;
1121                                 race_laptime = time; // valid
1122                         }
1123
1124                         break;
1125
1126                 case RACE_NET_CHECKPOINT_CLEAR:
1127                         race_laptime = 0;
1128                         race_checkpointtime = 0;
1129                         break;
1130
1131                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1132                         race_laptime = ReadCoord();
1133                         race_checkpointtime = -99999;
1134                         // fall through
1135                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1136                         race_nextcheckpoint = ReadByte();
1137
1138                         race_nextbesttime = ReadInt24_t();
1139                         if(race_nextbestname)
1140                                 strunzone(race_nextbestname);
1141                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1142                         break;
1143
1144                 case RACE_NET_CHECKPOINT_HIT_RACE:
1145                         race_mycheckpoint = ReadByte();
1146                         race_mycheckpointtime = time;
1147                         race_mycheckpointdelta = ReadInt24_t();
1148                         race_mycheckpointlapsdelta = ReadByte();
1149                         if(race_mycheckpointlapsdelta >= 128)
1150                                 race_mycheckpointlapsdelta -= 256;
1151                         if(race_mycheckpointenemy)
1152                                 strunzone(race_mycheckpointenemy);
1153                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1154                         break;
1155
1156                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1157                         race_othercheckpoint = ReadByte();
1158                         race_othercheckpointtime = time;
1159                         race_othercheckpointdelta = ReadInt24_t();
1160                         race_othercheckpointlapsdelta = ReadByte();
1161                         if(race_othercheckpointlapsdelta >= 128)
1162                                 race_othercheckpointlapsdelta -= 256;
1163                         if(race_othercheckpointenemy)
1164                                 strunzone(race_othercheckpointenemy);
1165                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1166                         break;
1167
1168                 case RACE_NET_PENALTY_RACE:
1169                         race_penaltyeventtime = time;
1170                         race_penaltytime = ReadShort();
1171                         //race_penaltyaccumulator += race_penaltytime;
1172                         if(race_penaltyreason)
1173                                 strunzone(race_penaltyreason);
1174                         race_penaltyreason = strzone(ReadString());
1175                         break;
1176
1177                 case RACE_NET_PENALTY_QUALIFYING:
1178                         race_penaltyeventtime = time;
1179                         race_penaltytime = ReadShort();
1180                         race_penaltyaccumulator += race_penaltytime;
1181                         if(race_penaltyreason)
1182                                 strunzone(race_penaltyreason);
1183                         race_penaltyreason = strzone(ReadString());
1184                         break;
1185
1186                 case RACE_NET_SERVER_RECORD:
1187                         race_server_record = ReadInt24_t();
1188                         break;
1189                 case RACE_NET_SPEED_AWARD:
1190                         race_speedaward = ReadInt24_t();
1191                         if(race_speedaward_holder)
1192                                 strunzone(race_speedaward_holder);
1193                         race_speedaward_holder = strzone(ReadString());
1194                         break;
1195                 case RACE_NET_SPEED_AWARD_BEST:
1196                         race_speedaward_alltimebest = ReadInt24_t();
1197                         if(race_speedaward_alltimebest_holder)
1198                                 strunzone(race_speedaward_alltimebest_holder);
1199                         race_speedaward_alltimebest_holder = strzone(ReadString());
1200                         break;
1201                 case RACE_NET_SERVER_RANKINGS:
1202                         float pos, prevpos, del;
1203                         pos = ReadShort();
1204                         prevpos = ReadShort();
1205                         del = ReadShort();
1206
1207                         // move other rankings out of the way
1208                         float i;
1209                         if (prevpos) {
1210                                 for (i=prevpos-1;i>pos-1;--i) {
1211                                         grecordtime[i] = grecordtime[i-1];
1212                                         if(grecordholder[i])
1213                                                 strunzone(grecordholder[i]);
1214                                         grecordholder[i] = strzone(grecordholder[i-1]);
1215                                 }
1216                         } else if (del) { // a record has been deleted by the admin
1217                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1218                                         if (i == RANKINGS_CNT-1) { // clear out last record
1219                                                 grecordtime[i] = 0;
1220                                                 if (grecordholder[i])
1221                                                         strunzone(grecordholder[i]);
1222                                                 grecordholder[i] = string_null;
1223                                         }
1224                                         else {
1225                                                 grecordtime[i] = grecordtime[i+1];
1226                                                 if (grecordholder[i])
1227                                                         strunzone(grecordholder[i]);
1228                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1229                                         }
1230                                 }
1231                         } else { // player has no ranked record yet
1232                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1233                                         grecordtime[i] = grecordtime[i-1];
1234                                         if(grecordholder[i])
1235                                                 strunzone(grecordholder[i]);
1236                                         grecordholder[i] = strzone(grecordholder[i-1]);
1237                                 }
1238                         }
1239
1240                         // store new ranking
1241                         if(grecordholder[pos-1] != "")
1242                                 strunzone(grecordholder[pos-1]);
1243                         grecordholder[pos-1] = strzone(ReadString());
1244                         grecordtime[pos-1] = ReadInt24_t();
1245                         if(grecordholder[pos-1] == GetPlayerName(player_localentnum -1))
1246                                 race_myrank = pos;
1247                         break;
1248                 case RACE_NET_SERVER_STATUS:
1249                         race_status = ReadShort();
1250                         if(race_status_name)
1251                                 strunzone(race_status_name);
1252                         race_status_name = strzone(ReadString());
1253         }
1254 }
1255
1256 void Net_ReadDom()
1257 {
1258         if (dom_total_pps == 0)
1259                 dom_total_pps = ReadShort() / 100.0;
1260         dom_pps_red = ReadShort() / 100.0;
1261         dom_pps_blue = ReadShort() / 100.0;
1262         //if dom_pps_yellow/dom_pps_pink was negative the first time we read it,
1263         //it means the relative team doesn't exist and we don't have to read its value anymore
1264         if (dom_pps_yellow >= 0)
1265                 dom_pps_yellow = ReadShort() / 100.0;
1266         if (dom_pps_pink >= 0)
1267                 dom_pps_pink = ReadShort() / 100.0;
1268 }
1269
1270 void Net_ReadSpawn()
1271 {
1272         zoomin_effect = 1;
1273         current_viewzoom = 0.6;
1274 }
1275
1276 void Net_TeamNagger()
1277 {
1278         teamnagger = 1;
1279 }
1280
1281 void Net_ReadPingPLReport()
1282 {
1283         float e, pi, pl, ml;
1284         e = ReadByte();
1285         pi = ReadShort();
1286         pl = ReadByte();
1287         ml = ReadByte();
1288         if not(playerslots[e])
1289                 return;
1290         playerslots[e].ping = pi;
1291         playerslots[e].ping_packetloss = pl / 255.0;
1292         playerslots[e].ping_movementloss = ml / 255.0;
1293 }
1294
1295 void Net_VoteDialog(float highlight) {
1296         if(highlight) {
1297                 vote_highlighted = ReadByte();
1298                 return;
1299         }
1300
1301         vote_yescount = ReadByte();
1302         vote_nocount = ReadByte();
1303         vote_needed = ReadByte();
1304         vote_active = 1;
1305 }
1306
1307 void Net_VoteDialogReset() {
1308         vote_active = 0;
1309 }
1310
1311 void Net_Notify() {
1312         float type;
1313         type = ReadByte();
1314
1315         if(type == CSQC_KILLNOTIFY)
1316         {
1317                 HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1318         }
1319         else if(type == CSQC_CENTERPRINT)
1320         {
1321                 HUD_Centerprint(ReadString(), ReadString(), ReadShort(), ReadByte());
1322         }
1323 }
1324
1325 void Net_WeaponComplain() {
1326         complain_weapon = ReadByte();
1327
1328         if(complain_weapon_name)
1329                 strunzone(complain_weapon_name);
1330         complain_weapon_name = strzone(ReadString());
1331
1332         complain_weapon_type = ReadByte();
1333
1334         complain_weapon_time = time;
1335         weapontime = time; // ping the weapon panel
1336 }
1337
1338 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1339 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1340 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1341 float CSQC_Parse_TempEntity()
1342 {
1343         local float bHandled;
1344                 bHandled  = true;
1345         // Acquire TE ID
1346         local float nTEID;
1347                 nTEID = ReadByte();
1348
1349                 // NOTE: Could just do return instead of break...
1350         switch(nTEID)
1351         {
1352                 case TE_CSQC_TARGET_MUSIC:
1353                         Net_TargetMusic();
1354                         bHandled = true;
1355                         break;
1356                 case TE_CSQC_PICTURE:
1357                         Net_MapVote_Picture();
1358                         bHandled = true;
1359                         break;
1360                 case TE_CSQC_RACE:
1361                         Net_ReadRace();
1362                         bHandled = true;
1363                         break;
1364                 case TE_CSQC_DOM:
1365                         Net_ReadDom();
1366                         bHandled = true;
1367                         break;
1368                 case TE_CSQC_SPAWN:
1369                         Net_ReadSpawn();
1370                         bHandled = true;
1371                         break;
1372                 case TE_CSQC_ZCURVEPARTICLES:
1373                         Net_ReadZCurveParticles();
1374                         bHandled = true;
1375                         break;
1376                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1377                         Net_ReadNexgunBeamParticle();
1378                         bHandled = true;
1379                         break;
1380                 case TE_CSQC_TEAMNAGGER:
1381                         Net_TeamNagger();
1382                         bHandled = true;
1383                         break;
1384                 case TE_CSQC_VOTE:
1385                         Net_VoteDialog(ReadByte());
1386                         bHandled = true;
1387                         break;
1388                 case TE_CSQC_VOTERESET:
1389                         Net_VoteDialogReset();
1390                         bHandled = true;
1391                         break;
1392                 case TE_CSQC_LIGHTNINGARC:
1393                         Net_ReadLightningarc();
1394                         bHandled = true;
1395                         break;
1396                 case TE_CSQC_PINGPLREPORT:
1397                         Net_ReadPingPLReport();
1398                         bHandled = true;
1399                         break;
1400                 case TE_CSQC_ANNOUNCE:
1401                         announce_snd = strzone(ReadString());
1402                         bHandled = true;
1403                         break;
1404                 case TE_CSQC_NOTIFY:
1405                         Net_Notify();
1406                         bHandled = true;
1407                         break;
1408                 case TE_CSQC_WEAPONCOMPLAIN:
1409                         Net_WeaponComplain();
1410                         bHandled = true;
1411                         break;
1412                 case TE_CSQC_CR_MAXBULLETS:
1413                         cr_maxbullets = ReadByte();
1414                         bHandled = true;
1415                         break;
1416                 default:
1417                         // No special logic for this temporary entity; return 0 so the engine can handle it
1418                         bHandled = false;
1419                         break;
1420         }
1421
1422         return bHandled;
1423 }
1424
1425 string getcommandkey(string text, string command)
1426 {
1427         string keys;
1428         float n, j, k, l;
1429
1430         if (!hud_showbinds)
1431                 return text;
1432
1433         keys = db_get(binddb, command);
1434         if (!keys)
1435         {
1436                 n = tokenize(findkeysforcommand(command)); // uses '...' strings
1437                 for(j = 0; j < n; ++j)
1438                 {
1439                         k = stof(argv(j));
1440                         if(k != -1)
1441                         {
1442                                 if ("" == keys)
1443                                         keys = keynumtostring(k);
1444                                 else
1445                                         keys = strcat(keys, ", ", keynumtostring(k));
1446
1447                                 ++l;
1448                                 if (hud_showbinds_limit > 0 && hud_showbinds_limit >= l) break;
1449                         }
1450
1451                 }
1452                 db_put(binddb, command, keys);
1453         }
1454
1455         if ("" == keys) {
1456                 if (hud_showbinds > 1)
1457                         return strcat(text, " (not bound)");
1458                 else
1459                         return text;
1460         }
1461         else if (hud_showbinds > 1)
1462                 return strcat(text, " (", keys, ")");
1463         else
1464                 return keys;
1465 }