qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 void Porto_Draw()
   4 {
   5         vector p, dir, ang, q, nextdir;
   6         float idx, portal_number, portal1_idx;
   7
   8         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
   9                 return;
  10         if(g_balance_porto_secondary)
  11                 return;
  12         if(intermission == 1)
  13                 return;
  14         if(intermission == 2)
  15                 return;
  16         if (getstati(STAT_HEALTH) <= 0)
  17                 return;
  18
  19         dir = view_forward;
  20
  21         if(angles_held_status)
  22         {
  23                 makevectors(angles_held);
  24                 dir = v_forward;
  25         }
  26
  27         p = view_origin;
  28
  29         polyline[0] = p;
  30         idx = 1;
  31         portal_number = 0;
  32         nextdir = dir;
  33
  34         for(;;)
  35         {
  36                 dir = nextdir;
  37                 traceline(p, p + 65536 * dir, TRUE, porto);
  38                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  39                         return;
  40                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  41                 p = trace_endpos;
  42                 polyline[idx] = p;
  43                 ++idx;
  44                 if(idx >= 16)
  45                         return;
  46                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  47                         continue;
  48                 ++portal_number;
  49                 ang = vectoangles2(trace_plane_normal, dir);
  50                 ang_x = -ang_x;
  51                 makevectors(ang);
  52                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  53                         return;
  54                 if(portal_number == 1)
  55                 {
  56                         portal1_idx = idx;
  57                         if(portal_number >= 2)
  58                                 break;
  59                 }
  60         }
  61
  62         while(idx >= 2)
  63         {
  64                 p = polyline[idx-2];
  65                 q = polyline[idx-1];
  66                 if(idx == 2)
  67                         p = p - view_up * 16;
  68                 if(idx-1 >= portal1_idx)
  69                 {
  70                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  71                 }
  72                 else
  73                 {
  74                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  75                 }
  76                 --idx;
  77         }
  78 }
  79
  80 void Porto_Init()
  81 {
  82         porto = spawn();
  83         porto.classname = "porto";
  84         porto.draw = Porto_Draw;
  85         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
  86 }
  87
  88 float drawtime;
  89 float avgspeed;
  90 vector GetCurrentFov(float fov)
  91 {
  92         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
  93         float velocityzoom, curspeed;
  94         vector v;
  95
  96         zoomsensitivity = autocvar_cl_zoomsensitivity;
  97         zoomfactor = autocvar_cl_zoomfactor;
  98         if(zoomfactor < 1 || zoomfactor > 16)
  99                 zoomfactor = 2.5;
 100         zoomspeed = autocvar_cl_zoomspeed;
 101         if(zoomspeed >= 0)
 102         if(zoomspeed < 0.5 || zoomspeed > 16)
 103                         zoomspeed = 3.5;
 104
 105         zoomdir = button_zoom;
 106         if(hud == HUD_NORMAL)
 107         if((activeweapon == WEP_NEX && nex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 108                 zoomdir += button_attack2;
 109         if(spectatee_status > 0 || isdemo())
 110         {
 111                 if(spectatorbutton_zoom)
 112                 {
 113                         if(zoomdir)
 114                                 zoomdir = 0;
 115                         else
 116                                 zoomdir = 1;
 117                 }
 118                 // fteqcc failed twice here already, don't optimize this
 119         }
 120
 121         if(zoomdir) { zoomin_effect = 0; }
 122
 123         if(camera_active)
 124         {
 125                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 126         }
 127         else if(autocvar_cl_spawnzoom && zoomin_effect)
 128         {
 129                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 16);
 130
 131                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 132                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 133                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 134         }
 135         else
 136         {
 137                 if(zoomspeed < 0) // instant zoom
 138                 {
 139                         if(zoomdir)
 140                                 current_viewzoom = 1 / zoomfactor;
 141                         else
 142                                 current_viewzoom = 1;
 143                 }
 144                 else
 145                 {
 146                         if(zoomdir)
 147                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 148                         else
 149                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 150                 }
 151         }
 152
 153         if(almost_equals(current_viewzoom, 1))
 154                 current_zoomfraction = 0;
 155         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 156                 current_zoomfraction = 1;
 157         else
 158                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 159
 160         if(zoomsensitivity < 1)
 161                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 162         else
 163                 setsensitivityscale(1);
 164
 165         makevectors(view_angles);
 166
 167         if(autocvar_cl_velocityzoom && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 168         {
 169                 if(intermission) { curspeed = 0; }
 170                 else
 171                 {
 172                         v = pmove_vel;
 173                         if(csqcplayer)
 174                                 v = csqcplayer.velocity;
 175
 176                         switch(autocvar_cl_velocityzoom_type)
 177                         {
 178                                 case 3: curspeed = max(0, v_forward * v); break;
 179                                 case 2: curspeed = (v_forward * v); break;
 180                                 case 1: default: curspeed = vlen(v); break;
 181                         }
 182                 }
 183
 184                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 185                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 186                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 187
 188                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 189         }
 190         else
 191                 velocityzoom = 1;
 192
 193         float frustumx, frustumy, fovx, fovy;
 194         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 195         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 196         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 197         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 198
 199         return '1 0 0' * fovx + '0 1 0' * fovy;
 200 }
 201
 202 // this function must match W_SetupShot!
 203 float zoomscript_caught;
 204
 205 vector wcross_origin;
 206 float wcross_scale_prev, wcross_alpha_prev;
 207 vector wcross_color_prev;
 208 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 209 vector wcross_color_goal_prev;
 210 float wcross_changedonetime;
 211
 212 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 213 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 214 float wcross_name_changestarttime, wcross_name_changedonetime;
 215 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 216
 217 float wcross_ring_prev;
 218
 219 entity trueaim;
 220 entity trueaim_rifle;
 221
 222 #define SHOTTYPE_HITTEAM 1
 223 #define SHOTTYPE_HITOBSTRUCTION 2
 224 #define SHOTTYPE_HITWORLD 3
 225 #define SHOTTYPE_HITENEMY 4
 226
 227 void TrueAim_Init()
 228 {
 229         trueaim = spawn();
 230         trueaim.classname = "trueaim";
 231         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 232         trueaim_rifle = spawn();
 233         trueaim_rifle.classname = "trueaim_rifle";
 234         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 235 }
 236
 237 float EnemyHitCheck()
 238 {
 239         float t, n;
 240         wcross_origin = project_3d_to_2d(trace_endpos);
 241         wcross_origin_z = 0;
 242         if(trace_ent)
 243                 n = trace_ent.entnum;
 244         else
 245                 n = trace_networkentity;
 246         if(n < 1)
 247                 return SHOTTYPE_HITWORLD;
 248         if(n > maxclients)
 249                 return SHOTTYPE_HITWORLD;
 250         t = GetPlayerColor(n - 1);
 251         if(teamplay)
 252                 if(t == myteam)
 253                         return SHOTTYPE_HITTEAM;
 254         if(t == NUM_SPECTATOR)
 255                 return SHOTTYPE_HITWORLD;
 256         return SHOTTYPE_HITENEMY;
 257 }
 258
 259 float TrueAimCheck()
 260 {
 261         float nudge = 1; // added to traceline target and subtracted from result
 262         vector vecs, trueaimpoint, w_shotorg;
 263         vector mi, ma, dv;
 264         float shottype;
 265         entity ta;
 266         float mv;
 267
 268         mi = ma = '0 0 0';
 269         ta = trueaim;
 270         mv = MOVE_NOMONSTERS;
 271
 272         switch(activeweapon)
 273         {
 274                 case WEP_TUBA: // no aim
 275                 case WEP_PORTO: // shoots from eye
 276                 case WEP_HOOK: // no trueaim
 277                 case WEP_GRENADE_LAUNCHER: // toss curve
 278                         return SHOTTYPE_HITWORLD;
 279                 case WEP_NEX:
 280                 case WEP_MINSTANEX:
 281                         mv = MOVE_NORMAL;
 282                         break;
 283                 case WEP_RIFLE:
 284                         ta = trueaim_rifle;
 285                         mv = MOVE_NORMAL;
 286                         if(zoomscript_caught)
 287                         {
 288                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 289                                 return EnemyHitCheck();
 290                         }
 291                         break;
 292                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 293                         mi = '-3 -3 -3';
 294                         ma = '3 3 3';
 295                         break;
 296                 case WEP_FIREBALL: // projectile has a size!
 297                         mi = '-16 -16 -16';
 298                         ma = '16 16 16';
 299                         break;
 300                 case WEP_SEEKER: // projectile has a size!
 301                         mi = '-2 -2 -2';
 302                         ma = '2 2 2';
 303                         break;
 304                 case WEP_ELECTRO: // projectile has a size!
 305                         mi = '0 0 -3';
 306                         ma = '0 0 -3';
 307                         break;
 308         }
 309
 310         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 311
 312         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 313         trueaimpoint = trace_endpos;
 314
 315         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 316                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 317
 318         if(vecs_x > 0)
 319                 vecs_y = -vecs_y;
 320         else
 321                 vecs = '0 0 0';
 322
 323         dv = view_right * vecs_y + view_up * vecs_z;
 324         w_shotorg = view_origin + dv;
 325
 326         // now move the vecs forward as much as requested if possible
 327         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 328         w_shotorg = trace_endpos - view_forward * nudge;
 329
 330         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 331         shottype = EnemyHitCheck();
 332         if(shottype != SHOTTYPE_HITWORLD)
 333                 return shottype;
 334
 335 #if 0
 336         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 337         // or rather, I know why, but see no fix
 338         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 339                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 340                 return SHOTTYPE_HITOBSTRUCTION;
 341 #endif
 342
 343         return SHOTTYPE_HITWORLD;
 344 }
 345
 346 void CSQC_common_hud(void);
 347
 348 void PostInit(void);
 349 void CSQC_Demo_Camera();
 350 float HUD_WouldDrawScoreboard();
 351 float camera_mode;
 352 const float CAMERA_FREE = 1;
 353 const float CAMERA_CHASE = 2;
 354 float reticle_type;
 355 string NextFrameCommand;
 356
 357 vector freeze_org, freeze_ang;
 358 entity nightvision_noise, nightvision_noise2;
 359
 360 #define MAX_TIME_DIFF 5
 361 float pickup_crosshair_time, pickup_crosshair_size;
 362 float hit_time, typehit_time;
 363 float nextsound_hit_time, nextsound_typehit_time;
 364 float hitindication_crosshair_time, hitindication_crosshair_size;
 365 float use_nex_chargepool;
 366
 367 float myhealth, myhealth_prev;
 368 float myhealth_flash;
 369
 370 float old_blurradius, old_bluralpha;
 371 float old_sharpen_intensity;
 372
 373 vector myhealth_gentlergb;
 374
 375 float contentavgalpha, liquidalpha_prev;
 376 vector liquidcolor_prev;
 377
 378 float eventchase_current_distance;
 379
 380 vector damage_blurpostprocess, content_blurpostprocess;
 381
 382 float checkfail[16];
 383
 384 float rainbow_last_flicker;
 385 vector rainbow_prev_color;
 386
 387 #define BUTTON_3 4
 388 #define BUTTON_4 8
 389 float cl_notice_run();
 390 float prev_myteam;
 391 void CSQC_UpdateView(float w, float h)
 392 {
 393         entity e;
 394         float fov;
 395         float f, i, j;
 396         vector v;
 397         vector vf_size, vf_min;
 398         float a;
 399
 400         execute_next_frame();
 401
 402         ++framecount;
 403
 404         hud = getstati(STAT_HUD);
 405
 406         if(autocvar__hud_showbinds_reload) // menu can set this one
 407         {
 408                 db_close(binddb);
 409                 binddb = db_create();
 410                 cvar_set("_hud_showbinds_reload", "0");
 411         }
 412
 413         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
 414                 view_quality = getproperty(VF_MINFPS_QUALITY);
 415         else
 416                 view_quality = 1;
 417
 418         button_attack2 = (input_buttons & BUTTON_3);
 419         button_zoom = (input_buttons & BUTTON_4);
 420
 421 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 422         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 423         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 424         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 425         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 426         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 427         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 428         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 429
 430         vf_size = getpropertyvec(VF_SIZE);
 431         vf_min = getpropertyvec(VF_MIN);
 432         vid_width = vf_size_x;
 433         vid_height = vf_size_y;
 434
 435         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
 436         vector splash_pos = '0 0 0', splash_size = '0 0 0';
 437
 438         WaypointSprite_Load();
 439
 440         CSQCPlayer_SetCamera();
 441
 442 #ifdef COMPAT_XON050_ENGINE
 443         if(spectatee_status)
 444                 myteam = GetPlayerColor(spectatee_status - 1);
 445         else
 446 #endif
 447                 myteam = GetPlayerColor(player_localentnum - 1);
 448
 449         if(myteam != prev_myteam)
 450         {
 451                 myteamcolors = colormapPaletteColor(myteam, 1);
 452                 for(i = 0; i < HUD_PANEL_NUM; ++i)
 453                         hud_panel[i].update_time = time;
 454                 prev_myteam = myteam;
 455         }
 456
 457         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 458
 459         float is_dead = (getstati(STAT_HEALTH) <= 0);
 460
 461         // FIXME do we need this hack?
 462         if(isdemo())
 463         {
 464                 // in demos, input_buttons do not work
 465                 button_zoom = (autocvar__togglezoom == "-");
 466         }
 467         else if(button_zoom
 468                 && autocvar_cl_unpress_zoom_on_death
 469                 && (spectatee_status >= 0)
 470                 && (is_dead || intermission))
 471         {
 472                 // no zoom while dead or in intermission please
 473                 localcmd("-zoom\n");
 474                 button_zoom = FALSE;
 475         }
 476
 477         // event chase camera
 478         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 479         {
 480                 if((spectatee_status >= 0 && (autocvar_cl_eventchase_death && is_dead)) || intermission)
 481                 {
 482                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 483                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
 484
 485                         // detect maximum viewoffset and use it
 486                         if(autocvar_cl_eventchase_viewoffset)
 487                         {
 488                                 WarpZone_TraceLine(current_view_origin, current_view_origin + autocvar_cl_eventchase_viewoffset + ('0 0 1' * autocvar_cl_eventchase_maxs_z), MOVE_WORLDONLY, self);
 489                                 if(trace_fraction == 1) { current_view_origin += autocvar_cl_eventchase_viewoffset; }
 490                                 else { current_view_origin_z += max(0, (trace_endpos_z - current_view_origin_z) - autocvar_cl_eventchase_maxs_z); }
 491                         }
 492
 493                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 494                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
 495                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 496                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
 497
 498                         // make the camera smooth back
 499                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 500                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 501                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 502                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 503
 504                         makevectors(view_angles);
 505
 506                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
 507                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
 508
 509                         // If the boxtrace fails, revert back to line tracing.
 510                         if(trace_startsolid)
 511                         {
 512                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
 513                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 514                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins_z)));
 515                         }
 516                         else { setproperty(VF_ORIGIN, trace_endpos); }
 517
 518                         setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 519                 }
 520                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 521                 {
 522                         cvar_set("chase_active", "0");
 523                         eventchase_current_distance = 0; // start from 0 next time
 524                 }
 525         }
 526         // workaround for camera stuck between player's legs when using chase_active 1
 527         // because the engine stops updating the chase_active camera when the game ends
 528         else if(intermission)
 529         {
 530                 cvar_settemp("chase_active", "-1");
 531                 eventchase_current_distance = 0;
 532         }
 533
 534         // do lockview after event chase camera so that it still applies whenever necessary.
 535         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1)))
 536         {
 537                 setproperty(VF_ORIGIN, freeze_org);
 538                 setproperty(VF_ANGLES, freeze_ang);
 539         }
 540         else
 541         {
 542                 freeze_org = getpropertyvec(VF_ORIGIN);
 543                 freeze_ang = getpropertyvec(VF_ANGLES);
 544         }
 545
 546         WarpZone_FixView();
 547         //WarpZone_FixPMove();
 548
 549         // Render the Scene
 550         view_origin = getpropertyvec(VF_ORIGIN);
 551         view_angles = getpropertyvec(VF_ANGLES);
 552         makevectors(view_angles);
 553         view_forward = v_forward;
 554         view_right = v_right;
 555         view_up = v_up;
 556
 557 #ifdef BLURTEST
 558         if(time > blurtest_time0 && time < blurtest_time1)
 559         {
 560                 float r, t;
 561
 562                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 563                 r = t * blurtest_radius;
 564                 f = 1 / pow(t, blurtest_power) - 1;
 565
 566                 cvar_set("r_glsl_postprocess", "1");
 567                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 568         }
 569         else
 570         {
 571                 cvar_set("r_glsl_postprocess", "0");
 572                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 573         }
 574 #endif
 575
 576         TargetMusic_Advance();
 577         Fog_Force();
 578
 579         if(drawtime == 0)
 580                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
 581         else
 582                 drawframetime = bound(0.000001, time - drawtime, 1);
 583         drawtime = time;
 584
 585         // watch for gametype changes here...
 586         // in ParseStuffCMD the cmd isn't executed yet :/
 587         // might even be better to add the gametype to TE_CSQC_INIT...?
 588         if(!postinit)
 589                 PostInit();
 590
 591         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 592         {
 593                 if(calledhooks & HOOK_START)
 594                 {
 595                         localcmd("\ncl_hook_gameend\n");
 596                         calledhooks |= HOOK_END;
 597                 }
 598         }
 599
 600         Announcer();
 601
 602         fov = autocvar_fov;
 603         if(fov <= 59.5)
 604         {
 605                 if(!zoomscript_caught)
 606                 {
 607                         localcmd("+button9\n");
 608                         zoomscript_caught = 1;
 609                 }
 610         }
 611         else
 612         {
 613                 if(zoomscript_caught)
 614                 {
 615                         localcmd("-button9\n");
 616                         zoomscript_caught = 0;
 617                 }
 618         }
 619
 620         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 621
 622         // next WANTED weapon (for HUD)
 623         switchweapon = getstati(STAT_SWITCHWEAPON);
 624
 625         // currently switching-to weapon (for crosshair)
 626         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
 627
 628         // actually active weapon (for zoom)
 629         activeweapon = getstati(STAT_ACTIVEWEAPON);
 630
 631         f = (serverflags & SERVERFLAG_TEAMPLAY);
 632         if(f != teamplay)
 633         {
 634                 teamplay = f;
 635                 HUD_InitScores();
 636         }
 637
 638         if(last_switchweapon != switchweapon)
 639         {
 640                 weapontime = time;
 641                 last_switchweapon = switchweapon;
 642                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
 643                 {
 644                         localcmd("-zoom\n");
 645                         button_zoom = FALSE;
 646                 }
 647                 if(autocvar_cl_unpress_attack_on_weapon_switch)
 648                 {
 649                         localcmd("-fire\n");
 650                         localcmd("-fire2\n");
 651                         button_attack2 = FALSE;
 652                 }
 653         }
 654         if(last_activeweapon != activeweapon)
 655         {
 656                 last_activeweapon = activeweapon;
 657
 658                 e = get_weaponinfo(activeweapon);
 659                 if(e.netname != "")
 660                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 661                 else
 662                         localcmd("\ncl_hook_activeweapon none\n");
 663         }
 664
 665         // ALWAYS Clear Current Scene First
 666         clearscene();
 667 #ifdef WORKAROUND_XON010
 668         if(checkextension("DP_CSQC_ROTATEMOVES"))
 669         {
 670 #endif
 671         setproperty(VF_ORIGIN, view_origin);
 672         setproperty(VF_ANGLES, view_angles);
 673 #ifdef WORKAROUND_XON010
 674         }
 675 #endif
 676
 677         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 678         setproperty(VF_SIZE, vf_size);
 679         setproperty(VF_MIN, vf_min);
 680
 681         // Assign Standard Viewflags
 682         // Draw the World (and sky)
 683         setproperty(VF_DRAWWORLD, 1);
 684
 685         // Set the console size vars
 686         vid_conwidth = autocvar_vid_conwidth;
 687         vid_conheight = autocvar_vid_conheight;
 688         vid_pixelheight = autocvar_vid_pixelheight;
 689
 690         setproperty(VF_FOV, GetCurrentFov(fov));
 691
 692         // Camera for demo playback
 693         if(camera_active)
 694         {
 695                 if(autocvar_camera_enable)
 696                         CSQC_Demo_Camera();
 697                 else
 698                 {
 699                         cvar_set("chase_active", ftos(chase_active_backup));
 700                         cvar_set("cl_demo_mousegrab", "0");
 701                         camera_active = FALSE;
 702                 }
 703         }
 704 #ifdef CAMERATEST
 705         else if(autocvar_camera_enable)
 706 #else
 707         else if(autocvar_camera_enable && isdemo())
 708 #endif
 709         {
 710                 // Enable required Darkplaces cvars
 711                 chase_active_backup = autocvar_chase_active;
 712                 cvar_set("chase_active", "2");
 713                 cvar_set("cl_demo_mousegrab", "1");
 714                 camera_active = TRUE;
 715                 camera_mode = FALSE;
 716         }
 717
 718         // Draw the Crosshair
 719         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 720
 721         // Draw the Engine Status Bar (the default Quake HUD)
 722         setproperty(VF_DRAWENGINESBAR, 0);
 723
 724         // Update the mouse position
 725         /*
 726            mousepos_x = vid_conwidth;
 727            mousepos_y = vid_conheight;
 728            mousepos = mousepos*0.5 + getmousepos();
 729          */
 730
 731         e = self;
 732         for(self = world; (self = nextent(self)); )
 733                 if(self.draw)
 734                         self.draw();
 735         self = e;
 736
 737         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 738         renderscene();
 739
 740         // now switch to 2D drawing mode by calling a 2D drawing function
 741         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 742         // next R_RenderScene call
 743         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 744
 745         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 746         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 747         {
 748                 // apply night vision effect
 749                 vector tc_00, tc_01, tc_10, tc_11;
 750                 vector rgb;
 751                 rgb_x = 0; // fteqcc sucks
 752                 rgb_y = 0; // fteqcc sucks
 753                 rgb_z = 0; // fteqcc sucks
 754
 755                 if(!nightvision_noise)
 756                 {
 757                         nightvision_noise = spawn();
 758                         nightvision_noise.classname = "nightvision_noise";
 759                 }
 760                 if(!nightvision_noise2)
 761                 {
 762                         nightvision_noise2 = spawn();
 763                         nightvision_noise2.classname = "nightvision_noise2";
 764                 }
 765
 766                 // color tint in yellow
 767                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 768
 769                 // draw BG
 770                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 771                 rgb = '1 1 1';
 772                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 773                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 774                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 775                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 776                 tc_11 = tc_01 + tc_10 - tc_00;
 777                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 778                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 779                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 780                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 781                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 782                 R_EndPolygon();
 783
 784                 // draw FG
 785                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 786                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 787                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 788                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 789                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 790                 tc_11 = tc_01 + tc_10 - tc_00;
 791                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 792                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 793                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 794                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 795                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 796                 R_EndPolygon();
 797         }
 798
 799         // Draw the aiming reticle for weapons that use it
 800         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 801         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 802         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 803         if(spectatee_status || is_dead || hud != HUD_NORMAL)
 804                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 805         else if((activeweapon == WEP_NEX || activeweapon == WEP_RIFLE || activeweapon == WEP_MINSTANEX) && (button_zoom || zoomscript_caught))
 806                 reticle_type = 2; // nex zoom
 807         else if(button_zoom || zoomscript_caught)
 808                 reticle_type = 1; // normal zoom
 809         else if((activeweapon == WEP_NEX) && button_attack2)
 810                 reticle_type = 2; // nex zoom
 811
 812         if(reticle_type && autocvar_cl_reticle)
 813         {
 814                 if(autocvar_cl_reticle_stretch)
 815                 {
 816                         reticle_size_x = vid_conwidth;
 817                         reticle_size_y = vid_conheight;
 818                         reticle_pos_x = 0;
 819                         reticle_pos_y = 0;
 820                 }
 821                 else
 822                 {
 823                         reticle_size_x = max(vid_conwidth, vid_conheight);
 824                         reticle_size_y = max(vid_conwidth, vid_conheight);
 825                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 826                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 827                 }
 828
 829                 f = current_zoomfraction;
 830                 if(zoomscript_caught)
 831                         f = 1;
 832                 if(autocvar_cl_reticle_item_normal)
 833                 {
 834                         if(reticle_type == 1 && f)
 835                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 836                 }
 837                 if(autocvar_cl_reticle_item_nex)
 838                 {
 839                         if(reticle_type == 2 && f)
 840                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 841                 }
 842         }
 843
 844
 845         // improved polyblend
 846         if(autocvar_hud_contents)
 847         {
 848                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 849                 vector liquidcolor;
 850
 851                 switch(pointcontents(view_origin))
 852                 {
 853                         case CONTENT_WATER:
 854                                 liquidalpha = autocvar_hud_contents_water_alpha;
 855                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 856                                 incontent = 1;
 857                                 break;
 858
 859                         case CONTENT_LAVA:
 860                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 861                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 862                                 incontent = 1;
 863                                 break;
 864
 865                         case CONTENT_SLIME:
 866                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 867                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 868                                 incontent = 1;
 869                                 break;
 870
 871                         default:
 872                                 liquidalpha = 0;
 873                                 liquidcolor = '0 0 0';
 874                                 incontent = 0;
 875                                 break;
 876                 }
 877
 878                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 879                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 880                         contentfadetime = autocvar_hud_contents_fadeintime;
 881                         liquidalpha_prev = liquidalpha;
 882                         liquidcolor_prev = liquidcolor;
 883                 }
 884                 else
 885                         contentfadetime = autocvar_hud_contents_fadeouttime;
 886
 887                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 888                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 889
 890                 if(contentavgalpha)
 891                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 892
 893                 if(autocvar_hud_postprocessing)
 894                 {
 895                         if(autocvar_hud_contents_blur && contentavgalpha)
 896                         {
 897                                 content_blurpostprocess_x = 1;
 898                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
 899                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
 900                         }
 901                         else
 902                         {
 903                                 content_blurpostprocess_x = 0;
 904                                 content_blurpostprocess_y = 0;
 905                                 content_blurpostprocess_z = 0;
 906                         }
 907                 }
 908         }
 909
 910         if(autocvar_hud_damage && !getstati(STAT_FROZEN))
 911         {
 912                 splash_size_x = max(vid_conwidth, vid_conheight);
 913                 splash_size_y = max(vid_conwidth, vid_conheight);
 914                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 915                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 916
 917                 float myhealth_flash_temp;
 918                 myhealth = getstati(STAT_HEALTH);
 919
 920                 // fade out
 921                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 922                 // add new damage
 923                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 924
 925                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 926                 pain_threshold = autocvar_hud_damage_pain_threshold;
 927                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 928                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 929
 930                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 931                 {
 932                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 933                 }
 934
 935                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 936
 937                 if(myhealth_prev < 1)
 938                 {
 939                         if(myhealth >= 1)
 940                         {
 941                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 942                                 myhealth_flash_temp = 0;
 943                         }
 944                         else
 945                         {
 946                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 947                         }
 948                 }
 949
 950                 if(spectatee_status == -1 || intermission)
 951                 {
 952                         myhealth_flash = 0; // observing, or match ended
 953                         myhealth_flash_temp = 0;
 954                 }
 955
 956                 myhealth_prev = myhealth;
 957
 958                 // IDEA: change damage color/picture based on player model for robot/alien species?
 959                 // pro: matches model better
 960                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
 961                 // maybe different reddish pics?
 962                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 963                 {
 964                         if(autocvar_cl_gentle_damage == 2)
 965                         {
 966                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 967                                 {
 968                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 969                                 }
 970                         }
 971                         else
 972                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 973
 974                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 975                 }
 976                 else
 977                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 978
 979                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
 980                 {
 981                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
 982                         {
 983                                 damage_blurpostprocess_x = 1;
 984                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
 985                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
 986                         }
 987                         else
 988                         {
 989                                 damage_blurpostprocess_x = 0;
 990                                 damage_blurpostprocess_y = 0;
 991                                 damage_blurpostprocess_z = 0;
 992                         }
 993                 }
 994         }
 995
 996         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
 997         float e2 = (autocvar_hud_powerup != 0);
 998         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
 999         {
1000                 // enable or disable rendering types if they are used or not
1001                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1002                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1003
1004                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1005                 if((damage_blurpostprocess_x || content_blurpostprocess_x))
1006                 {
1007                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
1008                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
1009                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1010                         {
1011                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1012                                 old_blurradius = blurradius;
1013                                 old_bluralpha = bluralpha;
1014                         }
1015                 }
1016                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1017                 {
1018                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1019                         old_blurradius = 0;
1020                         old_bluralpha = 0;
1021                 }
1022
1023                 // edge detection postprocess handling done second (used by hud_powerup)
1024                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
1025                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
1026                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
1027
1028                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1029
1030                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1031                 {
1032                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1033                         {
1034                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1035                                 old_sharpen_intensity = sharpen_intensity;
1036                         }
1037                 }
1038                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1039                 {
1040                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1041                         old_sharpen_intensity = 0;
1042                 }
1043
1044                 if(cvar("r_glsl_postprocess") == 0)
1045                         cvar_set("r_glsl_postprocess", "2");
1046         }
1047         else if(cvar("r_glsl_postprocess") == 2)
1048                 cvar_set("r_glsl_postprocess", "0");
1049
1050         if(menu_visible)
1051                 menu_show();
1052
1053         /*if(gametype == MAPINFO_TYPE_CTF)
1054           {
1055           ctf_view();
1056           } else */
1057
1058         // draw 2D entities
1059         e = self;
1060         for(self = world; (self = nextent(self)); )
1061                 if(self.draw2d)
1062                         self.draw2d();
1063         self = e;
1064         Draw_ShowNames_All();
1065
1066         scoreboard_active = HUD_WouldDrawScoreboard();
1067
1068         hit_time = getstatf(STAT_HIT_TIME);
1069         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
1070         {
1071                 if(time - hit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
1072                         sound(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTEN_NONE);
1073
1074                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
1075         }
1076         typehit_time = getstatf(STAT_TYPEHIT_TIME);
1077         if(typehit_time > nextsound_typehit_time)
1078         {
1079                 if(time - typehit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
1080                         sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTEN_NONE);
1081
1082                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
1083         }
1084
1085         //else
1086         {
1087                 if(gametype == MAPINFO_TYPE_FREEZETAG)
1088                 {
1089                         if(getstati(STAT_FROZEN))
1090                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1091                         if(getstatf(STAT_REVIVE_PROGRESS))
1092                         {
1093                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1094                                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1095                         }
1096                 }
1097
1098                 if(autocvar_r_letterbox == 0)
1099                         if(autocvar_viewsize < 120)
1100                                 CSQC_common_hud();
1101
1102                 // crosshair goes VERY LAST
1103                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL)
1104                 {
1105                         if not(autocvar_crosshair_enabled) // main toggle for crosshair rendering
1106                                 return;
1107
1108                         string wcross_style;
1109                         float wcross_alpha, wcross_resolution;
1110                         wcross_style = autocvar_crosshair;
1111                         if (wcross_style == "0")
1112                                 return;
1113                         wcross_resolution = autocvar_crosshair_size;
1114                         if (wcross_resolution == 0)
1115                                 return;
1116                         wcross_alpha = autocvar_crosshair_alpha;
1117                         if (wcross_alpha == 0)
1118                                 return;
1119
1120                         // TrueAim check
1121                         float shottype;
1122
1123                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1124                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
1125                         wcross_origin_z = 0;
1126                         if(autocvar_crosshair_hittest)
1127                         {
1128                                 vector wcross_oldorigin;
1129                                 wcross_oldorigin = wcross_origin;
1130                                 shottype = TrueAimCheck();
1131                                 if(shottype == SHOTTYPE_HITWORLD)
1132                                 {
1133                                         v = wcross_origin - wcross_oldorigin;
1134                                         v_x /= vid_conwidth;
1135                                         v_y /= vid_conheight;
1136                                         if(vlen(v) > 0.01)
1137                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1138                                 }
1139                                 if(!autocvar_crosshair_hittest_showimpact)
1140                                         wcross_origin = wcross_oldorigin;
1141                         }
1142                         else
1143                                 shottype = SHOTTYPE_HITWORLD;
1144
1145                         vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1146                         string wcross_wep = "", wcross_name;
1147                         float wcross_scale, wcross_blur;
1148
1149                         if (autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1150                         {
1151                                 e = get_weaponinfo(switchingweapon);
1152                                 if (e && e.netname != "")
1153                                 {
1154                                         wcross_wep = e.netname;
1155                                         if(autocvar_crosshair_per_weapon)
1156                                         {
1157                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1158                                                 if (wcross_resolution == 0)
1159                                                         return;
1160                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
1161                                                 if (wcross_alpha == 0)
1162                                                         return;
1163
1164                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1165                                                 if(wcross_style == "" || wcross_style == "0")
1166                                                         wcross_style = wcross_wep;
1167                                         }
1168                                 }
1169                         }
1170
1171                         //print(sprintf("crosshair style: %s\n", wcross_style));
1172                         wcross_name = strcat("gfx/crosshair", wcross_style);
1173
1174                         // MAIN CROSSHAIR COLOR DECISION
1175                         switch(autocvar_crosshair_color_special)
1176                         {
1177                                 case 1: // crosshair_color_per_weapon
1178                                 {
1179                                         if(wcross_wep != "")
1180                                         {
1181                                                 wcross_color = stov(cvar_string(sprintf("crosshair_%s_color", wcross_wep)));
1182                                                 break;
1183                                         }
1184                                         else { goto normalcolor; }
1185                                 }
1186
1187                                 case 2: // crosshair_color_by_health
1188                                 {
1189                                         float x = getstati(STAT_HEALTH);
1190
1191                                         //x = red
1192                                         //y = green
1193                                         //z = blue
1194
1195                                         wcross_color_z = 0;
1196
1197                                         if(x > 200)
1198                                         {
1199                                                 wcross_color_x = 0;
1200                                                 wcross_color_y = 1;
1201                                         }
1202                                         else if(x > 150)
1203                                         {
1204                                                 wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1205                                                 wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1206                                         }
1207                                         else if(x > 100)
1208                                         {
1209                                                 wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1210                                                 wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1211                                                 wcross_color_z = 1 - (x-100)*0.02;
1212                                         }
1213                                         else if(x > 50)
1214                                         {
1215                                                 wcross_color_x = 1;
1216                                                 wcross_color_y = 1;
1217                                                 wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1218                                         }
1219                                         else if(x > 20)
1220                                         {
1221                                                 wcross_color_x = 1;
1222                                                 wcross_color_y = (x-20)*90/27/100;
1223                                                 wcross_color_z = (x-20)*90/27/100 * 0.2;
1224                                         }
1225                                         else
1226                                         {
1227                                                 wcross_color_x = 1;
1228                                                 wcross_color_y = 0;
1229                                         }
1230                                         break;
1231                                 }
1232
1233                                 case 3: // crosshair_color_rainbow
1234                                 {
1235                                         if(time >= rainbow_last_flicker)
1236                                         {
1237                                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
1238                                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
1239                                         }
1240                                         wcross_color = rainbow_prev_color;
1241                                         break;
1242                                 }
1243                                 :normalcolor
1244                                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
1245                         }
1246
1247                         if(autocvar_crosshair_effect_scalefade)
1248                         {
1249                                 wcross_scale = wcross_resolution;
1250                                 wcross_resolution = 1;
1251                         }
1252                         else
1253                         {
1254                                 wcross_scale = 1;
1255                         }
1256
1257                         if(autocvar_crosshair_pickup)
1258                         {
1259                                 float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
1260
1261                                 if(pickup_crosshair_time < stat_pickup_time)
1262                                 {
1263                                         if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1264                                                 pickup_crosshair_size = 1;
1265
1266                                         pickup_crosshair_time = stat_pickup_time;
1267                                 }
1268
1269                                 if(pickup_crosshair_size > 0)
1270                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1271                                 else
1272                                         pickup_crosshair_size = 0;
1273
1274                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1275                         }
1276
1277                         if(autocvar_crosshair_hitindication)
1278                         {
1279                                 vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1280
1281                                 if(hitindication_crosshair_time < hit_time)
1282                                 {
1283                                         if(time - hit_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1284                                                 hitindication_crosshair_size = 1;
1285
1286                                         hitindication_crosshair_time = hit_time;
1287                                 }
1288
1289                                 if(hitindication_crosshair_size > 0)
1290                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1291                                 else
1292                                         hitindication_crosshair_size = 0;
1293
1294                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1295                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1296                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1297                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1298                         }
1299
1300                         if(shottype == SHOTTYPE_HITENEMY)
1301                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1302                         if(shottype == SHOTTYPE_HITTEAM)
1303                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1304
1305                         f = fabs(autocvar_crosshair_effect_time);
1306                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1307                         {
1308                                 wcross_changedonetime = time + f;
1309                         }
1310                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1311                         {
1312                                 wcross_name_changestarttime = time;
1313                                 wcross_name_changedonetime = time + f;
1314                                 if(wcross_name_goal_prev_prev)
1315                                         strunzone(wcross_name_goal_prev_prev);
1316                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1317                                 wcross_name_goal_prev = strzone(wcross_name);
1318                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1319                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1320                                 wcross_resolution_goal_prev = wcross_resolution;
1321                         }
1322
1323                         wcross_scale_goal_prev = wcross_scale;
1324                         wcross_alpha_goal_prev = wcross_alpha;
1325                         wcross_color_goal_prev = wcross_color;
1326
1327                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1328                         {
1329                                 wcross_blur = 1;
1330                                 wcross_alpha *= 0.75;
1331                         }
1332                         else
1333                                 wcross_blur = 0;
1334                         // *_prev is at time-frametime
1335                         // * is at wcross_changedonetime+f
1336                         // what do we have at time?
1337                         if(time < wcross_changedonetime)
1338                         {
1339                                 f = frametime / (wcross_changedonetime - time + frametime);
1340                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1341                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1342                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1343                         }
1344
1345                         wcross_scale_prev = wcross_scale;
1346                         wcross_alpha_prev = wcross_alpha;
1347                         wcross_color_prev = wcross_color;
1348
1349                         wcross_scale *= 1 - autocvar__menu_alpha;
1350                         wcross_alpha *= 1 - autocvar__menu_alpha;
1351                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1352
1353                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1354                         {
1355                                 // crosshair rings for weapon stats
1356                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1357                                 {
1358                                         // declarations and stats
1359                                         float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1360                                         string ring_image = string_null, ring_inner_image = string_null;
1361                                         vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1362
1363                                         ring_scale = autocvar_crosshair_ring_size;
1364
1365                                         float weapon_clipload, weapon_clipsize;
1366                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1367                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1368
1369                                         float nex_charge, nex_chargepool;
1370                                         nex_charge = getstatf(STAT_NEX_CHARGE);
1371                                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1372
1373                                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1374                                                 nex_charge_movingavg = nex_charge;
1375
1376
1377                                         // handle the values
1378                                         if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1379                                         {
1380                                                 if (nex_chargepool || use_nex_chargepool) {
1381                                                         use_nex_chargepool = 1;
1382                                                         ring_inner_value = nex_chargepool;
1383                                                 } else {
1384                                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1385                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1386                                                 }
1387
1388                                                 ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1389                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1390                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1391
1392                                                 // draw the outer ring to show the current charge of the weapon
1393                                                 ring_value = nex_charge;
1394                                                 ring_alpha = autocvar_crosshair_ring_nex_alpha;
1395                                                 ring_rgb = wcross_color;
1396                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1397                                         }
1398                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1399                                         {
1400                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1401                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1402                                                 ring_rgb = wcross_color;
1403                                                 ring_image = "gfx/crosshair_ring.tga";
1404                                         }
1405                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1406                                         {
1407                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1408                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1409                                                 ring_rgb = wcross_color;
1410                                                 ring_image = "gfx/crosshair_ring.tga";
1411                                         }
1412
1413                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1414                                         {
1415                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1416                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1417                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1418                                                 ring_rgb = wcross_color;
1419
1420                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1421                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1422                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1423                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1424                                                 else
1425                                                         ring_image = "gfx/crosshair_ring.tga";
1426                                         }
1427
1428                                         // if in weapon switch animation, fade ring out/in
1429                                         if(autocvar_crosshair_effect_time > 0)
1430                                         {
1431                                                 f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1432                                                 if not(f < 1)
1433                                                 {
1434                                                         wcross_ring_prev = ((ring_image) ? TRUE : FALSE);
1435                                                 }
1436
1437                                                 if(wcross_ring_prev)
1438                                                 {
1439                                                         if(f < 1)
1440                                                                 ring_alpha *= fabs(1 - bound(0, f, 1));
1441                                                 }
1442                                                 else
1443                                                 {
1444                                                         if(f < 1)
1445                                                                 ring_alpha *= bound(0, f, 1);
1446                                                 }
1447                                         }
1448
1449                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1450                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1451
1452                                         if (ring_value)
1453                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1454                                 }
1455
1456 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1457                                 do \
1458                                 { \
1459                                         if(wcross_blur > 0) \
1460                                         { \
1461                                                 for(i = -2; i <= 2; ++i) \
1462                                                 for(j = -2; j <= 2; ++j) \
1463                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1464                                         } \
1465                                         else \
1466                                         { \
1467                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1468                                         } \
1469                                 } \
1470                                 while(0)
1471
1472 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1473                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1474
1475 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1476                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1477
1478                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1479                                 {
1480                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1481                                         wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1482                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1483                                         f = 1 - f;
1484                                 }
1485                                 else
1486                                 {
1487                                         f = 1;
1488                                 }
1489                                 wcross_name_alpha_goal_prev = f;
1490
1491                                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1492                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1493
1494                                 if(autocvar_crosshair_dot)
1495                                 {
1496                                         vector wcross_color_old;
1497                                         wcross_color_old = wcross_color;
1498
1499                                         if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1500                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1501
1502                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1503                                         // FIXME why don't we use wcross_alpha here?cl_notice_run();
1504                                         wcross_color = wcross_color_old;
1505                                 }
1506                         }
1507                 }
1508                 else
1509                 {
1510                         wcross_scale_prev = 0;
1511                         wcross_alpha_prev = 0;
1512                         wcross_scale_goal_prev = 0;
1513                         wcross_alpha_goal_prev = 0;
1514                         wcross_changedonetime = 0;
1515                         if(wcross_name_goal_prev)
1516                                 strunzone(wcross_name_goal_prev);
1517                         wcross_name_goal_prev = string_null;
1518                         if(wcross_name_goal_prev_prev)
1519                                 strunzone(wcross_name_goal_prev_prev);
1520                         wcross_name_goal_prev_prev = string_null;
1521                         wcross_name_changestarttime = 0;
1522                         wcross_name_changedonetime = 0;
1523                         wcross_name_alpha_goal_prev = 0;
1524                         wcross_name_alpha_goal_prev_prev = 0;
1525                         wcross_resolution_goal_prev = 0;
1526                         wcross_resolution_goal_prev_prev = 0;
1527                 }
1528         }
1529
1530         if(NextFrameCommand)
1531         {
1532                 localcmd("\n", NextFrameCommand, "\n");
1533                 NextFrameCommand = string_null;
1534         }
1535
1536         // we must do this check AFTER a frame was rendered, or it won't work
1537         if(cs_project_is_b0rked == 0)
1538         {
1539                 string w0, h0;
1540                 w0 = ftos(autocvar_vid_conwidth);
1541                 h0 = ftos(autocvar_vid_conheight);
1542                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1543                 //setproperty(VF_FOV, '90 90 0');
1544                 setproperty(VF_ORIGIN, '0 0 0');
1545                 setproperty(VF_ANGLES, '0 0 0');
1546                 setproperty(VF_PERSPECTIVE, 1);
1547                 makevectors('0 0 0');
1548                 vector v1, v2;
1549                 cvar_set("vid_conwidth", "800");
1550                 cvar_set("vid_conheight", "600");
1551                 v1 = cs_project(v_forward);
1552                 cvar_set("vid_conwidth", "640");
1553                 cvar_set("vid_conheight", "480");
1554                 v2 = cs_project(v_forward);
1555                 if(v1 == v2)
1556                         cs_project_is_b0rked = 1;
1557                 else
1558                         cs_project_is_b0rked = -1;
1559                 cvar_set("vid_conwidth", w0);
1560                 cvar_set("vid_conheight", h0);
1561         }
1562
1563         if(autocvar__hud_configure)
1564                 HUD_Panel_Mouse();
1565
1566     if(hud && !intermission)
1567                 VEH_ACTION(hud, VR_HUD);
1568
1569         cl_notice_run();
1570
1571         // let's reset the view back to normal for the end
1572         setproperty(VF_MIN, '0 0 0');
1573         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1574 }
1575
1576
1577 void CSQC_common_hud(void)
1578 {
1579         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1580                 Accuracy_LoadLevels();
1581
1582     HUD_Main(); // always run these functions for alpha checks
1583     HUD_DrawScoreboard();
1584
1585     if (scoreboard_active) // scoreboard/accuracy
1586         HUD_Reset();
1587     else if (intermission == 2) // map voting screen
1588     {
1589         HUD_FinaleOverlay();
1590         HUD_Reset();
1591     }
1592 }
1593
1594
1595 // following vectors must be global to allow seamless switching between camera modes
1596 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1597 void CSQC_Demo_Camera()
1598 {
1599         float speed, attenuation, dimensions;
1600         vector tmp, delta;
1601
1602         if( autocvar_camera_reset || !camera_mode )
1603         {
1604                 camera_offset = '0 0 0';
1605                 current_angles = '0 0 0';
1606                 camera_direction = '0 0 0';
1607                 camera_offset_z += 30;
1608                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1609                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1610                 current_origin = view_origin;
1611                 current_camera_offset  = camera_offset;
1612                 cvar_set("camera_reset", "0");
1613                 camera_mode = CAMERA_CHASE;
1614         }
1615
1616         // Camera angles
1617         if( camera_roll )
1618                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1619
1620         if(autocvar_camera_look_player)
1621         {
1622                 vector dir;
1623                 float n;
1624
1625                 dir = normalize(view_origin - current_position);
1626                 n = mouse_angles_z;
1627                 mouse_angles = vectoangles(dir);
1628                 mouse_angles_x = mouse_angles_x * -1;
1629                 mouse_angles_z = n;
1630         }
1631         else
1632         {
1633                 tmp = getmousepos() * 0.1;
1634                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1635                 {
1636                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1637                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1638                 }
1639         }
1640
1641         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1642         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1643         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1644         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1645
1646         // Fix difference when angles don't have the same sign
1647         delta = '0 0 0';
1648         if(mouse_angles_y < -60 && current_angles_y > 60)
1649                 delta = '0 360 0';
1650         if(mouse_angles_y > 60 && current_angles_y < -60)
1651                 delta = '0 -360 0';
1652
1653         if(autocvar_camera_look_player)
1654                 attenuation = autocvar_camera_look_attenuation;
1655         else
1656                 attenuation = autocvar_camera_speed_attenuation;
1657
1658         attenuation = 1 / max(1, attenuation);
1659         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1660
1661         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1662         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1663         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1664         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1665
1666         // Camera position
1667         tmp = '0 0 0';
1668         dimensions = 0;
1669
1670         if( camera_direction_x )
1671         {
1672                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1673                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1674                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1675                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1676                 ++dimensions;
1677         }
1678
1679         if( camera_direction_y )
1680         {
1681                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1682                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1683                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1684                 ++dimensions;
1685         }
1686
1687         if( camera_direction_z )
1688         {
1689                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1690                 ++dimensions;
1691         }
1692
1693         if(autocvar_camera_free)
1694                 speed = autocvar_camera_speed_free;
1695         else
1696                 speed = autocvar_camera_speed_chase;
1697
1698         if(dimensions)
1699         {
1700                 speed = speed * sqrt(1 / dimensions);
1701                 camera_offset += tmp * speed;
1702         }
1703
1704         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1705
1706         // Camera modes
1707         if( autocvar_camera_free )
1708         {
1709                 if ( camera_mode == CAMERA_CHASE )
1710                 {
1711                         current_camera_offset = current_origin + current_camera_offset;
1712                         camera_offset = current_origin + camera_offset;
1713                 }
1714
1715                 camera_mode = CAMERA_FREE;
1716                 current_position = current_camera_offset;
1717         }
1718         else
1719         {
1720                 if ( camera_mode == CAMERA_FREE )
1721                 {
1722                         current_origin = view_origin;
1723                         camera_offset = camera_offset - current_origin;
1724                         current_camera_offset = current_camera_offset - current_origin;
1725                 }
1726
1727                 camera_mode = CAMERA_CHASE;
1728
1729                 if(autocvar_camera_chase_smoothly)
1730                         current_origin += (view_origin - current_origin) * attenuation;
1731                 else
1732                         current_origin = view_origin;
1733
1734                 current_position = current_origin + current_camera_offset;
1735         }
1736
1737         setproperty(VF_ANGLES, current_angles);
1738         setproperty(VF_ORIGIN, current_position);
1739 }