qcsrc/client/View.qc

   1 #define spider_rocket_icon "gfx/vehicles/rocket_ico.tga"
   2 #define spider_rocket_targ "gfx/vehicles/target.tga"
   3 #define SPIDER_CROSS "textures/spiderbot/cross.tga"
   4 #define rkt_size 32
   5 #define rld_size_x 256
   6 #define rld_size_y 16
   7
   8 void CSQC_WAKIZASHI_HUD();
   9
  10 entity porto;
  11 vector polyline[16];
  12 float trace_dphitcontents;
  13 float trace_networkentity;
  14 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
  15 float DPCONTENTS_SOLID = 1; // blocks player movement
  16 float DPCONTENTS_BODY = 32; // blocks player movement
  17 float DPCONTENTS_CORPSE = 64; // blocks player movement
  18 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
  19 void Porto_Draw()
  20 {
  21         vector p, dir, ang, q, nextdir;
  22         float idx, portal_number, portal1_idx;
  23
  24         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  25                 return;
  26         if(intermission == 1)
  27                 return;
  28         if(intermission == 2)
  29                 return;
  30         if (getstati(STAT_HEALTH) <= 0)
  31                 return;
  32
  33         dir = view_forward;
  34
  35         if(angles_held_status)
  36         {
  37                 makevectors(angles_held);
  38                 dir = v_forward;
  39         }
  40
  41         p = view_origin;
  42
  43         polyline[0] = p;
  44         idx = 1;
  45         portal_number = 0;
  46         nextdir = dir;
  47
  48         for(;;)
  49         {
  50                 dir = nextdir;
  51                 traceline(p, p + 65536 * dir, TRUE, porto);
  52                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  53                         return;
  54                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  55                 p = trace_endpos;
  56                 polyline[idx] = p;
  57                 ++idx;
  58                 if(idx >= 16)
  59                         return;
  60                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  61                         continue;
  62                 ++portal_number;
  63                 ang = vectoangles2(trace_plane_normal, dir);
  64                 ang_x = -ang_x;
  65                 makevectors(ang);
  66                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  67                         return;
  68                 if(portal_number == 1)
  69                         portal1_idx = idx;
  70                 if(portal_number >= 2)
  71                         break;
  72         }
  73
  74         while(idx >= 2)
  75         {
  76                 p = polyline[idx-2];
  77                 q = polyline[idx-1];
  78                 if(idx == 2)
  79                         p = p - view_up * 16;
  80                 if(idx-1 >= portal1_idx)
  81                 {
  82                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL);
  83                 }
  84                 else
  85                 {
  86                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL);
  87                 }
  88                 --idx;
  89         }
  90 }
  91
  92 /**
  93  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  94  *
  95  * TODO: Use a better solution where a common shared entitiy is used that contains
  96  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  97  * and STAT_FRAGLIMIT to be auto-sent)
  98  */
  99 void CheckForGamestartChange() {
 100         float startTime;
 101         startTime = getstatf(STAT_GAMESTARTTIME);
 102         if (previous_game_starttime != startTime) {
 103                 if ((time + 5.0) < startTime) {
 104                         //if connecting to server while restart was active don't always play prepareforbattle
 105                         sound(self, CHAN_VOICE, strcat("announcer/", cvar_string("cl_announcer"), "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
 106                 }
 107                 if (time < startTime) {
 108                         restartAnnouncer = spawn();
 109                         restartAnnouncer.think = restartAnnouncer_Think;
 110                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
 111                 }
 112         }
 113         previous_game_starttime = startTime;
 114 }
 115
 116 void Porto_Init()
 117 {
 118         porto = spawn();
 119         porto.classname = "porto";
 120         porto.draw = Porto_Draw;
 121         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 122 }
 123
 124 float drawtime;
 125 float avgspeed;
 126 vector GetCurrentFov(float fov)
 127 {
 128         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
 129
 130         zoomsensitivity = cvar("cl_zoomsensitivity");
 131         zoomfactor = cvar("cl_zoomfactor");
 132         if(zoomfactor < 1 || zoomfactor > 16)
 133                 zoomfactor = 2.5;
 134         zoomspeed = cvar("cl_zoomspeed");
 135         if(zoomspeed >= 0)
 136                 if(zoomspeed < 0.5 || zoomspeed > 16)
 137                         zoomspeed = 3.5;
 138
 139         zoomdir = button_zoom;
 140         if(getstati(STAT_ACTIVEWEAPON) == WEP_NEX) // do NOT use switchweapon here
 141                 zoomdir += button_attack2;
 142         if(spectatee_status > 0 || isdemo())
 143         {
 144                 if(spectatorbutton_zoom)
 145                         zoomdir = 0 + !zoomdir;
 146                 // do not even THINK about removing this 0
 147                 // _I_ know what I am doing
 148                 // fteqcc does not
 149         }
 150
 151         if(zoomdir)
 152                 zoomin_effect = 0;
 153
 154         if(zoomin_effect || camera_active)
 155         {
 156                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 157         }
 158         else
 159         {
 160                 if(zoomspeed < 0) // instant zoom
 161                 {
 162                         if(zoomdir)
 163                                 current_viewzoom = 1 / zoomfactor;
 164                         else
 165                                 current_viewzoom = 1;
 166                 }
 167                 else
 168                 {
 169                         if(zoomdir)
 170                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 171                         else
 172                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 173                 }
 174         }
 175
 176         if(almost_equals(current_viewzoom, 1))
 177                 current_zoomfraction = 0;
 178         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 179                 current_zoomfraction = 1;
 180         else
 181                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 182
 183         if(zoomsensitivity < 1)
 184                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 185         else
 186                 setsensitivityscale(1);
 187
 188         velocityzoom = bound(0, drawframetime / max(0.000000001, cvar_or("cl_velocityzoomtime", 0.3)), 1);
 189         avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
 190         velocityzoom = exp(float2range11(avgspeed * -cvar_or("cl_velocityzoom", 0) / 1) * 1);
 191
 192         //print(ftos(avgspeed), " avgspeed, ", ftos(cvar_or("cl_velocityzoom", 0)), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
 193
 194         float frustumx, frustumy, fovx, fovy;
 195         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 196         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 197         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 198         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 199
 200         return '1 0 0' * fovx + '0 1 0' * fovy;
 201 }
 202
 203 // this function must match W_SetupShot!
 204 float zoomscript_caught;
 205
 206 vector wcross_origin;
 207 float wcross_scale_prev, wcross_alpha_prev;
 208 vector wcross_color_prev;
 209 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 210 vector wcross_color_goal_prev;
 211 float wcross_changedonetime;
 212
 213 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 214 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 215 float wcross_name_changestarttime, wcross_name_changedonetime;
 216 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 217 entity trueaim;
 218 entity trueaim_rifle;
 219
 220 #define SHOTTYPE_HITTEAM 1
 221 #define SHOTTYPE_HITOBSTRUCTION 2
 222 #define SHOTTYPE_HITWORLD 3
 223 #define SHOTTYPE_HITENEMY 4
 224
 225 void TrueAim_Init()
 226 {
 227         trueaim = spawn();
 228         trueaim.classname = "trueaim";
 229         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 230         trueaim_rifle = spawn();
 231         trueaim_rifle.classname = "trueaim_rifle";
 232         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 233 }
 234
 235 float EnemyHitCheck()
 236 {
 237         float t;
 238         wcross_origin = project_3d_to_2d(trace_endpos);
 239         wcross_origin_z = 0;
 240         if(trace_networkentity < 1)
 241                 return SHOTTYPE_HITWORLD;
 242         if(trace_networkentity > maxclients)
 243                 return SHOTTYPE_HITWORLD;
 244         t = GetPlayerColor(trace_networkentity - 1);
 245         if(teamplay)
 246                 if(t == myteam)
 247                         return SHOTTYPE_HITTEAM;
 248         if(t == COLOR_SPECTATOR)
 249                 return SHOTTYPE_HITWORLD;
 250         return SHOTTYPE_HITENEMY;
 251 }
 252
 253 float TrueAimCheck()
 254 {
 255         float nudge = 1; // added to traceline target and subtracted from result
 256         vector vecs, trueaimpoint, w_shotorg;
 257         vector mi, ma, dv;
 258         float shottype;
 259         entity ta;
 260         float mv;
 261
 262         mi = ma = '0 0 0';
 263         ta = trueaim;
 264         mv = MOVE_NOMONSTERS;
 265
 266         switch(activeweapon)
 267         {
 268                 case WEP_TUBA: // no aim
 269                 case WEP_PORTO: // shoots from eye
 270                 case WEP_HOOK: // no trueaim
 271                 case WEP_GRENADE_LAUNCHER: // toss curve
 272                         return SHOTTYPE_HITWORLD;
 273                 case WEP_NEX:
 274                 case WEP_MINSTANEX:
 275                         mv = MOVE_NORMAL;
 276                         break;
 277                 case WEP_CAMPINGRIFLE:
 278                         ta = trueaim_rifle;
 279                         mv = MOVE_NORMAL;
 280                         if(zoomscript_caught)
 281                         {
 282                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 283                                 return EnemyHitCheck();
 284                         }
 285                         break;
 286                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 287                         mi = '-3 -3 -3';
 288                         ma = '3 3 3';
 289                         break;
 290                 case WEP_FIREBALL: // projectile has a size!
 291                         mi = '-16 -16 -16';
 292                         ma = '16 16 16';
 293                         break;
 294                 case WEP_SEEKER: // projectile has a size!
 295                         mi = '-2 -2 -2';
 296                         ma = '2 2 2';
 297                         break;
 298                 case WEP_ELECTRO: // projectile has a size!
 299                         mi = '0 0 -3';
 300                         ma = '0 0 -3';
 301                         break;
 302         }
 303
 304         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 305
 306         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 307         trueaimpoint = trace_endpos;
 308
 309         if(vecs_x > 0)
 310                 vecs_y = -vecs_y;
 311         else
 312                 vecs = '0 0 0';
 313
 314         dv = view_right * vecs_y + view_up * vecs_z;
 315         w_shotorg = view_origin + dv;
 316
 317         // now move the vecs forward as much as requested if possible
 318         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 319         w_shotorg = trace_endpos - view_forward * nudge;
 320
 321         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 322         shottype = EnemyHitCheck();
 323         if(shottype != SHOTTYPE_HITWORLD)
 324                 return shottype;
 325
 326 #if 0
 327         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 328         // or rather, I know why, but see no fix
 329         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 330                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 331                 return SHOTTYPE_HITOBSTRUCTION;
 332 #endif
 333
 334         return SHOTTYPE_HITWORLD;
 335 }
 336
 337 void CSQC_common_hud(void);
 338
 339 void PostInit(void);
 340 void CSQC_Demo_Camera();
 341 float HUD_WouldDrawScoreboard ();
 342 float view_set;
 343 float camera_mode;
 344 float zoom_type;
 345 string NextFrameCommand;
 346 void CSQC_SPIDER_HUD();
 347 void CSQC_RAPTOR_HUD();
 348
 349 vector freeze_pmove_org, freeze_input_angles;
 350
 351 void CSQC_UpdateView(float w, float h)
 352 {
 353         entity e;
 354         float fov;
 355         float f, i, j;
 356         vector v, vo;
 357
 358         vector reticle_pos, reticle_size;
 359
 360         WaypointSprite_Load();
 361
 362         if(spectatee_status)
 363                 myteam = GetPlayerColor(spectatee_status - 1);
 364         else
 365                 myteam = GetPlayerColor(player_localentnum - 1);
 366
 367         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 368         vo = '0 0 1' * getstati(STAT_VIEWHEIGHT);
 369
 370         warpzone_fixview_origin = pmove_org + vo;
 371         warpzone_fixview_cl_viewangles = input_angles;
 372         warpzone_fixview_angles = view_angles;
 373         WarpZone_FixView();
 374         pmove_org = warpzone_fixview_origin - vo;
 375         input_angles = warpzone_fixview_cl_viewangles;
 376         view_angles = warpzone_fixview_angles;
 377
 378         if(cvar("cl_lockview") || hud_configure)
 379         {
 380                 pmove_org = freeze_pmove_org;
 381                 input_angles = view_angles = freeze_input_angles;
 382                 R_SetView(VF_ORIGIN, pmove_org + vo);
 383                 R_SetView(VF_ANGLES, view_angles);
 384                 //R_SetView(VF_CL_VIEWANGLES, input_angles);
 385         }
 386         freeze_pmove_org = pmove_org;
 387         freeze_input_angles = input_angles;
 388
 389         // Render the Scene
 390         if(!intermission || !view_set)
 391         {
 392                 view_origin = pmove_org + vo;
 393                 view_angles = input_angles;
 394                 makevectors(view_angles);
 395                 view_forward = v_forward;
 396                 view_right = v_right;
 397                 view_up = v_up;
 398                 view_set = 1;
 399         }
 400
 401         vid_width = w;
 402         vid_height = h;
 403
 404 #ifdef BLURTEST
 405         if(time > blurtest_time0 && time < blurtest_time1)
 406         {
 407                 float r, t;
 408
 409                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 410                 r = t * blurtest_radius;
 411                 f = 1 / pow(t, blurtest_power) - 1;
 412
 413                 cvar_set("r_glsl_postprocess", "1");
 414                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 415         }
 416         else
 417         {
 418                 cvar_set("r_glsl_postprocess", "0");
 419                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 420         }
 421 #endif
 422
 423         TargetMusic_Advance();
 424         Fog_Force();
 425
 426         drawframetime = max(0.000001, time - drawtime);
 427         drawtime = time;
 428
 429         // watch for gametype changes here...
 430         // in ParseStuffCMD the cmd isn't executed yet :/
 431         // might even be better to add the gametype to TE_CSQC_INIT...?
 432         if(!postinit)
 433                 PostInit();
 434
 435         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 436                 if(calledhooks & HOOK_START)
 437                 {
 438                         localcmd("\ncl_hook_gameend;");
 439                         calledhooks |= HOOK_END;
 440                 }
 441
 442         CheckForGamestartChange();
 443         serverAnnouncer();
 444         maptimeAnnouncer();
 445         carrierAnnouncer();
 446
 447         fov = cvar("fov");
 448         if(button_zoom || fov <= 59.5)
 449         {
 450                 if(!zoomscript_caught)
 451                 {
 452                         localcmd("+button4\n");
 453                         zoomscript_caught = 1;
 454                         ignore_plus_zoom += 1;
 455                 }
 456         }
 457         else
 458         {
 459                 if(zoomscript_caught)
 460                 {
 461                         localcmd("-button4\n");
 462                         zoomscript_caught = 0;
 463                         ignore_minus_zoom += 1;
 464                 }
 465         }
 466
 467         hud_accuracy_hud = cvar_or("hud_accuracy_hud", 1);
 468         ColorTranslateMode = cvar("cl_stripcolorcodes");
 469         activeweapon = getstati(STAT_SWITCHWEAPON);
 470         f = cvar("teamplay");
 471         if(f != teamplay)
 472         {
 473                 teamplay = f;
 474                 HUD_InitScores();
 475         }
 476
 477         if(last_weapon != activeweapon) {
 478                 weapontime = time;
 479                 last_weapon = activeweapon;
 480         }
 481
 482         // ALWAYS Clear Current Scene First
 483         R_ClearScene();
 484
 485         // Assign Standard Viewflags
 486         // Draw the World (and sky)
 487         R_SetView(VF_DRAWWORLD, 1);
 488
 489         // Set the console size vars
 490         vid_conwidth = cvar("vid_conwidth");
 491         vid_conheight = cvar("vid_conheight");
 492         vid_pixelheight = cvar("vid_pixelheight");
 493
 494         R_SetView(VF_FOV, GetCurrentFov(fov));
 495
 496         // Camera for demo playback
 497         if(camera_active)
 498         {
 499                 if(cvar("camera_enable"))
 500                         CSQC_Demo_Camera();
 501                 else
 502                 {
 503                         cvar_set("chase_active", ftos(chase_active_backup));
 504                         cvar_set("cl_demo_mousegrab", "0");
 505                         camera_active = FALSE;
 506                 }
 507         }
 508 #ifdef CAMERATEST
 509         else if(cvar("camera_enable"))
 510 #else
 511         else if(cvar("camera_enable") && isdemo())
 512 #endif
 513         {
 514                 // Enable required Darkplaces cvars
 515                 chase_active_backup = cvar("chase_active");
 516                 cvar_set("chase_active", "2");
 517                 cvar_set("cl_demo_mousegrab", "1");
 518                 camera_active = TRUE;
 519                 camera_mode = FALSE;
 520         }
 521
 522         // Draw the Crosshair
 523         float scoreboard_active;
 524         scoreboard_active = HUD_WouldDrawScoreboard();
 525         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 526
 527         // Draw the Engine Status Bar (the default Quake HUD)
 528         R_SetView(VF_DRAWENGINEHUD, 0);
 529
 530         // fetch this one only once per frame
 531         hud_showbinds = cvar("hud_showbinds");
 532         hud_showbinds_limit = cvar("hud_showbinds_limit");
 533
 534         // Update the mouse position
 535         /*
 536            mousepos_x = vid_conwidth;
 537            mousepos_y = vid_conheight;
 538            mousepos = mousepos*0.5 + getmousepos();
 539          */
 540
 541         e = self;
 542         for(self = world; (self = nextent(self)); )
 543                 if(self.draw)
 544                         self.draw();
 545         self = e;
 546
 547         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 548         R_RenderScene();
 549
 550         // now switch to 2D drawing mode by calling a 2D drawing function
 551         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 552         // next R_RenderScene call
 553         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 554
 555         // draw the aiming reticle for weapons that use it (eg. Nex)
 556         // zoom_type is changed to the item we are zooming with, to decide which reticle to use
 557         if(button_zoom)
 558                 zoom_type = 0; // normal zoom
 559         else if(activeweapon == WEP_NEX && button_attack2)
 560                 zoom_type = 1; // nex zoom
 561
 562         reticle_size_x = max(vid_conwidth, vid_conheight);
 563         reticle_size_y = max(vid_conwidth, vid_conheight);
 564         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 565         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 566
 567         if(cvar("cl_reticle_nex"))
 568         {
 569                 precache_pic("textures/reticle_nex");
 570                 if(zoom_type == 1)
 571                         drawpic(reticle_pos, "textures/reticle_nex", reticle_size, '1 1 1', current_zoomfraction * cvar("cl_reticle_nex"), DRAWFLAG_NORMAL);
 572         }
 573
 574         // Draw the mouse cursor
 575         // NOTE: drawpic must happen after R_RenderScene for some reason
 576         //drawpic(getmousepos(), "gfx/cursor.tga", '11 14 0', '1 1 1', 1, 0);
 577         //drawstring('50 50', ftos(game), '10 10 0', '1 1 1', 1, 0);
 578         //self = edict_num(player_localnum);
 579         //drawstring('0 0', vtos(pmove_org), '8 8 0', '1 1 1', 1, 0);
 580         //drawstring('0 8', strcat("ORG: ", vtos(self.origin), " state: ", ftos(self.ctf_state), " HP: ", ftos(self.health)), '8 8 0', '1 1 1', 1, 0);
 581         // as long as the ctf part isn't in, this is useless
 582         if(menu_visible)
 583                 menu_show();
 584
 585         /*if(gametype == GAME_CTF)
 586           {
 587           ctf_view();
 588           } else */
 589
 590         // draw 2D entities
 591         e = self;
 592         for(self = world; (self = nextent(self)); )
 593                 if(self.draw2d)
 594                         self.draw2d();
 595         self = e;
 596
 597         // draw hud
 598         if(cvar("r_letterbox") == 0) {
 599                 HUD_DrawCenterPrint(); // draw centerprint messages even if viewsize >= 120
 600         }
 601
 602         float hud;
 603         hud = getstati(STAT_HUD);
 604         if(hud == HUD_SPIDERBOT)
 605         {
 606                 CSQC_SPIDER_HUD();
 607         }
 608         else if(hud == HUD_WAKIZASHI)
 609         CSQC_WAKIZASHI_HUD();
 610     else if(hud == HUD_RAPTOR)
 611         CSQC_RAPTOR_HUD();
 612         else
 613         {
 614                 if(cvar("r_letterbox") == 0)
 615                         if(cvar("viewsize") < 120)
 616                                 CSQC_common_hud();
 617
 618                 // crosshair goes VERY LAST
 619                 if(!scoreboard_active && !camera_active) {
 620                         // TrueAim check
 621                         float shottype;
 622                         float bullets, ring_scale;
 623                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 624                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 625                         wcross_origin_z = 0;
 626                         if(cvar("crosshair_hittest"))
 627                         {
 628                                 vector wcross_oldorigin;
 629                                 wcross_oldorigin = wcross_origin;
 630                                 shottype = TrueAimCheck();
 631                                 if(shottype == SHOTTYPE_HITWORLD)
 632                                 {
 633                                         v = wcross_origin - wcross_oldorigin;
 634                                         v_x /= vid_conwidth;
 635                                         v_y /= vid_conheight;
 636                                         if(vlen(v) > 0.01)
 637                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
 638                                 }
 639                                 if(!cvar("crosshair_hittest_showimpact"))
 640                                         wcross_origin = wcross_oldorigin;
 641                         }
 642                         else
 643                                 shottype = SHOTTYPE_HITWORLD;
 644
 645                         string wcross_style;
 646                         wcross_style = cvar_string("crosshair");
 647
 648                         if (wcross_style != "0") {
 649                                 vector wcross_color, wcross_size;
 650                                 string wcross_wep, wcross_name;
 651                                 float wcross_alpha, wcross_scale, wcross_blur, wcross_resolution;
 652
 653                                 wcross_color_x = cvar("crosshair_color_red");
 654                                 wcross_color_y = cvar("crosshair_color_green");
 655                                 wcross_color_z = cvar("crosshair_color_blue");
 656                                 wcross_alpha = cvar("crosshair_color_alpha");
 657                                 wcross_resolution = cvar("crosshair_size");
 658                                 if (cvar("crosshair_per_weapon")) {
 659                                         e = get_weaponinfo(activeweapon);
 660                                         if (e && e.netname != "")
 661                                         {
 662                                                 wcross_wep = e.netname;
 663                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 664                                                 if(wcross_style == "")
 665                                                         wcross_style = e.netname;
 666
 667                                                 if(!cvar("crosshair_color_override"))
 668                                                 {
 669                                                         wcross_color_x = cvar(strcat("crosshair_", wcross_wep, "_color_red"));
 670                                                         wcross_color_y = cvar(strcat("crosshair_", wcross_wep, "_color_green"));
 671                                                         wcross_color_z = cvar(strcat("crosshair_", wcross_wep, "_color_blue"));
 672                                                 }
 673
 674                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_color_alpha"));
 675                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 676                                         }
 677                                 }
 678
 679                                 wcross_name = strcat("gfx/crosshair", wcross_style);
 680
 681                                 if(cvar("crosshair_effect_scalefade"))
 682                                 {
 683                                         wcross_scale = wcross_resolution;
 684                                         wcross_resolution = 1;
 685                                 }
 686                                 else
 687                                 {
 688                                         wcross_scale = 1;
 689                                 }
 690
 691                                 if(shottype == SHOTTYPE_HITENEMY)
 692                                         wcross_scale *= cvar("crosshair_hittest"); // is not queried if hittest is 0
 693                                 if(shottype == SHOTTYPE_HITTEAM)
 694                                         wcross_scale /= cvar("crosshair_hittest"); // is not queried if hittest is 0
 695
 696                                 f = cvar("crosshair_effect_speed");
 697                                 if(f < 0)
 698                                         f *= -2 * g_weaponswitchdelay;
 699                                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
 700                                 {
 701                                         wcross_changedonetime = time + f;
 702                                 }
 703                                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
 704                                 {
 705                                         wcross_name_changestarttime = time;
 706                                         wcross_name_changedonetime = time + f;
 707                                         if(wcross_name_goal_prev_prev)
 708                                                 strunzone(wcross_name_goal_prev_prev);
 709                                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
 710                                         wcross_name_goal_prev = strzone(wcross_name);
 711                                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
 712                                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
 713                                         wcross_resolution_goal_prev = wcross_resolution;
 714                                 }
 715
 716                                 wcross_scale_goal_prev = wcross_scale;
 717                                 wcross_alpha_goal_prev = wcross_alpha;
 718                                 wcross_color_goal_prev = wcross_color;
 719
 720                                 if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && cvar("crosshair_hittest_blur") && !cvar("chase_active")))
 721                                 {
 722                                         wcross_blur = 1;
 723                                         wcross_alpha *= 0.75;
 724                                 }
 725                                 else
 726                                         wcross_blur = 0;
 727                                 // *_prev is at time-frametime
 728                                 // * is at wcross_changedonetime+f
 729                                 // what do we have at time?
 730                                 if(time < wcross_changedonetime)
 731                                 {
 732                                         f = frametime / (wcross_changedonetime - time + frametime);
 733                                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
 734                                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
 735                                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
 736                                 }
 737
 738                                 wcross_scale_prev = wcross_scale;
 739                                 wcross_alpha_prev = wcross_alpha;
 740                                 wcross_color_prev = wcross_color;
 741
 742                                 wcross_scale *= 1 - cvar("_menu_alpha");
 743                                 wcross_alpha *= 1 - cvar("_menu_alpha");
 744
 745                                 // ring around crosshair representing bullets left in camping rifle clip
 746                                 if (activeweapon == WEP_CAMPINGRIFLE)
 747                                 {
 748                                         ring_scale = cvar("crosshair_campingrifle_ring_size");
 749                                         bullets = bound(0, getstati(STAT_BULLETS_LOADED), 8);
 750                                 }
 751                                 else
 752                                         bullets = 0;
 753
 754 #define CROSSHAIR_DRAW_RING(i,j,sz,wcross_name,wcross_alpha) \
 755                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x * ring_scale + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y * ring_scale + j * wcross_blur)), strcat("gfx/hud/", cvar_string("hud_skin"), "/rifle_ring_", ftos(bullets)), sz * wcross_size * ring_scale, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
 756
 757 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
 758                                 do \
 759                                 { \
 760                                         if(wcross_blur > 0) \
 761                                         { \
 762                                                 for(i = -2; i <= 2; ++i) \
 763                                                         for(j = -2; j <= 2; ++j) \
 764                                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
 765                                         } \
 766                                         else \
 767                                         { \
 768                                                 M(0,0,sz,wcross_name,wcross_alpha); \
 769                                         } \
 770                                 } \
 771                                 while(0)
 772
 773 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
 774                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
 775
 776 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
 777                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
 778
 779                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
 780                                 {
 781                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
 782                                         wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
 783                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
 784                                         f = 1 - f;
 785                                 }
 786                                 else
 787                                 {
 788                                         f = 1;
 789                                 }
 790
 791                                 wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
 792                                 if(bullets)
 793                                 {
 794                                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_RING, wcross_resolution, wcross_name, wcross_alpha);
 795                                 }
 796                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
 797                                 wcross_name_alpha_goal_prev = f;
 798                         }
 799                 }
 800                 else
 801                 {
 802                         wcross_scale_prev = 0;
 803                         wcross_alpha_prev = 0;
 804                         wcross_scale_goal_prev = 0;
 805                         wcross_alpha_goal_prev = 0;
 806                         wcross_changedonetime = 0;
 807                         if(wcross_name_goal_prev)
 808                                 strunzone(wcross_name_goal_prev);
 809                         wcross_name_goal_prev = string_null;
 810                         if(wcross_name_goal_prev_prev)
 811                                 strunzone(wcross_name_goal_prev_prev);
 812                         wcross_name_goal_prev_prev = string_null;
 813                         wcross_name_changestarttime = 0;
 814                         wcross_name_changedonetime = 0;
 815                         wcross_name_alpha_goal_prev = 0;
 816                         wcross_name_alpha_goal_prev_prev = 0;
 817                         wcross_resolution_goal_prev = 0;
 818                         wcross_resolution_goal_prev_prev = 0;
 819                 }
 820         }
 821
 822         if(NextFrameCommand)
 823         {
 824                 localcmd("\n", NextFrameCommand, "\n");
 825                 NextFrameCommand = string_null;
 826         }
 827
 828         // we must do this check AFTER a frame was rendered, or it won't work
 829         if(cs_project_is_b0rked == 0)
 830         {
 831                 string w0, h0;
 832                 w0 = cvar_string("vid_conwidth");
 833                 h0 = cvar_string("vid_conheight");
 834                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
 835                 //R_SetView(VF_FOV, '90 90 0');
 836                 R_SetView(VF_ORIGIN, '0 0 0');
 837                 R_SetView(VF_ANGLES, '0 0 0');
 838                 R_SetView(VF_PERSPECTIVE, 1);
 839                 makevectors('0 0 0');
 840                 vector v1, v2;
 841                 cvar_set("vid_conwidth", "800");
 842                 cvar_set("vid_conheight", "600");
 843                 v1 = cs_project(v_forward);
 844                 cvar_set("vid_conwidth", "640");
 845                 cvar_set("vid_conheight", "480");
 846                 v2 = cs_project(v_forward);
 847                 if(v1 == v2)
 848                         cs_project_is_b0rked = 1;
 849                 else
 850                         cs_project_is_b0rked = -1;
 851                 cvar_set("vid_conwidth", w0);
 852                 cvar_set("vid_conheight", h0);
 853         }
 854
 855         if(hud_configure)
 856                 HUD_Panel_Mouse();
 857         // be safe against triggerbots until everyone has the fixed engine
 858         // this call is meant to overwrite the trace globals by something
 859         // unsuspicious
 860         traceline('0 0 0', '0 0 0', MOVE_WORLDONLY, world);
 861 }
 862
 863 #define spider_h "gfx/vehicles/hud_bg.tga"
 864 #define spider_b "gfx/vehicles/sbot.tga"
 865 #define spider_r "gfx/vehicles/sbot_rpods.tga"
 866 #define spider_g "gfx/vehicles/sbot_mguns.tga"
 867 #define spider_s "gfx/vehicles/shiled.tga"
 868 #define spider_a1 "gfx/hud/sb_rocket.tga"
 869 #define spider_a2 "gfx/sb_bullets.tga"
 870
 871 void CSQC_SPIDER_HUD()
 872 {
 873         float rockets, reload, heat, hp, shield;
 874         vector picsize, hudloc;
 875
 876     // Fetch health & ammo stats
 877     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
 878         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
 879         heat    = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 2);
 880         rockets =     getstati(STAT_VEHICLESTAT_AMMO2);
 881         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD2), 1);
 882
 883     // Draw the crosshairs
 884     picsize = drawgetimagesize(SPIDER_CROSS);
 885     picsize_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
 886     picsize_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
 887     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
 888
 889     hudloc_y =  4;
 890     hudloc_x = 4;
 891
 892     picsize = drawgetimagesize(spider_h) * 0.5;
 893     drawpic(hudloc, spider_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
 894
 895     picsize = drawgetimagesize(spider_a2) * 0.5;
 896     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
 897
 898     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
 899     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
 900     drawstring(hudloc + '136 102  0', strcat(ftos(100 - rint(heat * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
 901
 902     picsize = drawgetimagesize(spider_a1) * 0.85;
 903     if(rockets == 9)
 904     {
 905         drawpic(hudloc + '132 54  0', spider_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
 906         drawstring(hudloc + '179 69 0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
 907     }
 908     else
 909     {
 910         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
 911         drawstring(hudloc + '179 69  0', strcat(ftos(9 - rockets), "/8"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
 912     }
 913
 914     picsize = drawgetimagesize(spider_b) * 0.5;
 915     hudloc_y = 10.5;
 916     hudloc_x = 10.5;
 917
 918     drawpic(hudloc, spider_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
 919     drawpic(hudloc, spider_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
 920     drawpic(hudloc, spider_r, picsize, '1 1 1' * reload + '1 0 0' * (1 - reload), 1, DRAWFLAG_NORMAL);
 921     drawpic(hudloc, spider_g, picsize, '1 1 1' * (1 - heat) + '1 0 0' *  heat, 1, DRAWFLAG_NORMAL);
 922
 923
 924         /*
 925         // Draw health bar
 926         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
 927         p = p + '0 1 0' * vid_conheight - '0 32 0';
 928         //pp = ('0 1 0' * hp) + ('1 0 0' * (1-hp));
 929         drawfill(p, '256 0 0' * shield + '0 8 0' , '0.5 0.5 1', 0.75, DRAWFLAG_NORMAL);
 930         p_y += 8;
 931         drawfill(p, '256 0 0' * hp + '0 8 0' , '0 1 0', 0.75, DRAWFLAG_NORMAL);
 932         p_x += 256 * hp;
 933         drawfill(p, '256 0 0' * (1-hp) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
 934
 935         // Draw minigun heat indicator
 936         p = '0.5 0 0' * (vid_conwidth - 256);
 937         p = p + '0 1 0' * vid_conheight - '0 34  0';
 938         drawfill(p, '256 0 0' * (1-heat) + '0 2 0' ,'0 0 1', 0.5, DRAWFLAG_NORMAL);
 939         p_x += 256 * (1-heat);
 940         drawfill(p, '256 0 0' * heat  + '0 2 0' , '1 0 0', 0.5, DRAWFLAG_NORMAL);
 941
 942
 943         // Draw rocket icons for loaded/empty tubes.
 944         pp = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
 945         pp += '0 1 0' * vid_conheight - '0 64 0';
 946         for(i = 0; i < 8; ++i)
 947         {
 948                 p = pp + '1 0 0' * (rkt_size * i);
 949                 if(rockets == 8)
 950                 {
 951                         if(floor(reload * 8) == i)
 952                         {
 953                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 0 0' + '0 1 0' * ((reload*8)-i), 0.75 , DRAWFLAG_NORMAL);
 954                         }
 955                         else if(i < reload * 8)
 956                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 1 0', 0.75 , DRAWFLAG_NORMAL);
 957                         else
 958                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0.5 0.5 0.5', 0.75, DRAWFLAG_NORMAL);
 959                 }
 960                 else
 961                 {
 962                         if(i < rockets)
 963                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 0 0', 0.25, DRAWFLAG_NORMAL);
 964                         else
 965                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 1 0' * reload, 0.75, DRAWFLAG_NORMAL);
 966                 }
 967         }
 968         */
 969
 970         if (scoreboard_showscores)
 971         {
 972                 HUD_DrawScoreboard();
 973                 HUD_DrawCenterPrint();
 974         }
 975
 976 }
 977
 978 #define raptor_h "gfx/vehicles/hud_bg.tga"
 979 #define raptor_b "gfx/vehicles/raptor.tga"
 980 #define raptor_g1 "gfx/vehicles/raptor_guns.tga"
 981 #define raptor_g2 "gfx/vehicles/raptor_bombs.tga"
 982 #define raptor_s "gfx/vehicles/shiled.tga"
 983
 984 void CSQC_RAPTOR_HUD()
 985 {
 986         float rockets, reload, heat, hp, shield, energy;
 987         vector picsize, hudloc;
 988
 989     // Fetch health & ammo stats
 990     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
 991         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
 992         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
 993         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
 994
 995     // Draw the crosshairs
 996     picsize = drawgetimagesize(SPIDER_CROSS);
 997     picsize_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
 998     picsize_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
 999     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
1000
1001     hudloc_y =  4;
1002     hudloc_x = 4;
1003
1004     picsize = drawgetimagesize(raptor_h) * 0.5;
1005     drawpic(hudloc, raptor_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1006
1007     picsize = drawgetimagesize(spider_a2) * 0.5;
1008     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1009
1010     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1011     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1012     drawstring(hudloc + '136 102 0', strcat(ftos(rint(energy * 100)), "%"),'15 15 0','0.5 0.5 1', 1, DRAWFLAG_NORMAL);
1013
1014
1015     picsize = drawgetimagesize(spider_a1) * 0.85;
1016     if(reload == 1)
1017     {
1018         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1019         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 1 0', 0.5, DRAWFLAG_NORMAL);
1020     }
1021     else
1022     {
1023         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1024         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 0 1', 1, DRAWFLAG_NORMAL);
1025     }
1026
1027     picsize = drawgetimagesize(raptor_b) * 0.5;
1028     hudloc_y = 10.5;
1029     hudloc_x = 10.5;
1030
1031     drawpic(hudloc, raptor_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1032     drawpic(hudloc, raptor_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1033     drawpic(hudloc, raptor_g1, picsize, '1 1 1' * energy + '1 0 0' * (1 - energy), 1, DRAWFLAG_NORMAL);
1034     drawpic(hudloc, raptor_g2, picsize, '1 1 1' * reload + '1 0 0' *  (1 - reload), 1, DRAWFLAG_NORMAL);
1035
1036
1037         if (scoreboard_showscores)
1038         {
1039                 HUD_DrawScoreboard();
1040                 HUD_DrawCenterPrint();
1041         }
1042
1043 }
1044
1045 #define waki_h "gfx/vehicles/hud_bg.tga"
1046 #define waki_b "gfx/vehicles/waki.tga"
1047 #define waki_e "gfx/vehicles/waki_e.tga"
1048 #define waki_g "gfx/vehicles/waki_guns.tga"
1049 #define waki_r "gfx/vehicles/waki_rockets.tga"
1050 #define waki_s "gfx/vehicles/shiled.tga"
1051
1052 #define waki_a1 "gfx/hud/sb_rocket.tga"
1053 #define waki_a2 "gfx/sb_cells.tga"
1054
1055 void CSQC_WAKIZASHI_HUD()
1056 {
1057         // 0--1 floats. 1 = 100%, 0.6 = 50%.
1058         float health, shield, energy, rockets;
1059         vector picsize, hudloc;
1060
1061     picsize = drawgetimagesize(SPIDER_CROSS);
1062     picsize_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1063     picsize_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1064     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
1065
1066 /*
1067 const float STAT_VEHICLESTAT_HEALTH  = 60;
1068 const float STAT_VEHICLESTAT_SHIELD  = 61;
1069 const float STAT_VEHICLESTAT_ENERGY  = 62;
1070 const float STAT_VEHICLESTAT_AMMO1   = 63;
1071 const float STAT_VEHICLESTAT_RELAOD1 = 64;
1072 const float STAT_VEHICLESTAT_AMMO2   = 65;
1073 const float STAT_VEHICLESTAT_RELOAD2 = 66;
1074 */
1075     health  = min(getstatf(STAT_VEHICLESTAT_HEALTH),  1);
1076         shield  = min(getstatf(STAT_VEHICLESTAT_SHIELD),  1);
1077         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1078         rockets = bound(0,getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1079
1080     hudloc_y =  4;
1081     hudloc_x = 4;
1082
1083     picsize = drawgetimagesize(waki_h) * 0.5;
1084     drawpic(hudloc, waki_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1085
1086     picsize = drawgetimagesize(waki_a2) * 0.7;
1087     drawpic(hudloc + '116 92  0', waki_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1088
1089
1090     drawstring(hudloc + '145 19  0', strcat(ftos(rint(health * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1091     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1092
1093     drawstring(hudloc + '136 102  0', strcat(ftos(rint(energy * 100)), "%"),'14 14 0','1 1 1', 1, DRAWFLAG_NORMAL);
1094
1095     picsize = drawgetimagesize(waki_a1) * 0.75;
1096     if(rockets == 1)
1097     {
1098         drawpic(hudloc + '140 55  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1099         drawpic(hudloc + '144 59  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1100     }
1101     else
1102     {
1103         drawpic(hudloc + '140 55  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1104         drawpic(hudloc + '144 59  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1105         drawstring(hudloc + '165 69 0', strcat(ftos(rint(rockets * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1106     }
1107
1108     picsize = drawgetimagesize(waki_b) * 0.5;
1109     hudloc_y = 10.5;
1110     hudloc_x = 10.5;
1111
1112     drawpic(hudloc, waki_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1113     drawpic(hudloc, waki_b, picsize, '0 1 0' * health + '1 0 0' * (1 - health), 1, DRAWFLAG_NORMAL);
1114     drawpic(hudloc, waki_r, picsize, '1 1 1' * rockets + '1 0 0' * (1 - rockets), 1, DRAWFLAG_NORMAL);
1115     drawpic(hudloc, waki_e, picsize, '1 1 1' * energy + '1 0 0' *  (1 - energy), 1, DRAWFLAG_NORMAL);
1116
1117
1118
1119         /*
1120         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1121         p = p + '0 1 0' * vid_conheight - '0 32 0';
1122
1123         // Draw health bar
1124         p_y += 8;
1125         drawfill(p, '256 0 0' * health + '0 8 0' , '0 0.7 0', 0.75, DRAWFLAG_NORMAL);
1126         p_x += 256 * health;
1127         drawfill(p, '256 0 0' * (1 - health) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1128
1129         // Draw shiled bar
1130         p_x -= 256 * health;
1131         p_y += 4;
1132         drawfill(p, '256 0 0' * shield + '0 4 0' , '0.25 0.25 1', 0.5, DRAWFLAG_NORMAL);
1133
1134         // Draw energy
1135         //p_x -= 256 * health;
1136         p_y -= 8;
1137         drawfill(p, '256 0 0' * energy + '0 4 0' , '1 1 1', 0.75, DRAWFLAG_NORMAL);
1138
1139         // Draw rockets bar
1140         p_y += 12;
1141         drawfill(p, '256 0 0' * rockets + '0 4 0' , '1 0 0', 0.75, DRAWFLAG_NORMAL);
1142         */
1143
1144
1145
1146
1147         if (scoreboard_showscores)
1148         {
1149                 HUD_DrawScoreboard();
1150                 HUD_DrawCenterPrint();
1151         }
1152
1153 }
1154
1155
1156 void CSQC_common_hud(void)
1157 {
1158         // HUD_SortFrags(); done in HUD_Draw
1159         float hud;
1160         hud = getstati(STAT_HUD);
1161
1162         //hud = 10;
1163         switch(hud)
1164         {
1165                 case HUD_NORMAL:
1166                         // hud first
1167                         HUD_Main();
1168
1169                         // scoreboard/accuracy
1170                         if (intermission == 2 && !scoreboard_showaccuracy && !scoreboard_showscores) // map voting screen
1171                         {
1172                                 HUD_FinaleOverlay();
1173                                 HUD_Reset();
1174                         }
1175                         else if(scoreboard_showaccuracy && spectatee_status != -1)
1176                                 HUD_DrawAccuracyStats();
1177                         else
1178                                 HUD_DrawScoreboard();
1179
1180                         if (scoreboard_showscores || scoreboard_showaccuracy || scoreboard_showscores_force || getstati(STAT_HEALTH) <= 0 || intermission == 1)
1181                                 HUD_Reset();
1182
1183                         break;
1184
1185                 case HUD_SPIDERBOT:
1186                         CSQC_SPIDER_HUD();
1187                         break;
1188
1189                 case HUD_WAKIZASHI:
1190                         CSQC_WAKIZASHI_HUD();
1191                         break;
1192         }
1193 }
1194
1195
1196 // following vectors must be global to allow seamless switching between camera modes
1197 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1198 void CSQC_Demo_Camera()
1199 {
1200         float speed, attenuation, dimensions;
1201         vector tmp, delta;
1202
1203         if( cvar("camera_reset") || !camera_mode )
1204         {
1205                 camera_offset = '0 0 0';
1206                 current_angles = '0 0 0';
1207                 camera_direction = '0 0 0';
1208                 camera_offset_z += 30;
1209                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1210                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1211                 current_origin = view_origin;
1212                 current_camera_offset  = camera_offset;
1213                 cvar_set("camera_reset", "0");
1214                 camera_mode = CAMERA_CHASE;
1215         }
1216
1217         // Camera angles
1218         if( camera_roll )
1219                 mouse_angles_z += camera_roll * cvar("camera_speed_roll");
1220
1221         if(cvar("camera_look_player"))
1222         {
1223                 local vector dir;
1224                 local float n;
1225
1226                 dir = normalize(view_origin - current_position);
1227                 n = mouse_angles_z;
1228                 mouse_angles = vectoangles(dir);
1229                 mouse_angles_x = mouse_angles_x * -1;
1230                 mouse_angles_z = n;
1231         }
1232         else
1233         {
1234                 tmp = getmousepos() * 0.1;
1235                 if(vlen(tmp)>cvar("camera_mouse_treshold"))
1236                 {
1237                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1238                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1239                 }
1240         }
1241
1242         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1243         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1244         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1245         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1246
1247         // Fix difference when angles don't have the same sign
1248         delta = '0 0 0';
1249         if(mouse_angles_y < -60 && current_angles_y > 60)
1250                 delta = '0 360 0';
1251         if(mouse_angles_y > 60 && current_angles_y < -60)
1252                 delta = '0 -360 0';
1253
1254         if(cvar("camera_look_player"))
1255                 attenuation = cvar("camera_look_attenuation");
1256         else
1257                 attenuation = cvar("camera_speed_attenuation");
1258
1259         attenuation = 1 / max(1, attenuation);
1260         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1261
1262         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1263         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1264         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1265         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1266
1267         // Camera position
1268         tmp = '0 0 0';
1269         dimensions = 0;
1270
1271         if( camera_direction_x )
1272         {
1273                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1274                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1275                 if( cvar("camera_forward_follows") && !cvar("camera_look_player") )
1276                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1277                 ++dimensions;
1278         }
1279
1280         if( camera_direction_y )
1281         {
1282                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1283                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1284                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1285                 ++dimensions;
1286         }
1287
1288         if( camera_direction_z )
1289         {
1290                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1291                 ++dimensions;
1292         }
1293
1294         if(cvar("camera_free"))
1295                 speed = cvar("camera_speed_free");
1296         else
1297                 speed = cvar("camera_speed_chase");
1298
1299         if(dimensions)
1300         {
1301                 speed = speed * sqrt(1 / dimensions);
1302                 camera_offset += tmp * speed;
1303         }
1304
1305         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1306
1307         // Camera modes
1308         if( cvar("camera_free") )
1309         {
1310                 if ( camera_mode == CAMERA_CHASE )
1311                 {
1312                         current_camera_offset = current_origin + current_camera_offset;
1313                         camera_offset = current_origin + camera_offset;
1314                 }
1315
1316                 camera_mode = CAMERA_FREE;
1317                 current_position = current_camera_offset;
1318         }
1319         else
1320         {
1321                 if ( camera_mode == CAMERA_FREE )
1322                 {
1323                         current_origin = view_origin;
1324                         camera_offset = camera_offset - current_origin;
1325                         current_camera_offset = current_camera_offset - current_origin;
1326                 }
1327
1328                 camera_mode = CAMERA_CHASE;
1329
1330                 if(cvar("camera_chase_smoothly"))
1331                         current_origin += (view_origin - current_origin) * attenuation;
1332                 else
1333                         current_origin = view_origin;
1334
1335                 current_position = current_origin + current_camera_offset;
1336         }
1337
1338         R_SetView(VF_ANGLES, current_angles);
1339         R_SetView(VF_ORIGIN, current_position);
1340 }