qcsrc/client/View.qc

   1 #define spider_rocket_icon "gfx/vehicles/rocket_ico.tga"
   2 #define spider_rocket_targ "gfx/vehicles/target.tga"
   3 #define SPIDER_CROSS "textures/spiderbot/cross.tga"
   4 #define rkt_size 32
   5 #define rld_size_x 256
   6 #define rld_size_y 16
   7
   8 void CSQC_WAKIZASHI_HUD();
   9
  10 entity porto;
  11 vector polyline[16];
  12 float trace_dphitcontents;
  13 float trace_networkentity;
  14 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
  15 float DPCONTENTS_SOLID = 1; // blocks player movement
  16 float DPCONTENTS_BODY = 32; // blocks player movement
  17 float DPCONTENTS_CORPSE = 64; // blocks player movement
  18 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
  19 void Porto_Draw()
  20 {
  21         vector p, dir, ang, q, nextdir;
  22         float idx, portal_number, portal1_idx;
  23
  24         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  25                 return;
  26         if(intermission == 1)
  27                 return;
  28         if(intermission == 2)
  29                 return;
  30         if (getstati(STAT_HEALTH) <= 0)
  31                 return;
  32
  33         dir = view_forward;
  34
  35         if(angles_held_status)
  36         {
  37                 makevectors(angles_held);
  38                 dir = v_forward;
  39         }
  40
  41         p = view_origin;
  42
  43         polyline[0] = p;
  44         idx = 1;
  45         portal_number = 0;
  46         nextdir = dir;
  47
  48         for(;;)
  49         {
  50                 dir = nextdir;
  51                 traceline(p, p + 65536 * dir, TRUE, porto);
  52                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  53                         return;
  54                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  55                 p = trace_endpos;
  56                 polyline[idx] = p;
  57                 ++idx;
  58                 if(idx >= 16)
  59                         return;
  60                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  61                         continue;
  62                 ++portal_number;
  63                 ang = vectoangles2(trace_plane_normal, dir);
  64                 ang_x = -ang_x;
  65                 makevectors(ang);
  66                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  67                         return;
  68                 if(portal_number == 1)
  69                         portal1_idx = idx;
  70                 if(portal_number >= 2)
  71                         break;
  72         }
  73
  74         while(idx >= 2)
  75         {
  76                 p = polyline[idx-2];
  77                 q = polyline[idx-1];
  78                 if(idx == 2)
  79                         p = p - view_up * 16;
  80                 if(idx-1 >= portal1_idx)
  81                 {
  82                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  83                 }
  84                 else
  85                 {
  86                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  87                 }
  88                 --idx;
  89         }
  90 }
  91
  92 /**
  93  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  94  *
  95  * TODO: Use a better solution where a common shared entitiy is used that contains
  96  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  97  * and STAT_FRAGLIMIT to be auto-sent)
  98  */
  99 void CheckForGamestartChange() {
 100         float startTime;
 101         startTime = getstatf(STAT_GAMESTARTTIME);
 102         if (previous_game_starttime != startTime) {
 103                 if ((time + 5.0) < startTime) {
 104                         //if connecting to server while restart was active don't always play prepareforbattle
 105                         sound(self, CHAN_VOICE, strcat("announcer/", cvar_string("cl_announcer"), "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
 106                 }
 107                 if (time < startTime) {
 108                         restartAnnouncer = spawn();
 109                         restartAnnouncer.think = restartAnnouncer_Think;
 110                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
 111                 }
 112         }
 113         previous_game_starttime = startTime;
 114 }
 115
 116 void Porto_Init()
 117 {
 118         porto = spawn();
 119         porto.classname = "porto";
 120         porto.draw = Porto_Draw;
 121         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 122 }
 123
 124 float drawtime;
 125 float avgspeed;
 126 vector GetCurrentFov(float fov)
 127 {
 128         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
 129
 130         zoomsensitivity = cvar("cl_zoomsensitivity");
 131         zoomfactor = cvar("cl_zoomfactor");
 132         if(zoomfactor < 1 || zoomfactor > 16)
 133                 zoomfactor = 2.5;
 134         zoomspeed = cvar("cl_zoomspeed");
 135         if(zoomspeed >= 0)
 136                 if(zoomspeed < 0.5 || zoomspeed > 16)
 137                         zoomspeed = 3.5;
 138
 139         zoomdir = button_zoom;
 140         if((getstati(STAT_ACTIVEWEAPON) == WEP_NEX && nex_scope) || (getstati(STAT_ACTIVEWEAPON) == WEP_CAMPINGRIFLE && campingrifle_scope)) // do NOT use switchweapon here
 141                 zoomdir += button_attack2;
 142         if(spectatee_status > 0 || isdemo())
 143         {
 144                 if(spectatorbutton_zoom)
 145                         zoomdir = 0 + !zoomdir;
 146                 // do not even THINK about removing this 0
 147                 // _I_ know what I am doing
 148                 // fteqcc does not
 149         }
 150
 151         if(zoomdir)
 152                 zoomin_effect = 0;
 153
 154         if(zoomin_effect || camera_active)
 155         {
 156                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 157         }
 158         else
 159         {
 160                 if(zoomspeed < 0) // instant zoom
 161                 {
 162                         if(zoomdir)
 163                                 current_viewzoom = 1 / zoomfactor;
 164                         else
 165                                 current_viewzoom = 1;
 166                 }
 167                 else
 168                 {
 169                         if(zoomdir)
 170                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 171                         else
 172                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 173                 }
 174         }
 175
 176         if(almost_equals(current_viewzoom, 1))
 177                 current_zoomfraction = 0;
 178         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 179                 current_zoomfraction = 1;
 180         else
 181                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 182
 183         if(zoomsensitivity < 1)
 184                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 185         else
 186                 setsensitivityscale(1);
 187
 188         velocityzoom = bound(0, drawframetime / max(0.000000001, cvar_or("cl_velocityzoomtime", 0.3)), 1);
 189         avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
 190         velocityzoom = exp(float2range11(avgspeed * -cvar_or("cl_velocityzoom", 0) / 1) * 1);
 191
 192         //print(ftos(avgspeed), " avgspeed, ", ftos(cvar_or("cl_velocityzoom", 0)), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
 193
 194         float frustumx, frustumy, fovx, fovy;
 195         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 196         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 197         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 198         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 199
 200         return '1 0 0' * fovx + '0 1 0' * fovy;
 201 }
 202
 203 // this function must match W_SetupShot!
 204 float zoomscript_caught;
 205
 206 vector wcross_origin;
 207 float wcross_scale_prev, wcross_alpha_prev;
 208 vector wcross_color_prev;
 209 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 210 vector wcross_color_goal_prev;
 211 float wcross_changedonetime;
 212
 213 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 214 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 215 float wcross_name_changestarttime, wcross_name_changedonetime;
 216 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 217 entity trueaim;
 218 entity trueaim_rifle;
 219
 220 #define SHOTTYPE_HITTEAM 1
 221 #define SHOTTYPE_HITOBSTRUCTION 2
 222 #define SHOTTYPE_HITWORLD 3
 223 #define SHOTTYPE_HITENEMY 4
 224
 225 void TrueAim_Init()
 226 {
 227         trueaim = spawn();
 228         trueaim.classname = "trueaim";
 229         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 230         trueaim_rifle = spawn();
 231         trueaim_rifle.classname = "trueaim_rifle";
 232         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 233 }
 234
 235 float EnemyHitCheck()
 236 {
 237         float t;
 238         wcross_origin = project_3d_to_2d(trace_endpos);
 239         wcross_origin_z = 0;
 240         if(trace_networkentity < 1)
 241                 return SHOTTYPE_HITWORLD;
 242         if(trace_networkentity > maxclients)
 243                 return SHOTTYPE_HITWORLD;
 244         t = GetPlayerColor(trace_networkentity - 1);
 245         if(teamplay)
 246                 if(t == myteam)
 247                         return SHOTTYPE_HITTEAM;
 248         if(t == COLOR_SPECTATOR)
 249                 return SHOTTYPE_HITWORLD;
 250         return SHOTTYPE_HITENEMY;
 251 }
 252
 253 float TrueAimCheck()
 254 {
 255         float nudge = 1; // added to traceline target and subtracted from result
 256         vector vecs, trueaimpoint, w_shotorg;
 257         vector mi, ma, dv;
 258         float shottype;
 259         entity ta;
 260         float mv;
 261
 262         mi = ma = '0 0 0';
 263         ta = trueaim;
 264         mv = MOVE_NOMONSTERS;
 265
 266         switch(activeweapon)
 267         {
 268                 case WEP_TUBA: // no aim
 269                 case WEP_PORTO: // shoots from eye
 270                 case WEP_HOOK: // no trueaim
 271                 case WEP_GRENADE_LAUNCHER: // toss curve
 272                         return SHOTTYPE_HITWORLD;
 273                 case WEP_NEX:
 274                 case WEP_MINSTANEX:
 275                         mv = MOVE_NORMAL;
 276                         break;
 277                 case WEP_CAMPINGRIFLE:
 278                         ta = trueaim_rifle;
 279                         mv = MOVE_NORMAL;
 280                         if(zoomscript_caught)
 281                         {
 282                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 283                                 return EnemyHitCheck();
 284                         }
 285                         break;
 286                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 287                         mi = '-3 -3 -3';
 288                         ma = '3 3 3';
 289                         break;
 290                 case WEP_FIREBALL: // projectile has a size!
 291                         mi = '-16 -16 -16';
 292                         ma = '16 16 16';
 293                         break;
 294                 case WEP_SEEKER: // projectile has a size!
 295                         mi = '-2 -2 -2';
 296                         ma = '2 2 2';
 297                         break;
 298                 case WEP_ELECTRO: // projectile has a size!
 299                         mi = '0 0 -3';
 300                         ma = '0 0 -3';
 301                         break;
 302         }
 303
 304         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 305
 306         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 307         trueaimpoint = trace_endpos;
 308
 309         if(vecs_x > 0)
 310                 vecs_y = -vecs_y;
 311         else
 312                 vecs = '0 0 0';
 313
 314         dv = view_right * vecs_y + view_up * vecs_z;
 315         w_shotorg = view_origin + dv;
 316
 317         // now move the vecs forward as much as requested if possible
 318         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 319         w_shotorg = trace_endpos - view_forward * nudge;
 320
 321         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 322         shottype = EnemyHitCheck();
 323         if(shottype != SHOTTYPE_HITWORLD)
 324                 return shottype;
 325
 326 #if 0
 327         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 328         // or rather, I know why, but see no fix
 329         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 330                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 331                 return SHOTTYPE_HITOBSTRUCTION;
 332 #endif
 333
 334         return SHOTTYPE_HITWORLD;
 335 }
 336
 337 void CSQC_common_hud(void);
 338
 339 void PostInit(void);
 340 void CSQC_Demo_Camera();
 341 float HUD_WouldDrawScoreboard ();
 342 float view_set;
 343 float camera_mode;
 344 float reticle_type;
 345 string NextFrameCommand;
 346 void CSQC_SPIDER_HUD();
 347 void CSQC_RAPTOR_HUD();
 348
 349 vector freeze_pmove_org, freeze_input_angles;
 350
 351 void CSQC_UpdateView(float w, float h)
 352 {
 353         entity e;
 354         float fov;
 355         float f, i, j;
 356         vector v, vo;
 357         vector vf_size, vf_min;
 358
 359         vf_size = R_SetView3fv(VF_SIZE);
 360         vf_min = R_SetView3fv(VF_MIN);
 361         vid_width = vf_size_x;
 362         vid_height = vf_size_y;
 363
 364         vector reticle_pos, reticle_size;
 365
 366         WaypointSprite_Load();
 367
 368         if(spectatee_status)
 369                 myteam = GetPlayerColor(spectatee_status - 1);
 370         else
 371                 myteam = GetPlayerColor(player_localentnum - 1);
 372
 373         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 374         vo = '0 0 1' * getstati(STAT_VIEWHEIGHT);
 375
 376         warpzone_fixview_origin = pmove_org + vo;
 377         warpzone_fixview_cl_viewangles = input_angles;
 378         warpzone_fixview_angles = view_angles;
 379         WarpZone_FixView();
 380         pmove_org = warpzone_fixview_origin - vo;
 381         input_angles = warpzone_fixview_cl_viewangles;
 382         view_angles = warpzone_fixview_angles;
 383
 384         if(cvar("cl_lockview") || autocvar__hud_configure)
 385         {
 386                 pmove_org = freeze_pmove_org;
 387                 input_angles = view_angles = freeze_input_angles;
 388                 R_SetView(VF_ORIGIN, pmove_org + vo);
 389                 R_SetView(VF_ANGLES, view_angles);
 390                 //R_SetView(VF_CL_VIEWANGLES, input_angles);
 391         }
 392         freeze_pmove_org = pmove_org;
 393         freeze_input_angles = input_angles;
 394
 395         // Render the Scene
 396         if(!intermission || !view_set)
 397         {
 398                 view_origin = pmove_org + vo;
 399                 view_angles = input_angles;
 400                 makevectors(view_angles);
 401                 view_forward = v_forward;
 402                 view_right = v_right;
 403                 view_up = v_up;
 404                 view_set = 1;
 405         }
 406
 407 #ifdef BLURTEST
 408         if(time > blurtest_time0 && time < blurtest_time1)
 409         {
 410                 float r, t;
 411
 412                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 413                 r = t * blurtest_radius;
 414                 f = 1 / pow(t, blurtest_power) - 1;
 415
 416                 cvar_set("r_glsl_postprocess", "1");
 417                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 418         }
 419         else
 420         {
 421                 cvar_set("r_glsl_postprocess", "0");
 422                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 423         }
 424 #endif
 425
 426         TargetMusic_Advance();
 427         Fog_Force();
 428
 429         drawframetime = max(0.000001, time - drawtime);
 430         drawtime = time;
 431
 432         // watch for gametype changes here...
 433         // in ParseStuffCMD the cmd isn't executed yet :/
 434         // might even be better to add the gametype to TE_CSQC_INIT...?
 435         if(!postinit)
 436                 PostInit();
 437
 438         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 439                 if(calledhooks & HOOK_START)
 440                 {
 441                         localcmd("\ncl_hook_gameend\n");
 442                         calledhooks |= HOOK_END;
 443                 }
 444
 445         CheckForGamestartChange();
 446         serverAnnouncer();
 447         maptimeAnnouncer();
 448         carrierAnnouncer();
 449
 450         fov = cvar("fov");
 451         if(button_zoom || fov <= 59.5)
 452         {
 453                 if(!zoomscript_caught)
 454                 {
 455                         localcmd("+button4\n");
 456                         zoomscript_caught = 1;
 457                         ignore_plus_zoom += 1;
 458                 }
 459         }
 460         else
 461         {
 462                 if(zoomscript_caught)
 463                 {
 464                         localcmd("-button4\n");
 465                         zoomscript_caught = 0;
 466                         ignore_minus_zoom += 1;
 467                 }
 468         }
 469
 470         hud_accuracy_hud = cvar_or("hud_accuracy_hud", 1);
 471         ColorTranslateMode = cvar("cl_stripcolorcodes");
 472         activeweapon = getstati(STAT_SWITCHWEAPON);
 473         f = cvar("teamplay");
 474         if(f != teamplay)
 475         {
 476                 teamplay = f;
 477                 HUD_InitScores();
 478         }
 479
 480         if(last_weapon != activeweapon) {
 481                 weapontime = time;
 482                 last_weapon = activeweapon;
 483
 484                 e = get_weaponinfo(activeweapon);
 485                 if(e.netname != "")
 486                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 487                 else
 488                         localcmd("\ncl_hook_activeweapon none\n");
 489         }
 490
 491         // ALWAYS Clear Current Scene First
 492         R_ClearScene();
 493
 494         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 495         R_SetView(VF_SIZE, vf_size);
 496         R_SetView(VF_MIN, vf_min);
 497
 498         // Assign Standard Viewflags
 499         // Draw the World (and sky)
 500         R_SetView(VF_DRAWWORLD, 1);
 501
 502         // Set the console size vars
 503         vid_conwidth = cvar("vid_conwidth");
 504         vid_conheight = cvar("vid_conheight");
 505         vid_pixelheight = cvar("vid_pixelheight");
 506
 507         R_SetView(VF_FOV, GetCurrentFov(fov));
 508
 509         // Camera for demo playback
 510         if(camera_active)
 511         {
 512                 if(cvar("camera_enable"))
 513                         CSQC_Demo_Camera();
 514                 else
 515                 {
 516                         cvar_set("chase_active", ftos(chase_active_backup));
 517                         cvar_set("cl_demo_mousegrab", "0");
 518                         camera_active = FALSE;
 519                 }
 520         }
 521 #ifdef CAMERATEST
 522         else if(cvar("camera_enable"))
 523 #else
 524         else if(cvar("camera_enable") && isdemo())
 525 #endif
 526         {
 527                 // Enable required Darkplaces cvars
 528                 chase_active_backup = cvar("chase_active");
 529                 cvar_set("chase_active", "2");
 530                 cvar_set("cl_demo_mousegrab", "1");
 531                 camera_active = TRUE;
 532                 camera_mode = FALSE;
 533         }
 534
 535         // Draw the Crosshair
 536         float scoreboard_active;
 537         scoreboard_active = HUD_WouldDrawScoreboard();
 538         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 539
 540         // Draw the Engine Status Bar (the default Quake HUD)
 541         R_SetView(VF_DRAWENGINEHUD, 0);
 542
 543         // fetch this one only once per frame
 544         hud_showbinds = cvar("hud_showbinds");
 545         hud_showbinds_limit = cvar("hud_showbinds_limit");
 546
 547         // Update the mouse position
 548         /*
 549            mousepos_x = vid_conwidth;
 550            mousepos_y = vid_conheight;
 551            mousepos = mousepos*0.5 + getmousepos();
 552          */
 553
 554         e = self;
 555         for(self = world; (self = nextent(self)); )
 556                 if(self.draw)
 557                         self.draw();
 558         self = e;
 559
 560         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 561         R_RenderScene();
 562
 563         // now switch to 2D drawing mode by calling a 2D drawing function
 564         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 565         // next R_RenderScene call
 566         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 567
 568         // Draw the aiming reticle for weapons that use it
 569         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 570         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 571         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 572         if(spectatee_status || getstati(STAT_HEALTH) <= 0)
 573                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 574         else if(button_zoom || zoomscript_caught)
 575                 reticle_type = 1; // normal zoom
 576         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_CAMPINGRIFLE && button_attack2)
 577                 reticle_type = 2; // nex zoom
 578
 579         if(cvar("cl_reticle_stretch"))
 580         {
 581                 reticle_size_x = vid_conwidth;
 582                 reticle_size_y = vid_conheight;
 583                 reticle_pos_x = 0;
 584                 reticle_pos_y = 0;
 585         }
 586         else
 587         {
 588                 reticle_size_x = max(vid_conwidth, vid_conheight);
 589                 reticle_size_y = max(vid_conwidth, vid_conheight);
 590                 reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 591                 reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 592         }
 593
 594         f = current_zoomfraction;
 595         if(zoomscript_caught)
 596                 f = 1;
 597         if(cvar("cl_reticle_item_normal"))
 598         {
 599                 precache_pic("gfx/reticle_normal");
 600                 if(reticle_type == 1 && f)
 601                         drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * cvar("cl_reticle_item_normal"), DRAWFLAG_NORMAL);
 602         }
 603         if(cvar("cl_reticle_item_nex"))
 604         {
 605                 precache_pic("gfx/reticle_nex");
 606                 if(reticle_type == 2 && f)
 607                         drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * cvar("cl_reticle_item_nex"), DRAWFLAG_NORMAL);
 608         }
 609
 610         // Draw the mouse cursor
 611         // NOTE: drawpic must happen after R_RenderScene for some reason
 612         //drawpic(getmousepos(), "gfx/cursor.tga", '11 14 0', '1 1 1', 1, 0);
 613         //drawstring('50 50', ftos(game), '10 10 0', '1 1 1', 1, 0);
 614         //self = edict_num(player_localnum);
 615         //drawstring('0 0', vtos(pmove_org), '8 8 0', '1 1 1', 1, 0);
 616         //drawstring('0 8', strcat("ORG: ", vtos(self.origin), " state: ", ftos(self.ctf_state), " HP: ", ftos(self.health)), '8 8 0', '1 1 1', 1, 0);
 617         // as long as the ctf part isn't in, this is useless
 618         if(menu_visible)
 619                 menu_show();
 620
 621         /*if(gametype == GAME_CTF)
 622           {
 623           ctf_view();
 624           } else */
 625
 626         // draw 2D entities
 627         e = self;
 628         for(self = world; (self = nextent(self)); )
 629                 if(self.draw2d)
 630                         self.draw2d();
 631         self = e;
 632
 633         float hud;
 634         hud = getstati(STAT_HUD);
 635         if(hud == HUD_SPIDERBOT)
 636         {
 637                 CSQC_SPIDER_HUD();
 638         }
 639         else if(hud == HUD_WAKIZASHI)
 640         CSQC_WAKIZASHI_HUD();
 641     else if(hud == HUD_RAPTOR)
 642         CSQC_RAPTOR_HUD();
 643         else
 644         {
 645                 if(cvar("r_letterbox") == 0)
 646                         if(cvar("viewsize") < 120)
 647                                 CSQC_common_hud();
 648
 649                 // crosshair goes VERY LAST
 650                 if(!scoreboard_active && !camera_active && intermission != 2) {
 651                         // TrueAim check
 652                         float shottype;
 653                         float bullets, ring_scale;
 654                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 655                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 656                         wcross_origin_z = 0;
 657                         if(cvar("crosshair_hittest"))
 658                         {
 659                                 vector wcross_oldorigin;
 660                                 wcross_oldorigin = wcross_origin;
 661                                 shottype = TrueAimCheck();
 662                                 if(shottype == SHOTTYPE_HITWORLD)
 663                                 {
 664                                         v = wcross_origin - wcross_oldorigin;
 665                                         v_x /= vid_conwidth;
 666                                         v_y /= vid_conheight;
 667                                         if(vlen(v) > 0.01)
 668                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
 669                                 }
 670                                 if(!cvar("crosshair_hittest_showimpact"))
 671                                         wcross_origin = wcross_oldorigin;
 672                         }
 673                         else
 674                                 shottype = SHOTTYPE_HITWORLD;
 675
 676                         string wcross_style;
 677                         wcross_style = cvar_string("crosshair");
 678
 679                         if (wcross_style != "0") {
 680                                 vector wcross_color, wcross_size;
 681                                 string wcross_wep, wcross_name;
 682                                 float wcross_alpha, wcross_scale, wcross_blur, wcross_resolution;
 683
 684                                 wcross_color_x = cvar("crosshair_color_red");
 685                                 wcross_color_y = cvar("crosshair_color_green");
 686                                 wcross_color_z = cvar("crosshair_color_blue");
 687                                 wcross_alpha = cvar("crosshair_color_alpha");
 688                                 wcross_resolution = cvar("crosshair_size");
 689                                 if (cvar("crosshair_per_weapon")) {
 690                                         e = get_weaponinfo(activeweapon);
 691                                         if (e && e.netname != "")
 692                                         {
 693                                                 wcross_wep = e.netname;
 694                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 695                                                 if(wcross_style == "")
 696                                                         wcross_style = e.netname;
 697
 698                                                 if(!cvar("crosshair_color_override"))
 699                                                 {
 700                                                         wcross_color_x = cvar(strcat("crosshair_", wcross_wep, "_color_red"));
 701                                                         wcross_color_y = cvar(strcat("crosshair_", wcross_wep, "_color_green"));
 702                                                         wcross_color_z = cvar(strcat("crosshair_", wcross_wep, "_color_blue"));
 703                                                 }
 704
 705                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_color_alpha"));
 706                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 707                                         }
 708                                 }
 709
 710                                 wcross_name = strcat("gfx/crosshair", wcross_style);
 711
 712                                 if(cvar("crosshair_effect_scalefade"))
 713                                 {
 714                                         wcross_scale = wcross_resolution;
 715                                         wcross_resolution = 1;
 716                                 }
 717                                 else
 718                                 {
 719                                         wcross_scale = 1;
 720                                 }
 721
 722                                 if(shottype == SHOTTYPE_HITENEMY)
 723                                         wcross_scale *= cvar("crosshair_hittest"); // is not queried if hittest is 0
 724                                 if(shottype == SHOTTYPE_HITTEAM)
 725                                         wcross_scale /= cvar("crosshair_hittest"); // is not queried if hittest is 0
 726
 727                                 f = cvar("crosshair_effect_speed");
 728                                 if(f < 0)
 729                                         f *= -2 * g_weaponswitchdelay;
 730                                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
 731                                 {
 732                                         wcross_changedonetime = time + f;
 733                                 }
 734                                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
 735                                 {
 736                                         wcross_name_changestarttime = time;
 737                                         wcross_name_changedonetime = time + f;
 738                                         if(wcross_name_goal_prev_prev)
 739                                                 strunzone(wcross_name_goal_prev_prev);
 740                                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
 741                                         wcross_name_goal_prev = strzone(wcross_name);
 742                                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
 743                                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
 744                                         wcross_resolution_goal_prev = wcross_resolution;
 745                                 }
 746
 747                                 wcross_scale_goal_prev = wcross_scale;
 748                                 wcross_alpha_goal_prev = wcross_alpha;
 749                                 wcross_color_goal_prev = wcross_color;
 750
 751                                 if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && cvar("crosshair_hittest_blur") && !cvar("chase_active")))
 752                                 {
 753                                         wcross_blur = 1;
 754                                         wcross_alpha *= 0.75;
 755                                 }
 756                                 else
 757                                         wcross_blur = 0;
 758                                 // *_prev is at time-frametime
 759                                 // * is at wcross_changedonetime+f
 760                                 // what do we have at time?
 761                                 if(time < wcross_changedonetime)
 762                                 {
 763                                         f = frametime / (wcross_changedonetime - time + frametime);
 764                                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
 765                                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
 766                                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
 767                                 }
 768
 769                                 wcross_scale_prev = wcross_scale;
 770                                 wcross_alpha_prev = wcross_alpha;
 771                                 wcross_color_prev = wcross_color;
 772
 773                                 wcross_scale *= 1 - cvar("_menu_alpha");
 774                                 wcross_alpha *= 1 - cvar("_menu_alpha");
 775
 776                                 // ring around crosshair representing bullets left in camping rifle clip
 777                                 if (activeweapon == WEP_CAMPINGRIFLE)
 778                                 {
 779                                         ring_scale = cvar("crosshair_campingrifle_ring_size");
 780                                         bullets = bound(0, getstati(STAT_BULLETS_LOADED), 4);
 781                                 }
 782                                 else
 783                                         bullets = 0;
 784
 785 #define CROSSHAIR_DRAW_RING(i,j,sz,wcross_name,wcross_alpha) \
 786                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x * ring_scale + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y * ring_scale + j * wcross_blur)), strcat("gfx/rifle_ring_", ftos(bullets)), sz * wcross_size * ring_scale, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
 787
 788 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
 789                                 do \
 790                                 { \
 791                                         if(wcross_blur > 0) \
 792                                         { \
 793                                                 for(i = -2; i <= 2; ++i) \
 794                                                         for(j = -2; j <= 2; ++j) \
 795                                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
 796                                         } \
 797                                         else \
 798                                         { \
 799                                                 M(0,0,sz,wcross_name,wcross_alpha); \
 800                                         } \
 801                                 } \
 802                                 while(0)
 803
 804 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
 805                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
 806
 807 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
 808                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
 809
 810                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
 811                                 {
 812                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
 813                                         wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
 814                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
 815                                         f = 1 - f;
 816                                 }
 817                                 else
 818                                 {
 819                                         f = 1;
 820                                 }
 821
 822                                 wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
 823                                 if(bullets)
 824                                 {
 825                                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_RING, wcross_resolution, wcross_name, wcross_alpha);
 826                                 }
 827                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
 828                                 wcross_name_alpha_goal_prev = f;
 829                         }
 830                 }
 831                 else
 832                 {
 833                         wcross_scale_prev = 0;
 834                         wcross_alpha_prev = 0;
 835                         wcross_scale_goal_prev = 0;
 836                         wcross_alpha_goal_prev = 0;
 837                         wcross_changedonetime = 0;
 838                         if(wcross_name_goal_prev)
 839                                 strunzone(wcross_name_goal_prev);
 840                         wcross_name_goal_prev = string_null;
 841                         if(wcross_name_goal_prev_prev)
 842                                 strunzone(wcross_name_goal_prev_prev);
 843                         wcross_name_goal_prev_prev = string_null;
 844                         wcross_name_changestarttime = 0;
 845                         wcross_name_changedonetime = 0;
 846                         wcross_name_alpha_goal_prev = 0;
 847                         wcross_name_alpha_goal_prev_prev = 0;
 848                         wcross_resolution_goal_prev = 0;
 849                         wcross_resolution_goal_prev_prev = 0;
 850                 }
 851         }
 852
 853         if(NextFrameCommand)
 854         {
 855                 localcmd("\n", NextFrameCommand, "\n");
 856                 NextFrameCommand = string_null;
 857         }
 858
 859         // we must do this check AFTER a frame was rendered, or it won't work
 860         if(cs_project_is_b0rked == 0)
 861         {
 862                 string w0, h0;
 863                 w0 = cvar_string("vid_conwidth");
 864                 h0 = cvar_string("vid_conheight");
 865                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
 866                 //R_SetView(VF_FOV, '90 90 0');
 867                 R_SetView(VF_ORIGIN, '0 0 0');
 868                 R_SetView(VF_ANGLES, '0 0 0');
 869                 R_SetView(VF_PERSPECTIVE, 1);
 870                 makevectors('0 0 0');
 871                 vector v1, v2;
 872                 cvar_set("vid_conwidth", "800");
 873                 cvar_set("vid_conheight", "600");
 874                 v1 = cs_project(v_forward);
 875                 cvar_set("vid_conwidth", "640");
 876                 cvar_set("vid_conheight", "480");
 877                 v2 = cs_project(v_forward);
 878                 if(v1 == v2)
 879                         cs_project_is_b0rked = 1;
 880                 else
 881                         cs_project_is_b0rked = -1;
 882                 cvar_set("vid_conwidth", w0);
 883                 cvar_set("vid_conheight", h0);
 884         }
 885
 886         if(autocvar__hud_configure)
 887                 HUD_Panel_Mouse();
 888         // be safe against triggerbots until everyone has the fixed engine
 889         // this call is meant to overwrite the trace globals by something
 890         // unsuspicious
 891         traceline('0 0 0', '0 0 0', MOVE_WORLDONLY, world);
 892 }
 893
 894 #define spider_h "gfx/vehicles/hud_bg.tga"
 895 #define spider_b "gfx/vehicles/sbot.tga"
 896 #define spider_r "gfx/vehicles/sbot_rpods.tga"
 897 #define spider_g "gfx/vehicles/sbot_mguns.tga"
 898 #define spider_s "gfx/vehicles/shiled.tga"
 899 #define spider_a1 "gfx/hud/sb_rocket.tga"
 900 #define spider_a2 "gfx/sb_bullets.tga"
 901
 902 void CSQC_SPIDER_HUD()
 903 {
 904         float rockets, reload, heat, hp, shield;
 905         vector picsize, hudloc;
 906
 907     // Fetch health & ammo stats
 908     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
 909         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
 910         heat    = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 2);
 911         rockets =     getstati(STAT_VEHICLESTAT_AMMO2);
 912         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD2), 1);
 913
 914     // Draw the crosshairs
 915     picsize = drawgetimagesize(SPIDER_CROSS);
 916     picsize_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
 917     picsize_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
 918     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
 919
 920     hudloc_y =  4;
 921     hudloc_x = 4;
 922
 923     picsize = drawgetimagesize(spider_h) * 0.5;
 924     drawpic(hudloc, spider_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
 925
 926     picsize = drawgetimagesize(spider_a2) * 0.5;
 927     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
 928
 929     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
 930     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
 931     drawstring(hudloc + '136 102  0', strcat(ftos(100 - rint(heat * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
 932
 933     picsize = drawgetimagesize(spider_a1) * 0.85;
 934     if(rockets == 9)
 935     {
 936         drawpic(hudloc + '132 54  0', spider_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
 937         drawstring(hudloc + '179 69 0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
 938     }
 939     else
 940     {
 941         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
 942         drawstring(hudloc + '179 69  0', strcat(ftos(9 - rockets), "/8"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
 943     }
 944
 945     picsize = drawgetimagesize(spider_b) * 0.5;
 946     hudloc_y = 10.5;
 947     hudloc_x = 10.5;
 948
 949     drawpic(hudloc, spider_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
 950     drawpic(hudloc, spider_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
 951     drawpic(hudloc, spider_r, picsize, '1 1 1' * reload + '1 0 0' * (1 - reload), 1, DRAWFLAG_NORMAL);
 952     drawpic(hudloc, spider_g, picsize, '1 1 1' * (1 - heat) + '1 0 0' *  heat, 1, DRAWFLAG_NORMAL);
 953
 954
 955         /*
 956         // Draw health bar
 957         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
 958         p = p + '0 1 0' * vid_conheight - '0 32 0';
 959         //pp = ('0 1 0' * hp) + ('1 0 0' * (1-hp));
 960         drawfill(p, '256 0 0' * shield + '0 8 0' , '0.5 0.5 1', 0.75, DRAWFLAG_NORMAL);
 961         p_y += 8;
 962         drawfill(p, '256 0 0' * hp + '0 8 0' , '0 1 0', 0.75, DRAWFLAG_NORMAL);
 963         p_x += 256 * hp;
 964         drawfill(p, '256 0 0' * (1-hp) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
 965
 966         // Draw minigun heat indicator
 967         p = '0.5 0 0' * (vid_conwidth - 256);
 968         p = p + '0 1 0' * vid_conheight - '0 34  0';
 969         drawfill(p, '256 0 0' * (1-heat) + '0 2 0' ,'0 0 1', 0.5, DRAWFLAG_NORMAL);
 970         p_x += 256 * (1-heat);
 971         drawfill(p, '256 0 0' * heat  + '0 2 0' , '1 0 0', 0.5, DRAWFLAG_NORMAL);
 972
 973
 974         // Draw rocket icons for loaded/empty tubes.
 975         pp = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
 976         pp += '0 1 0' * vid_conheight - '0 64 0';
 977         for(i = 0; i < 8; ++i)
 978         {
 979                 p = pp + '1 0 0' * (rkt_size * i);
 980                 if(rockets == 8)
 981                 {
 982                         if(floor(reload * 8) == i)
 983                         {
 984                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 0 0' + '0 1 0' * ((reload*8)-i), 0.75 , DRAWFLAG_NORMAL);
 985                         }
 986                         else if(i < reload * 8)
 987                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 1 0', 0.75 , DRAWFLAG_NORMAL);
 988                         else
 989                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0.5 0.5 0.5', 0.75, DRAWFLAG_NORMAL);
 990                 }
 991                 else
 992                 {
 993                         if(i < rockets)
 994                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 0 0', 0.25, DRAWFLAG_NORMAL);
 995                         else
 996                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 1 0' * reload, 0.75, DRAWFLAG_NORMAL);
 997                 }
 998         }
 999         */
1000
1001         if (scoreboard_showscores)
1002         {
1003                 HUD_DrawScoreboard();
1004                 HUD_DrawCenterPrint();
1005         }
1006
1007 }
1008
1009 #define raptor_h "gfx/vehicles/hud_bg.tga"
1010 #define raptor_b "gfx/vehicles/raptor.tga"
1011 #define raptor_g1 "gfx/vehicles/raptor_guns.tga"
1012 #define raptor_g2 "gfx/vehicles/raptor_bombs.tga"
1013 #define raptor_s "gfx/vehicles/shiled.tga"
1014
1015 void CSQC_RAPTOR_HUD()
1016 {
1017         float rockets, reload, heat, hp, shield, energy;
1018         vector picsize, hudloc;
1019
1020     // Fetch health & ammo stats
1021     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1022         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1023         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1024         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1025
1026     // Draw the crosshairs
1027     picsize = drawgetimagesize(SPIDER_CROSS);
1028     picsize_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1029     picsize_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1030     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
1031
1032     hudloc_y =  4;
1033     hudloc_x = 4;
1034
1035     picsize = drawgetimagesize(raptor_h) * 0.5;
1036     drawpic(hudloc, raptor_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1037
1038     picsize = drawgetimagesize(spider_a2) * 0.5;
1039     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1040
1041     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1042     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1043     drawstring(hudloc + '136 102 0', strcat(ftos(rint(energy * 100)), "%"),'15 15 0','0.5 0.5 1', 1, DRAWFLAG_NORMAL);
1044
1045
1046     picsize = drawgetimagesize(spider_a1) * 0.85;
1047     if(reload == 1)
1048     {
1049         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1050         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 1 0', 0.5, DRAWFLAG_NORMAL);
1051     }
1052     else
1053     {
1054         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1055         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 0 1', 1, DRAWFLAG_NORMAL);
1056     }
1057
1058     picsize = drawgetimagesize(raptor_b) * 0.5;
1059     hudloc_y = 10.5;
1060     hudloc_x = 10.5;
1061
1062     drawpic(hudloc, raptor_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1063     drawpic(hudloc, raptor_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1064     drawpic(hudloc, raptor_g1, picsize, '1 1 1' * energy + '1 0 0' * (1 - energy), 1, DRAWFLAG_NORMAL);
1065     drawpic(hudloc, raptor_g2, picsize, '1 1 1' * reload + '1 0 0' *  (1 - reload), 1, DRAWFLAG_NORMAL);
1066
1067
1068         if (scoreboard_showscores)
1069         {
1070                 HUD_DrawScoreboard();
1071                 HUD_DrawCenterPrint();
1072         }
1073
1074 }
1075
1076 #define waki_h "gfx/vehicles/hud_bg.tga"
1077 #define waki_b "gfx/vehicles/waki.tga"
1078 #define waki_e "gfx/vehicles/waki_e.tga"
1079 #define waki_g "gfx/vehicles/waki_guns.tga"
1080 #define waki_r "gfx/vehicles/waki_rockets.tga"
1081 #define waki_s "gfx/vehicles/shiled.tga"
1082
1083 #define waki_a1 "gfx/hud/sb_rocket.tga"
1084 #define waki_a2 "gfx/sb_cells.tga"
1085
1086 void CSQC_WAKIZASHI_HUD()
1087 {
1088         // 0--1 floats. 1 = 100%, 0.6 = 50%.
1089         float health, shield, energy, rockets;
1090         vector picsize, hudloc;
1091
1092     picsize = drawgetimagesize(SPIDER_CROSS);
1093     picsize_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1094     picsize_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1095     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
1096
1097 /*
1098 const float STAT_VEHICLESTAT_HEALTH  = 60;
1099 const float STAT_VEHICLESTAT_SHIELD  = 61;
1100 const float STAT_VEHICLESTAT_ENERGY  = 62;
1101 const float STAT_VEHICLESTAT_AMMO1   = 63;
1102 const float STAT_VEHICLESTAT_RELAOD1 = 64;
1103 const float STAT_VEHICLESTAT_AMMO2   = 65;
1104 const float STAT_VEHICLESTAT_RELOAD2 = 66;
1105 */
1106     health  = min(getstatf(STAT_VEHICLESTAT_HEALTH),  1);
1107         shield  = min(getstatf(STAT_VEHICLESTAT_SHIELD),  1);
1108         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1109         rockets = bound(0,getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1110
1111     hudloc_y =  4;
1112     hudloc_x = 4;
1113
1114     picsize = drawgetimagesize(waki_h) * 0.5;
1115     drawpic(hudloc, waki_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1116
1117     picsize = drawgetimagesize(waki_a2) * 0.7;
1118     drawpic(hudloc + '116 92  0', waki_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1119
1120
1121     drawstring(hudloc + '145 19  0', strcat(ftos(rint(health * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1122     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1123
1124     drawstring(hudloc + '136 102  0', strcat(ftos(rint(energy * 100)), "%"),'14 14 0','1 1 1', 1, DRAWFLAG_NORMAL);
1125
1126     picsize = drawgetimagesize(waki_a1) * 0.75;
1127     if(rockets == 1)
1128     {
1129         drawpic(hudloc + '140 55  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1130         drawpic(hudloc + '144 59  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1131     }
1132     else
1133     {
1134         drawpic(hudloc + '140 55  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1135         drawpic(hudloc + '144 59  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1136         drawstring(hudloc + '165 69 0', strcat(ftos(rint(rockets * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1137     }
1138
1139     picsize = drawgetimagesize(waki_b) * 0.5;
1140     hudloc_y = 10.5;
1141     hudloc_x = 10.5;
1142
1143     drawpic(hudloc, waki_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1144     drawpic(hudloc, waki_b, picsize, '0 1 0' * health + '1 0 0' * (1 - health), 1, DRAWFLAG_NORMAL);
1145     drawpic(hudloc, waki_r, picsize, '1 1 1' * rockets + '1 0 0' * (1 - rockets), 1, DRAWFLAG_NORMAL);
1146     drawpic(hudloc, waki_e, picsize, '1 1 1' * energy + '1 0 0' *  (1 - energy), 1, DRAWFLAG_NORMAL);
1147
1148
1149
1150         /*
1151         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1152         p = p + '0 1 0' * vid_conheight - '0 32 0';
1153
1154         // Draw health bar
1155         p_y += 8;
1156         drawfill(p, '256 0 0' * health + '0 8 0' , '0 0.7 0', 0.75, DRAWFLAG_NORMAL);
1157         p_x += 256 * health;
1158         drawfill(p, '256 0 0' * (1 - health) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1159
1160         // Draw shiled bar
1161         p_x -= 256 * health;
1162         p_y += 4;
1163         drawfill(p, '256 0 0' * shield + '0 4 0' , '0.25 0.25 1', 0.5, DRAWFLAG_NORMAL);
1164
1165         // Draw energy
1166         //p_x -= 256 * health;
1167         p_y -= 8;
1168         drawfill(p, '256 0 0' * energy + '0 4 0' , '1 1 1', 0.75, DRAWFLAG_NORMAL);
1169
1170         // Draw rockets bar
1171         p_y += 12;
1172         drawfill(p, '256 0 0' * rockets + '0 4 0' , '1 0 0', 0.75, DRAWFLAG_NORMAL);
1173         */
1174
1175
1176
1177
1178         if (scoreboard_showscores)
1179         {
1180                 HUD_DrawScoreboard();
1181                 HUD_DrawCenterPrint();
1182         }
1183
1184 }
1185
1186
1187 void CSQC_common_hud(void)
1188 {
1189         // HUD_SortFrags(); done in HUD_Draw
1190         float hud;
1191         hud = getstati(STAT_HUD);
1192
1193         //hud = 10;
1194         switch(hud)
1195         {
1196                 case HUD_NORMAL:
1197                         // do some accuracy var caching
1198                         float i;
1199                         if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1200                         {
1201                                 acc_levels = tokenize(cvar_string("hud_panel_weapons_accuracy_color_levels"));
1202                                 if (acc_levels > MAX_ACCURACY_LEVELS)
1203                                         acc_levels = MAX_ACCURACY_LEVELS;
1204
1205                                 for (i = 0; i < acc_levels; ++i)
1206                                         acc_lev[i] = stof(argv(i));
1207                         }
1208
1209                         HUD_Main(); // always run these functions for alpha checks
1210                         HUD_DrawScoreboard();
1211
1212                         if (scoreboard_showscores || scoreboard_showscores_force || getstati(STAT_HEALTH) <= 0 || intermission == 1) // scoreboard/accuracy
1213                         {
1214                                 HUD_Reset();
1215                                 // HUD_DrawScoreboard takes care of centerprint_start
1216                         }
1217                         else if (intermission == 2) // map voting screen
1218                         {
1219                                 HUD_FinaleOverlay();
1220                                 HUD_Reset();
1221
1222                                 centerprint_start_x = 0;
1223                                 centerprint_start_y = cvar("scr_centerpos") * vid_conheight;
1224                         }
1225                         else // hud
1226                         {
1227                                 centerprint_start_x = 0;
1228                                 centerprint_start_y = cvar("scr_centerpos") * vid_conheight;
1229                         }
1230
1231                         HUD_DrawCenterPrint();
1232                         break;
1233
1234                 case HUD_SPIDERBOT:
1235                         CSQC_SPIDER_HUD();
1236                         break;
1237
1238                 case HUD_WAKIZASHI:
1239                         CSQC_WAKIZASHI_HUD();
1240                         break;
1241         }
1242 }
1243
1244
1245 // following vectors must be global to allow seamless switching between camera modes
1246 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1247 void CSQC_Demo_Camera()
1248 {
1249         float speed, attenuation, dimensions;
1250         vector tmp, delta;
1251
1252         if( cvar("camera_reset") || !camera_mode )
1253         {
1254                 camera_offset = '0 0 0';
1255                 current_angles = '0 0 0';
1256                 camera_direction = '0 0 0';
1257                 camera_offset_z += 30;
1258                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1259                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1260                 current_origin = view_origin;
1261                 current_camera_offset  = camera_offset;
1262                 cvar_set("camera_reset", "0");
1263                 camera_mode = CAMERA_CHASE;
1264         }
1265
1266         // Camera angles
1267         if( camera_roll )
1268                 mouse_angles_z += camera_roll * cvar("camera_speed_roll");
1269
1270         if(cvar("camera_look_player"))
1271         {
1272                 local vector dir;
1273                 local float n;
1274
1275                 dir = normalize(view_origin - current_position);
1276                 n = mouse_angles_z;
1277                 mouse_angles = vectoangles(dir);
1278                 mouse_angles_x = mouse_angles_x * -1;
1279                 mouse_angles_z = n;
1280         }
1281         else
1282         {
1283                 tmp = getmousepos() * 0.1;
1284                 if(vlen(tmp)>cvar("camera_mouse_treshold"))
1285                 {
1286                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1287                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1288                 }
1289         }
1290
1291         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1292         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1293         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1294         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1295
1296         // Fix difference when angles don't have the same sign
1297         delta = '0 0 0';
1298         if(mouse_angles_y < -60 && current_angles_y > 60)
1299                 delta = '0 360 0';
1300         if(mouse_angles_y > 60 && current_angles_y < -60)
1301                 delta = '0 -360 0';
1302
1303         if(cvar("camera_look_player"))
1304                 attenuation = cvar("camera_look_attenuation");
1305         else
1306                 attenuation = cvar("camera_speed_attenuation");
1307
1308         attenuation = 1 / max(1, attenuation);
1309         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1310
1311         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1312         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1313         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1314         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1315
1316         // Camera position
1317         tmp = '0 0 0';
1318         dimensions = 0;
1319
1320         if( camera_direction_x )
1321         {
1322                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1323                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1324                 if( cvar("camera_forward_follows") && !cvar("camera_look_player") )
1325                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1326                 ++dimensions;
1327         }
1328
1329         if( camera_direction_y )
1330         {
1331                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1332                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1333                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1334                 ++dimensions;
1335         }
1336
1337         if( camera_direction_z )
1338         {
1339                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1340                 ++dimensions;
1341         }
1342
1343         if(cvar("camera_free"))
1344                 speed = cvar("camera_speed_free");
1345         else
1346                 speed = cvar("camera_speed_chase");
1347
1348         if(dimensions)
1349         {
1350                 speed = speed * sqrt(1 / dimensions);
1351                 camera_offset += tmp * speed;
1352         }
1353
1354         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1355
1356         // Camera modes
1357         if( cvar("camera_free") )
1358         {
1359                 if ( camera_mode == CAMERA_CHASE )
1360                 {
1361                         current_camera_offset = current_origin + current_camera_offset;
1362                         camera_offset = current_origin + camera_offset;
1363                 }
1364
1365                 camera_mode = CAMERA_FREE;
1366                 current_position = current_camera_offset;
1367         }
1368         else
1369         {
1370                 if ( camera_mode == CAMERA_FREE )
1371                 {
1372                         current_origin = view_origin;
1373                         camera_offset = camera_offset - current_origin;
1374                         current_camera_offset = current_camera_offset - current_origin;
1375                 }
1376
1377                 camera_mode = CAMERA_CHASE;
1378
1379                 if(cvar("camera_chase_smoothly"))
1380                         current_origin += (view_origin - current_origin) * attenuation;
1381                 else
1382                         current_origin = view_origin;
1383
1384                 current_position = current_origin + current_camera_offset;
1385         }
1386
1387         R_SetView(VF_ANGLES, current_angles);
1388         R_SetView(VF_ORIGIN, current_position);
1389 }