qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
   6
   7 void cvar_clientsettemp(string cv, string val)
   8 {
   9         entity e;
  10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  11                 if(e.netname == cv)
  12                         goto saved;
  13         e = spawn();
  14         e.classname = "saved_cvar_value";
  15         e.netname = strzone(cv);
  16         e.message = strzone(cvar_string(cv));
  17 :saved
  18         cvar_set(cv, val);
  19 }
  20
  21 void cvar_clientsettemp_restore()
  22 {
  23         entity e;
  24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  25                         cvar_set(e.netname, e.message);
  26 }
  27
  28 void() menu_show_error =
  29 {
  30         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  31 };
  32
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  34 // Useful for precaching things
  35
  36 void() menu_sub_null =
  37 {
  38 };
  39
  40 #ifdef USE_FTE
  41 float __engine_check;
  42 #endif
  43
  44 string forcefog;
  45 string cl_announcer_prev;
  46 void WaypointSprite_Load();
  47 void CSQC_Init(void)
  48 {
  49         prvm_language = cvar_string("prvm_language");
  50
  51 #ifdef USE_FTE
  52 #pragma target ID
  53         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  54         if(!__engine_check)
  55         {
  56                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
  57                 localcmd("\ndisconnect\n");
  58                 return;
  59         }
  60 #pragma target FTE
  61 #endif
  62
  63         check_unacceptable_compiler_bugs();
  64
  65 #ifdef WATERMARK
  66         print(sprintf(_("^4CSQC Build information: %s\n"), WATERMARK()));
  67 #endif
  68
  69         float i;
  70
  71         binddb = db_create();
  72         tempdb = db_create();
  73         ClientProgsDB = db_load("client.db");
  74         compressShortVector_init();
  75
  76         drawfont = FONT_USER+1;
  77         menu_visible = FALSE;
  78         menu_show = menu_show_error;
  79         menu_action = menu_sub_null;
  80
  81         for(i = 0; i < 255; ++i)
  82                 if(getplayerkey(i, "viewentity") == "")
  83                         break;
  84         maxclients = i;
  85
  86         //ctf_temp_1 = "";
  87         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used
  88         //registercmd("ctf_menu");
  89         registercmd("ons_map");
  90         registercmd("hud_configure");
  91         registercmd("hud_save");
  92         //registercmd("menu_action");
  93
  94         registercmd("+button3");
  95         registercmd("-button3");
  96         registercmd("+button4");
  97         registercmd("-button4");
  98         registercmd("+showscores");registercmd("-showscores");
  99         registercmd("+showaccuracy");registercmd("-showaccuracy");
 100
 101 #ifndef CAMERATEST
 102         if(isdemo())
 103         {
 104 #endif
 105                 registercmd("+forward");registercmd("-forward");
 106                 registercmd("+back");registercmd("-back");
 107                 registercmd("+moveup");registercmd("-moveup");
 108                 registercmd("+movedown");registercmd("-movedown");
 109                 registercmd("+moveright");registercmd("-moveright");
 110                 registercmd("+moveleft");registercmd("-moveleft");
 111                 registercmd("+roll_right");registercmd("-roll_right");
 112                 registercmd("+roll_left");registercmd("-roll_left");
 113 #ifndef CAMERATEST
 114         }
 115 #endif
 116         registercvar("hud_usecsqc", "1");
 117         registercvar("scoreboard_columns", "default", CVAR_SAVE);
 118
 119         gametype = 0;
 120
 121         // hud_fields uses strunzone on the titles!
 122         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 123                 hud_title[i] = strzone("(null)");
 124
 125         postinit = false;
 126
 127         calledhooks = 0;
 128
 129         teams = Sort_Spawn();
 130         players = Sort_Spawn();
 131
 132         GetTeam(COLOR_SPECTATOR, true); // add specs first
 133
 134         RegisterWeapons();
 135
 136         WaypointSprite_Load();
 137
 138         // precaches
 139         precache_sound("misc/hit.wav");
 140         precache_sound("misc/typehit.wav");
 141         Projectile_Precache();
 142         Hook_Precache();
 143         GibSplash_Precache();
 144         Casings_Precache();
 145         DamageInfo_Precache();
 146         if(autocvar_cl_announcer != cl_announcer_prev) {
 147                 Announcer_Precache();
 148                 if(cl_announcer_prev)
 149                         strunzone(cl_announcer_prev);
 150                 cl_announcer_prev = strzone(autocvar_cl_announcer);
 151         }
 152         Tuba_Precache();
 153
 154         if(autocvar_cl_reticle_item_normal) precache_pic("gfx/reticle_normal");
 155         if(autocvar_cl_reticle_item_nex) precache_pic("gfx/reticle_nex");
 156
 157         get_mi_min_max_texcoords(1); // try the CLEVER way first
 158         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 159         shortmapname = mi_shortname;
 160
 161         if(precache_pic(minimapname) == "")
 162         {
 163                 // but maybe we have a non-clever minimap
 164                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 165                 if(precache_pic(minimapname) == "")
 166                         minimapname = ""; // FAIL
 167                 else
 168                         get_mi_min_max_texcoords(0); // load new texcoords
 169         }
 170
 171         mi_center = (mi_min + mi_max) * 0.5;
 172         mi_scale = mi_max - mi_min;
 173         minimapname = strzone(minimapname);
 174
 175         WarpZone_Init();
 176
 177         hud_configure_prev = -1;
 178         tab_panel = -1;
 179 }
 180
 181 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 182 void CSQC_Shutdown(void)
 183 {
 184 #ifdef USE_FTE
 185 #pragma TARGET id
 186         if(!__engine_check)
 187                 return 0;
 188 #pragma TARGET fte
 189 #endif
 190
 191         WarpZone_Shutdown();
 192
 193         remove(teams);
 194         remove(players);
 195         db_close(binddb);
 196         db_close(tempdb);
 197         if(autocvar_cl_db_saveasdump)
 198                 db_dump(ClientProgsDB, "client.db");
 199         else
 200                 db_save(ClientProgsDB, "client.db");
 201         db_close(ClientProgsDB);
 202
 203         cvar_clientsettemp_restore();
 204
 205         if(camera_active)
 206                 cvar_set("chase_active",ftos(chase_active_backup));
 207
 208         if not(isdemo())
 209         {
 210                 if not(calledhooks & HOOK_START)
 211                         localcmd("\n_cl_hook_gamestart nop\n");
 212                 if not(calledhooks & HOOK_END)
 213                         localcmd("\ncl_hook_gameend\n");
 214         }
 215 }
 216
 217 .float has_team;
 218 float SetTeam(entity o, float Team)
 219 {
 220         entity tm;
 221         if(teamplay)
 222         {
 223                 switch(Team)
 224                 {
 225                         case -1:
 226                         case COLOR_TEAM1:
 227                         case COLOR_TEAM2:
 228                         case COLOR_TEAM3:
 229                         case COLOR_TEAM4:
 230                                 break;
 231                         default:
 232                                 if(GetTeam(Team, false) == NULL)
 233                                 {
 234                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 235                                         Team = COLOR_SPECTATOR;
 236                                 }
 237                                 break;
 238                 }
 239         }
 240         else
 241         {
 242                 switch(Team)
 243                 {
 244                         case -1:
 245                         case 0:
 246                                 break;
 247                         default:
 248                                 if(GetTeam(Team, false) == NULL)
 249                                 {
 250                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 251                                         Team = COLOR_SPECTATOR;
 252                                 }
 253                                 break;
 254                 }
 255         }
 256         if(Team == -1) // leave
 257         {
 258                 if(o.has_team)
 259                 {
 260                         tm = GetTeam(o.team, false);
 261                         tm.team_size -= 1;
 262                         o.has_team = 0;
 263                         return TRUE;
 264                 }
 265         }
 266         else
 267         {
 268                 if not(o.has_team)
 269                 {
 270                         o.team = Team;
 271                         tm = GetTeam(Team, true);
 272                         tm.team_size += 1;
 273                         o.has_team = 1;
 274                         return TRUE;
 275                 }
 276                 else if(Team != o.team)
 277                 {
 278                         tm = GetTeam(o.team, false);
 279                         tm.team_size -= 1;
 280                         o.team = Team;
 281                         tm = GetTeam(Team, true);
 282                         tm.team_size += 1;
 283                         return TRUE;
 284                 }
 285         }
 286         return FALSE;
 287 }
 288
 289 void Playerchecker_Think()
 290 {
 291         float i;
 292         entity e;
 293         for(i = 0; i < maxclients; ++i)
 294         {
 295                 e = playerslots[i];
 296                 if(GetPlayerName(i) == "")
 297                 {
 298                         if(e.sort_prev)
 299                         {
 300                                 // player disconnected
 301                                 SetTeam(e, -1);
 302                                 RemovePlayer(e);
 303                                 e.sort_prev = world;
 304                                 //e.gotscores = 0;
 305                         }
 306                 }
 307                 else
 308                 {
 309                         if not(e.sort_prev)
 310                         {
 311                                 // player connected
 312                                 if not(e)
 313                                         playerslots[i] = e = spawn();
 314                                 e.sv_entnum = i;
 315                                 e.ping = 0;
 316                                 e.ping_packetloss = 0;
 317                                 e.ping_movementloss = 0;
 318                                 //e.gotscores = 0; // we might already have the scores...
 319                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 320                                 RegisterPlayer(e);
 321                                 HUD_UpdatePlayerPos(e);
 322                         }
 323                 }
 324         }
 325         self.nextthink = time + 0.2;
 326 }
 327
 328 void Porto_Init();
 329 void TrueAim_Init();
 330 void PostInit(void)
 331 {
 332         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
 333
 334         entity playerchecker;
 335         playerchecker = spawn();
 336         playerchecker.think = Playerchecker_Think;
 337         playerchecker.nextthink = time + 0.2;
 338
 339         Porto_Init();
 340         TrueAim_Init();
 341
 342         postinit = true;
 343 }
 344
 345 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function
 346 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.
 347 float button_zoom;
 348 void Cmd_HUD_SetFields(float);
 349 void Cmd_HUD_Help(float);
 350 float CSQC_ConsoleCommand(string strMessage)
 351 {
 352         float argc;
 353         // Tokenize String
 354         //argc = tokenize(strMessage);
 355         argc = tokenize_console(strMessage);
 356
 357         // Acquire Command
 358         local string strCmd;
 359         strCmd = argv(0);
 360
 361         if(strCmd == "hud_configure") { // config hud
 362                 cvar_set("_hud_configure", ftos(!autocvar__hud_configure));
 363                 return true;
 364         } else if(strCmd == "hud_save") { // save hud config
 365                 if(argv(1) == "" || argv(2)) {
 366                         print(_("Usage:\n"));
 367                         print(_("hud_save configname   (saves to hud_skinname_configname.cfg)\n"));
 368                 }
 369                 else
 370                         HUD_Panel_ExportCfg(argv(1));
 371                 return true;
 372         } else if(strCmd == "+button4") { // zoom
 373                 // return false, because the message shall be sent to the server anyway (for demos/speccing)
 374                 if(ignore_plus_zoom)
 375                 {
 376                         --ignore_plus_zoom;
 377                         return false;
 378                 }
 379                 button_zoom = 1;
 380                 return true;
 381         } else if(strCmd == "-button4") { // zoom
 382                 if(ignore_minus_zoom)
 383                 {
 384                         --ignore_minus_zoom;
 385                         return false;
 386                 }
 387                 button_zoom = 0;
 388                 return true;
 389         } else if(strCmd == "+button3") { // secondary
 390                 button_attack2 = 1;
 391                 return false;
 392         } else if(strCmd == "-button3") { // secondary
 393                 button_attack2 = 0;
 394                 return false;
 395         } else if(strCmd == "+showscores") {
 396                 scoreboard_showscores = true;
 397                 return true;
 398         } else if(strCmd == "-showscores") {
 399                 scoreboard_showscores = false;
 400                 return true;
 401         } else if(strCmd == "+showaccuracy") {
 402                 scoreboard_showaccuracy = true;
 403                 return true;
 404         } else if(strCmd == "-showaccuracy") {
 405                 scoreboard_showaccuracy = false;
 406                 return true;
 407         }
 408
 409         if(camera_active)
 410         if(strCmd == "+forward" || strCmd == "-back") {
 411                 ++camera_direction_x;
 412                 return true;
 413         } else if(strCmd == "-forward" || strCmd == "+back") {
 414                 --camera_direction_x;
 415                 return true;
 416         } else if(strCmd == "+moveright" || strCmd == "-moveleft") {
 417                 --camera_direction_y;
 418                 return true;
 419         } else if(strCmd == "-moveright" || strCmd == "+moveleft") {
 420                 ++camera_direction_y;
 421                 return true;
 422         } else if(strCmd == "+moveup" || strCmd == "-movedown") {
 423                 ++camera_direction_z;
 424                 return true;
 425         } else if(strCmd == "-moveup" || strCmd == "+movedown") {
 426                 --camera_direction_z;
 427                 return true;
 428         } else if(strCmd == "+roll_right" || strCmd == "-roll_left") {
 429                 ++camera_roll;
 430                 return true;
 431         } else if(strCmd == "+roll_left" || strCmd == "-roll_right") {
 432                 --camera_roll;
 433                 return true;
 434         }
 435
 436         return false;
 437 }
 438
 439 .vector view_ofs;
 440 entity debug_shotorg;
 441 void ShotOrg_Draw()
 442 {
 443         self.origin = view_origin + view_forward * self.view_ofs_x + view_right * self.view_ofs_y + view_up * self.view_ofs_z;
 444         self.angles = view_angles;
 445         self.angles_x = -self.angles_x;
 446         if not(self.cnt)
 447                 self.drawmask = MASK_NORMAL;
 448         else
 449                 self.drawmask = 0;
 450 }
 451 void ShotOrg_Draw2D()
 452 {
 453         vector coord2d_topleft, coord2d_topright, coord2d;
 454         string s;
 455         vector fs;
 456
 457         s = vtos(self.view_ofs);
 458         s = substring(s, 1, strlen(s) - 2);
 459         if(tokenize_console(s) == 3)
 460                 s = strcat(argv(0), " ", argv(1), " ", argv(2));
 461
 462         coord2d_topleft = project_3d_to_2d(self.origin + view_up * 4 - view_right * 4);
 463         coord2d_topright = project_3d_to_2d(self.origin + view_up * 4 + view_right * 4);
 464
 465         fs = '1 1 0' * ((coord2d_topright_x - coord2d_topleft_x) / stringwidth(s, FALSE, '8 8 0'));
 466
 467         coord2d = coord2d_topleft;
 468         if(fs_x < 8)
 469         {
 470                 coord2d_x += (coord2d_topright_x - coord2d_topleft_x) * (1 - 8 / fs_x) * 0.5;
 471                 fs = '8 8 0';
 472         }
 473         coord2d_y -= fs_y;
 474         coord2d_z = 0;
 475         drawstring(coord2d, s, fs, '1 1 1', 1, 0);
 476 }
 477
 478 void ShotOrg_Spawn()
 479 {
 480         debug_shotorg = spawn();
 481         debug_shotorg.draw = ShotOrg_Draw;
 482         debug_shotorg.draw2d = ShotOrg_Draw2D;
 483         debug_shotorg.renderflags = RF_VIEWMODEL;
 484         debug_shotorg.effects = EF_FULLBRIGHT;
 485         precache_model("models/shotorg_adjuster.md3");
 486         setmodel(debug_shotorg, "models/shotorg_adjuster.md3");
 487         debug_shotorg.scale = 2;
 488         debug_shotorg.view_ofs = '25 8 -8';
 489 }
 490
 491 void DrawDebugModel()
 492 {
 493         if(time - floor(time) > 0.5)
 494         {
 495                 PolyDrawModel(self);
 496                 self.drawmask = 0;
 497         }
 498         else
 499         {
 500                 self.renderflags = 0;
 501                 self.drawmask = MASK_NORMAL;
 502         }
 503 }
 504
 505 void GameCommand(string msg)
 506 {
 507         string s;
 508         float argc;
 509         entity e;
 510         argc = tokenize_console(msg);
 511
 512         if(argv(0) == "help" || argc == 0)
 513         {
 514                 print(_("Usage: cl_cmd COMMAND..., where possible commands are:\n"));
 515                 print(_("  settemp cvar value\n"));
 516                 print(_("  scoreboard_columns_set ...\n"));
 517                 print(_("  scoreboard_columns_help\n"));
 518                 GameCommand_Generic("help");
 519                 return;
 520         }
 521
 522         if(GameCommand_Generic(msg))
 523                 return;
 524
 525         string cmd;
 526         cmd = argv(0);
 527         if(cmd == "mv_download") {
 528                 Cmd_MapVote_MapDownload(argc);
 529         }
 530         else if(cmd == "settemp") {
 531                 cvar_clientsettemp(argv(1), argv(2));
 532         }
 533         else if(cmd == "scoreboard_columns_set") {
 534                 Cmd_HUD_SetFields(argc);
 535         }
 536         else if(cmd == "scoreboard_columns_help") {
 537                 Cmd_HUD_Help(argc);
 538         }
 539 #ifdef BLURTEST
 540         else if(cmd == "blurtest") {
 541                 blurtest_time0 = time;
 542                 blurtest_time1 = time + stof(argv(1));
 543                 blurtest_radius = stof(argv(2));
 544                 blurtest_power = stof(argv(3));
 545         }
 546 #endif
 547         else if(cmd == "shotorg_move") {
 548                 if(!debug_shotorg)
 549                         ShotOrg_Spawn();
 550                 else
 551                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stov(argv(1));
 552                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 553         }
 554         else if(cmd == "shotorg_movez") {
 555                 if(!debug_shotorg)
 556                         ShotOrg_Spawn();
 557                 else
 558                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stof(argv(1)) * (debug_shotorg.view_ofs * (1 / debug_shotorg.view_ofs_x)); // closer/farther, same xy pos
 559                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 560         }
 561         else if(cmd == "shotorg_set") {
 562                 if(!debug_shotorg)
 563                         ShotOrg_Spawn();
 564                 else
 565                         debug_shotorg.view_ofs = stov(argv(1));
 566                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 567         }
 568         else if(cmd == "shotorg_setz") {
 569                 if(!debug_shotorg)
 570                         ShotOrg_Spawn();
 571                 else
 572                         debug_shotorg.view_ofs = debug_shotorg.view_ofs * (stof(argv(1)) / debug_shotorg.view_ofs_x); // closer/farther, same xy pos
 573                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 574         }
 575         else if(cmd == "shotorg_toggle_hide") {
 576                 if(debug_shotorg)
 577                 {
 578                         debug_shotorg.cnt = !debug_shotorg.cnt;
 579                 }
 580         }
 581         else if(cmd == "shotorg_end") {
 582                 if(debug_shotorg)
 583                 {
 584                         print(vtos(debug_shotorg.view_ofs), "\n");
 585                         remove(debug_shotorg);
 586                         debug_shotorg = world;
 587                 }
 588                 localcmd("sv_cmd debug_shotorg\n");
 589         }
 590         else if(cmd == "sendcvar") {
 591                 // W_FixWeaponOrder will trash argv, so save what we need.
 592                 string thiscvar;
 593                 thiscvar = strzone(argv(1));
 594                 s = cvar_string(thiscvar);
 595                 if(thiscvar == "cl_weaponpriority")
 596                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
 597                 else if(substring(thiscvar, 0, 17) == "cl_weaponpriority" && strlen(thiscvar) == 18)
 598                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
 599                 localcmd("cmd sentcvar ", thiscvar, " \"", s, "\"\n");
 600                 strunzone(thiscvar);
 601         }
 602         else if(cmd == "spawn") {
 603                 s = argv(1);
 604                 e = spawn();
 605                 precache_model(s);
 606                 setmodel(e, s);
 607                 setorigin(e, view_origin);
 608                 e.angles = view_angles;
 609                 e.draw = DrawDebugModel;
 610                 e.classname = "debugmodel";
 611         }
 612     else if(cmd == "vyes")
 613     {
 614         if(uid2name_dialog)
 615         {
 616             vote_active = 0; // force the panel to disappear right as we have selected the value (to prevent it from fading out in the normal vote panel pos)
 617             vote_prev = 0;
 618             cvar_set("cl_allow_uid2name", "1");
 619             vote_change = -9999;
 620                         uid2name_dialog = 0;
 621         }
 622         else
 623         {
 624             localcmd("cmd vote yes\n");
 625         }
 626     }
 627     else if(cmd == "vno")
 628     {
 629         if(uid2name_dialog)
 630         {
 631             vote_active = 0;
 632             vote_prev = 0;
 633             cvar_set("cl_allow_uid2name", "0");
 634             vote_change = -9999;
 635                         uid2name_dialog = 0;
 636         }
 637         else
 638         {
 639             localcmd("cmd vote no\n");
 640         }
 641     }
 642
 643         else
 644         {
 645                 print("Invalid command. For a list of supported commands, try cl_cmd help.\n");
 646         }
 647
 648         return;
 649 }
 650
 651 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 652 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 653 // All keys are in ascii.
 654 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.
 655 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 656 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 657 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 658 {
 659         local float bSkipKey;
 660         bSkipKey = false;
 661
 662         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 663                 return true;
 664
 665         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 666                 return true;
 667
 668         if(menu_visible)
 669                 if(menu_action(bInputType, nPrimary, nSecondary))
 670                         return TRUE;
 671
 672         return bSkipKey;
 673 }
 674
 675 // END REQUIRED CSQC FUNCTIONS
 676 // --------------------------------------------------------------------------
 677
 678 // --------------------------------------------------------------------------
 679 // BEGIN OPTIONAL CSQC FUNCTIONS
 680 void Ent_ReadEntCS()
 681 {
 682         InterpolateOrigin_Undo();
 683
 684         self.classname = "entcs_receiver";
 685         self.sv_entnum = ReadByte() - 1;
 686         self.origin_x = ReadShort();
 687         self.origin_y = ReadShort();
 688         self.origin_z = ReadShort();
 689         self.angles_y = ReadByte() * 360.0 / 256;
 690         self.origin_z = self.angles_x = self.angles_z = 0;
 691
 692         InterpolateOrigin_Note();
 693 }
 694
 695 void Ent_Remove();
 696
 697 void Ent_RemovePlayerScore()
 698 {
 699         float i;
 700
 701         if(self.owner)
 702         {
 703                 SetTeam(self.owner, -1);
 704                 self.owner.gotscores = 0;
 705                 for(i = 0; i < MAX_SCORE; ++i)
 706                         self.owner.(scores[i]) = 0; // clear all scores
 707         }
 708 }
 709
 710 void Ent_ReadPlayerScore()
 711 {
 712         float i, n;
 713         float isNew;
 714         entity o;
 715
 716         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 717         // (no I've never heard of M-x replace-string, sed, or anything like that)
 718         isNew = !self.owner; // workaround for DP bug
 719         n = ReadByte()-1;
 720
 721 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 722         if(!isNew && n != self.sv_entnum)
 723         {
 724                 print(_("A CSQC entity changed its owner!\n"));
 725                 isNew = true;
 726                 Ent_Remove();
 727                 self.enttype = ENT_CLIENT_SCORES;
 728         }
 729 #endif
 730
 731         self.sv_entnum = n;
 732
 733         if not(playerslots[self.sv_entnum])
 734                 playerslots[self.sv_entnum] = spawn();
 735         o = self.owner = playerslots[self.sv_entnum];
 736         o.sv_entnum = self.sv_entnum;
 737         o.gotscores = 1;
 738
 739         //if not(o.sort_prev)
 740         //      RegisterPlayer(o);
 741         //playerchecker will do this for us later, if it has not already done so
 742
 743         float sf, lf;
 744 #if MAX_SCORE <= 8
 745         sf = ReadByte();
 746         lf = ReadByte();
 747 #else
 748         sf = ReadShort();
 749         lf = ReadShort();
 750 #endif
 751         float p;
 752         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 753                 if(sf & p)
 754                 {
 755                         if(lf & p)
 756                                 o.(scores[i]) = ReadInt24_t();
 757                         else
 758                                 o.(scores[i]) = ReadChar();
 759                 }
 760
 761         if(o.sort_prev)
 762                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 763
 764         self.entremove = Ent_RemovePlayerScore;
 765 }
 766
 767 void Ent_ReadTeamScore()
 768 {
 769         float i;
 770         entity o;
 771
 772         self.team = ReadByte();
 773         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 774
 775         float sf, lf;
 776 #if MAX_TEAMSCORE <= 8
 777         sf = ReadByte();
 778         lf = ReadByte();
 779 #else
 780         sf = ReadShort();
 781         lf = ReadShort();
 782 #endif
 783         float p;
 784         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 785                 if(sf & p)
 786                 {
 787                         if(lf & p)
 788                                 o.(teamscores[i]) = ReadInt24_t();
 789                         else
 790                                 o.(teamscores[i]) = ReadChar();
 791                 }
 792
 793         HUD_UpdateTeamPos(o);
 794 }
 795
 796 void Net_Reset()
 797 {
 798 }
 799
 800 void Ent_ClientData()
 801 {
 802         float f;
 803         float newspectatee_status;
 804
 805         f = ReadByte();
 806
 807         scoreboard_showscores_force = (f & 1);
 808
 809         if(f & 2)
 810         {
 811                 newspectatee_status = ReadByte();
 812                 if(newspectatee_status == player_localentnum)
 813                         newspectatee_status = -1; // observing
 814         }
 815         else
 816                 newspectatee_status = 0;
 817
 818         spectatorbutton_zoom = (f & 4);
 819
 820         if(f & 8)
 821         {
 822                 angles_held_status = 1;
 823                 angles_held_x = ReadAngle();
 824                 angles_held_y = ReadAngle();
 825                 angles_held_z = 0;
 826         }
 827         else
 828                 angles_held_status = 0;
 829
 830         if(newspectatee_status != spectatee_status)
 831         {
 832                 float i;
 833
 834                 // clear race stuff
 835                 race_laptime = 0;
 836                 race_checkpointtime = 0;
 837         }
 838         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 839         {
 840                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 841                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 842                 )
 843                         last_p_health = -1;
 844                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 845                         health_time = -1;
 846         }
 847         spectatee_status = newspectatee_status;
 848 }
 849
 850 void Ent_Nagger()
 851 {
 852         float nags, i, j, b, f;
 853
 854         nags = ReadByte();
 855
 856         if(nags & 128)
 857         {
 858                 if(vote_called_vote)
 859                         strunzone(vote_called_vote);
 860                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 861         }
 862
 863         if(nags & 1)
 864         {
 865                 for(j = 0; j < maxclients; ++j)
 866                         if(playerslots[j])
 867                                 playerslots[j].ready = 1;
 868                 for(i = 1; i <= maxclients; i += 8)
 869                 {
 870                         f = ReadByte();
 871                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 872                                 if not(f & b)
 873                                         if(playerslots[j])
 874                                                 playerslots[j].ready = 0;
 875                 }
 876         }
 877
 878         ready_waiting = (nags & 1);
 879         ready_waiting_for_me = (nags & 2);
 880         vote_waiting = (nags & 4);
 881         vote_waiting_for_me = (nags & 8);
 882         warmup_stage = (nags & 16);
 883 }
 884
 885 void Ent_RandomSeed()
 886 {
 887         float s;
 888         prandom_debug();
 889         s = ReadShort();
 890         psrandom(s);
 891 }
 892
 893 void Ent_ReadAccuracy(void)
 894 {
 895         float sf, f, w, b;
 896         sf = ReadInt24_t();
 897         if(sf == 0)
 898         {
 899                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 900                         weapon_accuracy[w] = -1;
 901                 return;
 902         }
 903
 904         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w, f *= 2)
 905         {
 906                 if(sf & f)
 907                 {
 908                         b = ReadByte();
 909                         if(b == 0)
 910                                 weapon_accuracy[w] = -1;
 911                         else if(b == 255)
 912                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 913                         else
 914                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 915                 }
 916         }
 917 }
 918
 919 void Ent_ShowNames()
 920 {
 921     float sf;
 922
 923     // entity init, TODO can this be done only once somehow?
 924     self.the_entnum = ReadByte(); // TODO: fixme to only send once somehow
 925     self.draw2d = Draw_ShowNames;
 926     //self.movetype = MOVETYPE_FLY; // movetype needed so we can traceline?
 927     self.mins = '-20 -20 -24';
 928     self.maxs = '20 20 45';
 929
 930     sf = ReadByte();
 931
 932     if(sf & 1)
 933     {
 934         self.origin_x = ReadShort();
 935         self.origin_y = ReadShort();
 936         self.origin_z = ReadShort();
 937     }
 938     if(sf & 2)
 939     {
 940         self.healthvalue = ReadByte();
 941         self.armorvalue = ReadByte();
 942     }
 943
 944     if(sf & 128) // same team
 945         self.sameteam = TRUE;
 946     else
 947         self.sameteam = FALSE;
 948 }
 949
 950 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 951 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 952 void Ent_RadarLink();
 953 void Ent_Init();
 954 void Ent_ScoresInfo();
 955 void(float bIsNewEntity) CSQC_Ent_Update =
 956 {
 957         float t;
 958         float savetime;
 959         t = ReadByte();
 960
 961         // set up the "time" global for received entities to be correct for interpolation purposes
 962         savetime = time;
 963         if(servertime)
 964         {
 965                 time = servertime;
 966         }
 967         else
 968         {
 969                 serverprevtime = time;
 970                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 971                 time = serverprevtime + serverdeltatime;
 972         }
 973
 974 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 975         if(self.enttype)
 976                 if(t != self.enttype)
 977                 {
 978                         print(_("A CSQC entity changed its type!\n"));
 979                         Ent_Remove();
 980                         bIsNewEntity = 1;
 981                 }
 982 #endif
 983         self.enttype = t;
 984         switch(t)
 985         {
 986                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 987                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 988                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 989                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 990                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 991                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 992                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 993                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 994                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 995                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 996                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 997                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 998                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 999                 case ENT_CLIENT_INIT: Ent_Init(); break;
1000                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
1001                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
1002                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
1003                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
1004                 case ENT_CLIENT_WALL: Ent_Wall(); break;
1005                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
1006                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
1007                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
1008                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
1009                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
1010                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
1011                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
1012                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
1013                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
1014                 case ENT_CLIENT_SHOWNAMES: Ent_ShowNames(); break;
1015                 default:
1016                         error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
1017                         break;
1018         }
1019
1020         time = savetime;
1021 };
1022 // Destructor, but does NOT deallocate the entity by calling remove(). Also
1023 // used when an entity changes its type. For an entity that someone interacts
1024 // with others, make sure it can no longer do so.
1025 void Ent_Remove()
1026 {
1027         if(self.entremove)
1028                 self.entremove();
1029
1030         self.enttype = 0;
1031         self.classname = "";
1032         self.draw = menu_sub_null;
1033         self.entremove = menu_sub_null;
1034         // TODO possibly set more stuff to defaults
1035 }
1036 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
1037 void CSQC_Ent_Remove()
1038 {
1039         if(self.enttype)
1040                 Ent_Remove();
1041         remove(self);
1042 }
1043
1044 void Gamemode_Init()
1045 {
1046         if not(isdemo())
1047         {
1048                 localcmd("\n_cl_hook_gamestart ", GametypeNameFromType(gametype), "\n");
1049                 calledhooks |= HOOK_START;
1050         }
1051 }
1052 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
1053 void CSQC_Parse_StuffCmd(string strMessage)
1054 {
1055         localcmd(strMessage);
1056 }
1057 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
1058 void CSQC_Parse_Print(string strMessage)
1059 {
1060         print(ColorTranslateRGB(strMessage));
1061 }
1062
1063 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.
1064 void CSQC_Parse_CenterPrint(string strMessage)
1065 {
1066         centerprint(strMessage);
1067 }
1068
1069 string notranslate_fogcmd1 = "\nfog ";
1070 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
1071 void Fog_Force()
1072 {
1073         // TODO somehow thwart prvm_globalset client ...
1074
1075         if(forcefog != "")
1076                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
1077 }
1078
1079 void Gamemode_Init();
1080 void Ent_ScoresInfo()
1081 {
1082         float i;
1083         self.classname = "ent_client_scores_info";
1084         gametype = ReadByte();
1085         for(i = 0; i < MAX_SCORE; ++i)
1086         {
1087                 scores_label[i] = strzone(ReadString());
1088                 scores_flags[i] = ReadByte();
1089         }
1090         for(i = 0; i < MAX_TEAMSCORE; ++i)
1091         {
1092                 teamscores_label[i] = strzone(ReadString());
1093                 teamscores_flags[i] = ReadByte();
1094         }
1095         HUD_InitScores();
1096         Gamemode_Init();
1097 }
1098
1099 void Ent_Init()
1100 {
1101         self.classname = "ent_client_init";
1102
1103         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1104
1105         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1106         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1107         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1108         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1109         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1110         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1111         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1112         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1113         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1114         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1115         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1116         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1117
1118         if(forcefog)
1119                 strunzone(forcefog);
1120         forcefog = strzone(ReadString());
1121
1122         armorblockpercent = ReadByte() / 255.0;
1123
1124         g_weaponswitchdelay = ReadByte() / 255.0;
1125
1126         g_balance_grenadelauncher_bouncefactor = ReadCoord();
1127         g_balance_grenadelauncher_bouncestop = ReadCoord();
1128         g_balance_electro_secondary_bouncefactor = ReadCoord();
1129         g_balance_electro_secondary_bouncestop = ReadCoord();
1130
1131         nex_scope = !ReadByte();
1132         sniperrifle_scope = !ReadByte();
1133
1134         serverflags = ReadByte();
1135
1136         minelayer_maxmines = ReadByte();
1137
1138         g_trueaim_minrange = ReadCoord();
1139
1140         if(!postinit)
1141                 PostInit();
1142 }
1143
1144 void Net_ReadRace()
1145 {
1146         float b;
1147
1148         b = ReadByte();
1149
1150         switch(b)
1151         {
1152                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1153                         race_checkpoint = ReadByte();
1154                         race_time = ReadInt24_t();
1155                         race_previousbesttime = ReadInt24_t();
1156                         if(race_previousbestname)
1157                                 strunzone(race_previousbestname);
1158                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1159
1160                         race_checkpointtime = time;
1161
1162                         if(race_checkpoint == 0 || race_checkpoint == 254)
1163                         {
1164                                 race_penaltyaccumulator = 0;
1165                                 race_laptime = time; // valid
1166                         }
1167
1168                         break;
1169
1170                 case RACE_NET_CHECKPOINT_CLEAR:
1171                         race_laptime = 0;
1172                         race_checkpointtime = 0;
1173                         break;
1174
1175                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1176                         race_laptime = ReadCoord();
1177                         race_checkpointtime = -99999;
1178                         // fall through
1179                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1180                         race_nextcheckpoint = ReadByte();
1181
1182                         race_nextbesttime = ReadInt24_t();
1183                         if(race_nextbestname)
1184                                 strunzone(race_nextbestname);
1185                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1186                         break;
1187
1188                 case RACE_NET_CHECKPOINT_HIT_RACE:
1189                         race_mycheckpoint = ReadByte();
1190                         race_mycheckpointtime = time;
1191                         race_mycheckpointdelta = ReadInt24_t();
1192                         race_mycheckpointlapsdelta = ReadByte();
1193                         if(race_mycheckpointlapsdelta >= 128)
1194                                 race_mycheckpointlapsdelta -= 256;
1195                         if(race_mycheckpointenemy)
1196                                 strunzone(race_mycheckpointenemy);
1197                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1198                         break;
1199
1200                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1201                         race_othercheckpoint = ReadByte();
1202                         race_othercheckpointtime = time;
1203                         race_othercheckpointdelta = ReadInt24_t();
1204                         race_othercheckpointlapsdelta = ReadByte();
1205                         if(race_othercheckpointlapsdelta >= 128)
1206                                 race_othercheckpointlapsdelta -= 256;
1207                         if(race_othercheckpointenemy)
1208                                 strunzone(race_othercheckpointenemy);
1209                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1210                         break;
1211
1212                 case RACE_NET_PENALTY_RACE:
1213                         race_penaltyeventtime = time;
1214                         race_penaltytime = ReadShort();
1215                         //race_penaltyaccumulator += race_penaltytime;
1216                         if(race_penaltyreason)
1217                                 strunzone(race_penaltyreason);
1218                         race_penaltyreason = strzone(ReadString());
1219                         break;
1220
1221                 case RACE_NET_PENALTY_QUALIFYING:
1222                         race_penaltyeventtime = time;
1223                         race_penaltytime = ReadShort();
1224                         race_penaltyaccumulator += race_penaltytime;
1225                         if(race_penaltyreason)
1226                                 strunzone(race_penaltyreason);
1227                         race_penaltyreason = strzone(ReadString());
1228                         break;
1229
1230                 case RACE_NET_SERVER_RECORD:
1231                         race_server_record = ReadInt24_t();
1232                         break;
1233                 case RACE_NET_SPEED_AWARD:
1234                         race_speedaward = ReadInt24_t();
1235                         if(race_speedaward_holder)
1236                                 strunzone(race_speedaward_holder);
1237                         race_speedaward_holder = strzone(ReadString());
1238                         break;
1239                 case RACE_NET_SPEED_AWARD_BEST:
1240                         race_speedaward_alltimebest = ReadInt24_t();
1241                         if(race_speedaward_alltimebest_holder)
1242                                 strunzone(race_speedaward_alltimebest_holder);
1243                         race_speedaward_alltimebest_holder = strzone(ReadString());
1244                         break;
1245                 case RACE_NET_SERVER_RANKINGS:
1246                         float pos, prevpos, del;
1247                         pos = ReadShort();
1248                         prevpos = ReadShort();
1249                         del = ReadShort();
1250
1251                         // move other rankings out of the way
1252                         float i;
1253                         if (prevpos) {
1254                                 for (i=prevpos-1;i>pos-1;--i) {
1255                                         grecordtime[i] = grecordtime[i-1];
1256                                         if(grecordholder[i])
1257                                                 strunzone(grecordholder[i]);
1258                                         grecordholder[i] = strzone(grecordholder[i-1]);
1259                                 }
1260                         } else if (del) { // a record has been deleted by the admin
1261                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1262                                         if (i == RANKINGS_CNT-1) { // clear out last record
1263                                                 grecordtime[i] = 0;
1264                                                 if (grecordholder[i])
1265                                                         strunzone(grecordholder[i]);
1266                                                 grecordholder[i] = string_null;
1267                                         }
1268                                         else {
1269                                                 grecordtime[i] = grecordtime[i+1];
1270                                                 if (grecordholder[i])
1271                                                         strunzone(grecordholder[i]);
1272                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1273                                         }
1274                                 }
1275                         } else { // player has no ranked record yet
1276                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1277                                         grecordtime[i] = grecordtime[i-1];
1278                                         if(grecordholder[i])
1279                                                 strunzone(grecordholder[i]);
1280                                         grecordholder[i] = strzone(grecordholder[i-1]);
1281                                 }
1282                         }
1283
1284                         // store new ranking
1285                         if(grecordholder[pos-1] != "")
1286                                 strunzone(grecordholder[pos-1]);
1287                         grecordholder[pos-1] = strzone(ReadString());
1288                         grecordtime[pos-1] = ReadInt24_t();
1289                         if(grecordholder[pos-1] == GetPlayerName(player_localentnum -1))
1290                                 race_myrank = pos;
1291                         break;
1292                 case RACE_NET_SERVER_STATUS:
1293                         race_status = ReadShort();
1294                         if(race_status_name)
1295                                 strunzone(race_status_name);
1296                         race_status_name = strzone(ReadString());
1297         }
1298 }
1299
1300 void Net_ReadSpawn()
1301 {
1302         zoomin_effect = 1;
1303         current_viewzoom = 0.6;
1304 }
1305
1306 void Net_TeamNagger()
1307 {
1308         teamnagger = 1;
1309 }
1310
1311 void Net_ReadPingPLReport()
1312 {
1313         float e, pi, pl, ml;
1314         e = ReadByte();
1315         pi = ReadShort();
1316         pl = ReadByte();
1317         ml = ReadByte();
1318         if not(playerslots[e])
1319                 return;
1320         playerslots[e].ping = pi;
1321         playerslots[e].ping_packetloss = pl / 255.0;
1322         playerslots[e].ping_movementloss = ml / 255.0;
1323 }
1324
1325 void Net_VoteDialog(float highlight) {
1326         if(highlight) {
1327                 vote_highlighted = ReadByte();
1328                 return;
1329         }
1330
1331         vote_yescount = ReadByte();
1332         vote_nocount = ReadByte();
1333         vote_needed = ReadByte();
1334         vote_active = 1;
1335 }
1336
1337 void Net_VoteDialogReset() {
1338         vote_active = 0;
1339 }
1340
1341 void Net_Notify() {
1342         float type;
1343         type = ReadByte();
1344
1345         if(type == CSQC_KILLNOTIFY)
1346         {
1347                 HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1348         }
1349         else if(type == CSQC_CENTERPRINT)
1350         {
1351                 HUD_Centerprint(ReadString(), ReadString(), ReadShort(), ReadByte());
1352         }
1353 }
1354
1355 void Net_WeaponComplain() {
1356         complain_weapon = ReadByte();
1357
1358         if(complain_weapon_name)
1359                 strunzone(complain_weapon_name);
1360         complain_weapon_name = strzone(ReadString());
1361
1362         complain_weapon_type = ReadByte();
1363
1364         complain_weapon_time = time;
1365         weapontime = time; // ping the weapon panel
1366 }
1367
1368 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1369 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1370 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1371 float CSQC_Parse_TempEntity()
1372 {
1373         local float bHandled;
1374                 bHandled  = true;
1375         // Acquire TE ID
1376         local float nTEID;
1377                 nTEID = ReadByte();
1378
1379                 // NOTE: Could just do return instead of break...
1380         switch(nTEID)
1381         {
1382                 case TE_CSQC_TARGET_MUSIC:
1383                         Net_TargetMusic();
1384                         bHandled = true;
1385                         break;
1386                 case TE_CSQC_PICTURE:
1387                         Net_MapVote_Picture();
1388                         bHandled = true;
1389                         break;
1390                 case TE_CSQC_RACE:
1391                         Net_ReadRace();
1392                         bHandled = true;
1393                         break;
1394                 case TE_CSQC_SPAWN:
1395                         Net_ReadSpawn();
1396                         bHandled = true;
1397                         break;
1398                 case TE_CSQC_ZCURVEPARTICLES:
1399                         Net_ReadZCurveParticles();
1400                         bHandled = true;
1401                         break;
1402                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1403                         Net_ReadNexgunBeamParticle();
1404                         bHandled = true;
1405                         break;
1406                 case TE_CSQC_TEAMNAGGER:
1407                         Net_TeamNagger();
1408                         bHandled = true;
1409                         break;
1410                 case TE_CSQC_VOTE:
1411                         Net_VoteDialog(ReadByte());
1412                         bHandled = true;
1413                         break;
1414                 case TE_CSQC_VOTERESET:
1415                         Net_VoteDialogReset();
1416                         bHandled = true;
1417                         break;
1418                 case TE_CSQC_LIGHTNINGARC:
1419                         Net_ReadLightningarc();
1420                         bHandled = true;
1421                         break;
1422                 case TE_CSQC_PINGPLREPORT:
1423                         Net_ReadPingPLReport();
1424                         bHandled = true;
1425                         break;
1426                 case TE_CSQC_ANNOUNCE:
1427                         announce_snd = strzone(ReadString());
1428                         bHandled = true;
1429                         break;
1430                 case TE_CSQC_NOTIFY:
1431                         Net_Notify();
1432                         bHandled = true;
1433                         break;
1434                 case TE_CSQC_WEAPONCOMPLAIN:
1435                         Net_WeaponComplain();
1436                         bHandled = true;
1437                         break;
1438                 default:
1439                         // No special logic for this temporary entity; return 0 so the engine can handle it
1440                         bHandled = false;
1441                         break;
1442         }
1443
1444         return bHandled;
1445 }
1446
1447 string getcommandkey(string text, string command)
1448 {
1449         string keys;
1450         float n, j, k, l;
1451
1452         if (!autocvar_hud_showbinds)
1453                 return text;
1454
1455         keys = db_get(binddb, command);
1456         if (!keys)
1457         {
1458                 n = tokenize(findkeysforcommand(command)); // uses '...' strings
1459                 for(j = 0; j < n; ++j)
1460                 {
1461                         k = stof(argv(j));
1462                         if(k != -1)
1463                         {
1464                                 if ("" == keys)
1465                                         keys = keynumtostring(k);
1466                                 else
1467                                         keys = strcat(keys, ", ", keynumtostring(k));
1468
1469                                 ++l;
1470                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit >= l) break;
1471                         }
1472
1473                 }
1474                 db_put(binddb, command, keys);
1475         }
1476
1477         if ("" == keys) {
1478                 if (autocvar_hud_showbinds > 1)
1479                         return sprintf(_("%s (not bound)"), text);
1480                 else
1481                         return text;
1482         }
1483         else if (autocvar_hud_showbinds > 1)
1484                 return sprintf(_("%s (%s)"), text, keys);
1485         else
1486                 return keys;
1487 }