qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
   4 float DPCONTENTS_SOLID = 1; // blocks player movement
   5 float DPCONTENTS_BODY = 32; // blocks player movement
   6 float DPCONTENTS_CORPSE = 64; // blocks player movement
   7 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
   8 void Porto_Draw()
   9 {
  10         vector p, dir, ang, q, nextdir;
  11         float idx, portal_number, portal1_idx;
  12
  13         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  14                 return;
  15         if(intermission == 1)
  16                 return;
  17         if(intermission == 2)
  18                 return;
  19         if (getstati(STAT_HEALTH) <= 0)
  20                 return;
  21
  22         dir = view_forward;
  23
  24         if(angles_held_status)
  25         {
  26                 makevectors(angles_held);
  27                 dir = v_forward;
  28         }
  29
  30         p = view_origin;
  31
  32         polyline[0] = p;
  33         idx = 1;
  34         portal_number = 0;
  35         nextdir = dir;
  36
  37         for(;;)
  38         {
  39                 dir = nextdir;
  40                 traceline(p, p + 65536 * dir, TRUE, porto);
  41                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  42                         return;
  43                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  44                 p = trace_endpos;
  45                 polyline[idx] = p;
  46                 ++idx;
  47                 if(idx >= 16)
  48                         return;
  49                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  50                         continue;
  51                 ++portal_number;
  52                 ang = vectoangles2(trace_plane_normal, dir);
  53                 ang_x = -ang_x;
  54                 makevectors(ang);
  55                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  56                         return;
  57                 if(portal_number == 1)
  58                         portal1_idx = idx;
  59                 if(portal_number >= 2)
  60                         break;
  61         }
  62
  63         while(idx >= 2)
  64         {
  65                 p = polyline[idx-2];
  66                 q = polyline[idx-1];
  67                 if(idx == 2)
  68                         p = p - view_up * 16;
  69                 if(idx-1 >= portal1_idx)
  70                 {
  71                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  72                 }
  73                 else
  74                 {
  75                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  76                 }
  77                 --idx;
  78         }
  79 }
  80
  81 void Porto_Init()
  82 {
  83         porto = spawn();
  84         porto.classname = "porto";
  85         porto.draw = Porto_Draw;
  86         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
  87 }
  88
  89 float drawtime;
  90 float avgspeed;
  91 vector GetCurrentFov(float fov)
  92 {
  93         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
  94         float velocityzoom, curspeed;
  95
  96         zoomsensitivity = autocvar_cl_zoomsensitivity;
  97         zoomfactor = autocvar_cl_zoomfactor;
  98         if(zoomfactor < 1 || zoomfactor > 16)
  99                 zoomfactor = 2.5;
 100         zoomspeed = autocvar_cl_zoomspeed;
 101         if(zoomspeed >= 0)
 102                 if(zoomspeed < 0.5 || zoomspeed > 16)
 103                         zoomspeed = 3.5;
 104
 105         zoomdir = button_zoom;
 106         if(hud == HUD_NORMAL)
 107         if((activeweapon == WEP_NEX && nex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 108                 zoomdir += button_attack2;
 109         if(spectatee_status > 0 || isdemo())
 110         {
 111                 if(spectatorbutton_zoom)
 112                 {
 113                         if(zoomdir)
 114                                 zoomdir = 0;
 115                         else
 116                                 zoomdir = 1;
 117                 }
 118                 // fteqcc failed twice here already, don't optimize this
 119         }
 120
 121         if(zoomdir)
 122                 zoomin_effect = 0;
 123
 124         if(zoomin_effect || camera_active)
 125         {
 126                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 127         }
 128         else
 129         {
 130                 if(zoomspeed < 0) // instant zoom
 131                 {
 132                         if(zoomdir)
 133                                 current_viewzoom = 1 / zoomfactor;
 134                         else
 135                                 current_viewzoom = 1;
 136                 }
 137                 else
 138                 {
 139                         if(zoomdir)
 140                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 141                         else
 142                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 143                 }
 144         }
 145
 146         if(almost_equals(current_viewzoom, 1))
 147                 current_zoomfraction = 0;
 148         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 149                 current_zoomfraction = 1;
 150         else
 151                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 152
 153         if(zoomsensitivity < 1)
 154                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 155         else
 156                 setsensitivityscale(1);
 157
 158         makevectors(view_angles);
 159
 160         if(autocvar_cl_velocityzoom)
 161         {
 162                 switch(autocvar_cl_velocityzoom_type)
 163                 {
 164                         case 3: curspeed = max(0, v_forward * pmove_vel); break;
 165                         case 2: curspeed = (v_forward * pmove_vel); break;
 166                         case 1: default: curspeed = vlen(pmove_vel); break;
 167                 }
 168
 169                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 170                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 171                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 172
 173                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 174         }
 175         else
 176                 velocityzoom = 1;
 177
 178         float frustumx, frustumy, fovx, fovy;
 179         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 180         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 181         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 182         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 183
 184         return '1 0 0' * fovx + '0 1 0' * fovy;
 185 }
 186
 187 // this function must match W_SetupShot!
 188 float zoomscript_caught;
 189
 190 vector wcross_origin;
 191 float wcross_scale_prev, wcross_alpha_prev;
 192 vector wcross_color_prev;
 193 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 194 vector wcross_color_goal_prev;
 195 float wcross_changedonetime;
 196
 197 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 198 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 199 float wcross_name_changestarttime, wcross_name_changedonetime;
 200 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 201 entity trueaim;
 202 entity trueaim_rifle;
 203
 204 #define SHOTTYPE_HITTEAM 1
 205 #define SHOTTYPE_HITOBSTRUCTION 2
 206 #define SHOTTYPE_HITWORLD 3
 207 #define SHOTTYPE_HITENEMY 4
 208
 209 void TrueAim_Init()
 210 {
 211         trueaim = spawn();
 212         trueaim.classname = "trueaim";
 213         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 214         trueaim_rifle = spawn();
 215         trueaim_rifle.classname = "trueaim_rifle";
 216         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 217 }
 218
 219 float EnemyHitCheck()
 220 {
 221         float t;
 222         wcross_origin = project_3d_to_2d(trace_endpos);
 223         wcross_origin_z = 0;
 224         if(trace_networkentity < 1)
 225                 return SHOTTYPE_HITWORLD;
 226         if(trace_networkentity > maxclients)
 227                 return SHOTTYPE_HITWORLD;
 228         t = GetPlayerColor(trace_networkentity - 1);
 229         if(teamplay)
 230                 if(t == myteam)
 231                         return SHOTTYPE_HITTEAM;
 232         if(t == COLOR_SPECTATOR)
 233                 return SHOTTYPE_HITWORLD;
 234         return SHOTTYPE_HITENEMY;
 235 }
 236
 237 float TrueAimCheck()
 238 {
 239         float nudge = 1; // added to traceline target and subtracted from result
 240         vector vecs, trueaimpoint, w_shotorg;
 241         vector mi, ma, dv;
 242         float shottype;
 243         entity ta;
 244         float mv;
 245
 246         mi = ma = '0 0 0';
 247         ta = trueaim;
 248         mv = MOVE_NOMONSTERS;
 249
 250         switch(activeweapon)
 251         {
 252                 case WEP_TUBA: // no aim
 253                 case WEP_PORTO: // shoots from eye
 254                 case WEP_HOOK: // no trueaim
 255                 case WEP_GRENADE_LAUNCHER: // toss curve
 256                         return SHOTTYPE_HITWORLD;
 257                 case WEP_NEX:
 258                 case WEP_MINSTANEX:
 259                         mv = MOVE_NORMAL;
 260                         break;
 261                 case WEP_RIFLE:
 262                         ta = trueaim_rifle;
 263                         mv = MOVE_NORMAL;
 264                         if(zoomscript_caught)
 265                         {
 266                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 267                                 return EnemyHitCheck();
 268                         }
 269                         break;
 270                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 271                         mi = '-3 -3 -3';
 272                         ma = '3 3 3';
 273                         break;
 274                 case WEP_FIREBALL: // projectile has a size!
 275                         mi = '-16 -16 -16';
 276                         ma = '16 16 16';
 277                         break;
 278                 case WEP_SEEKER: // projectile has a size!
 279                         mi = '-2 -2 -2';
 280                         ma = '2 2 2';
 281                         break;
 282                 case WEP_ELECTRO: // projectile has a size!
 283                         mi = '0 0 -3';
 284                         ma = '0 0 -3';
 285                         break;
 286         }
 287
 288         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 289
 290         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 291         trueaimpoint = trace_endpos;
 292
 293         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 294                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 295
 296         if(vecs_x > 0)
 297                 vecs_y = -vecs_y;
 298         else
 299                 vecs = '0 0 0';
 300
 301         dv = view_right * vecs_y + view_up * vecs_z;
 302         w_shotorg = view_origin + dv;
 303
 304         // now move the vecs forward as much as requested if possible
 305         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 306         w_shotorg = trace_endpos - view_forward * nudge;
 307
 308         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 309         shottype = EnemyHitCheck();
 310         if(shottype != SHOTTYPE_HITWORLD)
 311                 return shottype;
 312
 313 #if 0
 314         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 315         // or rather, I know why, but see no fix
 316         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 317                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 318                 return SHOTTYPE_HITOBSTRUCTION;
 319 #endif
 320
 321         return SHOTTYPE_HITWORLD;
 322 }
 323
 324 void CSQC_common_hud(void);
 325
 326 void PostInit(void);
 327 void CSQC_Demo_Camera();
 328 float HUD_WouldDrawScoreboard();
 329 float camera_mode;
 330 float reticle_type;
 331 string NextFrameCommand;
 332 void CSQC_SPIDER_HUD();
 333 void CSQC_RAPTOR_HUD();
 334
 335 vector freeze_org, freeze_ang;
 336 entity nightvision_noise, nightvision_noise2;
 337
 338 #define MAX_TIME_DIFF 5
 339 float pickup_crosshair_time, pickup_crosshair_size;
 340 float hit_time, typehit_time;
 341 float nextsound_hit_time, nextsound_typehit_time;
 342 float hitindication_crosshair_time, hitindication_crosshair_size;
 343 float use_nex_chargepool;
 344
 345 float myhealth, myhealth_prev;
 346 float myhealth_flash;
 347
 348 float old_blurradius, old_bluralpha;
 349 float old_sharpen_intensity;
 350
 351 vector myhealth_gentlergb;
 352
 353 float contentavgalpha, liquidalpha_prev;
 354 vector liquidcolor_prev;
 355
 356 float eventchase_current_distance;
 357
 358 vector damage_blurpostprocess, content_blurpostprocess;
 359
 360 float checkfail[16];
 361
 362 void CSQC_UpdateView(float w, float h)
 363 {
 364         entity e;
 365         float fov;
 366         float f, i, j;
 367         vector v;
 368         vector vf_size, vf_min;
 369         float a;
 370         hud = getstati(STAT_HUD);
 371
 372         button_attack2 = (input_buttons & BUTTON_3);
 373         button_zoom = (input_buttons & BUTTON_4);
 374
 375         // FIXME do we need this hack?
 376         if(isdemo())
 377         {
 378                 // in demos, input_buttons do not work
 379                 button_zoom = (autocvar__togglezoom == "-");
 380         }
 381
 382 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 383         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 384         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 385         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 386         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 387         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 388         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 389
 390         vf_size = R_SetView3fv(VF_SIZE);
 391         vf_min = R_SetView3fv(VF_MIN);
 392         vid_width = vf_size_x;
 393         vid_height = vf_size_y;
 394
 395         vector reticle_pos, reticle_size;
 396         vector splash_pos, splash_size;
 397
 398         WaypointSprite_Load();
 399
 400         if(spectatee_status)
 401                 myteam = GetPlayerColor(spectatee_status - 1);
 402         else
 403                 myteam = GetPlayerColor(player_localentnum - 1);
 404
 405         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 406
 407         // event chase camera
 408         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 409         {
 410                 if(spectatee_status >= 0 && (autocvar_cl_eventchase_death && getstati(STAT_HEALTH) <= 0 && !intermission) || intermission)
 411                 {
 412                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 413                         vector current_view_origin = R_SetView3fv(VF_ORIGIN);
 414
 415                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 416                         // Ideally, there should be another way to enable third person cameras, such as through R_SetView()
 417                         if(!autocvar_chase_active)
 418                                 cvar_set("chase_active", "-1"); // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 419
 420                         // make the camera smooth back
 421                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 422                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 423                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 424                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 425
 426                         vector eventchase_target_origin;
 427                         makevectors(view_angles);
 428                         // pass 1, used to check where the camera would go and obtain the trace_fraction
 429                         eventchase_target_origin = current_view_origin - v_forward * eventchase_current_distance;
 430                         WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 431                         // pass 2, also multiplying view_forward with trace_fraction, to prevent the camera from going through walls
 432                         // The 0.1 subtraction is to not limit the camera precisely at the wall surface, as that allows the view to poke through
 433                         eventchase_target_origin = current_view_origin - v_forward * eventchase_current_distance * (trace_fraction - 0.1);
 434                         WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 435
 436                         R_SetView(VF_ORIGIN, trace_endpos);
 437                         R_SetView(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 438                 }
 439                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 440                 {
 441                         cvar_set("chase_active", "0");
 442                         eventchase_current_distance = 0; // start from 0 next time
 443                 }
 444         }
 445
 446         // do lockview after event chase camera so that it still applies whenever necessary.
 447         if(autocvar_cl_lockview || (autocvar__hud_configure && spectatee_status <= 0) || intermission > 1)
 448         {
 449                 R_SetView(VF_ORIGIN, freeze_org);
 450                 R_SetView(VF_ANGLES, freeze_ang);
 451         }
 452         else
 453         {
 454                 freeze_org = R_SetView3fv(VF_ORIGIN);
 455                 freeze_ang = R_SetView3fv(VF_ANGLES);
 456         }
 457
 458         WarpZone_FixView();
 459         //WarpZone_FixPMove();
 460
 461         // Render the Scene
 462         view_origin = R_SetView3fv(VF_ORIGIN);
 463         view_angles = R_SetView3fv(VF_ANGLES);
 464         makevectors(view_angles);
 465         view_forward = v_forward;
 466         view_right = v_right;
 467         view_up = v_up;
 468
 469 #ifdef BLURTEST
 470         if(time > blurtest_time0 && time < blurtest_time1)
 471         {
 472                 float r, t;
 473
 474                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 475                 r = t * blurtest_radius;
 476                 f = 1 / pow(t, blurtest_power) - 1;
 477
 478                 cvar_set("r_glsl_postprocess", "1");
 479                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 480         }
 481         else
 482         {
 483                 cvar_set("r_glsl_postprocess", "0");
 484                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 485         }
 486 #endif
 487
 488         TargetMusic_Advance();
 489         Fog_Force();
 490
 491         if(drawtime == 0)
 492                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
 493         else
 494                 drawframetime = bound(0.000001, time - drawtime, 1);
 495         drawtime = time;
 496
 497         // watch for gametype changes here...
 498         // in ParseStuffCMD the cmd isn't executed yet :/
 499         // might even be better to add the gametype to TE_CSQC_INIT...?
 500         if(!postinit)
 501                 PostInit();
 502
 503         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 504         {
 505                 if(calledhooks & HOOK_START)
 506                 {
 507                         localcmd("\ncl_hook_gameend\n");
 508                         calledhooks |= HOOK_END;
 509                 }
 510         }
 511
 512   Announcer();
 513
 514         fov = autocvar_fov;
 515         if(fov <= 59.5)
 516         {
 517                 if(!zoomscript_caught)
 518                 {
 519                         localcmd("+button9\n");
 520                         zoomscript_caught = 1;
 521                 }
 522         }
 523         else
 524         {
 525                 if(zoomscript_caught)
 526                 {
 527                         localcmd("-button9\n");
 528                         zoomscript_caught = 0;
 529                 }
 530         }
 531
 532         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 533
 534         // next WANTED weapon (for HUD)
 535         switchweapon = getstati(STAT_SWITCHWEAPON);
 536
 537         // currently switching-to weapon (for crosshair)
 538         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
 539
 540         // actually active weapon (for zoom)
 541         activeweapon = getstati(STAT_ACTIVEWEAPON);
 542
 543         f = (serverflags & SERVERFLAG_TEAMPLAY);
 544         if(f != teamplay)
 545         {
 546                 teamplay = f;
 547                 HUD_InitScores();
 548         }
 549
 550         if(last_switchweapon != switchweapon) {
 551                 weapontime = time;
 552                 last_switchweapon = switchweapon;
 553         }
 554         if(last_activeweapon != activeweapon) {
 555                 last_activeweapon = activeweapon;
 556
 557                 e = get_weaponinfo(activeweapon);
 558                 if(e.netname != "")
 559                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 560                 else
 561                         localcmd("\ncl_hook_activeweapon none\n");
 562         }
 563
 564         // ALWAYS Clear Current Scene First
 565         R_ClearScene();
 566 #ifdef WORKAROUND_XON010
 567         if(checkextension("DP_CSQC_ROTATEMOVES"))
 568         {
 569 #endif
 570         R_SetView(VF_ORIGIN, view_origin);
 571         R_SetView(VF_ANGLES, view_angles);
 572 #ifdef WORKAROUND_XON010
 573         }
 574 #endif
 575
 576         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 577         R_SetView(VF_SIZE, vf_size);
 578         R_SetView(VF_MIN, vf_min);
 579
 580         // Assign Standard Viewflags
 581         // Draw the World (and sky)
 582         R_SetView(VF_DRAWWORLD, 1);
 583
 584         // Set the console size vars
 585         vid_conwidth = autocvar_vid_conwidth;
 586         vid_conheight = autocvar_vid_conheight;
 587         vid_pixelheight = autocvar_vid_pixelheight;
 588
 589         R_SetView(VF_FOV, GetCurrentFov(fov));
 590
 591         // Camera for demo playback
 592         if(camera_active)
 593         {
 594                 if(autocvar_camera_enable)
 595                         CSQC_Demo_Camera();
 596                 else
 597                 {
 598                         cvar_set("chase_active", ftos(chase_active_backup));
 599                         cvar_set("cl_demo_mousegrab", "0");
 600                         camera_active = FALSE;
 601                 }
 602         }
 603 #ifdef CAMERATEST
 604         else if(autocvar_camera_enable)
 605 #else
 606         else if(autocvar_camera_enable && isdemo())
 607 #endif
 608         {
 609                 // Enable required Darkplaces cvars
 610                 chase_active_backup = autocvar_chase_active;
 611                 cvar_set("chase_active", "2");
 612                 cvar_set("cl_demo_mousegrab", "1");
 613                 camera_active = TRUE;
 614                 camera_mode = FALSE;
 615         }
 616
 617         // Draw the Crosshair
 618         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 619
 620         // Draw the Engine Status Bar (the default Quake HUD)
 621         R_SetView(VF_DRAWENGINEHUD, 0);
 622
 623         // Update the mouse position
 624         /*
 625            mousepos_x = vid_conwidth;
 626            mousepos_y = vid_conheight;
 627            mousepos = mousepos*0.5 + getmousepos();
 628          */
 629
 630         e = self;
 631         for(self = world; (self = nextent(self)); )
 632                 if(self.draw)
 633                         self.draw();
 634         self = e;
 635
 636         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 637         R_RenderScene();
 638
 639         // now switch to 2D drawing mode by calling a 2D drawing function
 640         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 641         // next R_RenderScene call
 642         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 643
 644         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 645         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 646         {
 647                 // apply night vision effect
 648                 vector rgb, tc_00, tc_01, tc_10, tc_11;
 649
 650                 if(!nightvision_noise)
 651                 {
 652                         nightvision_noise = spawn();
 653                         nightvision_noise.classname = "nightvision_noise";
 654                 }
 655                 if(!nightvision_noise2)
 656                 {
 657                         nightvision_noise2 = spawn();
 658                         nightvision_noise2.classname = "nightvision_noise2";
 659                 }
 660
 661                 // color tint in yellow
 662                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 663
 664                 // draw BG
 665                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 666                 rgb = '1 1 1';
 667                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 668                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 669                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 670                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 671                 tc_11 = tc_01 + tc_10 - tc_00;
 672                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 673                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 674                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 675                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 676                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 677                 R_EndPolygon();
 678
 679                 // draw FG
 680                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 681                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 682                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 683                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 684                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 685                 tc_11 = tc_01 + tc_10 - tc_00;
 686                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 687                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 688                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 689                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 690                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 691                 R_EndPolygon();
 692         }
 693
 694         // Draw the aiming reticle for weapons that use it
 695         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 696         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 697         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 698         if(spectatee_status || getstati(STAT_HEALTH) <= 0 || hud != HUD_NORMAL)
 699                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 700         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_RIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 701                 reticle_type = 2; // nex zoom
 702         else if(button_zoom || zoomscript_caught)
 703                 reticle_type = 1; // normal zoom
 704         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_RIFLE && button_attack2)
 705                 reticle_type = 2; // nex zoom
 706
 707         if(reticle_type && autocvar_cl_reticle)
 708         {
 709                 if(autocvar_cl_reticle_stretch)
 710                 {
 711                         reticle_size_x = vid_conwidth;
 712                         reticle_size_y = vid_conheight;
 713                         reticle_pos_x = 0;
 714                         reticle_pos_y = 0;
 715                 }
 716                 else
 717                 {
 718                         reticle_size_x = max(vid_conwidth, vid_conheight);
 719                         reticle_size_y = max(vid_conwidth, vid_conheight);
 720                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 721                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 722                 }
 723
 724                 f = current_zoomfraction;
 725                 if(zoomscript_caught)
 726                         f = 1;
 727                 if(autocvar_cl_reticle_item_normal)
 728                 {
 729                         if(reticle_type == 1 && f)
 730                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 731                 }
 732                 if(autocvar_cl_reticle_item_nex)
 733                 {
 734                         if(reticle_type == 2 && f)
 735                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 736                 }
 737         }
 738
 739
 740         // improved polyblend
 741         vector rgb;
 742         if(autocvar_hud_contents)
 743         {
 744                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 745                 vector liquidcolor;
 746
 747                 switch(pointcontents(view_origin))
 748                 {
 749                         case CONTENT_WATER:
 750                                 liquidalpha = autocvar_hud_contents_water_alpha;
 751                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 752                                 incontent = 1;
 753                                 break;
 754
 755                         case CONTENT_LAVA:
 756                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 757                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 758                                 incontent = 1;
 759                                 break;
 760
 761                         case CONTENT_SLIME:
 762                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 763                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 764                                 incontent = 1;
 765                                 break;
 766
 767                         default:
 768                                 liquidalpha = 0;
 769                                 liquidcolor = '0 0 0';
 770                                 incontent = 0;
 771                                 break;
 772                 }
 773
 774                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 775                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 776                         contentfadetime = autocvar_hud_contents_fadeintime;
 777                         liquidalpha_prev = liquidalpha;
 778                         liquidcolor_prev = liquidcolor;
 779                 }
 780                 else
 781                         contentfadetime = autocvar_hud_contents_fadeouttime;
 782
 783                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 784                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 785
 786                 if(contentavgalpha)
 787                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 788
 789                 if(autocvar_hud_postprocessing)
 790                 {
 791                         if(autocvar_hud_contents_blur && contentavgalpha)
 792                         {
 793                                 content_blurpostprocess_x = 1;
 794                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
 795                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
 796                         }
 797                         else
 798                         {
 799                                 content_blurpostprocess_x = 0;
 800                                 content_blurpostprocess_y = 0;
 801                                 content_blurpostprocess_z = 0;
 802                         }
 803                 }
 804         }
 805
 806         if(autocvar_hud_damage)
 807         {
 808                 splash_size_x = max(vid_conwidth, vid_conheight);
 809                 splash_size_y = max(vid_conwidth, vid_conheight);
 810                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 811                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 812
 813                 float myhealth_flash_temp;
 814                 myhealth = getstati(STAT_HEALTH);
 815
 816                 // fade out
 817                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 818                 // add new damage
 819                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 820
 821                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 822                 pain_threshold = autocvar_hud_damage_pain_threshold;
 823                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 824                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 825
 826                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 827                 {
 828                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 829                 }
 830
 831                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 832
 833                 if(myhealth_prev < 1)
 834                 {
 835                         if(myhealth >= 1)
 836                         {
 837                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 838                                 myhealth_flash_temp = 0;
 839                         }
 840                         else
 841                         {
 842                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 843                         }
 844                 }
 845
 846                 if(spectatee_status == -1 || intermission)
 847                 {
 848                         myhealth_flash = 0; // observing, or match ended
 849                         myhealth_flash_temp = 0;
 850                 }
 851
 852                 myhealth_prev = myhealth;
 853
 854                 // IDEA: change damage color/picture based on player model for robot/alien species?
 855                 // pro: matches model better
 856                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
 857                 // maybe different reddish pics?
 858                 if(autocvar_chase_active >= 0) // not while the event chase camera is active
 859                 {
 860                         if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 861                         {
 862                                 if(autocvar_cl_gentle_damage == 2)
 863                                 {
 864                                         if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 865                                         {
 866                                                 myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 867                                         }
 868                                 }
 869                                 else
 870                                         myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 871
 872                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 873                         }
 874                         else
 875                                 drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 876                 }
 877
 878                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
 879                 {
 880                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
 881                         {
 882                                 damage_blurpostprocess_x = 1;
 883                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
 884                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
 885                         }
 886                         else
 887                         {
 888                                 damage_blurpostprocess_x = 0;
 889                                 damage_blurpostprocess_y = 0;
 890                                 damage_blurpostprocess_z = 0;
 891                         }
 892                 }
 893         }
 894
 895         if(autocvar_hud_postprocessing) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
 896         {
 897                 // enable or disable rendering types if they are used or not
 898                 if(cvar("r_glsl_postprocess_uservec1_enable") != (autocvar_hud_postprocessing_maxbluralpha != 0)) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(autocvar_hud_postprocessing_maxbluralpha != 0)); }
 899                 if(cvar("r_glsl_postprocess_uservec2_enable") != (autocvar_hud_powerup != 0)) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(autocvar_hud_powerup != 0)); }
 900
 901                 // blur postprocess handling done first (used by hud_damage and hud_contents)
 902                 if((damage_blurpostprocess_x || content_blurpostprocess_x) && autocvar_chase_active >= 0) // not while the event chase camera is active
 903                 {
 904                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
 905                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
 906                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
 907                         {
 908                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
 909                                 old_blurradius = blurradius;
 910                                 old_bluralpha = bluralpha;
 911                         }
 912                 }
 913                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
 914                 {
 915                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 916                         old_blurradius = 0;
 917                         old_bluralpha = 0;
 918                 }
 919
 920                 // edge detection postprocess handling done second (used by hud_powerup)
 921                 float sharpen_intensity, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
 922                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
 923                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
 924
 925                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
 926
 927                 if(autocvar_hud_powerup && sharpen_intensity > 0 && autocvar_chase_active >= 0) // not while the event chase camera is active
 928                 {
 929                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
 930                         {
 931                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
 932                                 old_sharpen_intensity = sharpen_intensity;
 933                         }
 934                 }
 935                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
 936                 {
 937                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
 938                         old_sharpen_intensity = 0;
 939                 }
 940         }
 941
 942         if(menu_visible)
 943                 menu_show();
 944
 945         /*if(gametype == GAME_CTF)
 946           {
 947           ctf_view();
 948           } else */
 949
 950         // draw 2D entities
 951         e = self;
 952         for(self = world; (self = nextent(self)); )
 953                 if(self.draw2d)
 954                         self.draw2d();
 955         self = e;
 956         Draw_ShowNames_All();
 957
 958         scoreboard_active = HUD_WouldDrawScoreboard();
 959
 960         hit_time = getstatf(STAT_HIT_TIME);
 961         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
 962         {
 963                 if(time - hit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
 964                         sound(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
 965
 966                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
 967         }
 968         typehit_time = getstatf(STAT_TYPEHIT_TIME);
 969         if(typehit_time > nextsound_typehit_time)
 970         {
 971                 if(time - typehit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
 972                         sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
 973
 974                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
 975         }
 976
 977         //else
 978         {
 979                 if(gametype == GAME_FREEZETAG)
 980                 {
 981                         if(getstati(STAT_FROZEN))
 982                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 983                         if(getstatf(STAT_REVIVE_PROGRESS))
 984                         {
 985                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 986                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 987                         }
 988                 }
 989
 990                 if(autocvar_r_letterbox == 0)
 991                         if(autocvar_viewsize < 120)
 992                                 CSQC_common_hud();
 993
 994                 // crosshair goes VERY LAST
 995                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL) {
 996                         string wcross_style;
 997                         float wcross_alpha, wcross_resolution;
 998                         wcross_style = autocvar_crosshair;
 999                         if (wcross_style == "0")
1000                                 return;
1001                         wcross_resolution = autocvar_crosshair_size;
1002                         if (wcross_resolution == 0)
1003                                 return;
1004                         wcross_alpha = autocvar_crosshair_alpha;
1005                         if (wcross_alpha == 0)
1006                                 return;
1007
1008                         // TrueAim check
1009                         float shottype;
1010
1011                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1012                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
1013                         wcross_origin_z = 0;
1014                         if(autocvar_crosshair_hittest)
1015                         {
1016                                 vector wcross_oldorigin;
1017                                 wcross_oldorigin = wcross_origin;
1018                                 shottype = TrueAimCheck();
1019                                 if(shottype == SHOTTYPE_HITWORLD)
1020                                 {
1021                                         v = wcross_origin - wcross_oldorigin;
1022                                         v_x /= vid_conwidth;
1023                                         v_y /= vid_conheight;
1024                                         if(vlen(v) > 0.01)
1025                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1026                                 }
1027                                 if(!autocvar_crosshair_hittest_showimpact)
1028                                         wcross_origin = wcross_oldorigin;
1029                         }
1030                         else
1031                                 shottype = SHOTTYPE_HITWORLD;
1032
1033                         vector wcross_color, wcross_size;
1034                         string wcross_wep, wcross_name;
1035                         float wcross_scale, wcross_blur;
1036
1037                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
1038                                 e = get_weaponinfo(switchingweapon);
1039                                 if (e && e.netname != "")
1040                                 {
1041                                         wcross_wep = e.netname;
1042                                         if(autocvar_crosshair_per_weapon)
1043                                         {
1044                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1045                                                 if (wcross_resolution == 0)
1046                                                         return;
1047                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
1048                                                 if (wcross_alpha == 0)
1049                                                         return;
1050
1051                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1052                                                 if(wcross_style == "" || wcross_style == "0")
1053                                                         wcross_style = wcross_wep;
1054                                         }
1055                                 }
1056                         }
1057                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
1058                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
1059                         else if(autocvar_crosshair_color_by_health)
1060                         {
1061                                 float x = getstati(STAT_HEALTH);
1062
1063                                 //x = red
1064                                 //y = green
1065                                 //z = blue
1066
1067                                 wcross_color_z = 0;
1068
1069                                 if(x > 200)
1070                                 {
1071                                         wcross_color_x = 0;
1072                                         wcross_color_y = 1;
1073                                 }
1074                                 else if(x > 150)
1075                                 {
1076                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1077                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1078                                 }
1079                                 else if(x > 100)
1080                                 {
1081                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1082                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1083                                         wcross_color_z = 1 - (x-100)*0.02;
1084                                 }
1085                                 else if(x > 50)
1086                                 {
1087                                         wcross_color_x = 1;
1088                                         wcross_color_y = 1;
1089                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1090                                 }
1091                                 else if(x > 20)
1092                                 {
1093                                         wcross_color_x = 1;
1094                                         wcross_color_y = (x-20)*90/27/100;
1095                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
1096                                 }
1097                                 else
1098                                 {
1099                                         wcross_color_x = 1;
1100                                         wcross_color_y = 0;
1101                                 }
1102                         }
1103                         else
1104                                 wcross_color = stov(autocvar_crosshair_color);
1105
1106                         wcross_name = strcat("gfx/crosshair", wcross_style);
1107
1108                         if(autocvar_crosshair_effect_scalefade)
1109                         {
1110                                 wcross_scale = wcross_resolution;
1111                                 wcross_resolution = 1;
1112                         }
1113                         else
1114                         {
1115                                 wcross_scale = 1;
1116                         }
1117
1118                         if(autocvar_crosshair_pickup)
1119                         {
1120                                 float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
1121
1122                                 if(pickup_crosshair_time < stat_pickup_time)
1123                                 {
1124                                         if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1125                                                 pickup_crosshair_size = 1;
1126
1127                                         pickup_crosshair_time = stat_pickup_time;
1128                                 }
1129
1130                                 if(pickup_crosshair_size > 0)
1131                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1132                                 else
1133                                         pickup_crosshair_size = 0;
1134
1135                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1136                         }
1137
1138                         if(autocvar_crosshair_hitindication)
1139                         {
1140                                 vector hitindication_color = stov(autocvar_crosshair_hitindication_color);
1141                                 if(hitindication_crosshair_time < hit_time)
1142                                 {
1143                                         if(time - hit_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1144                                                 hitindication_crosshair_size = 1;
1145
1146                                         hitindication_crosshair_time = hit_time;
1147                                 }
1148
1149                                 if(hitindication_crosshair_size > 0)
1150                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1151                                 else
1152                                         hitindication_crosshair_size = 0;
1153
1154                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1155                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1156                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1157                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1158                         }
1159
1160                         if(shottype == SHOTTYPE_HITENEMY)
1161                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1162                         if(shottype == SHOTTYPE_HITTEAM)
1163                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1164
1165                         f = autocvar_crosshair_effect_speed;
1166                         if(f < 0)
1167                                 f *= -2 * g_weaponswitchdelay; // anim starts when weapon has been lowered and new weapon comes up
1168                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1169                         {
1170                                 wcross_changedonetime = time + f;
1171                         }
1172                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1173                         {
1174                                 wcross_name_changestarttime = time;
1175                                 wcross_name_changedonetime = time + f;
1176                                 if(wcross_name_goal_prev_prev)
1177                                         strunzone(wcross_name_goal_prev_prev);
1178                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1179                                 wcross_name_goal_prev = strzone(wcross_name);
1180                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1181                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1182                                 wcross_resolution_goal_prev = wcross_resolution;
1183                         }
1184
1185                         wcross_scale_goal_prev = wcross_scale;
1186                         wcross_alpha_goal_prev = wcross_alpha;
1187                         wcross_color_goal_prev = wcross_color;
1188
1189                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1190                         {
1191                                 wcross_blur = 1;
1192                                 wcross_alpha *= 0.75;
1193                         }
1194                         else
1195                                 wcross_blur = 0;
1196                         // *_prev is at time-frametime
1197                         // * is at wcross_changedonetime+f
1198                         // what do we have at time?
1199                         if(time < wcross_changedonetime)
1200                         {
1201                                 f = frametime / (wcross_changedonetime - time + frametime);
1202                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1203                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1204                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1205                         }
1206
1207                         wcross_scale_prev = wcross_scale;
1208                         wcross_alpha_prev = wcross_alpha;
1209                         wcross_color_prev = wcross_color;
1210
1211                         wcross_scale *= 1 - autocvar__menu_alpha;
1212                         wcross_alpha *= 1 - autocvar__menu_alpha;
1213                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1214
1215                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1216                         {
1217                                 // crosshair rings for weapon stats
1218                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1219                                 {
1220                                         // declarations and stats
1221                                         float ring_value, ring_scale, ring_alpha, ring_inner_value, ring_inner_alpha;
1222                                         string ring_image, ring_inner_image;
1223                                         vector ring_rgb, ring_inner_rgb;
1224
1225                                         ring_scale = autocvar_crosshair_ring_size;
1226
1227                                         float weapon_clipload, weapon_clipsize;
1228                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1229                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1230
1231                                         float nex_charge, nex_chargepool;
1232                                         nex_charge = getstatf(STAT_NEX_CHARGE);
1233                                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1234
1235                                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1236                                                 nex_charge_movingavg = nex_charge;
1237
1238
1239                                         // handle the values
1240                                         if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1241                                         {
1242                                                 if (nex_chargepool || use_nex_chargepool) {
1243                                                         use_nex_chargepool = 1;
1244                                                         ring_inner_value = nex_chargepool;
1245                                                 } else {
1246                                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1247                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1248                                                 }
1249
1250                                                 ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1251                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1252                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1253
1254                                                 // draw the outer ring to show the current charge of the weapon
1255                                                 ring_value = nex_charge;
1256                                                 ring_alpha = autocvar_crosshair_ring_nex_alpha;
1257                                                 ring_rgb = wcross_color;
1258                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1259                                         }
1260                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1261                                         {
1262                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1263                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1264                                                 ring_rgb = wcross_color;
1265                                                 ring_image = "gfx/crosshair_ring.tga";
1266                                         }
1267                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1268                                         {
1269                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1270                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1271                                                 ring_rgb = wcross_color;
1272                                                 ring_image = "gfx/crosshair_ring.tga";
1273                                         }
1274
1275                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1276                                         {
1277                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1278                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1279                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1280                                                 ring_rgb = wcross_color;
1281
1282                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1283                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1284                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1285                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1286                                                 else
1287                                                         ring_image = "gfx/crosshair_ring.tga";
1288                                         }
1289
1290                                         // if in weapon switch animation, fade ring out/in
1291                                         if(g_weaponswitchdelay > 0)
1292                                         {
1293                                                 f = (time - wcross_name_changestarttime) / g_weaponswitchdelay;
1294                                                 if(f > 0 && f < 2)
1295                                                         ring_alpha *= fabs(1 - f);
1296                                         }
1297
1298                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1299                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1300
1301                                         if (ring_value)
1302                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1303                                 }
1304
1305 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1306                                 do \
1307                                 { \
1308                                         if(wcross_blur > 0) \
1309                                         { \
1310                                                 for(i = -2; i <= 2; ++i) \
1311                                                 for(j = -2; j <= 2; ++j) \
1312                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1313                                         } \
1314                                         else \
1315                                         { \
1316                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1317                                         } \
1318                                 } \
1319                                 while(0)
1320
1321 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1322                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1323
1324 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1325                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1326
1327                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1328                                 {
1329                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1330                                         wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1331                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1332                                         f = 1 - f;
1333                                 }
1334                                 else
1335                                 {
1336                                         f = 1;
1337                                 }
1338                                 wcross_name_alpha_goal_prev = f;
1339
1340                                 wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1341                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1342
1343                                 if(autocvar_crosshair_dot)
1344                                 {
1345                                         vector wcross_color_old;
1346                                         wcross_color_old = wcross_color;
1347                                         if(autocvar_crosshair_dot_color != "0")
1348                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1349                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1350                                         // FIXME why don't we use wcross_alpha here?
1351                                         wcross_color = wcross_color_old;
1352                                 }
1353                         }
1354                 }
1355                 else
1356                 {
1357                         wcross_scale_prev = 0;
1358                         wcross_alpha_prev = 0;
1359                         wcross_scale_goal_prev = 0;
1360                         wcross_alpha_goal_prev = 0;
1361                         wcross_changedonetime = 0;
1362                         if(wcross_name_goal_prev)
1363                                 strunzone(wcross_name_goal_prev);
1364                         wcross_name_goal_prev = string_null;
1365                         if(wcross_name_goal_prev_prev)
1366                                 strunzone(wcross_name_goal_prev_prev);
1367                         wcross_name_goal_prev_prev = string_null;
1368                         wcross_name_changestarttime = 0;
1369                         wcross_name_changedonetime = 0;
1370                         wcross_name_alpha_goal_prev = 0;
1371                         wcross_name_alpha_goal_prev_prev = 0;
1372                         wcross_resolution_goal_prev = 0;
1373                         wcross_resolution_goal_prev_prev = 0;
1374                 }
1375         }
1376
1377         if(NextFrameCommand)
1378         {
1379                 localcmd("\n", NextFrameCommand, "\n");
1380                 NextFrameCommand = string_null;
1381         }
1382
1383         // we must do this check AFTER a frame was rendered, or it won't work
1384         if(cs_project_is_b0rked == 0)
1385         {
1386                 string w0, h0;
1387                 w0 = ftos(autocvar_vid_conwidth);
1388                 h0 = ftos(autocvar_vid_conheight);
1389                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
1390                 //R_SetView(VF_FOV, '90 90 0');
1391                 R_SetView(VF_ORIGIN, '0 0 0');
1392                 R_SetView(VF_ANGLES, '0 0 0');
1393                 R_SetView(VF_PERSPECTIVE, 1);
1394                 makevectors('0 0 0');
1395                 vector v1, v2;
1396                 cvar_set("vid_conwidth", "800");
1397                 cvar_set("vid_conheight", "600");
1398                 v1 = cs_project(v_forward);
1399                 cvar_set("vid_conwidth", "640");
1400                 cvar_set("vid_conheight", "480");
1401                 v2 = cs_project(v_forward);
1402                 if(v1 == v2)
1403                         cs_project_is_b0rked = 1;
1404                 else
1405                         cs_project_is_b0rked = -1;
1406                 cvar_set("vid_conwidth", w0);
1407                 cvar_set("vid_conheight", h0);
1408         }
1409
1410         if(autocvar__hud_configure)
1411                 HUD_Panel_Mouse();
1412
1413     if(hud && !intermission)
1414     {
1415         if(hud == HUD_SPIDERBOT)
1416             CSQC_SPIDER_HUD();
1417         else if(hud == HUD_WAKIZASHI)
1418             CSQC_WAKIZASHI_HUD();
1419         else if(hud == HUD_RAPTOR)
1420             CSQC_RAPTOR_HUD();
1421         else if(hud == HUD_BUMBLEBEE)
1422             CSQC_BUMBLE_HUD();
1423     }
1424         // let's reset the view back to normal for the end
1425         R_SetView(VF_MIN, '0 0 0');
1426         R_SetView(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1427 }
1428
1429
1430 void CSQC_common_hud(void)
1431 {
1432     // do some accuracy var caching
1433     float i;
1434     if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1435     {
1436         if(autocvar_accuracy_color_levels != acc_color_levels)
1437         {
1438             if(acc_color_levels)
1439                 strunzone(acc_color_levels);
1440             acc_color_levels = strzone(autocvar_accuracy_color_levels);
1441             acc_levels = tokenize_console(acc_color_levels);
1442             if (acc_levels > MAX_ACCURACY_LEVELS)
1443                 acc_levels = MAX_ACCURACY_LEVELS;
1444
1445             for (i = 0; i < acc_levels; ++i)
1446                 acc_lev[i] = stof(argv(i)) / 100.0;
1447         }
1448         // let know that acc_col[] needs to be loaded
1449         acc_col_x[0] = -1;
1450     }
1451
1452     HUD_Main(); // always run these functions for alpha checks
1453     HUD_DrawScoreboard();
1454
1455     if (scoreboard_active) // scoreboard/accuracy
1456         HUD_Reset();
1457     else if (intermission == 2) // map voting screen
1458     {
1459         HUD_FinaleOverlay();
1460         HUD_Reset();
1461     }
1462         /*
1463         switch(hud)
1464         {
1465                 case HUD_SPIDERBOT:
1466                         CSQC_SPIDER_HUD();
1467                         break;
1468
1469                 case HUD_WAKIZASHI:
1470                         CSQC_WAKIZASHI_HUD();
1471                         break;
1472
1473         case HUD_BUMBLEBEE:
1474             CSQC_BUMBLE_HUD();
1475             break;
1476         }
1477         */
1478 }
1479
1480
1481 // following vectors must be global to allow seamless switching between camera modes
1482 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1483 void CSQC_Demo_Camera()
1484 {
1485         float speed, attenuation, dimensions;
1486         vector tmp, delta;
1487
1488         if( autocvar_camera_reset || !camera_mode )
1489         {
1490                 camera_offset = '0 0 0';
1491                 current_angles = '0 0 0';
1492                 camera_direction = '0 0 0';
1493                 camera_offset_z += 30;
1494                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1495                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1496                 current_origin = view_origin;
1497                 current_camera_offset  = camera_offset;
1498                 cvar_set("camera_reset", "0");
1499                 camera_mode = CAMERA_CHASE;
1500         }
1501
1502         // Camera angles
1503         if( camera_roll )
1504                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1505
1506         if(autocvar_camera_look_player)
1507         {
1508                 vector dir;
1509                 float n;
1510
1511                 dir = normalize(view_origin - current_position);
1512                 n = mouse_angles_z;
1513                 mouse_angles = vectoangles(dir);
1514                 mouse_angles_x = mouse_angles_x * -1;
1515                 mouse_angles_z = n;
1516         }
1517         else
1518         {
1519                 tmp = getmousepos() * 0.1;
1520                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1521                 {
1522                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1523                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1524                 }
1525         }
1526
1527         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1528         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1529         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1530         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1531
1532         // Fix difference when angles don't have the same sign
1533         delta = '0 0 0';
1534         if(mouse_angles_y < -60 && current_angles_y > 60)
1535                 delta = '0 360 0';
1536         if(mouse_angles_y > 60 && current_angles_y < -60)
1537                 delta = '0 -360 0';
1538
1539         if(autocvar_camera_look_player)
1540                 attenuation = autocvar_camera_look_attenuation;
1541         else
1542                 attenuation = autocvar_camera_speed_attenuation;
1543
1544         attenuation = 1 / max(1, attenuation);
1545         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1546
1547         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1548         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1549         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1550         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1551
1552         // Camera position
1553         tmp = '0 0 0';
1554         dimensions = 0;
1555
1556         if( camera_direction_x )
1557         {
1558                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1559                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1560                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1561                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1562                 ++dimensions;
1563         }
1564
1565         if( camera_direction_y )
1566         {
1567                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1568                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1569                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1570                 ++dimensions;
1571         }
1572
1573         if( camera_direction_z )
1574         {
1575                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1576                 ++dimensions;
1577         }
1578
1579         if(autocvar_camera_free)
1580                 speed = autocvar_camera_speed_free;
1581         else
1582                 speed = autocvar_camera_speed_chase;
1583
1584         if(dimensions)
1585         {
1586                 speed = speed * sqrt(1 / dimensions);
1587                 camera_offset += tmp * speed;
1588         }
1589
1590         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1591
1592         // Camera modes
1593         if( autocvar_camera_free )
1594         {
1595                 if ( camera_mode == CAMERA_CHASE )
1596                 {
1597                         current_camera_offset = current_origin + current_camera_offset;
1598                         camera_offset = current_origin + camera_offset;
1599                 }
1600
1601                 camera_mode = CAMERA_FREE;
1602                 current_position = current_camera_offset;
1603         }
1604         else
1605         {
1606                 if ( camera_mode == CAMERA_FREE )
1607                 {
1608                         current_origin = view_origin;
1609                         camera_offset = camera_offset - current_origin;
1610                         current_camera_offset = current_camera_offset - current_origin;
1611                 }
1612
1613                 camera_mode = CAMERA_CHASE;
1614
1615                 if(autocvar_camera_chase_smoothly)
1616                         current_origin += (view_origin - current_origin) * attenuation;
1617                 else
1618                         current_origin = view_origin;
1619
1620                 current_position = current_origin + current_camera_offset;
1621         }
1622
1623         R_SetView(VF_ANGLES, current_angles);
1624         R_SetView(VF_ORIGIN, current_position);
1625 }