qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 entity clearentity_ent;
   6 void clearentity(entity e)
   7 {
   8         if not(clearentity_ent)
   9         {
  10                 clearentity_ent = spawn();
  11                 clearentity_ent.classname = "clearentity";
  12         }
  13         float n = e.entnum;
  14         copyentity(clearentity_ent, e);
  15         e.entnum = n;
  16 }
  17
  18 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  19 void menu_show_error()
  20 {
  21         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  22 }
  23
  24 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  25 // Useful for precaching things
  26
  27 void menu_sub_null()
  28 {
  29 }
  30
  31 #ifdef USE_FTE
  32 float __engine_check;
  33 #endif
  34
  35 void precache_playermodel(string m)
  36 {
  37         string f;
  38
  39         if(substring(m, -9,5) == "_lod1")
  40                 return;
  41         if(substring(m, -9,5) == "_lod2")
  42                 return;
  43         precache_model(m);
  44         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
  45         if(fexists(f))
  46                 precache_model(f);
  47         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
  48         if(fexists(f))
  49                 precache_model(f);
  50
  51         /*
  52         float globhandle, i, n;
  53         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
  54         if (globhandle < 0)
  55                 return;
  56         n = search_getsize(globhandle);
  57         for (i = 0; i < n; ++i)
  58         {
  59                 //print(search_getfilename(globhandle, i), "\n");
  60                 f = search_getfilename(globhandle, i);
  61                 PrecachePlayerSounds(f);
  62         }
  63         search_end(globhandle);
  64         */
  65 }
  66 void precache_all_playermodels(string pattern)
  67 {
  68         float globhandle, i, n;
  69         string f;
  70
  71         globhandle = search_begin(pattern, TRUE, FALSE);
  72         if (globhandle < 0)
  73                 return;
  74         n = search_getsize(globhandle);
  75         for (i = 0; i < n; ++i)
  76         {
  77                 //print(search_getfilename(globhandle, i), "\n");
  78                 f = search_getfilename(globhandle, i);
  79                 precache_playermodel(f);
  80         }
  81         search_end(globhandle);
  82 }
  83
  84 string forcefog;
  85 void WaypointSprite_Load();
  86 void ConsoleCommand_macro_init();
  87 void CSQC_Init(void)
  88 {
  89         prvm_language = cvar_string("prvm_language");
  90 #ifdef USE_FTE
  91 #pragma target ID
  92         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  93         if(!__engine_check)
  94         {
  95                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
  96                 localcmd("\ndisconnect\n");
  97                 return;
  98         }
  99 #pragma target FTE
 100 #endif
 101
 102         check_unacceptable_compiler_bugs();
 103
 104 #ifdef WATERMARK
 105         print(sprintf(_("^4CSQC Build information: ^1%s\n"), WATERMARK));
 106 #endif
 107
 108         float i;
 109
 110 #ifdef COMPAT_XON050_ENGINE
 111         // old engine lacks implementation of player_localnum
 112         player_localnum = player_localentnum - 1;
 113 #endif
 114
 115         binddb = db_create();
 116         tempdb = db_create();
 117         ClientProgsDB = db_load("client.db");
 118         compressShortVector_init();
 119
 120         draw_endBoldFont();
 121         menu_visible = FALSE;
 122         menu_show = menu_show_error;
 123         menu_action = func_null;
 124
 125         for(i = 0; i < 255; ++i)
 126                 if(getplayerkeyvalue(i, "viewentity") == "")
 127                         break;
 128         maxclients = i;
 129
 130         //registercommand("hud_configure");
 131         //registercommand("hud_save");
 132         //registercommand("menu_action");
 133
 134         ConsoleCommand_macro_init();
 135
 136         registercvar("hud_usecsqc", "1");
 137         registercvar("scoreboard_columns", "default");
 138
 139         gametype = 0;
 140
 141         // hud_fields uses strunzone on the titles!
 142         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 143                 hud_title[i] = strzone("(null)");
 144
 145         postinit = false;
 146
 147         calledhooks = 0;
 148
 149         teams = Sort_Spawn();
 150         players = Sort_Spawn();
 151
 152         GetTeam(FL_SPECTATOR, true); // add specs first
 153
 154         // needs to be done so early because of the constants they create
 155         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 156         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 157         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 158         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 159
 160         WaypointSprite_Load();
 161
 162         // precaches
 163         precache_model("null");
 164         precache_sound("misc/hit.wav");
 165         precache_sound("misc/typehit.wav");
 166         if (autocvar_cl_precacheplayermodels)
 167         {
 168                 precache_all_playermodels("models/player/*.zym");
 169                 precache_all_playermodels("models/player/*.dpm");
 170                 precache_all_playermodels("models/player/*.md3");
 171                 precache_all_playermodels("models/player/*.psk");
 172                 precache_all_playermodels("models/player/*.iqm");
 173         }
 174
 175         Projectile_Precache();
 176         Hook_Precache();
 177         GibSplash_Precache();
 178         Casings_Precache();
 179         DamageInfo_Precache();
 180         Vehicles_Precache();
 181         turrets_precache();
 182     Announcer_Precache();
 183         Tuba_Precache();
 184         CSQCPlayer_Precache();
 185
 186         if(autocvar_cl_reticle)
 187         {
 188                 if(autocvar_cl_reticle_item_normal) { precache_pic("gfx/reticle_normal"); }
 189                 if(autocvar_cl_reticle_item_nex) { precache_pic("gfx/reticle_nex"); }
 190         }
 191
 192         get_mi_min_max_texcoords(1); // try the CLEVER way first
 193         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 194         shortmapname = mi_shortname;
 195
 196         if(precache_pic(minimapname) == "")
 197         {
 198                 // but maybe we have a non-clever minimap
 199                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 200                 if(precache_pic(minimapname) == "")
 201                         minimapname = ""; // FAIL
 202                 else
 203                         get_mi_min_max_texcoords(0); // load new texcoords
 204         }
 205
 206         mi_center = (mi_min + mi_max) * 0.5;
 207         mi_scale = mi_max - mi_min;
 208         minimapname = strzone(minimapname);
 209
 210         WarpZone_Init();
 211
 212         hud_configure_prev = -1;
 213         tab_panel = -1;
 214
 215         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 216 }
 217
 218 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 219 void Shutdown(void)
 220 {
 221 #ifdef USE_FTE
 222 #pragma TARGET id
 223         if(!__engine_check)
 224                 return 0;
 225 #pragma TARGET fte
 226 #endif
 227
 228         WarpZone_Shutdown();
 229
 230         remove(teams);
 231         remove(players);
 232         db_close(binddb);
 233         db_close(tempdb);
 234         if(autocvar_cl_db_saveasdump)
 235                 db_dump(ClientProgsDB, "client.db");
 236         else
 237                 db_save(ClientProgsDB, "client.db");
 238         db_close(ClientProgsDB);
 239
 240         if(camera_active)
 241                 cvar_set("chase_active",ftos(chase_active_backup));
 242
 243         // unset the event chasecam's chase_active
 244         if(autocvar_chase_active < 0)
 245                 cvar_set("chase_active", "0");
 246
 247         if not(isdemo())
 248         {
 249                 if not(calledhooks & HOOK_START)
 250                         localcmd("\n_cl_hook_gamestart nop\n");
 251                 if not(calledhooks & HOOK_END)
 252                         localcmd("\ncl_hook_gameend\n");
 253         }
 254 }
 255
 256 .float has_team;
 257 float SetTeam(entity o, float Team)
 258 {
 259         entity tm;
 260         if(teamplay)
 261         {
 262                 switch(Team)
 263                 {
 264                         case -1:
 265                         case FL_TEAM_1:
 266                         case FL_TEAM_2:
 267                         case FL_TEAM_3:
 268                         case FL_TEAM_4:
 269                                 break;
 270                         default:
 271                                 if(GetTeam(Team, false) == world)
 272                                 {
 273                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 274                                         Team = FL_SPECTATOR;
 275                                 }
 276                                 break;
 277                 }
 278         }
 279         else
 280         {
 281                 switch(Team)
 282                 {
 283                         case -1:
 284                         case 0:
 285                                 break;
 286                         default:
 287                                 if(GetTeam(Team, false) == world)
 288                                 {
 289                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 290                                         Team = FL_SPECTATOR;
 291                                 }
 292                                 break;
 293                 }
 294         }
 295         if(Team == -1) // leave
 296         {
 297                 if(o.has_team)
 298                 {
 299                         tm = GetTeam(o.team, false);
 300                         tm.team_size -= 1;
 301                         o.has_team = 0;
 302                         return TRUE;
 303                 }
 304         }
 305         else
 306         {
 307                 if not(o.has_team)
 308                 {
 309                         o.team = Team;
 310                         tm = GetTeam(Team, true);
 311                         tm.team_size += 1;
 312                         o.has_team = 1;
 313                         return TRUE;
 314                 }
 315                 else if(Team != o.team)
 316                 {
 317                         tm = GetTeam(o.team, false);
 318                         tm.team_size -= 1;
 319                         o.team = Team;
 320                         tm = GetTeam(Team, true);
 321                         tm.team_size += 1;
 322                         return TRUE;
 323                 }
 324         }
 325         return FALSE;
 326 }
 327
 328 void Playerchecker_Think()
 329 {
 330         float i;
 331         entity e;
 332         for(i = 0; i < maxclients; ++i)
 333         {
 334                 e = playerslots[i];
 335                 if(GetPlayerName(i) == "")
 336                 {
 337                         if(e.sort_prev)
 338                         {
 339                                 // player disconnected
 340                                 SetTeam(e, -1);
 341                                 RemovePlayer(e);
 342                                 e.sort_prev = world;
 343                                 //e.gotscores = 0;
 344                         }
 345                 }
 346                 else
 347                 {
 348                         if not(e.sort_prev)
 349                         {
 350                                 // player connected
 351                                 if not(e)
 352                                         playerslots[i] = e = spawn();
 353                                 e.sv_entnum = i;
 354                                 e.ping = 0;
 355                                 e.ping_packetloss = 0;
 356                                 e.ping_movementloss = 0;
 357                                 //e.gotscores = 0; // we might already have the scores...
 358                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 359                                 RegisterPlayer(e);
 360                                 HUD_UpdatePlayerPos(e);
 361                         }
 362                 }
 363         }
 364         self.nextthink = time + 0.2;
 365 }
 366
 367 void Porto_Init();
 368 void TrueAim_Init();
 369 void PostInit(void)
 370 {
 371         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
 372
 373         entity playerchecker;
 374         playerchecker = spawn();
 375         playerchecker.think = Playerchecker_Think;
 376         playerchecker.nextthink = time + 0.2;
 377
 378         Porto_Init();
 379         TrueAim_Init();
 380
 381         postinit = true;
 382 }
 383
 384 float button_zoom;
 385
 386 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 387 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 388 // All keys are in ascii.
 389 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 390 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 391 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 392 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 393 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 394 {
 395         float bSkipKey;
 396         bSkipKey = false;
 397
 398         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 399                 return true;
 400
 401         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 402                 return true;
 403
 404         if(menu_visible && menu_action)
 405                 if(menu_action(bInputType, nPrimary, nSecondary))
 406                         return TRUE;
 407
 408         return bSkipKey;
 409 }
 410
 411 // END REQUIRED CSQC FUNCTIONS
 412 // --------------------------------------------------------------------------
 413
 414 // --------------------------------------------------------------------------
 415 // BEGIN OPTIONAL CSQC FUNCTIONS
 416 void Ent_RemoveEntCS()
 417 {
 418         entcs_receiver[self.sv_entnum] = world;
 419 }
 420 void Ent_ReadEntCS()
 421 {
 422         float sf;
 423         InterpolateOrigin_Undo();
 424
 425         self.classname = "entcs_receiver";
 426         sf = ReadByte();
 427
 428         if(sf & 1)
 429                 self.sv_entnum = ReadByte();
 430         if(sf & 2)
 431         {
 432                 self.origin_x = ReadShort();
 433                 self.origin_y = ReadShort();
 434                 self.origin_z = ReadShort();
 435         }
 436         if(sf & 4)
 437         {
 438                 self.angles_y = ReadByte() * 360.0 / 256;
 439                 self.angles_x = self.angles_z = 0;
 440         }
 441         if(sf & 8)
 442                 self.healthvalue = ReadByte() * 10;
 443         if(sf & 16)
 444                 self.armorvalue = ReadByte() * 10;
 445
 446         entcs_receiver[self.sv_entnum] = self;
 447         self.entremove = Ent_RemoveEntCS;
 448
 449         InterpolateOrigin_Note();
 450 }
 451
 452 void Ent_Remove();
 453
 454 void Ent_RemovePlayerScore()
 455 {
 456         float i;
 457
 458         if(self.owner)
 459         {
 460                 SetTeam(self.owner, -1);
 461                 self.owner.gotscores = 0;
 462                 for(i = 0; i < MAX_SCORE; ++i)
 463                         self.owner.(scores[i]) = 0; // clear all scores
 464         }
 465 }
 466
 467 void Ent_ReadPlayerScore()
 468 {
 469         float i, n;
 470         float isNew;
 471         entity o;
 472
 473         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 474         // (no I've never heard of M-x replace-string, sed, or anything like that)
 475         isNew = !self.owner; // workaround for DP bug
 476         n = ReadByte()-1;
 477
 478 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 479         if(!isNew && n != self.sv_entnum)
 480         {
 481                 //print(_("A CSQC entity changed its owner!\n"));
 482                 print(sprintf(_("A CSQC entity changed its owner! (edict: %d, classname: %s)\n"), num_for_edict(self), self.classname));
 483                 isNew = true;
 484                 Ent_Remove();
 485                 self.enttype = ENT_CLIENT_SCORES;
 486         }
 487 #endif
 488
 489         self.sv_entnum = n;
 490
 491         if not(playerslots[self.sv_entnum])
 492                 playerslots[self.sv_entnum] = spawn();
 493         o = self.owner = playerslots[self.sv_entnum];
 494         o.sv_entnum = self.sv_entnum;
 495         o.gotscores = 1;
 496
 497         //if not(o.sort_prev)
 498         //      RegisterPlayer(o);
 499         //playerchecker will do this for us later, if it has not already done so
 500
 501         float sf, lf;
 502 #if MAX_SCORE <= 8
 503         sf = ReadByte();
 504         lf = ReadByte();
 505 #else
 506         sf = ReadShort();
 507         lf = ReadShort();
 508 #endif
 509         float p;
 510         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 511                 if(sf & p)
 512                 {
 513                         if(lf & p)
 514                                 o.(scores[i]) = ReadInt24_t();
 515                         else
 516                                 o.(scores[i]) = ReadChar();
 517                 }
 518
 519         if(o.sort_prev)
 520                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 521
 522         self.entremove = Ent_RemovePlayerScore;
 523 }
 524
 525 void Ent_ReadTeamScore()
 526 {
 527         float i;
 528         entity o;
 529
 530         self.team = ReadByte();
 531         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 532
 533         float sf, lf;
 534 #if MAX_TEAMSCORE <= 8
 535         sf = ReadByte();
 536         lf = ReadByte();
 537 #else
 538         sf = ReadShort();
 539         lf = ReadShort();
 540 #endif
 541         float p;
 542         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 543                 if(sf & p)
 544                 {
 545                         if(lf & p)
 546                                 o.(teamscores[i]) = ReadInt24_t();
 547                         else
 548                                 o.(teamscores[i]) = ReadChar();
 549                 }
 550
 551         HUD_UpdateTeamPos(o);
 552 }
 553
 554 void Ent_ClientData()
 555 {
 556         float f;
 557         float newspectatee_status;
 558
 559         f = ReadByte();
 560
 561         scoreboard_showscores_force = (f & 1);
 562
 563         if(f & 2)
 564         {
 565                 newspectatee_status = ReadByte();
 566                 if(newspectatee_status == player_localnum + 1)
 567                         newspectatee_status = -1; // observing
 568         }
 569         else
 570                 newspectatee_status = 0;
 571
 572         spectatorbutton_zoom = (f & 4);
 573
 574         if(f & 8)
 575         {
 576                 angles_held_status = 1;
 577                 angles_held_x = ReadAngle();
 578                 angles_held_y = ReadAngle();
 579                 angles_held_z = 0;
 580         }
 581         else
 582                 angles_held_status = 0;
 583
 584         if(newspectatee_status != spectatee_status)
 585         {
 586                 // clear race stuff
 587                 race_laptime = 0;
 588                 race_checkpointtime = 0;
 589         }
 590         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 591         {
 592                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 593                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 594                 )
 595                         prev_p_health = -1;
 596                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 597                         prev_health = -1;
 598         }
 599         spectatee_status = newspectatee_status;
 600
 601         // non-COMPAT_XON050_ENGINE: we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 602 }
 603
 604 void Ent_Nagger()
 605 {
 606         float nags, i, j, b, f;
 607
 608         nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 609
 610         if(!(nags & 4))
 611         {
 612                 if(vote_called_vote)
 613                         strunzone(vote_called_vote);
 614                 vote_called_vote = string_null;
 615                 vote_active = 0;
 616         }
 617         else
 618         {
 619                 vote_active = 1;
 620         }
 621
 622         if(nags & 64)
 623         {
 624                 vote_yescount = ReadByte();
 625                 vote_nocount = ReadByte();
 626                 vote_needed = ReadByte();
 627                 vote_highlighted = ReadChar();
 628         }
 629
 630         if(nags & 128)
 631         {
 632                 if(vote_called_vote)
 633                         strunzone(vote_called_vote);
 634                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 635         }
 636
 637         if(nags & 1)
 638         {
 639                 for(j = 0; j < maxclients; ++j)
 640                         if(playerslots[j])
 641                                 playerslots[j].ready = 1;
 642                 for(i = 1; i <= maxclients; i += 8)
 643                 {
 644                         f = ReadByte();
 645                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 646                                 if not(f & b)
 647                                         if(playerslots[j])
 648                                                 playerslots[j].ready = 0;
 649                 }
 650         }
 651
 652         ready_waiting = (nags & 1);
 653         ready_waiting_for_me = (nags & 2);
 654         vote_waiting = (nags & 4);
 655         vote_waiting_for_me = (nags & 8);
 656         warmup_stage = (nags & 16);
 657 }
 658
 659 void Ent_RandomSeed()
 660 {
 661         float s;
 662         prandom_debug();
 663         s = ReadShort();
 664         psrandom(s);
 665 }
 666
 667 void Ent_ReadAccuracy(void)
 668 {
 669         float sf, f, w, b;
 670         sf = ReadInt24_t();
 671         if(sf == 0)
 672         {
 673                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 674                         weapon_accuracy[w] = -1;
 675                 return;
 676         }
 677
 678         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 679         {
 680                 if(sf & f)
 681                 {
 682                         b = ReadByte();
 683                         if(b == 0)
 684                                 weapon_accuracy[w] = -1;
 685                         else if(b == 255)
 686                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 687                         else
 688                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 689                 }
 690                 if(f == 0x800000)
 691                         f = 1;
 692                 else
 693                         f *= 2;
 694         }
 695 }
 696
 697 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 698 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 699 void Ent_RadarLink();
 700 void Ent_Init();
 701 void Ent_ScoresInfo();
 702 void CSQC_Ent_Update(float bIsNewEntity)
 703 {
 704         float t;
 705         float savetime;
 706         t = ReadByte();
 707
 708         if(autocvar_developer_csqcentities)
 709                 print(sprintf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t));
 710
 711         // set up the "time" global for received entities to be correct for interpolation purposes
 712         savetime = time;
 713         if(servertime)
 714         {
 715                 time = servertime;
 716         }
 717         else
 718         {
 719                 serverprevtime = time;
 720                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 721                 time = serverprevtime + serverdeltatime;
 722         }
 723
 724 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 725         if(self.enttype)
 726         {
 727                 if(t != self.enttype || bIsNewEntity)
 728                 {
 729                         //print(_("A CSQC entity changed its type!\n"));
 730                         print(sprintf(_("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n"), num_for_edict(self), self.entnum, self.enttype, t));
 731                         Ent_Remove();
 732                         clearentity(self);
 733                         bIsNewEntity = 1;
 734                 }
 735         }
 736         else
 737         {
 738                 if(!bIsNewEntity)
 739                 {
 740                         print(sprintf(_("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n"), num_for_edict(self), self.entnum, t));
 741                         bIsNewEntity = 1;
 742                 }
 743         }
 744 #endif
 745         self.enttype = t;
 746         switch(t)
 747         {
 748                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 749                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 750                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 751                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 752                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 753                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 754                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 755                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 756                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 757                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 758                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 759                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 760                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 761                 case ENT_CLIENT_INIT: Ent_Init(); break;
 762                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 763                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 764                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 765                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 766                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 767                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 768                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 769                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 770                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 771                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 772                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 773                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 774                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
 775                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
 776                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 777                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 778                 case ENT_CLIENT_TURRET: ent_turret(); break;
 779                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 780                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 781                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 782                 default:
 783                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 784                         error(sprintf(_("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n"), self.enttype, num_for_edict(self), self.classname));
 785                         break;
 786         }
 787
 788         time = savetime;
 789 }
 790 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 791 // used when an entity changes its type. For an entity that someone interacts
 792 // with others, make sure it can no longer do so.
 793 void Ent_Remove()
 794 {
 795         if(self.entremove)
 796                 self.entremove();
 797
 798         if(self.skeletonindex)
 799         {
 800                 skel_delete(self.skeletonindex);
 801                 self.skeletonindex = 0;
 802         }
 803
 804         if(self.snd_looping > 0)
 805         {
 806                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 807                 self.snd_looping = 0;
 808         }
 809
 810         self.enttype = 0;
 811         self.classname = "";
 812         self.draw = menu_sub_null;
 813         self.entremove = menu_sub_null;
 814         // TODO possibly set more stuff to defaults
 815 }
 816 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 817 void CSQC_Ent_Remove()
 818 {
 819         if(autocvar_developer_csqcentities)
 820                 print(sprintf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype));
 821
 822         if(wasfreed(self))
 823         {
 824                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 825                 return;
 826         }
 827         if(self.enttype)
 828                 Ent_Remove();
 829         remove(self);
 830 }
 831
 832 void Gamemode_Init()
 833 {
 834         if not(isdemo())
 835         {
 836                 if(!(calledhooks & HOOK_START))
 837                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 838                 calledhooks |= HOOK_START;
 839         }
 840 }
 841 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 842 void CSQC_Parse_StuffCmd(string strMessage)
 843 {
 844         if(autocvar_developer_csqcentities)
 845                 print(sprintf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage));
 846
 847         localcmd(strMessage);
 848 }
 849 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 850 void CSQC_Parse_Print(string strMessage)
 851 {
 852         if(autocvar_developer_csqcentities)
 853                 print(sprintf("CSQC_Parse_Print(\"%s\")\n", strMessage));
 854
 855         print(ColorTranslateRGB(strMessage));
 856 }
 857
 858 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 859 void CSQC_Parse_CenterPrint(string strMessage)
 860 {
 861         if(autocvar_developer_csqcentities)
 862                 print(sprintf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage));
 863
 864         centerprint_hud(strMessage);
 865 }
 866
 867 string notranslate_fogcmd1 = "\nfog ";
 868 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 869 void Fog_Force()
 870 {
 871         // TODO somehow thwart prvm_globalset client ...
 872
 873         if(forcefog != "")
 874                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
 875 }
 876
 877 void Gamemode_Init();
 878 void Ent_ScoresInfo()
 879 {
 880         float i;
 881         self.classname = "ent_client_scores_info";
 882         gametype = ReadInt24_t();
 883         for(i = 0; i < MAX_SCORE; ++i)
 884         {
 885                 scores_label[i] = strzone(ReadString());
 886                 scores_flags[i] = ReadByte();
 887         }
 888         for(i = 0; i < MAX_TEAMSCORE; ++i)
 889         {
 890                 teamscores_label[i] = strzone(ReadString());
 891                 teamscores_flags[i] = ReadByte();
 892         }
 893         HUD_InitScores();
 894         Gamemode_Init();
 895 }
 896
 897 void Ent_Init()
 898 {
 899         self.classname = "ent_client_init";
 900
 901         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 902
 903         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 904         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 905         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 906         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 907         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 908         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 909         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 910         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 911         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 912         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 913         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 914         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 915
 916         if(forcefog)
 917                 strunzone(forcefog);
 918         forcefog = strzone(ReadString());
 919
 920         armorblockpercent = ReadByte() / 255.0;
 921
 922         g_weaponswitchdelay = ReadByte() / 255.0;
 923
 924         g_balance_grenadelauncher_bouncefactor = ReadCoord();
 925         g_balance_grenadelauncher_bouncestop = ReadCoord();
 926         g_balance_electro_secondary_bouncefactor = ReadCoord();
 927         g_balance_electro_secondary_bouncestop = ReadCoord();
 928
 929         nex_scope = !ReadByte();
 930         rifle_scope = !ReadByte();
 931
 932         serverflags = ReadByte();
 933
 934         minelayer_maxmines = ReadByte();
 935
 936         hagar_maxrockets = ReadByte();
 937
 938         g_trueaim_minrange = ReadCoord();
 939         g_balance_porto_secondary = ReadByte();
 940
 941         if(!postinit)
 942                 PostInit();
 943 }
 944
 945 void Net_ReadRace()
 946 {
 947         float b;
 948
 949         b = ReadByte();
 950
 951         switch(b)
 952         {
 953                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
 954                         race_checkpoint = ReadByte();
 955                         race_time = ReadInt24_t();
 956                         race_previousbesttime = ReadInt24_t();
 957                         if(race_previousbestname)
 958                                 strunzone(race_previousbestname);
 959                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
 960
 961                         race_checkpointtime = time;
 962
 963                         if(race_checkpoint == 0 || race_checkpoint == 254)
 964                         {
 965                                 race_penaltyaccumulator = 0;
 966                                 race_laptime = time; // valid
 967                         }
 968
 969                         break;
 970
 971                 case RACE_NET_CHECKPOINT_CLEAR:
 972                         race_laptime = 0;
 973                         race_checkpointtime = 0;
 974                         break;
 975
 976                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
 977                         race_laptime = ReadCoord();
 978                         race_checkpointtime = -99999;
 979                         // fall through
 980                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
 981                         race_nextcheckpoint = ReadByte();
 982
 983                         race_nextbesttime = ReadInt24_t();
 984                         if(race_nextbestname)
 985                                 strunzone(race_nextbestname);
 986                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
 987                         break;
 988
 989                 case RACE_NET_CHECKPOINT_HIT_RACE:
 990                         race_mycheckpoint = ReadByte();
 991                         race_mycheckpointtime = time;
 992                         race_mycheckpointdelta = ReadInt24_t();
 993                         race_mycheckpointlapsdelta = ReadByte();
 994                         if(race_mycheckpointlapsdelta >= 128)
 995                                 race_mycheckpointlapsdelta -= 256;
 996                         if(race_mycheckpointenemy)
 997                                 strunzone(race_mycheckpointenemy);
 998                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
 999                         break;
1000
1001                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1002                         race_othercheckpoint = ReadByte();
1003                         race_othercheckpointtime = time;
1004                         race_othercheckpointdelta = ReadInt24_t();
1005                         race_othercheckpointlapsdelta = ReadByte();
1006                         if(race_othercheckpointlapsdelta >= 128)
1007                                 race_othercheckpointlapsdelta -= 256;
1008                         if(race_othercheckpointenemy)
1009                                 strunzone(race_othercheckpointenemy);
1010                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1011                         break;
1012
1013                 case RACE_NET_PENALTY_RACE:
1014                         race_penaltyeventtime = time;
1015                         race_penaltytime = ReadShort();
1016                         //race_penaltyaccumulator += race_penaltytime;
1017                         if(race_penaltyreason)
1018                                 strunzone(race_penaltyreason);
1019                         race_penaltyreason = strzone(ReadString());
1020                         break;
1021
1022                 case RACE_NET_PENALTY_QUALIFYING:
1023                         race_penaltyeventtime = time;
1024                         race_penaltytime = ReadShort();
1025                         race_penaltyaccumulator += race_penaltytime;
1026                         if(race_penaltyreason)
1027                                 strunzone(race_penaltyreason);
1028                         race_penaltyreason = strzone(ReadString());
1029                         break;
1030
1031                 case RACE_NET_SERVER_RECORD:
1032                         race_server_record = ReadInt24_t();
1033                         break;
1034                 case RACE_NET_SPEED_AWARD:
1035                         race_speedaward = ReadInt24_t();
1036                         if(race_speedaward_holder)
1037                                 strunzone(race_speedaward_holder);
1038                         race_speedaward_holder = strzone(ReadString());
1039                         break;
1040                 case RACE_NET_SPEED_AWARD_BEST:
1041                         race_speedaward_alltimebest = ReadInt24_t();
1042                         if(race_speedaward_alltimebest_holder)
1043                                 strunzone(race_speedaward_alltimebest_holder);
1044                         race_speedaward_alltimebest_holder = strzone(ReadString());
1045                         break;
1046                 case RACE_NET_SERVER_RANKINGS:
1047                         float pos, prevpos, del;
1048                         pos = ReadShort();
1049                         prevpos = ReadShort();
1050                         del = ReadShort();
1051
1052                         // move other rankings out of the way
1053                         float i;
1054                         if (prevpos) {
1055                                 for (i=prevpos-1;i>pos-1;--i) {
1056                                         grecordtime[i] = grecordtime[i-1];
1057                                         if(grecordholder[i])
1058                                                 strunzone(grecordholder[i]);
1059                                         grecordholder[i] = strzone(grecordholder[i-1]);
1060                                 }
1061                         } else if (del) { // a record has been deleted by the admin
1062                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1063                                         if (i == RANKINGS_CNT-1) { // clear out last record
1064                                                 grecordtime[i] = 0;
1065                                                 if (grecordholder[i])
1066                                                         strunzone(grecordholder[i]);
1067                                                 grecordholder[i] = string_null;
1068                                         }
1069                                         else {
1070                                                 grecordtime[i] = grecordtime[i+1];
1071                                                 if (grecordholder[i])
1072                                                         strunzone(grecordholder[i]);
1073                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1074                                         }
1075                                 }
1076                         } else { // player has no ranked record yet
1077                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1078                                         grecordtime[i] = grecordtime[i-1];
1079                                         if(grecordholder[i])
1080                                                 strunzone(grecordholder[i]);
1081                                         grecordholder[i] = strzone(grecordholder[i-1]);
1082                                 }
1083                         }
1084
1085                         // store new ranking
1086                         if(grecordholder[pos-1] != "")
1087                                 strunzone(grecordholder[pos-1]);
1088                         grecordholder[pos-1] = strzone(ReadString());
1089                         grecordtime[pos-1] = ReadInt24_t();
1090                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1091                                 race_myrank = pos;
1092                         break;
1093                 case RACE_NET_SERVER_STATUS:
1094                         race_status = ReadShort();
1095                         if(race_status_name)
1096                                 strunzone(race_status_name);
1097                         race_status_name = strzone(ReadString());
1098         }
1099 }
1100
1101 void Net_ReadSpawn()
1102 {
1103         zoomin_effect = 1;
1104         current_viewzoom = 0.6;
1105 }
1106
1107 void Net_TeamNagger()
1108 {
1109         teamnagger = 1;
1110 }
1111
1112 void Net_ReadPingPLReport()
1113 {
1114         float e, pi, pl, ml;
1115         e = ReadByte();
1116         pi = ReadShort();
1117         pl = ReadByte();
1118         ml = ReadByte();
1119         if not(playerslots[e])
1120                 return;
1121         playerslots[e].ping = pi;
1122         playerslots[e].ping_packetloss = pl / 255.0;
1123         playerslots[e].ping_movementloss = ml / 255.0;
1124 }
1125
1126 void Net_WeaponComplain() {
1127         complain_weapon = ReadByte();
1128
1129         if(complain_weapon_name)
1130                 strunzone(complain_weapon_name);
1131         complain_weapon_name = strzone(ReadString());
1132
1133         complain_weapon_type = ReadByte();
1134
1135         complain_weapon_time = time;
1136         weapontime = time; // ping the weapon panel
1137 }
1138
1139 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1140 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1141 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1142 float CSQC_Parse_TempEntity()
1143 {
1144         float bHandled;
1145                 bHandled  = true;
1146         // Acquire TE ID
1147         float nTEID;
1148                 nTEID = ReadByte();
1149
1150         if(autocvar_developer_csqcentities)
1151                 print(sprintf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID));
1152
1153                 // NOTE: Could just do return instead of break...
1154         switch(nTEID)
1155         {
1156                 case TE_CSQC_TARGET_MUSIC:
1157                         Net_TargetMusic();
1158                         bHandled = true;
1159                         break;
1160                 case TE_CSQC_PICTURE:
1161                         Net_MapVote_Picture();
1162                         bHandled = true;
1163                         break;
1164                 case TE_CSQC_RACE:
1165                         Net_ReadRace();
1166                         bHandled = true;
1167                         break;
1168                 case TE_CSQC_SPAWN:
1169                         Net_ReadSpawn();
1170                         bHandled = true;
1171                         break;
1172                 case TE_CSQC_ZCURVEPARTICLES:
1173                         Net_ReadZCurveParticles();
1174                         bHandled = true;
1175                         break;
1176                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1177                         Net_ReadNexgunBeamParticle();
1178                         bHandled = true;
1179                         break;
1180                 case TE_CSQC_TEAMNAGGER:
1181                         Net_TeamNagger();
1182                         bHandled = true;
1183                         break;
1184                 case TE_CSQC_LIGHTNINGARC:
1185                         Net_ReadLightningarc();
1186                         bHandled = true;
1187                         break;
1188                 case TE_CSQC_PINGPLREPORT:
1189                         Net_ReadPingPLReport();
1190                         bHandled = true;
1191                         break;
1192                 case TE_CSQC_ANNOUNCE:
1193                         Announcer_Play(ReadString());
1194                         bHandled = true;
1195                         break;
1196                 case TE_CSQC_KILLNOTIFY:
1197                         HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1198                         bHandled = true;
1199                         break;
1200                 case TE_CSQC_KILLCENTERPRINT:
1201                         HUD_KillCenterprint(ReadString(), ReadString(), ReadShort(), ReadByte());
1202                         bHandled = true;
1203                         break;
1204                 case TE_CSQC_CENTERPRINT_GENERIC:
1205                         float id;
1206                         string s;
1207                         id = ReadByte();
1208                         s = ReadString();
1209                         if (id != 0 && s != "")
1210                                 centerprint_generic(id, s, ReadByte(), ReadByte());
1211                         else
1212                                 centerprint_generic(id, s, 0, 0);
1213                         bHandled = true;
1214                         break;
1215                 case TE_CSQC_WEAPONCOMPLAIN:
1216                         Net_WeaponComplain();
1217                         bHandled = true;
1218                         break;
1219                 case TE_CSQC_VEHICLESETUP:
1220                         Net_VehicleSetup();
1221                         bHandled = true;
1222                         break;
1223                 case TE_CSQC_SVNOTICE:
1224                         cl_notice_read();
1225                         bHandled = true;
1226                         break;
1227                 case TE_CSQC_NOTIFICATION:
1228                         Read_Notification();
1229                         bHandled = true;
1230                         break;
1231                 default:
1232                         // No special logic for this temporary entity; return 0 so the engine can handle it
1233                         bHandled = false;
1234                         break;
1235         }
1236
1237         return bHandled;
1238 }
1239
1240 string getcommandkey(string text, string command)
1241 {
1242         string keys;
1243         float n, j, k, l = 0;
1244
1245         if (!autocvar_hud_showbinds)
1246                 return text;
1247
1248         keys = db_get(binddb, command);
1249         if (keys == "")
1250         {
1251                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1252                 for(j = 0; j < n; ++j)
1253                 {
1254                         k = stof(argv(j));
1255                         if(k != -1)
1256                         {
1257                                 if ("" == keys)
1258                                         keys = keynumtostring(k);
1259                                 else
1260                                         keys = strcat(keys, ", ", keynumtostring(k));
1261
1262                                 ++l;
1263                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit >= l) break;
1264                         }
1265
1266                 }
1267                 if (keys == "")
1268                         keys = "NO_KEY";
1269                 db_put(binddb, command, keys);
1270         }
1271
1272         if (keys == "NO_KEY") {
1273                 if (autocvar_hud_showbinds > 1)
1274                         return sprintf(_("%s (not bound)"), text);
1275                 else
1276                         return text;
1277         }
1278         else if (autocvar_hud_showbinds > 1)
1279                 return sprintf(_("%s (%s)"), text, keys);
1280         else
1281                 return keys;
1282 }